New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zdfgls.F90 in branches/UKMO/r6232_HZG_WAVE-coupling/NEMOGCM/NEMO/OPA_SRC/ZDF – NEMO

source: branches/UKMO/r6232_HZG_WAVE-coupling/NEMOGCM/NEMO/OPA_SRC/ZDF/zdfgls.F90 @ 7809

Last change on this file since 7809 was 7809, checked in by jcastill, 7 years ago

First implementation of the HZG wave focing/coupling branch - only ln_phioc and ln_tauoc in place. This is crashing amm7 runs with Baltic boundary conditions, but not without them.
File size: 62.9 KB
Line 
1MODULE zdfgls
2   !!======================================================================
3   !!                       ***  MODULE  zdfgls  ***
4   !! Ocean physics:  vertical mixing coefficient computed from the gls
5   !!                 turbulent closure parameterization
6   !!======================================================================
7   !! History :   3.0  !  2009-09  (G. Reffray)  Original code
8   !!             3.3  !  2010-10  (C. Bricaud)  Add in the reference
9   !!----------------------------------------------------------------------
10#if defined key_zdfgls   ||   defined key_esopa
11   !!----------------------------------------------------------------------
12   !!   'key_zdfgls'                 Generic Length Scale vertical physics
13   !!----------------------------------------------------------------------
14   !!   zdf_gls       : update momentum and tracer Kz from a gls scheme
15   !!   zdf_gls_init  : initialization, namelist read, and parameters control
16   !!   gls_rst       : read/write gls restart in ocean restart file
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE dom_oce        ! ocean space and time domain
20   USE domvvl         ! ocean space and time domain : variable volume layer
21   USE zdf_oce        ! ocean vertical physics
22   USE zdfbfr         ! bottom friction (only for rn_bfrz0)
23   USE sbc_oce        ! surface boundary condition: ocean
24   USE phycst         ! physical constants
25   USE zdfmxl         ! mixed layer
26   USE sbcwave, ONLY: hsw,rn_crban
27   !
28   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
29   USE lib_mpp        ! MPP manager
30   USE wrk_nemo       ! work arrays
31   USE prtctl         ! Print control
32   USE in_out_manager ! I/O manager
33   USE iom            ! I/O manager library
34   USE timing         ! Timing
35   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
36
37   IMPLICIT NONE
38   PRIVATE
39
40   PUBLIC   zdf_gls        ! routine called in step module
41   PUBLIC   zdf_gls_init   ! routine called in opa module
42   PUBLIC   gls_rst        ! routine called in step module
43
44   LOGICAL , PUBLIC, PARAMETER ::   lk_zdfgls = .TRUE.   !: TKE vertical mixing flag
45   !
46   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   mxln    !: now mixing length
47   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   zwall   !: wall function
48   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   ustars2 !: Squared surface velocity scale at T-points
49   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   ustarb2 !: Squared bottom  velocity scale at T-points
50
51   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   rsbc_tke1
52   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   rsbc_tke3
53   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   rsbc_psi1
54
55   !                              !! ** Namelist  namzdf_gls  **
56   LOGICAL  ::   ln_length_lim     ! use limit on the dissipation rate under stable stratification (Galperin et al. 1988)
57   LOGICAL  ::   ln_sigpsi         ! Activate Burchard (2003) modification for k-eps closure & wave breaking mixing
58   INTEGER  ::   nn_bc_surf        ! surface boundary condition (=0/1)
59   INTEGER  ::   nn_bc_bot         ! bottom boundary condition (=0/1)
60   INTEGER  ::   nn_z0_met         ! Method for surface roughness computation
61   INTEGER  ::   nn_stab_func      ! stability functions G88, KC or Canuto (=0/1/2)
62   INTEGER  ::   nn_clos           ! closure 0/1/2/3 MY82/k-eps/k-w/gen
63   REAL(wp) ::   rn_clim_galp      ! Holt 2008 value for k-eps: 0.267
64   REAL(wp) ::   rn_epsmin         ! minimum value of dissipation (m2/s3)
65   REAL(wp) ::   rn_emin           ! minimum value of TKE (m2/s2)
66   REAL(wp) ::   rn_charn          ! Charnock constant for surface breaking waves mixing : 1400. (standard) or 2.e5 (Stacey value)
67   REAL(wp) ::   rn_crban_default  ! Craig and Banner constant for surface breaking waves mixing
68   REAL(wp) ::   rn_hsro           ! Minimum surface roughness
69   REAL(wp) ::   rn_frac_hs        ! Fraction of wave height as surface roughness (if nn_z0_met = 1)
70
71   REAL(wp) ::   rcm_sf        =  0.73_wp     ! Shear free turbulence parameters
72   REAL(wp) ::   ra_sf         = -2.0_wp      ! Must be negative -2 < ra_sf < -1
73   REAL(wp) ::   rl_sf         =  0.2_wp      ! 0 <rl_sf<vkarmn   
74   REAL(wp) ::   rghmin        = -0.28_wp
75   REAL(wp) ::   rgh0          =  0.0329_wp
76   REAL(wp) ::   rghcri        =  0.03_wp
77   REAL(wp) ::   ra1           =  0.92_wp
78   REAL(wp) ::   ra2           =  0.74_wp
79   REAL(wp) ::   rb1           = 16.60_wp
80   REAL(wp) ::   rb2           = 10.10_wp         
81   REAL(wp) ::   re2           =  1.33_wp         
82   REAL(wp) ::   rl1           =  0.107_wp
83   REAL(wp) ::   rl2           =  0.0032_wp
84   REAL(wp) ::   rl3           =  0.0864_wp
85   REAL(wp) ::   rl4           =  0.12_wp
86   REAL(wp) ::   rl5           = 11.9_wp
87   REAL(wp) ::   rl6           =  0.4_wp
88   REAL(wp) ::   rl7           =  0.0_wp
89   REAL(wp) ::   rl8           =  0.48_wp
90   REAL(wp) ::   rm1           =  0.127_wp
91   REAL(wp) ::   rm2           =  0.00336_wp
92   REAL(wp) ::   rm3           =  0.0906_wp
93   REAL(wp) ::   rm4           =  0.101_wp
94   REAL(wp) ::   rm5           = 11.2_wp
95   REAL(wp) ::   rm6           =  0.4_wp
96   REAL(wp) ::   rm7           =  0.0_wp
97   REAL(wp) ::   rm8           =  0.318_wp
98   REAL(wp) ::   rtrans        =  0.1_wp
99   REAL(wp) ::   rc02, rc02r, rc03, rc04                          ! coefficients deduced from above parameters
100   REAL(wp) ::   rsbc_tke1_default, rsbc_tke2, rfact_tke          !     -           -           -        -
101   REAL(wp) ::   rsbc_psi2, rsbc_psi3, rfact_psi                  !     -           -           -        -
102   REAL(wp) ::   rsbc_zs1, rsbc_zs2                               !     -           -           -        -
103   REAL(wp) ::   rc0, rc2, rc3, rf6, rcff, rc_diff                !     -           -           -        -
104   REAL(wp) ::   rs0, rs1, rs2, rs4, rs5, rs6                     !     -           -           -        -
105   REAL(wp) ::   rd0, rd1, rd2, rd3, rd4, rd5                     !     -           -           -        -
106   REAL(wp) ::   rsc_tke, rsc_psi, rpsi1, rpsi2, rpsi3, rsc_psi0  !     -           -           -        -
107   REAL(wp) ::   rpsi3m, rpsi3p, rpp, rmm, rnn                    !     -           -           -        -
108
109   !! * Substitutions
110#  include "domzgr_substitute.h90"
111#  include "vectopt_loop_substitute.h90"
112   !!----------------------------------------------------------------------
113   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
114   !! $Id$
115   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
116   !!----------------------------------------------------------------------
117CONTAINS
118
119   INTEGER FUNCTION zdf_gls_alloc()
120      !!----------------------------------------------------------------------
121      !!                ***  FUNCTION zdf_gls_alloc  ***
122      !!----------------------------------------------------------------------
123      ALLOCATE( mxln(jpi,jpj,jpk) , zwall(jpi,jpj,jpk) ,     &
124         &      ustars2(jpi,jpj)  , ustarb2(jpi,jpj)   ,     &
125         &      rsbc_tke1(jpi,jpj), rsbc_tke3(jpi,jpj) ,     &
126         &      rsbc_psi1(jpi,jpj), STAT= zdf_gls_alloc )
127         !
128      IF( lk_mpp             )   CALL mpp_sum ( zdf_gls_alloc )
129      IF( zdf_gls_alloc /= 0 )   CALL ctl_warn('zdf_gls_alloc: failed to allocate arrays')
130   END FUNCTION zdf_gls_alloc
131
132
133   SUBROUTINE zdf_gls( kt )
134      !!----------------------------------------------------------------------
135      !!                   ***  ROUTINE zdf_gls  ***
136      !!
137      !! ** Purpose :   Compute the vertical eddy viscosity and diffusivity
138      !!              coefficients using the GLS turbulent closure scheme.
139      !!----------------------------------------------------------------------
140      INTEGER, INTENT(in) ::   kt ! ocean time step
141      INTEGER  ::   ji, jj, jk, ibot, ibotm1, dir  ! dummy loop arguments
142      REAL(wp) ::   zesh2, zsigpsi, zcoef, zex1, zex2   ! local scalars
143      REAL(wp) ::   ztx2, zty2, zup, zdown, zcof        !   -      -
144      REAL(wp) ::   zratio, zrn2, zflxb, sh             !   -      -
145      REAL(wp) ::   prod, buoy, diss, zdiss, sm         !   -      -
146      REAL(wp) ::   gh, gm, shr, dif, zsqen, zav        !   -      -
147      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zdep
148      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zkar
149      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zflxs       ! Turbulence fluxed induced by internal waves
150      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zhsro       ! Surface roughness (surface waves)
151      REAL(wp), POINTER, DIMENSION(:,:,:) ::   eb          ! tke at time before
152      REAL(wp), POINTER, DIMENSION(:,:,:) ::   mxlb        ! mixing length at time before
153      REAL(wp), POINTER, DIMENSION(:,:,:) ::   shear       ! vertical shear
154      REAL(wp), POINTER, DIMENSION(:,:,:) ::   eps         ! dissipation rate
155      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zwall_psi   ! Wall function use in the wb case (ln_sigpsi)
156      REAL(wp), POINTER, DIMENSION(:,:,:) ::   psi         ! psi at time now
157      REAL(wp), POINTER, DIMENSION(:,:,:) ::   z_elem_a    ! element of the first  matrix diagonal
158      REAL(wp), POINTER, DIMENSION(:,:,:) ::   z_elem_b    ! element of the second matrix diagonal
159      REAL(wp), POINTER, DIMENSION(:,:,:) ::   z_elem_c    ! element of the third  matrix diagonal
160      !!--------------------------------------------------------------------
161      !
162      IF( nn_timing == 1 )  CALL timing_start('zdf_gls')
163      !
164      CALL wrk_alloc( jpi,jpj, zdep, zkar, zflxs, zhsro )
165      CALL wrk_alloc( jpi,jpj,jpk, eb, mxlb, shear, eps, zwall_psi, z_elem_a, z_elem_b, z_elem_c, psi  )
166     
167      ! Preliminary computing
168
169      ustars2 = 0._wp   ;   ustarb2 = 0._wp   ;   psi  = 0._wp   ;   zwall_psi = 0._wp
170
171
172      ! variable initialization
173      IF( ln_phioc ) THEN
174         rsbc_tke1(:,:) = (-rsc_tke*rn_crban(:,:)/(rcm_sf*ra_sf*rl_sf))**(2._wp/3._wp)  ! k_eps = 53.Dirichlet + Wave breaking
175         rsbc_tke3(:,:) = rdt * rn_crban(:,:)                                           ! Neumann + Wave breaking
176         rsbc_psi1(:,:) = rc0**rpp * rsbc_tke1(:,:)**rmm * rl_sf**rnn                   ! Dirichlet + Wave breaking
177      ENDIF
178
179      IF( kt /= nit000 ) THEN   ! restore before value to compute tke
180         avt (:,:,:) = avt_k (:,:,:)
181         avm (:,:,:) = avm_k (:,:,:)
182         avmu(:,:,:) = avmu_k(:,:,:)
183         avmv(:,:,:) = avmv_k(:,:,:) 
184      ENDIF
185
186      ! Compute surface and bottom friction at T-points
187!CDIR NOVERRCHK         
188      DO jj = 2, jpjm1         
189!CDIR NOVERRCHK         
190         DO ji = fs_2, fs_jpim1   ! vector opt.         
191            !
192            ! surface friction
193            ustars2(ji,jj) = r1_rau0 * taum(ji,jj) * tmask(ji,jj,1)
194            !   
195            ! bottom friction (explicit before friction)       
196            ! Note that we chose here not to bound the friction as in dynbfr)   
197            ztx2 = (  bfrua(ji,jj)  * ub(ji,jj,mbku(ji,jj)) + bfrua(ji-1,jj) * ub(ji-1,jj,mbku(ji-1,jj))  )   &         
198               & * ( 1._wp - 0.5_wp * umask(ji,jj,1) * umask(ji-1,jj,1)  )     
199            zty2 = (  bfrva(ji,jj)  * vb(ji,jj,mbkv(ji,jj)) + bfrva(ji,jj-1) * vb(ji,jj-1,mbkv(ji,jj-1))  )   &         
200               & * ( 1._wp - 0.5_wp * vmask(ji,jj,1) * vmask(ji,jj-1,1)  )     
201            ustarb2(ji,jj) = SQRT( ztx2 * ztx2 + zty2 * zty2 ) * tmask(ji,jj,1)         
202         END DO         
203      END DO   
204
205      ! Set surface roughness length
206      SELECT CASE ( nn_z0_met )
207      !
208      CASE ( 0 )             ! Constant roughness         
209         zhsro(:,:) = rn_hsro
210      CASE ( 1 )             ! Standard Charnock formula
211         zhsro(:,:) = MAX(rsbc_zs1 * ustars2(:,:), rn_hsro)
212      CASE ( 2 )             ! Roughness formulae according to Rascle et al., Ocean Modelling (2008)
213         zdep(:,:)  = 30.*TANH(2.*0.3/(28.*SQRT(MAX(ustars2(:,:),rsmall))))             ! Wave age (eq. 10)
214         zhsro(:,:) = MAX(rsbc_zs2 * ustars2(:,:) * zdep(:,:)**1.5, rn_hsro) ! zhsro = rn_frac_hs * Hsw (eq. 11)
215      CASE ( 3 )             ! Roughness given by the wave model (coupled or read in file)
216         WHERE( hsw == 0._wp ) ! surface roughness length according to Charnock formula when sign. wave height 0
217            zhsro = MAX(rn_charn / grav * ustars2, rn_hsro)
218         ELSEWHERE
219            zhsro = MAX(hsw, rn_hsro)
220         END WHERE
221      END SELECT
222
223      ! Compute shear and dissipation rate
224      DO jk = 2, jpkm1
225         DO jj = 2, jpjm1
226            DO ji = fs_2, fs_jpim1   ! vector opt.
227               avmu(ji,jj,jk) = avmu(ji,jj,jk) * ( un(ji,jj,jk-1) - un(ji,jj,jk) )   &
228                  &                            * ( ub(ji,jj,jk-1) - ub(ji,jj,jk) )   &
229                  &                            / (  fse3uw_n(ji,jj,jk)               &
230                  &                            *    fse3uw_b(ji,jj,jk) )
231               avmv(ji,jj,jk) = avmv(ji,jj,jk) * ( vn(ji,jj,jk-1) - vn(ji,jj,jk) )   &
232                  &                            * ( vb(ji,jj,jk-1) - vb(ji,jj,jk) )   &
233                  &                            / (  fse3vw_n(ji,jj,jk)               &
234                  &                            *    fse3vw_b(ji,jj,jk) )
235               eps(ji,jj,jk)  = rc03 * en(ji,jj,jk) * SQRT(en(ji,jj,jk)) / mxln(ji,jj,jk)
236            END DO
237         END DO
238      END DO
239      !
240      ! Lateral boundary conditions (avmu,avmv) (sign unchanged)
241      CALL lbc_lnk( avmu, 'U', 1. )   ;   CALL lbc_lnk( avmv, 'V', 1. )
242
243      ! Save tke at before time step
244      eb  (:,:,:) = en  (:,:,:)
245      mxlb(:,:,:) = mxln(:,:,:)
246
247      IF( nn_clos == 0 ) THEN    ! Mellor-Yamada
248         DO jk = 2, jpkm1
249            DO jj = 2, jpjm1 
250               DO ji = fs_2, fs_jpim1   ! vector opt.
251                  zup   = mxln(ji,jj,jk) * fsdepw(ji,jj,mbkt(ji,jj)+1)
252                  zdown = vkarmn * fsdepw(ji,jj,jk) * ( -fsdepw(ji,jj,jk) + fsdepw(ji,jj,mbkt(ji,jj)+1) )
253                  zcoef = ( zup / MAX( zdown, rsmall ) )
254                  zwall (ji,jj,jk) = ( 1._wp + re2 * zcoef*zcoef ) * tmask(ji,jj,jk)
255               END DO
256            END DO
257         END DO
258      ENDIF
259
260      !!---------------------------------!!
261      !!   Equation to prognostic k      !!
262      !!---------------------------------!!
263      !
264      ! Now Turbulent kinetic energy (output in en)
265      ! -------------------------------
266      ! Resolution of a tridiagonal linear system by a "methode de chasse"
267      ! computation from level 2 to jpkm1  (e(1) computed after and e(jpk)=0 ).
268      ! The surface boundary condition are set after
269      ! The bottom boundary condition are also set after. In standard e(bottom)=0.
270      ! z_elem_b : diagonal z_elem_c : upper diagonal z_elem_a : lower diagonal
271      ! Warning : after this step, en : right hand side of the matrix
272
273      DO jk = 2, jpkm1
274         DO jj = 2, jpjm1
275            DO ji = fs_2, fs_jpim1   ! vector opt.
276               !
277               ! shear prod. at w-point weightened by mask
278               shear(ji,jj,jk) =  ( avmu(ji-1,jj,jk) + avmu(ji,jj,jk) ) / MAX( 1.e0 , umask(ji-1,jj,jk) + umask(ji,jj,jk) )   &
279                  &             + ( avmv(ji,jj-1,jk) + avmv(ji,jj,jk) ) / MAX( 1.e0 , vmask(ji,jj-1,jk) + vmask(ji,jj,jk) )
280               !
281               ! stratif. destruction
282               buoy = - avt(ji,jj,jk) * rn2(ji,jj,jk)
283               !
284               ! shear prod. - stratif. destruction
285               diss = eps(ji,jj,jk)
286               !
287               dir = 0.5_wp + SIGN( 0.5_wp, shear(ji,jj,jk) + buoy )   ! dir =1(=0) if shear(ji,jj,jk)+buoy >0(<0)
288               !
289               zesh2 = dir*(shear(ji,jj,jk)+buoy)+(1._wp-dir)*shear(ji,jj,jk)          ! production term
290               zdiss = dir*(diss/en(ji,jj,jk))   +(1._wp-dir)*(diss-buoy)/en(ji,jj,jk) ! dissipation term
291               !
292               ! Compute a wall function from 1. to rsc_psi*zwall/rsc_psi0
293               ! Note that as long that Dirichlet boundary conditions are NOT set at the first and last levels (GOTM style)
294               ! there is no need to set a boundary condition for zwall_psi at the top and bottom boundaries.
295               ! Otherwise, this should be rsc_psi/rsc_psi0
296               IF( ln_sigpsi ) THEN
297                  zsigpsi = MIN( 1._wp, zesh2 / eps(ji,jj,jk) )     ! 0. <= zsigpsi <= 1.
298                  zwall_psi(ji,jj,jk) = rsc_psi /   & 
299                     &     (  zsigpsi * rsc_psi + (1._wp-zsigpsi) * rsc_psi0 / MAX( zwall(ji,jj,jk), 1._wp )  )
300               ELSE
301                  zwall_psi(ji,jj,jk) = 1._wp
302               ENDIF
303               !
304               ! building the matrix
305               zcof = rfact_tke * tmask(ji,jj,jk)
306               !
307               ! lower diagonal
308               z_elem_a(ji,jj,jk) = zcof * ( avm  (ji,jj,jk  ) + avm  (ji,jj,jk-1) )   &
309                  &                      / ( fse3t(ji,jj,jk-1) * fse3w(ji,jj,jk  ) )
310               !
311               ! upper diagonal
312               z_elem_c(ji,jj,jk) = zcof * ( avm  (ji,jj,jk+1) + avm  (ji,jj,jk  ) )   &
313                  &                      / ( fse3t(ji,jj,jk  ) * fse3w(ji,jj,jk) )
314               !
315               ! diagonal
316               z_elem_b(ji,jj,jk) = 1._wp - z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk)  &
317                  &                       + rdt * zdiss * tmask(ji,jj,jk) 
318               !
319               ! right hand side in en
320               en(ji,jj,jk) = en(ji,jj,jk) + rdt * zesh2 * tmask(ji,jj,jk)
321            END DO
322         END DO
323      END DO
324      !
325      z_elem_b(:,:,jpk) = 1._wp
326      !
327      ! Set surface condition on zwall_psi (1 at the bottom)
328      zwall_psi(:,:,1) = zwall_psi(:,:,2)
329      zwall_psi(:,:,jpk) = 1.
330      !
331      ! Surface boundary condition on tke
332      ! ---------------------------------
333      !
334      SELECT CASE ( nn_bc_surf )
335      !
336      CASE ( 0 )             ! Dirichlet case
337         IF( ln_phioc ) THEN  ! wave induced mixing case with forced/coupled fields
338            ! First level
339            en(:,:,1) = MAX( rsbc_tke1(:,:) * ustars2(:,:), rn_emin )
340            z_elem_a(:,:,1) = en(:,:,1)
341            z_elem_c(:,:,1) = 0._wp
342            z_elem_b(:,:,1) = 1._wp
343
344            ! One level below
345            en(:,:,2) = MAX( rsbc_tke1(:,:) * ustars2(:,:) * ((zhsro(:,:)+fsdepw(:,:,2))/zhsro(:,:) )**ra_sf, rn_emin )
346            z_elem_a(:,:,2) = 0._wp
347            z_elem_c(:,:,2) = 0._wp
348            z_elem_b(:,:,2) = 1._wp
349         ELSE                 ! wave induced mixing case with default values
350            en(:,:,1) = rc02r * ustars2(:,:) * (1._wp + rsbc_tke1_default)**(2._wp/3._wp)
351            en(:,:,1) = MAX(en(:,:,1), rn_emin) 
352            z_elem_a(:,:,1) = en(:,:,1)
353            z_elem_c(:,:,1) = 0._wp
354            z_elem_b(:,:,1) = 1._wp
355            !
356            ! One level below
357            en(:,:,2) = rc02r * ustars2(:,:) * (1._wp + rsbc_tke1_default * ((zhsro(:,:)+fsdepw(:,:,2)) &
358                &            / zhsro(:,:) )**(1.5_wp*ra_sf))**(2._wp/3._wp)
359            en(:,:,2) = MAX(en(:,:,2), rn_emin )
360            z_elem_a(:,:,2) = 0._wp 
361            z_elem_c(:,:,2) = 0._wp
362            z_elem_b(:,:,2) = 1._wp
363            !
364            !
365         ENDIF
366      CASE ( 1 )             ! Neumann boundary condition on d(e)/dz
367         IF( ln_phioc ) THEN   ! Shear free case: d(e)/dz=Fw with forced/coupled fields
368            ! Dirichlet conditions at k=1
369            en(:,:,1) = MAX( rsbc_tke1(:,:) * ustars2(:,:), rn_emin )
370            z_elem_a(:,:,1) = en(:,:,1)
371            z_elem_c(:,:,1) = 0._wp
372            z_elem_b(:,:,1) = 1._wp
373            ! at k=2, set de/dz=Fw
374            z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
375            z_elem_a(:,:,2) = 0._wp
376            zflxs(:,:) = rsbc_tke3(:,:) * ustars2(:,:)**1.5_wp * ((zhsro(:,:)+fsdept(:,:,1) ) / zhsro(:,:) )**(1.5*ra_sf)
377            en(:,:,2) = en(:,:,2) + zflxs(:,:) / fse3w(:,:,2)
378         ELSE                  ! Shear free case: d(e)/dz=Fw with default values
379            ! Dirichlet conditions at k=1
380            en(:,:,1)       = rc02r * ustars2(:,:) * (1._wp + rsbc_tke1_default)**(2._wp/3._wp)
381            en(:,:,1)       = MAX(en(:,:,1), rn_emin)     
382            z_elem_a(:,:,1) = en(:,:,1)
383            z_elem_c(:,:,1) = 0._wp
384            z_elem_b(:,:,1) = 1._wp
385            !
386            ! at k=2, set de/dz=Fw
387            !cbr
388            z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
389            z_elem_a(:,:,2) = 0._wp
390            zkar(:,:)       = (rl_sf + (vkarmn-rl_sf)*(1.-exp(-rtrans*fsdept(:,:,1)/zhsro(:,:)) ))
391            zflxs(:,:)      = rsbc_tke2 * ustars2(:,:)**1.5_wp * zkar(:,:) &
392                 &                      * ((zhsro(:,:)+fsdept(:,:,1))/zhsro(:,:) )**(1.5_wp*ra_sf)
393
394            en(:,:,2) = en(:,:,2) + zflxs(:,:)/fse3w(:,:,2)
395            !
396            !
397         ENDIF
398      END SELECT
399
400      ! Bottom boundary condition on tke
401      ! --------------------------------
402      !
403      SELECT CASE ( nn_bc_bot )
404      !
405      CASE ( 0 )             ! Dirichlet
406         !                      ! en(ibot) = u*^2 / Co2 and mxln(ibot) = rn_lmin
407         !                      ! Balance between the production and the dissipation terms
408!CDIR NOVERRCHK
409         DO jj = 2, jpjm1
410!CDIR NOVERRCHK
411            DO ji = fs_2, fs_jpim1   ! vector opt.
412               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
413               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
414               !
415               ! Bottom level Dirichlet condition:
416               z_elem_a(ji,jj,ibot  ) = 0._wp
417               z_elem_c(ji,jj,ibot  ) = 0._wp
418               z_elem_b(ji,jj,ibot  ) = 1._wp
419               en(ji,jj,ibot  ) = MAX( rc02r * ustarb2(ji,jj), rn_emin )
420               !
421               ! Just above last level, Dirichlet condition again
422               z_elem_a(ji,jj,ibotm1) = 0._wp
423               z_elem_c(ji,jj,ibotm1) = 0._wp
424               z_elem_b(ji,jj,ibotm1) = 1._wp
425               en(ji,jj,ibotm1) = MAX( rc02r * ustarb2(ji,jj), rn_emin ) 
426            END DO
427         END DO
428         !
429      CASE ( 1 )             ! Neumman boundary condition
430         !                     
431!CDIR NOVERRCHK
432         DO jj = 2, jpjm1
433!CDIR NOVERRCHK
434            DO ji = fs_2, fs_jpim1   ! vector opt.
435               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
436               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
437               !
438               ! Bottom level Dirichlet condition:
439               z_elem_a(ji,jj,ibot) = 0._wp
440               z_elem_c(ji,jj,ibot) = 0._wp
441               z_elem_b(ji,jj,ibot) = 1._wp
442               en(ji,jj,ibot) = MAX( rc02r * ustarb2(ji,jj), rn_emin )
443               !
444               ! Just above last level: Neumann condition
445               z_elem_b(ji,jj,ibotm1) = z_elem_b(ji,jj,ibotm1) + z_elem_c(ji,jj,ibotm1)   ! Remove z_elem_c from z_elem_b
446               z_elem_c(ji,jj,ibotm1) = 0._wp
447            END DO
448         END DO
449         !
450      END SELECT
451
452      ! Matrix inversion (en prescribed at surface and the bottom)
453      ! ----------------------------------------------------------
454      !
455      DO jk = 2, jpkm1                             ! First recurrence : Dk = Dk - Lk * Uk-1 / Dk-1
456         DO jj = 2, jpjm1
457            DO ji = fs_2, fs_jpim1    ! vector opt.
458               z_elem_b(ji,jj,jk) = z_elem_b(ji,jj,jk) - z_elem_a(ji,jj,jk) * z_elem_c(ji,jj,jk-1) / z_elem_b(ji,jj,jk-1)
459            END DO
460         END DO
461      END DO
462      DO jk = 2, jpk                               ! Second recurrence : Lk = RHSk - Lk / Dk-1 * Lk-1
463         DO jj = 2, jpjm1
464            DO ji = fs_2, fs_jpim1    ! vector opt.
465               z_elem_a(ji,jj,jk) = en(ji,jj,jk) - z_elem_a(ji,jj,jk) / z_elem_b(ji,jj,jk-1) * z_elem_a(ji,jj,jk-1)
466            END DO
467         END DO
468      END DO
469      DO jk = jpk-1, 2, -1                         ! thrid recurrence : Ek = ( Lk - Uk * Ek+1 ) / Dk
470         DO jj = 2, jpjm1
471            DO ji = fs_2, fs_jpim1    ! vector opt.
472               en(ji,jj,jk) = ( z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk) * en(ji,jj,jk+1) ) / z_elem_b(ji,jj,jk)
473            END DO
474         END DO
475      END DO
476      !                                            ! set the minimum value of tke
477      en(:,:,:) = MAX( en(:,:,:), rn_emin )
478
479      !!----------------------------------------!!
480      !!   Solve prognostic equation for psi    !!
481      !!----------------------------------------!!
482
483      ! Set psi to previous time step value
484      !
485      SELECT CASE ( nn_clos )
486      !
487      CASE( 0 )               ! k-kl  (Mellor-Yamada)
488         DO jk = 2, jpkm1
489            DO jj = 2, jpjm1
490               DO ji = fs_2, fs_jpim1   ! vector opt.
491                  psi(ji,jj,jk)  = eb(ji,jj,jk) * mxlb(ji,jj,jk)
492               END DO
493            END DO
494         END DO
495         !
496      CASE( 1 )               ! k-eps
497         DO jk = 2, jpkm1
498            DO jj = 2, jpjm1
499               DO ji = fs_2, fs_jpim1   ! vector opt.
500                  psi(ji,jj,jk)  = eps(ji,jj,jk)
501               END DO
502            END DO
503         END DO
504         !
505      CASE( 2 )               ! k-w
506         DO jk = 2, jpkm1
507            DO jj = 2, jpjm1
508               DO ji = fs_2, fs_jpim1   ! vector opt.
509                  psi(ji,jj,jk)  = SQRT( eb(ji,jj,jk) ) / ( rc0 * mxlb(ji,jj,jk) )
510               END DO
511            END DO
512         END DO
513         !
514      CASE( 3 )               ! generic
515         DO jk = 2, jpkm1
516            DO jj = 2, jpjm1
517               DO ji = fs_2, fs_jpim1   ! vector opt.
518                  psi(ji,jj,jk)  = rc02 * eb(ji,jj,jk) * mxlb(ji,jj,jk)**rnn 
519               END DO
520            END DO
521         END DO
522         !
523      END SELECT
524      !
525      ! Now gls (output in psi)
526      ! -------------------------------
527      ! Resolution of a tridiagonal linear system by a "methode de chasse"
528      ! computation from level 2 to jpkm1  (e(1) already computed and e(jpk)=0 ).
529      ! z_elem_b : diagonal z_elem_c : upper diagonal z_elem_a : lower diagonal
530      ! Warning : after this step, en : right hand side of the matrix
531
532      DO jk = 2, jpkm1
533         DO jj = 2, jpjm1
534            DO ji = fs_2, fs_jpim1   ! vector opt.
535               !
536               ! psi / k
537               zratio = psi(ji,jj,jk) / eb(ji,jj,jk) 
538               !
539               ! psi3+ : stable : B=-KhN²<0 => N²>0 if rn2>0 dir = 1 (stable) otherwise dir = 0 (unstable)
540               dir = 0.5_wp + SIGN( 0.5_wp, rn2(ji,jj,jk) )
541               !
542               rpsi3 = dir * rpsi3m + ( 1._wp - dir ) * rpsi3p
543               !
544               ! shear prod. - stratif. destruction
545               prod = rpsi1 * zratio * shear(ji,jj,jk)
546               !
547               ! stratif. destruction
548               buoy = rpsi3 * zratio * (- avt(ji,jj,jk) * rn2(ji,jj,jk) )
549               !
550               ! shear prod. - stratif. destruction
551               diss = rpsi2 * zratio * zwall(ji,jj,jk) * eps(ji,jj,jk)
552               !
553               dir = 0.5_wp + SIGN( 0.5_wp, prod + buoy )   ! dir =1(=0) if shear(ji,jj,jk)+buoy >0(<0)
554               !
555               zesh2 = dir * ( prod + buoy )          + (1._wp - dir ) * prod                        ! production term
556               zdiss = dir * ( diss / psi(ji,jj,jk) ) + (1._wp - dir ) * (diss-buoy) / psi(ji,jj,jk) ! dissipation term
557               !                                                       
558               ! building the matrix
559               zcof = rfact_psi * zwall_psi(ji,jj,jk) * tmask(ji,jj,jk)
560               ! lower diagonal
561               z_elem_a(ji,jj,jk) = zcof * ( avm  (ji,jj,jk  ) + avm  (ji,jj,jk-1) )   &
562                  &                      / ( fse3t(ji,jj,jk-1) * fse3w(ji,jj,jk  ) )
563               ! upper diagonal
564               z_elem_c(ji,jj,jk) = zcof * ( avm  (ji,jj,jk+1) + avm  (ji,jj,jk  ) )   &
565                  &                      / ( fse3t(ji,jj,jk  ) * fse3w(ji,jj,jk) )
566               ! diagonal
567               z_elem_b(ji,jj,jk) = 1._wp - z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk)  &
568                  &                       + rdt * zdiss * tmask(ji,jj,jk)
569               !
570               ! right hand side in psi
571               psi(ji,jj,jk) = psi(ji,jj,jk) + rdt * zesh2 * tmask(ji,jj,jk)
572            END DO
573         END DO
574      END DO
575      !
576      z_elem_b(:,:,jpk) = 1._wp
577
578      ! Surface boundary condition on psi
579      ! ---------------------------------
580      !
581      SELECT CASE ( nn_bc_surf )
582      !
583      CASE ( 0 )             ! Dirichlet boundary conditions
584         IF( ln_phioc ) THEN   ! Wave induced mixing case
585                               ! en(1) = q2(1) = 0.5 * (15.8 * Ccb)^(2/3) * u*^2
586                               ! balance between the production and the
587                               ! dissipation terms including the wave effect
588            ! Surface value
589            zdep(:,:)       = zhsro(:,:) * rl_sf ! Cosmetic
590            psi (:,:,1)     = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
591            z_elem_a(:,:,1) = psi(:,:,1)     
592            z_elem_c(:,:,1) = 0._wp
593            z_elem_b(:,:,1) = 1._wp
594            !
595            ! One level below
596            zex1 = (rmm*ra_sf+rnn)
597            zex2 = (rmm*ra_sf)
598            zdep(:,:) = ( (zhsro(:,:) + fsdepw(:,:,2))**zex1 ) / zhsro(:,:)**zex2
599            psi (:,:,2) = rsbc_psi1(:,:) * ustars2(:,:)**rmm * zdep(:,:) * tmask(:,:,1)
600            z_elem_a(:,:,2) = 0._wp
601            z_elem_c(:,:,2) = 0._wp
602            z_elem_b(:,:,2) = 1._wp
603            !
604            !
605         ELSE                  ! Wave induced mixing case with default values
606            ! Surface value
607            zdep(:,:)       = zhsro(:,:) * rl_sf ! Cosmetic
608            psi (:,:,1)     = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
609            z_elem_a(:,:,1) = psi(:,:,1)
610            z_elem_c(:,:,1) = 0._wp
611            z_elem_b(:,:,1) = 1._wp
612            !
613            ! One level below
614            zkar(:,:)       = (rl_sf + (vkarmn-rl_sf)*(1._wp-exp(-rtrans*fsdepw(:,:,2)/zhsro(:,:) )))
615            zdep(:,:)       = (zhsro(:,:) + fsdepw(:,:,2)) * zkar(:,:)
616            psi (:,:,2)     = rc0**rpp * en(:,:,2)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
617            z_elem_a(:,:,2) = 0._wp
618            z_elem_c(:,:,2) = 0._wp
619            z_elem_b(:,:,2) = 1._wp
620            !
621            !
622         ENDIF
623      CASE ( 1 )             ! Neumann boundary condition on d(psi)/dz
624         IF( ln_phioc ) THEN  ! Wave induced mixing case with forced/coupled fields
625            !
626            zdep(:,:) = rl_sf * zhsro(:,:)
627            psi (:,:,1) = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
628            z_elem_a(:,:,1) = psi(:,:,1)
629            z_elem_c(:,:,1) = 0._wp
630            z_elem_b(:,:,1) = 1._wp
631            !
632            ! Neumann condition at k=2
633            z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
634            z_elem_a(:,:,2) = 0._wp
635            !
636            ! Set psi vertical flux at the surface:
637            zdep(:,:) = (zhsro(:,:) + fsdept(:,:,1))**(rmm*ra_sf+rnn-1._wp) / zhsro(:,:)**(rmm*ra_sf)
638            zflxs(:,:) = rsbc_psi3 * ( zwall_psi(:,:,1)*avm(:,:,1) + zwall_psi(:,:,2)*avm(:,:,2) ) &
639               &                   * en(:,:,1)**rmm * zdep
640            psi(:,:,2) = psi(:,:,2) + zflxs(:,:) / fse3w(:,:,2)
641            !
642         ELSE                 ! Wave induced mixing case with default values
643            ! Surface value: Dirichlet
644            zdep(:,:)       = zhsro(:,:) * rl_sf
645            psi (:,:,1)     = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
646            z_elem_a(:,:,1) = psi(:,:,1)
647            z_elem_c(:,:,1) = 0._wp
648            z_elem_b(:,:,1) = 1._wp
649            !
650            ! Neumann condition at k=2
651            z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
652            z_elem_a(:,:,2) = 0._wp
653            !
654            ! Set psi vertical flux at the surface:
655            zkar(:,:) = rl_sf + (vkarmn-rl_sf)*(1._wp-exp(-rtrans*fsdept(:,:,1)/zhsro(:,:) )) ! Lengh scale slope
656            zdep(:,:) = ((zhsro(:,:) + fsdept(:,:,1)) / zhsro(:,:))**(rmm*ra_sf)
657            zflxs(:,:) = (rnn + rsbc_tke1_default * (rnn + rmm*ra_sf) * zdep(:,:)) * &
658                       (1._wp + rsbc_tke1_default * zdep(:,:))**(2._wp*rmm/3._wp-1_wp)
659            zdep(:,:) =  rsbc_psi1(:,:) * (zwall_psi(:,:,1)*avm(:,:,1)+zwall_psi(:,:,2)*avm(:,:,2)) * &
660                   & ustars2(:,:)**rmm * zkar(:,:)**rnn * (zhsro(:,:) + fsdept(:,:,1))**(rnn-1.)
661            zflxs(:,:) = zdep(:,:) * zflxs(:,:)
662            psi(:,:,2) = psi(:,:,2) + zflxs(:,:) / fse3w(:,:,2)
663            !   
664            !
665         ENDIF
666      END SELECT
667
668      ! Bottom boundary condition on psi
669      ! --------------------------------
670      !
671      SELECT CASE ( nn_bc_bot )
672      !
673      !
674      CASE ( 0 )             ! Dirichlet
675         !                      ! en(ibot) = u*^2 / Co2 and mxln(ibot) = vkarmn * rn_bfrz0
676         !                      ! Balance between the production and the dissipation terms
677!CDIR NOVERRCHK
678         DO jj = 2, jpjm1
679!CDIR NOVERRCHK
680            DO ji = fs_2, fs_jpim1   ! vector opt.
681               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
682               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
683               zdep(ji,jj) = vkarmn * rn_bfrz0
684               psi (ji,jj,ibot) = rc0**rpp * en(ji,jj,ibot)**rmm * zdep(ji,jj)**rnn
685               z_elem_a(ji,jj,ibot) = 0._wp
686               z_elem_c(ji,jj,ibot) = 0._wp
687               z_elem_b(ji,jj,ibot) = 1._wp
688               !
689               ! Just above last level, Dirichlet condition again (GOTM like)
690               zdep(ji,jj) = vkarmn * ( rn_bfrz0 + fse3t(ji,jj,ibotm1) )
691               psi (ji,jj,ibotm1) = rc0**rpp * en(ji,jj,ibot  )**rmm * zdep(ji,jj)**rnn
692               z_elem_a(ji,jj,ibotm1) = 0._wp
693               z_elem_c(ji,jj,ibotm1) = 0._wp
694               z_elem_b(ji,jj,ibotm1) = 1._wp
695            END DO
696         END DO
697         !
698      CASE ( 1 )             ! Neumman boundary condition
699         !                     
700!CDIR NOVERRCHK
701         DO jj = 2, jpjm1
702!CDIR NOVERRCHK
703            DO ji = fs_2, fs_jpim1   ! vector opt.
704               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
705               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
706               !
707               ! Bottom level Dirichlet condition:
708               zdep(ji,jj) = vkarmn * rn_bfrz0
709               psi (ji,jj,ibot) = rc0**rpp * en(ji,jj,ibot)**rmm * zdep(ji,jj)**rnn
710               !
711               z_elem_a(ji,jj,ibot) = 0._wp
712               z_elem_c(ji,jj,ibot) = 0._wp
713               z_elem_b(ji,jj,ibot) = 1._wp
714               !
715               ! Just above last level: Neumann condition with flux injection
716               z_elem_b(ji,jj,ibotm1) = z_elem_b(ji,jj,ibotm1) + z_elem_c(ji,jj,ibotm1) ! Remove z_elem_c from z_elem_b
717               z_elem_c(ji,jj,ibotm1) = 0.
718               !
719               ! Set psi vertical flux at the bottom:
720               zdep(ji,jj) = rn_bfrz0 + 0.5_wp*fse3t(ji,jj,ibotm1)
721               zflxb = rsbc_psi2 * ( avm(ji,jj,ibot) + avm(ji,jj,ibotm1) )   &
722                  &  * (0.5_wp*(en(ji,jj,ibot)+en(ji,jj,ibotm1)))**rmm * zdep(ji,jj)**(rnn-1._wp)
723               psi(ji,jj,ibotm1) = psi(ji,jj,ibotm1) + zflxb / fse3w(ji,jj,ibotm1)
724            END DO
725         END DO
726         !
727      END SELECT
728
729      ! Matrix inversion
730      ! ----------------
731      !
732      DO jk = 2, jpkm1                             ! First recurrence : Dk = Dk - Lk * Uk-1 / Dk-1
733         DO jj = 2, jpjm1
734            DO ji = fs_2, fs_jpim1    ! vector opt.
735               z_elem_b(ji,jj,jk) = z_elem_b(ji,jj,jk) - z_elem_a(ji,jj,jk) * z_elem_c(ji,jj,jk-1) / z_elem_b(ji,jj,jk-1)
736            END DO
737         END DO
738      END DO
739      DO jk = 2, jpk                               ! Second recurrence : Lk = RHSk - Lk / Dk-1 * Lk-1
740         DO jj = 2, jpjm1
741            DO ji = fs_2, fs_jpim1    ! vector opt.
742               z_elem_a(ji,jj,jk) = psi(ji,jj,jk) - z_elem_a(ji,jj,jk) / z_elem_b(ji,jj,jk-1) * z_elem_a(ji,jj,jk-1)
743            END DO
744         END DO
745      END DO
746      DO jk = jpk-1, 2, -1                         ! Third recurrence : Ek = ( Lk - Uk * Ek+1 ) / Dk
747         DO jj = 2, jpjm1
748            DO ji = fs_2, fs_jpim1    ! vector opt.
749               psi(ji,jj,jk) = ( z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk) * psi(ji,jj,jk+1) ) / z_elem_b(ji,jj,jk)
750            END DO
751         END DO
752      END DO
753
754      ! Set dissipation
755      !----------------
756
757      SELECT CASE ( nn_clos )
758      !
759      CASE( 0 )               ! k-kl  (Mellor-Yamada)
760         DO jk = 1, jpkm1
761            DO jj = 2, jpjm1
762               DO ji = fs_2, fs_jpim1   ! vector opt.
763                  eps(ji,jj,jk) = rc03 * en(ji,jj,jk) * en(ji,jj,jk) * SQRT( en(ji,jj,jk) ) / MAX( psi(ji,jj,jk), rn_epsmin)
764               END DO
765            END DO
766         END DO
767         !
768      CASE( 1 )               ! k-eps
769         DO jk = 1, jpkm1
770            DO jj = 2, jpjm1
771               DO ji = fs_2, fs_jpim1   ! vector opt.
772                  eps(ji,jj,jk) = psi(ji,jj,jk)
773               END DO
774            END DO
775         END DO
776         !
777      CASE( 2 )               ! k-w
778         DO jk = 1, jpkm1
779            DO jj = 2, jpjm1
780               DO ji = fs_2, fs_jpim1   ! vector opt.
781                  eps(ji,jj,jk) = rc04 * en(ji,jj,jk) * psi(ji,jj,jk) 
782               END DO
783            END DO
784         END DO
785         !
786      CASE( 3 )               ! generic
787         zcoef = rc0**( 3._wp  + rpp/rnn )
788         zex1  =      ( 1.5_wp + rmm/rnn )
789         zex2  = -1._wp / rnn
790         DO jk = 1, jpkm1
791            DO jj = 2, jpjm1
792               DO ji = fs_2, fs_jpim1   ! vector opt.
793                  eps(ji,jj,jk) = zcoef * en(ji,jj,jk)**zex1 * psi(ji,jj,jk)**zex2
794               END DO
795            END DO
796         END DO
797         !
798      END SELECT
799
800      ! Limit dissipation rate under stable stratification
801      ! --------------------------------------------------
802      DO jk = 1, jpkm1 ! Note that this set boundary conditions on mxln at the same time
803         DO jj = 2, jpjm1
804            DO ji = fs_2, fs_jpim1    ! vector opt.
805               ! limitation
806               eps(ji,jj,jk)  = MAX( eps(ji,jj,jk), rn_epsmin )
807               mxln(ji,jj,jk)  = rc03 * en(ji,jj,jk) * SQRT( en(ji,jj,jk) ) / eps(ji,jj,jk)
808               ! Galperin criterium (NOTE : Not required if the proper value of C3 in stable cases is calculated)
809               zrn2 = MAX( rn2(ji,jj,jk), rsmall )
810               IF (ln_length_lim) mxln(ji,jj,jk) = MIN(  rn_clim_galp * SQRT( 2._wp * en(ji,jj,jk) / zrn2 ), mxln(ji,jj,jk) )
811            END DO
812         END DO
813      END DO 
814
815      !
816      ! Stability function and vertical viscosity and diffusivity
817      ! ---------------------------------------------------------
818      !
819      SELECT CASE ( nn_stab_func )
820      !
821      CASE ( 0 , 1 )             ! Galperin or Kantha-Clayson stability functions
822         DO jk = 2, jpkm1
823            DO jj = 2, jpjm1
824               DO ji = fs_2, fs_jpim1   ! vector opt.
825                  ! zcof =  l²/q²
826                  zcof = mxlb(ji,jj,jk) * mxlb(ji,jj,jk) / ( 2._wp*eb(ji,jj,jk) )
827                  ! Gh = -N²l²/q²
828                  gh = - rn2(ji,jj,jk) * zcof
829                  gh = MIN( gh, rgh0   )
830                  gh = MAX( gh, rghmin )
831                  ! Stability functions from Kantha and Clayson (if C2=C3=0 => Galperin)
832                  sh = ra2*( 1._wp-6._wp*ra1/rb1 ) / ( 1.-3.*ra2*gh*(6.*ra1+rb2*( 1._wp-rc3 ) ) )
833                  sm = ( rb1**(-1._wp/3._wp) + ( 18._wp*ra1*ra1 + 9._wp*ra1*ra2*(1._wp-rc2) )*sh*gh ) / (1._wp-9._wp*ra1*ra2*gh)
834                  !
835                  ! Store stability function in avmu and avmv
836                  avmu(ji,jj,jk) = rc_diff * sh * tmask(ji,jj,jk)
837                  avmv(ji,jj,jk) = rc_diff * sm * tmask(ji,jj,jk)
838               END DO
839            END DO
840         END DO
841         !
842      CASE ( 2, 3 )               ! Canuto stability functions
843         DO jk = 2, jpkm1
844            DO jj = 2, jpjm1
845               DO ji = fs_2, fs_jpim1   ! vector opt.
846                  ! zcof =  l²/q²
847                  zcof = mxlb(ji,jj,jk)*mxlb(ji,jj,jk) / ( 2._wp * eb(ji,jj,jk) )
848                  ! Gh = -N²l²/q²
849                  gh = - rn2(ji,jj,jk) * zcof
850                  gh = MIN( gh, rgh0   )
851                  gh = MAX( gh, rghmin )
852                  gh = gh * rf6
853                  ! Gm =  M²l²/q² Shear number
854                  shr = shear(ji,jj,jk) / MAX( avm(ji,jj,jk), rsmall )
855                  gm = MAX( shr * zcof , 1.e-10 )
856                  gm = gm * rf6
857                  gm = MIN ( (rd0 - rd1*gh + rd3*gh*gh) / (rd2-rd4*gh) , gm )
858                  ! Stability functions from Canuto
859                  rcff = rd0 - rd1*gh +rd2*gm + rd3*gh*gh - rd4*gh*gm + rd5*gm*gm
860                  sm = (rs0 - rs1*gh + rs2*gm) / rcff
861                  sh = (rs4 - rs5*gh + rs6*gm) / rcff
862                  !
863                  ! Store stability function in avmu and avmv
864                  avmu(ji,jj,jk) = rc_diff * sh * tmask(ji,jj,jk)
865                  avmv(ji,jj,jk) = rc_diff * sm * tmask(ji,jj,jk)
866               END DO
867            END DO
868         END DO
869         !
870      END SELECT
871
872      ! Boundary conditions on stability functions for momentum (Neumann):
873      ! Lines below are useless if GOTM style Dirichlet conditions are used
874
875      avmv(:,:,1) = avmv(:,:,2)
876
877      DO jj = 2, jpjm1
878         DO ji = fs_2, fs_jpim1   ! vector opt.
879            avmv(ji,jj,mbkt(ji,jj)+1) = avmv(ji,jj,mbkt(ji,jj))
880         END DO
881      END DO
882
883      ! Compute diffusivities/viscosities
884      ! The computation below could be restrained to jk=2 to jpkm1 if GOTM style Dirichlet conditions are used
885      DO jk = 1, jpk
886         DO jj = 2, jpjm1
887            DO ji = fs_2, fs_jpim1   ! vector opt.
888               zsqen         = SQRT( 2._wp * en(ji,jj,jk) ) * mxln(ji,jj,jk)
889               zav           = zsqen * avmu(ji,jj,jk)
890               avt(ji,jj,jk) = MAX( zav, avtb(jk) )*tmask(ji,jj,jk) ! apply mask for zdfmxl routine
891               zav           = zsqen * avmv(ji,jj,jk)
892               avm(ji,jj,jk) = MAX( zav, avmb(jk) ) ! Note that avm is not masked at the surface and the bottom
893            END DO
894         END DO
895      END DO
896      !
897      ! Lateral boundary conditions (sign unchanged)
898      avt(:,:,1)  = 0._wp
899      CALL lbc_lnk( avm, 'W', 1. )   ;   CALL lbc_lnk( avt, 'W', 1. )
900
901      DO jk = 2, jpkm1            !* vertical eddy viscosity at u- and v-points
902         DO jj = 2, jpjm1
903            DO ji = fs_2, fs_jpim1   ! vector opt.
904               avmu(ji,jj,jk) = 0.5 * ( avm(ji,jj,jk) + avm(ji+1,jj  ,jk) ) * umask(ji,jj,jk)
905               avmv(ji,jj,jk) = 0.5 * ( avm(ji,jj,jk) + avm(ji  ,jj+1,jk) ) * vmask(ji,jj,jk)
906            END DO
907         END DO
908      END DO
909      avmu(:,:,1) = 0._wp             ;   avmv(:,:,1) = 0._wp                 ! set surface to zero
910      CALL lbc_lnk( avmu, 'U', 1. )   ;   CALL lbc_lnk( avmv, 'V', 1. )       ! Lateral boundary conditions
911
912      IF(ln_ctl) THEN
913         CALL prt_ctl( tab3d_1=en  , clinfo1=' gls  - e: ', tab3d_2=avt, clinfo2=' t: ', ovlap=1, kdim=jpk)
914         CALL prt_ctl( tab3d_1=avmu, clinfo1=' gls  - u: ', mask1=umask,                   &
915            &          tab3d_2=avmv, clinfo2=       ' v: ', mask2=vmask, ovlap=1, kdim=jpk )
916      ENDIF
917      !
918      avt_k (:,:,:) = avt (:,:,:)
919      avm_k (:,:,:) = avm (:,:,:)
920      avmu_k(:,:,:) = avmu(:,:,:)
921      avmv_k(:,:,:) = avmv(:,:,:)
922      !
923      CALL wrk_dealloc( jpi,jpj, zdep, zkar, zflxs, zhsro )
924      CALL wrk_dealloc( jpi,jpj,jpk, eb, mxlb, shear, eps, zwall_psi, z_elem_a, z_elem_b, z_elem_c, psi )
925      !
926      IF( nn_timing == 1 )  CALL timing_stop('zdf_gls')
927      !
928      !
929   END SUBROUTINE zdf_gls
930
931
932   SUBROUTINE zdf_gls_init
933      !!----------------------------------------------------------------------
934      !!                  ***  ROUTINE zdf_gls_init  ***
935      !!                     
936      !! ** Purpose :   Initialization of the vertical eddy diffivity and
937      !!      viscosity when using a gls turbulent closure scheme
938      !!
939      !! ** Method  :   Read the namzdf_gls namelist and check the parameters
940      !!      called at the first timestep (nit000)
941      !!
942      !! ** input   :   Namlist namzdf_gls
943      !!
944      !! ** Action  :   Increase by 1 the nstop flag is setting problem encounter
945      !!
946      !!----------------------------------------------------------------------
947      USE dynzdf_exp
948      USE trazdf_exp
949      !
950      INTEGER ::   jk    ! dummy loop indices
951      INTEGER ::   ios   ! Local integer output status for namelist read
952      REAL(wp)::   zcr   ! local scalar
953      !!
954      NAMELIST/namzdf_gls/rn_emin, rn_epsmin, ln_length_lim, &
955         &            rn_clim_galp, ln_sigpsi, rn_hsro,      &
956         &            rn_crban_default, rn_charn, rn_frac_hs,&
957         &            nn_bc_surf, nn_bc_bot, nn_z0_met,      &
958         &            nn_stab_func, nn_clos
959      !!----------------------------------------------------------
960      !
961      IF( nn_timing == 1 )  CALL timing_start('zdf_gls_init')
962      !
963      REWIND( numnam_ref )              ! Namelist namzdf_gls in reference namelist : Vertical eddy diffivity and viscosity using gls turbulent closure scheme
964      READ  ( numnam_ref, namzdf_gls, IOSTAT = ios, ERR = 901)
965901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_gls in reference namelist', lwp )
966
967      REWIND( numnam_cfg )              ! Namelist namzdf_gls in configuration namelist : Vertical eddy diffivity and viscosity using gls turbulent closure scheme
968      READ  ( numnam_cfg, namzdf_gls, IOSTAT = ios, ERR = 902 )
969902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_gls in configuration namelist', lwp )
970      IF(lwm) WRITE ( numond, namzdf_gls )
971
972      IF(lwp) THEN                     !* Control print
973         WRITE(numout,*)
974         WRITE(numout,*) 'zdf_gls_init : gls turbulent closure scheme'
975         WRITE(numout,*) '~~~~~~~~~~~~'
976         WRITE(numout,*) '   Namelist namzdf_gls : set gls mixing parameters'
977         WRITE(numout,*) '      minimum value of en                           rn_emin        = ', rn_emin
978         WRITE(numout,*) '      minimum value of eps                          rn_epsmin      = ', rn_epsmin
979         WRITE(numout,*) '      Limit dissipation rate under stable stratif.  ln_length_lim  = ', ln_length_lim
980         WRITE(numout,*) '      Galperin limit (Standard: 0.53, Holt: 0.26)   rn_clim_galp   = ', rn_clim_galp
981         WRITE(numout,*) '      TKE Surface boundary condition                nn_bc_surf     = ', nn_bc_surf
982         WRITE(numout,*) '      TKE Bottom boundary condition                 nn_bc_bot      = ', nn_bc_bot
983         WRITE(numout,*) '      Modify psi Schmidt number (wb case)           ln_sigpsi      = ', ln_sigpsi
984         WRITE(numout,*) '      Craig and Banner coefficient (default)        rn_crban       = ', rn_crban_default
985         WRITE(numout,*) '      Charnock coefficient                          rn_charn       = ', rn_charn
986         WRITE(numout,*) '      Surface roughness formula                     nn_z0_met      = ', nn_z0_met
987         WRITE(numout,*) '      Wave height frac. (used if nn_z0_met=2)       rn_frac_hs     = ', rn_frac_hs
988         WRITE(numout,*) '      Stability functions                           nn_stab_func   = ', nn_stab_func
989         WRITE(numout,*) '      Type of closure                               nn_clos        = ', nn_clos
990         WRITE(numout,*) '      Surface roughness (m)                         rn_hsro        = ', rn_hsro
991         WRITE(numout,*) '      Bottom roughness (m) (nambfr namelist)        rn_bfrz0       = ', rn_bfrz0
992      ENDIF
993
994      !                                !* allocate gls arrays
995      IF( zdf_gls_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'zdf_gls_init : unable to allocate arrays' )
996
997      !                                !* Check of some namelist values
998      IF( nn_bc_surf < 0 .OR. nn_bc_surf > 1 ) CALL ctl_stop( 'zdf_gls_init: bad flag: nn_bc_surf is 0 or 1' ) 
999      IF( nn_bc_surf < 0 .OR. nn_bc_surf > 1 ) CALL ctl_stop( 'zdf_gls_init: bad flag: nn_bc_surf is 0 or 1' ) 
1000      IF( nn_z0_met < 0 .OR. nn_z0_met > 3 ) CALL ctl_stop( 'zdf_gls_init: bad flag: nn_z0_met is 0, 1, 2 or 3' ) 
1001      IF( nn_z0_met == 3 .AND. .NOT.ln_sdw ) CALL ctl_stop( 'zdf_gls_init: nn_z0_met=3 requires ln_sdw=T' ) 
1002      IF( nn_stab_func  < 0 .OR. nn_stab_func  > 3 ) CALL ctl_stop( 'zdf_gls_init: bad flag: nn_stab_func is 0, 1, 2 and 3' ) 
1003      IF( nn_clos       < 0 .OR. nn_clos       > 3 ) CALL ctl_stop( 'zdf_gls_init: bad flag: nn_clos is 0, 1, 2 or 3' )
1004
1005      SELECT CASE ( nn_clos )          !* set the parameters for the chosen closure
1006      !
1007      CASE( 0 )                              ! k-kl  (Mellor-Yamada)
1008         !
1009         IF(lwp) WRITE(numout,*) 'The choosen closure is k-kl closed to the classical Mellor-Yamada'
1010         rpp     = 0._wp
1011         rmm     = 1._wp
1012         rnn     = 1._wp
1013         rsc_tke = 1.96_wp
1014         rsc_psi = 1.96_wp
1015         rpsi1   = 0.9_wp
1016         rpsi3p  = 1._wp
1017         rpsi2   = 0.5_wp
1018         !
1019         SELECT CASE ( nn_stab_func )
1020         CASE( 0, 1 )   ;   rpsi3m = 2.53_wp       ! G88 or KC stability functions
1021         CASE( 2 )      ;   rpsi3m = 2.62_wp       ! Canuto A stability functions
1022         CASE( 3 )      ;   rpsi3m = 2.38          ! Canuto B stability functions (caution : constant not identified)
1023         END SELECT
1024         !
1025      CASE( 1 )                              ! k-eps
1026         !
1027         IF(lwp) WRITE(numout,*) 'The choosen closure is k-eps'
1028         rpp     =  3._wp
1029         rmm     =  1.5_wp
1030         rnn     = -1._wp
1031         rsc_tke =  1._wp
1032         rsc_psi =  1.2_wp  ! Schmidt number for psi
1033         rpsi1   =  1.44_wp
1034         rpsi3p  =  1._wp
1035         rpsi2   =  1.92_wp
1036         !
1037         SELECT CASE ( nn_stab_func )
1038         CASE( 0, 1 )   ;   rpsi3m = -0.52_wp      ! G88 or KC stability functions
1039         CASE( 2 )      ;   rpsi3m = -0.629_wp     ! Canuto A stability functions
1040         CASE( 3 )      ;   rpsi3m = -0.566        ! Canuto B stability functions
1041         END SELECT
1042         !
1043      CASE( 2 )                              ! k-omega
1044         !
1045         IF(lwp) WRITE(numout,*) 'The choosen closure is k-omega'
1046         rpp     = -1._wp
1047         rmm     =  0.5_wp
1048         rnn     = -1._wp
1049         rsc_tke =  2._wp
1050         rsc_psi =  2._wp
1051         rpsi1   =  0.555_wp
1052         rpsi3p  =  1._wp
1053         rpsi2   =  0.833_wp
1054         !
1055         SELECT CASE ( nn_stab_func )
1056         CASE( 0, 1 )   ;   rpsi3m = -0.58_wp       ! G88 or KC stability functions
1057         CASE( 2 )      ;   rpsi3m = -0.64_wp       ! Canuto A stability functions
1058         CASE( 3 )      ;   rpsi3m = -0.64_wp       ! Canuto B stability functions caution : constant not identified)
1059         END SELECT
1060         !
1061      CASE( 3 )                              ! generic
1062         !
1063         IF(lwp) WRITE(numout,*) 'The choosen closure is generic'
1064         rpp     = 2._wp
1065         rmm     = 1._wp
1066         rnn     = -0.67_wp
1067         rsc_tke = 0.8_wp
1068         rsc_psi = 1.07_wp
1069         rpsi1   = 1._wp
1070         rpsi3p  = 1._wp
1071         rpsi2   = 1.22_wp
1072         !
1073         SELECT CASE ( nn_stab_func )
1074         CASE( 0, 1 )   ;   rpsi3m = 0.1_wp         ! G88 or KC stability functions
1075         CASE( 2 )      ;   rpsi3m = 0.05_wp        ! Canuto A stability functions
1076         CASE( 3 )      ;   rpsi3m = 0.05_wp        ! Canuto B stability functions caution : constant not identified)
1077         END SELECT
1078         !
1079      END SELECT
1080
1081      !
1082      SELECT CASE ( nn_stab_func )     !* set the parameters of the stability functions
1083      !
1084      CASE ( 0 )                             ! Galperin stability functions
1085         !
1086         IF(lwp) WRITE(numout,*) 'Stability functions from Galperin'
1087         rc2     =  0._wp
1088         rc3     =  0._wp
1089         rc_diff =  1._wp
1090         rc0     =  0.5544_wp
1091         rcm_sf  =  0.9884_wp
1092         rghmin  = -0.28_wp
1093         rgh0    =  0.0233_wp
1094         rghcri  =  0.02_wp
1095         !
1096      CASE ( 1 )                             ! Kantha-Clayson stability functions
1097         !
1098         IF(lwp) WRITE(numout,*) 'Stability functions from Kantha-Clayson'
1099         rc2     =  0.7_wp
1100         rc3     =  0.2_wp
1101         rc_diff =  1._wp
1102         rc0     =  0.5544_wp
1103         rcm_sf  =  0.9884_wp
1104         rghmin  = -0.28_wp
1105         rgh0    =  0.0233_wp
1106         rghcri  =  0.02_wp
1107         !
1108      CASE ( 2 )                             ! Canuto A stability functions
1109         !
1110         IF(lwp) WRITE(numout,*) 'Stability functions from Canuto A'
1111         rs0 = 1.5_wp * rl1 * rl5*rl5
1112         rs1 = -rl4*(rl6+rl7) + 2._wp*rl4*rl5*(rl1-(1._wp/3._wp)*rl2-rl3) + 1.5_wp*rl1*rl5*rl8
1113         rs2 = -(3._wp/8._wp) * rl1*(rl6*rl6-rl7*rl7)
1114         rs4 = 2._wp * rl5
1115         rs5 = 2._wp * rl4
1116         rs6 = (2._wp/3._wp) * rl5 * ( 3._wp*rl3*rl3 - rl2*rl2 ) - 0.5_wp * rl5*rl1 * (3._wp*rl3-rl2)   &
1117            &                                                    + 0.75_wp * rl1 * ( rl6 - rl7 )
1118         rd0 = 3._wp * rl5*rl5
1119         rd1 = rl5 * ( 7._wp*rl4 + 3._wp*rl8 )
1120         rd2 = rl5*rl5 * ( 3._wp*rl3*rl3 - rl2*rl2 ) - 0.75_wp*(rl6*rl6 - rl7*rl7 )
1121         rd3 = rl4 * ( 4._wp*rl4 + 3._wp*rl8)
1122         rd4 = rl4 * ( rl2 * rl6 - 3._wp*rl3*rl7 - rl5*(rl2*rl2 - rl3*rl3 ) ) + rl5*rl8 * ( 3._wp*rl3*rl3 - rl2*rl2 )
1123         rd5 = 0.25_wp * ( rl2*rl2 - 3._wp *rl3*rl3 ) * ( rl6*rl6 - rl7*rl7 )
1124         rc0 = 0.5268_wp
1125         rf6 = 8._wp / (rc0**6._wp)
1126         rc_diff = SQRT(2._wp) / (rc0**3._wp)
1127         rcm_sf  =  0.7310_wp
1128         rghmin  = -0.28_wp
1129         rgh0    =  0.0329_wp
1130         rghcri  =  0.03_wp
1131         !
1132      CASE ( 3 )                             ! Canuto B stability functions
1133         !
1134         IF(lwp) WRITE(numout,*) 'Stability functions from Canuto B'
1135         rs0 = 1.5_wp * rm1 * rm5*rm5
1136         rs1 = -rm4 * (rm6+rm7) + 2._wp * rm4*rm5*(rm1-(1._wp/3._wp)*rm2-rm3) + 1.5_wp * rm1*rm5*rm8
1137         rs2 = -(3._wp/8._wp) * rm1 * (rm6*rm6-rm7*rm7 )
1138         rs4 = 2._wp * rm5
1139         rs5 = 2._wp * rm4
1140         rs6 = (2._wp/3._wp) * rm5 * (3._wp*rm3*rm3-rm2*rm2) - 0.5_wp * rm5*rm1*(3._wp*rm3-rm2) + 0.75_wp * rm1*(rm6-rm7)
1141         rd0 = 3._wp * rm5*rm5
1142         rd1 = rm5 * (7._wp*rm4 + 3._wp*rm8)
1143         rd2 = rm5*rm5 * (3._wp*rm3*rm3 - rm2*rm2) - 0.75_wp * (rm6*rm6 - rm7*rm7)
1144         rd3 = rm4 * ( 4._wp*rm4 + 3._wp*rm8 )
1145         rd4 = rm4 * ( rm2*rm6 -3._wp*rm3*rm7 - rm5*(rm2*rm2 - rm3*rm3) ) + rm5 * rm8 * ( 3._wp*rm3*rm3 - rm2*rm2 )
1146         rd5 = 0.25_wp * ( rm2*rm2 - 3._wp*rm3*rm3 ) * ( rm6*rm6 - rm7*rm7 )
1147         rc0 = 0.5268_wp            !!       rc0 = 0.5540_wp (Warner ...) to verify !
1148         rf6 = 8._wp / ( rc0**6._wp )
1149         rc_diff = SQRT(2._wp)/(rc0**3.)
1150         rcm_sf  =  0.7470_wp
1151         rghmin  = -0.28_wp
1152         rgh0    =  0.0444_wp
1153         rghcri  =  0.0414_wp
1154         !
1155      END SELECT
1156   
1157      !                                !* Set Schmidt number for psi diffusion in the wave breaking case
1158      !                                     ! See Eq. (13) of Carniel et al, OM, 30, 225-239, 2009
1159      !                                     !  or Eq. (17) of Burchard, JPO, 31, 3133-3145, 2001
1160      IF( ln_sigpsi ) THEN
1161         ra_sf = -1.5 ! Set kinetic energy slope, then deduce rsc_psi and rl_sf
1162         ! Verification: retrieve Burchard (2001) results by uncomenting the line below:
1163         ! Note that the results depend on the value of rn_cm_sf which is constant (=rc0) in his work
1164         ! ra_sf = -SQRT(2./3.*rc0**3./rn_cm_sf*rn_sc_tke)/vkarmn
1165         rsc_psi0 = rsc_tke/(24.*rpsi2)*(-1.+(4.*rnn + ra_sf*(1.+4.*rmm))**2./(ra_sf**2.))
1166      ELSE
1167         rsc_psi0 = rsc_psi
1168      ENDIF
1169 
1170      !                                !* Shear free turbulence parameters
1171      !
1172      ra_sf  = -4._wp*rnn*SQRT(rsc_tke) / ( (1._wp+4._wp*rmm)*SQRT(rsc_tke) &
1173               &                              - SQRT(rsc_tke + 24._wp*rsc_psi0*rpsi2 ) )
1174
1175      IF( .NOT. ln_phioc .AND. rn_crban_default==0._wp ) THEN
1176         rl_sf = vkarmn
1177      ELSE
1178         rl_sf = rc0 * SQRT(rc0/rcm_sf) * SQRT( ( (1._wp + 4._wp*rmm + 8._wp*rmm**2_wp)*rsc_tke          &
1179                 &                                       + 12._wp * rsc_psi0*rpsi2 - (1._wp + 4._wp*rmm) &
1180                 &                                                *SQRT(rsc_tke*(rsc_tke                 &
1181                 &                                                   + 24._wp*rsc_psi0*rpsi2)) )         &
1182                 &                                         /(12._wp*rnn**2.)                             &
1183                 &                                       )
1184      ENDIF
1185
1186      !
1187      IF(lwp) THEN                     !* Control print
1188         WRITE(numout,*)
1189         WRITE(numout,*) 'Limit values'
1190         WRITE(numout,*) '~~~~~~~~~~~~'
1191         WRITE(numout,*) 'Parameter  m = ',rmm
1192         WRITE(numout,*) 'Parameter  n = ',rnn
1193         WRITE(numout,*) 'Parameter  p = ',rpp
1194         WRITE(numout,*) 'rpsi1   = ',rpsi1
1195         WRITE(numout,*) 'rpsi2   = ',rpsi2
1196         WRITE(numout,*) 'rpsi3m  = ',rpsi3m
1197         WRITE(numout,*) 'rpsi3p  = ',rpsi3p
1198         WRITE(numout,*) 'rsc_tke = ',rsc_tke
1199         WRITE(numout,*) 'rsc_psi = ',rsc_psi
1200         WRITE(numout,*) 'rsc_psi0 = ',rsc_psi0
1201         WRITE(numout,*) 'rc0     = ',rc0
1202         WRITE(numout,*)
1203         WRITE(numout,*) 'Shear free turbulence parameters:'
1204         WRITE(numout,*) 'rcm_sf  = ',rcm_sf
1205         WRITE(numout,*) 'ra_sf   = ',ra_sf
1206         WRITE(numout,*) 'rl_sf   = ',rl_sf
1207         WRITE(numout,*)
1208      ENDIF
1209
1210      !                                !* Constants initialization
1211      rc02  = rc0  * rc0   ;   rc02r = 1. / rc02
1212      rc03  = rc02 * rc0
1213      rc04  = rc03 * rc0
1214      rsbc_tke1_default = -3._wp/2._wp*rn_crban_default*ra_sf*rl_sf
1215      rsbc_tke2         = rdt * rn_crban_default / rl_sf
1216      zcr               = MAX( rsmall, rsbc_tke1_default**(1./(-ra_sf*3._wp/2._wp))-1._wp )
1217      rtrans            = 0.2_wp / zcr
1218      rsbc_zs1  = rn_charn/grav                                          ! Charnock formula for surface roughness
1219      rsbc_zs2  = rn_frac_hs / 0.85_wp / grav * 665._wp                  ! Rascle formula for surface roughness
1220      rsbc_psi1 = -0.5_wp * rdt * rc0**(rpp-2._wp*rmm) / rsc_psi
1221      rsbc_psi2 = -0.5_wp * rdt * rc0**rpp * rnn * vkarmn**rnn / rsc_psi ! Neumann + NO Wave breaking
1222
1223      rfact_tke = -0.5_wp / rsc_tke * rdt                                ! Cst used for the Diffusion term of tke
1224      rfact_psi = -0.5_wp / rsc_psi * rdt                                ! Cst used for the Diffusion term of tke
1225
1226      !                                !* Wall proximity function
1227      zwall (:,:,:) = 1._wp * tmask(:,:,:)
1228
1229      !                                !* set vertical eddy coef. to the background value
1230      DO jk = 1, jpk
1231         avt (:,:,jk) = avtb(jk) * tmask(:,:,jk)
1232         avm (:,:,jk) = avmb(jk) * tmask(:,:,jk)
1233         avmu(:,:,jk) = avmb(jk) * umask(:,:,jk)
1234         avmv(:,:,jk) = avmb(jk) * vmask(:,:,jk)
1235      END DO
1236      !                             
1237      CALL gls_rst( nit000, 'READ' )   !* read or initialize all required files
1238      !
1239      IF( nn_timing == 1 )  CALL timing_stop('zdf_gls_init')
1240      !
1241   END SUBROUTINE zdf_gls_init
1242
1243
1244   SUBROUTINE gls_rst( kt, cdrw )
1245      !!---------------------------------------------------------------------
1246      !!                   ***  ROUTINE ts_rst  ***
1247      !!                     
1248      !! ** Purpose :   Read or write TKE file (en) in restart file
1249      !!
1250      !! ** Method  :   use of IOM library
1251      !!                if the restart does not contain TKE, en is either
1252      !!                set to rn_emin or recomputed (nn_igls/=0)
1253      !!----------------------------------------------------------------------
1254      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
1255      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
1256      !
1257      INTEGER ::   jit, jk   ! dummy loop indices
1258      INTEGER ::   id1, id2, id3, id4, id5, id6
1259      INTEGER ::   ji, jj, ikbu, ikbv
1260      REAL(wp)::   cbx, cby
1261      !!----------------------------------------------------------------------
1262      !
1263      IF( TRIM(cdrw) == 'READ' ) THEN        ! Read/initialise
1264         !                                   ! ---------------
1265         IF( ln_rstart ) THEN                   !* Read the restart file
1266            id1 = iom_varid( numror, 'en'   , ldstop = .FALSE. )
1267            id2 = iom_varid( numror, 'avt'  , ldstop = .FALSE. )
1268            id3 = iom_varid( numror, 'avm'  , ldstop = .FALSE. )
1269            id4 = iom_varid( numror, 'avmu' , ldstop = .FALSE. )
1270            id5 = iom_varid( numror, 'avmv' , ldstop = .FALSE. )
1271            id6 = iom_varid( numror, 'mxln' , ldstop = .FALSE. )
1272            !
1273            IF( MIN( id1, id2, id3, id4, id5, id6 ) > 0 ) THEN        ! all required arrays exist
1274               CALL iom_get( numror, jpdom_autoglo, 'en'    , en     )
1275               CALL iom_get( numror, jpdom_autoglo, 'avt'   , avt    )
1276               CALL iom_get( numror, jpdom_autoglo, 'avm'   , avm    )
1277               CALL iom_get( numror, jpdom_autoglo, 'avmu'  , avmu   )
1278               CALL iom_get( numror, jpdom_autoglo, 'avmv'  , avmv   )
1279               CALL iom_get( numror, jpdom_autoglo, 'mxln'  , mxln   )
1280            ELSE                       
1281               IF(lwp) WRITE(numout,*) ' ===>>>> : previous run without gls scheme, en and mxln computed by iterative loop'
1282               en  (:,:,:) = rn_emin
1283               mxln(:,:,:) = 0.05       
1284               avt_k (:,:,:) = avt (:,:,:)
1285               avm_k (:,:,:) = avm (:,:,:)
1286               avmu_k(:,:,:) = avmu(:,:,:)
1287               avmv_k(:,:,:) = avmv(:,:,:)
1288               DO jit = nit000 + 1, nit000 + 10   ;   CALL zdf_gls( jit )   ;   END DO
1289            ENDIF
1290         ELSE                                   !* Start from rest
1291            IF(lwp) WRITE(numout,*) ' ===>>>> : Initialisation of en and mxln by background values'
1292            en  (:,:,:) = rn_emin
1293            mxln(:,:,:) = 0.05       
1294         ENDIF
1295         !
1296      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN   ! Create restart file
1297         !                                   ! -------------------
1298         IF(lwp) WRITE(numout,*) '---- gls-rst ----'
1299         CALL iom_rstput( kt, nitrst, numrow, 'en'   , en     ) 
1300         CALL iom_rstput( kt, nitrst, numrow, 'avt'  , avt_k  )
1301         CALL iom_rstput( kt, nitrst, numrow, 'avm'  , avm_k  )
1302         CALL iom_rstput( kt, nitrst, numrow, 'avmu' , avmu_k ) 
1303         CALL iom_rstput( kt, nitrst, numrow, 'avmv' , avmv_k )
1304         CALL iom_rstput( kt, nitrst, numrow, 'mxln' , mxln   )
1305         !
1306      ENDIF
1307      !
1308   END SUBROUTINE gls_rst
1309
1310#else
1311   !!----------------------------------------------------------------------
1312   !!   Dummy module :                                        NO TKE scheme
1313   !!----------------------------------------------------------------------
1314   LOGICAL, PUBLIC, PARAMETER ::   lk_zdfgls = .FALSE.   !: TKE flag
1315CONTAINS
1316   SUBROUTINE zdf_gls_init           ! Empty routine
1317      WRITE(*,*) 'zdf_gls_init: You should not have seen this print! error?'
1318   END SUBROUTINE zdf_gls_init
1319   SUBROUTINE zdf_gls( kt )          ! Empty routine
1320      WRITE(*,*) 'zdf_gls: You should not have seen this print! error?', kt
1321   END SUBROUTINE zdf_gls
1322   SUBROUTINE gls_rst( kt, cdrw )          ! Empty routine
1323      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
1324      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
1325      WRITE(*,*) 'gls_rst: You should not have seen this print! error?', kt, cdrw
1326   END SUBROUTINE gls_rst
1327#endif
1328
1329   !!======================================================================
1330END MODULE zdfgls
1331
Note: See TracBrowser for help on using the repository browser.