New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limsbc.F90 in branches/UKMO/r5936_hadgem3_cplseq/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/UKMO/r5936_hadgem3_cplseq/NEMOGCM/NEMO/LIM_SRC_3/limsbc.F90 @ 7131

Last change on this file since 7131 was 7131, checked in by jcastill, 7 years ago

Remove svn keywords

File size: 21.7 KB
Line 
1MODULE limsbc
2   !!======================================================================
3   !!                       ***  MODULE limsbc   ***
4   !!           computation of the flux at the sea ice/ocean interface
5   !!======================================================================
6   !! History :   -   ! 2006-07 (M. Vancoppelle)  LIM3 original code
7   !!            3.0  ! 2008-03 (C. Tallandier)  surface module
8   !!             -   ! 2008-04 (C. Tallandier)  split in 2 + new ice-ocean coupling
9   !!            3.3  ! 2010-05 (G. Madec) decrease ocean & ice reference salinities in the Baltic sea
10   !!                 !                  + simplification of the ice-ocean stress calculation
11   !!            3.4  ! 2011-02 (G. Madec) dynamical allocation
12   !!             -   ! 2012    (D. Iovino) salt flux change
13   !!             -   ! 2012-05 (C. Rousset) add penetration solar flux
14   !!            3.5  ! 2012-10 (A. Coward, G. Madec) salt fluxes ; ice+snow mass
15   !!----------------------------------------------------------------------
16#if defined key_lim3
17   !!----------------------------------------------------------------------
18   !!   'key_lim3'                                    LIM 3.0 sea-ice model
19   !!----------------------------------------------------------------------
20   !!   lim_sbc_alloc : allocate the limsbc arrays
21   !!   lim_sbc_init  : initialisation
22   !!   lim_sbc_flx   : updates mass, heat and salt fluxes at the ocean surface
23   !!   lim_sbc_tau   : update i- and j-stresses, and its modulus at the ocean surface
24   !!----------------------------------------------------------------------
25   USE par_oce          ! ocean parameters
26   USE phycst           ! physical constants
27   USE dom_oce          ! ocean domain
28   USE ice              ! LIM sea-ice variables
29   USE sbc_ice          ! Surface boundary condition: sea-ice fields
30   USE sbc_oce          ! Surface boundary condition: ocean fields
31   USE sbccpl
32   USE oce       , ONLY : sshn, sshb, snwice_mass, snwice_mass_b, snwice_fmass
33   USE albedo           ! albedo parameters
34   USE lbclnk           ! ocean lateral boundary condition - MPP exchanges
35   USE lib_mpp          ! MPP library
36   USE wrk_nemo         ! work arrays
37   USE in_out_manager   ! I/O manager
38   USE prtctl           ! Print control
39   USE lib_fortran      ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
40   USE traqsr           ! add penetration of solar flux in the calculation of heat budget
41   USE iom
42   USE domvvl           ! Variable volume
43   USE limctl
44   USE limcons
45
46   IMPLICIT NONE
47   PRIVATE
48
49   PUBLIC   lim_sbc_init   ! called by sbc_lim_init
50   PUBLIC   lim_sbc_flx    ! called by sbc_ice_lim
51   PUBLIC   lim_sbc_tau    ! called by sbc_ice_lim
52
53   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   utau_oce, vtau_oce   ! air-ocean surface i- & j-stress     [N/m2]
54   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   tmod_io              ! modulus of the ice-ocean velocity   [m/s]
55   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::   soce_0  , sice_0     ! cst SSS and ice salinity (levitating sea-ice)
56
57   !! * Substitutions
58#  include "vectopt_loop_substitute.h90"
59#  include "domzgr_substitute.h90"
60   !!----------------------------------------------------------------------
61   !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2011)
62   !! $Id$
63   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
64   !!----------------------------------------------------------------------
65CONTAINS
66
67   INTEGER FUNCTION lim_sbc_alloc()
68      !!-------------------------------------------------------------------
69      !!             ***  ROUTINE lim_sbc_alloc ***
70      !!-------------------------------------------------------------------
71      ALLOCATE( soce_0(jpi,jpj) , utau_oce(jpi,jpj) ,                       &
72         &      sice_0(jpi,jpj) , vtau_oce(jpi,jpj) , tmod_io(jpi,jpj), STAT=lim_sbc_alloc)
73         !
74      IF( lk_mpp             )   CALL mpp_sum( lim_sbc_alloc )
75      IF( lim_sbc_alloc /= 0 )   CALL ctl_warn('lim_sbc_alloc: failed to allocate arrays')
76   END FUNCTION lim_sbc_alloc
77
78
79   SUBROUTINE lim_sbc_flx( kt )
80      !!-------------------------------------------------------------------
81      !!                ***  ROUTINE lim_sbc_flx ***
82      !! 
83      !! ** Purpose :   Update the surface ocean boundary condition for heat
84      !!              salt and mass over areas where sea-ice is non-zero
85      !!         
86      !! ** Action  : - computes the heat and freshwater/salt fluxes
87      !!              at the ice-ocean interface.
88      !!              - Update the ocean sbc
89      !!     
90      !! ** Outputs : - qsr     : sea heat flux:     solar
91      !!              - qns     : sea heat flux: non solar
92      !!              - emp     : freshwater budget: volume flux
93      !!              - sfx     : salt flux
94      !!              - fr_i    : ice fraction
95      !!              - tn_ice  : sea-ice surface temperature
96      !!              - alb_ice : sea-ice albedo (only useful in coupled mode)
97      !!
98      !! References : Goosse, H. et al. 1996, Bul. Soc. Roy. Sc. Liege, 65, 87-90.
99      !!              Tartinville et al. 2001 Ocean Modelling, 3, 95-108.
100      !!              These refs are now obsolete since everything has been revised
101      !!              The ref should be Rousset et al., 2015
102      !!---------------------------------------------------------------------
103      INTEGER, INTENT(in) ::   kt                                  ! number of iteration
104      INTEGER  ::   ji, jj, jl, jk                                 ! dummy loop indices
105      REAL(wp) ::   zqmass                                         ! Heat flux associated with mass exchange ice->ocean (W.m-2)
106      REAL(wp) ::   zqsr                                           ! New solar flux received by the ocean
107      !
108      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zalb_cs, zalb_os     ! 2D/3D workspace
109      !!---------------------------------------------------------------------
110
111      ! make calls for heat fluxes before it is modified
112      IF( iom_use('qsr_oce') )   CALL iom_put( "qsr_oce" , qsr_oce(:,:) * pfrld(:,:) )                                   !     solar flux at ocean surface
113      IF( iom_use('qns_oce') )   CALL iom_put( "qns_oce" , qns_oce(:,:) * pfrld(:,:) + qemp_oce(:,:) )                   ! non-solar flux at ocean surface
114      IF( iom_use('qsr_ice') )   CALL iom_put( "qsr_ice" , SUM( qsr_ice(:,:,:) * a_i_b(:,:,:), dim=3 ) )                 !     solar flux at ice surface
115      IF( iom_use('qns_ice') )   CALL iom_put( "qns_ice" , SUM( qns_ice(:,:,:) * a_i_b(:,:,:), dim=3 ) + qemp_ice(:,:) ) ! non-solar flux at ice surface
116      IF( iom_use('qtr_ice') )   CALL iom_put( "qtr_ice" , SUM( ftr_ice(:,:,:) * a_i_b(:,:,:), dim=3 ) )                 !     solar flux transmitted thru ice
117      IF( iom_use('qt_oce' ) )   CALL iom_put( "qt_oce"  , ( qsr_oce(:,:) + qns_oce(:,:) ) * pfrld(:,:) + qemp_oce(:,:) ) 
118      IF( iom_use('qt_ice' ) )   CALL iom_put( "qt_ice"  , SUM( ( qns_ice(:,:,:) + qsr_ice(:,:,:) )   &
119         &                                                      * a_i_b(:,:,:), dim=3 ) + qemp_ice(:,:) )
120      IF( iom_use('qemp_oce' ) )   CALL iom_put( "qemp_oce"  , qemp_oce(:,:) ) 
121      IF( iom_use('qemp_ice' ) )   CALL iom_put( "qemp_ice"  , qemp_ice(:,:) ) 
122
123      ! pfrld is the lead fraction at the previous time step (actually between TRP and THD)
124      DO jj = 1, jpj
125         DO ji = 1, jpi
126
127            !------------------------------------------!
128            !      heat flux at the ocean surface      !
129            !------------------------------------------!
130            ! Solar heat flux reaching the ocean = zqsr (W.m-2)
131            !---------------------------------------------------
132            zqsr = qsr_tot(ji,jj)
133            DO jl = 1, jpl
134               zqsr = zqsr - a_i_b(ji,jj,jl) * (  qsr_ice(ji,jj,jl) - ftr_ice(ji,jj,jl) ) 
135            END DO
136
137            ! Total heat flux reaching the ocean = hfx_out (W.m-2)
138            !---------------------------------------------------
139            zqmass         = hfx_thd(ji,jj) + hfx_dyn(ji,jj) + hfx_res(ji,jj) ! heat flux from snow is 0 (T=0 degC)
140            hfx_out(ji,jj) = hfx_out(ji,jj) + zqmass + zqsr
141
142            ! Add the residual from heat diffusion equation (W.m-2)
143            !-------------------------------------------------------
144            hfx_out(ji,jj) = hfx_out(ji,jj) + hfx_err_dif(ji,jj)
145
146            ! New qsr and qns used to compute the oceanic heat flux at the next time step
147            !---------------------------------------------------
148            qsr(ji,jj) = zqsr                                     
149            qns(ji,jj) = hfx_out(ji,jj) - zqsr             
150
151            !------------------------------------------!
152            !      mass flux at the ocean surface      !
153            !------------------------------------------!
154            !  case of realistic freshwater flux (Tartinville et al., 2001) (presently ACTIVATED)
155            !  -------------------------------------------------------------------------------------
156            !  The idea of this approach is that the system that we consider is the ICE-OCEAN system
157            !  Thus  FW  flux  =  External ( E-P+snow melt)
158            !       Salt flux  =  Exchanges in the ice-ocean system then converted into FW
159            !                     Associated to Ice formation AND Ice melting
160            !                     Even if i see Ice melting as a FW and SALT flux
161            !       
162            ! mass flux from ice/ocean
163            wfx_ice(ji,jj) = wfx_bog(ji,jj) + wfx_bom(ji,jj) + wfx_sum(ji,jj) + wfx_sni(ji,jj)   &
164                           + wfx_opw(ji,jj) + wfx_dyn(ji,jj) + wfx_res(ji,jj)
165
166            ! mass flux at the ocean/ice interface
167            fmmflx(ji,jj) = - ( wfx_ice(ji,jj) + wfx_snw(ji,jj) ) * r1_rdtice  ! F/M mass flux save at least for biogeochemical model
168            emp(ji,jj)    = emp_oce(ji,jj) - wfx_ice(ji,jj) - wfx_snw(ji,jj)   ! mass flux + F/M mass flux (always ice/ocean mass exchange)
169           
170         END DO
171      END DO
172
173      !------------------------------------------!
174      !      salt flux at the ocean surface      !
175      !------------------------------------------!
176      sfx(:,:) = sfx_bog(:,:) + sfx_bom(:,:) + sfx_sum(:,:) + sfx_sni(:,:) + sfx_opw(:,:)   &
177         &     + sfx_res(:,:) + sfx_dyn(:,:) + sfx_bri(:,:)
178
179      !-------------------------------------------------------------!
180      !   mass of snow and ice per unit area for embedded sea-ice   !
181      !-------------------------------------------------------------!
182      IF( nn_ice_embd /= 0 ) THEN
183         ! save mass from the previous ice time step
184         snwice_mass_b(:,:) = snwice_mass(:,:)                 
185         ! new mass per unit area
186         snwice_mass  (:,:) = tmask(:,:,1) * ( rhosn * vt_s(:,:) + rhoic * vt_i(:,:)  ) 
187         ! time evolution of snow+ice mass
188         snwice_fmass (:,:) = ( snwice_mass(:,:) - snwice_mass_b(:,:) ) * r1_rdtice
189      ENDIF
190
191      !-----------------------------------------------!
192      !   Storing the transmitted variables           !
193      !-----------------------------------------------!
194      fr_i  (:,:)   = at_i(:,:)             ! Sea-ice fraction           
195      tn_ice(:,:,:) = t_su(:,:,:)           ! Ice surface temperature                     
196
197      !------------------------------------------------------------------------!
198      !    Snow/ice albedo (only if sent to coupler, useless in forced mode)   !
199      !------------------------------------------------------------------------!
200      CALL wrk_alloc( jpi, jpj, jpl, zalb_cs, zalb_os )   
201      CALL albedo_ice( t_su, ht_i, ht_s, zalb_cs, zalb_os )  ! cloud-sky and overcast-sky ice albedos
202      alb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:)
203      CALL wrk_dealloc( jpi, jpj, jpl, zalb_cs, zalb_os )
204
205      ! conservation test
206      IF( ln_limdiahsb ) CALL lim_cons_final( 'limsbc' )
207
208      ! control prints
209      IF( ln_icectl )   CALL lim_prt( kt, iiceprt, jiceprt, 3, ' - Final state lim_sbc - ' )
210
211      IF(ln_ctl) THEN
212         CALL prt_ctl( tab2d_1=qsr   , clinfo1=' lim_sbc: qsr    : ', tab2d_2=qns , clinfo2=' qns     : ' )
213         CALL prt_ctl( tab2d_1=emp   , clinfo1=' lim_sbc: emp    : ', tab2d_2=sfx , clinfo2=' sfx     : ' )
214         CALL prt_ctl( tab2d_1=fr_i  , clinfo1=' lim_sbc: fr_i   : ' )
215         CALL prt_ctl( tab3d_1=tn_ice, clinfo1=' lim_sbc: tn_ice : ', kdim=jpl )
216      ENDIF
217
218   END SUBROUTINE lim_sbc_flx
219
220
221   SUBROUTINE lim_sbc_tau( kt , pu_oce, pv_oce )
222      !!-------------------------------------------------------------------
223      !!                ***  ROUTINE lim_sbc_tau ***
224      !! 
225      !! ** Purpose : Update the ocean surface stresses due to the ice
226      !!         
227      !! ** Action  : * at each ice time step (every nn_fsbc time step):
228      !!                - compute the modulus of ice-ocean relative velocity
229      !!                  (*rho*Cd) at T-point (C-grid) or I-point (B-grid)
230      !!                      tmod_io = rhoco * | U_ice-U_oce |
231      !!                - update the modulus of stress at ocean surface
232      !!                      taum = frld * taum + (1-frld) * tmod_io * | U_ice-U_oce |
233      !!              * at each ocean time step (every kt):
234      !!                  compute linearized ice-ocean stresses as
235      !!                      Utau = tmod_io * | U_ice - pU_oce |
236      !!                using instantaneous current ocean velocity (usually before)
237      !!
238      !!    NB: - ice-ocean rotation angle no more allowed
239      !!        - here we make an approximation: taum is only computed every ice time step
240      !!          This avoids mutiple average to pass from T -> U,V grids and next from U,V grids
241      !!          to T grid. taum is used in TKE and GLS, which should not be too sensitive to this approximaton...
242      !!
243      !! ** Outputs : - utau, vtau   : surface ocean i- and j-stress (u- & v-pts) updated with ice-ocean fluxes
244      !!              - taum         : modulus of the surface ocean stress (T-point) updated with ice-ocean fluxes
245      !!---------------------------------------------------------------------
246      INTEGER ,                     INTENT(in) ::   kt               ! ocean time-step index
247      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) ::   pu_oce, pv_oce   ! surface ocean currents
248      !!
249      INTEGER  ::   ji, jj   ! dummy loop indices
250      REAL(wp) ::   zat_u, zutau_ice, zu_t, zmodt   ! local scalar
251      REAL(wp) ::   zat_v, zvtau_ice, zv_t          !   -      -
252      !!---------------------------------------------------------------------
253      !
254      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN     !==  Ice time-step only  ==!   (i.e. surface module time-step)
255         DO jj = 2, jpjm1                             !* update the modulus of stress at ocean surface (T-point)
256            DO ji = fs_2, fs_jpim1
257               !                                               ! 2*(U_ice-U_oce) at T-point
258               zu_t = u_ice(ji,jj) + u_ice(ji-1,jj) - u_oce(ji,jj) - u_oce(ji-1,jj)   
259               zv_t = v_ice(ji,jj) + v_ice(ji,jj-1) - v_oce(ji,jj) - v_oce(ji,jj-1) 
260               !                                              ! |U_ice-U_oce|^2
261               zmodt =  0.25_wp * (  zu_t * zu_t + zv_t * zv_t  )
262               !                                               ! update the ocean stress modulus
263               taum(ji,jj) = ( 1._wp - at_i(ji,jj) ) * taum(ji,jj) + at_i(ji,jj) * rhoco * zmodt
264               tmod_io(ji,jj) = rhoco * SQRT( zmodt )          ! rhoco * |U_ice-U_oce| at T-point
265            END DO
266         END DO
267         CALL lbc_lnk( taum, 'T', 1. )   ;   CALL lbc_lnk( tmod_io, 'T', 1. )
268         !
269         utau_oce(:,:) = utau(:,:)                    !* save the air-ocean stresses at ice time-step
270         vtau_oce(:,:) = vtau(:,:)
271         !
272      ENDIF
273      !
274      !                                      !==  every ocean time-step  ==!
275      !
276      DO jj = 2, jpjm1                                !* update the stress WITHOUT a ice-ocean rotation angle
277         DO ji = fs_2, fs_jpim1   ! Vect. Opt.
278            zat_u  = ( at_i(ji,jj) + at_i(ji+1,jj) ) * 0.5_wp   ! ice area at u and V-points
279            zat_v  = ( at_i(ji,jj) + at_i(ji,jj+1) ) * 0.5_wp
280            !                                                   ! linearized quadratic drag formulation
281            zutau_ice   = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji+1,jj) ) * ( u_ice(ji,jj) - pu_oce(ji,jj) )
282            zvtau_ice   = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji,jj+1) ) * ( v_ice(ji,jj) - pv_oce(ji,jj) )
283            !                                                   ! stresses at the ocean surface
284            utau(ji,jj) = ( 1._wp - zat_u ) * utau_oce(ji,jj) + zat_u * zutau_ice
285            vtau(ji,jj) = ( 1._wp - zat_v ) * vtau_oce(ji,jj) + zat_v * zvtau_ice
286         END DO
287      END DO
288      CALL lbc_lnk( utau, 'U', -1. )   ;   CALL lbc_lnk( vtau, 'V', -1. )   ! lateral boundary condition
289      !
290      IF(ln_ctl)   CALL prt_ctl( tab2d_1=utau, clinfo1=' lim_sbc: utau   : ', mask1=umask,   &
291         &                       tab2d_2=vtau, clinfo2=' vtau    : '        , mask2=vmask )
292     
293   END SUBROUTINE lim_sbc_tau
294
295
296   SUBROUTINE lim_sbc_init
297      !!-------------------------------------------------------------------
298      !!                  ***  ROUTINE lim_sbc_init  ***
299      !!             
300      !! ** Purpose : Preparation of the file ice_evolu for the output of
301      !!      the temporal evolution of key variables
302      !!
303      !! ** input   : Namelist namicedia
304      !!-------------------------------------------------------------------
305      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
306      REAL(wp) ::   zcoefu, zcoefv, zcoeff          ! local scalar
307      IF(lwp) WRITE(numout,*)
308      IF(lwp) WRITE(numout,*) 'lim_sbc_init : LIM-3 sea-ice - surface boundary condition'
309      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~   '
310
311      !                                      ! allocate lim_sbc array
312      IF( lim_sbc_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'lim_sbc_init : unable to allocate standard arrays' )
313      !
314      soce_0(:,:) = soce                     ! constant SSS and ice salinity used in levitating sea-ice case
315      sice_0(:,:) = sice
316      !
317      IF( cp_cfg == "orca" ) THEN            ! decrease ocean & ice reference salinities in the Baltic sea
318         WHERE( 14._wp <= glamt(:,:) .AND. glamt(:,:) <= 32._wp .AND.   &
319            &   54._wp <= gphit(:,:) .AND. gphit(:,:) <= 66._wp         ) 
320            soce_0(:,:) = 4._wp
321            sice_0(:,:) = 2._wp
322         END WHERE
323      ENDIF
324      !
325      IF( .NOT. ln_rstart ) THEN
326         !                                      ! embedded sea ice
327         IF( nn_ice_embd /= 0 ) THEN            ! mass exchanges between ice and ocean (case 1 or 2) set the snow+ice mass
328            snwice_mass  (:,:) = tmask(:,:,1) * ( rhosn * vt_s(:,:) + rhoic * vt_i(:,:)  )
329            snwice_mass_b(:,:) = snwice_mass(:,:)
330         ELSE
331            snwice_mass  (:,:) = 0.0_wp         ! no mass exchanges
332            snwice_mass_b(:,:) = 0.0_wp         ! no mass exchanges
333         ENDIF
334         IF( nn_ice_embd == 2 ) THEN            ! full embedment (case 2) deplete the initial ssh below sea-ice area
335            sshn(:,:) = sshn(:,:) - snwice_mass(:,:) * r1_rau0
336            sshb(:,:) = sshb(:,:) - snwice_mass(:,:) * r1_rau0
337#if defined key_vvl           
338           ! key_vvl necessary? clem: yes for compilation purpose
339            DO jk = 1,jpkm1                     ! adjust initial vertical scale factors
340               fse3t_n(:,:,jk) = e3t_0(:,:,jk)*( 1._wp + sshn(:,:)*tmask(:,:,1)/(ht_0(:,:) + 1.0 - tmask(:,:,1)) )
341               fse3t_b(:,:,jk) = e3t_0(:,:,jk)*( 1._wp + sshb(:,:)*tmask(:,:,1)/(ht_0(:,:) + 1.0 - tmask(:,:,1)) )
342            ENDDO
343            fse3t_a(:,:,:) = fse3t_b(:,:,:)
344            ! Reconstruction of all vertical scale factors at now and before time
345            ! steps
346            ! =============================================================================
347            ! Horizontal scale factor interpolations
348            ! --------------------------------------
349            CALL dom_vvl_interpol( fse3t_b(:,:,:), fse3u_b(:,:,:), 'U' )
350            CALL dom_vvl_interpol( fse3t_b(:,:,:), fse3v_b(:,:,:), 'V' )
351            CALL dom_vvl_interpol( fse3t_n(:,:,:), fse3u_n(:,:,:), 'U' )
352            CALL dom_vvl_interpol( fse3t_n(:,:,:), fse3v_n(:,:,:), 'V' )
353            CALL dom_vvl_interpol( fse3u_n(:,:,:), fse3f_n(:,:,:), 'F' )
354            ! Vertical scale factor interpolations
355            ! ------------------------------------
356            CALL dom_vvl_interpol( fse3t_n(:,:,:), fse3w_n (:,:,:), 'W'  )
357            CALL dom_vvl_interpol( fse3u_n(:,:,:), fse3uw_n(:,:,:), 'UW' )
358            CALL dom_vvl_interpol( fse3v_n(:,:,:), fse3vw_n(:,:,:), 'VW' )
359            CALL dom_vvl_interpol( fse3u_b(:,:,:), fse3uw_b(:,:,:), 'UW' )
360            CALL dom_vvl_interpol( fse3v_b(:,:,:), fse3vw_b(:,:,:), 'VW' )
361            ! t- and w- points depth
362            ! ----------------------
363            fsdept_n(:,:,1) = 0.5_wp * fse3w_n(:,:,1)
364            fsdepw_n(:,:,1) = 0.0_wp
365            fsde3w_n(:,:,1) = fsdept_n(:,:,1) - sshn(:,:)
366            DO jk = 2, jpk
367               fsdept_n(:,:,jk) = fsdept_n(:,:,jk-1) + fse3w_n(:,:,jk)
368               fsdepw_n(:,:,jk) = fsdepw_n(:,:,jk-1) + fse3t_n(:,:,jk-1)
369               fsde3w_n(:,:,jk) = fsdept_n(:,:,jk  ) - sshn   (:,:)
370            END DO
371#endif
372         ENDIF
373      ENDIF ! .NOT. ln_rstart
374      !
375
376   END SUBROUTINE lim_sbc_init
377
378#else
379   !!----------------------------------------------------------------------
380   !!   Default option :        Dummy module       NO LIM 3.0 sea-ice model
381   !!----------------------------------------------------------------------
382CONTAINS
383   SUBROUTINE lim_sbc           ! Dummy routine
384   END SUBROUTINE lim_sbc
385#endif 
386
387   !!======================================================================
388END MODULE limsbc
Note: See TracBrowser for help on using the repository browser.