New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv.F90 in branches/UKMO/r6232_INGV1_WAVE-coupling/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/UKMO/r6232_INGV1_WAVE-coupling/NEMOGCM/NEMO/OPA_SRC/TRA/traadv.F90 @ 7471

Last change on this file since 7471 was 7471, checked in by jcastill, 7 years ago

Version as merged to the trunk during the Nov-2016 merge party, equivalent to branches/UKMO/r5936_INGV1_WAVE-coupling@7360
File size: 14.9 KB
Line 
1MODULE traadv
2   !!==============================================================================
3   !!                       ***  MODULE  traadv  ***
4   !! Ocean active tracers:  advection trend
5   !!==============================================================================
6   !! History :  2.0  !  2005-11  (G. Madec)  Original code
7   !!            3.3  !  2010-09  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
8   !!            3.6  !  2015-06  (E. Clementi) Addition of Stokes drift in case of wave coupling
9   !!            4.0  !  2011-06  (G. Madec)  Addition of Mixed Layer Eddy parameterisation
10   !!----------------------------------------------------------------------
11
12   !!----------------------------------------------------------------------
13   !!   tra_adv      : compute ocean tracer advection trend
14   !!   tra_adv_ctl  : control the different options of advection scheme
15   !!----------------------------------------------------------------------
16   USE oce             ! ocean dynamics and active tracers
17   USE dom_oce         ! ocean space and time domain
18   USE domvvl          ! variable vertical scale factors
19   USE traadv_cen2     ! 2nd order centered scheme (tra_adv_cen2   routine)
20   USE traadv_tvd      ! TVD      scheme           (tra_adv_tvd    routine)
21   USE traadv_muscl    ! MUSCL    scheme           (tra_adv_muscl  routine)
22   USE traadv_muscl2   ! MUSCL2   scheme           (tra_adv_muscl2 routine)
23   USE traadv_ubs      ! UBS      scheme           (tra_adv_ubs    routine)
24   USE traadv_qck      ! QUICKEST scheme           (tra_adv_qck    routine)
25   USE traadv_eiv      ! eddy induced velocity     (tra_adv_eiv    routine)
26   USE traadv_mle      ! ML eddy induced velocity  (tra_adv_mle    routine)
27   USE cla             ! cross land advection      (cla_traadv     routine)
28   USE ldftra_oce      ! lateral diffusion coefficient on tracers
29   !
30   USE in_out_manager  ! I/O manager
31   USE iom             ! I/O module
32   USE prtctl          ! Print control
33   USE lib_mpp         ! MPP library
34   USE wrk_nemo        ! Memory Allocation
35   USE timing          ! Timing
36   USE sbc_oce
37   USE sbcwave        ! wave module
38   USE sbc_oce        ! surface boundary condition: ocean
39   USE diaptr         ! Poleward heat transport
40
41   IMPLICIT NONE
42   PRIVATE
43
44   PUBLIC   tra_adv        ! routine called by step module
45   PUBLIC   tra_adv_init   ! routine called by opa module
46
47   !                              !!* Namelist namtra_adv *
48   LOGICAL ::   ln_traadv_cen2     ! 2nd order centered scheme flag
49   LOGICAL ::   ln_traadv_tvd      ! TVD scheme flag
50   LOGICAL ::   ln_traadv_tvd_zts  ! TVD scheme flag with vertical sub time-stepping
51   LOGICAL ::   ln_traadv_muscl    ! MUSCL scheme flag
52   LOGICAL ::   ln_traadv_muscl2   ! MUSCL2 scheme flag
53   LOGICAL ::   ln_traadv_ubs      ! UBS scheme flag
54   LOGICAL ::   ln_traadv_qck      ! QUICKEST scheme flag
55   LOGICAL ::   ln_traadv_msc_ups  ! use upstream scheme within muscl
56
57
58   INTEGER ::   nadv   ! choice of the type of advection scheme
59
60   !! * Substitutions
61#  include "domzgr_substitute.h90"
62#  include "vectopt_loop_substitute.h90"
63   !!----------------------------------------------------------------------
64   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
65   !! $Id$
66   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
67   !!----------------------------------------------------------------------
68CONTAINS
69
70   SUBROUTINE tra_adv( kt )
71      !!----------------------------------------------------------------------
72      !!                  ***  ROUTINE tra_adv  ***
73      !!
74      !! ** Purpose :   compute the ocean tracer advection trend.
75      !!
76      !! ** Method  : - Update (ua,va) with the advection term following nadv
77      !!----------------------------------------------------------------------
78      !
79      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
80      !
81      INTEGER ::   jk   ! dummy loop index
82      REAL(wp), POINTER, DIMENSION(:,:,:) :: zun, zvn, zwn
83      !!----------------------------------------------------------------------
84      !
85      IF( nn_timing == 1 )  CALL timing_start('tra_adv')
86      !
87      CALL wrk_alloc( jpi, jpj, jpk, zun, zvn, zwn )
88      !                                          ! set time step
89      zun(:,:,:) = 0.0 
90      zvn(:,:,:) = 0.0 
91      zwn(:,:,:) = 0.0 
92      !     
93      IF( neuler == 0 .AND. kt == nit000 ) THEN     ! at nit000
94         r2dtra(:) =  rdttra(:)                          ! = rdtra (restarting with Euler time stepping)
95      ELSEIF( kt <= nit000 + 1) THEN                ! at nit000 or nit000+1
96         r2dtra(:) = 2._wp * rdttra(:)                   ! = 2 rdttra (leapfrog)
97      ENDIF
98      !
99      IF( nn_cla == 1 .AND. cp_cfg == 'orca' .AND. jp_cfg == 2 )   CALL cla_traadv( kt )       !==  Cross Land Advection  ==! (hor. advection)
100      !
101      !                                               !==  effective transport  ==!
102      IF(ln_wave .AND. ln_sdw) THEN
103         DO jk = 1, jpkm1 
104            zun(:,:,jk) = e2u(:,:) * fse3u(:,:,jk) *      & 
105                        &  ( un(:,:,jk) + usd3d(:,:,jk) )                     !eulerian transport + Stokes Drift
106            zvn(:,:,jk) = e1v(:,:) * fse3v(:,:,jk) *      & 
107                        &  ( vn(:,:,jk) + vsd3d(:,:,jk) ) 
108            zwn(:,:,jk) = e1e2t(:,:) *                    & 
109                        &  ( wn(:,:,jk) + wsd3d(:,:,jk) ) 
110         END DO
111      ELSE
112         DO jk = 1, jpkm1 
113            zun(:,:,jk) = e2u  (:,:) * fse3u(:,:,jk) * un(:,:,jk)             ! eulerian transport only
114            zvn(:,:,jk) = e1v  (:,:) * fse3v(:,:,jk) * vn(:,:,jk) 
115            zwn(:,:,jk) = e1e2t(:,:)                 * wn(:,:,jk) 
116         END DO
117      ENDIF 
118      !
119      IF( ln_vvl_ztilde .OR. ln_vvl_layer ) THEN
120         zun(:,:,:) = zun(:,:,:) + un_td(:,:,:)
121         zvn(:,:,:) = zvn(:,:,:) + vn_td(:,:,:)
122      ENDIF
123      !
124      zun(:,:,jpk) = 0._wp                                                     ! no transport trough the bottom
125      zvn(:,:,jpk) = 0._wp                                                     ! no transport trough the bottom
126      zwn(:,:,jpk) = 0._wp                                                     ! no transport trough the bottom
127      !
128      IF( lk_traldf_eiv .AND. .NOT. ln_traldf_grif )   &
129         &              CALL tra_adv_eiv( kt, nit000, zun, zvn, zwn, 'TRA' )    ! add the eiv transport (if necessary)
130      !
131      IF( ln_mle    )   CALL tra_adv_mle( kt, nit000, zun, zvn, zwn, 'TRA' )    ! add the mle transport (if necessary)
132      !
133      CALL iom_put( "uocetr_eff", zun )                                         ! output effective transport     
134      CALL iom_put( "vocetr_eff", zvn )
135      CALL iom_put( "wocetr_eff", zwn )
136      !
137      IF( ln_diaptr )   CALL dia_ptr( zvn )                                     ! diagnose the effective MSF
138      !
139   
140      SELECT CASE ( nadv )                            !==  compute advection trend and add it to general trend  ==!
141      CASE ( 1 )   ;    CALL tra_adv_cen2   ( kt, nit000, 'TRA',         zun, zvn, zwn, tsb, tsn, tsa, jpts )   !  2nd order centered
142      CASE ( 2 )   ;    CALL tra_adv_tvd    ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )   !  TVD
143      CASE ( 3 )   ;    CALL tra_adv_muscl  ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb,      tsa, jpts, ln_traadv_msc_ups )   !  MUSCL
144      CASE ( 4 )   ;    CALL tra_adv_muscl2 ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )   !  MUSCL2
145      CASE ( 5 )   ;    CALL tra_adv_ubs    ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )   !  UBS
146      CASE ( 6 )   ;    CALL tra_adv_qck    ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )   !  QUICKEST
147      CASE ( 7 )   ;    CALL tra_adv_tvd_zts( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )   !  TVD ZTS
148      !
149      CASE (-1 )                                      !==  esopa: test all possibility with control print  ==!
150         CALL tra_adv_cen2  ( kt, nit000, 'TRA',         zun, zvn, zwn, tsb, tsn, tsa, jpts )         
151         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv0 - Ta: ', mask1=tmask,               &
152            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
153         CALL tra_adv_tvd   ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )         
154         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv1 - Ta: ', mask1=tmask,               &
155            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
156         CALL tra_adv_muscl ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb,      tsa, jpts, ln_traadv_msc_ups )         
157         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv3 - Ta: ', mask1=tmask,               &
158            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
159         CALL tra_adv_muscl2( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )         
160         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv4 - Ta: ', mask1=tmask,               &
161            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
162         CALL tra_adv_ubs   ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )         
163         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv5 - Ta: ', mask1=tmask,               &
164            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
165         CALL tra_adv_qck   ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )         
166         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv6 - Ta: ', mask1=tmask,               &
167            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
168      END SELECT
169      !
170      !                                              ! print mean trends (used for debugging)
171      IF(ln_ctl)   CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv  - Ta: ', mask1=tmask,               &
172         &                       tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
173      !
174      IF( nn_timing == 1 )  CALL timing_stop( 'tra_adv' )
175      !
176      CALL wrk_dealloc( jpi, jpj, jpk, zun, zvn, zwn )
177      !                                         
178   END SUBROUTINE tra_adv
179
180
181   SUBROUTINE tra_adv_init
182      !!---------------------------------------------------------------------
183      !!                  ***  ROUTINE tra_adv_init  ***
184      !!               
185      !! ** Purpose :   Control the consistency between namelist options for
186      !!              tracer advection schemes and set nadv
187      !!----------------------------------------------------------------------
188      INTEGER ::   ioptio
189      INTEGER ::   ios                 ! Local integer output status for namelist read
190      !!
191      NAMELIST/namtra_adv/ ln_traadv_cen2 , ln_traadv_tvd,     &
192         &                 ln_traadv_muscl, ln_traadv_muscl2,  &
193         &                 ln_traadv_ubs  , ln_traadv_qck,     &
194         &                 ln_traadv_msc_ups, ln_traadv_tvd_zts
195      !!----------------------------------------------------------------------
196
197      REWIND( numnam_ref )              ! Namelist namtra_adv in reference namelist : Tracer advection scheme
198      READ  ( numnam_ref, namtra_adv, IOSTAT = ios, ERR = 901)
199901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_adv in reference namelist', lwp )
200
201      REWIND( numnam_cfg )              ! Namelist namtra_adv in configuration namelist : Tracer advection scheme
202      READ  ( numnam_cfg, namtra_adv, IOSTAT = ios, ERR = 902 )
203902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_adv in configuration namelist', lwp )
204      IF(lwm) WRITE ( numond, namtra_adv )
205
206      IF(lwp) THEN                    ! Namelist print
207         WRITE(numout,*)
208         WRITE(numout,*) 'tra_adv_init : choice/control of the tracer advection scheme'
209         WRITE(numout,*) '~~~~~~~~~~~'
210         WRITE(numout,*) '   Namelist namtra_adv : chose a advection scheme for tracers'
211         WRITE(numout,*) '      2nd order advection scheme     ln_traadv_cen2    = ', ln_traadv_cen2
212         WRITE(numout,*) '      TVD advection scheme           ln_traadv_tvd     = ', ln_traadv_tvd
213         WRITE(numout,*) '      MUSCL  advection scheme        ln_traadv_muscl   = ', ln_traadv_muscl
214         WRITE(numout,*) '      MUSCL2 advection scheme        ln_traadv_muscl2  = ', ln_traadv_muscl2
215         WRITE(numout,*) '      UBS    advection scheme        ln_traadv_ubs     = ', ln_traadv_ubs
216         WRITE(numout,*) '      QUICKEST advection scheme      ln_traadv_qck     = ', ln_traadv_qck
217         WRITE(numout,*) '      upstream scheme within muscl   ln_traadv_msc_ups = ', ln_traadv_msc_ups
218         WRITE(numout,*) '      TVD advection scheme with zts  ln_traadv_tvd_zts = ', ln_traadv_tvd_zts
219      ENDIF
220
221      ioptio = 0                      ! Parameter control
222      IF( ln_traadv_cen2   )   ioptio = ioptio + 1
223      IF( ln_traadv_tvd    )   ioptio = ioptio + 1
224      IF( ln_traadv_muscl  )   ioptio = ioptio + 1
225      IF( ln_traadv_muscl2 )   ioptio = ioptio + 1
226      IF( ln_traadv_ubs    )   ioptio = ioptio + 1
227      IF( ln_traadv_qck    )   ioptio = ioptio + 1
228      IF( ln_traadv_tvd_zts)   ioptio = ioptio + 1
229      IF( lk_esopa         )   ioptio =          1
230
231      IF( ( ln_traadv_muscl .OR. ln_traadv_muscl2 .OR. ln_traadv_ubs .OR. ln_traadv_qck .OR. ln_traadv_tvd_zts )   &
232         .AND. ln_isfcav )   CALL ctl_stop( 'Only traadv_cen2 and traadv_tvd is compatible with ice shelf cavity')
233
234      IF( ioptio /= 1 )   CALL ctl_stop( 'Choose ONE advection scheme in namelist namtra_adv' )
235
236      !                              ! Set nadv
237      IF( ln_traadv_cen2   )   nadv =  1
238      IF( ln_traadv_tvd    )   nadv =  2
239      IF( ln_traadv_muscl  )   nadv =  3
240      IF( ln_traadv_muscl2 )   nadv =  4
241      IF( ln_traadv_ubs    )   nadv =  5
242      IF( ln_traadv_qck    )   nadv =  6
243      IF( ln_traadv_tvd_zts)   nadv =  7
244      IF( lk_esopa         )   nadv = -1
245
246      IF(lwp) THEN                   ! Print the choice
247         WRITE(numout,*)
248         IF( nadv ==  1 )   WRITE(numout,*) '         2nd order scheme is used'
249         IF( nadv ==  2 )   WRITE(numout,*) '         TVD       scheme is used'
250         IF( nadv ==  3 )   WRITE(numout,*) '         MUSCL     scheme is used'
251         IF( nadv ==  4 )   WRITE(numout,*) '         MUSCL2    scheme is used'
252         IF( nadv ==  5 )   WRITE(numout,*) '         UBS       scheme is used'
253         IF( nadv ==  6 )   WRITE(numout,*) '         QUICKEST  scheme is used'
254         IF( nadv ==  7 )   WRITE(numout,*) '         TVD ZTS   scheme is used'
255         IF( nadv == -1 )   WRITE(numout,*) '         esopa test: use all advection scheme'
256      ENDIF
257      !
258      CALL tra_adv_mle_init          ! initialisation of the Mixed Layer Eddy parametrisation (MLE)
259      !
260   END SUBROUTINE tra_adv_init
261
262  !!======================================================================
263END MODULE traadv
Note: See TracBrowser for help on using the repository browser.