New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zdfgls.F90 in branches/UKMO/r6232_HZG_WAVE-coupling/NEMOGCM/NEMO/OPA_SRC/ZDF – NEMO

source: branches/UKMO/r6232_HZG_WAVE-coupling/NEMOGCM/NEMO/OPA_SRC/ZDF/zdfgls.F90 @ 9462

Last change on this file since 9462 was 9462, checked in by jcastill, 6 years ago

Rearrange some lines so that it merges with operational branches
File size: 67.2 KB
Line 
1MODULE zdfgls
2   !!======================================================================
3   !!                       ***  MODULE  zdfgls  ***
4   !! Ocean physics:  vertical mixing coefficient computed from the gls
5   !!                 turbulent closure parameterization
6   !!======================================================================
7   !! History :   3.0  !  2009-09  (G. Reffray)  Original code
8   !!             3.3  !  2010-10  (C. Bricaud)  Add in the reference
9   !!----------------------------------------------------------------------
10#if defined key_zdfgls   ||   defined key_esopa
11   !!----------------------------------------------------------------------
12   !!   'key_zdfgls'                 Generic Length Scale vertical physics
13   !!----------------------------------------------------------------------
14   !!   zdf_gls       : update momentum and tracer Kz from a gls scheme
15   !!   zdf_gls_init  : initialization, namelist read, and parameters control
16   !!   gls_rst       : read/write gls restart in ocean restart file
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE dom_oce        ! ocean space and time domain
20   USE domvvl         ! ocean space and time domain : variable volume layer
21   USE zdf_oce        ! ocean vertical physics
22   USE zdfbfr         ! bottom friction (only for rn_bfrz0)
23   USE sbc_oce        ! surface boundary condition: ocean
24   USE phycst         ! physical constants
25   USE zdfmxl         ! mixed layer
26   USE sbcwave
27   !
28   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
29   USE lib_mpp        ! MPP manager
30   USE wrk_nemo       ! work arrays
31   USE prtctl         ! Print control
32   USE in_out_manager ! I/O manager
33   USE iom            ! I/O manager library
34   USE timing         ! Timing
35   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
36
37   IMPLICIT NONE
38   PRIVATE
39
40   PUBLIC   zdf_gls        ! routine called in step module
41   PUBLIC   zdf_gls_init   ! routine called in opa module
42   PUBLIC   gls_rst        ! routine called in step module
43
44   LOGICAL , PUBLIC, PARAMETER ::   lk_zdfgls = .TRUE.   !: TKE vertical mixing flag
45   !
46   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   mxln    !: now mixing length
47   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   zwall   !: wall function
48   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   ustars2 !: Squared surface velocity scale at T-points
49   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   ustarb2 !: Squared bottom  velocity scale at T-points
50
51   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   rsbc_tke1
52   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   rsbc_tke3
53   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   rsbc_psi1
54   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   rtrans
55
56   !                              !! ** Namelist  namzdf_gls  **
57   LOGICAL  ::   ln_length_lim     ! use limit on the dissipation rate under stable stratification (Galperin et al. 1988)
58   LOGICAL  ::   ln_sigpsi         ! Activate Burchard (2003) modification for k-eps closure & wave breaking mixing
59   INTEGER  ::   nn_bc_surf        ! surface boundary condition (=0/1)
60   INTEGER  ::   nn_bc_bot         ! bottom boundary condition (=0/1)
61   INTEGER  ::   nn_z0_met         ! Method for surface roughness computation
62   INTEGER  ::   nn_stab_func      ! stability functions G88, KC or Canuto (=0/1/2)
63   INTEGER  ::   nn_clos           ! closure 0/1/2/3 MY82/k-eps/k-w/gen
64   REAL(wp) ::   rn_clim_galp      ! Holt 2008 value for k-eps: 0.267
65   REAL(wp) ::   rn_epsmin         ! minimum value of dissipation (m2/s3)
66   REAL(wp) ::   rn_emin           ! minimum value of TKE (m2/s2)
67   REAL(wp) ::   rn_charn          ! Charnock constant for surface breaking waves mixing : 1400. (standard) or 2.e5 (Stacey value)
68   REAL(wp) ::   rn_crban_default  ! Craig and Banner constant for surface breaking waves mixing
69   REAL(wp) ::   rn_hsro           ! Minimum surface roughness
70   REAL(wp) ::   rn_frac_hs        ! Fraction of wave height as surface roughness (if nn_z0_met = 1, 3)
71
72   REAL(wp) ::   rcm_sf        =  0.73_wp     ! Shear free turbulence parameters
73   REAL(wp) ::   ra_sf         = -2.0_wp      ! Must be negative -2 < ra_sf < -1
74   REAL(wp) ::   rl_sf         =  0.2_wp      ! 0 <rl_sf<vkarmn   
75   REAL(wp) ::   rghmin        = -0.28_wp
76   REAL(wp) ::   rgh0          =  0.0329_wp
77   REAL(wp) ::   rghcri        =  0.03_wp
78   REAL(wp) ::   ra1           =  0.92_wp
79   REAL(wp) ::   ra2           =  0.74_wp
80   REAL(wp) ::   rb1           = 16.60_wp
81   REAL(wp) ::   rb2           = 10.10_wp         
82   REAL(wp) ::   re2           =  1.33_wp         
83   REAL(wp) ::   rl1           =  0.107_wp
84   REAL(wp) ::   rl2           =  0.0032_wp
85   REAL(wp) ::   rl3           =  0.0864_wp
86   REAL(wp) ::   rl4           =  0.12_wp
87   REAL(wp) ::   rl5           = 11.9_wp
88   REAL(wp) ::   rl6           =  0.4_wp
89   REAL(wp) ::   rl7           =  0.0_wp
90   REAL(wp) ::   rl8           =  0.48_wp
91   REAL(wp) ::   rm1           =  0.127_wp
92   REAL(wp) ::   rm2           =  0.00336_wp
93   REAL(wp) ::   rm3           =  0.0906_wp
94   REAL(wp) ::   rm4           =  0.101_wp
95   REAL(wp) ::   rm5           = 11.2_wp
96   REAL(wp) ::   rm6           =  0.4_wp
97   REAL(wp) ::   rm7           =  0.0_wp
98   REAL(wp) ::   rm8           =  0.318_wp
99   REAL(wp) ::   rtrans_default =  0.1_wp
100   REAL(wp) ::   rc02, rc02r, rc03, rc04                          ! coefficients deduced from above parameters
101   REAL(wp) ::   rsbc_tke1_default, rsbc_tke2, rfact_tke          !     -           -           -        -
102   REAL(wp) ::   rsbc_psi2, rsbc_psi3, rfact_psi                  !     -           -           -        -
103   REAL(wp) ::   rsbc_zs1, rsbc_zs2                               !     -           -           -        -
104   REAL(wp) ::   rc0, rc2, rc3, rf6, rcff, rc_diff                !     -           -           -        -
105   REAL(wp) ::   rs0, rs1, rs2, rs4, rs5, rs6                     !     -           -           -        -
106   REAL(wp) ::   rd0, rd1, rd2, rd3, rd4, rd5                     !     -           -           -        -
107   REAL(wp) ::   rsc_tke, rsc_psi, rpsi1, rpsi2, rpsi3, rsc_psi0  !     -           -           -        -
108   REAL(wp) ::   rpsi3m, rpsi3p, rpp, rmm, rnn                    !     -           -           -        -
109
110   !! * Substitutions
111#  include "domzgr_substitute.h90"
112#  include "vectopt_loop_substitute.h90"
113   !!----------------------------------------------------------------------
114   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
115   !! $Id$
116   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
117   !!----------------------------------------------------------------------
118CONTAINS
119
120   INTEGER FUNCTION zdf_gls_alloc()
121      !!----------------------------------------------------------------------
122      !!                ***  FUNCTION zdf_gls_alloc  ***
123      !!----------------------------------------------------------------------
124      ALLOCATE( mxln(jpi,jpj,jpk) , zwall(jpi,jpj,jpk) ,     &
125         &      ustars2(jpi,jpj)  , ustarb2(jpi,jpj)   ,     &
126         &      rsbc_tke1(jpi,jpj), rsbc_tke3(jpi,jpj) ,     &
127         &      rsbc_psi1(jpi,jpj), rtrans(jpi,jpj), STAT= zdf_gls_alloc )
128         !
129      IF( lk_mpp             )   CALL mpp_sum ( zdf_gls_alloc )
130      IF( zdf_gls_alloc /= 0 )   CALL ctl_warn('zdf_gls_alloc: failed to allocate arrays')
131   END FUNCTION zdf_gls_alloc
132
133
134   SUBROUTINE zdf_gls( kt )
135      !!----------------------------------------------------------------------
136      !!                   ***  ROUTINE zdf_gls  ***
137      !!
138      !! ** Purpose :   Compute the vertical eddy viscosity and diffusivity
139      !!              coefficients using the GLS turbulent closure scheme.
140      !!----------------------------------------------------------------------
141      INTEGER, INTENT(in) ::   kt ! ocean time step
142      INTEGER  ::   ji, jj, jk, ibot, ibotm1, dir  ! dummy loop arguments
143      REAL(wp) ::   zesh2, zsigpsi, zcoef, zex1, zex2   ! local scalars
144      REAL(wp) ::   ztx2, zty2, zup, zdown, zcof        !   -      -
145      REAL(wp) ::   zratio, zrn2, zflxb, sh             !   -      -
146      REAL(wp) ::   prod, buoy, diss, zdiss, sm         !   -      -
147      REAL(wp) ::   gh, gm, shr, dif, zsqen, zav        !   -      -
148      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zdep
149      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zkar
150      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zflxs       ! Turbulence fluxed induced by internal waves
151      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zhsro       ! Surface roughness (surface waves)
152      REAL(wp), POINTER, DIMENSION(:,:,:) ::   eb          ! tke at time before
153      REAL(wp), POINTER, DIMENSION(:,:,:) ::   mxlb        ! mixing length at time before
154      REAL(wp), POINTER, DIMENSION(:,:,:) ::   shear       ! vertical shear
155      REAL(wp), POINTER, DIMENSION(:,:,:) ::   eps         ! dissipation rate
156      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zwall_psi   ! Wall function use in the wb case (ln_sigpsi)
157      REAL(wp), POINTER, DIMENSION(:,:,:) ::   psi         ! psi at time now
158      REAL(wp), POINTER, DIMENSION(:,:,:) ::   z_elem_a    ! element of the first  matrix diagonal
159      REAL(wp), POINTER, DIMENSION(:,:,:) ::   z_elem_b    ! element of the second matrix diagonal
160      REAL(wp), POINTER, DIMENSION(:,:,:) ::   z_elem_c    ! element of the third  matrix diagonal
161      !!--------------------------------------------------------------------
162      !
163      IF( nn_timing == 1 )  CALL timing_start('zdf_gls')
164      !
165      CALL wrk_alloc( jpi,jpj, zdep, zkar, zflxs, zhsro )
166      CALL wrk_alloc( jpi,jpj,jpk, eb, mxlb, shear, eps, zwall_psi, z_elem_a, z_elem_b, z_elem_c, psi  )
167     
168      ! Preliminary computing
169
170      ustars2 = 0._wp   ;   ustarb2 = 0._wp   ;   psi  = 0._wp   ;   zwall_psi = 0._wp
171
172
173      ! variable initialization
174      IF( ln_phioc ) THEN
175         IF( nn_wmix==jp_janssen ) THEN
176            rsbc_tke1(:,:) = (-rsc_tke*rn_crban(:,:)/(rcm_sf*ra_sf*rl_sf))**(2._wp/3._wp)  ! k_eps = 53.Dirichlet + Wave breaking
177            rsbc_tke3(:,:) = rdt * rn_crban(:,:)                                           ! Neumann + Wave breaking
178            rsbc_psi1(:,:) = rc0**rpp * rsbc_tke1(:,:)**rmm * rl_sf**rnn                   ! Dirichlet + Wave breaking
179         ELSE IF( nn_wmix==jp_craigbanner ) THEN
180            rsbc_tke1(:,:) = -3._wp/2._wp*rn_crban(:,:)*ra_sf*rl_sf
181            rsbc_tke3(:,:) = rdt * rn_crban(:,:) / rl_sf
182            rtrans(:,:) = 0.2_wp / MAX( rsmall, rsbc_tke1(:,:)**(1./(-ra_sf*3._wp/2._wp))-1._wp )
183         ENDIF
184      ENDIF
185
186      IF( kt /= nit000 ) THEN   ! restore before value to compute tke
187         avt (:,:,:) = avt_k (:,:,:)
188         avm (:,:,:) = avm_k (:,:,:)
189         avmu(:,:,:) = avmu_k(:,:,:)
190         avmv(:,:,:) = avmv_k(:,:,:) 
191      ENDIF
192
193      ! Compute surface and bottom friction at T-points
194!CDIR NOVERRCHK         
195      DO jj = 2, jpjm1         
196!CDIR NOVERRCHK         
197         DO ji = fs_2, fs_jpim1   ! vector opt.         
198            !
199            ! surface friction
200            ustars2(ji,jj) = r1_rau0 * taum(ji,jj) * tmask(ji,jj,1)
201            !   
202            ! bottom friction (explicit before friction)       
203            ! Note that we chose here not to bound the friction as in dynbfr)   
204            ztx2 = (  bfrua(ji,jj)  * ub(ji,jj,mbku(ji,jj)) + bfrua(ji-1,jj) * ub(ji-1,jj,mbku(ji-1,jj))  )   &         
205               & * ( 1._wp - 0.5_wp * umask(ji,jj,1) * umask(ji-1,jj,1)  )     
206            zty2 = (  bfrva(ji,jj)  * vb(ji,jj,mbkv(ji,jj)) + bfrva(ji,jj-1) * vb(ji,jj-1,mbkv(ji,jj-1))  )   &         
207               & * ( 1._wp - 0.5_wp * vmask(ji,jj,1) * vmask(ji,jj-1,1)  )     
208            ustarb2(ji,jj) = SQRT( ztx2 * ztx2 + zty2 * zty2 ) * tmask(ji,jj,1)         
209         END DO         
210      END DO   
211
212      ! Set surface roughness length
213      SELECT CASE ( nn_z0_met )
214      !
215      CASE ( 0 )             ! Constant roughness         
216         zhsro(:,:) = rn_hsro
217      CASE ( 1 )             ! Standard Charnock formula
218         zhsro(:,:) = MAX(rsbc_zs1 * ustars2(:,:), rn_hsro)
219      CASE ( 2 )             ! Roughness formulae according to Rascle et al., Ocean Modelling (2008)
220         zdep(:,:)  = 30.*TANH(2.*0.3/(28.*SQRT(MAX(ustars2(:,:),rsmall))))             ! Wave age (eq. 10)
221         zhsro(:,:) = MAX(rsbc_zs2 * ustars2(:,:) * zdep(:,:)**1.5, rn_hsro) ! zhsro = rn_frac_hs * Hsw (eq. 11)
222      CASE ( 3 )             ! Roughness given by the wave model (coupled or read in file)
223         zhsro = MAX(rn_frac_hs * hsw, rn_hsro)
224      END SELECT
225
226      ! Compute shear and dissipation rate
227      DO jk = 2, jpkm1
228         DO jj = 2, jpjm1
229            DO ji = fs_2, fs_jpim1   ! vector opt.
230               avmu(ji,jj,jk) = avmu(ji,jj,jk) * ( un(ji,jj,jk-1) - un(ji,jj,jk) )   &
231                  &                            * ( ub(ji,jj,jk-1) - ub(ji,jj,jk) )   &
232                  &                            / (  fse3uw_n(ji,jj,jk)               &
233                  &                            *    fse3uw_b(ji,jj,jk) )
234               avmv(ji,jj,jk) = avmv(ji,jj,jk) * ( vn(ji,jj,jk-1) - vn(ji,jj,jk) )   &
235                  &                            * ( vb(ji,jj,jk-1) - vb(ji,jj,jk) )   &
236                  &                            / (  fse3vw_n(ji,jj,jk)               &
237                  &                            *    fse3vw_b(ji,jj,jk) )
238               eps(ji,jj,jk)  = rc03 * en(ji,jj,jk) * SQRT(en(ji,jj,jk)) / mxln(ji,jj,jk)
239            END DO
240         END DO
241      END DO
242      !
243      ! Lateral boundary conditions (avmu,avmv) (sign unchanged)
244      CALL lbc_lnk( avmu, 'U', 1. )   ;   CALL lbc_lnk( avmv, 'V', 1. )
245
246      ! Save tke at before time step
247      eb  (:,:,:) = en  (:,:,:)
248      mxlb(:,:,:) = mxln(:,:,:)
249
250      IF( nn_clos == 0 ) THEN    ! Mellor-Yamada
251         DO jk = 2, jpkm1
252            DO jj = 2, jpjm1 
253               DO ji = fs_2, fs_jpim1   ! vector opt.
254                  zup   = mxln(ji,jj,jk) * fsdepw(ji,jj,mbkt(ji,jj)+1)
255                  zdown = vkarmn * fsdepw(ji,jj,jk) * ( -fsdepw(ji,jj,jk) + fsdepw(ji,jj,mbkt(ji,jj)+1) )
256                  zcoef = ( zup / MAX( zdown, rsmall ) )
257                  zwall (ji,jj,jk) = ( 1._wp + re2 * zcoef*zcoef ) * tmask(ji,jj,jk)
258               END DO
259            END DO
260         END DO
261      ENDIF
262
263      !!---------------------------------!!
264      !!   Equation to prognostic k      !!
265      !!---------------------------------!!
266      !
267      ! Now Turbulent kinetic energy (output in en)
268      ! -------------------------------
269      ! Resolution of a tridiagonal linear system by a "methode de chasse"
270      ! computation from level 2 to jpkm1  (e(1) computed after and e(jpk)=0 ).
271      ! The surface boundary condition are set after
272      ! The bottom boundary condition are also set after. In standard e(bottom)=0.
273      ! z_elem_b : diagonal z_elem_c : upper diagonal z_elem_a : lower diagonal
274      ! Warning : after this step, en : right hand side of the matrix
275
276      DO jk = 2, jpkm1
277         DO jj = 2, jpjm1
278            DO ji = fs_2, fs_jpim1   ! vector opt.
279               !
280               ! shear prod. at w-point weightened by mask
281               shear(ji,jj,jk) =  ( avmu(ji-1,jj,jk) + avmu(ji,jj,jk) ) / MAX( 1.e0 , umask(ji-1,jj,jk) + umask(ji,jj,jk) )   &
282                  &             + ( avmv(ji,jj-1,jk) + avmv(ji,jj,jk) ) / MAX( 1.e0 , vmask(ji,jj-1,jk) + vmask(ji,jj,jk) )
283               !
284               ! stratif. destruction
285               buoy = - avt(ji,jj,jk) * rn2(ji,jj,jk)
286               !
287               ! shear prod. - stratif. destruction
288               diss = eps(ji,jj,jk)
289               !
290               dir = 0.5_wp + SIGN( 0.5_wp, shear(ji,jj,jk) + buoy )   ! dir =1(=0) if shear(ji,jj,jk)+buoy >0(<0)
291               !
292               zesh2 = dir*(shear(ji,jj,jk)+buoy)+(1._wp-dir)*shear(ji,jj,jk)          ! production term
293               zdiss = dir*(diss/en(ji,jj,jk))   +(1._wp-dir)*(diss-buoy)/en(ji,jj,jk) ! dissipation term
294               !
295               ! Compute a wall function from 1. to rsc_psi*zwall/rsc_psi0
296               ! Note that as long that Dirichlet boundary conditions are NOT set at the first and last levels (GOTM style)
297               ! there is no need to set a boundary condition for zwall_psi at the top and bottom boundaries.
298               ! Otherwise, this should be rsc_psi/rsc_psi0
299               IF( ln_sigpsi ) THEN
300                  zsigpsi = MIN( 1._wp, zesh2 / eps(ji,jj,jk) )     ! 0. <= zsigpsi <= 1.
301                  zwall_psi(ji,jj,jk) = rsc_psi /   & 
302                     &     (  zsigpsi * rsc_psi + (1._wp-zsigpsi) * rsc_psi0 / MAX( zwall(ji,jj,jk), 1._wp )  )
303               ELSE
304                  zwall_psi(ji,jj,jk) = 1._wp
305               ENDIF
306               !
307               ! building the matrix
308               zcof = rfact_tke * tmask(ji,jj,jk)
309               !
310               ! lower diagonal
311               z_elem_a(ji,jj,jk) = zcof * ( avm  (ji,jj,jk  ) + avm  (ji,jj,jk-1) )   &
312                  &                      / ( fse3t(ji,jj,jk-1) * fse3w(ji,jj,jk  ) )
313               !
314               ! upper diagonal
315               z_elem_c(ji,jj,jk) = zcof * ( avm  (ji,jj,jk+1) + avm  (ji,jj,jk  ) )   &
316                  &                      / ( fse3t(ji,jj,jk  ) * fse3w(ji,jj,jk) )
317               !
318               ! diagonal
319               z_elem_b(ji,jj,jk) = 1._wp - z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk)  &
320                  &                       + rdt * zdiss * tmask(ji,jj,jk) 
321               !
322               ! right hand side in en
323               en(ji,jj,jk) = en(ji,jj,jk) + rdt * zesh2 * tmask(ji,jj,jk)
324            END DO
325         END DO
326      END DO
327      !
328      z_elem_b(:,:,jpk) = 1._wp
329      !
330      ! Set surface condition on zwall_psi (1 at the bottom)
331      zwall_psi(:,:,1) = zwall_psi(:,:,2)
332      zwall_psi(:,:,jpk) = 1.
333      !
334      ! Surface boundary condition on tke
335      ! ---------------------------------
336      !
337      IF( ln_phioc ) THEN
338         SELECT CASE ( nn_bc_surf )
339         !
340         CASE ( 0 )             ! Dirichlet case
341            IF( nn_wmix==jp_janssen ) THEN
342               ! First level
343               en(:,:,1) = MAX( rsbc_tke1(:,:) * ustars2(:,:), rn_emin )
344               z_elem_a(:,:,1) = en(:,:,1)
345               z_elem_c(:,:,1) = 0._wp
346               z_elem_b(:,:,1) = 1._wp
347
348               ! One level below
349               en(:,:,2) = MAX( rsbc_tke1(:,:) * ustars2(:,:) * ((zhsro(:,:)+fsdepw(:,:,2))/zhsro(:,:) )**ra_sf, rn_emin )
350               z_elem_a(:,:,2) = 0._wp
351               z_elem_c(:,:,2) = 0._wp
352               z_elem_b(:,:,2) = 1._wp
353            ELSE IF( nn_wmix==jp_craigbanner ) THEN
354               en(:,:,1) = rc02r * ustars2(:,:) * (1._wp + rsbc_tke1(:,:))**(2._wp/3._wp)
355               en(:,:,1) = MAX(en(:,:,1), rn_emin) 
356               z_elem_a(:,:,1) = en(:,:,1)
357               z_elem_c(:,:,1) = 0._wp
358               z_elem_b(:,:,1) = 1._wp
359               !
360               ! One level below
361               en(:,:,2) = rc02r * ustars2(:,:) * (1._wp + rsbc_tke1(:,:) * ((zhsro(:,:)+fsdepw(:,:,2)) &
362                   &            / zhsro(:,:) )**(1.5_wp*ra_sf))**(2._wp/3._wp)
363               en(:,:,2) = MAX(en(:,:,2), rn_emin )
364               z_elem_a(:,:,2) = 0._wp 
365               z_elem_c(:,:,2) = 0._wp
366               z_elem_b(:,:,2) = 1._wp
367               !
368            ENDIF
369         CASE ( 1 )             ! Neumann boundary condition on d(e)/dz
370            IF( nn_wmix==jp_janssen ) THEN
371               ! Dirichlet conditions at k=1
372               en(:,:,1) = MAX( rsbc_tke1(:,:) * ustars2(:,:), rn_emin )
373               z_elem_a(:,:,1) = en(:,:,1)
374               z_elem_c(:,:,1) = 0._wp
375               z_elem_b(:,:,1) = 1._wp
376               ! at k=2, set de/dz=Fw
377               z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
378               z_elem_a(:,:,2) = 0._wp
379               zflxs(:,:) = rsbc_tke3(:,:) * ustars2(:,:)**1.5_wp * ((zhsro(:,:)+fsdept(:,:,1) ) / zhsro(:,:) )**(1.5*ra_sf)
380               en(:,:,2) = en(:,:,2) + zflxs(:,:) / fse3w(:,:,2)
381            ELSE IF( nn_wmix==jp_craigbanner ) THEN
382               ! Dirichlet conditions at k=1
383               en(:,:,1)       = rc02r * ustars2(:,:) * (1._wp + rsbc_tke1(:,:))**(2._wp/3._wp)
384               en(:,:,1)       = MAX(en(:,:,1), rn_emin)     
385               z_elem_a(:,:,1) = en(:,:,1)
386               z_elem_c(:,:,1) = 0._wp
387               z_elem_b(:,:,1) = 1._wp
388               !
389               ! at k=2, set de/dz=Fw
390               !cbr
391               z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
392               z_elem_a(:,:,2) = 0._wp
393               zkar(:,:)       = (rl_sf + (vkarmn-rl_sf)*(1.-exp(-rtrans(:,:)*fsdept(:,:,1)/zhsro(:,:)) ))
394               zflxs(:,:)      = rsbc_tke3(:,:) * ustars2(:,:)**1.5_wp * zkar(:,:) &
395                    &                           * ((zhsro(:,:)+fsdept(:,:,1))/zhsro(:,:) )**(1.5_wp*ra_sf)
396
397               en(:,:,2) = en(:,:,2) + zflxs(:,:)/fse3w(:,:,2)
398               !
399            ENDIF
400         END SELECT
401      ELSE
402      SELECT CASE ( nn_bc_surf )
403      !
404      CASE ( 0 )             ! Dirichlet case
405      ! First level
406      en(:,:,1) = rc02r * ustars2(:,:) * (1._wp + rsbc_tke1_default)**(2._wp/3._wp)
407      en(:,:,1) = MAX(en(:,:,1), rn_emin) 
408      z_elem_a(:,:,1) = en(:,:,1)
409      z_elem_c(:,:,1) = 0._wp
410      z_elem_b(:,:,1) = 1._wp
411      !
412      ! One level below
413      en(:,:,2) = rc02r * ustars2(:,:) * (1._wp + rsbc_tke1_default * ((zhsro(:,:)+fsdepw(:,:,2)) &
414          &            / zhsro(:,:) )**(1.5_wp*ra_sf))**(2._wp/3._wp)
415      en(:,:,2) = MAX(en(:,:,2), rn_emin )
416      z_elem_a(:,:,2) = 0._wp 
417      z_elem_c(:,:,2) = 0._wp
418      z_elem_b(:,:,2) = 1._wp
419      !
420      !
421      CASE ( 1 )             ! Neumann boundary condition on d(e)/dz
422      ! Dirichlet conditions at k=1
423      en(:,:,1)       = rc02r * ustars2(:,:) * (1._wp + rsbc_tke1_default)**(2._wp/3._wp)
424      en(:,:,1)       = MAX(en(:,:,1), rn_emin)     
425      z_elem_a(:,:,1) = en(:,:,1)
426      z_elem_c(:,:,1) = 0._wp
427      z_elem_b(:,:,1) = 1._wp
428      !
429      ! at k=2, set de/dz=Fw
430      !cbr
431      z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
432      z_elem_a(:,:,2) = 0._wp
433      zkar(:,:)       = (rl_sf + (vkarmn-rl_sf)*(1.-exp(-rtrans_default*fsdept(:,:,1)/zhsro(:,:)) ))
434      zflxs(:,:)      = rsbc_tke2 * ustars2(:,:)**1.5_wp * zkar(:,:) &
435           &                      * ((zhsro(:,:)+fsdept(:,:,1))/zhsro(:,:) )**(1.5_wp*ra_sf)
436
437      en(:,:,2) = en(:,:,2) + zflxs(:,:)/fse3w(:,:,2)
438      !
439      !
440      END SELECT
441      ENDIF ! ln_phioc
442
443      ! Bottom boundary condition on tke
444      ! --------------------------------
445      !
446      SELECT CASE ( nn_bc_bot )
447      !
448      CASE ( 0 )             ! Dirichlet
449         !                      ! en(ibot) = u*^2 / Co2 and mxln(ibot) = rn_lmin
450         !                      ! Balance between the production and the dissipation terms
451!CDIR NOVERRCHK
452         DO jj = 2, jpjm1
453!CDIR NOVERRCHK
454            DO ji = fs_2, fs_jpim1   ! vector opt.
455               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
456               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
457               !
458               ! Bottom level Dirichlet condition:
459               z_elem_a(ji,jj,ibot  ) = 0._wp
460               z_elem_c(ji,jj,ibot  ) = 0._wp
461               z_elem_b(ji,jj,ibot  ) = 1._wp
462               en(ji,jj,ibot  ) = MAX( rc02r * ustarb2(ji,jj), rn_emin )
463               !
464               ! Just above last level, Dirichlet condition again
465               z_elem_a(ji,jj,ibotm1) = 0._wp
466               z_elem_c(ji,jj,ibotm1) = 0._wp
467               z_elem_b(ji,jj,ibotm1) = 1._wp
468               en(ji,jj,ibotm1) = MAX( rc02r * ustarb2(ji,jj), rn_emin ) 
469            END DO
470         END DO
471         !
472      CASE ( 1 )             ! Neumman boundary condition
473         !                     
474!CDIR NOVERRCHK
475         DO jj = 2, jpjm1
476!CDIR NOVERRCHK
477            DO ji = fs_2, fs_jpim1   ! vector opt.
478               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
479               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
480               !
481               ! Bottom level Dirichlet condition:
482               z_elem_a(ji,jj,ibot) = 0._wp
483               z_elem_c(ji,jj,ibot) = 0._wp
484               z_elem_b(ji,jj,ibot) = 1._wp
485               en(ji,jj,ibot) = MAX( rc02r * ustarb2(ji,jj), rn_emin )
486               !
487               ! Just above last level: Neumann condition
488               z_elem_b(ji,jj,ibotm1) = z_elem_b(ji,jj,ibotm1) + z_elem_c(ji,jj,ibotm1)   ! Remove z_elem_c from z_elem_b
489               z_elem_c(ji,jj,ibotm1) = 0._wp
490            END DO
491         END DO
492         !
493      END SELECT
494
495      ! Matrix inversion (en prescribed at surface and the bottom)
496      ! ----------------------------------------------------------
497      !
498      DO jk = 2, jpkm1                             ! First recurrence : Dk = Dk - Lk * Uk-1 / Dk-1
499         DO jj = 2, jpjm1
500            DO ji = fs_2, fs_jpim1    ! vector opt.
501               z_elem_b(ji,jj,jk) = z_elem_b(ji,jj,jk) - z_elem_a(ji,jj,jk) * z_elem_c(ji,jj,jk-1) / z_elem_b(ji,jj,jk-1)
502            END DO
503         END DO
504      END DO
505      DO jk = 2, jpk                               ! Second recurrence : Lk = RHSk - Lk / Dk-1 * Lk-1
506         DO jj = 2, jpjm1
507            DO ji = fs_2, fs_jpim1    ! vector opt.
508               z_elem_a(ji,jj,jk) = en(ji,jj,jk) - z_elem_a(ji,jj,jk) / z_elem_b(ji,jj,jk-1) * z_elem_a(ji,jj,jk-1)
509            END DO
510         END DO
511      END DO
512      DO jk = jpk-1, 2, -1                         ! thrid recurrence : Ek = ( Lk - Uk * Ek+1 ) / Dk
513         DO jj = 2, jpjm1
514            DO ji = fs_2, fs_jpim1    ! vector opt.
515               en(ji,jj,jk) = ( z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk) * en(ji,jj,jk+1) ) / z_elem_b(ji,jj,jk)
516            END DO
517         END DO
518      END DO
519      !                                            ! set the minimum value of tke
520      en(:,:,:) = MAX( en(:,:,:), rn_emin )
521
522      !!----------------------------------------!!
523      !!   Solve prognostic equation for psi    !!
524      !!----------------------------------------!!
525
526      ! Set psi to previous time step value
527      !
528      SELECT CASE ( nn_clos )
529      !
530      CASE( 0 )               ! k-kl  (Mellor-Yamada)
531         DO jk = 2, jpkm1
532            DO jj = 2, jpjm1
533               DO ji = fs_2, fs_jpim1   ! vector opt.
534                  psi(ji,jj,jk)  = eb(ji,jj,jk) * mxlb(ji,jj,jk)
535               END DO
536            END DO
537         END DO
538         !
539      CASE( 1 )               ! k-eps
540         DO jk = 2, jpkm1
541            DO jj = 2, jpjm1
542               DO ji = fs_2, fs_jpim1   ! vector opt.
543                  psi(ji,jj,jk)  = eps(ji,jj,jk)
544               END DO
545            END DO
546         END DO
547         !
548      CASE( 2 )               ! k-w
549         DO jk = 2, jpkm1
550            DO jj = 2, jpjm1
551               DO ji = fs_2, fs_jpim1   ! vector opt.
552                  psi(ji,jj,jk)  = SQRT( eb(ji,jj,jk) ) / ( rc0 * mxlb(ji,jj,jk) )
553               END DO
554            END DO
555         END DO
556         !
557      CASE( 3 )               ! generic
558         DO jk = 2, jpkm1
559            DO jj = 2, jpjm1
560               DO ji = fs_2, fs_jpim1   ! vector opt.
561                  psi(ji,jj,jk)  = rc02 * eb(ji,jj,jk) * mxlb(ji,jj,jk)**rnn 
562               END DO
563            END DO
564         END DO
565         !
566      END SELECT
567      !
568      ! Now gls (output in psi)
569      ! -------------------------------
570      ! Resolution of a tridiagonal linear system by a "methode de chasse"
571      ! computation from level 2 to jpkm1  (e(1) already computed and e(jpk)=0 ).
572      ! z_elem_b : diagonal z_elem_c : upper diagonal z_elem_a : lower diagonal
573      ! Warning : after this step, en : right hand side of the matrix
574
575      DO jk = 2, jpkm1
576         DO jj = 2, jpjm1
577            DO ji = fs_2, fs_jpim1   ! vector opt.
578               !
579               ! psi / k
580               zratio = psi(ji,jj,jk) / eb(ji,jj,jk) 
581               !
582               ! psi3+ : stable : B=-KhN²<0 => N²>0 if rn2>0 dir = 1 (stable) otherwise dir = 0 (unstable)
583               dir = 0.5_wp + SIGN( 0.5_wp, rn2(ji,jj,jk) )
584               !
585               rpsi3 = dir * rpsi3m + ( 1._wp - dir ) * rpsi3p
586               !
587               ! shear prod. - stratif. destruction
588               prod = rpsi1 * zratio * shear(ji,jj,jk)
589               !
590               ! stratif. destruction
591               buoy = rpsi3 * zratio * (- avt(ji,jj,jk) * rn2(ji,jj,jk) )
592               !
593               ! shear prod. - stratif. destruction
594               diss = rpsi2 * zratio * zwall(ji,jj,jk) * eps(ji,jj,jk)
595               !
596               dir = 0.5_wp + SIGN( 0.5_wp, prod + buoy )   ! dir =1(=0) if shear(ji,jj,jk)+buoy >0(<0)
597               !
598               zesh2 = dir * ( prod + buoy )          + (1._wp - dir ) * prod                        ! production term
599               zdiss = dir * ( diss / psi(ji,jj,jk) ) + (1._wp - dir ) * (diss-buoy) / psi(ji,jj,jk) ! dissipation term
600               !                                                       
601               ! building the matrix
602               zcof = rfact_psi * zwall_psi(ji,jj,jk) * tmask(ji,jj,jk)
603               ! lower diagonal
604               z_elem_a(ji,jj,jk) = zcof * ( avm  (ji,jj,jk  ) + avm  (ji,jj,jk-1) )   &
605                  &                      / ( fse3t(ji,jj,jk-1) * fse3w(ji,jj,jk  ) )
606               ! upper diagonal
607               z_elem_c(ji,jj,jk) = zcof * ( avm  (ji,jj,jk+1) + avm  (ji,jj,jk  ) )   &
608                  &                      / ( fse3t(ji,jj,jk  ) * fse3w(ji,jj,jk) )
609               ! diagonal
610               z_elem_b(ji,jj,jk) = 1._wp - z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk)  &
611                  &                       + rdt * zdiss * tmask(ji,jj,jk)
612               !
613               ! right hand side in psi
614               psi(ji,jj,jk) = psi(ji,jj,jk) + rdt * zesh2 * tmask(ji,jj,jk)
615            END DO
616         END DO
617      END DO
618      !
619      z_elem_b(:,:,jpk) = 1._wp
620
621      ! Surface boundary condition on psi
622      ! ---------------------------------
623      !
624      SELECT CASE ( nn_bc_surf )
625      !
626      CASE ( 0 )             ! Dirichlet boundary conditions
627         IF( ln_phioc ) THEN   ! Wave induced mixing case
628                               ! en(1) = q2(1) = 0.5 * (15.8 * Ccb)^(2/3) * u*^2
629                               ! balance between the production and the
630                               ! dissipation terms including the wave effect
631            IF( nn_wmix==jp_janssen ) THEN
632               ! Surface value
633               zdep(:,:)       = zhsro(:,:) * rl_sf ! Cosmetic
634               psi (:,:,1)     = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
635               z_elem_a(:,:,1) = psi(:,:,1)     
636               z_elem_c(:,:,1) = 0._wp
637               z_elem_b(:,:,1) = 1._wp
638               !
639               ! One level below
640               zex1 = (rmm*ra_sf+rnn)
641               zex2 = (rmm*ra_sf)
642               zdep(:,:) = ( (zhsro(:,:) + fsdepw(:,:,2))**zex1 ) / zhsro(:,:)**zex2
643               psi (:,:,2) = rsbc_psi1(:,:) * ustars2(:,:)**rmm * zdep(:,:) * tmask(:,:,1)
644               z_elem_a(:,:,2) = 0._wp
645               z_elem_c(:,:,2) = 0._wp
646               z_elem_b(:,:,2) = 1._wp
647               !
648               !
649            ELSE IF( nn_wmix==jp_craigbanner ) THEN
650               ! Surface value
651               zdep(:,:)       = zhsro(:,:) * rl_sf ! Cosmetic
652               psi (:,:,1)     = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
653               z_elem_a(:,:,1) = psi(:,:,1)
654               z_elem_c(:,:,1) = 0._wp
655               z_elem_b(:,:,1) = 1._wp
656               !
657               ! One level below
658               zkar(:,:)       = (rl_sf + (vkarmn-rl_sf)*(1._wp-exp(-rtrans(:,:)*fsdepw(:,:,2)/zhsro(:,:) )))
659               zdep(:,:)       = (zhsro(:,:) + fsdepw(:,:,2)) * zkar(:,:)
660               psi (:,:,2)     = rc0**rpp * en(:,:,2)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
661               z_elem_a(:,:,2) = 0._wp
662               z_elem_c(:,:,2) = 0._wp
663               z_elem_b(:,:,2) = 1._wp
664               !
665               !
666            ENDIF
667         ELSE                  ! Wave induced mixing case with default values
668            ! Surface value
669            zdep(:,:)       = zhsro(:,:) * rl_sf ! Cosmetic
670            psi (:,:,1)     = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
671            z_elem_a(:,:,1) = psi(:,:,1)
672            z_elem_c(:,:,1) = 0._wp
673            z_elem_b(:,:,1) = 1._wp
674            !
675            ! One level below
676            zkar(:,:)       = (rl_sf + (vkarmn-rl_sf)*(1._wp-exp(-rtrans_default*fsdepw(:,:,2)/zhsro(:,:) )))
677            zdep(:,:)       = (zhsro(:,:) + fsdepw(:,:,2)) * zkar(:,:)
678            psi (:,:,2)     = rc0**rpp * en(:,:,2)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
679            z_elem_a(:,:,2) = 0._wp
680            z_elem_c(:,:,2) = 0._wp
681            z_elem_b(:,:,2) = 1._wp
682            !
683            !
684         ENDIF
685      CASE ( 1 )             ! Neumann boundary condition on d(psi)/dz
686         IF( ln_phioc ) THEN  ! Wave induced mixing case with forced/coupled fields
687            IF( nn_wmix==jp_janssen ) THEN
688               !
689               zdep(:,:) = rl_sf * zhsro(:,:)
690               psi (:,:,1) = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
691               z_elem_a(:,:,1) = psi(:,:,1)
692               z_elem_c(:,:,1) = 0._wp
693               z_elem_b(:,:,1) = 1._wp
694               !
695               ! Neumann condition at k=2
696               z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
697               z_elem_a(:,:,2) = 0._wp
698               !
699               ! Set psi vertical flux at the surface:
700               zdep(:,:) = (zhsro(:,:) + fsdept(:,:,1))**(rmm*ra_sf+rnn-1._wp) / zhsro(:,:)**(rmm*ra_sf)
701               zflxs(:,:) = rsbc_psi3 * ( zwall_psi(:,:,1)*avm(:,:,1) + zwall_psi(:,:,2)*avm(:,:,2) ) &
702                  &                   * en(:,:,1)**rmm * zdep
703               psi(:,:,2) = psi(:,:,2) + zflxs(:,:) / fse3w(:,:,2)
704               !
705            ELSE IF( nn_wmix==jp_craigbanner ) THEN
706               ! Surface value: Dirichlet
707               zdep(:,:)       = zhsro(:,:) * rl_sf
708               psi (:,:,1)     = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
709               z_elem_a(:,:,1) = psi(:,:,1)
710               z_elem_c(:,:,1) = 0._wp
711               z_elem_b(:,:,1) = 1._wp
712               !
713               ! Neumann condition at k=2
714               z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
715               z_elem_a(:,:,2) = 0._wp
716               !
717               ! Set psi vertical flux at the surface:
718               zkar(:,:) = rl_sf + (vkarmn-rl_sf)*(1._wp-exp(-rtrans(:,:)*fsdept(:,:,1)/zhsro(:,:) )) ! Lengh scale slope
719               zdep(:,:) = ((zhsro(:,:) + fsdept(:,:,1)) / zhsro(:,:))**(rmm*ra_sf)
720               zflxs(:,:) = (rnn + rsbc_tke1(:,:) * (rnn + rmm*ra_sf) * zdep(:,:)) * &
721                          (1._wp + rsbc_tke1(:,:) * zdep(:,:))**(2._wp*rmm/3._wp-1_wp)
722               zdep(:,:) =  rsbc_psi1(:,:) * (zwall_psi(:,:,1)*avm(:,:,1)+zwall_psi(:,:,2)*avm(:,:,2)) * &
723                      & ustars2(:,:)**rmm * zkar(:,:)**rnn * (zhsro(:,:) + fsdept(:,:,1))**(rnn-1.)
724               zflxs(:,:) = zdep(:,:) * zflxs(:,:)
725               psi(:,:,2) = psi(:,:,2) + zflxs(:,:) / fse3w(:,:,2)
726               !   
727            ENDIF
728         ELSE                 ! Wave induced mixing case with default values
729            ! Surface value: Dirichlet
730            zdep(:,:)       = zhsro(:,:) * rl_sf
731            psi (:,:,1)     = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
732            z_elem_a(:,:,1) = psi(:,:,1)
733            z_elem_c(:,:,1) = 0._wp
734            z_elem_b(:,:,1) = 1._wp
735            !
736            ! Neumann condition at k=2
737            z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
738            z_elem_a(:,:,2) = 0._wp
739            !
740            ! Set psi vertical flux at the surface:
741            zkar(:,:) = rl_sf + (vkarmn-rl_sf)*(1._wp-exp(-rtrans_default*fsdept(:,:,1)/zhsro(:,:) )) ! Lengh scale slope
742            zdep(:,:) = ((zhsro(:,:) + fsdept(:,:,1)) / zhsro(:,:))**(rmm*ra_sf)
743            zflxs(:,:) = (rnn + rsbc_tke1_default * (rnn + rmm*ra_sf) * zdep(:,:)) * &
744                       (1._wp + rsbc_tke1_default * zdep(:,:))**(2._wp*rmm/3._wp-1_wp)
745            zdep(:,:) =  rsbc_psi1(:,:) * (zwall_psi(:,:,1)*avm(:,:,1)+zwall_psi(:,:,2)*avm(:,:,2)) * &
746                   & ustars2(:,:)**rmm * zkar(:,:)**rnn * (zhsro(:,:) + fsdept(:,:,1))**(rnn-1.)
747            zflxs(:,:) = zdep(:,:) * zflxs(:,:)
748            psi(:,:,2) = psi(:,:,2) + zflxs(:,:) / fse3w(:,:,2)
749            !   
750            !
751         ENDIF
752      END SELECT
753
754      ! Bottom boundary condition on psi
755      ! --------------------------------
756      !
757      SELECT CASE ( nn_bc_bot )
758      !
759      !
760      CASE ( 0 )             ! Dirichlet
761         !                      ! en(ibot) = u*^2 / Co2 and mxln(ibot) = vkarmn * rn_bfrz0
762         !                      ! Balance between the production and the dissipation terms
763!CDIR NOVERRCHK
764         DO jj = 2, jpjm1
765!CDIR NOVERRCHK
766            DO ji = fs_2, fs_jpim1   ! vector opt.
767               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
768               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
769               zdep(ji,jj) = vkarmn * rn_bfrz0
770               psi (ji,jj,ibot) = rc0**rpp * en(ji,jj,ibot)**rmm * zdep(ji,jj)**rnn
771               z_elem_a(ji,jj,ibot) = 0._wp
772               z_elem_c(ji,jj,ibot) = 0._wp
773               z_elem_b(ji,jj,ibot) = 1._wp
774               !
775               ! Just above last level, Dirichlet condition again (GOTM like)
776               zdep(ji,jj) = vkarmn * ( rn_bfrz0 + fse3t(ji,jj,ibotm1) )
777               psi (ji,jj,ibotm1) = rc0**rpp * en(ji,jj,ibot  )**rmm * zdep(ji,jj)**rnn
778               z_elem_a(ji,jj,ibotm1) = 0._wp
779               z_elem_c(ji,jj,ibotm1) = 0._wp
780               z_elem_b(ji,jj,ibotm1) = 1._wp
781            END DO
782         END DO
783         !
784      CASE ( 1 )             ! Neumman boundary condition
785         !                     
786!CDIR NOVERRCHK
787         DO jj = 2, jpjm1
788!CDIR NOVERRCHK
789            DO ji = fs_2, fs_jpim1   ! vector opt.
790               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
791               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
792               !
793               ! Bottom level Dirichlet condition:
794               zdep(ji,jj) = vkarmn * rn_bfrz0
795               psi (ji,jj,ibot) = rc0**rpp * en(ji,jj,ibot)**rmm * zdep(ji,jj)**rnn
796               !
797               z_elem_a(ji,jj,ibot) = 0._wp
798               z_elem_c(ji,jj,ibot) = 0._wp
799               z_elem_b(ji,jj,ibot) = 1._wp
800               !
801               ! Just above last level: Neumann condition with flux injection
802               z_elem_b(ji,jj,ibotm1) = z_elem_b(ji,jj,ibotm1) + z_elem_c(ji,jj,ibotm1) ! Remove z_elem_c from z_elem_b
803               z_elem_c(ji,jj,ibotm1) = 0.
804               !
805               ! Set psi vertical flux at the bottom:
806               zdep(ji,jj) = rn_bfrz0 + 0.5_wp*fse3t(ji,jj,ibotm1)
807               zflxb = rsbc_psi2 * ( avm(ji,jj,ibot) + avm(ji,jj,ibotm1) )   &
808                  &  * (0.5_wp*(en(ji,jj,ibot)+en(ji,jj,ibotm1)))**rmm * zdep(ji,jj)**(rnn-1._wp)
809               psi(ji,jj,ibotm1) = psi(ji,jj,ibotm1) + zflxb / fse3w(ji,jj,ibotm1)
810            END DO
811         END DO
812         !
813      END SELECT
814
815      ! Matrix inversion
816      ! ----------------
817      !
818      DO jk = 2, jpkm1                             ! First recurrence : Dk = Dk - Lk * Uk-1 / Dk-1
819         DO jj = 2, jpjm1
820            DO ji = fs_2, fs_jpim1    ! vector opt.
821               z_elem_b(ji,jj,jk) = z_elem_b(ji,jj,jk) - z_elem_a(ji,jj,jk) * z_elem_c(ji,jj,jk-1) / z_elem_b(ji,jj,jk-1)
822            END DO
823         END DO
824      END DO
825      DO jk = 2, jpk                               ! Second recurrence : Lk = RHSk - Lk / Dk-1 * Lk-1
826         DO jj = 2, jpjm1
827            DO ji = fs_2, fs_jpim1    ! vector opt.
828               z_elem_a(ji,jj,jk) = psi(ji,jj,jk) - z_elem_a(ji,jj,jk) / z_elem_b(ji,jj,jk-1) * z_elem_a(ji,jj,jk-1)
829            END DO
830         END DO
831      END DO
832      DO jk = jpk-1, 2, -1                         ! Third recurrence : Ek = ( Lk - Uk * Ek+1 ) / Dk
833         DO jj = 2, jpjm1
834            DO ji = fs_2, fs_jpim1    ! vector opt.
835               psi(ji,jj,jk) = ( z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk) * psi(ji,jj,jk+1) ) / z_elem_b(ji,jj,jk)
836            END DO
837         END DO
838      END DO
839
840      ! Set dissipation
841      !----------------
842
843      SELECT CASE ( nn_clos )
844      !
845      CASE( 0 )               ! k-kl  (Mellor-Yamada)
846         DO jk = 1, jpkm1
847            DO jj = 2, jpjm1
848               DO ji = fs_2, fs_jpim1   ! vector opt.
849                  eps(ji,jj,jk) = rc03 * en(ji,jj,jk) * en(ji,jj,jk) * SQRT( en(ji,jj,jk) ) / MAX( psi(ji,jj,jk), rn_epsmin)
850               END DO
851            END DO
852         END DO
853         !
854      CASE( 1 )               ! k-eps
855         DO jk = 1, jpkm1
856            DO jj = 2, jpjm1
857               DO ji = fs_2, fs_jpim1   ! vector opt.
858                  eps(ji,jj,jk) = psi(ji,jj,jk)
859               END DO
860            END DO
861         END DO
862         !
863      CASE( 2 )               ! k-w
864         DO jk = 1, jpkm1
865            DO jj = 2, jpjm1
866               DO ji = fs_2, fs_jpim1   ! vector opt.
867                  eps(ji,jj,jk) = rc04 * en(ji,jj,jk) * psi(ji,jj,jk) 
868               END DO
869            END DO
870         END DO
871         !
872      CASE( 3 )               ! generic
873         zcoef = rc0**( 3._wp  + rpp/rnn )
874         zex1  =      ( 1.5_wp + rmm/rnn )
875         zex2  = -1._wp / rnn
876         DO jk = 1, jpkm1
877            DO jj = 2, jpjm1
878               DO ji = fs_2, fs_jpim1   ! vector opt.
879                  eps(ji,jj,jk) = zcoef * en(ji,jj,jk)**zex1 * psi(ji,jj,jk)**zex2
880               END DO
881            END DO
882         END DO
883         !
884      END SELECT
885
886      ! Limit dissipation rate under stable stratification
887      ! --------------------------------------------------
888      DO jk = 1, jpkm1 ! Note that this set boundary conditions on mxln at the same time
889         DO jj = 2, jpjm1
890            DO ji = fs_2, fs_jpim1    ! vector opt.
891               ! limitation
892               eps(ji,jj,jk)  = MAX( eps(ji,jj,jk), rn_epsmin )
893               mxln(ji,jj,jk)  = rc03 * en(ji,jj,jk) * SQRT( en(ji,jj,jk) ) / eps(ji,jj,jk)
894               ! Galperin criterium (NOTE : Not required if the proper value of C3 in stable cases is calculated)
895               zrn2 = MAX( rn2(ji,jj,jk), rsmall )
896               IF (ln_length_lim) mxln(ji,jj,jk) = MIN(  rn_clim_galp * SQRT( 2._wp * en(ji,jj,jk) / zrn2 ), mxln(ji,jj,jk) )
897            END DO
898         END DO
899      END DO 
900
901      !
902      ! Stability function and vertical viscosity and diffusivity
903      ! ---------------------------------------------------------
904      !
905      SELECT CASE ( nn_stab_func )
906      !
907      CASE ( 0 , 1 )             ! Galperin or Kantha-Clayson stability functions
908         DO jk = 2, jpkm1
909            DO jj = 2, jpjm1
910               DO ji = fs_2, fs_jpim1   ! vector opt.
911                  ! zcof =  l²/q²
912                  zcof = mxlb(ji,jj,jk) * mxlb(ji,jj,jk) / ( 2._wp*eb(ji,jj,jk) )
913                  ! Gh = -N²l²/q²
914                  gh = - rn2(ji,jj,jk) * zcof
915                  gh = MIN( gh, rgh0   )
916                  gh = MAX( gh, rghmin )
917                  ! Stability functions from Kantha and Clayson (if C2=C3=0 => Galperin)
918                  sh = ra2*( 1._wp-6._wp*ra1/rb1 ) / ( 1.-3.*ra2*gh*(6.*ra1+rb2*( 1._wp-rc3 ) ) )
919                  sm = ( rb1**(-1._wp/3._wp) + ( 18._wp*ra1*ra1 + 9._wp*ra1*ra2*(1._wp-rc2) )*sh*gh ) / (1._wp-9._wp*ra1*ra2*gh)
920                  !
921                  ! Store stability function in avmu and avmv
922                  avmu(ji,jj,jk) = rc_diff * sh * tmask(ji,jj,jk)
923                  avmv(ji,jj,jk) = rc_diff * sm * tmask(ji,jj,jk)
924               END DO
925            END DO
926         END DO
927         !
928      CASE ( 2, 3 )               ! Canuto stability functions
929         DO jk = 2, jpkm1
930            DO jj = 2, jpjm1
931               DO ji = fs_2, fs_jpim1   ! vector opt.
932                  ! zcof =  l²/q²
933                  zcof = mxlb(ji,jj,jk)*mxlb(ji,jj,jk) / ( 2._wp * eb(ji,jj,jk) )
934                  ! Gh = -N²l²/q²
935                  gh = - rn2(ji,jj,jk) * zcof
936                  gh = MIN( gh, rgh0   )
937                  gh = MAX( gh, rghmin )
938                  gh = gh * rf6
939                  ! Gm =  M²l²/q² Shear number
940                  shr = shear(ji,jj,jk) / MAX( avm(ji,jj,jk), rsmall )
941                  gm = MAX( shr * zcof , 1.e-10 )
942                  gm = gm * rf6
943                  gm = MIN ( (rd0 - rd1*gh + rd3*gh*gh) / (rd2-rd4*gh) , gm )
944                  ! Stability functions from Canuto
945                  rcff = rd0 - rd1*gh +rd2*gm + rd3*gh*gh - rd4*gh*gm + rd5*gm*gm
946                  sm = (rs0 - rs1*gh + rs2*gm) / rcff
947                  sh = (rs4 - rs5*gh + rs6*gm) / rcff
948                  !
949                  ! Store stability function in avmu and avmv
950                  avmu(ji,jj,jk) = rc_diff * sh * tmask(ji,jj,jk)
951                  avmv(ji,jj,jk) = rc_diff * sm * tmask(ji,jj,jk)
952               END DO
953            END DO
954         END DO
955         !
956      END SELECT
957
958      ! Boundary conditions on stability functions for momentum (Neumann):
959      ! Lines below are useless if GOTM style Dirichlet conditions are used
960
961      avmv(:,:,1) = avmv(:,:,2)
962
963      DO jj = 2, jpjm1
964         DO ji = fs_2, fs_jpim1   ! vector opt.
965            avmv(ji,jj,mbkt(ji,jj)+1) = avmv(ji,jj,mbkt(ji,jj))
966         END DO
967      END DO
968
969      ! Compute diffusivities/viscosities
970      ! The computation below could be restrained to jk=2 to jpkm1 if GOTM style Dirichlet conditions are used
971      DO jk = 1, jpk
972         DO jj = 2, jpjm1
973            DO ji = fs_2, fs_jpim1   ! vector opt.
974               zsqen         = SQRT( 2._wp * en(ji,jj,jk) ) * mxln(ji,jj,jk)
975               zav           = zsqen * avmu(ji,jj,jk)
976               avt(ji,jj,jk) = MAX( zav, avtb(jk) )*tmask(ji,jj,jk) ! apply mask for zdfmxl routine
977               zav           = zsqen * avmv(ji,jj,jk)
978               avm(ji,jj,jk) = MAX( zav, avmb(jk) ) ! Note that avm is not masked at the surface and the bottom
979            END DO
980         END DO
981      END DO
982      !
983      ! Lateral boundary conditions (sign unchanged)
984      avt(:,:,1)  = 0._wp
985      CALL lbc_lnk( avm, 'W', 1. )   ;   CALL lbc_lnk( avt, 'W', 1. )
986
987      DO jk = 2, jpkm1            !* vertical eddy viscosity at u- and v-points
988         DO jj = 2, jpjm1
989            DO ji = fs_2, fs_jpim1   ! vector opt.
990               avmu(ji,jj,jk) = 0.5 * ( avm(ji,jj,jk) + avm(ji+1,jj  ,jk) ) * umask(ji,jj,jk)
991               avmv(ji,jj,jk) = 0.5 * ( avm(ji,jj,jk) + avm(ji  ,jj+1,jk) ) * vmask(ji,jj,jk)
992            END DO
993         END DO
994      END DO
995      avmu(:,:,1) = 0._wp             ;   avmv(:,:,1) = 0._wp                 ! set surface to zero
996      CALL lbc_lnk( avmu, 'U', 1. )   ;   CALL lbc_lnk( avmv, 'V', 1. )       ! Lateral boundary conditions
997
998      IF(ln_ctl) THEN
999         CALL prt_ctl( tab3d_1=en  , clinfo1=' gls  - e: ', tab3d_2=avt, clinfo2=' t: ', ovlap=1, kdim=jpk)
1000         CALL prt_ctl( tab3d_1=avmu, clinfo1=' gls  - u: ', mask1=umask,                   &
1001            &          tab3d_2=avmv, clinfo2=       ' v: ', mask2=vmask, ovlap=1, kdim=jpk )
1002      ENDIF
1003      !
1004      avt_k (:,:,:) = avt (:,:,:)
1005      avm_k (:,:,:) = avm (:,:,:)
1006      avmu_k(:,:,:) = avmu(:,:,:)
1007      avmv_k(:,:,:) = avmv(:,:,:)
1008      !
1009      CALL wrk_dealloc( jpi,jpj, zdep, zkar, zflxs, zhsro )
1010      CALL wrk_dealloc( jpi,jpj,jpk, eb, mxlb, shear, eps, zwall_psi, z_elem_a, z_elem_b, z_elem_c, psi )
1011      !
1012      IF( nn_timing == 1 )  CALL timing_stop('zdf_gls')
1013      !
1014      !
1015   END SUBROUTINE zdf_gls
1016
1017
1018   SUBROUTINE zdf_gls_init
1019      !!----------------------------------------------------------------------
1020      !!                  ***  ROUTINE zdf_gls_init  ***
1021      !!                     
1022      !! ** Purpose :   Initialization of the vertical eddy diffivity and
1023      !!      viscosity when using a gls turbulent closure scheme
1024      !!
1025      !! ** Method  :   Read the namzdf_gls namelist and check the parameters
1026      !!      called at the first timestep (nit000)
1027      !!
1028      !! ** input   :   Namlist namzdf_gls
1029      !!
1030      !! ** Action  :   Increase by 1 the nstop flag is setting problem encounter
1031      !!
1032      !!----------------------------------------------------------------------
1033      USE dynzdf_exp
1034      USE trazdf_exp
1035      !
1036      INTEGER ::   jk    ! dummy loop indices
1037      INTEGER ::   ios   ! Local integer output status for namelist read
1038      REAL(wp)::   zcr   ! local scalar
1039      !!
1040      NAMELIST/namzdf_gls/rn_emin, rn_epsmin, ln_length_lim, &
1041         &            rn_clim_galp, ln_sigpsi, rn_hsro,      &
1042         &            rn_crban_default, rn_charn, rn_frac_hs,&
1043         &            nn_bc_surf, nn_bc_bot, nn_z0_met,      &
1044         &            nn_stab_func, nn_clos
1045      !!----------------------------------------------------------
1046      !
1047      IF( nn_timing == 1 )  CALL timing_start('zdf_gls_init')
1048      !
1049      REWIND( numnam_ref )              ! Namelist namzdf_gls in reference namelist : Vertical eddy diffivity and viscosity using gls turbulent closure scheme
1050      READ  ( numnam_ref, namzdf_gls, IOSTAT = ios, ERR = 901)
1051901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_gls in reference namelist', lwp )
1052
1053      REWIND( numnam_cfg )              ! Namelist namzdf_gls in configuration namelist : Vertical eddy diffivity and viscosity using gls turbulent closure scheme
1054      READ  ( numnam_cfg, namzdf_gls, IOSTAT = ios, ERR = 902 )
1055902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_gls in configuration namelist', lwp )
1056      IF(lwm) WRITE ( numond, namzdf_gls )
1057
1058      IF(lwp) THEN                     !* Control print
1059         WRITE(numout,*)
1060         WRITE(numout,*) 'zdf_gls_init : gls turbulent closure scheme'
1061         WRITE(numout,*) '~~~~~~~~~~~~'
1062         WRITE(numout,*) '   Namelist namzdf_gls : set gls mixing parameters'
1063         WRITE(numout,*) '      minimum value of en                           rn_emin        = ', rn_emin
1064         WRITE(numout,*) '      minimum value of eps                          rn_epsmin      = ', rn_epsmin
1065         WRITE(numout,*) '      Limit dissipation rate under stable stratif.  ln_length_lim  = ', ln_length_lim
1066         WRITE(numout,*) '      Galperin limit (Standard: 0.53, Holt: 0.26)   rn_clim_galp   = ', rn_clim_galp
1067         WRITE(numout,*) '      TKE Surface boundary condition                nn_bc_surf     = ', nn_bc_surf
1068         WRITE(numout,*) '      TKE Bottom boundary condition                 nn_bc_bot      = ', nn_bc_bot
1069         WRITE(numout,*) '      Modify psi Schmidt number (wb case)           ln_sigpsi      = ', ln_sigpsi
1070         WRITE(numout,*) '      Craig and Banner coefficient (default)        rn_crban       = ', rn_crban_default
1071         WRITE(numout,*) '      Charnock coefficient                          rn_charn       = ', rn_charn
1072         WRITE(numout,*) '      Surface roughness formula                     nn_z0_met      = ', nn_z0_met
1073         WRITE(numout,*) '      Wave height frac. (used if nn_z0_met=2)       rn_frac_hs     = ', rn_frac_hs
1074         WRITE(numout,*) '      Stability functions                           nn_stab_func   = ', nn_stab_func
1075         WRITE(numout,*) '      Type of closure                               nn_clos        = ', nn_clos
1076         WRITE(numout,*) '      Surface roughness (m)                         rn_hsro        = ', rn_hsro
1077         WRITE(numout,*) '      Bottom roughness (m) (nambfr namelist)        rn_bfrz0       = ', rn_bfrz0
1078      ENDIF
1079
1080      !                                !* allocate gls arrays
1081      IF( zdf_gls_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'zdf_gls_init : unable to allocate arrays' )
1082
1083      !                                !* Check of some namelist values
1084      IF( nn_bc_surf < 0 .OR. nn_bc_surf > 1 ) CALL ctl_stop( 'zdf_gls_init: bad flag: nn_bc_surf is 0 or 1' ) 
1085      IF( nn_bc_surf < 0 .OR. nn_bc_surf > 1 ) CALL ctl_stop( 'zdf_gls_init: bad flag: nn_bc_surf is 0 or 1' ) 
1086      IF( nn_z0_met < 0 .OR. nn_z0_met > 3 ) CALL ctl_stop( 'zdf_gls_init: bad flag: nn_z0_met is 0, 1, 2 or 3' ) 
1087      IF( nn_z0_met == 3 .AND. .NOT.ln_rough ) CALL ctl_stop( 'zdf_gls_init: nn_z0_met=3 requires ln_rough=T' ) 
1088      IF( nn_z0_met .NE. 3 .AND. ln_rough ) THEN
1089         CALL ctl_warn('W A R N I N G:  ln_rough=.TRUE. but nn_z0_met is not 3 - resetting nn_z0_met to 3') 
1090         nn_z0_met = 3 
1091      ENDIF
1092      IF( nn_stab_func  < 0 .OR. nn_stab_func  > 3 ) CALL ctl_stop( 'zdf_gls_init: bad flag: nn_stab_func is 0, 1, 2 and 3' ) 
1093      IF( nn_clos       < 0 .OR. nn_clos       > 3 ) CALL ctl_stop( 'zdf_gls_init: bad flag: nn_clos is 0, 1, 2 or 3' )
1094
1095      SELECT CASE ( nn_clos )          !* set the parameters for the chosen closure
1096      !
1097      CASE( 0 )                              ! k-kl  (Mellor-Yamada)
1098         !
1099         IF(lwp) WRITE(numout,*) 'The choosen closure is k-kl closed to the classical Mellor-Yamada'
1100         rpp     = 0._wp
1101         rmm     = 1._wp
1102         rnn     = 1._wp
1103         rsc_tke = 1.96_wp
1104         rsc_psi = 1.96_wp
1105         rpsi1   = 0.9_wp
1106         rpsi3p  = 1._wp
1107         rpsi2   = 0.5_wp
1108         !
1109         SELECT CASE ( nn_stab_func )
1110         CASE( 0, 1 )   ;   rpsi3m = 2.53_wp       ! G88 or KC stability functions
1111         CASE( 2 )      ;   rpsi3m = 2.62_wp       ! Canuto A stability functions
1112         CASE( 3 )      ;   rpsi3m = 2.38          ! Canuto B stability functions (caution : constant not identified)
1113         END SELECT
1114         !
1115      CASE( 1 )                              ! k-eps
1116         !
1117         IF(lwp) WRITE(numout,*) 'The choosen closure is k-eps'
1118         rpp     =  3._wp
1119         rmm     =  1.5_wp
1120         rnn     = -1._wp
1121         rsc_tke =  1._wp
1122         rsc_psi =  1.2_wp  ! Schmidt number for psi
1123         rpsi1   =  1.44_wp
1124         rpsi3p  =  1._wp
1125         rpsi2   =  1.92_wp
1126         !
1127         SELECT CASE ( nn_stab_func )
1128         CASE( 0, 1 )   ;   rpsi3m = -0.52_wp      ! G88 or KC stability functions
1129         CASE( 2 )      ;   rpsi3m = -0.629_wp     ! Canuto A stability functions
1130         CASE( 3 )      ;   rpsi3m = -0.566        ! Canuto B stability functions
1131         END SELECT
1132         !
1133      CASE( 2 )                              ! k-omega
1134         !
1135         IF(lwp) WRITE(numout,*) 'The choosen closure is k-omega'
1136         rpp     = -1._wp
1137         rmm     =  0.5_wp
1138         rnn     = -1._wp
1139         rsc_tke =  2._wp
1140         rsc_psi =  2._wp
1141         rpsi1   =  0.555_wp
1142         rpsi3p  =  1._wp
1143         rpsi2   =  0.833_wp
1144         !
1145         SELECT CASE ( nn_stab_func )
1146         CASE( 0, 1 )   ;   rpsi3m = -0.58_wp       ! G88 or KC stability functions
1147         CASE( 2 )      ;   rpsi3m = -0.64_wp       ! Canuto A stability functions
1148         CASE( 3 )      ;   rpsi3m = -0.64_wp       ! Canuto B stability functions caution : constant not identified)
1149         END SELECT
1150         !
1151      CASE( 3 )                              ! generic
1152         !
1153         IF(lwp) WRITE(numout,*) 'The choosen closure is generic'
1154         rpp     = 2._wp
1155         rmm     = 1._wp
1156         rnn     = -0.67_wp
1157         rsc_tke = 0.8_wp
1158         rsc_psi = 1.07_wp
1159         rpsi1   = 1._wp
1160         rpsi3p  = 1._wp
1161         rpsi2   = 1.22_wp
1162         !
1163         SELECT CASE ( nn_stab_func )
1164         CASE( 0, 1 )   ;   rpsi3m = 0.1_wp         ! G88 or KC stability functions
1165         CASE( 2 )      ;   rpsi3m = 0.05_wp        ! Canuto A stability functions
1166         CASE( 3 )      ;   rpsi3m = 0.05_wp        ! Canuto B stability functions caution : constant not identified)
1167         END SELECT
1168         !
1169      END SELECT
1170
1171      !
1172      SELECT CASE ( nn_stab_func )     !* set the parameters of the stability functions
1173      !
1174      CASE ( 0 )                             ! Galperin stability functions
1175         !
1176         IF(lwp) WRITE(numout,*) 'Stability functions from Galperin'
1177         rc2     =  0._wp
1178         rc3     =  0._wp
1179         rc_diff =  1._wp
1180         rc0     =  0.5544_wp
1181         rcm_sf  =  0.9884_wp
1182         rghmin  = -0.28_wp
1183         rgh0    =  0.0233_wp
1184         rghcri  =  0.02_wp
1185         !
1186      CASE ( 1 )                             ! Kantha-Clayson stability functions
1187         !
1188         IF(lwp) WRITE(numout,*) 'Stability functions from Kantha-Clayson'
1189         rc2     =  0.7_wp
1190         rc3     =  0.2_wp
1191         rc_diff =  1._wp
1192         rc0     =  0.5544_wp
1193         rcm_sf  =  0.9884_wp
1194         rghmin  = -0.28_wp
1195         rgh0    =  0.0233_wp
1196         rghcri  =  0.02_wp
1197         !
1198      CASE ( 2 )                             ! Canuto A stability functions
1199         !
1200         IF(lwp) WRITE(numout,*) 'Stability functions from Canuto A'
1201         rs0 = 1.5_wp * rl1 * rl5*rl5
1202         rs1 = -rl4*(rl6+rl7) + 2._wp*rl4*rl5*(rl1-(1._wp/3._wp)*rl2-rl3) + 1.5_wp*rl1*rl5*rl8
1203         rs2 = -(3._wp/8._wp) * rl1*(rl6*rl6-rl7*rl7)
1204         rs4 = 2._wp * rl5
1205         rs5 = 2._wp * rl4
1206         rs6 = (2._wp/3._wp) * rl5 * ( 3._wp*rl3*rl3 - rl2*rl2 ) - 0.5_wp * rl5*rl1 * (3._wp*rl3-rl2)   &
1207            &                                                    + 0.75_wp * rl1 * ( rl6 - rl7 )
1208         rd0 = 3._wp * rl5*rl5
1209         rd1 = rl5 * ( 7._wp*rl4 + 3._wp*rl8 )
1210         rd2 = rl5*rl5 * ( 3._wp*rl3*rl3 - rl2*rl2 ) - 0.75_wp*(rl6*rl6 - rl7*rl7 )
1211         rd3 = rl4 * ( 4._wp*rl4 + 3._wp*rl8)
1212         rd4 = rl4 * ( rl2 * rl6 - 3._wp*rl3*rl7 - rl5*(rl2*rl2 - rl3*rl3 ) ) + rl5*rl8 * ( 3._wp*rl3*rl3 - rl2*rl2 )
1213         rd5 = 0.25_wp * ( rl2*rl2 - 3._wp *rl3*rl3 ) * ( rl6*rl6 - rl7*rl7 )
1214         rc0 = 0.5268_wp
1215         rf6 = 8._wp / (rc0**6._wp)
1216         rc_diff = SQRT(2._wp) / (rc0**3._wp)
1217         rcm_sf  =  0.7310_wp
1218         rghmin  = -0.28_wp
1219         rgh0    =  0.0329_wp
1220         rghcri  =  0.03_wp
1221         !
1222      CASE ( 3 )                             ! Canuto B stability functions
1223         !
1224         IF(lwp) WRITE(numout,*) 'Stability functions from Canuto B'
1225         rs0 = 1.5_wp * rm1 * rm5*rm5
1226         rs1 = -rm4 * (rm6+rm7) + 2._wp * rm4*rm5*(rm1-(1._wp/3._wp)*rm2-rm3) + 1.5_wp * rm1*rm5*rm8
1227         rs2 = -(3._wp/8._wp) * rm1 * (rm6*rm6-rm7*rm7 )
1228         rs4 = 2._wp * rm5
1229         rs5 = 2._wp * rm4
1230         rs6 = (2._wp/3._wp) * rm5 * (3._wp*rm3*rm3-rm2*rm2) - 0.5_wp * rm5*rm1*(3._wp*rm3-rm2) + 0.75_wp * rm1*(rm6-rm7)
1231         rd0 = 3._wp * rm5*rm5
1232         rd1 = rm5 * (7._wp*rm4 + 3._wp*rm8)
1233         rd2 = rm5*rm5 * (3._wp*rm3*rm3 - rm2*rm2) - 0.75_wp * (rm6*rm6 - rm7*rm7)
1234         rd3 = rm4 * ( 4._wp*rm4 + 3._wp*rm8 )
1235         rd4 = rm4 * ( rm2*rm6 -3._wp*rm3*rm7 - rm5*(rm2*rm2 - rm3*rm3) ) + rm5 * rm8 * ( 3._wp*rm3*rm3 - rm2*rm2 )
1236         rd5 = 0.25_wp * ( rm2*rm2 - 3._wp*rm3*rm3 ) * ( rm6*rm6 - rm7*rm7 )
1237         rc0 = 0.5268_wp            !!       rc0 = 0.5540_wp (Warner ...) to verify !
1238         rf6 = 8._wp / ( rc0**6._wp )
1239         rc_diff = SQRT(2._wp)/(rc0**3.)
1240         rcm_sf  =  0.7470_wp
1241         rghmin  = -0.28_wp
1242         rgh0    =  0.0444_wp
1243         rghcri  =  0.0414_wp
1244         !
1245      END SELECT
1246   
1247      !                                !* Set Schmidt number for psi diffusion in the wave breaking case
1248      !                                     ! See Eq. (13) of Carniel et al, OM, 30, 225-239, 2009
1249      !                                     !  or Eq. (17) of Burchard, JPO, 31, 3133-3145, 2001
1250      IF( ln_sigpsi ) THEN
1251         ra_sf = -1.5 ! Set kinetic energy slope, then deduce rsc_psi and rl_sf
1252         ! Verification: retrieve Burchard (2001) results by uncomenting the line below:
1253         ! Note that the results depend on the value of rn_cm_sf which is constant (=rc0) in his work
1254         ! ra_sf = -SQRT(2./3.*rc0**3./rn_cm_sf*rn_sc_tke)/vkarmn
1255         rsc_psi0 = rsc_tke/(24.*rpsi2)*(-1.+(4.*rnn + ra_sf*(1.+4.*rmm))**2./(ra_sf**2.))
1256      ELSE
1257         rsc_psi0 = rsc_psi
1258      ENDIF
1259 
1260      !                                !* Shear free turbulence parameters
1261      !
1262      ra_sf  = -4._wp*rnn*SQRT(rsc_tke) / ( (1._wp+4._wp*rmm)*SQRT(rsc_tke) &
1263               &                              - SQRT(rsc_tke + 24._wp*rsc_psi0*rpsi2 ) )
1264
1265      IF( .NOT. ln_phioc .AND. rn_crban_default==0._wp ) THEN
1266         rl_sf = vkarmn
1267      ELSE
1268         rl_sf = rc0 * SQRT(rc0/rcm_sf) * SQRT( ( (1._wp + 4._wp*rmm + 8._wp*rmm**2_wp)*rsc_tke          &
1269                 &                                       + 12._wp * rsc_psi0*rpsi2 - (1._wp + 4._wp*rmm) &
1270                 &                                                *SQRT(rsc_tke*(rsc_tke                 &
1271                 &                                                   + 24._wp*rsc_psi0*rpsi2)) )         &
1272                 &                                         /(12._wp*rnn**2.)                             &
1273                 &                                       )
1274      ENDIF
1275
1276      !
1277      IF(lwp) THEN                     !* Control print
1278         WRITE(numout,*)
1279         WRITE(numout,*) 'Limit values'
1280         WRITE(numout,*) '~~~~~~~~~~~~'
1281         WRITE(numout,*) 'Parameter  m = ',rmm
1282         WRITE(numout,*) 'Parameter  n = ',rnn
1283         WRITE(numout,*) 'Parameter  p = ',rpp
1284         WRITE(numout,*) 'rpsi1   = ',rpsi1
1285         WRITE(numout,*) 'rpsi2   = ',rpsi2
1286         WRITE(numout,*) 'rpsi3m  = ',rpsi3m
1287         WRITE(numout,*) 'rpsi3p  = ',rpsi3p
1288         WRITE(numout,*) 'rsc_tke = ',rsc_tke
1289         WRITE(numout,*) 'rsc_psi = ',rsc_psi
1290         WRITE(numout,*) 'rsc_psi0 = ',rsc_psi0
1291         WRITE(numout,*) 'rc0     = ',rc0
1292         WRITE(numout,*)
1293         WRITE(numout,*) 'Shear free turbulence parameters:'
1294         WRITE(numout,*) 'rcm_sf  = ',rcm_sf
1295         WRITE(numout,*) 'ra_sf   = ',ra_sf
1296         WRITE(numout,*) 'rl_sf   = ',rl_sf
1297         WRITE(numout,*)
1298      ENDIF
1299
1300      !                                !* Constants initialization
1301      rc02  = rc0  * rc0   ;   rc02r = 1. / rc02
1302      rc03  = rc02 * rc0
1303      rc04  = rc03 * rc0
1304      rsbc_tke1_default = -3._wp/2._wp*rn_crban_default*ra_sf*rl_sf
1305      rsbc_tke2         = rdt * rn_crban_default / rl_sf
1306      zcr               = MAX( rsmall, rsbc_tke1_default**(1./(-ra_sf*3._wp/2._wp))-1._wp )
1307      rtrans_default    = 0.2_wp / zcr
1308      rsbc_zs1  = rn_charn/grav                                          ! Charnock formula for surface roughness
1309      rsbc_zs2  = rn_frac_hs / 0.85_wp / grav * 665._wp                  ! Rascle formula for surface roughness
1310      rsbc_psi1 = -0.5_wp * rdt * rc0**(rpp-2._wp*rmm) / rsc_psi
1311      rsbc_psi2 = -0.5_wp * rdt * rc0**rpp * rnn * vkarmn**rnn / rsc_psi ! Neumann + NO Wave breaking
1312
1313      rfact_tke = -0.5_wp / rsc_tke * rdt                                ! Cst used for the Diffusion term of tke
1314      rfact_psi = -0.5_wp / rsc_psi * rdt                                ! Cst used for the Diffusion term of tke
1315
1316      !                                !* Wall proximity function
1317      zwall (:,:,:) = 1._wp * tmask(:,:,:)
1318
1319      !                                !* set vertical eddy coef. to the background value
1320      DO jk = 1, jpk
1321         avt (:,:,jk) = avtb(jk) * tmask(:,:,jk)
1322         avm (:,:,jk) = avmb(jk) * tmask(:,:,jk)
1323         avmu(:,:,jk) = avmb(jk) * umask(:,:,jk)
1324         avmv(:,:,jk) = avmb(jk) * vmask(:,:,jk)
1325      END DO
1326      !                             
1327      CALL gls_rst( nit000, 'READ' )   !* read or initialize all required files
1328      !
1329      IF( nn_timing == 1 )  CALL timing_stop('zdf_gls_init')
1330      !
1331   END SUBROUTINE zdf_gls_init
1332
1333
1334   SUBROUTINE gls_rst( kt, cdrw )
1335      !!---------------------------------------------------------------------
1336      !!                   ***  ROUTINE ts_rst  ***
1337      !!                     
1338      !! ** Purpose :   Read or write TKE file (en) in restart file
1339      !!
1340      !! ** Method  :   use of IOM library
1341      !!                if the restart does not contain TKE, en is either
1342      !!                set to rn_emin or recomputed (nn_igls/=0)
1343      !!----------------------------------------------------------------------
1344      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
1345      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
1346      !
1347      INTEGER ::   jit, jk   ! dummy loop indices
1348      INTEGER ::   id1, id2, id3, id4, id5, id6
1349      INTEGER ::   ji, jj, ikbu, ikbv
1350      REAL(wp)::   cbx, cby
1351      !!----------------------------------------------------------------------
1352      !
1353      IF( TRIM(cdrw) == 'READ' ) THEN        ! Read/initialise
1354         !                                   ! ---------------
1355         IF( ln_rstart ) THEN                   !* Read the restart file
1356            id1 = iom_varid( numror, 'en'   , ldstop = .FALSE. )
1357            id2 = iom_varid( numror, 'avt'  , ldstop = .FALSE. )
1358            id3 = iom_varid( numror, 'avm'  , ldstop = .FALSE. )
1359            id4 = iom_varid( numror, 'avmu' , ldstop = .FALSE. )
1360            id5 = iom_varid( numror, 'avmv' , ldstop = .FALSE. )
1361            id6 = iom_varid( numror, 'mxln' , ldstop = .FALSE. )
1362            !
1363            IF( MIN( id1, id2, id3, id4, id5, id6 ) > 0 ) THEN        ! all required arrays exist
1364               CALL iom_get( numror, jpdom_autoglo, 'en'    , en     )
1365               CALL iom_get( numror, jpdom_autoglo, 'avt'   , avt    )
1366               CALL iom_get( numror, jpdom_autoglo, 'avm'   , avm    )
1367               CALL iom_get( numror, jpdom_autoglo, 'avmu'  , avmu   )
1368               CALL iom_get( numror, jpdom_autoglo, 'avmv'  , avmv   )
1369               CALL iom_get( numror, jpdom_autoglo, 'mxln'  , mxln   )
1370            ELSE                       
1371               IF(lwp) WRITE(numout,*) ' ===>>>> : previous run without gls scheme, en and mxln computed by iterative loop'
1372               en  (:,:,:) = rn_emin
1373               mxln(:,:,:) = 0.05       
1374               avt_k (:,:,:) = avt (:,:,:)
1375               avm_k (:,:,:) = avm (:,:,:)
1376               avmu_k(:,:,:) = avmu(:,:,:)
1377               avmv_k(:,:,:) = avmv(:,:,:)
1378               DO jit = nit000 + 1, nit000 + 10   ;   CALL zdf_gls( jit )   ;   END DO
1379            ENDIF
1380         ELSE                                   !* Start from rest
1381            IF(lwp) WRITE(numout,*) ' ===>>>> : Initialisation of en and mxln by background values'
1382            en  (:,:,:) = rn_emin
1383            mxln(:,:,:) = 0.05       
1384         ENDIF
1385         !
1386      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN   ! Create restart file
1387         !                                   ! -------------------
1388         IF(lwp) WRITE(numout,*) '---- gls-rst ----'
1389         CALL iom_rstput( kt, nitrst, numrow, 'en'   , en     ) 
1390         CALL iom_rstput( kt, nitrst, numrow, 'avt'  , avt_k  )
1391         CALL iom_rstput( kt, nitrst, numrow, 'avm'  , avm_k  )
1392         CALL iom_rstput( kt, nitrst, numrow, 'avmu' , avmu_k ) 
1393         CALL iom_rstput( kt, nitrst, numrow, 'avmv' , avmv_k )
1394         CALL iom_rstput( kt, nitrst, numrow, 'mxln' , mxln   )
1395         !
1396      ENDIF
1397      !
1398   END SUBROUTINE gls_rst
1399
1400#else
1401   !!----------------------------------------------------------------------
1402   !!   Dummy module :                                        NO TKE scheme
1403   !!----------------------------------------------------------------------
1404   LOGICAL, PUBLIC, PARAMETER ::   lk_zdfgls = .FALSE.   !: TKE flag
1405CONTAINS
1406   SUBROUTINE zdf_gls_init           ! Empty routine
1407      WRITE(*,*) 'zdf_gls_init: You should not have seen this print! error?'
1408   END SUBROUTINE zdf_gls_init
1409   SUBROUTINE zdf_gls( kt )          ! Empty routine
1410      WRITE(*,*) 'zdf_gls: You should not have seen this print! error?', kt
1411   END SUBROUTINE zdf_gls
1412   SUBROUTINE gls_rst( kt, cdrw )          ! Empty routine
1413      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
1414      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
1415      WRITE(*,*) 'gls_rst: You should not have seen this print! error?', kt, cdrw
1416   END SUBROUTINE gls_rst
1417#endif
1418
1419   !!======================================================================
1420END MODULE zdfgls
1421
Note: See TracBrowser for help on using the repository browser.