New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynkeg.F90 in branches/UKMO/r6232_collate_bgc_diagnostics/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/UKMO/r6232_collate_bgc_diagnostics/NEMOGCM/NEMO/OPA_SRC/DYN/dynkeg.F90 @ 11134

Last change on this file since 11134 was 11134, checked in by jcastill, 5 years ago

Full set of changes as in the original branch
File size: 9.1 KB
RevLine 
[3]1MODULE dynkeg
2   !!======================================================================
3   !!                       ***  MODULE  dynkeg  ***
4   !! Ocean dynamics:  kinetic energy gradient trend
5   !!======================================================================
[5321]6   !! History :  1.0  !  1987-09  (P. Andrich, M.-A. Foujols)  Original code
7   !!            7.0  !  1997-05  (G. Madec)  Split dynber into dynkeg and dynhpg
8   !!  NEMO      1.0  !  2002-07  (G. Madec)  F90: Free form and module
[5328]9   !!            3.6  !  2015-05  (N. Ducousso, G. Madec)  add Hollingsworth scheme as an option
[503]10   !!----------------------------------------------------------------------
[5328]11   
[3]12   !!----------------------------------------------------------------------
13   !!   dyn_keg      : update the momentum trend with the horizontal tke
14   !!----------------------------------------------------------------------
15   USE oce             ! ocean dynamics and tracers
16   USE dom_oce         ! ocean space and time domain
[4990]17   USE trd_oce         ! trends: ocean variables
18   USE trddyn          ! trend manager: dynamics
19   !
[2715]20   USE in_out_manager  ! I/O manager
[5321]21   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
[2715]22   USE lib_mpp         ! MPP library
[258]23   USE prtctl          ! Print control
[3294]24   USE wrk_nemo        ! Memory Allocation
25   USE timing          ! Timing
[11134]26#if defined key_bdy 
27   USE bdy_oce         ! ocean open boundary conditions
28#endif
[3]29
30   IMPLICIT NONE
31   PRIVATE
32
[503]33   PUBLIC   dyn_keg    ! routine called by step module
[5328]34   
[5321]35   INTEGER, PARAMETER, PUBLIC  ::   nkeg_C2  = 0   !: 2nd order centered scheme (standard scheme)
36   INTEGER, PARAMETER, PUBLIC  ::   nkeg_HW  = 1   !: Hollingsworth et al., QJRMS, 1983
37   !
38   REAL(wp) ::   r1_48 = 1._wp / 48._wp   !: =1/(4*2*6)
[5328]39   
[3]40   !! * Substitutions
41#  include "vectopt_loop_substitute.h90"
[503]42   !!----------------------------------------------------------------------
[5321]43   !! NEMO/OPA 3.6 , NEMO Consortium (2015)
[11132]44   !! $Id$
[2715]45   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
[503]46   !!----------------------------------------------------------------------
[3]47CONTAINS
48
[5321]49   SUBROUTINE dyn_keg( kt, kscheme )
[3]50      !!----------------------------------------------------------------------
51      !!                  ***  ROUTINE dyn_keg  ***
52      !!
53      !! ** Purpose :   Compute the now momentum trend due to the horizontal
[5328]54      !!      gradient of the horizontal kinetic energy and add it to the
[3]55      !!      general momentum trend.
56      !!
[5328]57      !! ** Method  : * kscheme = nkeg_C2 : 2nd order centered scheme that
58      !!      conserve kinetic energy. Compute the now horizontal kinetic energy
[3]59      !!         zhke = 1/2 [ mi-1( un^2 ) + mj-1( vn^2 ) ]
[5321]60      !!              * kscheme = nkeg_HW : Hollingsworth correction following
61      !!      Arakawa (2001). The now horizontal kinetic energy is given by:
62      !!         zhke = 1/6 [ mi-1(  2 * un^2 + ((un(j+1)+un(j-1))/2)^2  )
63      !!                    + mj-1(  2 * vn^2 + ((vn(i+1)+vn(i-1))/2)^2  ) ]
[5328]64      !!     
[3]65      !!      Take its horizontal gradient and add it to the general momentum
66      !!      trend (ua,va).
67      !!         ua = ua - 1/e1u di[ zhke ]
68      !!         va = va - 1/e2v dj[ zhke ]
69      !!
70      !! ** Action : - Update the (ua, va) with the hor. ke gradient trend
[4990]71      !!             - send this trends to trd_dyn (l_trddyn=T) for post-processing
[5321]72      !!
73      !! ** References : Arakawa, A., International Geophysics 2001.
74      !!                 Hollingsworth et al., Quart. J. Roy. Meteor. Soc., 1983.
[503]75      !!----------------------------------------------------------------------
[5321]76      INTEGER, INTENT( in ) ::   kt        ! ocean time-step index
[5328]77      INTEGER, INTENT( in ) ::   kscheme   ! =0/1   type of KEG scheme
[4990]78      !
[503]79      INTEGER  ::   ji, jj, jk   ! dummy loop indices
80      REAL(wp) ::   zu, zv       ! temporary scalars
[5328]81      REAL(wp), POINTER, DIMENSION(:,:,:) :: zhke
82      REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrdu, ztrdv 
[11134]83#if defined key_bdy 
84      INTEGER  ::   jb                 ! dummy loop indices
85      INTEGER  ::   ii, ij, igrd, ib_bdy   ! local integers
86      INTEGER  ::   fu, fv 
87#endif 
[3]88      !!----------------------------------------------------------------------
[3294]89      !
[5321]90      IF( nn_timing == 1 )   CALL timing_start('dyn_keg')
[3294]91      !
[5328]92      CALL wrk_alloc( jpi,jpj,jpk,   zhke )
[3294]93      !
[3]94      IF( kt == nit000 ) THEN
95         IF(lwp) WRITE(numout,*)
[5321]96         IF(lwp) WRITE(numout,*) 'dyn_keg : kinetic energy gradient trend, scheme number=', kscheme
[3]97         IF(lwp) WRITE(numout,*) '~~~~~~~'
98      ENDIF
[216]99
[503]100      IF( l_trddyn ) THEN           ! Save ua and va trends
[5321]101         CALL wrk_alloc( jpi,jpj,jpk,   ztrdu, ztrdv )
[5328]102         ztrdu(:,:,:) = ua(:,:,:) 
103         ztrdv(:,:,:) = va(:,:,:) 
[216]104      ENDIF
[5328]105     
106      zhke(:,:,jpk) = 0._wp
[11134]107
108#if defined key_bdy 
109      ! Maria Luneva & Fred Wobus: July-2016
110      ! compensate for lack of turbulent kinetic energy on liquid bdy points
111      DO ib_bdy = 1, nb_bdy 
112         IF( cn_dyn3d(ib_bdy) /= 'none' ) THEN
113            igrd = 2           ! Copying normal velocity into points outside bdy
114            DO jb = 1, idx_bdy(ib_bdy)%nblenrim(igrd) 
115               DO jk = 1, jpkm1 
116                  ii   = idx_bdy(ib_bdy)%nbi(jb,igrd) 
117                  ij   = idx_bdy(ib_bdy)%nbj(jb,igrd) 
118                  fu   = NINT( idx_bdy(ib_bdy)%flagu(jb,igrd) ) 
119                  un(ii-fu,ij,jk) = un(ii,ij,jk) * umask(ii,ij,jk) 
120               END DO
121            END DO 
122            !
123            igrd = 3           ! Copying normal velocity into points outside bdy
124            DO jb = 1, idx_bdy(ib_bdy)%nblenrim(igrd) 
125               DO jk = 1, jpkm1 
126                  ii   = idx_bdy(ib_bdy)%nbi(jb,igrd) 
127                  ij   = idx_bdy(ib_bdy)%nbj(jb,igrd) 
128                  fv   = NINT( idx_bdy(ib_bdy)%flagv(jb,igrd) ) 
129                  vn(ii,ij-fv,jk) = vn(ii,ij,jk) * vmask(ii,ij,jk) 
130               END DO
131            END DO
132         ENDIF
133      ENDDO 
134#endif       
135
[5328]136      SELECT CASE ( kscheme )             !== Horizontal kinetic energy at T-point  ==!
137      !
138      CASE ( nkeg_C2 )                          !--  Standard scheme  --!
139         DO jk = 1, jpkm1
[5321]140            DO jj = 2, jpj
141               DO ji = fs_2, jpi   ! vector opt.
142                  zu =    un(ji-1,jj  ,jk) * un(ji-1,jj  ,jk)   &
143                     &  + un(ji  ,jj  ,jk) * un(ji  ,jj  ,jk)
144                  zv =    vn(ji  ,jj-1,jk) * vn(ji  ,jj-1,jk)   &
145                     &  + vn(ji  ,jj  ,jk) * vn(ji  ,jj  ,jk)
[5328]146                  zhke(ji,jj,jk) = 0.25_wp * ( zv + zu )
147               END DO 
[5321]148            END DO
[5328]149         END DO
[5321]150         !
[11134]151         CALL lbc_lnk( zhke, 'T', 1. )
152         !
[5328]153      CASE ( nkeg_HW )                          !--  Hollingsworth scheme  --!
154         DO jk = 1, jpkm1
155            DO jj = 2, jpjm1       
[5321]156               DO ji = fs_2, jpim1   ! vector opt.
157                  zu = 8._wp * ( un(ji-1,jj  ,jk) * un(ji-1,jj  ,jk)    &
158                     &         + un(ji  ,jj  ,jk) * un(ji  ,jj  ,jk) )  &
159                     &   +     ( un(ji-1,jj-1,jk) + un(ji-1,jj+1,jk) ) * ( un(ji-1,jj-1,jk) + un(ji-1,jj+1,jk) )   &
160                     &   +     ( un(ji  ,jj-1,jk) + un(ji  ,jj+1,jk) ) * ( un(ji  ,jj-1,jk) + un(ji  ,jj+1,jk) )
161                     !
162                  zv = 8._wp * ( vn(ji  ,jj-1,jk) * vn(ji  ,jj-1,jk)    &
163                     &         + vn(ji  ,jj  ,jk) * vn(ji  ,jj  ,jk) )  &
164                     &  +      ( vn(ji-1,jj-1,jk) + vn(ji+1,jj-1,jk) ) * ( vn(ji-1,jj-1,jk) + vn(ji+1,jj-1,jk) )   &
165                     &  +      ( vn(ji-1,jj  ,jk) + vn(ji+1,jj  ,jk) ) * ( vn(ji-1,jj  ,jk) + vn(ji+1,jj  ,jk) )
[5328]166                  zhke(ji,jj,jk) = r1_48 * ( zv + zu )
167               END DO 
[5321]168            END DO
[5328]169         END DO
170         CALL lbc_lnk( zhke, 'T', 1. )
[5321]171         !
[5328]172      END SELECT
173      !
[11134]174
175#if defined key_bdy 
176      ! restore velocity masks at points outside boundary
177      un(:,:,:) = un(:,:,:) * umask(:,:,:) 
178      vn(:,:,:) = vn(:,:,:) * vmask(:,:,:) 
179#endif 
180
[5328]181      DO jk = 1, jpkm1                    !==  grad( KE ) added to the general momentum trends  ==!
[5321]182         DO jj = 2, jpjm1
[3]183            DO ji = fs_2, fs_jpim1   ! vector opt.
[5328]184               ua(ji,jj,jk) = ua(ji,jj,jk) - ( zhke(ji+1,jj  ,jk) - zhke(ji,jj,jk) ) / e1u(ji,jj)
185               va(ji,jj,jk) = va(ji,jj,jk) - ( zhke(ji  ,jj+1,jk) - zhke(ji,jj,jk) ) / e2v(ji,jj)
186            END DO
[3]187         END DO
[5321]188      END DO
189      !
190      IF( l_trddyn ) THEN                 ! save the Kinetic Energy trends for diagnostic
[503]191         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
192         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
[4990]193         CALL trd_dyn( ztrdu, ztrdv, jpdyn_keg, kt )
[5321]194         CALL wrk_dealloc( jpi,jpj,jpk,   ztrdu, ztrdv )
[216]195      ENDIF
[503]196      !
197      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' keg  - Ua: ', mask1=umask,   &
198         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
199      !
[5328]200      CALL wrk_dealloc( jpi,jpj,jpk,   zhke )
[2715]201      !
[5321]202      IF( nn_timing == 1 )   CALL timing_stop('dyn_keg')
[3294]203      !
[3]204   END SUBROUTINE dyn_keg
205
206   !!======================================================================
207END MODULE dynkeg
Note: See TracBrowser for help on using the repository browser.