New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcwave.F90 in branches/UKMO/r6232_HZG_WAVE-coupling/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/UKMO/r6232_HZG_WAVE-coupling/NEMOGCM/NEMO/OPA_SRC/SBC/sbcwave.F90 @ 7809

Last change on this file since 7809 was 7809, checked in by jcastill, 7 years ago

First implementation of the HZG wave focing/coupling branch - only ln_phioc and ln_tauoc in place. This is crashing amm7 runs with Baltic boundary conditions, but not without them.
File size: 19.4 KB
Line 
1MODULE sbcwave
2   !!======================================================================
3   !!                       ***  MODULE  sbcwave  ***
4   !! Wave module
5   !!======================================================================
6   !! History :  3.3  !   2011-09  (Adani M)  Original code: Drag Coefficient
7   !!         :  3.4  !   2012-10  (Adani M)                 Stokes Drift
8   !!            3.6  !   2014-09  (Clementi E, Oddo P)New Stokes Drift Computation
9   !!             -   !   2016-12  (G. Madec, E. Clementi) update Stoke drift computation
10   !!                                                     + add sbc_wave_ini routine
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   sbc_stokes    : calculate 3D Stokes-drift velocities
15   !!   sbc_wave      : wave data from wave model in netcdf files
16   !!   sbc_wave_init : initialisation fo surface waves
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean variables
19   USE sbc_oce        ! Surface boundary condition: ocean fields
20   USE zdf_oce,  ONLY : ln_zdfqiao
21   USE bdy_oce        ! open boundary condition variables
22   USE domvvl         ! domain: variable volume layers
23   !
24   USE iom            ! I/O manager library
25   USE in_out_manager ! I/O manager
26   USE lib_mpp        ! distribued memory computing library
27   USE fldread        ! read input fields
28   USE wrk_nemo       !
29   USE phycst         ! physical constants
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   sbc_stokes      ! routine called in sbccpl
35   PUBLIC   sbc_wave        ! routine called in sbcmod
36   PUBLIC   sbc_wave_init   ! routine called in sbcmod
37   
38   ! Variables checking if the wave parameters are coupled (if not, they are read from file)
39   LOGICAL, PUBLIC ::   cpl_hsig   = .FALSE.
40   LOGICAL, PUBLIC ::   cpl_phioc  = .FALSE.
41   LOGICAL, PUBLIC ::   cpl_sdrftx = .FALSE.
42   LOGICAL, PUBLIC ::   cpl_sdrfty = .FALSE.
43   LOGICAL, PUBLIC ::   cpl_wper   = .FALSE.
44   LOGICAL, PUBLIC ::   cpl_wnum   = .FALSE.
45   LOGICAL, PUBLIC ::   cpl_tauoc  = .FALSE.
46   LOGICAL, PUBLIC ::   cpl_wdrag  = .FALSE.
47
48   INTEGER ::   jpfld    ! number of files to read for stokes drift
49   INTEGER ::   jp_usd   ! index of stokes drift  (i-component) (m/s)    at T-point
50   INTEGER ::   jp_vsd   ! index of stokes drift  (j-component) (m/s)    at T-point
51   INTEGER ::   jp_hsw   ! index of significant wave hight      (m)      at T-point
52   INTEGER ::   jp_wmp   ! index of mean wave period            (s)      at T-point
53
54   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::  sf_cd    ! structure of input fields (file informations, fields read) Drag Coefficient
55   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::  sf_sd    ! structure of input fields (file informations, fields read) Stokes Drift
56   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::  sf_wn    ! structure of input fields (file informations, fields read) wave number for Qiao
57   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::  sf_tauoc ! structure of input fields (file informations, fields read) normalized wave stress into the ocean
58   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::  sf_phioc ! structure of input fields (file informations, fields read) wave to ocean energy
59   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   cdn_wave            !:
60   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   hsw, wmp, wnum      !:
61   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   rn_crban            !: Craig and Banner constant for surface breaking waves mixing
62   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   tauoc_wave          !:
63   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   tsd2d               !:
64   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   div_sd              !: barotropic stokes drift divergence
65   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   ut0sd, vt0sd        !: surface Stokes drift velocities at t-point
66   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:,:) ::   usd  , vsd  , wsd   !: Stokes drift velocities at u-, v- & w-points, resp.
67
68#  include "vectopt_loop_substitute.h90"
69   !!----------------------------------------------------------------------
70   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
71   !! $Id$
72   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
73   !!----------------------------------------------------------------------
74CONTAINS
75
76   SUBROUTINE sbc_stokes( )
77      !!---------------------------------------------------------------------
78      !!                     ***  ROUTINE sbc_stokes  ***
79      !!
80      !! ** Purpose :   compute the 3d Stokes Drift according to Breivik et al.,
81      !!                2014 (DOI: 10.1175/JPO-D-14-0020.1)
82      !!
83      !! ** Method  : - Calculate Stokes transport speed
84      !!              - Calculate horizontal divergence
85      !!              - Integrate the horizontal divergenze from the bottom
86      !! ** action 
87      !!---------------------------------------------------------------------
88      INTEGER  ::   jj, ji, jk   ! dummy loop argument
89      INTEGER  ::   ik           ! local integer
90      REAL(wp) ::  ztransp, zfac, ztemp
91      REAL(wp) ::  zdep_u, zdep_v, zkh_u, zkh_v, zda_u, zda_v
92      REAL(wp), DIMENSION(:,:)  , POINTER ::   zk_t, zk_u, zk_v, zu0_sd, zv0_sd   ! 2D workspace
93      REAL(wp), DIMENSION(:,:,:), POINTER ::   ze3divh                            ! 3D workspace
94
95      !!---------------------------------------------------------------------
96      !
97
98      CALL wrk_alloc( jpi,jpj,jpk,   ze3divh )
99      CALL wrk_alloc( jpi,jpj,       zk_t, zk_u, zk_v, zu0_sd, zv0_sd ) 
100      !
101      zfac = 2.0_wp * rpi / 16.0_wp
102      DO jj = 1, jpj               ! exp. wave number at t-point    (Eq. (19) in Breivick et al. (2014) )
103         DO ji = 1, jpi
104            ! Stokes drift velocity estimated from Hs and Tmean
105            ztransp = zfac * hsw(ji,jj)*hsw(ji,jj) / MAX( wmp(ji,jj), 0.0000001_wp )
106            ! Stokes surface speed
107            tsd2d(ji,jj) = SQRT( ut0sd(ji,jj)*ut0sd(ji,jj) + vt0sd(ji,jj)*vt0sd(ji,jj))
108            ! Wavenumber scale
109            zk_t(ji,jj) = ABS( tsd2d(ji,jj) ) / MAX( ABS( 5.97_wp*ztransp ), 0.0000001_wp )
110         END DO
111      END DO
112      DO jj = 1, jpjm1              ! exp. wave number & Stokes drift velocity at u- & v-points
113         DO ji = 1, jpim1
114            zk_u(ji,jj) = 0.5_wp * ( zk_t(ji,jj) + zk_t(ji+1,jj) )
115            zk_v(ji,jj) = 0.5_wp * ( zk_t(ji,jj) + zk_t(ji,jj+1) )
116            !
117            zu0_sd(ji,jj) = 0.5_wp * ( ut0sd(ji,jj) + ut0sd(ji+1,jj) )
118            zv0_sd(ji,jj) = 0.5_wp * ( vt0sd(ji,jj) + vt0sd(ji,jj+1) )
119         END DO
120      END DO
121      !
122      !                       !==  horizontal Stokes Drift 3D velocity  ==!
123      DO jk = 1, jpkm1
124         DO jj = 2, jpjm1
125            DO ji = 2, jpim1
126               zdep_u = 0.5_wp * ( gdept_n(ji,jj,jk) + gdept_n(ji+1,jj,jk) )
127               zdep_v = 0.5_wp * ( gdept_n(ji,jj,jk) + gdept_n(ji,jj+1,jk) )
128               !                         
129               zkh_u = zk_u(ji,jj) * zdep_u     ! k * depth
130               zkh_v = zk_v(ji,jj) * zdep_v
131               !                                ! Depth attenuation
132               zda_u = EXP( -2.0_wp*zkh_u ) / ( 1.0_wp + 8.0_wp*zkh_u )
133               zda_v = EXP( -2.0_wp*zkh_v ) / ( 1.0_wp + 8.0_wp*zkh_v )
134               !
135               usd(ji,jj,jk) = zda_u * zk_u(ji,jj) * umask(ji,jj,jk)
136               vsd(ji,jj,jk) = zda_v * zk_v(ji,jj) * vmask(ji,jj,jk)
137            END DO
138         END DO
139      END DO
140      CALL lbc_lnk( usd(:,:,:), 'U', vsd(:,:,:), 'V', -1. )
141      !
142      !                       !==  vertical Stokes Drift 3D velocity  ==!
143      !
144      DO jk = 1, jpkm1               ! Horizontal e3*divergence
145         DO jj = 2, jpj
146            DO ji = fs_2, jpi
147               ze3divh(ji,jj,jk) = (  e2u(ji  ,jj) * e3u_n(ji  ,jj,jk) * usd(ji,  jj,jk)    &
148                  &                 - e2u(ji-1,jj) * e3u_n(ji-1,jj,jk) * usd(ji-1,jj,jk)    &
149                  &                 + e1v(ji,jj  ) * e3v_n(ji,jj  ,jk) * vsd(ji,jj  ,jk)    &
150                  &                 - e1v(ji,jj-1) * e3v_n(ji,jj-1,jk) * vsd(ji,jj-1,jk)  ) * r1_e12t(ji,jj)
151            END DO
152         END DO
153      END DO
154      !
155      IF( .NOT. AGRIF_Root() ) THEN
156         IF( nbondi ==  1 .OR. nbondi == 2 )   ze3divh(nlci-1,   :  ,:) = 0._wp      ! east
157         IF( nbondi == -1 .OR. nbondi == 2 )   ze3divh(  2   ,   :  ,:) = 0._wp      ! west
158         IF( nbondj ==  1 .OR. nbondj == 2 )   ze3divh(  :   ,nlcj-1,:) = 0._wp      ! north
159         IF( nbondj == -1 .OR. nbondj == 2 )   ze3divh(  :   ,  2   ,:) = 0._wp      ! south
160      ENDIF
161      !
162      CALL lbc_lnk( ze3divh, 'T', 1. )
163      !
164      IF( .NOT. lk_vvl ) THEN   ;   ik = 1   ! none zero velocity through the sea surface
165      ELSE                      ;   ik = 2   ! w=0 at the surface (set one for all in sbc_wave_init)
166      ENDIF
167      DO jk = jpkm1, ik, -1          ! integrate from the bottom the hor. divergence (NB: at k=jpk w is always zero)
168         wsd(:,:,jk) = wsd(:,:,jk+1) - ze3divh(:,:,jk)
169      END DO
170#if defined key_bdy
171      IF( lk_bdy ) THEN
172         DO jk = 1, jpkm1
173            wsd(:,:,jk) = wsd(:,:,jk) * bdytmask(:,:)
174         END DO
175      ENDIF
176#endif
177      !                       !==  Horizontal divergence of barotropic Stokes transport  ==!
178      div_sd(:,:) = 0._wp
179      DO jk = 1, jpkm1                                 !
180        div_sd(:,:) = div_sd(:,:) + ze3divh(:,:,jk)
181      END DO
182      !
183      CALL iom_put( "ustokes",  usd  )
184      CALL iom_put( "vstokes",  vsd  )
185      CALL iom_put( "wstokes",  wsd  )
186      !
187      CALL wrk_dealloc( jpi,jpj,jpk,   ze3divh )
188      CALL wrk_dealloc( jpi,jpj,       zk_t, zk_u, zk_v, zu0_sd, zv0_sd )
189      !
190   END SUBROUTINE sbc_stokes
191
192
193   SUBROUTINE sbc_wave( kt )
194      !!---------------------------------------------------------------------
195      !!                     ***  ROUTINE sbc_wave  ***
196      !!
197      !! ** Purpose :   read wave parameters from wave model  in netcdf files.
198      !!
199      !! ** Method  : - Read namelist namsbc_wave
200      !!              - Read Cd_n10 fields in netcdf files
201      !!              - Read stokes drift 2d in netcdf files
202      !!              - Read wave number in netcdf files
203      !!              - Compute 3d stokes drift using Breivik et al.,2014
204      !!                formulation
205      !! ** action 
206      !!---------------------------------------------------------------------
207      INTEGER, INTENT(in   ) ::   kt   ! ocean time step
208      !!---------------------------------------------------------------------
209      !
210      IF( ln_cdgw .AND. .NOT. cpl_wdrag ) THEN     !==  Neutral drag coefficient  ==!
211         CALL fld_read( kt, nn_fsbc, sf_cd )             ! read from external forcing
212         cdn_wave(:,:) = sf_cd(1)%fnow(:,:,1)
213         ! check that the drag coefficient contains proper information even if
214         ! the masks do not match - the momentum stress is not masked!
215         WHERE( cdn_wave < 0.0 ) cdn_wave = 1.5e-3
216         WHERE( cdn_wave > 1.0 ) cdn_wave = 1.5e-3
217      ENDIF
218
219      IF( ln_tauoc .AND. .NOT. cpl_tauoc ) THEN    !==  Wave induced stress  ==!
220         CALL fld_read( kt, nn_fsbc, sf_tauoc )          ! read wave norm stress from external forcing
221         tauoc_wave(:,:) = sf_tauoc(1)%fnow(:,:,1)
222         WHERE( tauoc_wave < -100.0 ) tauoc_wave = 1.0
223         WHERE( tauoc_wave >  100.0 ) tauoc_wave = 1.0
224      ENDIF
225
226      IF( ln_phioc .AND. .NOT. cpl_phioc ) THEN    !==  Wave to ocean energy  ==!
227         CALL fld_read( kt, nn_fsbc, sf_phioc )          ! read wave to ocean energy from external forcing
228         rn_crban(:,:) = 29.0 * sf_phioc(1)%fnow(:,:,1)     ! ! Alfa is phioc*sqrt(rw/ra)sbc_wa
229         WHERE( rn_crban <  10.0 ) rn_crban =  10.0
230         WHERE( rn_crban > 300.0 ) rn_crban = 300.0
231      ENDIF
232
233      IF( ln_sdw )  THEN                           !==  Computation of the 3d Stokes Drift  ==!
234         !
235         IF( jpfld > 0 ) THEN                            ! Read from file only if the field is not coupled
236            CALL fld_read( kt, nn_fsbc, sf_sd )          ! read wave parameters from external forcing
237            IF( jp_hsw > 0 )   hsw  (:,:) = sf_sd(jp_hsw)%fnow(:,:,1)   ! significant wave height
238            IF( jp_wmp > 0 )   wmp  (:,:) = sf_sd(jp_wmp)%fnow(:,:,1)   ! wave mean period
239            IF( jp_usd > 0 )   ut0sd(:,:) = sf_sd(jp_usd)%fnow(:,:,1)   ! 2D zonal Stokes Drift at T point
240            IF( jp_vsd > 0 )   vt0sd(:,:) = sf_sd(jp_vsd)%fnow(:,:,1)   ! 2D meridional Stokes Drift at T point
241         ENDIF
242         !
243         ! Read also wave number if needed, so that it is available in coupling routines
244         IF( ln_zdfqiao .AND. .NOT.cpl_wnum ) THEN
245            CALL fld_read( kt, nn_fsbc, sf_wn )          ! read wave parameters from external forcing
246            wnum(:,:) = sf_wn(1)%fnow(:,:,1)
247         ENDIF
248           
249         !                                         !==  Computation of the 3d Stokes Drift  ==!
250         !
251         IF( jpfld == 4 )   CALL sbc_stokes()            ! Calculate only if required fields are read
252         !                                               ! In coupled wave model-NEMO case the call is done after coupling
253         !
254      ENDIF
255      !
256   END SUBROUTINE sbc_wave
257
258
259   SUBROUTINE sbc_wave_init
260      !!---------------------------------------------------------------------
261      !!                     ***  ROUTINE sbc_wave_init  ***
262      !!
263      !! ** Purpose :   read wave parameters from wave model  in netcdf files.
264      !!
265      !! ** Method  : - Read namelist namsbc_wave
266      !!              - Read Cd_n10 fields in netcdf files
267      !!              - Read stokes drift 2d in netcdf files
268      !!              - Read wave number in netcdf files
269      !!              - Compute 3d stokes drift using Breivik et al.,2014
270      !!                formulation
271      !! ** action 
272      !!---------------------------------------------------------------------
273      INTEGER ::   ierror, ios   ! local integer
274      INTEGER ::   ifpr
275      !!
276      CHARACTER(len=100)     ::  cn_dir                          ! Root directory for location of drag coefficient files
277      TYPE(FLD_N), ALLOCATABLE, DIMENSION(:) ::   slf_i     ! array of namelist informations on the fields to read
278      TYPE(FLD_N)            ::  sn_cdg, sn_usd, sn_vsd,  sn_phioc, &
279                             &   sn_hsw, sn_wmp, sn_wnum, sn_tauoc      ! informations about the fields to be read
280      !
281      NAMELIST/namsbc_wave/  sn_cdg, cn_dir, sn_usd, sn_vsd, sn_hsw, sn_wmp, sn_wnum, sn_tauoc, sn_phioc
282      !!---------------------------------------------------------------------
283      !
284      REWIND( numnam_ref )              ! Namelist namsbc_wave in reference namelist : File for drag coeff. from wave model
285      READ  ( numnam_ref, namsbc_wave, IOSTAT = ios, ERR = 901)
286901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_wave in reference namelist', lwp )
287         
288      REWIND( numnam_cfg )              ! Namelist namsbc_wave in configuration namelist : File for drag coeff. from wave model
289      READ  ( numnam_cfg, namsbc_wave, IOSTAT = ios, ERR = 902 )
290902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_wave in configuration namelist', lwp )
291      IF(lwm) WRITE ( numond, namsbc_wave )
292      !
293      IF( ln_cdgw ) THEN
294         IF( .NOT. cpl_wdrag ) THEN
295            ALLOCATE( sf_cd(1), STAT=ierror )           !* allocate and fill sf_wave with sn_cdg
296            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable to allocate sf_cd structure' )
297            !
298                                   ALLOCATE( sf_cd(1)%fnow(jpi,jpj,1)   )
299            IF( sn_cdg%ln_tint )   ALLOCATE( sf_cd(1)%fdta(jpi,jpj,1,2) )
300            CALL fld_fill( sf_cd, (/ sn_cdg /), cn_dir, 'sbc_wave_init', 'Wave module ', 'namsbc_wave' )
301         ENDIF
302         ALLOCATE( cdn_wave(jpi,jpj) )
303      ENDIF
304
305      IF( ln_tauoc ) THEN
306         IF( .NOT. cpl_tauoc ) THEN
307            ALLOCATE( sf_tauoc(1), STAT=ierror )           !* allocate and fill sf_wave with sn_tauoc
308            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable to allocate sf_tauoc structure' )
309            !
310                                    ALLOCATE( sf_tauoc(1)%fnow(jpi,jpj,1)   )
311            IF( sn_tauoc%ln_tint )  ALLOCATE( sf_tauoc(1)%fdta(jpi,jpj,1,2) )
312            CALL fld_fill( sf_tauoc, (/ sn_tauoc /), cn_dir, 'sbc_wave_init', 'Wave module', 'namsbc_wave' )
313         ENDIF
314         ALLOCATE( tauoc_wave(jpi,jpj) )
315      ENDIF
316
317      IF( ln_phioc ) THEN
318         IF( .NOT. cpl_phioc ) THEN
319            ALLOCATE( sf_phioc(1), STAT=ierror )           !* allocate and fill sf_wave with sn_phioc
320            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable to allocate sf_phioc structure' )
321            !
322                                    ALLOCATE( sf_phioc(1)%fnow(jpi,jpj,1)   )
323            IF( sn_phioc%ln_tint )  ALLOCATE( sf_phioc(1)%fdta(jpi,jpj,1,2) )
324            CALL fld_fill( sf_phioc, (/ sn_phioc /), cn_dir, 'sbc_wave_init', 'Wave module', 'namsbc_wave' )
325         ENDIF
326         ALLOCATE( rn_crban(jpi,jpj) )
327      ENDIF
328
329      IF( ln_sdw ) THEN   ! Find out how many fields have to be read from file if not coupled
330         jpfld=0
331         jp_usd=0   ;   jp_vsd=0   ;   jp_hsw=0   ;   jp_wmp=0
332         IF( .NOT. cpl_sdrftx ) THEN
333            jpfld  = jpfld + 1
334            jp_usd = jpfld
335         ENDIF
336         IF( .NOT. cpl_sdrfty ) THEN
337            jpfld  = jpfld + 1
338            jp_vsd = jpfld
339         ENDIF
340         IF( .NOT. cpl_hsig ) THEN
341            jpfld  = jpfld + 1
342            jp_hsw = jpfld
343         ENDIF
344         IF( .NOT. cpl_wper ) THEN
345            jpfld  = jpfld + 1
346            jp_wmp = jpfld
347         ENDIF
348
349         ! Read from file only the non-coupled fields
350         IF( jpfld > 0 ) THEN
351            ALLOCATE( slf_i(jpfld) )
352            IF( jp_usd > 0 )   slf_i(jp_usd) = sn_usd
353            IF( jp_vsd > 0 )   slf_i(jp_vsd) = sn_vsd
354            IF( jp_hsw > 0 )   slf_i(jp_hsw) = sn_hsw
355            IF( jp_wmp > 0 )   slf_i(jp_wmp) = sn_wmp
356            ALLOCATE( sf_sd(jpfld), STAT=ierror )   !* allocate and fill sf_sd with stokes drift
357            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable to allocate sf_sd structure' )
358            !
359            DO ifpr= 1, jpfld
360               ALLOCATE( sf_sd(ifpr)%fnow(jpi,jpj,1) )
361               IF( slf_i(ifpr)%ln_tint )   ALLOCATE( sf_sd(ifpr)%fdta(jpi,jpj,1,2) )
362            END DO
363            !
364            CALL fld_fill( sf_sd, slf_i, cn_dir, 'sbc_wave_init', 'Wave module ', 'namsbc_wave' )
365         ENDIF
366         ALLOCATE( usd  (jpi,jpj,jpk), vsd  (jpi,jpj,jpk), wsd(jpi,jpj,jpk) )
367         ALLOCATE( hsw  (jpi,jpj)    , wmp  (jpi,jpj)     )
368         ALLOCATE( ut0sd(jpi,jpj)    , vt0sd(jpi,jpj)     )
369         ALLOCATE( div_sd(jpi,jpj) )
370         ALLOCATE( tsd2d (jpi,jpj) )
371         usd(:,:,:) = 0._wp
372         vsd(:,:,:) = 0._wp
373         wsd(:,:,:) = 0._wp
374         ! Wave number needed only if ln_zdfqiao=T
375         IF( ln_zdfqiao .AND. .NOT.cpl_wnum ) THEN
376            ALLOCATE( sf_wn(1), STAT=ierror )           !* allocate and fill sf_wave with sn_wnum
377            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable toallocate sf_wn structure' )
378                                   ALLOCATE( sf_wn(1)%fnow(jpi,jpj,1)   )
379            IF( sn_wnum%ln_tint )  ALLOCATE( sf_wn(1)%fdta(jpi,jpj,1,2) )
380            CALL fld_fill( sf_wn, (/ sn_wnum /), cn_dir, 'sbc_wave', 'Wave module', 'namsbc_wave' )
381         ENDIF
382         ALLOCATE( wnum(jpi,jpj) )
383      ENDIF
384      !
385   END SUBROUTINE sbc_wave_init
386
387   !!======================================================================
388END MODULE sbcwave
Note: See TracBrowser for help on using the repository browser.