New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcmod.F90 in branches/UKMO/r6232_HZG_WAVE-coupling/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/UKMO/r6232_HZG_WAVE-coupling/NEMOGCM/NEMO/OPA_SRC/SBC/sbcmod.F90

Last change on this file was 9259, checked in by jcastill, 6 years ago

Changes to stop reading and using the pressure forcing file when coupling to the atmospheric mean sea level pressure

File size: 31.4 KB
Line 
1MODULE sbcmod
2   !!======================================================================
3   !!                       ***  MODULE  sbcmod  ***
4   !! Surface module :  provide to the ocean its surface boundary condition
5   !!======================================================================
6   !! History :  3.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.1  ! 2008-08  (S. Masson, A. Caubel, E. Maisonnave, G. Madec) coupled interface
8   !!            3.3  ! 2010-04  (M. Leclair, G. Madec)  Forcing averaged over 2 time steps
9   !!            3.3  ! 2010-10  (S. Masson)  add diurnal cycle
10   !!            3.3  ! 2010-09  (D. Storkey) add ice boundary conditions (BDY)
11   !!             -   ! 2010-11  (G. Madec) ice-ocean stress always computed at each ocean time-step
12   !!             -   ! 2010-10  (J. Chanut, C. Bricaud, G. Madec)  add the surface pressure forcing
13   !!            3.4  ! 2011-11  (C. Harris) CICE added as an option
14   !!            3.5  ! 2012-11  (A. Coward, G. Madec) Rethink of heat, mass and salt surface fluxes
15   !!            3.6  ! 2014-11  (P. Mathiot, C. Harris) add ice shelves melting                   
16   !!----------------------------------------------------------------------
17
18   !!----------------------------------------------------------------------
19   !!   sbc_init       : read namsbc namelist
20   !!   sbc            : surface ocean momentum, heat and freshwater boundary conditions
21   !!----------------------------------------------------------------------
22   USE oce              ! ocean dynamics and tracers
23   USE dom_oce          ! ocean space and time domain
24   USE phycst           ! physical constants
25   USE sbc_oce          ! Surface boundary condition: ocean fields
26   USE trc_oce          ! shared ocean-passive tracers variables
27   USE sbc_ice          ! Surface boundary condition: ice fields
28   USE sbcdcy           ! surface boundary condition: diurnal cycle
29   USE sbcssm           ! surface boundary condition: sea-surface mean variables
30   USE sbcapr           ! surface boundary condition: atmospheric pressure
31   USE sbcana           ! surface boundary condition: analytical formulation
32   USE sbcflx           ! surface boundary condition: flux formulation
33   USE sbcblk_clio      ! surface boundary condition: bulk formulation : CLIO
34   USE sbcblk_core      ! surface boundary condition: bulk formulation : CORE
35   USE sbcblk_mfs       ! surface boundary condition: bulk formulation : MFS
36   USE sbcice_if        ! surface boundary condition: ice-if sea-ice model
37   USE sbcice_lim       ! surface boundary condition: LIM 3.0 sea-ice model
38   USE sbcice_lim_2     ! surface boundary condition: LIM 2.0 sea-ice model
39   USE sbcice_cice      ! surface boundary condition: CICE    sea-ice model
40   USE sbccpl           ! surface boundary condition: coupled florulation
41   USE cpl_oasis3       ! OASIS routines for coupling
42   USE sbcssr           ! surface boundary condition: sea surface restoring
43   USE sbcrnf           ! surface boundary condition: runoffs
44   USE sbcisf           ! surface boundary condition: ice shelf
45   USE sbcfwb           ! surface boundary condition: freshwater budget
46   USE closea           ! closed sea
47   USE icbstp           ! Icebergs!
48
49   USE prtctl           ! Print control                    (prt_ctl routine)
50   USE iom              ! IOM library
51   USE in_out_manager   ! I/O manager
52   USE lib_mpp          ! MPP library
53   USE timing           ! Timing
54   USE sbcwave          ! Wave module
55   USE bdy_par          ! Require lk_bdy
56
57   IMPLICIT NONE
58   PRIVATE
59
60   PUBLIC   sbc        ! routine called by step.F90
61   PUBLIC   sbc_init   ! routine called by opa.F90
62   
63   INTEGER ::   nsbc   ! type of surface boundary condition (deduced from namsbc informations)
64     
65   !! * Substitutions
66#  include "domzgr_substitute.h90"
67   !!----------------------------------------------------------------------
68   !! NEMO/OPA 4.0 , NEMO-consortium (2011)
69   !! $Id$
70   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
71   !!----------------------------------------------------------------------
72CONTAINS
73
74   SUBROUTINE sbc_init
75      !!---------------------------------------------------------------------
76      !!                    ***  ROUTINE sbc_init ***
77      !!
78      !! ** Purpose :   Initialisation of the ocean surface boundary computation
79      !!
80      !! ** Method  :   Read the namsbc namelist and set derived parameters
81      !!                Call init routines for all other SBC modules that have one
82      !!
83      !! ** Action  : - read namsbc parameters
84      !!              - nsbc: type of sbc
85      !!----------------------------------------------------------------------
86      INTEGER ::   icpt   ! local integer
87      !!
88      NAMELIST/namsbc/ nn_fsbc   , ln_ana    , ln_flx, ln_blk_clio, ln_blk_core, ln_mixcpl,   &
89         &             ln_blk_mfs, ln_apr_dyn, nn_ice, nn_ice_embd, ln_dm2dc   , ln_rnf   ,   &
90         &             ln_ssr    , nn_isf    , nn_fwb, ln_wave    , nn_lsm     , nn_limflx,   &
91                       nn_components, ln_cpl , ln_wavcpl, nn_drag
92      INTEGER  ::   ios
93      INTEGER  ::   ierr, ierr0, ierr1, ierr2, ierr3, jpm
94      !!----------------------------------------------------------------------
95
96      IF(lwp) THEN
97         WRITE(numout,*)
98         WRITE(numout,*) 'sbc_init : surface boundary condition setting'
99         WRITE(numout,*) '~~~~~~~~ '
100      ENDIF
101
102      REWIND( numnam_ref )              ! Namelist namsbc in reference namelist : Surface boundary
103      READ  ( numnam_ref, namsbc, IOSTAT = ios, ERR = 901)
104901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc in reference namelist', lwp )
105
106      REWIND( numnam_cfg )              ! Namelist namsbc in configuration namelist : Parameters of the run
107      READ  ( numnam_cfg, namsbc, IOSTAT = ios, ERR = 902 )
108902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc in configuration namelist', lwp )
109      IF(lwm) WRITE ( numond, namsbc )
110
111      !                          ! overwrite namelist parameter using CPP key information
112      IF( Agrif_Root() ) THEN                ! AGRIF zoom
113        IF( lk_lim2 )   nn_ice      = 2
114        IF( lk_lim3 )   nn_ice      = 3
115        IF( lk_cice )   nn_ice      = 4
116      ENDIF
117      IF( cp_cfg == 'gyre' ) THEN            ! GYRE configuration
118          ln_ana      = .TRUE.   
119          nn_ice      =   0
120      ENDIF
121
122      IF(lwp) THEN               ! Control print
123         WRITE(numout,*) '        Namelist namsbc (partly overwritten with CPP key setting)'
124         WRITE(numout,*) '           frequency update of sbc (and ice)             nn_fsbc     = ', nn_fsbc
125         WRITE(numout,*) '           Type of sbc : '
126         WRITE(numout,*) '              analytical formulation                     ln_ana      = ', ln_ana
127         WRITE(numout,*) '              flux       formulation                     ln_flx      = ', ln_flx
128         WRITE(numout,*) '              CLIO bulk  formulation                     ln_blk_clio = ', ln_blk_clio
129         WRITE(numout,*) '              CORE bulk  formulation                     ln_blk_core = ', ln_blk_core
130         WRITE(numout,*) '              MFS  bulk  formulation                     ln_blk_mfs  = ', ln_blk_mfs
131         WRITE(numout,*) '              ocean-atmosphere coupled formulation       ln_cpl      = ', ln_cpl
132         WRITE(numout,*) '              forced-coupled atm mixed formulation       ln_mixcpl   = ', ln_mixcpl
133         WRITE(numout,*) '              forced-coupled wav mixed formulation       ln_wavcpl   = ', ln_wavcpl
134         WRITE(numout,*) '              wave physics                               ln_wave     = ', ln_wave 
135         WRITE(numout,*) '              OASIS coupling (with atm or sas)           lk_oasis    = ', lk_oasis
136         WRITE(numout,*) '              components of your executable              nn_components = ', nn_components
137         WRITE(numout,*) '              Multicategory heat flux formulation (LIM3) nn_limflx   = ', nn_limflx
138         WRITE(numout,*) '              momentum formulation                       nn_drag     = ', nn_drag
139         WRITE(numout,*) '           Misc. options of sbc : '
140         WRITE(numout,*) '              Patm gradient added in ocean & ice Eqs.    ln_apr_dyn  = ', ln_apr_dyn
141         WRITE(numout,*) '              ice management in the sbc (=0/1/2/3)       nn_ice      = ', nn_ice 
142         WRITE(numout,*) '              ice-ocean embedded/levitating (=0/1/2)     nn_ice_embd = ', nn_ice_embd
143         WRITE(numout,*) '              daily mean to diurnal cycle qsr            ln_dm2dc    = ', ln_dm2dc 
144         WRITE(numout,*) '              runoff / runoff mouths                     ln_rnf      = ', ln_rnf
145         WRITE(numout,*) '              iceshelf formulation                       nn_isf      = ', nn_isf
146         WRITE(numout,*) '              Sea Surface Restoring on SST and/or SSS    ln_ssr      = ', ln_ssr
147         WRITE(numout,*) '              FreshWater Budget control  (=0/1/2)        nn_fwb      = ', nn_fwb
148         WRITE(numout,*) '              closed sea (=0/1) (set in namdom)          nn_closea   = ', nn_closea
149         WRITE(numout,*) '              n. of iterations if land-sea-mask applied  nn_lsm      = ', nn_lsm
150      ENDIF
151
152      ! LIM3 Multi-category heat flux formulation
153      SELECT CASE ( nn_limflx)
154      CASE ( -1 )
155         IF(lwp) WRITE(numout,*) '              Use of per-category fluxes (nn_limflx = -1) '
156      CASE ( 0  )
157         IF(lwp) WRITE(numout,*) '              Average per-category fluxes (nn_limflx = 0) ' 
158      CASE ( 1  )
159         IF(lwp) WRITE(numout,*) '              Average then redistribute per-category fluxes (nn_limflx = 1) '
160      CASE ( 2  )
161         IF(lwp) WRITE(numout,*) '              Redistribute a single flux over categories (nn_limflx = 2) '
162      END SELECT
163      !
164      IF ( nn_components /= jp_iam_nemo .AND. .NOT. lk_oasis )   &
165         &      CALL ctl_stop( 'STOP', 'sbc_init : OPA-SAS coupled via OASIS, but key_oasis3 disabled' )
166      IF ( nn_components == jp_iam_opa .AND. ln_cpl )   &
167         &      CALL ctl_stop( 'STOP', 'sbc_init : OPA-SAS coupled via OASIS, but ln_cpl = T in OPA' )
168      IF ( nn_components == jp_iam_opa .AND. ( ln_mixcpl .OR. ln_wavcpl) )   &
169         &      CALL ctl_stop( 'STOP', 'sbc_init : OPA-SAS coupled via OASIS, but ln_mixcpl or ln_wavcpl = T in OPA' )
170      IF ( ln_cpl .AND. .NOT. lk_oasis )    &
171         &      CALL ctl_stop( 'STOP', 'sbc_init : OASIS-coupled atmosphere model, but key_oasis3 disabled' )
172      IF( ( ln_mixcpl .OR. ln_wavcpl ) .AND. .NOT. lk_oasis )    &
173         &      CALL ctl_stop( 'the forced-coupled mixed mode (ln_mixcpl or ln_wavcpl) requires the cpp key key_oasis3' )
174      IF( ( ln_mixcpl .OR. ln_wavcpl ) .AND. .NOT. ln_cpl )    &
175         &      CALL ctl_stop( 'the forced-coupled mixed mode (ln_mixcpl or ln_wavcpl) requires ln_cpl = T' )
176      IF( ( ln_mixcpl .OR. ln_wavcpl ) .AND. nn_components /= jp_iam_nemo )    &
177         &      CALL ctl_stop( 'the forced-coupled mixed mode (ln_mixcpl or ln_wavcpl) is not yet working with sas-opa coupling via oasis' )
178
179      !                              ! allocate sbc arrays
180      IF( sbc_oce_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_oce arrays' )
181
182      !                          ! Checks:
183      IF( nn_isf .EQ. 0 ) THEN                      ! variable initialisation if no ice shelf
184         IF( sbc_isf_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_isf arrays' )
185         fwfisf  (:,:)   = 0.0_wp ; fwfisf_b  (:,:)   = 0.0_wp
186         risf_tsc(:,:,:) = 0.0_wp ; risf_tsc_b(:,:,:) = 0.0_wp
187         rdivisf       = 0.0_wp
188      END IF
189      IF( nn_ice == 0 .AND. nn_components /= jp_iam_opa )   fr_i(:,:) = 0.e0 ! no ice in the domain, ice fraction is always zero
190
191      sfx(:,:) = 0.0_wp                            ! the salt flux due to freezing/melting will be computed (i.e. will be non-zero)
192                                                   ! only if sea-ice is present
193 
194      fmmflx(:,:) = 0.0_wp                        ! freezing-melting array initialisation
195     
196      taum(:,:) = 0.0_wp                           ! Initialise taum for use in gls in case of reduced restart
197
198      !                                            ! restartability   
199      IF( ( nn_ice == 2 .OR. nn_ice ==3 ) .AND. .NOT.( ln_blk_clio .OR. ln_blk_core .OR. ln_cpl ) )   &
200         &   CALL ctl_stop( 'LIM sea-ice model requires a bulk formulation or coupled configuration' )
201      IF( nn_ice == 4 .AND. .NOT.( ln_blk_core .OR. ln_cpl ) )   &
202         &   CALL ctl_stop( 'CICE sea-ice model requires ln_blk_core or ln_cpl' )
203      IF( nn_ice == 4 .AND. lk_agrif )   &
204         &   CALL ctl_stop( 'CICE sea-ice model not currently available with AGRIF' )
205      IF( ( nn_ice == 3 .OR. nn_ice == 4 ) .AND. nn_ice_embd == 0 )   &
206         &   CALL ctl_stop( 'LIM3 and CICE sea-ice models require nn_ice_embd = 1 or 2' )
207      IF( ( nn_ice /= 3 ) .AND. ( nn_limflx >= 0 ) )   &
208         &   WRITE(numout,*) 'The nn_limflx>=0 option has no effect if sea ice model is not LIM3'
209      IF( ( nn_ice == 3 ) .AND. ( ln_cpl ) .AND. ( ( nn_limflx == -1 ) .OR. ( nn_limflx == 1 ) ) )   &
210         &   CALL ctl_stop( 'The chosen nn_limflx for LIM3 in coupled mode must be 0 or 2' )
211      IF( ( nn_ice == 3 ) .AND. ( .NOT. ln_cpl ) .AND. ( nn_limflx == 2 ) )   &
212         &   CALL ctl_stop( 'The chosen nn_limflx for LIM3 in forced mode cannot be 2' )
213
214      IF( ln_dm2dc )   nday_qsr = -1   ! initialisation flag
215
216      IF( ln_dm2dc .AND. .NOT.( ln_flx .OR. ln_blk_core ) .AND. nn_components /= jp_iam_opa )   &
217         &   CALL ctl_stop( 'diurnal cycle into qsr field from daily values requires a flux or core-bulk formulation' )
218      !                          ! Choice of the Surface Boudary Condition (set nsbc)
219      ll_purecpl = ln_cpl .AND. .NOT. ln_mixcpl .AND. .NOT. ln_wavcpl
220      !
221      icpt = 0
222      IF( ln_ana          ) THEN   ;   nsbc = jp_ana     ; icpt = icpt + 1   ;   ENDIF       ! analytical           formulation
223      IF( ln_flx          ) THEN   ;   nsbc = jp_flx     ; icpt = icpt + 1   ;   ENDIF       ! flux                 formulation
224      IF( ln_blk_clio     ) THEN   ;   nsbc = jp_clio    ; icpt = icpt + 1   ;   ENDIF       ! CLIO bulk            formulation
225      IF( ln_blk_core     ) THEN   ;   nsbc = jp_core    ; icpt = icpt + 1   ;   ENDIF       ! CORE bulk            formulation
226      IF( ln_blk_mfs      ) THEN   ;   nsbc = jp_mfs     ; icpt = icpt + 1   ;   ENDIF       ! MFS  bulk            formulation
227      IF( ll_purecpl      ) THEN   ;   nsbc = jp_purecpl ; icpt = icpt + 1   ;   ENDIF       ! Pure Coupled         formulation
228      IF( cp_cfg == 'gyre') THEN   ;   nsbc = jp_gyre                        ;   ENDIF       ! GYRE analytical      formulation
229      IF( nn_components == jp_iam_opa )   &
230         &                  THEN   ;   nsbc = jp_none    ; icpt = icpt + 1   ;   ENDIF       ! opa coupling via SAS module
231      IF( lk_esopa        )            nsbc = jp_esopa                                       ! esopa test, ALL formulations
232      !
233      IF( icpt /= 1 .AND. .NOT.lk_esopa ) THEN
234         WRITE(numout,*)
235         WRITE(numout,*) '           E R R O R in setting the sbc, one and only one namelist/CPP key option '
236         WRITE(numout,*) '                     must be choosen. You choose ', icpt, ' option(s)'
237         WRITE(numout,*) '                     We stop'
238         nstop = nstop + 1
239      ENDIF
240      IF(lwp) THEN
241         WRITE(numout,*)
242         IF( nsbc == jp_esopa   )   WRITE(numout,*) '              ESOPA test All surface boundary conditions'
243         IF( nsbc == jp_gyre    )   WRITE(numout,*) '              GYRE analytical formulation'
244         IF( nsbc == jp_ana     )   WRITE(numout,*) '              analytical formulation'
245         IF( nsbc == jp_flx     )   WRITE(numout,*) '              flux formulation'
246         IF( nsbc == jp_clio    )   WRITE(numout,*) '              CLIO bulk formulation'
247         IF( nsbc == jp_core    )   WRITE(numout,*) '              CORE bulk formulation'
248         IF( nsbc == jp_purecpl )   WRITE(numout,*) '              pure coupled formulation'
249         IF( nsbc == jp_mfs     )   WRITE(numout,*) '              MFS Bulk formulation'
250         IF( nsbc == jp_none    )   WRITE(numout,*) '              OPA coupled to SAS via oasis'
251         IF( ln_mixcpl          )   WRITE(numout,*) '              + forced-coupled mixed atm formulation'
252         IF( ln_wavcpl          )   WRITE(numout,*) '              + forced-coupled mixed wav formulation'
253         IF( nn_components/= jp_iam_nemo )  &
254            &                       WRITE(numout,*) '              + OASIS coupled SAS'
255      ENDIF
256      !
257      IF( lk_oasis )   CALL sbc_cpl_init (nn_ice)   ! OASIS initialisation. must be done before: (1) first time step
258      !                                                     !                                            (2) the use of nn_fsbc
259
260!     nn_fsbc initialization if OPA-SAS coupling via OASIS
261!     sas model time step has to be declared in OASIS (mandatory) -> nn_fsbc has to be modified accordingly
262      IF ( nn_components /= jp_iam_nemo ) THEN
263
264         IF ( nn_components == jp_iam_opa ) nn_fsbc = cpl_freq('O_SFLX') / NINT(rdt)
265         IF ( nn_components == jp_iam_sas ) nn_fsbc = cpl_freq('I_SFLX') / NINT(rdt)
266         !
267         IF(lwp)THEN
268            WRITE(numout,*)
269            WRITE(numout,*)"   OPA-SAS coupled via OASIS : nn_fsbc re-defined from OASIS namcouple ", nn_fsbc
270            WRITE(numout,*)
271         ENDIF
272      ENDIF
273
274      IF( MOD( nitend - nit000 + 1, nn_fsbc) /= 0 .OR.   &
275          MOD( nstock             , nn_fsbc) /= 0 ) THEN
276         WRITE(ctmp1,*) 'experiment length (', nitend - nit000 + 1, ') or nstock (', nstock,   &
277            &           ' is NOT a multiple of nn_fsbc (', nn_fsbc, ')'
278         CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' )
279      ENDIF
280      !
281      IF( MOD( rday, REAL(nn_fsbc, wp) * rdt ) /= 0 )   &
282         &  CALL ctl_warn( 'nn_fsbc is NOT a multiple of the number of time steps in a day' )
283      !
284      IF( ln_dm2dc .AND. ( ( NINT(rday) / ( nn_fsbc * NINT(rdt) ) )  < 8 ) )   &
285         &   CALL ctl_warn( 'diurnal cycle for qsr: the sampling of the diurnal cycle is too small...' )
286
287                               CALL sbc_ssm_init               ! Sea-surface mean fields initialisation
288      !
289      IF( ln_ssr           )   CALL sbc_ssr_init               ! Sea-Surface Restoring initialisation
290      !
291                               CALL sbc_rnf_init               ! Runof initialisation
292      !
293      IF( nn_ice == 3      )   CALL sbc_lim_init               ! LIM3 initialisation
294
295      IF( nn_ice == 4      )   CALL cice_sbc_init( nsbc )      ! CICE initialisation
296      !
297      IF( ln_wave          )   CALL sbc_wave_init              ! surface wave initialisation
298      !
299     
300   END SUBROUTINE sbc_init
301
302
303   SUBROUTINE sbc( kt )
304      !!---------------------------------------------------------------------
305      !!                    ***  ROUTINE sbc  ***
306      !!             
307      !! ** Purpose :   provide at each time-step the ocean surface boundary
308      !!                condition (momentum, heat and freshwater fluxes)
309      !!
310      !! ** Method  :   blah blah  to be written ?????????
311      !!                CAUTION : never mask the surface stress field (tke sbc)
312      !!
313      !! ** Action  : - set the ocean surface boundary condition at before and now
314      !!                time step, i.e. 
315      !!                utau_b, vtau_b, qns_b, qsr_b, emp_n, sfx_b, qrp_b, erp_b
316      !!                utau  , vtau  , qns  , qsr  , emp  , sfx  , qrp  , erp
317      !!              - updte the ice fraction : fr_i
318      !!----------------------------------------------------------------------
319      USE bdydta, ONLY: bdy_dta 
320      !
321      INTEGER, INTENT(in) ::   kt       ! ocean time step
322      !!---------------------------------------------------------------------
323      !
324      IF( nn_timing == 1 )  CALL timing_start('sbc')
325      !
326      !                                            ! ---------------------------------------- !
327      IF( kt /= nit000 ) THEN                      !          Swap of forcing fields          !
328         !                                         ! ---------------------------------------- !
329         utau_b(:,:) = utau(:,:)                         ! Swap the ocean forcing fields
330         vtau_b(:,:) = vtau(:,:)                         ! (except at nit000 where before fields
331         qns_b (:,:) = qns (:,:)                         !  are set at the end of the routine)
332         ! The 3D heat content due to qsr forcing is treated in traqsr
333         ! qsr_b (:,:) = qsr (:,:)
334         emp_b(:,:) = emp(:,:)
335         sfx_b(:,:) = sfx(:,:)
336      ENDIF
337      !                                            ! ---------------------------------------- !
338      !                                            !        forcing field computation         !
339      !                                            ! ---------------------------------------- !
340      !
341
342      IF( ln_apr_dyn ) CALL sbc_apr( kt )                ! atmospheric pressure provided at kt+0.5*nn_fsbc
343                                                         ! (caution called before sbc_ssm)
344      !
345      IF( nn_components /= jp_iam_sas )   CALL sbc_ssm( kt )   ! ocean sea surface variables (sst_m, sss_m, ssu_m, ssv_m)
346      !                                                        ! averaged over nf_sbc time-step
347
348      IF (ln_wave) CALL sbc_wave( kt )
349                                                   !==  sbc formulation  ==!
350                                                           
351      SELECT CASE( nsbc )                                ! Compute ocean surface boundary condition
352      !                                                  ! (i.e. utau,vtau, qns, qsr, emp, sfx)
353      CASE( jp_gyre  )   ;   CALL sbc_gyre    ( kt )                    ! analytical formulation : GYRE configuration
354      CASE( jp_ana   )   ;   CALL sbc_ana     ( kt )                    ! analytical formulation : uniform sbc
355      CASE( jp_flx   )   ;   CALL sbc_flx     ( kt )                    ! flux formulation
356      CASE( jp_clio  )   ;   CALL sbc_blk_clio( kt )                    ! bulk formulation : CLIO for the ocean
357      CASE( jp_core  )   
358         IF( nn_components == jp_iam_sas ) &
359            &                CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice )   ! OPA-SAS coupling: SAS receiving fields from OPA
360                             CALL sbc_blk_core( kt )                    ! bulk formulation : CORE for the ocean
361                                                                        ! from oce: sea surface variables (sst_m, sss_m,  ssu_m,  ssv_m)
362      CASE( jp_purecpl )  ;  CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice )   ! pure coupled formulation
363                                                                        !
364      CASE( jp_mfs   )   ;   CALL sbc_blk_mfs ( kt )                    ! bulk formulation : MFS for the ocean
365      CASE( jp_none  ) 
366         IF( nn_components == jp_iam_opa ) &
367                             CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice )   ! OPA-SAS coupling: OPA receiving fields from SAS
368      CASE( jp_esopa )                               
369                             CALL sbc_ana     ( kt )                    ! ESOPA, test ALL the formulations
370                             CALL sbc_gyre    ( kt )                    !
371                             CALL sbc_flx     ( kt )                    !
372                             CALL sbc_blk_clio( kt )                    !
373                             CALL sbc_blk_core( kt )                    !
374                             CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice )   !
375      END SELECT
376
377      IF( ln_mixcpl .OR. ln_wavcpl )  CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice )   ! forced-coupled mixed formulation after forcing
378
379      IF( ln_wave .AND. (ln_tauoc .OR. ln_tauw) ) CALL sbc_stress( )    ! Wave stress update
380      IF( lk_bdy )           CALL bdy_dta ( kt, time_offset=+1 )        ! update dynamic & tracer data at open boundaries
381                                                                        ! (caution called after sbc_ssm[_cpl] and before ice)
382
383      !                                            !==  Misc. Options  ==!
384     
385      SELECT CASE( nn_ice )                                       ! Update heat and freshwater fluxes over sea-ice areas
386      CASE(  1 )   ;         CALL sbc_ice_if   ( kt )                ! Ice-cover climatology ("Ice-if" model)
387      CASE(  2 )   ;         CALL sbc_ice_lim_2( kt, nsbc )          ! LIM-2 ice model
388      CASE(  3 )   ;         CALL sbc_ice_lim  ( kt, nsbc )          ! LIM-3 ice model
389      CASE(  4 )   ;         CALL sbc_ice_cice ( kt, nsbc )          ! CICE ice model
390      END SELECT                                             
391
392      IF( ln_icebergs    )   CALL icb_stp( kt )                   ! compute icebergs
393
394      IF( nn_isf   /= 0  )   CALL sbc_isf( kt )                    ! compute iceshelves
395
396      IF( ln_rnf         )   CALL sbc_rnf( kt )                   ! add runoffs to fresh water fluxes
397 
398      IF( ln_ssr         )   CALL sbc_ssr( kt )                   ! add SST/SSS damping term
399
400      IF( nn_fwb    /= 0 )   CALL sbc_fwb( kt, nn_fwb, nn_fsbc )  ! control the freshwater budget
401
402      IF( nn_closea == 1 )   CALL sbc_clo( kt )                   ! treatment of closed sea in the model domain
403      !                                                           ! (update freshwater fluxes)
404!RBbug do not understand why see ticket 667
405!clem: it looks like it is necessary for the north fold (in certain circumstances). Don't know why.
406      CALL lbc_lnk( emp, 'T', 1. )
407      !
408      IF( kt == nit000 ) THEN                          !   set the forcing field at nit000 - 1    !
409         !                                             ! ---------------------------------------- !
410         IF( ln_rstart .AND.    &                               !* Restart: read in restart file
411            & iom_varid( numror, 'utau_b', ldstop = .FALSE. ) > 0 ) THEN
412            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields red in the restart file'
413            CALL iom_get( numror, jpdom_autoglo, 'utau_b', utau_b )   ! before i-stress  (U-point)
414            CALL iom_get( numror, jpdom_autoglo, 'vtau_b', vtau_b )   ! before j-stress  (V-point)
415            CALL iom_get( numror, jpdom_autoglo, 'qns_b' , qns_b  )   ! before non solar heat flux (T-point)
416            ! The 3D heat content due to qsr forcing is treated in traqsr
417            ! CALL iom_get( numror, jpdom_autoglo, 'qsr_b' , qsr_b  ) ! before     solar heat flux (T-point)
418            CALL iom_get( numror, jpdom_autoglo, 'emp_b', emp_b  )    ! before     freshwater flux (T-point)
419            ! To ensure restart capability with 3.3x/3.4 restart files    !! to be removed in v3.6
420            IF( iom_varid( numror, 'sfx_b', ldstop = .FALSE. ) > 0 ) THEN
421               CALL iom_get( numror, jpdom_autoglo, 'sfx_b', sfx_b )  ! before salt flux (T-point)
422            ELSE
423               sfx_b (:,:) = sfx(:,:)
424            ENDIF
425         ELSE                                                   !* no restart: set from nit000 values
426            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields set to nit000'
427            utau_b(:,:) = utau(:,:) 
428            vtau_b(:,:) = vtau(:,:)
429            qns_b (:,:) = qns (:,:)
430            emp_b (:,:) = emp(:,:)
431            sfx_b (:,:) = sfx(:,:)
432         ENDIF
433      ENDIF
434      !                                                ! ---------------------------------------- !
435      IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
436         !                                             ! ---------------------------------------- !
437         IF(lwp) WRITE(numout,*)
438         IF(lwp) WRITE(numout,*) 'sbc : ocean surface forcing fields written in ocean restart file ',   &
439            &                    'at it= ', kt,' date= ', ndastp
440         IF(lwp) WRITE(numout,*) '~~~~'
441         CALL iom_rstput( kt, nitrst, numrow, 'utau_b' , utau )
442         CALL iom_rstput( kt, nitrst, numrow, 'vtau_b' , vtau )
443         CALL iom_rstput( kt, nitrst, numrow, 'qns_b'  , qns  )
444         ! The 3D heat content due to qsr forcing is treated in traqsr
445         ! CALL iom_rstput( kt, nitrst, numrow, 'qsr_b'  , qsr  )
446         CALL iom_rstput( kt, nitrst, numrow, 'emp_b'  , emp  )
447         CALL iom_rstput( kt, nitrst, numrow, 'sfx_b'  , sfx  )
448      ENDIF
449
450      !                                                ! ---------------------------------------- !
451      !                                                !        Outputs and control print         !
452      !                                                ! ---------------------------------------- !
453      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
454         CALL iom_put( "empmr" , emp  - rnf )                   ! upward water flux
455         CALL iom_put( "saltflx", sfx  )                        ! downward salt flux 
456                                                                ! (includes virtual salt flux beneath ice
457                                                                ! in linear free surface case)
458         CALL iom_put( "fmmflx", fmmflx  )                      ! Freezing-melting water flux
459         CALL iom_put( "qt"    , qns  + qsr )                   ! total heat flux
460         CALL iom_put( "qns"   , qns        )                   ! solar heat flux
461         CALL iom_put( "qsr"   ,       qsr  )                   ! solar heat flux
462         IF( nn_ice > 0 .OR. nn_components == jp_iam_opa )   CALL iom_put( "ice_cover", fr_i )   ! ice fraction
463         CALL iom_put( "taum"  , taum       )                   ! wind stress module
464         CALL iom_put( "wspd"  , wndm       )                   ! wind speed  module over free ocean or leads in presence of sea-ice
465      ENDIF
466      !
467      CALL iom_put( "utau", utau )   ! i-wind stress   (stress can be updated at
468      CALL iom_put( "vtau", vtau )   ! j-wind stress    each time step in sea-ice)
469      !
470      IF(ln_ctl) THEN         ! print mean trends (used for debugging)
471         CALL prt_ctl(tab2d_1=fr_i              , clinfo1=' fr_i     - : ', mask1=tmask, ovlap=1 )
472         CALL prt_ctl(tab2d_1=(emp-rnf + fwfisf), clinfo1=' emp-rnf  - : ', mask1=tmask, ovlap=1 )
473         CALL prt_ctl(tab2d_1=(sfx-rnf + fwfisf), clinfo1=' sfx-rnf  - : ', mask1=tmask, ovlap=1 )
474         CALL prt_ctl(tab2d_1=qns              , clinfo1=' qns      - : ', mask1=tmask, ovlap=1 )
475         CALL prt_ctl(tab2d_1=qsr              , clinfo1=' qsr      - : ', mask1=tmask, ovlap=1 )
476         CALL prt_ctl(tab3d_1=tmask            , clinfo1=' tmask    - : ', mask1=tmask, ovlap=1, kdim=jpk )
477         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_tem), clinfo1=' sst      - : ', mask1=tmask, ovlap=1, kdim=1   )
478         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_sal), clinfo1=' sss      - : ', mask1=tmask, ovlap=1, kdim=1   )
479         CALL prt_ctl(tab2d_1=utau             , clinfo1=' utau     - : ', mask1=umask,                      &
480            &         tab2d_2=vtau             , clinfo2=' vtau     - : ', mask2=vmask, ovlap=1 )
481      ENDIF
482
483      IF( kt == nitend )   CALL sbc_final         ! Close down surface module if necessary
484      !
485      IF( nn_timing == 1 )  CALL timing_stop('sbc')
486      !
487   END SUBROUTINE sbc
488
489
490   SUBROUTINE sbc_final
491      !!---------------------------------------------------------------------
492      !!                    ***  ROUTINE sbc_final  ***
493      !!
494      !! ** Purpose :   Finalize CICE (if used)
495      !!---------------------------------------------------------------------
496      !
497      IF( nn_ice == 4 )   CALL cice_sbc_final
498      !
499   END SUBROUTINE sbc_final
500
501   !!======================================================================
502END MODULE sbcmod
Note: See TracBrowser for help on using the repository browser.