New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv.F90 in branches/UKMO/r5936_INGV1_WAVE-coupling/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/UKMO/r5936_INGV1_WAVE-coupling/NEMOGCM/NEMO/OPA_SRC/TRA/traadv.F90 @ 7167

Last change on this file since 7167 was 7167, checked in by jcastill, 7 years ago

Changes as in branch 2015/dev_r5936_INGV1_WAVE at r7078
File size: 16.5 KB
Line 
1MODULE traadv
2   !!==============================================================================
3   !!                       ***  MODULE  traadv  ***
4   !! Ocean active tracers:  advection trend
5   !!==============================================================================
6   !! History :  2.0  !  2005-11  (G. Madec)  Original code
7   !!            3.3  !  2010-09  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
8   !!            3.6  !  2011-06  (G. Madec)  Addition of Mixed Layer Eddy parameterisation
9   !!            3.7  !  2014-05  (G. Madec)  Add 2nd/4th order cases for CEN and FCT schemes
10   !!             -   !  2014-12  (G. Madec) suppression of cross land advection option
11   !!            3.6  !  2015-06  (E. Clementi) Addition of Stokes drift in case of wave coupling
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   tra_adv       : compute ocean tracer advection trend
16   !!   tra_adv_ctl   : control the different options of advection scheme
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE dom_oce        ! ocean space and time domain
20   USE domvvl         ! variable vertical scale factors
21   USE traadv_cen     ! centered scheme           (tra_adv_cen  routine)
22   USE traadv_fct     ! FCT      scheme           (tra_adv_fct  routine)
23   USE traadv_mus     ! MUSCL    scheme           (tra_adv_mus  routine)
24   USE traadv_ubs     ! UBS      scheme           (tra_adv_ubs  routine)
25   USE traadv_qck     ! QUICKEST scheme           (tra_adv_qck  routine)
26   USE traadv_mle     ! ML eddy induced velocity  (tra_adv_mle  routine)
27   USE ldftra         ! lateral diffusion: eddy diffusivity & EIV coeff.
28   USE ldfslp         ! Lateral diffusion: slopes of neutral surfaces
29   USE c1d            ! 1D vertical configuration
30   !
31   USE in_out_manager ! I/O manager
32   USE iom            ! I/O module
33   USE prtctl         ! Print control
34   USE lib_mpp        ! MPP library
35   USE wrk_nemo       ! Memory Allocation
36   USE timing         ! Timing
37   USE sbcwave        ! wave module
38   USE sbc_oce        ! surface boundary condition: ocean
39
40   USE diaptr         ! Poleward heat transport
41   USE sbcwave        ! wave module
42   USE sbc_oce        ! surface boundary condition: ocean
43
44   IMPLICIT NONE
45   PRIVATE
46
47   PUBLIC   tra_adv        ! routine called by step module
48   PUBLIC   tra_adv_init   ! routine called by opa module
49
50   !                            !!* Namelist namtra_adv *
51   LOGICAL ::   ln_traadv_cen    ! centered scheme flag
52   INTEGER ::      nn_cen_h, nn_cen_v   ! =2/4 : horizontal and vertical choices of the order of CEN scheme
53   LOGICAL ::   ln_traadv_fct    ! FCT scheme flag
54   INTEGER ::      nn_fct_h, nn_fct_v   ! =2/4 : horizontal and vertical choices of the order of FCT scheme
55   INTEGER ::      nn_fct_zts           ! >=1 : 2nd order FCT with vertical sub-timestepping
56   LOGICAL ::   ln_traadv_mus    ! MUSCL scheme flag
57   LOGICAL ::      ln_mus_ups           ! use upstream scheme in vivcinity of river mouths
58   LOGICAL ::   ln_traadv_ubs    ! UBS scheme flag
59   INTEGER ::      nn_ubs_v             ! =2/4 : vertical choice of the order of UBS scheme
60   LOGICAL ::   ln_traadv_qck    ! QUICKEST scheme flag
61
62   INTEGER ::              nadv             ! choice of the type of advection scheme
63   !
64   !                                        ! associated indices:
65   INTEGER, PARAMETER ::   np_NO_adv  = 0   ! no T-S advection
66   INTEGER, PARAMETER ::   np_CEN     = 1   ! 2nd/4th order centered scheme
67   INTEGER, PARAMETER ::   np_FCT     = 2   ! 2nd/4th order Flux Corrected Transport scheme
68   INTEGER, PARAMETER ::   np_FCT_zts = 3   ! 2nd order FCT scheme with vertical sub-timestepping
69   INTEGER, PARAMETER ::   np_MUS     = 4   ! MUSCL scheme
70   INTEGER, PARAMETER ::   np_UBS     = 5   ! 3rd order Upstream Biased Scheme
71   INTEGER, PARAMETER ::   np_QCK     = 6   ! QUICK scheme
72   
73   !! * Substitutions
74#  include "domzgr_substitute.h90"
75#  include "vectopt_loop_substitute.h90"
76   !!----------------------------------------------------------------------
77   !! NEMO/OPA 3.7 , NEMO Consortium (2014)
78   !! $Id$
79   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
80   !!----------------------------------------------------------------------
81CONTAINS
82
83   SUBROUTINE tra_adv( kt )
84      !!----------------------------------------------------------------------
85      !!                  ***  ROUTINE tra_adv  ***
86      !!
87      !! ** Purpose :   compute the ocean tracer advection trend.
88      !!
89      !! ** Method  : - Update (ua,va) with the advection term following nadv
90      !!----------------------------------------------------------------------
91      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
92      !
93      INTEGER ::   jk   ! dummy loop index
94      REAL(wp), POINTER, DIMENSION(:,:,:) :: zun, zvn, zwn
95      !!----------------------------------------------------------------------
96      !
97      IF( nn_timing == 1 )  CALL timing_start('tra_adv')
98      !
99      CALL wrk_alloc( jpi,jpj,jpk,   zun, zvn, zwn )
100      !
101      !                                          ! set time step
102      zun(:,:,:) = 0.0
103      zvn(:,:,:) = 0.0
104      zwn(:,:,:) = 0.0
105      !   
106      IF( neuler == 0 .AND. kt == nit000 ) THEN     ! at nit000
107         r2dtra(:) =  rdttra(:)                          ! = rdtra (restarting with Euler time stepping)
108      ELSEIF( kt <= nit000 + 1) THEN                ! at nit000 or nit000+1
109         r2dtra(:) = 2._wp * rdttra(:)                   ! = 2 rdttra (leapfrog)
110      ENDIF
111      !
112      !                                         !==  effective transport  ==!
113      IF (ln_wave .AND. ln_sdw) THEN
114         DO jk = 1, jpkm1
115            zun(:,:,jk) = e2u(:,:) * fse3u(:,:,jk) *      &
116                        &  ( un(:,:,jk) + usd3d(:,:,jk) )                     !eulerian transport + Stokes Drift
117            zvn(:,:,jk) = e1v(:,:) * fse3v(:,:,jk) *      &
118                        &  ( vn(:,:,jk) + vsd3d(:,:,jk) )
119            zwn(:,:,jk) = e1e2t(:,:) *                    &
120                        &  ( wn(:,:,jk) + wsd3d(:,:,jk) )
121         END DO
122      ELSE
123      DO jk = 1, jpkm1
124         zun(:,:,jk) = e2u  (:,:) * fse3u(:,:,jk) * un(:,:,jk)                  ! eulerian transport only
125         zvn(:,:,jk) = e1v  (:,:) * fse3v(:,:,jk) * vn(:,:,jk)
126         zwn(:,:,jk) = e1e2t(:,:)                 * wn(:,:,jk)
127      END DO
128      ENDIF
129      !
130      IF( ln_vvl_ztilde .OR. ln_vvl_layer ) THEN                                ! add z-tilde and/or vvl corrections
131         zun(:,:,:) = zun(:,:,:) + un_td(:,:,:)
132         zvn(:,:,:) = zvn(:,:,:) + vn_td(:,:,:)
133      ENDIF
134      !
135      zun(:,:,jpk) = 0._wp                                                      ! no transport trough the bottom
136      zvn(:,:,jpk) = 0._wp
137      zwn(:,:,jpk) = 0._wp
138      !
139      IF( ln_ldfeiv .AND. .NOT. ln_traldf_triad )   &
140         &              CALL ldf_eiv_trp( kt, nit000, zun, zvn, zwn, 'TRA' )   ! add the eiv transport (if necessary)
141      !
142      IF( ln_mle    )   CALL tra_adv_mle( kt, nit000, zun, zvn, zwn, 'TRA' )   ! add the mle transport (if necessary)
143      !
144      CALL iom_put( "uocetr_eff", zun )                                        ! output effective transport     
145      CALL iom_put( "vocetr_eff", zvn )
146      CALL iom_put( "wocetr_eff", zwn )
147      !
148!!gm ???
149      IF( ln_diaptr )   CALL dia_ptr( zvn )                                    ! diagnose the effective MSF
150!!gm ???
151      !
152      SELECT CASE ( nadv )                      !==  compute advection trend and add it to general trend  ==!
153      !
154      CASE ( np_CEN )                                    ! Centered scheme : 2nd / 4th order
155         CALL tra_adv_cen    ( kt, nit000, 'TRA',         zun, zvn, zwn     , tsn, tsa, jpts, nn_cen_h, nn_cen_v )
156      CASE ( np_FCT )                                    ! FCT scheme      : 2nd / 4th order
157         CALL tra_adv_fct    ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts, nn_fct_h, nn_fct_v )
158      CASE ( np_FCT_zts )                                ! 2nd order FCT with vertical time-splitting
159         CALL tra_adv_fct_zts( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts        , nn_fct_zts )
160      CASE ( np_MUS )                                    ! MUSCL
161         CALL tra_adv_mus    ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb,      tsa, jpts        , ln_mus_ups ) 
162      CASE ( np_UBS )                                    ! UBS
163         CALL tra_adv_ubs    ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts        , nn_ubs_v   )
164      CASE ( np_QCK )                                    ! QUICKEST
165         CALL tra_adv_qck    ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts                     )
166      !
167      END SELECT
168      !
169      !                                              ! print mean trends (used for debugging)
170      IF(ln_ctl)   CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv  - Ta: ', mask1=tmask,               &
171         &                       tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
172      !
173      IF( nn_timing == 1 )  CALL timing_stop( 'tra_adv' )
174      !
175      CALL wrk_dealloc( jpi,jpj,jpk,   zun, zvn, zwn )
176      !                                         
177   END SUBROUTINE tra_adv
178
179
180   SUBROUTINE tra_adv_init
181      !!---------------------------------------------------------------------
182      !!                  ***  ROUTINE tra_adv_init  ***
183      !!               
184      !! ** Purpose :   Control the consistency between namelist options for
185      !!              tracer advection schemes and set nadv
186      !!----------------------------------------------------------------------
187      INTEGER ::   ioptio, ios   ! Local integers
188      !
189      NAMELIST/namtra_adv/ ln_traadv_cen, nn_cen_h, nn_cen_v,               &   ! CEN
190         &                 ln_traadv_fct, nn_fct_h, nn_fct_v, nn_fct_zts,   &   ! FCT
191         &                 ln_traadv_mus,                     ln_mus_ups,   &   ! MUSCL
192         &                 ln_traadv_ubs,           nn_ubs_v,               &   ! UBS
193         &                 ln_traadv_qck                                        ! QCK
194      !!----------------------------------------------------------------------
195      !
196      !                                !==  Namelist  ==!
197      !
198      REWIND( numnam_ref )                   ! Namelist namtra_adv in reference namelist : Tracer advection scheme
199      READ  ( numnam_ref, namtra_adv, IOSTAT = ios, ERR = 901)
200901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_adv in reference namelist', lwp )
201      !
202      REWIND( numnam_cfg )                   ! Namelist namtra_adv in configuration namelist : Tracer advection scheme
203      READ  ( numnam_cfg, namtra_adv, IOSTAT = ios, ERR = 902 )
204902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_adv in configuration namelist', lwp )
205      IF(lwm) WRITE ( numond, namtra_adv )
206
207      IF(lwp) THEN                           ! Namelist print
208         WRITE(numout,*)
209         WRITE(numout,*) 'tra_adv_init : choice/control of the tracer advection scheme'
210         WRITE(numout,*) '~~~~~~~~~~~'
211         WRITE(numout,*) '   Namelist namtra_adv : chose a advection scheme for tracers'
212         WRITE(numout,*) '      centered scheme                           ln_traadv_cen = ', ln_traadv_cen
213         WRITE(numout,*) '            horizontal 2nd/4th order               nn_cen_h   = ', nn_fct_h
214         WRITE(numout,*) '            vertical   2nd/4th order               nn_cen_v   = ', nn_fct_v
215         WRITE(numout,*) '      Flux Corrected Transport scheme           ln_traadv_fct = ', ln_traadv_fct
216         WRITE(numout,*) '            horizontal 2nd/4th order               nn_fct_h   = ', nn_fct_h
217         WRITE(numout,*) '            vertical   2nd/4th order               nn_fct_v   = ', nn_fct_v
218         WRITE(numout,*) '            2nd order + vertical sub-timestepping  nn_fct_zts = ', nn_fct_zts
219         WRITE(numout,*) '      MUSCL scheme                              ln_traadv_mus = ', ln_traadv_mus
220         WRITE(numout,*) '            + upstream scheme near river mouths    ln_mus_ups = ', ln_mus_ups
221         WRITE(numout,*) '      UBS scheme                                ln_traadv_ubs = ', ln_traadv_ubs
222         WRITE(numout,*) '            vertical   2nd/4th order               nn_ubs_v   = ', nn_ubs_v
223         WRITE(numout,*) '      QUICKEST scheme                           ln_traadv_qck = ', ln_traadv_qck
224      ENDIF
225
226      ioptio = 0                       !==  Parameter control  ==!
227      IF( ln_traadv_cen )   ioptio = ioptio + 1
228      IF( ln_traadv_fct )   ioptio = ioptio + 1
229      IF( ln_traadv_mus )   ioptio = ioptio + 1
230      IF( ln_traadv_ubs )   ioptio = ioptio + 1
231      IF( ln_traadv_qck )   ioptio = ioptio + 1
232      !
233      IF( ioptio == 0 ) THEN
234         nadv = np_NO_adv
235         CALL ctl_warn( 'tra_adv_init: You are running without tracer advection.' )
236      ENDIF
237      IF( (ioptio /= 1).AND. (.NOT. lk_c1d ) ) & 
238        CALL ctl_stop( 'tra_adv_init: Choose ONE advection scheme in namelist namtra_adv' )
239      !
240      IF( ln_traadv_cen .AND. ( nn_cen_h /= 2 .AND. nn_cen_h /= 4 )   &          ! Centered
241                        .AND. ( nn_cen_v /= 2 .AND. nn_cen_v /= 4 )   ) THEN
242        CALL ctl_stop( 'tra_adv_init: CEN scheme, choose 2nd or 4th order' )
243      ENDIF
244      IF( ln_traadv_fct .AND. ( nn_fct_h /= 2 .AND. nn_fct_h /= 4 )   &          ! FCT
245                        .AND. ( nn_fct_v /= 2 .AND. nn_fct_v /= 4 )   ) THEN
246        CALL ctl_stop( 'tra_adv_init: FCT scheme, choose 2nd or 4th order' )
247      ENDIF
248      IF( ln_traadv_fct .AND. nn_fct_zts > 0 ) THEN
249         IF( nn_fct_h == 4 ) THEN
250            nn_fct_h = 2
251            CALL ctl_stop( 'tra_adv_init: force 2nd order FCT scheme, 4th order does not exist with sub-timestepping' )
252         ENDIF
253         IF( lk_vvl ) THEN
254            CALL ctl_stop( 'tra_adv_init: vertical sub-timestepping not allow in non-linear free surface' )
255         ENDIF
256         IF( nn_fct_zts == 1 )   CALL ctl_warn( 'tra_adv_init: FCT with ONE sub-timestep = FCT without sub-timestep' )
257      ENDIF
258      IF( ln_traadv_ubs .AND. ( nn_ubs_v /= 2 .AND. nn_ubs_v /= 4 )   ) THEN     ! UBS
259        CALL ctl_stop( 'tra_adv_init: UBS scheme, choose 2nd or 4th order' )
260      ENDIF
261      IF( ln_traadv_ubs .AND. nn_ubs_v == 4 ) THEN
262         CALL ctl_warn( 'tra_adv_init: UBS scheme, only 2nd FCT scheme available on the vertical. It will be used' )
263      ENDIF
264      IF( ln_isfcav ) THEN                                                       ! ice-shelf cavities
265         IF(  ln_traadv_cen .AND. nn_cen_v /= 4    .OR.   &                            ! NO 4th order with ISF
266            & ln_traadv_fct .AND. nn_fct_v /= 4   )   CALL ctl_stop( 'tra_adv_init: 4th order COMPACT scheme not allowed with ISF' )
267      ENDIF
268      !
269      !                                !==  used advection scheme  ==! 
270      !                                      ! set nadv
271      IF( ln_traadv_cen                      )   nadv = np_CEN
272      IF( ln_traadv_fct                      )   nadv = np_FCT
273      IF( ln_traadv_fct .AND. nn_fct_zts > 0 )   nadv = np_FCT_zts
274      IF( ln_traadv_mus                      )   nadv = np_MUS
275      IF( ln_traadv_ubs                      )   nadv = np_UBS
276      IF( ln_traadv_qck                      )   nadv = np_QCK
277
278      IF(lwp) THEN                           ! Print the choice
279         WRITE(numout,*)
280         IF( nadv == np_NO_adv  )   WRITE(numout,*) '         NO T-S advection'
281         IF( nadv == np_CEN     )   WRITE(numout,*) '         CEN      scheme is used. Horizontal order: ', nn_cen_h,   &
282            &                                                                        ' Vertical   order: ', nn_cen_v
283         IF( nadv == np_FCT     )   WRITE(numout,*) '         FCT      scheme is used. Horizontal order: ', nn_fct_h,   &
284            &                                                                        ' Vertical   order: ', nn_fct_v
285         IF( nadv == np_FCT_zts )   WRITE(numout,*) '         use 2nd order FCT with ', nn_fct_zts,'vertical sub-timestepping'
286         IF( nadv == np_MUS     )   WRITE(numout,*) '         MUSCL    scheme is used'
287         IF( nadv == np_UBS     )   WRITE(numout,*) '         UBS      scheme is used'
288         IF( nadv == np_QCK     )   WRITE(numout,*) '         QUICKEST scheme is used'
289      ENDIF
290      !
291      CALL tra_adv_mle_init            !== initialisation of the Mixed Layer Eddy parametrisation (MLE)  ==!
292      !
293   END SUBROUTINE tra_adv_init
294
295  !!======================================================================
296END MODULE traadv
Note: See TracBrowser for help on using the repository browser.