New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcsbc.F90 in branches/UKMO/r5518_sst_landsea_cpl/NEMOGCM/NEMO/TOP_SRC/TRP – NEMO

source: branches/UKMO/r5518_sst_landsea_cpl/NEMOGCM/NEMO/TOP_SRC/TRP/trcsbc.F90 @ 7147

Last change on this file since 7147 was 7147, checked in by jcastill, 7 years ago

Remove svn keywords

File size: 10.5 KB
Line 
1MODULE trcsbc
2   !!==============================================================================
3   !!                       ***  MODULE  trcsbc  ***
4   !! Ocean passive tracers:  surface boundary condition
5   !!======================================================================
6   !! History :  8.2  !  1998-10  (G. Madec, G. Roullet, M. Imbard)  Original code
7   !!            8.2  !  2001-02  (D. Ludicone)  sea ice and free surface
8   !!            8.5  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            9.0  !  2004-03  (C. Ethe)  adapted for passive tracers
10   !!                 !  2006-08  (C. Deltel) Diagnose ML trends for passive tracers
11   !!==============================================================================
12#if defined key_top
13   !!----------------------------------------------------------------------
14   !!   'key_top'                                                TOP models
15   !!----------------------------------------------------------------------
16   !!   trc_sbc      : update the tracer trend at ocean surface
17   !!----------------------------------------------------------------------
18   USE oce_trc         ! ocean dynamics and active tracers variables
19   USE trc             ! ocean  passive tracers variables
20   USE prtctl_trc      ! Print control for debbuging
21   USE iom
22   USE trd_oce
23   USE trdtra
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   trc_sbc   ! routine called by step.F90
29
30   REAL(wp) ::   r2dt  !  time-step at surface
31
32   !! * Substitutions
33#  include "domzgr_substitute.h90"
34#  include "vectopt_loop_substitute.h90"
35   !!----------------------------------------------------------------------
36   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
37   !! $Id$
38   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
39   !!----------------------------------------------------------------------
40CONTAINS
41
42   SUBROUTINE trc_sbc ( kt )
43      !!----------------------------------------------------------------------
44      !!                  ***  ROUTINE trc_sbc  ***
45      !!                   
46      !! ** Purpose :   Compute the tracer surface boundary condition trend of
47      !!      (concentration/dilution effect) and add it to the general
48      !!       trend of tracer equations.
49      !!
50      !! ** Method :
51      !!      * concentration/dilution effect:
52      !!            The surface freshwater flux modify the ocean volume
53      !!         and thus the concentration of a tracer as :
54      !!            tra = tra + emp * trn / e3t   for k=1
55      !!         where emp, the surface freshwater budget (evaporation minus
56      !!         precipitation ) given in kg/m2/s is divided
57      !!         by 1035 kg/m3 (density of ocean water) to obtain m/s.
58      !!
59      !! ** Action  : - Update the 1st level of tra with the trend associated
60      !!                with the tracer surface boundary condition
61      !!
62      !!----------------------------------------------------------------------
63      !
64      INTEGER, INTENT( in ) ::   kt          ! ocean time-step index
65      !
66      INTEGER  ::   ji, jj, jn                                     ! dummy loop indices
67      REAL(wp) ::   zse3t, zrtrn, zratio, zfact                    ! temporary scalars
68      REAL(wp) ::   zswitch, zftra, zcd, zdtra, ztfx, ztra         ! temporary scalars
69      CHARACTER (len=22) :: charout
70      REAL(wp), POINTER, DIMENSION(:,:  ) :: zsfx
71      REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrtrd
72
73      !!---------------------------------------------------------------------
74      !
75      IF( nn_timing == 1 )  CALL timing_start('trc_sbc')
76      !
77      ! Allocate temporary workspace
78                      CALL wrk_alloc( jpi, jpj,      zsfx   )
79      IF( l_trdtrc )  CALL wrk_alloc( jpi, jpj, jpk, ztrtrd )
80      !
81      zrtrn = 1.e-15_wp
82
83      SELECT CASE( nn_ice_embd )         ! levitating or embedded sea-ice option
84         CASE( 0    )   ;   zswitch = 1  ! (0) standard levitating sea-ice : salt exchange only
85         CASE( 1, 2 )   ;   zswitch = 0  ! (1) levitating sea-ice: salt and volume exchange but no pressure effect                               
86      !                                  ! (2) embedded sea-ice : salt and volume fluxes and pressure
87      END SELECT
88
89      IF( ln_top_euler) THEN
90         r2dt =  rdttrc(1)              ! = rdttrc (use Euler time stepping)
91      ELSE
92         IF( neuler == 0 .AND. kt == nittrc000 ) THEN     ! at nittrc000
93            r2dt = rdttrc(1)           ! = rdttrc (restarting with Euler time stepping)
94         ELSEIF( kt <= nittrc000 + nn_dttrc ) THEN          ! at nittrc000 or nittrc000+1
95            r2dt = 2. * rdttrc(1)       ! = 2 rdttrc (leapfrog)
96         ENDIF
97      ENDIF
98
99
100      IF( kt == nittrc000 ) THEN
101         IF(lwp) WRITE(numout,*)
102         IF(lwp) WRITE(numout,*) 'trc_sbc : Passive tracers surface boundary condition'
103         IF(lwp) WRITE(numout,*) '~~~~~~~ '
104
105         IF( ln_rsttr .AND.    &                     ! Restart: read in restart  file
106            iom_varid( numrtr, 'sbc_'//TRIM(ctrcnm(1))//'_b', ldstop = .FALSE. ) > 0 ) THEN
107            IF(lwp) WRITE(numout,*) '          nittrc000-nn_dttrc surface tracer content forcing fields red in the restart file'
108            zfact = 0.5_wp
109            DO jn = 1, jptra
110               CALL iom_get( numrtr, jpdom_autoglo, 'sbc_'//TRIM(ctrcnm(jn))//'_b', sbc_trc_b(:,:,jn) )   ! before tracer content sbc
111            END DO
112         ELSE                                         ! No restart or restart not found: Euler forward time stepping
113           zfact = 1._wp
114           sbc_trc_b(:,:,:) = 0._wp
115         ENDIF
116      ELSE                                         ! Swap of forcing fields
117         IF( ln_top_euler ) THEN
118            zfact = 1._wp
119            sbc_trc_b(:,:,:) = 0._wp
120         ELSE
121            zfact = 0.5_wp
122            sbc_trc_b(:,:,:) = sbc_trc(:,:,:)
123         ENDIF
124         !
125      ENDIF
126
127      ! Coupling online : river runoff is added to the horizontal divergence (hdivn) in the subroutine sbc_rnf_div
128      ! one only consider the concentration/dilution effect due to evaporation minus precipitation + freezing/melting of sea-ice
129      ! Coupling offline : runoff are in emp which contains E-P-R
130      !
131      IF( .NOT. lk_offline .AND. lk_vvl ) THEN  ! online coupling with vvl
132         zsfx(:,:) = 0._wp
133      ELSE                                      ! online coupling free surface or offline with free surface
134         zsfx(:,:) = emp(:,:)
135      ENDIF
136
137      ! 0. initialization
138      DO jn = 1, jptra
139         !
140         IF( l_trdtrc ) ztrtrd(:,:,:) = tra(:,:,:,jn)  ! save trends
141         !                                             ! add the trend to the general tracer trend
142
143         IF ( nn_ice_tr == -1 ) THEN  ! No tracers in sea ice (null concentration in sea ice)
144
145            DO jj = 2, jpj
146               DO ji = fs_2, fs_jpim1   ! vector opt.
147                  sbc_trc(ji,jj,jn) = zsfx(ji,jj) * r1_rau0 * trn(ji,jj,1,jn)
148               END DO
149            END DO
150
151         ELSE
152
153            DO jj = 2, jpj
154               DO ji = fs_2, fs_jpim1   ! vector opt.
155                  zse3t = 1. / fse3t(ji,jj,1)
156                  ! tracer flux at the ice/ocean interface (tracer/m2/s)
157                  zftra = - trc_i(ji,jj,jn) * fmmflx(ji,jj) ! uptake of tracer in the sea ice
158                  zcd   =   trc_o(ji,jj,jn) * fmmflx(ji,jj) ! concentration dilution due to freezing-melting,
159                                                               ! only used in the levitating sea ice case
160                  ! tracer flux only       : add concentration dilution term in net tracer flux, no F-M in volume flux
161                  ! tracer and mass fluxes : no concentration dilution term in net tracer flux, F-M term in volume flux
162                  ztfx  = zftra + zswitch * zcd                ! net tracer flux (+C/D if no ice/ocean mass exchange)
163   
164                  zdtra = r1_rau0 * ( ztfx + zsfx(ji,jj) * trn(ji,jj,1,jn) ) 
165                  IF ( zdtra < 0. ) THEN
166                     zratio = -zdtra * zse3t * r2dt / ( trn(ji,jj,1,jn) + zrtrn )
167                     zdtra = MIN(1.0, zratio) * zdtra ! avoid negative concentrations to arise
168                  ENDIF
169                  sbc_trc(ji,jj,jn) =  zdtra 
170               END DO
171            END DO
172         ENDIF
173         !                                       Concentration dilution effect on tracers due to evaporation & precipitation
174         DO jj = 2, jpj
175            DO ji = fs_2, fs_jpim1   ! vector opt.
176               zse3t = zfact / fse3t(ji,jj,1)
177               tra(ji,jj,1,jn) = tra(ji,jj,1,jn) + ( sbc_trc_b(ji,jj,jn) + sbc_trc(ji,jj,jn) ) * zse3t
178            END DO
179         END DO
180         !
181         IF( l_trdtrc ) THEN
182            ztrtrd(:,:,:) = tra(:,:,:,jn) - ztrtrd(:,:,:)
183            CALL trd_tra( kt, 'TRC', jn, jptra_nsr, ztrtrd )
184         END IF
185         !                                                       ! ===========
186      END DO                                                     ! tracer loop
187      !                                                          ! ===========
188
189      !                                           Write in the tracer restar  file
190      !                                          *******************************
191      IF( lrst_trc ) THEN
192         IF(lwp) WRITE(numout,*)
193         IF(lwp) WRITE(numout,*) 'sbc : ocean surface tracer content forcing fields written in tracer restart file ',   &
194            &                    'at it= ', kt,' date= ', ndastp
195         IF(lwp) WRITE(numout,*) '~~~~'
196         DO jn = 1, jptra
197            CALL iom_rstput( kt, nitrst, numrtw, 'sbc_'//TRIM(ctrcnm(jn))//'_b', sbc_trc(:,:,jn) )
198         END DO
199      ENDIF
200      !
201      IF( ln_ctl )   THEN
202         WRITE(charout, FMT="('sbc ')") ;  CALL prt_ctl_trc_info(charout)
203                                           CALL prt_ctl_trc( tab4d=tra, mask=tmask, clinfo=ctrcnm, clinfo2='trd' )
204      ENDIF
205                      CALL wrk_dealloc( jpi, jpj,      zsfx   )
206      IF( l_trdtrc )  CALL wrk_dealloc( jpi, jpj, jpk, ztrtrd )
207      !
208      IF( nn_timing == 1 )  CALL timing_stop('trc_sbc')
209      !
210   END SUBROUTINE trc_sbc
211
212#else
213   !!----------------------------------------------------------------------
214   !!   Dummy module :                      NO passive tracer
215   !!----------------------------------------------------------------------
216CONTAINS
217   SUBROUTINE trc_sbc (kt)              ! Empty routine
218      INTEGER, INTENT(in) :: kt
219      WRITE(*,*) 'trc_sbc: You should not have seen this print! error?', kt
220   END SUBROUTINE trc_sbc
221#endif
222   
223   !!======================================================================
224END MODULE trcsbc
Note: See TracBrowser for help on using the repository browser.