New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zdfgls.F90 in branches/UKMO/r6232_HZG_WAVE-coupling/NEMOGCM/NEMO/OPA_SRC/ZDF – NEMO

source: branches/UKMO/r6232_HZG_WAVE-coupling/NEMOGCM/NEMO/OPA_SRC/ZDF/zdfgls.F90 @ 7853

Last change on this file since 7853 was 7853, checked in by jcastill, 7 years ago

Add the original Craig and Banner vertical mixing scheme in case of wave coupling - further checks on wave forcing fields in case the ocean and wave land/sea masks are not the same
File size: 67.8 KB
Line 
1MODULE zdfgls
2   !!======================================================================
3   !!                       ***  MODULE  zdfgls  ***
4   !! Ocean physics:  vertical mixing coefficient computed from the gls
5   !!                 turbulent closure parameterization
6   !!======================================================================
7   !! History :   3.0  !  2009-09  (G. Reffray)  Original code
8   !!             3.3  !  2010-10  (C. Bricaud)  Add in the reference
9   !!----------------------------------------------------------------------
10#if defined key_zdfgls   ||   defined key_esopa
11   !!----------------------------------------------------------------------
12   !!   'key_zdfgls'                 Generic Length Scale vertical physics
13   !!----------------------------------------------------------------------
14   !!   zdf_gls       : update momentum and tracer Kz from a gls scheme
15   !!   zdf_gls_init  : initialization, namelist read, and parameters control
16   !!   gls_rst       : read/write gls restart in ocean restart file
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE dom_oce        ! ocean space and time domain
20   USE domvvl         ! ocean space and time domain : variable volume layer
21   USE zdf_oce        ! ocean vertical physics
22   USE zdfbfr         ! bottom friction (only for rn_bfrz0)
23   USE sbc_oce        ! surface boundary condition: ocean
24   USE phycst         ! physical constants
25   USE zdfmxl         ! mixed layer
26   USE sbcwave, ONLY: hsw,rn_crban
27   !
28   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
29   USE lib_mpp        ! MPP manager
30   USE wrk_nemo       ! work arrays
31   USE prtctl         ! Print control
32   USE in_out_manager ! I/O manager
33   USE iom            ! I/O manager library
34   USE timing         ! Timing
35   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
36
37   IMPLICIT NONE
38   PRIVATE
39
40   PUBLIC   zdf_gls        ! routine called in step module
41   PUBLIC   zdf_gls_init   ! routine called in opa module
42   PUBLIC   gls_rst        ! routine called in step module
43
44   LOGICAL , PUBLIC, PARAMETER ::   lk_zdfgls = .TRUE.   !: TKE vertical mixing flag
45   !
46   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   mxln    !: now mixing length
47   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   zwall   !: wall function
48   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   ustars2 !: Squared surface velocity scale at T-points
49   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   ustarb2 !: Squared bottom  velocity scale at T-points
50
51   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   rsbc_tke1
52   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   rsbc_tke3
53   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   rsbc_psi1
54   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   rtrans
55
56   !                              !! ** Namelist  namzdf_gls  **
57   LOGICAL  ::   ln_length_lim     ! use limit on the dissipation rate under stable stratification (Galperin et al. 1988)
58   LOGICAL  ::   ln_sigpsi         ! Activate Burchard (2003) modification for k-eps closure & wave breaking mixing
59   INTEGER  ::   nn_bc_surf        ! surface boundary condition (=0/1)
60   INTEGER  ::   nn_bc_bot         ! bottom boundary condition (=0/1)
61   INTEGER  ::   nn_z0_met         ! Method for surface roughness computation
62   INTEGER  ::   nn_stab_func      ! stability functions G88, KC or Canuto (=0/1/2)
63   INTEGER  ::   nn_clos           ! closure 0/1/2/3 MY82/k-eps/k-w/gen
64   INTEGER  ::   nn_wmix           ! type of wave breaking mixing
65   INTEGER, PUBLIC, PARAMETER ::   jp_craigbanner = 0   ! Craig and Banner formulation (original NEMO formulation -
66                                                        !    direct conversion of mechanical to turbulent energy)
67   INTEGER, PUBLIC, PARAMETER ::   jp_janssen     = 1   ! Janssen formulation - no assumption on direct energy conversion
68   REAL(wp) ::   rn_clim_galp      ! Holt 2008 value for k-eps: 0.267
69   REAL(wp) ::   rn_epsmin         ! minimum value of dissipation (m2/s3)
70   REAL(wp) ::   rn_emin           ! minimum value of TKE (m2/s2)
71   REAL(wp) ::   rn_charn          ! Charnock constant for surface breaking waves mixing : 1400. (standard) or 2.e5 (Stacey value)
72   REAL(wp) ::   rn_crban_default  ! Craig and Banner constant for surface breaking waves mixing
73   REAL(wp) ::   rn_hsro           ! Minimum surface roughness
74   REAL(wp) ::   rn_frac_hs        ! Fraction of wave height as surface roughness (if nn_z0_met = 1)
75
76   REAL(wp) ::   rcm_sf        =  0.73_wp     ! Shear free turbulence parameters
77   REAL(wp) ::   ra_sf         = -2.0_wp      ! Must be negative -2 < ra_sf < -1
78   REAL(wp) ::   rl_sf         =  0.2_wp      ! 0 <rl_sf<vkarmn   
79   REAL(wp) ::   rghmin        = -0.28_wp
80   REAL(wp) ::   rgh0          =  0.0329_wp
81   REAL(wp) ::   rghcri        =  0.03_wp
82   REAL(wp) ::   ra1           =  0.92_wp
83   REAL(wp) ::   ra2           =  0.74_wp
84   REAL(wp) ::   rb1           = 16.60_wp
85   REAL(wp) ::   rb2           = 10.10_wp         
86   REAL(wp) ::   re2           =  1.33_wp         
87   REAL(wp) ::   rl1           =  0.107_wp
88   REAL(wp) ::   rl2           =  0.0032_wp
89   REAL(wp) ::   rl3           =  0.0864_wp
90   REAL(wp) ::   rl4           =  0.12_wp
91   REAL(wp) ::   rl5           = 11.9_wp
92   REAL(wp) ::   rl6           =  0.4_wp
93   REAL(wp) ::   rl7           =  0.0_wp
94   REAL(wp) ::   rl8           =  0.48_wp
95   REAL(wp) ::   rm1           =  0.127_wp
96   REAL(wp) ::   rm2           =  0.00336_wp
97   REAL(wp) ::   rm3           =  0.0906_wp
98   REAL(wp) ::   rm4           =  0.101_wp
99   REAL(wp) ::   rm5           = 11.2_wp
100   REAL(wp) ::   rm6           =  0.4_wp
101   REAL(wp) ::   rm7           =  0.0_wp
102   REAL(wp) ::   rm8           =  0.318_wp
103   REAL(wp) ::   rtrans_default =  0.1_wp
104   REAL(wp) ::   rc02, rc02r, rc03, rc04                          ! coefficients deduced from above parameters
105   REAL(wp) ::   rsbc_tke1_default, rsbc_tke2, rfact_tke          !     -           -           -        -
106   REAL(wp) ::   rsbc_psi2, rsbc_psi3, rfact_psi                  !     -           -           -        -
107   REAL(wp) ::   rsbc_zs1, rsbc_zs2                               !     -           -           -        -
108   REAL(wp) ::   rc0, rc2, rc3, rf6, rcff, rc_diff                !     -           -           -        -
109   REAL(wp) ::   rs0, rs1, rs2, rs4, rs5, rs6                     !     -           -           -        -
110   REAL(wp) ::   rd0, rd1, rd2, rd3, rd4, rd5                     !     -           -           -        -
111   REAL(wp) ::   rsc_tke, rsc_psi, rpsi1, rpsi2, rpsi3, rsc_psi0  !     -           -           -        -
112   REAL(wp) ::   rpsi3m, rpsi3p, rpp, rmm, rnn                    !     -           -           -        -
113
114   !! * Substitutions
115#  include "domzgr_substitute.h90"
116#  include "vectopt_loop_substitute.h90"
117   !!----------------------------------------------------------------------
118   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
119   !! $Id$
120   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
121   !!----------------------------------------------------------------------
122CONTAINS
123
124   INTEGER FUNCTION zdf_gls_alloc()
125      !!----------------------------------------------------------------------
126      !!                ***  FUNCTION zdf_gls_alloc  ***
127      !!----------------------------------------------------------------------
128      ALLOCATE( mxln(jpi,jpj,jpk) , zwall(jpi,jpj,jpk) ,     &
129         &      ustars2(jpi,jpj)  , ustarb2(jpi,jpj)   ,     &
130         &      rsbc_tke1(jpi,jpj), rsbc_tke3(jpi,jpj) ,     &
131         &      rsbc_psi1(jpi,jpj), rtrans(jpi,jpj), STAT= zdf_gls_alloc )
132         !
133      IF( lk_mpp             )   CALL mpp_sum ( zdf_gls_alloc )
134      IF( zdf_gls_alloc /= 0 )   CALL ctl_warn('zdf_gls_alloc: failed to allocate arrays')
135   END FUNCTION zdf_gls_alloc
136
137
138   SUBROUTINE zdf_gls( kt )
139      !!----------------------------------------------------------------------
140      !!                   ***  ROUTINE zdf_gls  ***
141      !!
142      !! ** Purpose :   Compute the vertical eddy viscosity and diffusivity
143      !!              coefficients using the GLS turbulent closure scheme.
144      !!----------------------------------------------------------------------
145      INTEGER, INTENT(in) ::   kt ! ocean time step
146      INTEGER  ::   ji, jj, jk, ibot, ibotm1, dir  ! dummy loop arguments
147      REAL(wp) ::   zesh2, zsigpsi, zcoef, zex1, zex2   ! local scalars
148      REAL(wp) ::   ztx2, zty2, zup, zdown, zcof        !   -      -
149      REAL(wp) ::   zratio, zrn2, zflxb, sh             !   -      -
150      REAL(wp) ::   prod, buoy, diss, zdiss, sm         !   -      -
151      REAL(wp) ::   gh, gm, shr, dif, zsqen, zav        !   -      -
152      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zdep
153      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zkar
154      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zflxs       ! Turbulence fluxed induced by internal waves
155      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zhsro       ! Surface roughness (surface waves)
156      REAL(wp), POINTER, DIMENSION(:,:,:) ::   eb          ! tke at time before
157      REAL(wp), POINTER, DIMENSION(:,:,:) ::   mxlb        ! mixing length at time before
158      REAL(wp), POINTER, DIMENSION(:,:,:) ::   shear       ! vertical shear
159      REAL(wp), POINTER, DIMENSION(:,:,:) ::   eps         ! dissipation rate
160      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zwall_psi   ! Wall function use in the wb case (ln_sigpsi)
161      REAL(wp), POINTER, DIMENSION(:,:,:) ::   psi         ! psi at time now
162      REAL(wp), POINTER, DIMENSION(:,:,:) ::   z_elem_a    ! element of the first  matrix diagonal
163      REAL(wp), POINTER, DIMENSION(:,:,:) ::   z_elem_b    ! element of the second matrix diagonal
164      REAL(wp), POINTER, DIMENSION(:,:,:) ::   z_elem_c    ! element of the third  matrix diagonal
165      !!--------------------------------------------------------------------
166      !
167      IF( nn_timing == 1 )  CALL timing_start('zdf_gls')
168      !
169      CALL wrk_alloc( jpi,jpj, zdep, zkar, zflxs, zhsro )
170      CALL wrk_alloc( jpi,jpj,jpk, eb, mxlb, shear, eps, zwall_psi, z_elem_a, z_elem_b, z_elem_c, psi  )
171     
172      ! Preliminary computing
173
174      ustars2 = 0._wp   ;   ustarb2 = 0._wp   ;   psi  = 0._wp   ;   zwall_psi = 0._wp
175
176
177      ! variable initialization
178      IF( ln_phioc ) THEN
179         IF( nn_wmix==jp_janssen ) THEN
180            rsbc_tke1(:,:) = (-rsc_tke*rn_crban(:,:)/(rcm_sf*ra_sf*rl_sf))**(2._wp/3._wp)  ! k_eps = 53.Dirichlet + Wave breaking
181            rsbc_tke3(:,:) = rdt * rn_crban(:,:)                                           ! Neumann + Wave breaking
182            rsbc_psi1(:,:) = rc0**rpp * rsbc_tke1(:,:)**rmm * rl_sf**rnn                   ! Dirichlet + Wave breaking
183         ELSE
184            rsbc_tke1(:,:) = -3._wp/2._wp*rn_crban(:,:)*ra_sf*rl_sf
185            rsbc_tke3(:,:) = rdt * rn_crban(:,:) / rl_sf
186            rtrans(:,:) = 0.2_wp / MAX( rsmall, rsbc_tke1(:,:)**(1./(-ra_sf*3._wp/2._wp))-1._wp )
187         ENDIF
188      ENDIF
189
190      IF( kt /= nit000 ) THEN   ! restore before value to compute tke
191         avt (:,:,:) = avt_k (:,:,:)
192         avm (:,:,:) = avm_k (:,:,:)
193         avmu(:,:,:) = avmu_k(:,:,:)
194         avmv(:,:,:) = avmv_k(:,:,:) 
195      ENDIF
196
197      ! Compute surface and bottom friction at T-points
198!CDIR NOVERRCHK         
199      DO jj = 2, jpjm1         
200!CDIR NOVERRCHK         
201         DO ji = fs_2, fs_jpim1   ! vector opt.         
202            !
203            ! surface friction
204            ustars2(ji,jj) = r1_rau0 * taum(ji,jj) * tmask(ji,jj,1)
205            !   
206            ! bottom friction (explicit before friction)       
207            ! Note that we chose here not to bound the friction as in dynbfr)   
208            ztx2 = (  bfrua(ji,jj)  * ub(ji,jj,mbku(ji,jj)) + bfrua(ji-1,jj) * ub(ji-1,jj,mbku(ji-1,jj))  )   &         
209               & * ( 1._wp - 0.5_wp * umask(ji,jj,1) * umask(ji-1,jj,1)  )     
210            zty2 = (  bfrva(ji,jj)  * vb(ji,jj,mbkv(ji,jj)) + bfrva(ji,jj-1) * vb(ji,jj-1,mbkv(ji,jj-1))  )   &         
211               & * ( 1._wp - 0.5_wp * vmask(ji,jj,1) * vmask(ji,jj-1,1)  )     
212            ustarb2(ji,jj) = SQRT( ztx2 * ztx2 + zty2 * zty2 ) * tmask(ji,jj,1)         
213         END DO         
214      END DO   
215
216      ! Set surface roughness length
217      SELECT CASE ( nn_z0_met )
218      !
219      CASE ( 0 )             ! Constant roughness         
220         zhsro(:,:) = rn_hsro
221      CASE ( 1 )             ! Standard Charnock formula
222         zhsro(:,:) = MAX(rsbc_zs1 * ustars2(:,:), rn_hsro)
223      CASE ( 2 )             ! Roughness formulae according to Rascle et al., Ocean Modelling (2008)
224         zdep(:,:)  = 30.*TANH(2.*0.3/(28.*SQRT(MAX(ustars2(:,:),rsmall))))             ! Wave age (eq. 10)
225         zhsro(:,:) = MAX(rsbc_zs2 * ustars2(:,:) * zdep(:,:)**1.5, rn_hsro) ! zhsro = rn_frac_hs * Hsw (eq. 11)
226      CASE ( 3 )             ! Roughness given by the wave model (coupled or read in file)
227         WHERE( hsw == 0._wp ) ! surface roughness length according to Charnock formula when sign. wave height 0
228            zhsro = MAX(rn_charn / grav * ustars2, rn_hsro)
229         ELSEWHERE
230            zhsro = MAX(hsw, rn_hsro)
231         END WHERE
232      END SELECT
233
234      ! Compute shear and dissipation rate
235      DO jk = 2, jpkm1
236         DO jj = 2, jpjm1
237            DO ji = fs_2, fs_jpim1   ! vector opt.
238               avmu(ji,jj,jk) = avmu(ji,jj,jk) * ( un(ji,jj,jk-1) - un(ji,jj,jk) )   &
239                  &                            * ( ub(ji,jj,jk-1) - ub(ji,jj,jk) )   &
240                  &                            / (  fse3uw_n(ji,jj,jk)               &
241                  &                            *    fse3uw_b(ji,jj,jk) )
242               avmv(ji,jj,jk) = avmv(ji,jj,jk) * ( vn(ji,jj,jk-1) - vn(ji,jj,jk) )   &
243                  &                            * ( vb(ji,jj,jk-1) - vb(ji,jj,jk) )   &
244                  &                            / (  fse3vw_n(ji,jj,jk)               &
245                  &                            *    fse3vw_b(ji,jj,jk) )
246               eps(ji,jj,jk)  = rc03 * en(ji,jj,jk) * SQRT(en(ji,jj,jk)) / mxln(ji,jj,jk)
247            END DO
248         END DO
249      END DO
250      !
251      ! Lateral boundary conditions (avmu,avmv) (sign unchanged)
252      CALL lbc_lnk( avmu, 'U', 1. )   ;   CALL lbc_lnk( avmv, 'V', 1. )
253
254      ! Save tke at before time step
255      eb  (:,:,:) = en  (:,:,:)
256      mxlb(:,:,:) = mxln(:,:,:)
257
258      IF( nn_clos == 0 ) THEN    ! Mellor-Yamada
259         DO jk = 2, jpkm1
260            DO jj = 2, jpjm1 
261               DO ji = fs_2, fs_jpim1   ! vector opt.
262                  zup   = mxln(ji,jj,jk) * fsdepw(ji,jj,mbkt(ji,jj)+1)
263                  zdown = vkarmn * fsdepw(ji,jj,jk) * ( -fsdepw(ji,jj,jk) + fsdepw(ji,jj,mbkt(ji,jj)+1) )
264                  zcoef = ( zup / MAX( zdown, rsmall ) )
265                  zwall (ji,jj,jk) = ( 1._wp + re2 * zcoef*zcoef ) * tmask(ji,jj,jk)
266               END DO
267            END DO
268         END DO
269      ENDIF
270
271      !!---------------------------------!!
272      !!   Equation to prognostic k      !!
273      !!---------------------------------!!
274      !
275      ! Now Turbulent kinetic energy (output in en)
276      ! -------------------------------
277      ! Resolution of a tridiagonal linear system by a "methode de chasse"
278      ! computation from level 2 to jpkm1  (e(1) computed after and e(jpk)=0 ).
279      ! The surface boundary condition are set after
280      ! The bottom boundary condition are also set after. In standard e(bottom)=0.
281      ! z_elem_b : diagonal z_elem_c : upper diagonal z_elem_a : lower diagonal
282      ! Warning : after this step, en : right hand side of the matrix
283
284      DO jk = 2, jpkm1
285         DO jj = 2, jpjm1
286            DO ji = fs_2, fs_jpim1   ! vector opt.
287               !
288               ! shear prod. at w-point weightened by mask
289               shear(ji,jj,jk) =  ( avmu(ji-1,jj,jk) + avmu(ji,jj,jk) ) / MAX( 1.e0 , umask(ji-1,jj,jk) + umask(ji,jj,jk) )   &
290                  &             + ( avmv(ji,jj-1,jk) + avmv(ji,jj,jk) ) / MAX( 1.e0 , vmask(ji,jj-1,jk) + vmask(ji,jj,jk) )
291               !
292               ! stratif. destruction
293               buoy = - avt(ji,jj,jk) * rn2(ji,jj,jk)
294               !
295               ! shear prod. - stratif. destruction
296               diss = eps(ji,jj,jk)
297               !
298               dir = 0.5_wp + SIGN( 0.5_wp, shear(ji,jj,jk) + buoy )   ! dir =1(=0) if shear(ji,jj,jk)+buoy >0(<0)
299               !
300               zesh2 = dir*(shear(ji,jj,jk)+buoy)+(1._wp-dir)*shear(ji,jj,jk)          ! production term
301               zdiss = dir*(diss/en(ji,jj,jk))   +(1._wp-dir)*(diss-buoy)/en(ji,jj,jk) ! dissipation term
302               !
303               ! Compute a wall function from 1. to rsc_psi*zwall/rsc_psi0
304               ! Note that as long that Dirichlet boundary conditions are NOT set at the first and last levels (GOTM style)
305               ! there is no need to set a boundary condition for zwall_psi at the top and bottom boundaries.
306               ! Otherwise, this should be rsc_psi/rsc_psi0
307               IF( ln_sigpsi ) THEN
308                  zsigpsi = MIN( 1._wp, zesh2 / eps(ji,jj,jk) )     ! 0. <= zsigpsi <= 1.
309                  zwall_psi(ji,jj,jk) = rsc_psi /   & 
310                     &     (  zsigpsi * rsc_psi + (1._wp-zsigpsi) * rsc_psi0 / MAX( zwall(ji,jj,jk), 1._wp )  )
311               ELSE
312                  zwall_psi(ji,jj,jk) = 1._wp
313               ENDIF
314               !
315               ! building the matrix
316               zcof = rfact_tke * tmask(ji,jj,jk)
317               !
318               ! lower diagonal
319               z_elem_a(ji,jj,jk) = zcof * ( avm  (ji,jj,jk  ) + avm  (ji,jj,jk-1) )   &
320                  &                      / ( fse3t(ji,jj,jk-1) * fse3w(ji,jj,jk  ) )
321               !
322               ! upper diagonal
323               z_elem_c(ji,jj,jk) = zcof * ( avm  (ji,jj,jk+1) + avm  (ji,jj,jk  ) )   &
324                  &                      / ( fse3t(ji,jj,jk  ) * fse3w(ji,jj,jk) )
325               !
326               ! diagonal
327               z_elem_b(ji,jj,jk) = 1._wp - z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk)  &
328                  &                       + rdt * zdiss * tmask(ji,jj,jk) 
329               !
330               ! right hand side in en
331               en(ji,jj,jk) = en(ji,jj,jk) + rdt * zesh2 * tmask(ji,jj,jk)
332            END DO
333         END DO
334      END DO
335      !
336      z_elem_b(:,:,jpk) = 1._wp
337      !
338      ! Set surface condition on zwall_psi (1 at the bottom)
339      zwall_psi(:,:,1) = zwall_psi(:,:,2)
340      zwall_psi(:,:,jpk) = 1.
341      !
342      ! Surface boundary condition on tke
343      ! ---------------------------------
344      !
345      SELECT CASE ( nn_bc_surf )
346      !
347      CASE ( 0 )             ! Dirichlet case
348         IF( ln_phioc ) THEN  ! wave induced mixing case with forced/coupled fields
349            IF( nn_wmix==jp_janssen ) THEN
350               ! First level
351               en(:,:,1) = MAX( rsbc_tke1(:,:) * ustars2(:,:), rn_emin )
352               z_elem_a(:,:,1) = en(:,:,1)
353               z_elem_c(:,:,1) = 0._wp
354               z_elem_b(:,:,1) = 1._wp
355
356               ! One level below
357               en(:,:,2) = MAX( rsbc_tke1(:,:) * ustars2(:,:) * ((zhsro(:,:)+fsdepw(:,:,2))/zhsro(:,:) )**ra_sf, rn_emin )
358               z_elem_a(:,:,2) = 0._wp
359               z_elem_c(:,:,2) = 0._wp
360               z_elem_b(:,:,2) = 1._wp
361            ELSE
362               en(:,:,1) = rc02r * ustars2(:,:) * (1._wp + rsbc_tke1(:,:))**(2._wp/3._wp)
363               en(:,:,1) = MAX(en(:,:,1), rn_emin) 
364               z_elem_a(:,:,1) = en(:,:,1)
365               z_elem_c(:,:,1) = 0._wp
366               z_elem_b(:,:,1) = 1._wp
367               !
368               ! One level below
369               en(:,:,2) = rc02r * ustars2(:,:) * (1._wp + rsbc_tke1(:,:) * ((zhsro(:,:)+fsdepw(:,:,2)) &
370                   &            / zhsro(:,:) )**(1.5_wp*ra_sf))**(2._wp/3._wp)
371               en(:,:,2) = MAX(en(:,:,2), rn_emin )
372               z_elem_a(:,:,2) = 0._wp 
373               z_elem_c(:,:,2) = 0._wp
374               z_elem_b(:,:,2) = 1._wp
375               !
376            ENDIF
377         ELSE                 ! wave induced mixing case with default values
378            en(:,:,1) = rc02r * ustars2(:,:) * (1._wp + rsbc_tke1_default)**(2._wp/3._wp)
379            en(:,:,1) = MAX(en(:,:,1), rn_emin) 
380            z_elem_a(:,:,1) = en(:,:,1)
381            z_elem_c(:,:,1) = 0._wp
382            z_elem_b(:,:,1) = 1._wp
383            !
384            ! One level below
385            en(:,:,2) = rc02r * ustars2(:,:) * (1._wp + rsbc_tke1_default * ((zhsro(:,:)+fsdepw(:,:,2)) &
386                &            / zhsro(:,:) )**(1.5_wp*ra_sf))**(2._wp/3._wp)
387            en(:,:,2) = MAX(en(:,:,2), rn_emin )
388            z_elem_a(:,:,2) = 0._wp 
389            z_elem_c(:,:,2) = 0._wp
390            z_elem_b(:,:,2) = 1._wp
391            !
392            !
393         ENDIF
394      CASE ( 1 )             ! Neumann boundary condition on d(e)/dz
395         IF( ln_phioc ) THEN   ! Shear free case: d(e)/dz=Fw with forced/coupled fields
396            IF( nn_wmix==jp_janssen ) THEN
397               ! Dirichlet conditions at k=1
398               en(:,:,1) = MAX( rsbc_tke1(:,:) * ustars2(:,:), rn_emin )
399               z_elem_a(:,:,1) = en(:,:,1)
400               z_elem_c(:,:,1) = 0._wp
401               z_elem_b(:,:,1) = 1._wp
402               ! at k=2, set de/dz=Fw
403               z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
404               z_elem_a(:,:,2) = 0._wp
405               zflxs(:,:) = rsbc_tke3(:,:) * ustars2(:,:)**1.5_wp * ((zhsro(:,:)+fsdept(:,:,1) ) / zhsro(:,:) )**(1.5*ra_sf)
406               en(:,:,2) = en(:,:,2) + zflxs(:,:) / fse3w(:,:,2)
407            ELSE
408               ! Dirichlet conditions at k=1
409               en(:,:,1)       = rc02r * ustars2(:,:) * (1._wp + rsbc_tke1(:,:))**(2._wp/3._wp)
410               en(:,:,1)       = MAX(en(:,:,1), rn_emin)     
411               z_elem_a(:,:,1) = en(:,:,1)
412               z_elem_c(:,:,1) = 0._wp
413               z_elem_b(:,:,1) = 1._wp
414               !
415               ! at k=2, set de/dz=Fw
416               !cbr
417               z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
418               z_elem_a(:,:,2) = 0._wp
419               zkar(:,:)       = (rl_sf + (vkarmn-rl_sf)*(1.-exp(-rtrans(:,:)*fsdept(:,:,1)/zhsro(:,:)) ))
420               zflxs(:,:)      = rsbc_tke3(:,:) * ustars2(:,:)**1.5_wp * zkar(:,:) &
421                    &                           * ((zhsro(:,:)+fsdept(:,:,1))/zhsro(:,:) )**(1.5_wp*ra_sf)
422
423               en(:,:,2) = en(:,:,2) + zflxs(:,:)/fse3w(:,:,2)
424               !
425            ENDIF
426         ELSE                  ! Shear free case: d(e)/dz=Fw with default values
427            ! Dirichlet conditions at k=1
428            en(:,:,1)       = rc02r * ustars2(:,:) * (1._wp + rsbc_tke1_default)**(2._wp/3._wp)
429            en(:,:,1)       = MAX(en(:,:,1), rn_emin)     
430            z_elem_a(:,:,1) = en(:,:,1)
431            z_elem_c(:,:,1) = 0._wp
432            z_elem_b(:,:,1) = 1._wp
433            !
434            ! at k=2, set de/dz=Fw
435            !cbr
436            z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
437            z_elem_a(:,:,2) = 0._wp
438            zkar(:,:)       = (rl_sf + (vkarmn-rl_sf)*(1.-exp(-rtrans_default*fsdept(:,:,1)/zhsro(:,:)) ))
439            zflxs(:,:)      = rsbc_tke2 * ustars2(:,:)**1.5_wp * zkar(:,:) &
440                 &                      * ((zhsro(:,:)+fsdept(:,:,1))/zhsro(:,:) )**(1.5_wp*ra_sf)
441
442            en(:,:,2) = en(:,:,2) + zflxs(:,:)/fse3w(:,:,2)
443            !
444            !
445         ENDIF
446      END SELECT
447
448      ! Bottom boundary condition on tke
449      ! --------------------------------
450      !
451      SELECT CASE ( nn_bc_bot )
452      !
453      CASE ( 0 )             ! Dirichlet
454         !                      ! en(ibot) = u*^2 / Co2 and mxln(ibot) = rn_lmin
455         !                      ! Balance between the production and the dissipation terms
456!CDIR NOVERRCHK
457         DO jj = 2, jpjm1
458!CDIR NOVERRCHK
459            DO ji = fs_2, fs_jpim1   ! vector opt.
460               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
461               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
462               !
463               ! Bottom level Dirichlet condition:
464               z_elem_a(ji,jj,ibot  ) = 0._wp
465               z_elem_c(ji,jj,ibot  ) = 0._wp
466               z_elem_b(ji,jj,ibot  ) = 1._wp
467               en(ji,jj,ibot  ) = MAX( rc02r * ustarb2(ji,jj), rn_emin )
468               !
469               ! Just above last level, Dirichlet condition again
470               z_elem_a(ji,jj,ibotm1) = 0._wp
471               z_elem_c(ji,jj,ibotm1) = 0._wp
472               z_elem_b(ji,jj,ibotm1) = 1._wp
473               en(ji,jj,ibotm1) = MAX( rc02r * ustarb2(ji,jj), rn_emin ) 
474            END DO
475         END DO
476         !
477      CASE ( 1 )             ! Neumman boundary condition
478         !                     
479!CDIR NOVERRCHK
480         DO jj = 2, jpjm1
481!CDIR NOVERRCHK
482            DO ji = fs_2, fs_jpim1   ! vector opt.
483               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
484               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
485               !
486               ! Bottom level Dirichlet condition:
487               z_elem_a(ji,jj,ibot) = 0._wp
488               z_elem_c(ji,jj,ibot) = 0._wp
489               z_elem_b(ji,jj,ibot) = 1._wp
490               en(ji,jj,ibot) = MAX( rc02r * ustarb2(ji,jj), rn_emin )
491               !
492               ! Just above last level: Neumann condition
493               z_elem_b(ji,jj,ibotm1) = z_elem_b(ji,jj,ibotm1) + z_elem_c(ji,jj,ibotm1)   ! Remove z_elem_c from z_elem_b
494               z_elem_c(ji,jj,ibotm1) = 0._wp
495            END DO
496         END DO
497         !
498      END SELECT
499
500      ! Matrix inversion (en prescribed at surface and the bottom)
501      ! ----------------------------------------------------------
502      !
503      DO jk = 2, jpkm1                             ! First recurrence : Dk = Dk - Lk * Uk-1 / Dk-1
504         DO jj = 2, jpjm1
505            DO ji = fs_2, fs_jpim1    ! vector opt.
506               z_elem_b(ji,jj,jk) = z_elem_b(ji,jj,jk) - z_elem_a(ji,jj,jk) * z_elem_c(ji,jj,jk-1) / z_elem_b(ji,jj,jk-1)
507            END DO
508         END DO
509      END DO
510      DO jk = 2, jpk                               ! Second recurrence : Lk = RHSk - Lk / Dk-1 * Lk-1
511         DO jj = 2, jpjm1
512            DO ji = fs_2, fs_jpim1    ! vector opt.
513               z_elem_a(ji,jj,jk) = en(ji,jj,jk) - z_elem_a(ji,jj,jk) / z_elem_b(ji,jj,jk-1) * z_elem_a(ji,jj,jk-1)
514            END DO
515         END DO
516      END DO
517      DO jk = jpk-1, 2, -1                         ! thrid recurrence : Ek = ( Lk - Uk * Ek+1 ) / Dk
518         DO jj = 2, jpjm1
519            DO ji = fs_2, fs_jpim1    ! vector opt.
520               en(ji,jj,jk) = ( z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk) * en(ji,jj,jk+1) ) / z_elem_b(ji,jj,jk)
521            END DO
522         END DO
523      END DO
524      !                                            ! set the minimum value of tke
525      en(:,:,:) = MAX( en(:,:,:), rn_emin )
526
527      !!----------------------------------------!!
528      !!   Solve prognostic equation for psi    !!
529      !!----------------------------------------!!
530
531      ! Set psi to previous time step value
532      !
533      SELECT CASE ( nn_clos )
534      !
535      CASE( 0 )               ! k-kl  (Mellor-Yamada)
536         DO jk = 2, jpkm1
537            DO jj = 2, jpjm1
538               DO ji = fs_2, fs_jpim1   ! vector opt.
539                  psi(ji,jj,jk)  = eb(ji,jj,jk) * mxlb(ji,jj,jk)
540               END DO
541            END DO
542         END DO
543         !
544      CASE( 1 )               ! k-eps
545         DO jk = 2, jpkm1
546            DO jj = 2, jpjm1
547               DO ji = fs_2, fs_jpim1   ! vector opt.
548                  psi(ji,jj,jk)  = eps(ji,jj,jk)
549               END DO
550            END DO
551         END DO
552         !
553      CASE( 2 )               ! k-w
554         DO jk = 2, jpkm1
555            DO jj = 2, jpjm1
556               DO ji = fs_2, fs_jpim1   ! vector opt.
557                  psi(ji,jj,jk)  = SQRT( eb(ji,jj,jk) ) / ( rc0 * mxlb(ji,jj,jk) )
558               END DO
559            END DO
560         END DO
561         !
562      CASE( 3 )               ! generic
563         DO jk = 2, jpkm1
564            DO jj = 2, jpjm1
565               DO ji = fs_2, fs_jpim1   ! vector opt.
566                  psi(ji,jj,jk)  = rc02 * eb(ji,jj,jk) * mxlb(ji,jj,jk)**rnn 
567               END DO
568            END DO
569         END DO
570         !
571      END SELECT
572      !
573      ! Now gls (output in psi)
574      ! -------------------------------
575      ! Resolution of a tridiagonal linear system by a "methode de chasse"
576      ! computation from level 2 to jpkm1  (e(1) already computed and e(jpk)=0 ).
577      ! z_elem_b : diagonal z_elem_c : upper diagonal z_elem_a : lower diagonal
578      ! Warning : after this step, en : right hand side of the matrix
579
580      DO jk = 2, jpkm1
581         DO jj = 2, jpjm1
582            DO ji = fs_2, fs_jpim1   ! vector opt.
583               !
584               ! psi / k
585               zratio = psi(ji,jj,jk) / eb(ji,jj,jk) 
586               !
587               ! psi3+ : stable : B=-KhN²<0 => N²>0 if rn2>0 dir = 1 (stable) otherwise dir = 0 (unstable)
588               dir = 0.5_wp + SIGN( 0.5_wp, rn2(ji,jj,jk) )
589               !
590               rpsi3 = dir * rpsi3m + ( 1._wp - dir ) * rpsi3p
591               !
592               ! shear prod. - stratif. destruction
593               prod = rpsi1 * zratio * shear(ji,jj,jk)
594               !
595               ! stratif. destruction
596               buoy = rpsi3 * zratio * (- avt(ji,jj,jk) * rn2(ji,jj,jk) )
597               !
598               ! shear prod. - stratif. destruction
599               diss = rpsi2 * zratio * zwall(ji,jj,jk) * eps(ji,jj,jk)
600               !
601               dir = 0.5_wp + SIGN( 0.5_wp, prod + buoy )   ! dir =1(=0) if shear(ji,jj,jk)+buoy >0(<0)
602               !
603               zesh2 = dir * ( prod + buoy )          + (1._wp - dir ) * prod                        ! production term
604               zdiss = dir * ( diss / psi(ji,jj,jk) ) + (1._wp - dir ) * (diss-buoy) / psi(ji,jj,jk) ! dissipation term
605               !                                                       
606               ! building the matrix
607               zcof = rfact_psi * zwall_psi(ji,jj,jk) * tmask(ji,jj,jk)
608               ! lower diagonal
609               z_elem_a(ji,jj,jk) = zcof * ( avm  (ji,jj,jk  ) + avm  (ji,jj,jk-1) )   &
610                  &                      / ( fse3t(ji,jj,jk-1) * fse3w(ji,jj,jk  ) )
611               ! upper diagonal
612               z_elem_c(ji,jj,jk) = zcof * ( avm  (ji,jj,jk+1) + avm  (ji,jj,jk  ) )   &
613                  &                      / ( fse3t(ji,jj,jk  ) * fse3w(ji,jj,jk) )
614               ! diagonal
615               z_elem_b(ji,jj,jk) = 1._wp - z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk)  &
616                  &                       + rdt * zdiss * tmask(ji,jj,jk)
617               !
618               ! right hand side in psi
619               psi(ji,jj,jk) = psi(ji,jj,jk) + rdt * zesh2 * tmask(ji,jj,jk)
620            END DO
621         END DO
622      END DO
623      !
624      z_elem_b(:,:,jpk) = 1._wp
625
626      ! Surface boundary condition on psi
627      ! ---------------------------------
628      !
629      SELECT CASE ( nn_bc_surf )
630      !
631      CASE ( 0 )             ! Dirichlet boundary conditions
632         IF( ln_phioc ) THEN   ! Wave induced mixing case
633                               ! en(1) = q2(1) = 0.5 * (15.8 * Ccb)^(2/3) * u*^2
634                               ! balance between the production and the
635                               ! dissipation terms including the wave effect
636            IF( nn_wmix==jp_janssen ) THEN
637               ! Surface value
638               zdep(:,:)       = zhsro(:,:) * rl_sf ! Cosmetic
639               psi (:,:,1)     = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
640               z_elem_a(:,:,1) = psi(:,:,1)     
641               z_elem_c(:,:,1) = 0._wp
642               z_elem_b(:,:,1) = 1._wp
643               !
644               ! One level below
645               zex1 = (rmm*ra_sf+rnn)
646               zex2 = (rmm*ra_sf)
647               zdep(:,:) = ( (zhsro(:,:) + fsdepw(:,:,2))**zex1 ) / zhsro(:,:)**zex2
648               psi (:,:,2) = rsbc_psi1(:,:) * ustars2(:,:)**rmm * zdep(:,:) * tmask(:,:,1)
649               z_elem_a(:,:,2) = 0._wp
650               z_elem_c(:,:,2) = 0._wp
651               z_elem_b(:,:,2) = 1._wp
652               !
653               !
654            ELSE
655               ! Surface value
656               zdep(:,:)       = zhsro(:,:) * rl_sf ! Cosmetic
657               psi (:,:,1)     = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
658               z_elem_a(:,:,1) = psi(:,:,1)
659               z_elem_c(:,:,1) = 0._wp
660               z_elem_b(:,:,1) = 1._wp
661               !
662               ! One level below
663               zkar(:,:)       = (rl_sf + (vkarmn-rl_sf)*(1._wp-exp(-rtrans(:,:)*fsdepw(:,:,2)/zhsro(:,:) )))
664               zdep(:,:)       = (zhsro(:,:) + fsdepw(:,:,2)) * zkar(:,:)
665               psi (:,:,2)     = rc0**rpp * en(:,:,2)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
666               z_elem_a(:,:,2) = 0._wp
667               z_elem_c(:,:,2) = 0._wp
668               z_elem_b(:,:,2) = 1._wp
669               !
670               !
671            ENDIF
672         ELSE                  ! Wave induced mixing case with default values
673            ! Surface value
674            zdep(:,:)       = zhsro(:,:) * rl_sf ! Cosmetic
675            psi (:,:,1)     = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
676            z_elem_a(:,:,1) = psi(:,:,1)
677            z_elem_c(:,:,1) = 0._wp
678            z_elem_b(:,:,1) = 1._wp
679            !
680            ! One level below
681            zkar(:,:)       = (rl_sf + (vkarmn-rl_sf)*(1._wp-exp(-rtrans_default*fsdepw(:,:,2)/zhsro(:,:) )))
682            zdep(:,:)       = (zhsro(:,:) + fsdepw(:,:,2)) * zkar(:,:)
683            psi (:,:,2)     = rc0**rpp * en(:,:,2)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
684            z_elem_a(:,:,2) = 0._wp
685            z_elem_c(:,:,2) = 0._wp
686            z_elem_b(:,:,2) = 1._wp
687            !
688            !
689         ENDIF
690      CASE ( 1 )             ! Neumann boundary condition on d(psi)/dz
691         IF( ln_phioc ) THEN  ! Wave induced mixing case with forced/coupled fields
692            IF( nn_wmix==jp_janssen ) THEN
693               !
694               zdep(:,:) = rl_sf * zhsro(:,:)
695               psi (:,:,1) = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
696               z_elem_a(:,:,1) = psi(:,:,1)
697               z_elem_c(:,:,1) = 0._wp
698               z_elem_b(:,:,1) = 1._wp
699               !
700               ! Neumann condition at k=2
701               z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
702               z_elem_a(:,:,2) = 0._wp
703               !
704               ! Set psi vertical flux at the surface:
705               zdep(:,:) = (zhsro(:,:) + fsdept(:,:,1))**(rmm*ra_sf+rnn-1._wp) / zhsro(:,:)**(rmm*ra_sf)
706               zflxs(:,:) = rsbc_psi3 * ( zwall_psi(:,:,1)*avm(:,:,1) + zwall_psi(:,:,2)*avm(:,:,2) ) &
707                  &                   * en(:,:,1)**rmm * zdep
708               psi(:,:,2) = psi(:,:,2) + zflxs(:,:) / fse3w(:,:,2)
709               !
710            ELSE
711               ! Surface value: Dirichlet
712               zdep(:,:)       = zhsro(:,:) * rl_sf
713               psi (:,:,1)     = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
714               z_elem_a(:,:,1) = psi(:,:,1)
715               z_elem_c(:,:,1) = 0._wp
716               z_elem_b(:,:,1) = 1._wp
717               !
718               ! Neumann condition at k=2
719               z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
720               z_elem_a(:,:,2) = 0._wp
721               !
722               ! Set psi vertical flux at the surface:
723               zkar(:,:) = rl_sf + (vkarmn-rl_sf)*(1._wp-exp(-rtrans(:,:)*fsdept(:,:,1)/zhsro(:,:) )) ! Lengh scale slope
724               zdep(:,:) = ((zhsro(:,:) + fsdept(:,:,1)) / zhsro(:,:))**(rmm*ra_sf)
725               zflxs(:,:) = (rnn + rsbc_tke1(:,:) * (rnn + rmm*ra_sf) * zdep(:,:)) * &
726                          (1._wp + rsbc_tke1(:,:) * zdep(:,:))**(2._wp*rmm/3._wp-1_wp)
727               zdep(:,:) =  rsbc_psi1(:,:) * (zwall_psi(:,:,1)*avm(:,:,1)+zwall_psi(:,:,2)*avm(:,:,2)) * &
728                      & ustars2(:,:)**rmm * zkar(:,:)**rnn * (zhsro(:,:) + fsdept(:,:,1))**(rnn-1.)
729               zflxs(:,:) = zdep(:,:) * zflxs(:,:)
730               psi(:,:,2) = psi(:,:,2) + zflxs(:,:) / fse3w(:,:,2)
731               !   
732            ENDIF
733         ELSE                 ! Wave induced mixing case with default values
734            ! Surface value: Dirichlet
735            zdep(:,:)       = zhsro(:,:) * rl_sf
736            psi (:,:,1)     = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
737            z_elem_a(:,:,1) = psi(:,:,1)
738            z_elem_c(:,:,1) = 0._wp
739            z_elem_b(:,:,1) = 1._wp
740            !
741            ! Neumann condition at k=2
742            z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
743            z_elem_a(:,:,2) = 0._wp
744            !
745            ! Set psi vertical flux at the surface:
746            zkar(:,:) = rl_sf + (vkarmn-rl_sf)*(1._wp-exp(-rtrans_default*fsdept(:,:,1)/zhsro(:,:) )) ! Lengh scale slope
747            zdep(:,:) = ((zhsro(:,:) + fsdept(:,:,1)) / zhsro(:,:))**(rmm*ra_sf)
748            zflxs(:,:) = (rnn + rsbc_tke1_default * (rnn + rmm*ra_sf) * zdep(:,:)) * &
749                       (1._wp + rsbc_tke1_default * zdep(:,:))**(2._wp*rmm/3._wp-1_wp)
750            zdep(:,:) =  rsbc_psi1(:,:) * (zwall_psi(:,:,1)*avm(:,:,1)+zwall_psi(:,:,2)*avm(:,:,2)) * &
751                   & ustars2(:,:)**rmm * zkar(:,:)**rnn * (zhsro(:,:) + fsdept(:,:,1))**(rnn-1.)
752            zflxs(:,:) = zdep(:,:) * zflxs(:,:)
753            psi(:,:,2) = psi(:,:,2) + zflxs(:,:) / fse3w(:,:,2)
754            !   
755            !
756         ENDIF
757      END SELECT
758
759      ! Bottom boundary condition on psi
760      ! --------------------------------
761      !
762      SELECT CASE ( nn_bc_bot )
763      !
764      !
765      CASE ( 0 )             ! Dirichlet
766         !                      ! en(ibot) = u*^2 / Co2 and mxln(ibot) = vkarmn * rn_bfrz0
767         !                      ! Balance between the production and the dissipation terms
768!CDIR NOVERRCHK
769         DO jj = 2, jpjm1
770!CDIR NOVERRCHK
771            DO ji = fs_2, fs_jpim1   ! vector opt.
772               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
773               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
774               zdep(ji,jj) = vkarmn * rn_bfrz0
775               psi (ji,jj,ibot) = rc0**rpp * en(ji,jj,ibot)**rmm * zdep(ji,jj)**rnn
776               z_elem_a(ji,jj,ibot) = 0._wp
777               z_elem_c(ji,jj,ibot) = 0._wp
778               z_elem_b(ji,jj,ibot) = 1._wp
779               !
780               ! Just above last level, Dirichlet condition again (GOTM like)
781               zdep(ji,jj) = vkarmn * ( rn_bfrz0 + fse3t(ji,jj,ibotm1) )
782               psi (ji,jj,ibotm1) = rc0**rpp * en(ji,jj,ibot  )**rmm * zdep(ji,jj)**rnn
783               z_elem_a(ji,jj,ibotm1) = 0._wp
784               z_elem_c(ji,jj,ibotm1) = 0._wp
785               z_elem_b(ji,jj,ibotm1) = 1._wp
786            END DO
787         END DO
788         !
789      CASE ( 1 )             ! Neumman boundary condition
790         !                     
791!CDIR NOVERRCHK
792         DO jj = 2, jpjm1
793!CDIR NOVERRCHK
794            DO ji = fs_2, fs_jpim1   ! vector opt.
795               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
796               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
797               !
798               ! Bottom level Dirichlet condition:
799               zdep(ji,jj) = vkarmn * rn_bfrz0
800               psi (ji,jj,ibot) = rc0**rpp * en(ji,jj,ibot)**rmm * zdep(ji,jj)**rnn
801               !
802               z_elem_a(ji,jj,ibot) = 0._wp
803               z_elem_c(ji,jj,ibot) = 0._wp
804               z_elem_b(ji,jj,ibot) = 1._wp
805               !
806               ! Just above last level: Neumann condition with flux injection
807               z_elem_b(ji,jj,ibotm1) = z_elem_b(ji,jj,ibotm1) + z_elem_c(ji,jj,ibotm1) ! Remove z_elem_c from z_elem_b
808               z_elem_c(ji,jj,ibotm1) = 0.
809               !
810               ! Set psi vertical flux at the bottom:
811               zdep(ji,jj) = rn_bfrz0 + 0.5_wp*fse3t(ji,jj,ibotm1)
812               zflxb = rsbc_psi2 * ( avm(ji,jj,ibot) + avm(ji,jj,ibotm1) )   &
813                  &  * (0.5_wp*(en(ji,jj,ibot)+en(ji,jj,ibotm1)))**rmm * zdep(ji,jj)**(rnn-1._wp)
814               psi(ji,jj,ibotm1) = psi(ji,jj,ibotm1) + zflxb / fse3w(ji,jj,ibotm1)
815            END DO
816         END DO
817         !
818      END SELECT
819
820      ! Matrix inversion
821      ! ----------------
822      !
823      DO jk = 2, jpkm1                             ! First recurrence : Dk = Dk - Lk * Uk-1 / Dk-1
824         DO jj = 2, jpjm1
825            DO ji = fs_2, fs_jpim1    ! vector opt.
826               z_elem_b(ji,jj,jk) = z_elem_b(ji,jj,jk) - z_elem_a(ji,jj,jk) * z_elem_c(ji,jj,jk-1) / z_elem_b(ji,jj,jk-1)
827            END DO
828         END DO
829      END DO
830      DO jk = 2, jpk                               ! Second recurrence : Lk = RHSk - Lk / Dk-1 * Lk-1
831         DO jj = 2, jpjm1
832            DO ji = fs_2, fs_jpim1    ! vector opt.
833               z_elem_a(ji,jj,jk) = psi(ji,jj,jk) - z_elem_a(ji,jj,jk) / z_elem_b(ji,jj,jk-1) * z_elem_a(ji,jj,jk-1)
834            END DO
835         END DO
836      END DO
837      DO jk = jpk-1, 2, -1                         ! Third recurrence : Ek = ( Lk - Uk * Ek+1 ) / Dk
838         DO jj = 2, jpjm1
839            DO ji = fs_2, fs_jpim1    ! vector opt.
840               psi(ji,jj,jk) = ( z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk) * psi(ji,jj,jk+1) ) / z_elem_b(ji,jj,jk)
841            END DO
842         END DO
843      END DO
844
845      ! Set dissipation
846      !----------------
847
848      SELECT CASE ( nn_clos )
849      !
850      CASE( 0 )               ! k-kl  (Mellor-Yamada)
851         DO jk = 1, jpkm1
852            DO jj = 2, jpjm1
853               DO ji = fs_2, fs_jpim1   ! vector opt.
854                  eps(ji,jj,jk) = rc03 * en(ji,jj,jk) * en(ji,jj,jk) * SQRT( en(ji,jj,jk) ) / MAX( psi(ji,jj,jk), rn_epsmin)
855               END DO
856            END DO
857         END DO
858         !
859      CASE( 1 )               ! k-eps
860         DO jk = 1, jpkm1
861            DO jj = 2, jpjm1
862               DO ji = fs_2, fs_jpim1   ! vector opt.
863                  eps(ji,jj,jk) = psi(ji,jj,jk)
864               END DO
865            END DO
866         END DO
867         !
868      CASE( 2 )               ! k-w
869         DO jk = 1, jpkm1
870            DO jj = 2, jpjm1
871               DO ji = fs_2, fs_jpim1   ! vector opt.
872                  eps(ji,jj,jk) = rc04 * en(ji,jj,jk) * psi(ji,jj,jk) 
873               END DO
874            END DO
875         END DO
876         !
877      CASE( 3 )               ! generic
878         zcoef = rc0**( 3._wp  + rpp/rnn )
879         zex1  =      ( 1.5_wp + rmm/rnn )
880         zex2  = -1._wp / rnn
881         DO jk = 1, jpkm1
882            DO jj = 2, jpjm1
883               DO ji = fs_2, fs_jpim1   ! vector opt.
884                  eps(ji,jj,jk) = zcoef * en(ji,jj,jk)**zex1 * psi(ji,jj,jk)**zex2
885               END DO
886            END DO
887         END DO
888         !
889      END SELECT
890
891      ! Limit dissipation rate under stable stratification
892      ! --------------------------------------------------
893      DO jk = 1, jpkm1 ! Note that this set boundary conditions on mxln at the same time
894         DO jj = 2, jpjm1
895            DO ji = fs_2, fs_jpim1    ! vector opt.
896               ! limitation
897               eps(ji,jj,jk)  = MAX( eps(ji,jj,jk), rn_epsmin )
898               mxln(ji,jj,jk)  = rc03 * en(ji,jj,jk) * SQRT( en(ji,jj,jk) ) / eps(ji,jj,jk)
899               ! Galperin criterium (NOTE : Not required if the proper value of C3 in stable cases is calculated)
900               zrn2 = MAX( rn2(ji,jj,jk), rsmall )
901               IF (ln_length_lim) mxln(ji,jj,jk) = MIN(  rn_clim_galp * SQRT( 2._wp * en(ji,jj,jk) / zrn2 ), mxln(ji,jj,jk) )
902            END DO
903         END DO
904      END DO 
905
906      !
907      ! Stability function and vertical viscosity and diffusivity
908      ! ---------------------------------------------------------
909      !
910      SELECT CASE ( nn_stab_func )
911      !
912      CASE ( 0 , 1 )             ! Galperin or Kantha-Clayson stability functions
913         DO jk = 2, jpkm1
914            DO jj = 2, jpjm1
915               DO ji = fs_2, fs_jpim1   ! vector opt.
916                  ! zcof =  l²/q²
917                  zcof = mxlb(ji,jj,jk) * mxlb(ji,jj,jk) / ( 2._wp*eb(ji,jj,jk) )
918                  ! Gh = -N²l²/q²
919                  gh = - rn2(ji,jj,jk) * zcof
920                  gh = MIN( gh, rgh0   )
921                  gh = MAX( gh, rghmin )
922                  ! Stability functions from Kantha and Clayson (if C2=C3=0 => Galperin)
923                  sh = ra2*( 1._wp-6._wp*ra1/rb1 ) / ( 1.-3.*ra2*gh*(6.*ra1+rb2*( 1._wp-rc3 ) ) )
924                  sm = ( rb1**(-1._wp/3._wp) + ( 18._wp*ra1*ra1 + 9._wp*ra1*ra2*(1._wp-rc2) )*sh*gh ) / (1._wp-9._wp*ra1*ra2*gh)
925                  !
926                  ! Store stability function in avmu and avmv
927                  avmu(ji,jj,jk) = rc_diff * sh * tmask(ji,jj,jk)
928                  avmv(ji,jj,jk) = rc_diff * sm * tmask(ji,jj,jk)
929               END DO
930            END DO
931         END DO
932         !
933      CASE ( 2, 3 )               ! Canuto stability functions
934         DO jk = 2, jpkm1
935            DO jj = 2, jpjm1
936               DO ji = fs_2, fs_jpim1   ! vector opt.
937                  ! zcof =  l²/q²
938                  zcof = mxlb(ji,jj,jk)*mxlb(ji,jj,jk) / ( 2._wp * eb(ji,jj,jk) )
939                  ! Gh = -N²l²/q²
940                  gh = - rn2(ji,jj,jk) * zcof
941                  gh = MIN( gh, rgh0   )
942                  gh = MAX( gh, rghmin )
943                  gh = gh * rf6
944                  ! Gm =  M²l²/q² Shear number
945                  shr = shear(ji,jj,jk) / MAX( avm(ji,jj,jk), rsmall )
946                  gm = MAX( shr * zcof , 1.e-10 )
947                  gm = gm * rf6
948                  gm = MIN ( (rd0 - rd1*gh + rd3*gh*gh) / (rd2-rd4*gh) , gm )
949                  ! Stability functions from Canuto
950                  rcff = rd0 - rd1*gh +rd2*gm + rd3*gh*gh - rd4*gh*gm + rd5*gm*gm
951                  sm = (rs0 - rs1*gh + rs2*gm) / rcff
952                  sh = (rs4 - rs5*gh + rs6*gm) / rcff
953                  !
954                  ! Store stability function in avmu and avmv
955                  avmu(ji,jj,jk) = rc_diff * sh * tmask(ji,jj,jk)
956                  avmv(ji,jj,jk) = rc_diff * sm * tmask(ji,jj,jk)
957               END DO
958            END DO
959         END DO
960         !
961      END SELECT
962
963      ! Boundary conditions on stability functions for momentum (Neumann):
964      ! Lines below are useless if GOTM style Dirichlet conditions are used
965
966      avmv(:,:,1) = avmv(:,:,2)
967
968      DO jj = 2, jpjm1
969         DO ji = fs_2, fs_jpim1   ! vector opt.
970            avmv(ji,jj,mbkt(ji,jj)+1) = avmv(ji,jj,mbkt(ji,jj))
971         END DO
972      END DO
973
974      ! Compute diffusivities/viscosities
975      ! The computation below could be restrained to jk=2 to jpkm1 if GOTM style Dirichlet conditions are used
976      DO jk = 1, jpk
977         DO jj = 2, jpjm1
978            DO ji = fs_2, fs_jpim1   ! vector opt.
979               zsqen         = SQRT( 2._wp * en(ji,jj,jk) ) * mxln(ji,jj,jk)
980               zav           = zsqen * avmu(ji,jj,jk)
981               avt(ji,jj,jk) = MAX( zav, avtb(jk) )*tmask(ji,jj,jk) ! apply mask for zdfmxl routine
982               zav           = zsqen * avmv(ji,jj,jk)
983               avm(ji,jj,jk) = MAX( zav, avmb(jk) ) ! Note that avm is not masked at the surface and the bottom
984            END DO
985         END DO
986      END DO
987      !
988      ! Lateral boundary conditions (sign unchanged)
989      avt(:,:,1)  = 0._wp
990      CALL lbc_lnk( avm, 'W', 1. )   ;   CALL lbc_lnk( avt, 'W', 1. )
991
992      DO jk = 2, jpkm1            !* vertical eddy viscosity at u- and v-points
993         DO jj = 2, jpjm1
994            DO ji = fs_2, fs_jpim1   ! vector opt.
995               avmu(ji,jj,jk) = 0.5 * ( avm(ji,jj,jk) + avm(ji+1,jj  ,jk) ) * umask(ji,jj,jk)
996               avmv(ji,jj,jk) = 0.5 * ( avm(ji,jj,jk) + avm(ji  ,jj+1,jk) ) * vmask(ji,jj,jk)
997            END DO
998         END DO
999      END DO
1000      avmu(:,:,1) = 0._wp             ;   avmv(:,:,1) = 0._wp                 ! set surface to zero
1001      CALL lbc_lnk( avmu, 'U', 1. )   ;   CALL lbc_lnk( avmv, 'V', 1. )       ! Lateral boundary conditions
1002
1003      IF(ln_ctl) THEN
1004         CALL prt_ctl( tab3d_1=en  , clinfo1=' gls  - e: ', tab3d_2=avt, clinfo2=' t: ', ovlap=1, kdim=jpk)
1005         CALL prt_ctl( tab3d_1=avmu, clinfo1=' gls  - u: ', mask1=umask,                   &
1006            &          tab3d_2=avmv, clinfo2=       ' v: ', mask2=vmask, ovlap=1, kdim=jpk )
1007      ENDIF
1008      !
1009      avt_k (:,:,:) = avt (:,:,:)
1010      avm_k (:,:,:) = avm (:,:,:)
1011      avmu_k(:,:,:) = avmu(:,:,:)
1012      avmv_k(:,:,:) = avmv(:,:,:)
1013      !
1014      CALL wrk_dealloc( jpi,jpj, zdep, zkar, zflxs, zhsro )
1015      CALL wrk_dealloc( jpi,jpj,jpk, eb, mxlb, shear, eps, zwall_psi, z_elem_a, z_elem_b, z_elem_c, psi )
1016      !
1017      IF( nn_timing == 1 )  CALL timing_stop('zdf_gls')
1018      !
1019      !
1020   END SUBROUTINE zdf_gls
1021
1022
1023   SUBROUTINE zdf_gls_init
1024      !!----------------------------------------------------------------------
1025      !!                  ***  ROUTINE zdf_gls_init  ***
1026      !!                     
1027      !! ** Purpose :   Initialization of the vertical eddy diffivity and
1028      !!      viscosity when using a gls turbulent closure scheme
1029      !!
1030      !! ** Method  :   Read the namzdf_gls namelist and check the parameters
1031      !!      called at the first timestep (nit000)
1032      !!
1033      !! ** input   :   Namlist namzdf_gls
1034      !!
1035      !! ** Action  :   Increase by 1 the nstop flag is setting problem encounter
1036      !!
1037      !!----------------------------------------------------------------------
1038      USE dynzdf_exp
1039      USE trazdf_exp
1040      !
1041      INTEGER ::   jk    ! dummy loop indices
1042      INTEGER ::   ios   ! Local integer output status for namelist read
1043      REAL(wp)::   zcr   ! local scalar
1044      !!
1045      NAMELIST/namzdf_gls/rn_emin, rn_epsmin, ln_length_lim, &
1046         &            rn_clim_galp, ln_sigpsi, rn_hsro,      &
1047         &            rn_crban_default, rn_charn, rn_frac_hs,&
1048         &            nn_bc_surf, nn_bc_bot, nn_z0_met,      &
1049         &            nn_stab_func, nn_clos, nn_wmix
1050      !!----------------------------------------------------------
1051      !
1052      IF( nn_timing == 1 )  CALL timing_start('zdf_gls_init')
1053      !
1054      REWIND( numnam_ref )              ! Namelist namzdf_gls in reference namelist : Vertical eddy diffivity and viscosity using gls turbulent closure scheme
1055      READ  ( numnam_ref, namzdf_gls, IOSTAT = ios, ERR = 901)
1056901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_gls in reference namelist', lwp )
1057
1058      REWIND( numnam_cfg )              ! Namelist namzdf_gls in configuration namelist : Vertical eddy diffivity and viscosity using gls turbulent closure scheme
1059      READ  ( numnam_cfg, namzdf_gls, IOSTAT = ios, ERR = 902 )
1060902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_gls in configuration namelist', lwp )
1061      IF(lwm) WRITE ( numond, namzdf_gls )
1062
1063      IF(lwp) THEN                     !* Control print
1064         WRITE(numout,*)
1065         WRITE(numout,*) 'zdf_gls_init : gls turbulent closure scheme'
1066         WRITE(numout,*) '~~~~~~~~~~~~'
1067         WRITE(numout,*) '   Namelist namzdf_gls : set gls mixing parameters'
1068         WRITE(numout,*) '      minimum value of en                           rn_emin        = ', rn_emin
1069         WRITE(numout,*) '      minimum value of eps                          rn_epsmin      = ', rn_epsmin
1070         WRITE(numout,*) '      Limit dissipation rate under stable stratif.  ln_length_lim  = ', ln_length_lim
1071         WRITE(numout,*) '      Galperin limit (Standard: 0.53, Holt: 0.26)   rn_clim_galp   = ', rn_clim_galp
1072         WRITE(numout,*) '      TKE Surface boundary condition                nn_bc_surf     = ', nn_bc_surf
1073         WRITE(numout,*) '      TKE Bottom boundary condition                 nn_bc_bot      = ', nn_bc_bot
1074         WRITE(numout,*) '      Modify psi Schmidt number (wb case)           ln_sigpsi      = ', ln_sigpsi
1075         WRITE(numout,*) '      Craig and Banner coefficient (default)        rn_crban       = ', rn_crban_default
1076         WRITE(numout,*) '      Charnock coefficient                          rn_charn       = ', rn_charn
1077         WRITE(numout,*) '      Surface roughness formula                     nn_z0_met      = ', nn_z0_met
1078         WRITE(numout,*) '      Wave height frac. (used if nn_z0_met=2)       rn_frac_hs     = ', rn_frac_hs
1079         WRITE(numout,*) '      Stability functions                           nn_stab_func   = ', nn_stab_func
1080         WRITE(numout,*) '      Type of closure                               nn_clos        = ', nn_clos
1081         WRITE(numout,*) '      Surface roughness (m)                         rn_hsro        = ', rn_hsro
1082         WRITE(numout,*) '      Bottom roughness (m) (nambfr namelist)        rn_bfrz0       = ', rn_bfrz0
1083      ENDIF
1084
1085      !                                !* allocate gls arrays
1086      IF( zdf_gls_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'zdf_gls_init : unable to allocate arrays' )
1087
1088      !                                !* Check of some namelist values
1089      IF( nn_bc_surf < 0 .OR. nn_bc_surf > 1 ) CALL ctl_stop( 'zdf_gls_init: bad flag: nn_bc_surf is 0 or 1' ) 
1090      IF( nn_bc_surf < 0 .OR. nn_bc_surf > 1 ) CALL ctl_stop( 'zdf_gls_init: bad flag: nn_bc_surf is 0 or 1' ) 
1091      IF( nn_z0_met < 0 .OR. nn_z0_met > 3 ) CALL ctl_stop( 'zdf_gls_init: bad flag: nn_z0_met is 0, 1, 2 or 3' ) 
1092      IF( nn_z0_met == 3 .AND. .NOT.ln_sdw ) CALL ctl_stop( 'zdf_gls_init: nn_z0_met=3 requires ln_sdw=T' ) 
1093      IF( nn_stab_func  < 0 .OR. nn_stab_func  > 3 ) CALL ctl_stop( 'zdf_gls_init: bad flag: nn_stab_func is 0, 1, 2 and 3' ) 
1094      IF( nn_clos       < 0 .OR. nn_clos       > 3 ) CALL ctl_stop( 'zdf_gls_init: bad flag: nn_clos is 0, 1, 2 or 3' )
1095
1096      SELECT CASE ( nn_clos )          !* set the parameters for the chosen closure
1097      !
1098      CASE( 0 )                              ! k-kl  (Mellor-Yamada)
1099         !
1100         IF(lwp) WRITE(numout,*) 'The choosen closure is k-kl closed to the classical Mellor-Yamada'
1101         rpp     = 0._wp
1102         rmm     = 1._wp
1103         rnn     = 1._wp
1104         rsc_tke = 1.96_wp
1105         rsc_psi = 1.96_wp
1106         rpsi1   = 0.9_wp
1107         rpsi3p  = 1._wp
1108         rpsi2   = 0.5_wp
1109         !
1110         SELECT CASE ( nn_stab_func )
1111         CASE( 0, 1 )   ;   rpsi3m = 2.53_wp       ! G88 or KC stability functions
1112         CASE( 2 )      ;   rpsi3m = 2.62_wp       ! Canuto A stability functions
1113         CASE( 3 )      ;   rpsi3m = 2.38          ! Canuto B stability functions (caution : constant not identified)
1114         END SELECT
1115         !
1116      CASE( 1 )                              ! k-eps
1117         !
1118         IF(lwp) WRITE(numout,*) 'The choosen closure is k-eps'
1119         rpp     =  3._wp
1120         rmm     =  1.5_wp
1121         rnn     = -1._wp
1122         rsc_tke =  1._wp
1123         rsc_psi =  1.2_wp  ! Schmidt number for psi
1124         rpsi1   =  1.44_wp
1125         rpsi3p  =  1._wp
1126         rpsi2   =  1.92_wp
1127         !
1128         SELECT CASE ( nn_stab_func )
1129         CASE( 0, 1 )   ;   rpsi3m = -0.52_wp      ! G88 or KC stability functions
1130         CASE( 2 )      ;   rpsi3m = -0.629_wp     ! Canuto A stability functions
1131         CASE( 3 )      ;   rpsi3m = -0.566        ! Canuto B stability functions
1132         END SELECT
1133         !
1134      CASE( 2 )                              ! k-omega
1135         !
1136         IF(lwp) WRITE(numout,*) 'The choosen closure is k-omega'
1137         rpp     = -1._wp
1138         rmm     =  0.5_wp
1139         rnn     = -1._wp
1140         rsc_tke =  2._wp
1141         rsc_psi =  2._wp
1142         rpsi1   =  0.555_wp
1143         rpsi3p  =  1._wp
1144         rpsi2   =  0.833_wp
1145         !
1146         SELECT CASE ( nn_stab_func )
1147         CASE( 0, 1 )   ;   rpsi3m = -0.58_wp       ! G88 or KC stability functions
1148         CASE( 2 )      ;   rpsi3m = -0.64_wp       ! Canuto A stability functions
1149         CASE( 3 )      ;   rpsi3m = -0.64_wp       ! Canuto B stability functions caution : constant not identified)
1150         END SELECT
1151         !
1152      CASE( 3 )                              ! generic
1153         !
1154         IF(lwp) WRITE(numout,*) 'The choosen closure is generic'
1155         rpp     = 2._wp
1156         rmm     = 1._wp
1157         rnn     = -0.67_wp
1158         rsc_tke = 0.8_wp
1159         rsc_psi = 1.07_wp
1160         rpsi1   = 1._wp
1161         rpsi3p  = 1._wp
1162         rpsi2   = 1.22_wp
1163         !
1164         SELECT CASE ( nn_stab_func )
1165         CASE( 0, 1 )   ;   rpsi3m = 0.1_wp         ! G88 or KC stability functions
1166         CASE( 2 )      ;   rpsi3m = 0.05_wp        ! Canuto A stability functions
1167         CASE( 3 )      ;   rpsi3m = 0.05_wp        ! Canuto B stability functions caution : constant not identified)
1168         END SELECT
1169         !
1170      END SELECT
1171
1172      !
1173      SELECT CASE ( nn_stab_func )     !* set the parameters of the stability functions
1174      !
1175      CASE ( 0 )                             ! Galperin stability functions
1176         !
1177         IF(lwp) WRITE(numout,*) 'Stability functions from Galperin'
1178         rc2     =  0._wp
1179         rc3     =  0._wp
1180         rc_diff =  1._wp
1181         rc0     =  0.5544_wp
1182         rcm_sf  =  0.9884_wp
1183         rghmin  = -0.28_wp
1184         rgh0    =  0.0233_wp
1185         rghcri  =  0.02_wp
1186         !
1187      CASE ( 1 )                             ! Kantha-Clayson stability functions
1188         !
1189         IF(lwp) WRITE(numout,*) 'Stability functions from Kantha-Clayson'
1190         rc2     =  0.7_wp
1191         rc3     =  0.2_wp
1192         rc_diff =  1._wp
1193         rc0     =  0.5544_wp
1194         rcm_sf  =  0.9884_wp
1195         rghmin  = -0.28_wp
1196         rgh0    =  0.0233_wp
1197         rghcri  =  0.02_wp
1198         !
1199      CASE ( 2 )                             ! Canuto A stability functions
1200         !
1201         IF(lwp) WRITE(numout,*) 'Stability functions from Canuto A'
1202         rs0 = 1.5_wp * rl1 * rl5*rl5
1203         rs1 = -rl4*(rl6+rl7) + 2._wp*rl4*rl5*(rl1-(1._wp/3._wp)*rl2-rl3) + 1.5_wp*rl1*rl5*rl8
1204         rs2 = -(3._wp/8._wp) * rl1*(rl6*rl6-rl7*rl7)
1205         rs4 = 2._wp * rl5
1206         rs5 = 2._wp * rl4
1207         rs6 = (2._wp/3._wp) * rl5 * ( 3._wp*rl3*rl3 - rl2*rl2 ) - 0.5_wp * rl5*rl1 * (3._wp*rl3-rl2)   &
1208            &                                                    + 0.75_wp * rl1 * ( rl6 - rl7 )
1209         rd0 = 3._wp * rl5*rl5
1210         rd1 = rl5 * ( 7._wp*rl4 + 3._wp*rl8 )
1211         rd2 = rl5*rl5 * ( 3._wp*rl3*rl3 - rl2*rl2 ) - 0.75_wp*(rl6*rl6 - rl7*rl7 )
1212         rd3 = rl4 * ( 4._wp*rl4 + 3._wp*rl8)
1213         rd4 = rl4 * ( rl2 * rl6 - 3._wp*rl3*rl7 - rl5*(rl2*rl2 - rl3*rl3 ) ) + rl5*rl8 * ( 3._wp*rl3*rl3 - rl2*rl2 )
1214         rd5 = 0.25_wp * ( rl2*rl2 - 3._wp *rl3*rl3 ) * ( rl6*rl6 - rl7*rl7 )
1215         rc0 = 0.5268_wp
1216         rf6 = 8._wp / (rc0**6._wp)
1217         rc_diff = SQRT(2._wp) / (rc0**3._wp)
1218         rcm_sf  =  0.7310_wp
1219         rghmin  = -0.28_wp
1220         rgh0    =  0.0329_wp
1221         rghcri  =  0.03_wp
1222         !
1223      CASE ( 3 )                             ! Canuto B stability functions
1224         !
1225         IF(lwp) WRITE(numout,*) 'Stability functions from Canuto B'
1226         rs0 = 1.5_wp * rm1 * rm5*rm5
1227         rs1 = -rm4 * (rm6+rm7) + 2._wp * rm4*rm5*(rm1-(1._wp/3._wp)*rm2-rm3) + 1.5_wp * rm1*rm5*rm8
1228         rs2 = -(3._wp/8._wp) * rm1 * (rm6*rm6-rm7*rm7 )
1229         rs4 = 2._wp * rm5
1230         rs5 = 2._wp * rm4
1231         rs6 = (2._wp/3._wp) * rm5 * (3._wp*rm3*rm3-rm2*rm2) - 0.5_wp * rm5*rm1*(3._wp*rm3-rm2) + 0.75_wp * rm1*(rm6-rm7)
1232         rd0 = 3._wp * rm5*rm5
1233         rd1 = rm5 * (7._wp*rm4 + 3._wp*rm8)
1234         rd2 = rm5*rm5 * (3._wp*rm3*rm3 - rm2*rm2) - 0.75_wp * (rm6*rm6 - rm7*rm7)
1235         rd3 = rm4 * ( 4._wp*rm4 + 3._wp*rm8 )
1236         rd4 = rm4 * ( rm2*rm6 -3._wp*rm3*rm7 - rm5*(rm2*rm2 - rm3*rm3) ) + rm5 * rm8 * ( 3._wp*rm3*rm3 - rm2*rm2 )
1237         rd5 = 0.25_wp * ( rm2*rm2 - 3._wp*rm3*rm3 ) * ( rm6*rm6 - rm7*rm7 )
1238         rc0 = 0.5268_wp            !!       rc0 = 0.5540_wp (Warner ...) to verify !
1239         rf6 = 8._wp / ( rc0**6._wp )
1240         rc_diff = SQRT(2._wp)/(rc0**3.)
1241         rcm_sf  =  0.7470_wp
1242         rghmin  = -0.28_wp
1243         rgh0    =  0.0444_wp
1244         rghcri  =  0.0414_wp
1245         !
1246      END SELECT
1247   
1248      !                                !* Set Schmidt number for psi diffusion in the wave breaking case
1249      !                                     ! See Eq. (13) of Carniel et al, OM, 30, 225-239, 2009
1250      !                                     !  or Eq. (17) of Burchard, JPO, 31, 3133-3145, 2001
1251      IF( ln_sigpsi ) THEN
1252         ra_sf = -1.5 ! Set kinetic energy slope, then deduce rsc_psi and rl_sf
1253         ! Verification: retrieve Burchard (2001) results by uncomenting the line below:
1254         ! Note that the results depend on the value of rn_cm_sf which is constant (=rc0) in his work
1255         ! ra_sf = -SQRT(2./3.*rc0**3./rn_cm_sf*rn_sc_tke)/vkarmn
1256         rsc_psi0 = rsc_tke/(24.*rpsi2)*(-1.+(4.*rnn + ra_sf*(1.+4.*rmm))**2./(ra_sf**2.))
1257      ELSE
1258         rsc_psi0 = rsc_psi
1259      ENDIF
1260 
1261      !                                !* Shear free turbulence parameters
1262      !
1263      ra_sf  = -4._wp*rnn*SQRT(rsc_tke) / ( (1._wp+4._wp*rmm)*SQRT(rsc_tke) &
1264               &                              - SQRT(rsc_tke + 24._wp*rsc_psi0*rpsi2 ) )
1265
1266      IF( .NOT. ln_phioc .AND. rn_crban_default==0._wp ) THEN
1267         rl_sf = vkarmn
1268      ELSE
1269         rl_sf = rc0 * SQRT(rc0/rcm_sf) * SQRT( ( (1._wp + 4._wp*rmm + 8._wp*rmm**2_wp)*rsc_tke          &
1270                 &                                       + 12._wp * rsc_psi0*rpsi2 - (1._wp + 4._wp*rmm) &
1271                 &                                                *SQRT(rsc_tke*(rsc_tke                 &
1272                 &                                                   + 24._wp*rsc_psi0*rpsi2)) )         &
1273                 &                                         /(12._wp*rnn**2.)                             &
1274                 &                                       )
1275      ENDIF
1276
1277      !
1278      IF(lwp) THEN                     !* Control print
1279         WRITE(numout,*)
1280         WRITE(numout,*) 'Limit values'
1281         WRITE(numout,*) '~~~~~~~~~~~~'
1282         WRITE(numout,*) 'Parameter  m = ',rmm
1283         WRITE(numout,*) 'Parameter  n = ',rnn
1284         WRITE(numout,*) 'Parameter  p = ',rpp
1285         WRITE(numout,*) 'rpsi1   = ',rpsi1
1286         WRITE(numout,*) 'rpsi2   = ',rpsi2
1287         WRITE(numout,*) 'rpsi3m  = ',rpsi3m
1288         WRITE(numout,*) 'rpsi3p  = ',rpsi3p
1289         WRITE(numout,*) 'rsc_tke = ',rsc_tke
1290         WRITE(numout,*) 'rsc_psi = ',rsc_psi
1291         WRITE(numout,*) 'rsc_psi0 = ',rsc_psi0
1292         WRITE(numout,*) 'rc0     = ',rc0
1293         WRITE(numout,*)
1294         WRITE(numout,*) 'Shear free turbulence parameters:'
1295         WRITE(numout,*) 'rcm_sf  = ',rcm_sf
1296         WRITE(numout,*) 'ra_sf   = ',ra_sf
1297         WRITE(numout,*) 'rl_sf   = ',rl_sf
1298         WRITE(numout,*)
1299      ENDIF
1300
1301      !                                !* Constants initialization
1302      rc02  = rc0  * rc0   ;   rc02r = 1. / rc02
1303      rc03  = rc02 * rc0
1304      rc04  = rc03 * rc0
1305      rsbc_tke1_default = -3._wp/2._wp*rn_crban_default*ra_sf*rl_sf
1306      rsbc_tke2         = rdt * rn_crban_default / rl_sf
1307      zcr               = MAX( rsmall, rsbc_tke1_default**(1./(-ra_sf*3._wp/2._wp))-1._wp )
1308      rtrans_default    = 0.2_wp / zcr
1309      rsbc_zs1  = rn_charn/grav                                          ! Charnock formula for surface roughness
1310      rsbc_zs2  = rn_frac_hs / 0.85_wp / grav * 665._wp                  ! Rascle formula for surface roughness
1311      rsbc_psi1 = -0.5_wp * rdt * rc0**(rpp-2._wp*rmm) / rsc_psi
1312      rsbc_psi2 = -0.5_wp * rdt * rc0**rpp * rnn * vkarmn**rnn / rsc_psi ! Neumann + NO Wave breaking
1313
1314      rfact_tke = -0.5_wp / rsc_tke * rdt                                ! Cst used for the Diffusion term of tke
1315      rfact_psi = -0.5_wp / rsc_psi * rdt                                ! Cst used for the Diffusion term of tke
1316
1317      !                                !* Wall proximity function
1318      zwall (:,:,:) = 1._wp * tmask(:,:,:)
1319
1320      !                                !* set vertical eddy coef. to the background value
1321      DO jk = 1, jpk
1322         avt (:,:,jk) = avtb(jk) * tmask(:,:,jk)
1323         avm (:,:,jk) = avmb(jk) * tmask(:,:,jk)
1324         avmu(:,:,jk) = avmb(jk) * umask(:,:,jk)
1325         avmv(:,:,jk) = avmb(jk) * vmask(:,:,jk)
1326      END DO
1327      !                             
1328      CALL gls_rst( nit000, 'READ' )   !* read or initialize all required files
1329      !
1330      IF( nn_timing == 1 )  CALL timing_stop('zdf_gls_init')
1331      !
1332   END SUBROUTINE zdf_gls_init
1333
1334
1335   SUBROUTINE gls_rst( kt, cdrw )
1336      !!---------------------------------------------------------------------
1337      !!                   ***  ROUTINE ts_rst  ***
1338      !!                     
1339      !! ** Purpose :   Read or write TKE file (en) in restart file
1340      !!
1341      !! ** Method  :   use of IOM library
1342      !!                if the restart does not contain TKE, en is either
1343      !!                set to rn_emin or recomputed (nn_igls/=0)
1344      !!----------------------------------------------------------------------
1345      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
1346      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
1347      !
1348      INTEGER ::   jit, jk   ! dummy loop indices
1349      INTEGER ::   id1, id2, id3, id4, id5, id6
1350      INTEGER ::   ji, jj, ikbu, ikbv
1351      REAL(wp)::   cbx, cby
1352      !!----------------------------------------------------------------------
1353      !
1354      IF( TRIM(cdrw) == 'READ' ) THEN        ! Read/initialise
1355         !                                   ! ---------------
1356         IF( ln_rstart ) THEN                   !* Read the restart file
1357            id1 = iom_varid( numror, 'en'   , ldstop = .FALSE. )
1358            id2 = iom_varid( numror, 'avt'  , ldstop = .FALSE. )
1359            id3 = iom_varid( numror, 'avm'  , ldstop = .FALSE. )
1360            id4 = iom_varid( numror, 'avmu' , ldstop = .FALSE. )
1361            id5 = iom_varid( numror, 'avmv' , ldstop = .FALSE. )
1362            id6 = iom_varid( numror, 'mxln' , ldstop = .FALSE. )
1363            !
1364            IF( MIN( id1, id2, id3, id4, id5, id6 ) > 0 ) THEN        ! all required arrays exist
1365               CALL iom_get( numror, jpdom_autoglo, 'en'    , en     )
1366               CALL iom_get( numror, jpdom_autoglo, 'avt'   , avt    )
1367               CALL iom_get( numror, jpdom_autoglo, 'avm'   , avm    )
1368               CALL iom_get( numror, jpdom_autoglo, 'avmu'  , avmu   )
1369               CALL iom_get( numror, jpdom_autoglo, 'avmv'  , avmv   )
1370               CALL iom_get( numror, jpdom_autoglo, 'mxln'  , mxln   )
1371            ELSE                       
1372               IF(lwp) WRITE(numout,*) ' ===>>>> : previous run without gls scheme, en and mxln computed by iterative loop'
1373               en  (:,:,:) = rn_emin
1374               mxln(:,:,:) = 0.05       
1375               avt_k (:,:,:) = avt (:,:,:)
1376               avm_k (:,:,:) = avm (:,:,:)
1377               avmu_k(:,:,:) = avmu(:,:,:)
1378               avmv_k(:,:,:) = avmv(:,:,:)
1379               DO jit = nit000 + 1, nit000 + 10   ;   CALL zdf_gls( jit )   ;   END DO
1380            ENDIF
1381         ELSE                                   !* Start from rest
1382            IF(lwp) WRITE(numout,*) ' ===>>>> : Initialisation of en and mxln by background values'
1383            en  (:,:,:) = rn_emin
1384            mxln(:,:,:) = 0.05       
1385         ENDIF
1386         !
1387      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN   ! Create restart file
1388         !                                   ! -------------------
1389         IF(lwp) WRITE(numout,*) '---- gls-rst ----'
1390         CALL iom_rstput( kt, nitrst, numrow, 'en'   , en     ) 
1391         CALL iom_rstput( kt, nitrst, numrow, 'avt'  , avt_k  )
1392         CALL iom_rstput( kt, nitrst, numrow, 'avm'  , avm_k  )
1393         CALL iom_rstput( kt, nitrst, numrow, 'avmu' , avmu_k ) 
1394         CALL iom_rstput( kt, nitrst, numrow, 'avmv' , avmv_k )
1395         CALL iom_rstput( kt, nitrst, numrow, 'mxln' , mxln   )
1396         !
1397      ENDIF
1398      !
1399   END SUBROUTINE gls_rst
1400
1401#else
1402   !!----------------------------------------------------------------------
1403   !!   Dummy module :                                        NO TKE scheme
1404   !!----------------------------------------------------------------------
1405   LOGICAL, PUBLIC, PARAMETER ::   lk_zdfgls = .FALSE.   !: TKE flag
1406CONTAINS
1407   SUBROUTINE zdf_gls_init           ! Empty routine
1408      WRITE(*,*) 'zdf_gls_init: You should not have seen this print! error?'
1409   END SUBROUTINE zdf_gls_init
1410   SUBROUTINE zdf_gls( kt )          ! Empty routine
1411      WRITE(*,*) 'zdf_gls: You should not have seen this print! error?', kt
1412   END SUBROUTINE zdf_gls
1413   SUBROUTINE gls_rst( kt, cdrw )          ! Empty routine
1414      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
1415      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
1416      WRITE(*,*) 'gls_rst: You should not have seen this print! error?', kt, cdrw
1417   END SUBROUTINE gls_rst
1418#endif
1419
1420   !!======================================================================
1421END MODULE zdfgls
1422
Note: See TracBrowser for help on using the repository browser.