New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcwave.F90 in branches/UKMO/r6232_INGV1_WAVE-coupling/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/UKMO/r6232_INGV1_WAVE-coupling/NEMOGCM/NEMO/OPA_SRC/SBC/sbcwave.F90 @ 7863

Last change on this file since 7863 was 7863, checked in by jcastill, 7 years ago

Fix bug in the Stokes drift calculation
File size: 18.7 KB
Line 
1MODULE sbcwave
2   !!======================================================================
3   !!                       ***  MODULE  sbcwave  ***
4   !! Wave module
5   !!======================================================================
6   !! History :  3.3  !   2011-09  (Adani M)  Original code: Drag Coefficient
7   !!         :  3.4  !   2012-10  (Adani M)                 Stokes Drift
8   !!            3.6  !   2014-09  (Clementi E, Oddo P)New Stokes Drift Computation
9   !!             -   !   2016-12  (G. Madec, E. Clementi) update Stoke drift computation
10   !!                                                     + add sbc_wave_ini routine
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   sbc_stokes    : calculate 3D Stokes-drift velocities
15   !!   sbc_wave      : wave data from wave model in netcdf files
16   !!   sbc_wave_init : initialisation fo surface waves
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean variables
19   USE sbc_oce        ! Surface boundary condition: ocean fields
20   USE zdf_oce,  ONLY : ln_zdfqiao
21   USE bdy_oce        ! open boundary condition variables
22   USE domvvl         ! domain: variable volume layers
23   !
24   USE iom            ! I/O manager library
25   USE in_out_manager ! I/O manager
26   USE lib_mpp        ! distribued memory computing library
27   USE fldread        ! read input fields
28   USE wrk_nemo       !
29   USE phycst         ! physical constants
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   sbc_stokes      ! routine called in sbccpl
35   PUBLIC   sbc_wave        ! routine called in sbcmod
36   PUBLIC   sbc_wave_init   ! routine called in sbcmod
37   
38   ! Variables checking if the wave parameters are coupled (if not, they are read from file)
39   LOGICAL, PUBLIC ::   cpl_hsig   = .FALSE.
40   LOGICAL, PUBLIC ::   cpl_phioc  = .FALSE.
41   LOGICAL, PUBLIC ::   cpl_sdrftx = .FALSE.
42   LOGICAL, PUBLIC ::   cpl_sdrfty = .FALSE.
43   LOGICAL, PUBLIC ::   cpl_wper   = .FALSE.
44   LOGICAL, PUBLIC ::   cpl_wnum   = .FALSE.
45   LOGICAL, PUBLIC ::   cpl_tauoc  = .FALSE.
46   LOGICAL, PUBLIC ::   cpl_wdrag  = .FALSE.
47
48   INTEGER ::   jpfld    ! number of files to read for stokes drift
49   INTEGER ::   jp_usd   ! index of stokes drift  (i-component) (m/s)    at T-point
50   INTEGER ::   jp_vsd   ! index of stokes drift  (j-component) (m/s)    at T-point
51   INTEGER ::   jp_hsw   ! index of significant wave hight      (m)      at T-point
52   INTEGER ::   jp_wmp   ! index of mean wave period            (s)      at T-point
53
54   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::  sf_cd    ! structure of input fields (file informations, fields read) Drag Coefficient
55   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::  sf_sd    ! structure of input fields (file informations, fields read) Stokes Drift
56   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::  sf_wn    ! structure of input fields (file informations, fields read) wave number for Qiao
57   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::  sf_tauoc ! structure of input fields (file informations, fields read) normalized wave stress into the ocean
58   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   cdn_wave            !:
59   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   hsw, wmp, wnum      !:
60   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   tauoc_wave          !:
61   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   tsd2d               !:
62   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   div_sd              !: barotropic stokes drift divergence
63   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   ut0sd, vt0sd        !: surface Stokes drift velocities at t-point
64   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:,:) ::   usd  , vsd  , wsd   !: Stokes drift velocities at u-, v- & w-points, resp.
65
66#  include "vectopt_loop_substitute.h90"
67   !!----------------------------------------------------------------------
68   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
69   !! $Id$
70   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
71   !!----------------------------------------------------------------------
72CONTAINS
73
74   SUBROUTINE sbc_stokes( )
75      !!---------------------------------------------------------------------
76      !!                     ***  ROUTINE sbc_stokes  ***
77      !!
78      !! ** Purpose :   compute the 3d Stokes Drift according to Breivik et al.,
79      !!                2014 (DOI: 10.1175/JPO-D-14-0020.1)
80      !!
81      !! ** Method  : - Calculate Stokes transport speed
82      !!              - Calculate horizontal divergence
83      !!              - Integrate the horizontal divergenze from the bottom
84      !! ** action 
85      !!---------------------------------------------------------------------
86      INTEGER  ::   jj, ji, jk   ! dummy loop argument
87      INTEGER  ::   ik           ! local integer
88      REAL(wp) ::  ztransp, zfac, ztemp
89      REAL(wp) ::  zdep_u, zdep_v, zkh_u, zkh_v, zda_u, zda_v
90      REAL(wp), DIMENSION(:,:)  , POINTER ::   zk_t, zk_u, zk_v, zu0_sd, zv0_sd   ! 2D workspace
91      REAL(wp), DIMENSION(:,:,:), POINTER ::   ze3divh                            ! 3D workspace
92
93      !!---------------------------------------------------------------------
94      !
95
96      CALL wrk_alloc( jpi,jpj,jpk,   ze3divh )
97      CALL wrk_alloc( jpi,jpj,       zk_t, zk_u, zk_v, zu0_sd, zv0_sd ) 
98      !
99      zfac = 2.0_wp * rpi / 16.0_wp
100      DO jj = 1, jpj               ! exp. wave number at t-point    (Eq. (19) in Breivick et al. (2014) )
101         DO ji = 1, jpi
102            ! Stokes drift velocity estimated from Hs and Tmean
103            ztransp = zfac * hsw(ji,jj)*hsw(ji,jj) / MAX( wmp(ji,jj), 0.0000001_wp )
104            ! Stokes surface speed
105            tsd2d(ji,jj) = SQRT( ut0sd(ji,jj)*ut0sd(ji,jj) + vt0sd(ji,jj)*vt0sd(ji,jj))
106            ! Wavenumber scale
107            zk_t(ji,jj) = ABS( tsd2d(ji,jj) ) / MAX( ABS( 5.97_wp*ztransp ), 0.0000001_wp )
108         END DO
109      END DO
110      DO jj = 1, jpjm1              ! exp. wave number & Stokes drift velocity at u- & v-points
111         DO ji = 1, jpim1
112            zk_u(ji,jj) = 0.5_wp * ( zk_t(ji,jj) + zk_t(ji+1,jj) )
113            zk_v(ji,jj) = 0.5_wp * ( zk_t(ji,jj) + zk_t(ji,jj+1) )
114            !
115            zu0_sd(ji,jj) = 0.5_wp * ( ut0sd(ji,jj) + ut0sd(ji+1,jj) )
116            zv0_sd(ji,jj) = 0.5_wp * ( vt0sd(ji,jj) + vt0sd(ji,jj+1) )
117         END DO
118      END DO
119      !
120      !                       !==  horizontal Stokes Drift 3D velocity  ==!
121      DO jk = 1, jpkm1
122         DO jj = 2, jpjm1
123            DO ji = 2, jpim1
124               zdep_u = 0.5_wp * ( gdept_n(ji,jj,jk) + gdept_n(ji+1,jj,jk) )
125               zdep_v = 0.5_wp * ( gdept_n(ji,jj,jk) + gdept_n(ji,jj+1,jk) )
126               !                         
127               zkh_u = zk_u(ji,jj) * zdep_u     ! k * depth
128               zkh_v = zk_v(ji,jj) * zdep_v
129               !                                ! Depth attenuation
130               zda_u = EXP( -2.0_wp*zkh_u ) / ( 1.0_wp + 8.0_wp*zkh_u )
131               zda_v = EXP( -2.0_wp*zkh_v ) / ( 1.0_wp + 8.0_wp*zkh_v )
132               !
133               usd(ji,jj,jk) = zda_u * zu0_sd(ji,jj) * umask(ji,jj,jk)
134               vsd(ji,jj,jk) = zda_v * zv0_sd(ji,jj) * vmask(ji,jj,jk)
135            END DO
136         END DO
137      END DO
138      CALL lbc_lnk( usd(:,:,:), 'U', vsd(:,:,:), 'V', -1. )
139      !
140      !                       !==  vertical Stokes Drift 3D velocity  ==!
141      !
142      DO jk = 1, jpkm1               ! Horizontal e3*divergence
143         DO jj = 2, jpj
144            DO ji = fs_2, jpi
145               ze3divh(ji,jj,jk) = (  e2u(ji  ,jj) * e3u_n(ji  ,jj,jk) * usd(ji,  jj,jk)    &
146                  &                 - e2u(ji-1,jj) * e3u_n(ji-1,jj,jk) * usd(ji-1,jj,jk)    &
147                  &                 + e1v(ji,jj  ) * e3v_n(ji,jj  ,jk) * vsd(ji,jj  ,jk)    &
148                  &                 - e1v(ji,jj-1) * e3v_n(ji,jj-1,jk) * vsd(ji,jj-1,jk)  ) * r1_e12t(ji,jj)
149            END DO
150         END DO
151      END DO
152      !
153      IF( .NOT. AGRIF_Root() ) THEN
154         IF( nbondi ==  1 .OR. nbondi == 2 )   ze3divh(nlci-1,   :  ,:) = 0._wp      ! east
155         IF( nbondi == -1 .OR. nbondi == 2 )   ze3divh(  2   ,   :  ,:) = 0._wp      ! west
156         IF( nbondj ==  1 .OR. nbondj == 2 )   ze3divh(  :   ,nlcj-1,:) = 0._wp      ! north
157         IF( nbondj == -1 .OR. nbondj == 2 )   ze3divh(  :   ,  2   ,:) = 0._wp      ! south
158      ENDIF
159      !
160      CALL lbc_lnk( ze3divh, 'T', 1. )
161      !
162      IF( .NOT. lk_vvl ) THEN   ;   ik = 1   ! none zero velocity through the sea surface
163      ELSE                      ;   ik = 2   ! w=0 at the surface (set one for all in sbc_wave_init)
164      ENDIF
165      DO jk = jpkm1, ik, -1          ! integrate from the bottom the hor. divergence (NB: at k=jpk w is always zero)
166         wsd(:,:,jk) = wsd(:,:,jk+1) - ze3divh(:,:,jk)
167      END DO
168#if defined key_bdy
169      IF( lk_bdy ) THEN
170         DO jk = 1, jpkm1
171            wsd(:,:,jk) = wsd(:,:,jk) * bdytmask(:,:)
172         END DO
173      ENDIF
174#endif
175      !                       !==  Horizontal divergence of barotropic Stokes transport  ==!
176      div_sd(:,:) = 0._wp
177      DO jk = 1, jpkm1                                 !
178        div_sd(:,:) = div_sd(:,:) + ze3divh(:,:,jk)
179      END DO
180      !
181      CALL iom_put( "ustokes",  usd  )
182      CALL iom_put( "vstokes",  vsd  )
183      CALL iom_put( "wstokes",  wsd  )
184      !
185      CALL wrk_dealloc( jpi,jpj,jpk,   ze3divh )
186      CALL wrk_dealloc( jpi,jpj,       zk_t, zk_u, zk_v, zu0_sd, zv0_sd )
187      !
188   END SUBROUTINE sbc_stokes
189
190
191   SUBROUTINE sbc_wave( kt )
192      !!---------------------------------------------------------------------
193      !!                     ***  ROUTINE sbc_wave  ***
194      !!
195      !! ** Purpose :   read wave parameters from wave model  in netcdf files.
196      !!
197      !! ** Method  : - Read namelist namsbc_wave
198      !!              - Read Cd_n10 fields in netcdf files
199      !!              - Read stokes drift 2d in netcdf files
200      !!              - Read wave number in netcdf files
201      !!              - Compute 3d stokes drift using Breivik et al.,2014
202      !!                formulation
203      !! ** action 
204      !!---------------------------------------------------------------------
205      INTEGER, INTENT(in   ) ::   kt   ! ocean time step
206      !!---------------------------------------------------------------------
207      !
208      IF( ln_cdgw .AND. .NOT. cpl_wdrag ) THEN     !==  Neutral drag coefficient  ==!
209         CALL fld_read( kt, nn_fsbc, sf_cd )             ! read from external forcing
210         cdn_wave(:,:) = sf_cd(1)%fnow(:,:,1)
211         ! check that the drag coefficient contains proper information even if
212         ! the masks do not match - the momentum stress is not masked!
213         WHERE( cdn_wave < 0.0 ) cdn_wave = 1.5e-3
214         WHERE( cdn_wave > 1.0 ) cdn_wave = 1.5e-3
215      ENDIF
216
217      IF( ln_tauoc .AND. .NOT. cpl_tauoc ) THEN    !==  Wave induced stress  ==!
218         CALL fld_read( kt, nn_fsbc, sf_tauoc )          ! read wave norm stress from external forcing
219         tauoc_wave(:,:) = sf_tauoc(1)%fnow(:,:,1)
220         WHERE( tauoc_wave < -100.0 ) tauoc_wave = 1.0
221         WHERE( tauoc_wave >  100.0 ) tauoc_wave = 1.0
222      ENDIF
223
224      IF( ln_sdw )  THEN                           !==  Computation of the 3d Stokes Drift  ==!
225         !
226         IF( jpfld > 0 ) THEN                            ! Read from file only if the field is not coupled
227            CALL fld_read( kt, nn_fsbc, sf_sd )          ! read wave parameters from external forcing
228            IF( jp_hsw > 0 ) THEN
229               hsw  (:,:) = sf_sd(jp_hsw)%fnow(:,:,1)   ! significant wave height
230               WHERE( hsw > 100.0 ) hsw = 0.0
231               WHERE( hsw <   0.0 ) hsw = 0.0
232            ENDIF
233            IF( jp_wmp > 0 ) THEN
234               wmp  (:,:) = sf_sd(jp_wmp)%fnow(:,:,1)   ! wave mean period
235               WHERE( wmp > 100.0 ) wmp = 0.0
236               WHERE( wmp <   0.0 ) wmp = 0.0
237            ENDIF
238            IF( jp_usd > 0 ) THEN 
239               ut0sd(:,:) = sf_sd(jp_usd)%fnow(:,:,1)   ! 2D zonal Stokes Drift at T point
240               WHERE( ut0sd < -100.0 ) ut0sd = 1.0
241               WHERE( ut0sd >  100.0 ) ut0sd = 1.0
242            ENDIF
243            IF( jp_vsd > 0 ) THEN 
244               vt0sd(:,:) = sf_sd(jp_vsd)%fnow(:,:,1)   ! 2D meridional Stokes Drift at T point
245               WHERE( vt0sd < -100.0 ) vt0sd = 1.0
246               WHERE( vt0sd >  100.0 ) vt0sd = 1.0
247            ENDIF
248         ENDIF
249         !
250         ! Read also wave number if needed, so that it is available in coupling routines
251         IF( ln_zdfqiao .AND. .NOT.cpl_wnum ) THEN
252            CALL fld_read( kt, nn_fsbc, sf_wn )          ! read wave parameters from external forcing
253            wnum(:,:) = sf_wn(1)%fnow(:,:,1)
254         ENDIF
255           
256         !                                         !==  Computation of the 3d Stokes Drift  ==!
257         !
258         IF( jpfld == 4 )   CALL sbc_stokes()            ! Calculate only if required fields are read
259         !                                               ! In coupled wave model-NEMO case the call is done after coupling
260         !
261      ENDIF
262      !
263   END SUBROUTINE sbc_wave
264
265
266   SUBROUTINE sbc_wave_init
267      !!---------------------------------------------------------------------
268      !!                     ***  ROUTINE sbc_wave_init  ***
269      !!
270      !! ** Purpose :   read wave parameters from wave model  in netcdf files.
271      !!
272      !! ** Method  : - Read namelist namsbc_wave
273      !!              - Read Cd_n10 fields in netcdf files
274      !!              - Read stokes drift 2d in netcdf files
275      !!              - Read wave number in netcdf files
276      !!              - Compute 3d stokes drift using Breivik et al.,2014
277      !!                formulation
278      !! ** action 
279      !!---------------------------------------------------------------------
280      INTEGER ::   ierror, ios   ! local integer
281      INTEGER ::   ifpr
282      !!
283      CHARACTER(len=100)     ::  cn_dir                          ! Root directory for location of drag coefficient files
284      TYPE(FLD_N), ALLOCATABLE, DIMENSION(:) ::   slf_i     ! array of namelist informations on the fields to read
285      TYPE(FLD_N)            ::  sn_cdg, sn_usd, sn_vsd,  &
286                             &   sn_hsw, sn_wmp, sn_wnum, sn_tauoc      ! informations about the fields to be read
287      !
288      NAMELIST/namsbc_wave/  sn_cdg, cn_dir, sn_usd, sn_vsd, sn_hsw, sn_wmp, sn_wnum, sn_tauoc
289      !!---------------------------------------------------------------------
290      !
291      REWIND( numnam_ref )              ! Namelist namsbc_wave in reference namelist : File for drag coeff. from wave model
292      READ  ( numnam_ref, namsbc_wave, IOSTAT = ios, ERR = 901)
293901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_wave in reference namelist', lwp )
294         
295      REWIND( numnam_cfg )              ! Namelist namsbc_wave in configuration namelist : File for drag coeff. from wave model
296      READ  ( numnam_cfg, namsbc_wave, IOSTAT = ios, ERR = 902 )
297902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_wave in configuration namelist', lwp )
298      IF(lwm) WRITE ( numond, namsbc_wave )
299      !
300      IF( ln_cdgw ) THEN
301         IF( .NOT. cpl_wdrag ) THEN
302            ALLOCATE( sf_cd(1), STAT=ierror )           !* allocate and fill sf_wave with sn_cdg
303            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable to allocate sf_cd structure' )
304            !
305                                   ALLOCATE( sf_cd(1)%fnow(jpi,jpj,1)   )
306            IF( sn_cdg%ln_tint )   ALLOCATE( sf_cd(1)%fdta(jpi,jpj,1,2) )
307            CALL fld_fill( sf_cd, (/ sn_cdg /), cn_dir, 'sbc_wave_init', 'Wave module ', 'namsbc_wave' )
308         ENDIF
309         ALLOCATE( cdn_wave(jpi,jpj) )
310      ENDIF
311
312      IF( ln_tauoc ) THEN
313         IF( .NOT. cpl_tauoc ) THEN
314            ALLOCATE( sf_tauoc(1), STAT=ierror )           !* allocate and fill sf_wave with sn_tauoc
315            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable to allocate sf_tauoc structure' )
316            !
317                                    ALLOCATE( sf_tauoc(1)%fnow(jpi,jpj,1)   )
318            IF( sn_tauoc%ln_tint )  ALLOCATE( sf_tauoc(1)%fdta(jpi,jpj,1,2) )
319            CALL fld_fill( sf_tauoc, (/ sn_tauoc /), cn_dir, 'sbc_wave_init', 'Wave module', 'namsbc_wave' )
320         ENDIF
321         ALLOCATE( tauoc_wave(jpi,jpj) )
322      ENDIF
323
324      IF( ln_sdw ) THEN   ! Find out how many fields have to be read from file if not coupled
325         jpfld=0
326         jp_usd=0   ;   jp_vsd=0   ;   jp_hsw=0   ;   jp_wmp=0
327         IF( .NOT. cpl_sdrftx ) THEN
328            jpfld  = jpfld + 1
329            jp_usd = jpfld
330         ENDIF
331         IF( .NOT. cpl_sdrfty ) THEN
332            jpfld  = jpfld + 1
333            jp_vsd = jpfld
334         ENDIF
335         IF( .NOT. cpl_hsig ) THEN
336            jpfld  = jpfld + 1
337            jp_hsw = jpfld
338         ENDIF
339         IF( .NOT. cpl_wper ) THEN
340            jpfld  = jpfld + 1
341            jp_wmp = jpfld
342         ENDIF
343
344         ! Read from file only the non-coupled fields
345         IF( jpfld > 0 ) THEN
346            ALLOCATE( slf_i(jpfld) )
347            IF( jp_usd > 0 )   slf_i(jp_usd) = sn_usd
348            IF( jp_vsd > 0 )   slf_i(jp_vsd) = sn_vsd
349            IF( jp_hsw > 0 )   slf_i(jp_hsw) = sn_hsw
350            IF( jp_wmp > 0 )   slf_i(jp_wmp) = sn_wmp
351            ALLOCATE( sf_sd(jpfld), STAT=ierror )   !* allocate and fill sf_sd with stokes drift
352            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable to allocate sf_sd structure' )
353            !
354            DO ifpr= 1, jpfld
355               ALLOCATE( sf_sd(ifpr)%fnow(jpi,jpj,1) )
356               IF( slf_i(ifpr)%ln_tint )   ALLOCATE( sf_sd(ifpr)%fdta(jpi,jpj,1,2) )
357            END DO
358            !
359            CALL fld_fill( sf_sd, slf_i, cn_dir, 'sbc_wave_init', 'Wave module ', 'namsbc_wave' )
360         ENDIF
361         ALLOCATE( usd  (jpi,jpj,jpk), vsd  (jpi,jpj,jpk), wsd(jpi,jpj,jpk) )
362         ALLOCATE( hsw  (jpi,jpj)    , wmp  (jpi,jpj)     )
363         ALLOCATE( ut0sd(jpi,jpj)    , vt0sd(jpi,jpj)     )
364         ALLOCATE( div_sd(jpi,jpj) )
365         ALLOCATE( tsd2d (jpi,jpj) )
366         usd(:,:,:) = 0._wp
367         vsd(:,:,:) = 0._wp
368         wsd(:,:,:) = 0._wp
369         ! Wave number needed only if ln_zdfqiao=T
370         IF( ln_zdfqiao .AND. .NOT.cpl_wnum ) THEN
371            ALLOCATE( sf_wn(1), STAT=ierror )           !* allocate and fill sf_wave with sn_wnum
372            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable toallocate sf_wn structure' )
373                                   ALLOCATE( sf_wn(1)%fnow(jpi,jpj,1)   )
374            IF( sn_wnum%ln_tint )  ALLOCATE( sf_wn(1)%fdta(jpi,jpj,1,2) )
375            CALL fld_fill( sf_wn, (/ sn_wnum /), cn_dir, 'sbc_wave', 'Wave module', 'namsbc_wave' )
376         ENDIF
377         ALLOCATE( wnum(jpi,jpj) )
378      ENDIF
379      !
380   END SUBROUTINE sbc_wave_init
381
382   !!======================================================================
383END MODULE sbcwave
Note: See TracBrowser for help on using the repository browser.