New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcflx.F90 in branches/UKMO/r6232_HZG_WAVE-coupling/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/UKMO/r6232_HZG_WAVE-coupling/NEMOGCM/NEMO/OPA_SRC/SBC/sbcflx.F90 @ 7854

Last change on this file since 7854 was 7854, checked in by jcastill, 7 years ago

Addition of the HZG drag coefficient modification for core forcing - the input winds will be read from the core forcing input files, instead of being calculated from a wind wave forcing file
File size: 12.0 KB
Line 
1MODULE sbcflx
2   !!======================================================================
3   !!                       ***  MODULE  sbcflx  ***
4   !! Ocean forcing:  momentum, heat and freshwater flux formulation
5   !!=====================================================================
6   !! History :  1.0  !  2006-06  (G. Madec)  Original code
7   !!            3.3  !  2010-10  (S. Masson)  add diurnal cycle
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   namflx   : flux formulation namlist
12   !!   sbc_flx  : flux formulation as ocean surface boundary condition (forced mode, fluxes read in NetCDF files)
13   !!----------------------------------------------------------------------
14   USE oce             ! ocean dynamics and tracers
15   USE dom_oce         ! ocean space and time domain
16   USE sbc_oce         ! surface boundary condition: ocean fields
17   USE sbcdcy          ! surface boundary condition: diurnal cycle on qsr
18   USE phycst          ! physical constants
19   USE fldread         ! read input fields
20   USE iom             ! IOM library
21   USE in_out_manager  ! I/O manager
22   USE lib_mpp         ! distribued memory computing library
23   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
24   USE sbcwave         ! wave physics
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC sbc_flx       ! routine called by step.F90
30
31   INTEGER , PARAMETER ::   jpfld   = 5   ! maximum number of files to read
32   INTEGER , PARAMETER ::   jp_utau = 1   ! index of wind stress (i-component) file
33   INTEGER , PARAMETER ::   jp_vtau = 2   ! index of wind stress (j-component) file
34   INTEGER , PARAMETER ::   jp_qtot = 3   ! index of total (non solar+solar) heat file
35   INTEGER , PARAMETER ::   jp_qsr  = 4   ! index of solar heat file
36   INTEGER , PARAMETER ::   jp_emp  = 5   ! index of evaporation-precipation file
37   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf    ! structure of input fields (file informations, fields read)
38   LOGICAL , PUBLIC    ::   ln_shelf_flx = .FALSE. ! UKMO SHELF specific flux flag
39   INTEGER             ::   jpfld_local   ! maximum number of files to read (locally modified depending on ln_shelf_flx)
40
41   !! * Substitutions
42#  include "domzgr_substitute.h90"
43#  include "vectopt_loop_substitute.h90"
44   !!----------------------------------------------------------------------
45   !! NEMO/OPA 3.3 , NEMO-consortium (2010)
46   !! $Id$
47   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51   SUBROUTINE sbc_flx( kt )
52      !!---------------------------------------------------------------------
53      !!                    ***  ROUTINE sbc_flx  ***
54      !!                   
55      !! ** Purpose :   provide at each time step the surface ocean fluxes
56      !!                (momentum, heat, freshwater and runoff)
57      !!
58      !! ** Method  : - READ each fluxes in NetCDF files:
59      !!                   i-component of the stress              utau  (N/m2)
60      !!                   j-component of the stress              vtau  (N/m2)
61      !!                   net downward heat flux                 qtot  (watt/m2)
62      !!                   net downward radiative flux            qsr   (watt/m2)
63      !!                   net upward freshwater (evapo - precip) emp   (kg/m2/s)
64      !!
65      !!      CAUTION :  - never mask the surface stress fields
66      !!                 - the stress is assumed to be in the (i,j) mesh referential
67      !!
68      !! ** Action  :   update at each time-step
69      !!              - utau, vtau  i- and j-component of the wind stress
70      !!              - taum        wind stress module at T-point
71      !!              - wndm        10m wind module at T-point
72      !!              - qns         non solar heat flux including heat flux due to emp
73      !!              - qsr         solar heat flux
74      !!              - emp         upward mass flux (evap. - precip.)
75      !!              - sfx         salt flux; set to zero at nit000 but possibly non-zero
76      !!                            if ice is present (computed in limsbc(_2).F90)
77      !!----------------------------------------------------------------------
78      INTEGER, INTENT(in) ::   kt   ! ocean time step
79      !!
80      INTEGER  ::   ji, jj, jf            ! dummy indices
81      INTEGER  ::   ierror                ! return error code
82      INTEGER  ::   ios                   ! Local integer output status for namelist read
83      REAL(wp) ::   zfact                 ! temporary scalar
84      REAL(wp) ::   zrhoa  = 1.22         ! Air density kg/m3
85      REAL(wp) ::   zcdrag = 1.5e-3       ! drag coefficient
86      REAL(wp) ::   totwind               ! UKMO SHELF: Module of wind speed
87      REAL(wp) ::   ztx, zty, zmod, zcoef ! temporary variables
88      !!
89      CHARACTER(len=100) ::  cn_dir                               ! Root directory for location of flx files
90      NAMELIST/namsbc_flx/ ln_shelf_flx                           ! Put here to allow merging with another UKMO branch
91      TYPE(FLD_N), DIMENSION(jpfld) ::   slf_i                    ! array of namelist information structures
92      TYPE(FLD_N) ::   sn_utau, sn_vtau, sn_qtot, sn_qsr, sn_emp  ! informations about the fields to be read
93      NAMELIST/namsbc_flx/ cn_dir, sn_utau, sn_vtau, sn_qtot, sn_qsr, sn_emp
94      !!---------------------------------------------------------------------
95      !
96      IF( kt == nit000 ) THEN                ! First call kt=nit000 
97         ! set file information
98         REWIND( numnam_ref )              ! Namelist namsbc_flx in reference namelist : Files for fluxes
99         READ  ( numnam_ref, namsbc_flx, IOSTAT = ios, ERR = 901)
100901      IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_flx in reference namelist', lwp )
101
102         REWIND( numnam_cfg )              ! Namelist namsbc_flx in configuration namelist : Files for fluxes
103         READ  ( numnam_cfg, namsbc_flx, IOSTAT = ios, ERR = 902 )
104902      IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_flx in configuration namelist', lwp )
105         IF(lwm) WRITE ( numond, namsbc_flx ) 
106         !
107         !                                         ! check: do we plan to use ln_dm2dc with non-daily forcing?
108         IF( ln_dm2dc .AND. sn_qsr%nfreqh /= 24 )   &
109            &   CALL ctl_stop( 'sbc_blk_core: ln_dm2dc can be activated only with daily short-wave forcing' ) 
110         !
111         !                                         ! store namelist information in an array
112         slf_i(jp_utau) = sn_utau   ;   slf_i(jp_vtau) = sn_vtau
113         slf_i(jp_qtot) = sn_qtot   ;   slf_i(jp_qsr ) = sn_qsr 
114         slf_i(jp_emp ) = sn_emp
115         !
116         ALLOCATE( sf(jpfld), STAT=ierror )        ! set sf structure
117         IF( ierror > 0 ) THEN   
118            CALL ctl_stop( 'sbc_flx: unable to allocate sf structure' )   ;   RETURN 
119         ENDIF
120         DO ji= 1, jpfld
121            ALLOCATE( sf(ji)%fnow(jpi,jpj,1) )
122            IF( slf_i(ji)%ln_tint ) ALLOCATE( sf(ji)%fdta(jpi,jpj,1,2) )
123         END DO
124         !                                         ! fill sf with slf_i and control print
125         CALL fld_fill( sf, slf_i, cn_dir, 'sbc_flx', 'flux formulation for ocean surface boundary condition', 'namsbc_flx' )
126         !
127         sfx(:,:) = 0.0_wp                         ! salt flux due to freezing/melting (non-zero only if ice is present; set in limsbc(_2).F90)
128         !
129      ENDIF
130
131      CALL fld_read( kt, nn_fsbc, sf )                            ! input fields provided at the current time-step
132     
133      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN                        ! update ocean fluxes at each SBC frequency
134
135         IF( ln_dm2dc ) THEN   ;   qsr(:,:) = sbc_dcy( sf(jp_qsr)%fnow(:,:,1) )   ! modify now Qsr to include the diurnal cycle
136         ELSE                  ;   qsr(:,:) =          sf(jp_qsr)%fnow(:,:,1)
137         ENDIF
138!CDIR COLLAPSE
139         DO jj = 1, jpj                                           ! set the ocean fluxes from read fields
140            DO ji = 1, jpi
141               utau(ji,jj) = sf(jp_utau)%fnow(ji,jj,1)
142               vtau(ji,jj) = sf(jp_vtau)%fnow(ji,jj,1)
143               qns (ji,jj) = sf(jp_qtot)%fnow(ji,jj,1) - sf(jp_qsr)%fnow(ji,jj,1)
144               emp (ji,jj) = sf(jp_emp )%fnow(ji,jj,1)
145            END DO
146         END DO
147         !                                                        ! add modification due to drag coefficient read from wave forcing
148         !                                                        ! this code is inefficient but put here to allow merging with another UKMO branch
149         IF( ln_shelf_flx ) THEN
150            IF( ln_cdgw .AND. nn_drag == jp_std ) THEN
151               IF( cpl_wdrag ) THEN 
152                  ! reset utau and vtau to the wind components: the momentum will
153                  ! be calculated from the coupled value of the drag coefficient
154                  DO jj = 1, jpj
155                     DO ji = 1, jpi
156                        utau(ji,jj) = sf(jp_utau)%fnow(ji,jj,1)
157                        vtau(ji,jj) = sf(jp_vtau)%fnow(ji,jj,1)
158                     END DO
159                  END DO
160               ELSE
161                  DO jj = 1, jpj
162                     DO ji = 1, jpi
163                        totwind = sqrt((sf(jp_utau)%fnow(ji,jj,1))**2.0 + (sf(jp_vtau)%fnow(ji,jj,1))**2.0)
164                        utau(ji,jj) = zrhoa * cdn_wave(ji,jj) * sf(jp_utau)%fnow(ji,jj,1) * totwind
165                        vtau(ji,jj) = zrhoa * cdn_wave(ji,jj) * sf(jp_vtau)%fnow(ji,jj,1) * totwind
166                     END DO
167                  END DO
168               ENDIF
169            ELSE IF( nn_drag == jp_const ) THEN
170               DO jj = 1, jpj
171                  DO ji = 1, jpi
172                     totwind = sqrt((sf(jp_utau)%fnow(ji,jj,1))**2.0 + (sf(jp_vtau)%fnow(ji,jj,1))**2.0)
173                     utau(ji,jj) = zrhoa * zcdrag * sf(jp_utau)%fnow(ji,jj,1) * totwind
174                     vtau(ji,jj) = zrhoa * zcdrag * sf(jp_vtau)%fnow(ji,jj,1) * totwind
175                  END DO
176               END DO
177            ENDIF
178         ENDIF
179         !                                                        ! add to qns the heat due to e-p
180         qns(:,:) = qns(:,:) - emp(:,:) * sst_m(:,:) * rcp        ! mass flux is at SST
181         !
182         !                                                        ! module of wind stress and wind speed at T-point
183         zcoef = 1. / ( zrhoa * zcdrag )
184!CDIR NOVERRCHK
185         DO jj = 2, jpjm1
186!CDIR NOVERRCHK
187            DO ji = fs_2, fs_jpim1   ! vect. opt.
188               ztx = utau(ji-1,jj  ) + utau(ji,jj) 
189               zty = vtau(ji  ,jj-1) + vtau(ji,jj) 
190               zmod = 0.5 * SQRT( ztx * ztx + zty * zty )
191               taum(ji,jj) = zmod
192               IF( ln_shelf_flx ) THEN
193                  ztx = sf(jp_utau)%fnow(ji-1,jj  ) + sf(jp_utau)%fnow(ji,jj)
194                  zty = sf(jp_vtau)%fnow(ji  ,jj-1) + sf(jp_vtau)%fnow(ji,jj)
195                  wndm(ji,jj) = 0.5 * SQRT( ztx * ztx + zty * zty )
196               ELSE
197               wndm(ji,jj) = SQRT( zmod * zcoef )
198               ENDIF
199            END DO
200         END DO
201         taum(:,:) = taum(:,:) * tmask(:,:,1) ; wndm(:,:) = wndm(:,:) * tmask(:,:,1)
202         CALL lbc_lnk( taum(:,:), 'T', 1. )   ;   CALL lbc_lnk( wndm(:,:), 'T', 1. )
203
204         IF( nitend-nit000 <= 100 .AND. lwp ) THEN                ! control print (if less than 100 time-step asked)
205            WRITE(numout,*) 
206            WRITE(numout,*) '        read daily momentum, heat and freshwater fluxes OK'
207            DO jf = 1, jpfld
208               IF( jf == jp_utau .OR. jf == jp_vtau )   zfact =     1.
209               IF( jf == jp_qtot .OR. jf == jp_qsr  )   zfact =     0.1
210               IF( jf == jp_emp                     )   zfact = 86400.
211               WRITE(numout,*) 
212               WRITE(numout,*) ' day: ', ndastp , TRIM(sf(jf)%clvar), ' * ', zfact
213               CALL prihre( sf(jf)%fnow, jpi, jpj, 1, jpi, 20, 1, jpj, 10, zfact, numout )
214            END DO
215            CALL FLUSH(numout)
216         ENDIF
217         !
218      ENDIF
219      !
220   END SUBROUTINE sbc_flx
221
222   !!======================================================================
223END MODULE sbcflx
Note: See TracBrowser for help on using the repository browser.