source: branches/UKMO/r6232_collate_bgc_diagnostics/NEMOGCM/NEMO/OPA_SRC/BDY/bdylib.F90 @ 11134

Last change on this file since 11134 was 11134, checked in by jcastill, 17 months ago

Full set of changes as in the original branch

File size: 24.0 KB
Line 
1MODULE bdylib
2   !!======================================================================
3   !!                       ***  MODULE  bdylib  ***
4   !! Unstructured Open Boundary Cond. :  Library module of generic boundary algorithms.
5   !!======================================================================
6   !! History :  3.6  !  2013     (D. Storkey) new module
7   !!----------------------------------------------------------------------
8#if defined key_bdy 
9   !!----------------------------------------------------------------------
10   !!   'key_bdy' :                    Unstructured Open Boundary Condition
11   !!----------------------------------------------------------------------
12   !!   bdy_orlanski_2d
13   !!   bdy_orlanski_3d
14   !!----------------------------------------------------------------------
15   USE timing          ! Timing
16   USE oce             ! ocean dynamics and tracers
17   USE dom_oce         ! ocean space and time domain
18   USE bdy_oce         ! ocean open boundary conditions
19   USE phycst          ! physical constants
20   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
21   USE in_out_manager  !
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC   bdy_orlanski_2d     ! routine called where?
27   PUBLIC   bdy_orlanski_3d     ! routine called where?
28   PUBLIC   bdy_nmn     ! routine called where?
29
30   !!----------------------------------------------------------------------
31   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
32   !! $Id$
33   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
34   !!----------------------------------------------------------------------
35CONTAINS
36
37   SUBROUTINE bdy_orlanski_2d( idx, igrd, phib, phia, phi_ext, ll_npo )
38      !!----------------------------------------------------------------------
39      !!                 ***  SUBROUTINE bdy_orlanski_2d  ***
40      !!             
41      !!              - Apply Orlanski radiation condition adaptively to 2D fields:
42      !!                  - radiation plus weak nudging at outflow points
43      !!                  - no radiation and strong nudging at inflow points
44      !!
45      !!
46      !! References:  Marchesiello, McWilliams and Shchepetkin, Ocean Modelling vol. 3 (2001)   
47      !!----------------------------------------------------------------------
48      TYPE(OBC_INDEX),            INTENT(in)     ::   idx      ! BDY indices
49      INTEGER,                    INTENT(in)     ::   igrd     ! grid index
50      REAL(wp), DIMENSION(:,:),   INTENT(in)     ::   phib     ! model before 2D field
51      REAL(wp), DIMENSION(:,:),   INTENT(inout)  ::   phia     ! model after 2D field (to be updated)
52      REAL(wp), DIMENSION(:),     INTENT(in)     ::   phi_ext  ! external forcing data
53      LOGICAL,                    INTENT(in)     ::   ll_npo   ! switch for NPO version
54
55      INTEGER  ::   jb                                     ! dummy loop indices
56      INTEGER  ::   ii, ij, iibm1, iibm2, ijbm1, ijbm2     ! 2D addresses
57      INTEGER  ::   iijm1, iijp1, ijjm1, ijjp1             ! 2D addresses
58      INTEGER  ::   iibm1jp1, iibm1jm1, ijbm1jp1, ijbm1jm1 ! 2D addresses
59      INTEGER  ::   ii_offset, ij_offset                   ! offsets for mask indices
60      INTEGER  ::   flagu, flagv                           ! short cuts
61      REAL(wp) ::   zmask_x, zmask_y1, zmask_y2
62      REAL(wp) ::   zex1, zex2, zey, zey1, zey2
63      REAL(wp) ::   zdt, zdx, zdy, znor2, zrx, zry         ! intermediate calculations
64      REAL(wp) ::   zout, zwgt, zdy_centred
65      REAL(wp) ::   zdy_1, zdy_2, zsign_ups
66      REAL(wp), PARAMETER :: zepsilon = 1.e-30                 ! local small value
67      REAL(wp), POINTER, DIMENSION(:,:)          :: pmask      ! land/sea mask for field
68      REAL(wp), POINTER, DIMENSION(:,:)          :: pmask_xdif ! land/sea mask for x-derivatives
69      REAL(wp), POINTER, DIMENSION(:,:)          :: pmask_ydif ! land/sea mask for y-derivatives
70      REAL(wp), POINTER, DIMENSION(:,:)          :: pe_xdif    ! scale factors for x-derivatives
71      REAL(wp), POINTER, DIMENSION(:,:)          :: pe_ydif    ! scale factors for y-derivatives
72      !!----------------------------------------------------------------------
73
74      IF( nn_timing == 1 ) CALL timing_start('bdy_orlanski_2d')
75
76      ! ----------------------------------!
77      ! Orlanski boundary conditions     :!
78      ! ----------------------------------!
79     
80      SELECT CASE(igrd)
81         CASE(1)
82            pmask => tmask(:,:,1)
83            pmask_xdif => umask(:,:,1)
84            pmask_ydif => vmask(:,:,1)
85            pe_xdif => e1u(:,:)
86            pe_ydif => e2v(:,:)
87            ii_offset = 0
88            ij_offset = 0
89         CASE(2)
90            pmask => umask(:,:,1)
91            pmask_xdif => tmask(:,:,1)
92            pmask_ydif => fmask(:,:,1)
93            pe_xdif => e1t(:,:)
94            pe_ydif => e2f(:,:)
95            ii_offset = 1
96            ij_offset = 0
97         CASE(3)
98            pmask => vmask(:,:,1)
99            pmask_xdif => fmask(:,:,1)
100            pmask_ydif => tmask(:,:,1)
101            pe_xdif => e1f(:,:)
102            pe_ydif => e2t(:,:)
103            ii_offset = 0
104            ij_offset = 1
105         CASE DEFAULT ;   CALL ctl_stop( 'unrecognised value for igrd in bdy_orlanksi_2d' )
106      END SELECT
107      !
108      DO jb = 1, idx%nblenrim(igrd)
109         ii  = idx%nbi(jb,igrd)
110         ij  = idx%nbj(jb,igrd) 
111         flagu = int( idx%flagu(jb,igrd) )
112         flagv = int( idx%flagv(jb,igrd) )
113         !
114         ! Calculate positions of b-1 and b-2 points for this rim point
115         ! also (b-1,j-1) and (b-1,j+1) points
116         iibm1 = ii + flagu ; iibm2 = ii + 2*flagu 
117         ijbm1 = ij + flagv ; ijbm2 = ij + 2*flagv
118          !
119         iijm1 = ii - abs(flagv) ; iijp1 = ii + abs(flagv) 
120         ijjm1 = ij - abs(flagu) ; ijjp1 = ij + abs(flagu)
121         !
122         iibm1jm1 = ii + flagu - abs(flagv) ; iibm1jp1 = ii + flagu + abs(flagv) 
123         ijbm1jm1 = ij + flagv - abs(flagu) ; ijbm1jp1 = ij + flagv + abs(flagu) 
124         !
125         ! Calculate scale factors for calculation of spatial derivatives.       
126         zex1 = ( abs(iibm1-iibm2) * pe_xdif(iibm1+ii_offset,ijbm1          )         &
127        &       + abs(ijbm1-ijbm2) * pe_ydif(iibm1          ,ijbm1+ij_offset) ) 
128         zex2 = ( abs(iibm1-iibm2) * pe_xdif(iibm2+ii_offset,ijbm2          )         &
129        &       + abs(ijbm1-ijbm2) * pe_ydif(iibm2          ,ijbm2+ij_offset) ) 
130         zey1 = ( (iibm1-iibm1jm1) * pe_xdif(iibm1jm1+ii_offset,ijbm1jm1          )  & 
131        &      +  (ijbm1-ijbm1jm1) * pe_ydif(iibm1jm1          ,ijbm1jm1+ij_offset) ) 
132         zey2 = ( (iibm1jp1-iibm1) * pe_xdif(iibm1+ii_offset,ijbm1)                  &
133        &      +  (ijbm1jp1-ijbm1) * pe_ydif(iibm1          ,ijbm1+ij_offset) ) 
134         ! make sure scale factors are nonzero
135         if( zey1 .lt. rsmall ) zey1 = zey2
136         if( zey2 .lt. rsmall ) zey2 = zey1
137         zex1 = max(zex1,rsmall); zex2 = max(zex2,rsmall)
138         zey1 = max(zey1,rsmall); zey2 = max(zey2,rsmall); 
139         !
140         ! Calculate masks for calculation of spatial derivatives.       
141         zmask_x = ( abs(iibm1-iibm2) * pmask_xdif(iibm2+ii_offset,ijbm2          )         &
142        &          + abs(ijbm1-ijbm2) * pmask_ydif(iibm2          ,ijbm2+ij_offset) ) 
143         zmask_y1 = ( (iibm1-iibm1jm1) * pmask_xdif(iibm1jm1+ii_offset,ijbm1jm1          )  & 
144        &          +  (ijbm1-ijbm1jm1) * pmask_ydif(iibm1jm1          ,ijbm1jm1+ij_offset) ) 
145         zmask_y2 = ( (iibm1jp1-iibm1) * pmask_xdif(iibm1+ii_offset,ijbm1)                  &
146        &          +  (ijbm1jp1-ijbm1) * pmask_ydif(iibm1          ,ijbm1+ij_offset) ) 
147
148         ! Calculation of terms required for both versions of the scheme.
149         ! Mask derivatives to ensure correct land boundary conditions for each variable.
150         ! Centred derivative is calculated as average of "left" and "right" derivatives for
151         ! this reason.
152         ! Note no rdt factor in expression for zdt because it cancels in the expressions for
153         ! zrx and zry.
154         zdt = phia(iibm1,ijbm1) - phib(iibm1,ijbm1)
155         zdx = ( ( phia(iibm1,ijbm1) - phia(iibm2,ijbm2) ) / zex2 ) * zmask_x 
156         zdy_1 = ( ( phib(iibm1   ,ijbm1   ) - phib(iibm1jm1,ijbm1jm1) ) / zey1 ) * zmask_y1   
157         zdy_2 = ( ( phib(iibm1jp1,ijbm1jp1) - phib(iibm1   ,ijbm1)    ) / zey2 ) * zmask_y2 
158         zdy_centred = 0.5 * ( zdy_1 + zdy_2 )
159!!$         zdy_centred = phib(iibm1jp1,ijbm1jp1) - phib(iibm1jm1,ijbm1jm1)
160         ! upstream differencing for tangential derivatives
161         zsign_ups = sign( 1., zdt * zdy_centred )
162         zsign_ups = 0.5*( zsign_ups + abs(zsign_ups) )
163         zdy = zsign_ups * zdy_1 + (1. - zsign_ups) * zdy_2
164         znor2 = zdx * zdx + zdy * zdy
165         znor2 = max(znor2,zepsilon)
166         !
167         zrx = zdt * zdx / ( zex1 * znor2 ) 
168!!$         zrx = min(zrx,2.0_wp)
169         zout = sign( 1., zrx )
170         zout = 0.5*( zout + abs(zout) )
171         zwgt = 2.*rdt*( (1.-zout) * idx%nbd(jb,igrd) + zout * idx%nbdout(jb,igrd) )
172         ! only apply radiation on outflow points
173         if( ll_npo ) then     !! NPO version !!
174            phia(ii,ij) = (1.-zout) * ( phib(ii,ij) + zwgt * ( phi_ext(jb) - phib(ii,ij) ) )        &
175           &            + zout      * ( phib(ii,ij) + zrx*phia(iibm1,ijbm1)                         &
176           &                            + zwgt * ( phi_ext(jb) - phib(ii,ij) ) ) / ( 1. + zrx ) 
177         else                  !! full oblique radiation !!
178            zsign_ups = sign( 1., zdt * zdy )
179            zsign_ups = 0.5*( zsign_ups + abs(zsign_ups) )
180            zey = zsign_ups * zey1 + (1.-zsign_ups) * zey2 
181            zry = zdt * zdy / ( zey * znor2 ) 
182            phia(ii,ij) = (1.-zout) * ( phib(ii,ij) + zwgt * ( phi_ext(jb) - phib(ii,ij) ) )        &
183           &            + zout      * ( phib(ii,ij) + zrx*phia(iibm1,ijbm1)                         &
184           &                    - zsign_ups      * zry * ( phib(ii   ,ij   ) - phib(iijm1,ijjm1 ) ) &
185           &                    - (1.-zsign_ups) * zry * ( phib(iijp1,ijjp1) - phib(ii   ,ij    ) ) &
186           &                    + zwgt * ( phi_ext(jb) - phib(ii,ij) ) ) / ( 1. + zrx ) 
187         end if
188         phia(ii,ij) = phia(ii,ij) * pmask(ii,ij)
189      END DO
190      !
191      IF( nn_timing == 1 ) CALL timing_stop('bdy_orlanski_2d')
192
193   END SUBROUTINE bdy_orlanski_2d
194
195
196   SUBROUTINE bdy_orlanski_3d( idx, igrd, phib, phia, phi_ext, ll_npo )
197      !!----------------------------------------------------------------------
198      !!                 ***  SUBROUTINE bdy_orlanski_3d  ***
199      !!             
200      !!              - Apply Orlanski radiation condition adaptively to 3D fields:
201      !!                  - radiation plus weak nudging at outflow points
202      !!                  - no radiation and strong nudging at inflow points
203      !!
204      !!
205      !! References:  Marchesiello, McWilliams and Shchepetkin, Ocean Modelling vol. 3 (2001)   
206      !!----------------------------------------------------------------------
207      TYPE(OBC_INDEX),            INTENT(in)     ::   idx      ! BDY indices
208      INTEGER,                    INTENT(in)     ::   igrd     ! grid index
209      REAL(wp), DIMENSION(:,:,:), INTENT(in)     ::   phib     ! model before 3D field
210      REAL(wp), DIMENSION(:,:,:), INTENT(inout)  ::   phia     ! model after 3D field (to be updated)
211      REAL(wp), DIMENSION(:,:),   INTENT(in)     ::   phi_ext  ! external forcing data
212      LOGICAL,                    INTENT(in)     ::   ll_npo   ! switch for NPO version
213
214      INTEGER  ::   jb, jk                                 ! dummy loop indices
215      INTEGER  ::   ii, ij, iibm1, iibm2, ijbm1, ijbm2     ! 2D addresses
216      INTEGER  ::   iijm1, iijp1, ijjm1, ijjp1             ! 2D addresses
217      INTEGER  ::   iibm1jp1, iibm1jm1, ijbm1jp1, ijbm1jm1 ! 2D addresses
218      INTEGER  ::   ii_offset, ij_offset                   ! offsets for mask indices
219      INTEGER  ::   flagu, flagv                           ! short cuts
220      REAL(wp) ::   zmask_x, zmask_y1, zmask_y2
221      REAL(wp) ::   zex1, zex2, zey, zey1, zey2
222      REAL(wp) ::   zdt, zdx, zdy, znor2, zrx, zry         ! intermediate calculations
223      REAL(wp) ::   zout, zwgt, zdy_centred
224      REAL(wp) ::   zdy_1, zdy_2,  zsign_ups
225      REAL(wp), PARAMETER :: zepsilon = 1.e-30                 ! local small value
226      REAL(wp), POINTER, DIMENSION(:,:,:)        :: pmask      ! land/sea mask for field
227      REAL(wp), POINTER, DIMENSION(:,:,:)        :: pmask_xdif ! land/sea mask for x-derivatives
228      REAL(wp), POINTER, DIMENSION(:,:,:)        :: pmask_ydif ! land/sea mask for y-derivatives
229      REAL(wp), POINTER, DIMENSION(:,:)          :: pe_xdif    ! scale factors for x-derivatives
230      REAL(wp), POINTER, DIMENSION(:,:)          :: pe_ydif    ! scale factors for y-derivatives
231      !!----------------------------------------------------------------------
232
233      IF( nn_timing == 1 ) CALL timing_start('bdy_orlanski_3d')
234
235      ! ----------------------------------!
236      ! Orlanski boundary conditions     :!
237      ! ----------------------------------!
238     
239      SELECT CASE(igrd)
240         CASE(1)
241            pmask => tmask(:,:,:)
242            pmask_xdif => umask(:,:,:)
243            pmask_ydif => vmask(:,:,:)
244            pe_xdif => e1u(:,:)
245            pe_ydif => e2v(:,:)
246            ii_offset = 0
247            ij_offset = 0
248         CASE(2)
249            pmask => umask(:,:,:)
250            pmask_xdif => tmask(:,:,:)
251            pmask_ydif => fmask(:,:,:)
252            pe_xdif => e1t(:,:)
253            pe_ydif => e2f(:,:)
254            ii_offset = 1
255            ij_offset = 0
256         CASE(3)
257            pmask => vmask(:,:,:)
258            pmask_xdif => fmask(:,:,:)
259            pmask_ydif => tmask(:,:,:)
260            pe_xdif => e1f(:,:)
261            pe_ydif => e2t(:,:)
262            ii_offset = 0
263            ij_offset = 1
264         CASE DEFAULT ;   CALL ctl_stop( 'unrecognised value for igrd in bdy_orlanksi_2d' )
265      END SELECT
266
267      DO jk = 1, jpk
268         !           
269         DO jb = 1, idx%nblenrim(igrd)
270            ii  = idx%nbi(jb,igrd)
271            ij  = idx%nbj(jb,igrd) 
272            flagu = int( idx%flagu(jb,igrd) )
273            flagv = int( idx%flagv(jb,igrd) )
274            !
275            ! calculate positions of b-1 and b-2 points for this rim point
276            ! also (b-1,j-1) and (b-1,j+1) points
277            iibm1 = ii + flagu ; iibm2 = ii + 2*flagu 
278            ijbm1 = ij + flagv ; ijbm2 = ij + 2*flagv
279            !
280            iijm1 = ii - abs(flagv) ; iijp1 = ii + abs(flagv) 
281            ijjm1 = ij - abs(flagu) ; ijjp1 = ij + abs(flagu)
282            !
283            iibm1jm1 = ii + flagu - abs(flagv) ; iibm1jp1 = ii + flagu + abs(flagv) 
284            ijbm1jm1 = ij + flagv - abs(flagu) ; ijbm1jp1 = ij + flagv + abs(flagu) 
285            !
286            ! Calculate scale factors for calculation of spatial derivatives.       
287            zex1 = ( abs(iibm1-iibm2) * pe_xdif(iibm1+ii_offset,ijbm1          )         &
288           &       + abs(ijbm1-ijbm2) * pe_ydif(iibm1          ,ijbm1+ij_offset) ) 
289            zex2 = ( abs(iibm1-iibm2) * pe_xdif(iibm2+ii_offset,ijbm2          )         &
290           &       + abs(ijbm1-ijbm2) * pe_ydif(iibm2          ,ijbm2+ij_offset) ) 
291            zey1 = ( (iibm1-iibm1jm1) * pe_xdif(iibm1jm1+ii_offset,ijbm1jm1          )  & 
292           &      +  (ijbm1-ijbm1jm1) * pe_ydif(iibm1jm1          ,ijbm1jm1+ij_offset) ) 
293            zey2 = ( (iibm1jp1-iibm1) * pe_xdif(iibm1+ii_offset,ijbm1)                  &
294           &      +  (ijbm1jp1-ijbm1) * pe_ydif(iibm1          ,ijbm1+ij_offset) ) 
295            ! make sure scale factors are nonzero
296            if( zey1 .lt. rsmall ) zey1 = zey2
297            if( zey2 .lt. rsmall ) zey2 = zey1
298            zex1 = max(zex1,rsmall); zex2 = max(zex2,rsmall); 
299            zey1 = max(zey1,rsmall); zey2 = max(zey2,rsmall); 
300            !
301            ! Calculate masks for calculation of spatial derivatives.       
302            zmask_x = ( abs(iibm1-iibm2) * pmask_xdif(iibm2+ii_offset,ijbm2          ,jk)          &
303           &          + abs(ijbm1-ijbm2) * pmask_ydif(iibm2          ,ijbm2+ij_offset,jk) ) 
304            zmask_y1 = ( (iibm1-iibm1jm1) * pmask_xdif(iibm1jm1+ii_offset,ijbm1jm1          ,jk)   & 
305           &          +  (ijbm1-ijbm1jm1) * pmask_ydif(iibm1jm1          ,ijbm1jm1+ij_offset,jk) ) 
306            zmask_y2 = ( (iibm1jp1-iibm1) * pmask_xdif(iibm1+ii_offset,ijbm1          ,jk)         &
307           &          +  (ijbm1jp1-ijbm1) * pmask_ydif(iibm1          ,ijbm1+ij_offset,jk) ) 
308            !
309            ! Calculate normal (zrx) and tangential (zry) components of radiation velocities.
310            ! Mask derivatives to ensure correct land boundary conditions for each variable.
311            ! Centred derivative is calculated as average of "left" and "right" derivatives for
312            ! this reason.
313            zdt = phia(iibm1,ijbm1,jk) - phib(iibm1,ijbm1,jk)
314            zdx = ( ( phia(iibm1,ijbm1,jk) - phia(iibm2,ijbm2,jk) ) / zex2 ) * zmask_x                 
315            zdy_1 = ( ( phib(iibm1   ,ijbm1   ,jk) - phib(iibm1jm1,ijbm1jm1,jk) ) / zey1 ) * zmask_y1 
316            zdy_2 = ( ( phib(iibm1jp1,ijbm1jp1,jk) - phib(iibm1   ,ijbm1   ,jk) ) / zey2 ) * zmask_y2     
317            zdy_centred = 0.5 * ( zdy_1 + zdy_2 )
318!!$            zdy_centred = phib(iibm1jp1,ijbm1jp1,jk) - phib(iibm1jm1,ijbm1jm1,jk)
319            ! upstream differencing for tangential derivatives
320            zsign_ups = sign( 1., zdt * zdy_centred )
321            zsign_ups = 0.5*( zsign_ups + abs(zsign_ups) )
322            zdy = zsign_ups * zdy_1 + (1. - zsign_ups) * zdy_2
323            znor2 = zdx * zdx + zdy * zdy
324            znor2 = max(znor2,zepsilon)
325            !
326            ! update boundary value:
327            zrx = zdt * zdx / ( zex1 * znor2 )
328!!$            zrx = min(zrx,2.0_wp)
329            zout = sign( 1., zrx )
330            zout = 0.5*( zout + abs(zout) )
331            zwgt = 2.*rdt*( (1.-zout) * idx%nbd(jb,igrd) + zout * idx%nbdout(jb,igrd) )
332            ! only apply radiation on outflow points
333            if( ll_npo ) then     !! NPO version !!
334               phia(ii,ij,jk) = (1.-zout) * ( phib(ii,ij,jk) + zwgt * ( phi_ext(jb,jk) - phib(ii,ij,jk) ) ) &
335              &               + zout      * ( phib(ii,ij,jk) + zrx*phia(iibm1,ijbm1,jk)                     &
336              &                            + zwgt * ( phi_ext(jb,jk) - phib(ii,ij,jk) ) ) / ( 1. + zrx ) 
337            else                  !! full oblique radiation !!
338               zsign_ups = sign( 1., zdt * zdy )
339               zsign_ups = 0.5*( zsign_ups + abs(zsign_ups) )
340               zey = zsign_ups * zey1 + (1.-zsign_ups) * zey2 
341               zry = zdt * zdy / ( zey * znor2 ) 
342               phia(ii,ij,jk) = (1.-zout) * ( phib(ii,ij,jk) + zwgt * ( phi_ext(jb,jk) - phib(ii,ij,jk) ) )    &
343              &               + zout      * ( phib(ii,ij,jk) + zrx*phia(iibm1,ijbm1,jk)                        &
344              &                       - zsign_ups      * zry * ( phib(ii   ,ij   ,jk) - phib(iijm1,ijjm1,jk) ) &
345              &                       - (1.-zsign_ups) * zry * ( phib(iijp1,ijjp1,jk) - phib(ii   ,ij   ,jk) ) &
346              &                       + zwgt * ( phi_ext(jb,jk) - phib(ii,ij,jk) ) ) / ( 1. + zrx ) 
347            end if
348            phia(ii,ij,jk) = phia(ii,ij,jk) * pmask(ii,ij,jk)
349         END DO
350         !
351      END DO
352
353      IF( nn_timing == 1 ) CALL timing_stop('bdy_orlanski_3d')
354
355   END SUBROUTINE bdy_orlanski_3d
356
357   SUBROUTINE bdy_nmn( idx, igrd, phia ) 
358      !!----------------------------------------------------------------------
359      !!                 ***  SUBROUTINE bdy_nmn  ***
360      !!                     
361      !! ** Purpose : Duplicate the value at open boundaries, zero gradient.
362      !! 
363      !!----------------------------------------------------------------------
364      INTEGER,                    INTENT(in)     ::   igrd     ! grid index
365      REAL(wp), DIMENSION(:,:,:), INTENT(inout)  ::   phia     ! model after 3D field (to be updated)
366      TYPE(OBC_INDEX), INTENT(in) ::   idx  ! OBC indices
367      !! 
368      REAL(wp) ::   zcoef, zcoef1, zcoef2 
369      REAL(wp), POINTER, DIMENSION(:,:,:)        :: pmask      ! land/sea mask for field
370      REAL(wp), POINTER, DIMENSION(:,:)        :: bdypmask      ! land/sea mask for field
371      INTEGER  ::   ib, ik   ! dummy loop indices
372      INTEGER  ::   ii, ij, ip, jp   ! 2D addresses
373      !!----------------------------------------------------------------------
374      !
375      IF( nn_timing == 1 ) CALL timing_start('bdy_nmn') 
376      !
377      SELECT CASE(igrd) 
378         CASE(1) 
379            pmask => tmask(:,:,:) 
380            bdypmask => bdytmask(:,:) 
381         CASE(2) 
382            pmask => umask(:,:,:) 
383            bdypmask => bdyumask(:,:) 
384         CASE(3) 
385            pmask => vmask(:,:,:) 
386            bdypmask => bdyvmask(:,:) 
387         CASE DEFAULT ;   CALL ctl_stop( 'unrecognised value for igrd in bdy_nmn' ) 
388      END SELECT
389      DO ib = 1, idx%nblenrim(igrd) 
390         ii = idx%nbi(ib,igrd) 
391         ij = idx%nbj(ib,igrd) 
392         DO ik = 1, jpkm1 
393            ! search the sense of the gradient
394            zcoef1 = bdypmask(ii-1,ij  )*pmask(ii-1,ij,ik) +  bdypmask(ii+1,ij  )*pmask(ii+1,ij,ik) 
395            zcoef2 = bdypmask(ii  ,ij-1)*pmask(ii,ij-1,ik) +  bdypmask(ii  ,ij+1)*pmask(ii,ij+1,ik) 
396            IF ( nint(zcoef1+zcoef2) == 0) THEN 
397               ! corner **** we probably only want to set the tangentail component for the dynamics here
398               zcoef = pmask(ii-1,ij,ik) + pmask(ii+1,ij,ik) +  pmask(ii,ij-1,ik) +  pmask(ii,ij+1,ik) 
399               IF (zcoef > .5_wp) THEN ! Only set none isolated points.
400                 phia(ii,ij,ik) = phia(ii-1,ij  ,ik) * pmask(ii-1,ij  ,ik) + & 
401                   &              phia(ii+1,ij  ,ik) * pmask(ii+1,ij  ,ik) + & 
402                   &              phia(ii  ,ij-1,ik) * pmask(ii  ,ij-1,ik) + & 
403                   &              phia(ii  ,ij+1,ik) * pmask(ii  ,ij+1,ik) 
404                 phia(ii,ij,ik) = ( phia(ii,ij,ik) / zcoef ) * pmask(ii,ij,ik) 
405               ELSE
406                 phia(ii,ij,ik) = phia(ii,ij  ,ik) * pmask(ii,ij  ,ik) 
407               ENDIF
408            ELSEIF ( nint(zcoef1+zcoef2) == 2) THEN 
409               ! oblique corner **** we probably only want to set the normal component for the dynamics here
410               zcoef = pmask(ii-1,ij,ik)*bdypmask(ii-1,ij  ) + pmask(ii+1,ij,ik)*bdypmask(ii+1,ij  ) + & 
411                   &   pmask(ii,ij-1,ik)*bdypmask(ii,ij -1 ) +  pmask(ii,ij+1,ik)*bdypmask(ii,ij+1  ) 
412               phia(ii,ij,ik) = phia(ii-1,ij  ,ik) * pmask(ii-1,ij  ,ik)*bdypmask(ii-1,ij  ) + & 
413                   &            phia(ii+1,ij  ,ik) * pmask(ii+1,ij  ,ik)*bdypmask(ii+1,ij  )  + & 
414                   &            phia(ii  ,ij-1,ik) * pmask(ii  ,ij-1,ik)*bdypmask(ii,ij -1 ) + & 
415                   &            phia(ii  ,ij+1,ik) * pmask(ii  ,ij+1,ik)*bdypmask(ii,ij+1  ) 
416   
417               phia(ii,ij,ik) = ( phia(ii,ij,ik) / MAX(1._wp, zcoef) ) * pmask(ii,ij,ik) 
418            ELSE
419               ip = nint(bdypmask(ii+1,ij  )*pmask(ii+1,ij,ik) - bdypmask(ii-1,ij  )*pmask(ii-1,ij,ik)) 
420               jp = nint(bdypmask(ii  ,ij+1)*pmask(ii,ij+1,ik) - bdypmask(ii  ,ij-1)*pmask(ii,ij-1,ik)) 
421               phia(ii,ij,ik) = phia(ii+ip,ij+jp,ik) * pmask(ii+ip,ij+jp,ik) 
422            ENDIF
423         END DO
424      END DO 
425      !
426      IF( nn_timing == 1 ) CALL timing_stop('bdy_nmn') 
427      !
428   END SUBROUTINE bdy_nmn 
429
430
431#else
432   !!----------------------------------------------------------------------
433   !!   Dummy module                   NO Unstruct Open Boundary Conditions
434   !!----------------------------------------------------------------------
435CONTAINS
436   SUBROUTINE bdy_orlanski_2d( idx, igrd, phib, phia, phi_ext  )      ! Empty routine
437      WRITE(*,*) 'bdy_orlanski_2d: You should not have seen this print! error?', kt
438   END SUBROUTINE bdy_orlanski_2d
439   SUBROUTINE bdy_orlanski_3d( idx, igrd, phib, phia, phi_ext  )      ! Empty routine
440      WRITE(*,*) 'bdy_orlanski_3d: You should not have seen this print! error?', kt
441   END SUBROUTINE bdy_orlanski_3d
442   SUBROUTINE bdy_nmn( idx, igrd, phia )      ! Empty routine
443      WRITE(*,*) 'bdy_nmn: You should not have seen this print! error?', kt 
444   END SUBROUTINE bdy_nmn 
445#endif
446
447   !!======================================================================
448END MODULE bdylib
Note: See TracBrowser for help on using the repository browser.