New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcrnf.F90 in branches/UKMO/r6232_rnf_cplmask/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/UKMO/r6232_rnf_cplmask/NEMOGCM/NEMO/OPA_SRC/SBC/sbcrnf.F90 @ 9283

Last change on this file since 9283 was 9283, checked in by jcastill, 6 years ago

Remove svn keywords

File size: 29.9 KB
Line 
1MODULE sbcrnf
2   !!======================================================================
3   !!                       ***  MODULE  sbcrnf  ***
4   !! Ocean forcing:  river runoff
5   !!=====================================================================
6   !! History :  OPA  ! 2000-11  (R. Hordoir, E. Durand)  NetCDF FORMAT
7   !!   NEMO     1.0  ! 2002-09  (G. Madec)  F90: Free form and module
8   !!            3.0  ! 2006-07  (G. Madec)  Surface module
9   !!            3.2  ! 2009-04  (B. Lemaire)  Introduce iom_put
10   !!            3.3  ! 2010-10  (R. Furner, G. Madec) runoff distributed over ocean levels
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   sbc_rnf      : monthly runoffs read in a NetCDF file
15   !!   sbc_rnf_init : runoffs initialisation
16   !!   rnf_mouth    : set river mouth mask
17   !!----------------------------------------------------------------------
18   USE dom_oce         ! ocean space and time domain
19   USE phycst          ! physical constants
20   USE sbc_oce         ! surface boundary condition variables
21   USE sbcisf          ! PM we could remove it I think
22   USE closea          ! closed seas
23   USE fldread         ! read input field at current time step
24   USE in_out_manager  ! I/O manager
25   USE iom             ! I/O module
26   USE lib_mpp         ! MPP library
27   USE eosbn2
28   USE wrk_nemo        ! Memory allocation
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   sbc_rnf       ! routine call in sbcmod module
34   PUBLIC   sbc_rnf_div   ! routine called in divcurl module
35   PUBLIC   sbc_rnf_alloc ! routine call in sbcmod module
36   PUBLIC   sbc_rnf_init  ! (PUBLIC for TAM)
37   !                                                     !!* namsbc_rnf namelist *
38   CHARACTER(len=100)         ::   cn_dir          !: Root directory for location of rnf files
39   LOGICAL                    ::   ln_rnf_depth      !: depth       river runoffs attribute specified in a file
40   LOGICAL                    ::   ln_rnf_depth_ini  !: depth       river runoffs  computed at the initialisation
41   REAL(wp)                   ::   rn_rnf_max        !: maximum value of the runoff climatologie ( ln_rnf_depth_ini = .true )
42   REAL(wp)                   ::   rn_dep_max        !: depth over which runoffs is spread ( ln_rnf_depth_ini = .true )
43   INTEGER                    ::   nn_rnf_depth_file !: create (=1) a runoff depth file or not (=0)
44   LOGICAL                    ::   ln_rnf_tem      !: temperature river runoffs attribute specified in a file
45   LOGICAL           , PUBLIC ::   ln_rnf_sal      !: salinity    river runoffs attribute specified in a file
46   TYPE(FLD_N)       , PUBLIC ::   sn_rnf          !: information about the runoff file to be read
47   TYPE(FLD_N)                ::   sn_cnf          !: information about the runoff mouth file to be read
48   TYPE(FLD_N)                ::   sn_s_rnf        !: information about the salinities of runoff file to be read
49   TYPE(FLD_N)                ::   sn_t_rnf        !: information about the temperatures of runoff file to be read
50   TYPE(FLD_N)                ::   sn_dep_rnf      !: information about the depth which river inflow affects
51   LOGICAL           , PUBLIC ::   ln_rnf_mouth    !: specific treatment in mouths vicinity
52   REAL(wp)                   ::   rn_hrnf         !: runoffs, depth over which enhanced vertical mixing is used
53   REAL(wp)          , PUBLIC ::   rn_avt_rnf      !: runoffs, value of the additional vertical mixing coef. [m2/s]
54   REAL(wp)          , PUBLIC ::   rn_rfact        !: multiplicative factor for runoff
55
56   LOGICAL           , PUBLIC ::   l_rnfcpl = .false.       ! runoffs recieved from oasis
57
58   INTEGER , PUBLIC  ::   nkrnf = 0         !: nb of levels over which Kz is increased at river mouths
59   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   rnfmsk              !: river mouth mask (hori.)
60   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:)     ::   rnfmsk_z            !: river mouth mask (vert.)
61   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   h_rnf               !: depth of runoff in m
62   INTEGER,  PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   nk_rnf              !: depth of runoff in model levels
63   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   rnf_tsc_b, rnf_tsc  !: before and now T & S runoff contents   [K.m/s & PSU.m/s]   
64
65   TYPE(FLD),        ALLOCATABLE, DIMENSION(:) ::   sf_rnf       ! structure: river runoff (file information, fields read)
66   TYPE(FLD),        ALLOCATABLE, DIMENSION(:) ::   sf_s_rnf     ! structure: river runoff salinity (file information, fields read) 
67   TYPE(FLD),        ALLOCATABLE, DIMENSION(:) ::   sf_t_rnf     ! structure: river runoff temperature (file information, fields read) 
68 
69   !! * Substitutions 
70#  include "domzgr_substitute.h90" 
71   !!----------------------------------------------------------------------
72   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
73   !! $Id$
74   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
75   !!----------------------------------------------------------------------
76CONTAINS
77
78   INTEGER FUNCTION sbc_rnf_alloc()
79      !!----------------------------------------------------------------------
80      !!                ***  ROUTINE sbc_rnf_alloc  ***
81      !!----------------------------------------------------------------------
82      ALLOCATE( rnfmsk(jpi,jpj)         , rnfmsk_z(jpk)          ,     &
83         &      h_rnf (jpi,jpj)         , nk_rnf  (jpi,jpj)      ,     &
84         &      rnf_tsc_b(jpi,jpj,jpts) , rnf_tsc (jpi,jpj,jpts) ,     &
85         &      xrnfmask(jpi,jpj,1)     , STAT=sbc_rnf_alloc )
86         !
87      IF( lk_mpp            )   CALL mpp_sum ( sbc_rnf_alloc )
88      IF( sbc_rnf_alloc > 0 )   CALL ctl_warn('sbc_rnf_alloc: allocation of arrays failed')
89   END FUNCTION sbc_rnf_alloc
90
91
92   SUBROUTINE sbc_rnf( kt )
93      !!----------------------------------------------------------------------
94      !!                  ***  ROUTINE sbc_rnf  ***
95      !!
96      !! ** Purpose :   Introduce a climatological run off forcing
97      !!
98      !! ** Method  :   Set each river mouth with a monthly climatology
99      !!                provided from different data.
100      !!                CAUTION : upward water flux, runoff forced to be < 0
101      !!
102      !! ** Action  :   runoff updated runoff field at time-step kt
103      !!----------------------------------------------------------------------
104      INTEGER, INTENT(in) ::   kt          ! ocean time step
105      !
106      INTEGER  ::   ji, jj    ! dummy loop indices
107      INTEGER  ::   z_err = 0 ! dummy integer for error handling
108      !!----------------------------------------------------------------------
109      REAL(wp), DIMENSION(:,:), POINTER       ::   ztfrz   ! freezing point used for temperature correction
110      !
111      CALL wrk_alloc( jpi,jpj, ztfrz)
112
113      !                                            ! ---------------------------------------- !
114      IF( kt /= nit000 ) THEN                      !          Swap of forcing fields          !
115         !                                         ! ---------------------------------------- !
116         rnf_b    (:,:  ) = rnf    (:,:  )               ! Swap the ocean forcing fields except at nit000
117         rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)               ! where before fields are set at the end of the routine
118         !
119      ENDIF
120
121      !                                            !-------------------!
122      !                                            !   Update runoff   !
123      !                                            !-------------------!
124      !
125      IF( .NOT. l_rnfcpl )   CALL fld_read ( kt, nn_fsbc, sf_rnf   )    ! Read Runoffs data and provide it at kt
126      IF(   ln_rnf_tem   )   CALL fld_read ( kt, nn_fsbc, sf_t_rnf )    ! idem for runoffs temperature if required
127      IF(   ln_rnf_sal   )   CALL fld_read ( kt, nn_fsbc, sf_s_rnf )    ! idem for runoffs salinity    if required
128      !
129      IF( MOD( kt - 1, nn_fsbc ) == 0 ) THEN
130         !
131         IF( .NOT. l_rnfcpl )   &
132             rnf(:,:) = rnf(:,:) * (1. - xrnfmask(:,:,1)) + rn_rfact * sf_rnf(1)%fnow(:,:,1) * xrnfmask(:,:,1)  ! updated runoff value at time step kt
133
134         !
135         !                                                     ! set temperature & salinity content of runoffs
136         IF( ln_rnf_tem ) THEN                                       ! use runoffs temperature data
137            rnf_tsc(:,:,jp_tem) = ( sf_t_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rau0
138            WHERE( sf_t_rnf(1)%fnow(:,:,1) == -999._wp )             ! if missing data value use SST as runoffs temperature
139               rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rau0
140            END WHERE
141            WHERE( sf_t_rnf(1)%fnow(:,:,1) == -222._wp )             ! where fwf comes from melting of ice shelves or iceberg
142               ztfrz(:,:) = -1.9 !tfreez( sss_m(:,:) ) !PM to be discuss (trouble if sensitivity study)
143               rnf_tsc(:,:,jp_tem) = ztfrz(:,:) * rnf(:,:) * r1_rau0 - rnf(:,:) * lfusisf * r1_rau0_rcp
144            END WHERE
145         ELSE                                                        ! use SST as runoffs temperature
146            rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rau0
147         ENDIF
148         !                                                           ! use runoffs salinity data
149         IF( ln_rnf_sal )   rnf_tsc(:,:,jp_sal) = ( sf_s_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rau0
150         !                                                           ! else use S=0 for runoffs (done one for all in the init)
151         CALL iom_put( "runoffs", rnf )         ! output runoffs arrays
152      ENDIF
153      !
154      !                                                ! ---------------------------------------- !
155      IF( kt == nit000 ) THEN                          !   set the forcing field at nit000 - 1    !
156         !                                             ! ---------------------------------------- !
157         IF( ln_rstart .AND.    &                               !* Restart: read in restart file
158            & iom_varid( numror, 'rnf_b', ldstop = .FALSE. ) > 0 ) THEN
159            IF(lwp) WRITE(numout,*) '          nit000-1 runoff forcing fields red in the restart file'
160            CALL iom_get( numror, jpdom_autoglo, 'rnf_b', rnf_b )     ! before runoff
161            CALL iom_get( numror, jpdom_autoglo, 'rnf_hc_b', rnf_tsc_b(:,:,jp_tem) )   ! before heat content of runoff
162            CALL iom_get( numror, jpdom_autoglo, 'rnf_sc_b', rnf_tsc_b(:,:,jp_sal) )   ! before salinity content of runoff
163         ELSE                                                   !* no restart: set from nit000 values
164            IF(lwp) WRITE(numout,*) '          nit000-1 runoff forcing fields set to nit000'
165            rnf_b    (:,:  ) = rnf    (:,:  )
166            rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)
167         ENDIF
168      ENDIF
169      !                                                ! ---------------------------------------- !
170      IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
171         !                                             ! ---------------------------------------- !
172         IF(lwp) WRITE(numout,*)
173         IF(lwp) WRITE(numout,*) 'sbcrnf : runoff forcing fields written in ocean restart file ',   &
174            &                    'at it= ', kt,' date= ', ndastp
175         IF(lwp) WRITE(numout,*) '~~~~'
176         CALL iom_rstput( kt, nitrst, numrow, 'rnf_b' , rnf )
177         CALL iom_rstput( kt, nitrst, numrow, 'rnf_hc_b', rnf_tsc(:,:,jp_tem) )
178         CALL iom_rstput( kt, nitrst, numrow, 'rnf_sc_b', rnf_tsc(:,:,jp_sal) )
179      ENDIF
180      !
181      CALL wrk_dealloc( jpi,jpj, ztfrz)
182      !
183   END SUBROUTINE sbc_rnf
184
185
186   SUBROUTINE sbc_rnf_div( phdivn )
187      !!----------------------------------------------------------------------
188      !!                  ***  ROUTINE sbc_rnf  ***
189      !!
190      !! ** Purpose :   update the horizontal divergence with the runoff inflow
191      !!
192      !! ** Method  :
193      !!                CAUTION : rnf is positive (inflow) decreasing the
194      !!                          divergence and expressed in m/s
195      !!
196      !! ** Action  :   phdivn   decreased by the runoff inflow
197      !!----------------------------------------------------------------------
198      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   phdivn   ! horizontal divergence
199      !!
200      INTEGER  ::   ji, jj, jk   ! dummy loop indices
201      REAL(wp) ::   zfact     ! local scalar
202      !!----------------------------------------------------------------------
203      !
204      zfact = 0.5_wp
205      !
206      IF( ln_rnf_depth .OR. ln_rnf_depth_ini ) THEN      !==   runoff distributed over several levels   ==!
207         IF( lk_vvl ) THEN             ! variable volume case
208            DO jj = 1, jpj                   ! update the depth over which runoffs are distributed
209               DO ji = 1, jpi
210                  h_rnf(ji,jj) = 0._wp
211                  DO jk = 1, nk_rnf(ji,jj)                           ! recalculates h_rnf to be the depth in metres
212                     h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk)   ! to the bottom of the relevant grid box
213                  END DO
214                  !                          ! apply the runoff input flow
215                  DO jk = 1, nk_rnf(ji,jj)
216                     phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rau0 / h_rnf(ji,jj)
217                  END DO
218               END DO
219            END DO
220         ELSE                          ! constant volume case : just apply the runoff input flow
221            DO jj = 1, jpj
222               DO ji = 1, jpi
223                  DO jk = 1, nk_rnf(ji,jj)
224                     phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rau0 / h_rnf(ji,jj)
225                  END DO
226               END DO
227            END DO
228         ENDIF
229      ELSE                       !==   runoff put only at the surface   ==!
230         IF( lk_vvl ) THEN              ! variable volume case
231            h_rnf(:,:) = fse3t(:,:,1)   ! recalculate h_rnf to be depth of top box
232         ENDIF
233         phdivn(:,:,1) = phdivn(:,:,1) - ( rnf(:,:) + rnf_b(:,:) ) * zfact * r1_rau0 / fse3t(:,:,1)
234      ENDIF
235      !
236   END SUBROUTINE sbc_rnf_div
237
238
239   SUBROUTINE sbc_rnf_init
240      !!----------------------------------------------------------------------
241      !!                  ***  ROUTINE sbc_rnf_init  ***
242      !!
243      !! ** Purpose :   Initialisation of the runoffs if (ln_rnf=T)
244      !!
245      !! ** Method  : - read the runoff namsbc_rnf namelist
246      !!
247      !! ** Action  : - read parameters
248      !!----------------------------------------------------------------------
249      CHARACTER(len=32) ::   rn_dep_file   ! runoff file name
250      INTEGER           ::   ji, jj, jk, jm    ! dummy loop indices
251      INTEGER           ::   ierror, inum  ! temporary integer
252      INTEGER           ::   ios           ! Local integer output status for namelist read
253      INTEGER           ::   nbrec         ! temporary integer
254      REAL(wp)          ::   zacoef 
255      REAL(wp), DIMENSION(12)                 :: zrec             ! times records
256      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: zrnfcl   
257      REAL(wp), DIMENSION(:,:  ), ALLOCATABLE :: zrnf
258      !
259      NAMELIST/namsbc_rnf/ cn_dir            , ln_rnf_depth, ln_rnf_tem, ln_rnf_sal,   &
260         &                 sn_rnf, sn_cnf    , sn_s_rnf    , sn_t_rnf  , sn_dep_rnf,   &
261         &                 ln_rnf_mouth      , rn_hrnf     , rn_avt_rnf, rn_rfact,     &
262         &                 ln_rnf_depth_ini  , rn_dep_max  , rn_rnf_max, nn_rnf_depth_file
263      !!----------------------------------------------------------------------
264      !
265      !                                         !==  allocate runoff arrays
266      IF( sbc_rnf_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_rnf_alloc : unable to allocate arrays' )
267      !
268      IF( .NOT. ln_rnf ) THEN                      ! no specific treatment in vicinity of river mouths
269         ln_rnf_mouth  = .FALSE.                   ! default definition needed for example by sbc_ssr or by tra_adv_muscl
270         nkrnf         = 0
271         rnf     (:,:) = 0.0_wp
272         rnf_b   (:,:) = 0.0_wp
273         rnfmsk  (:,:) = 0.0_wp
274         rnfmsk_z(:)   = 0.0_wp
275         RETURN
276      ENDIF
277      !
278      !                                   ! ============
279      !                                   !   Namelist
280      !                                   ! ============
281      !
282      REWIND( numnam_ref )              ! Namelist namsbc_rnf in reference namelist : Runoffs
283      READ  ( numnam_ref, namsbc_rnf, IOSTAT = ios, ERR = 901)
284901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_rnf in reference namelist', lwp )
285
286      REWIND( numnam_cfg )              ! Namelist namsbc_rnf in configuration namelist : Runoffs
287      READ  ( numnam_cfg, namsbc_rnf, IOSTAT = ios, ERR = 902 )
288902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_rnf in configuration namelist', lwp )
289      IF(lwm) WRITE ( numond, namsbc_rnf )
290      !
291      !                                         ! Control print
292      IF(lwp) THEN
293         WRITE(numout,*)
294         WRITE(numout,*) 'sbc_rnf : runoff '
295         WRITE(numout,*) '~~~~~~~ '
296         WRITE(numout,*) '   Namelist namsbc_rnf'
297         WRITE(numout,*) '      specific river mouths treatment            ln_rnf_mouth = ', ln_rnf_mouth
298         WRITE(numout,*) '      river mouth additional Kz                  rn_avt_rnf   = ', rn_avt_rnf
299         WRITE(numout,*) '      depth of river mouth additional mixing     rn_hrnf      = ', rn_hrnf
300         WRITE(numout,*) '      multiplicative factor for runoff           rn_rfact     = ', rn_rfact
301      ENDIF
302      !                                   ! ==================
303      !                                   !   Type of runoff
304      !                                   ! ==================
305      !
306      IF( .NOT. l_rnfcpl ) THEN                   
307         ALLOCATE( sf_rnf(1), STAT=ierror )         ! Create sf_rnf structure (runoff inflow)
308         IF(lwp) WRITE(numout,*)
309         IF(lwp) WRITE(numout,*) '          runoffs inflow read in a file'
310         IF( ierror > 0 ) THEN
311            CALL ctl_stop( 'sbc_rnf: unable to allocate sf_rnf structure' )   ;   RETURN
312         ENDIF
313         ALLOCATE( sf_rnf(1)%fnow(jpi,jpj,1)   )
314         IF( sn_rnf%ln_tint ) ALLOCATE( sf_rnf(1)%fdta(jpi,jpj,1,2) )
315         CALL fld_fill( sf_rnf, (/ sn_rnf /), cn_dir, 'sbc_rnf_init', 'read runoffs data', 'namsbc_rnf' )
316      ENDIF
317      !
318      IF( ln_rnf_tem ) THEN                      ! Create (if required) sf_t_rnf structure
319         IF(lwp) WRITE(numout,*)
320         IF(lwp) WRITE(numout,*) '          runoffs temperatures read in a file'
321         ALLOCATE( sf_t_rnf(1), STAT=ierror  )
322         IF( ierror > 0 ) THEN
323            CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_t_rnf structure' )   ;   RETURN
324         ENDIF
325         ALLOCATE( sf_t_rnf(1)%fnow(jpi,jpj,1)   )
326         IF( sn_t_rnf%ln_tint ) ALLOCATE( sf_t_rnf(1)%fdta(jpi,jpj,1,2) )
327         CALL fld_fill (sf_t_rnf, (/ sn_t_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff temperature data', 'namsbc_rnf' )
328      ENDIF
329      !
330      IF( ln_rnf_sal  ) THEN                     ! Create (if required) sf_s_rnf and sf_t_rnf structures
331         IF(lwp) WRITE(numout,*)
332         IF(lwp) WRITE(numout,*) '          runoffs salinities read in a file'
333         ALLOCATE( sf_s_rnf(1), STAT=ierror  )
334         IF( ierror > 0 ) THEN
335            CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_s_rnf structure' )   ;   RETURN
336         ENDIF
337         ALLOCATE( sf_s_rnf(1)%fnow(jpi,jpj,1)   )
338         IF( sn_s_rnf%ln_tint ) ALLOCATE( sf_s_rnf(1)%fdta(jpi,jpj,1,2) )
339         CALL fld_fill (sf_s_rnf, (/ sn_s_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff salinity data', 'namsbc_rnf' )
340      ENDIF
341      !
342      IF( ln_rnf_depth ) THEN                    ! depth of runoffs set from a file
343         IF(lwp) WRITE(numout,*)
344         IF(lwp) WRITE(numout,*) '          runoffs depth read in a file'
345         rn_dep_file = TRIM( cn_dir )//TRIM( sn_dep_rnf%clname )
346         IF( .NOT. sn_dep_rnf%ln_clim ) THEN   ;   WRITE(rn_dep_file, '(a,"_y",i4)' ) TRIM( rn_dep_file ), nyear    ! add year
347            IF( sn_dep_rnf%cltype == 'monthly' )   WRITE(rn_dep_file, '(a,"m",i2)'  ) TRIM( rn_dep_file ), nmonth   ! add month
348         ENDIF
349         CALL iom_open ( rn_dep_file, inum )                           ! open file
350         CALL iom_get  ( inum, jpdom_data, sn_dep_rnf%clvar, h_rnf )   ! read the river mouth array
351         CALL iom_close( inum )                                        ! close file
352         !
353         nk_rnf(:,:) = 0                               ! set the number of level over which river runoffs are applied
354         DO jj = 1, jpj
355            DO ji = 1, jpi
356               IF( h_rnf(ji,jj) > 0._wp ) THEN
357                  jk = 2
358                  DO WHILE ( jk /= mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ;  jk = jk + 1
359                  END DO
360                  nk_rnf(ji,jj) = jk
361               ELSEIF( h_rnf(ji,jj) == -1._wp   ) THEN   ;  nk_rnf(ji,jj) = 1
362               ELSEIF( h_rnf(ji,jj) == -999._wp ) THEN   ;  nk_rnf(ji,jj) = mbkt(ji,jj)
363               ELSE
364                  CALL ctl_stop( 'sbc_rnf_init: runoff depth not positive, and not -999 or -1, rnf value in file fort.999'  )
365                  WRITE(999,*) 'ji, jj, h_rnf(ji,jj) :', ji, jj, h_rnf(ji,jj)
366               ENDIF
367            END DO
368         END DO
369         DO jj = 1, jpj                                ! set the associated depth
370            DO ji = 1, jpi
371               h_rnf(ji,jj) = 0._wp
372               DO jk = 1, nk_rnf(ji,jj)
373                  h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk)
374               END DO
375            END DO
376         END DO
377         !
378      ELSE IF( ln_rnf_depth_ini ) THEN           ! runoffs applied at the surface
379         !
380         IF(lwp) WRITE(numout,*)
381         IF(lwp) WRITE(numout,*) '    depth of runoff computed once from max value of runoff'
382         IF(lwp) WRITE(numout,*) '    max value of the runoff climatologie (over global domain) rn_rnf_max = ', rn_rnf_max
383         IF(lwp) WRITE(numout,*) '    depth over which runoffs is spread                        rn_dep_max = ', rn_dep_max
384         IF(lwp) WRITE(numout,*) '     create (=1) a runoff depth file or not (=0)      nn_rnf_depth_file  = ', nn_rnf_depth_file
385
386         CALL iom_open( TRIM( sn_rnf%clname ), inum )    !  open runoff file
387         CALL iom_gettime( inum, zrec, kntime=nbrec)
388         ALLOCATE( zrnfcl(jpi,jpj,nbrec) )     ;      ALLOCATE( zrnf(jpi,jpj) )
389         DO jm = 1, nbrec
390            CALL iom_get( inum, jpdom_data, TRIM( sn_rnf%clvar ), zrnfcl(:,:,jm), jm )
391         END DO
392         CALL iom_close( inum )
393         zrnf(:,:) = MAXVAL( zrnfcl(:,:,:), DIM=3 )   !  maximum value in time
394         DEALLOCATE( zrnfcl )
395         !
396         h_rnf(:,:) = 1.
397         !
398         zacoef = rn_dep_max / rn_rnf_max            ! coef of linear relation between runoff and its depth (150m for max of runoff)
399         !
400         WHERE( zrnf(:,:) > 0._wp )  h_rnf(:,:) = zacoef * zrnf(:,:)   ! compute depth for all runoffs
401         !
402         DO jj = 1, jpj                     ! take in account min depth of ocean rn_hmin
403            DO ji = 1, jpi
404               IF( zrnf(ji,jj) > 0._wp ) THEN
405                  jk = mbkt(ji,jj)
406                  h_rnf(ji,jj) = MIN( h_rnf(ji,jj), gdept_0(ji,jj,jk ) )
407               ENDIF
408            END DO
409         END DO
410         !
411         nk_rnf(:,:) = 0                       ! number of levels on which runoffs are distributed
412         DO jj = 1, jpj
413            DO ji = 1, jpi
414               IF( zrnf(ji,jj) > 0._wp ) THEN
415                  jk = 2
416                  DO WHILE ( jk /= mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ;  jk = jk + 1
417                  END DO
418                  nk_rnf(ji,jj) = jk
419               ELSE
420                  nk_rnf(ji,jj) = 1
421               ENDIF
422            END DO
423         END DO
424         !
425         DEALLOCATE( zrnf )
426         !
427         DO jj = 1, jpj                                ! set the associated depth
428            DO ji = 1, jpi
429               h_rnf(ji,jj) = 0._wp
430               DO jk = 1, nk_rnf(ji,jj)
431                  h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk)
432               END DO
433            END DO
434         END DO
435         !
436         IF( nn_rnf_depth_file == 1 ) THEN      !  save  output nb levels for runoff
437            IF(lwp) WRITE(numout,*) '              create runoff depht file'
438            CALL iom_open  ( TRIM( sn_dep_rnf%clname ), inum, ldwrt = .TRUE., kiolib = jprstlib )
439            CALL iom_rstput( 0, 0, inum, 'rodepth', h_rnf )
440            CALL iom_close ( inum )
441         ENDIF
442      ELSE                                       ! runoffs applied at the surface
443         nk_rnf(:,:) = 1
444         h_rnf (:,:) = fse3t(:,:,1)
445      ENDIF
446      !
447      xrnfmask(:,:,:) = 1.    ! default value for points using river forcing
448      IF (ln_usernfmask) THEN
449         IF(lwp) WRITE(numout,*)
450         IF(lwp) WRITE(numout,*) '          runoff mask read in a file'
451         CALL iom_open( 'rnfmask', inum )
452         CALL iom_get( inum, jpdom_data, 'rnfmask', xrnfmask(:,:,1), 1)
453         CALL iom_close( inum )
454      ENDIF
455      !
456      rnf(:,:) =  0._wp                         ! runoff initialisation
457      rnf_tsc(:,:,:) = 0._wp                    ! runoffs temperature & salinty contents initilisation
458      !
459      !                                   ! ========================
460      !                                   !   River mouth vicinity
461      !                                   ! ========================
462      !
463      IF( ln_rnf_mouth ) THEN                   ! Specific treatment in vicinity of river mouths :
464         !                                      !    - Increase Kz in surface layers ( rn_hrnf > 0 )
465         !                                      !    - set to zero SSS damping (ln_ssr=T)
466         !                                      !    - mixed upstream-centered (ln_traadv_cen2=T)
467         !
468         IF ( ln_rnf_depth )   CALL ctl_warn( 'sbc_rnf_init: increased mixing turned on but effects may already',   &
469            &                                              'be spread through depth by ln_rnf_depth'               )
470         !
471         nkrnf = 0                                  ! Number of level over which Kz increase
472         IF( rn_hrnf > 0._wp ) THEN
473            nkrnf = 2
474            DO WHILE( nkrnf /= jpkm1 .AND. gdepw_1d(nkrnf+1) < rn_hrnf )   ;   nkrnf = nkrnf + 1
475            END DO
476            IF( ln_sco )   CALL ctl_warn( 'sbc_rnf: number of levels over which Kz is increased is computed for zco...' )
477         ENDIF
478         IF(lwp) WRITE(numout,*)
479         IF(lwp) WRITE(numout,*) '          Specific treatment used in vicinity of river mouths :'
480         IF(lwp) WRITE(numout,*) '             - Increase Kz in surface layers (if rn_hrnf > 0 )'
481         IF(lwp) WRITE(numout,*) '               by ', rn_avt_rnf,' m2/s  over ', nkrnf, ' w-levels'
482         IF(lwp) WRITE(numout,*) '             - set to zero SSS damping       (if ln_ssr=T)'
483         IF(lwp) WRITE(numout,*) '             - mixed upstream-centered       (if ln_traadv_cen2=T)'
484         !
485         CALL rnf_mouth                             ! set river mouth mask
486         !
487      ELSE                                      ! No treatment at river mouths
488         IF(lwp) WRITE(numout,*)
489         IF(lwp) WRITE(numout,*) '          No specific treatment at river mouths'
490         rnfmsk  (:,:) = 0._wp
491         rnfmsk_z(:)   = 0._wp
492         nkrnf = 0
493      ENDIF
494      !
495   END SUBROUTINE sbc_rnf_init
496
497
498   SUBROUTINE rnf_mouth
499      !!----------------------------------------------------------------------
500      !!                  ***  ROUTINE rnf_mouth  ***
501      !!
502      !! ** Purpose :   define the river mouths mask
503      !!
504      !! ** Method  :   read the river mouth mask (=0/1) in the river runoff
505      !!                climatological file. Defined a given vertical structure.
506      !!                CAUTION, the vertical structure is hard coded on the
507      !!                first 5 levels.
508      !!                This fields can be used to:
509      !!                 - set an upstream advection scheme
510      !!                   (ln_rnf_mouth=T and ln_traadv_cen2=T)
511      !!                 - increase vertical on the top nn_krnf vertical levels
512      !!                   at river runoff input grid point (nn_krnf>=2, see step.F90)
513      !!                 - set to zero SSS restoring flux at river mouth grid points
514      !!
515      !! ** Action  :   rnfmsk   set to 1 at river runoff input, 0 elsewhere
516      !!                rnfmsk_z vertical structure
517      !!----------------------------------------------------------------------
518      INTEGER            ::   inum        ! temporary integers
519      CHARACTER(len=140) ::   cl_rnfile   ! runoff file name
520      !!----------------------------------------------------------------------
521      !
522      IF(lwp) WRITE(numout,*)
523      IF(lwp) WRITE(numout,*) 'rnf_mouth : river mouth mask'
524      IF(lwp) WRITE(numout,*) '~~~~~~~~~ '
525      !
526      cl_rnfile = TRIM( cn_dir )//TRIM( sn_cnf%clname )
527      IF( .NOT. sn_cnf%ln_clim ) THEN   ;   WRITE(cl_rnfile, '(a,"_y",i4)' ) TRIM( cl_rnfile ), nyear    ! add year
528         IF( sn_cnf%cltype == 'monthly' )   WRITE(cl_rnfile, '(a,"m",i2)'  ) TRIM( cl_rnfile ), nmonth   ! add month
529      ENDIF
530      !
531      ! horizontal mask (read in NetCDF file)
532      CALL iom_open ( cl_rnfile, inum )                           ! open file
533      CALL iom_get  ( inum, jpdom_data, sn_cnf%clvar, rnfmsk )    ! read the river mouth array
534      CALL iom_close( inum )                                      ! close file
535      !
536      IF( nn_closea == 1 )   CALL clo_rnf( rnfmsk )               ! closed sea inflow set as ruver mouth
537      !
538      rnfmsk_z(:)   = 0._wp                                       ! vertical structure
539      rnfmsk_z(1)   = 1.0
540      rnfmsk_z(2)   = 1.0                                         ! **********
541      rnfmsk_z(3)   = 0.5                                         ! HARD CODED on the 5 first levels
542      rnfmsk_z(4)   = 0.25                                        ! **********
543      rnfmsk_z(5)   = 0.125
544      !
545   END SUBROUTINE rnf_mouth
546
547   !!======================================================================
548END MODULE sbcrnf
Note: See TracBrowser for help on using the repository browser.