source: branches/UKMO/r6232_tracer_advection/NEMOGCM/NEMO/OPA_SRC/C1D/domc1d.F90 @ 9295

Last change on this file since 9295 was 9295, checked in by jcastill, 3 years ago

Remove svn keywords

File size: 9.7 KB
Line 
1MODULE domc1d
2   !!======================================================================
3   !!                     ***  MODULE  domc1d  ***
4   !! Ocean Domain : 1D column position from lat/lon namelist specification
5   !!======================================================================
6   !! History :  3.5  !  2013-04  (D. Calvert)  Original code
7   !!----------------------------------------------------------------------
8#if defined key_c1d
9   !!----------------------------------------------------------------------
10   !!   'key_c1d'   :                                      1D Configuration
11   !!----------------------------------------------------------------------
12   !!   dom_c1d     : Determine jpizoom/jpjzoom from a given lat/lon
13   !!----------------------------------------------------------------------
14   USE phycst                        ! Physical constants (and par_oce)
15   USE iom                           ! I/O library (iom_get)
16   USE in_out_manager                ! I/O manager (ctmp1)
17   USE dom_oce , ONLY : nimpp, njmpp ! Shared/distributed memory setting (mpp_init routine)
18   USE wrk_nemo                      ! Memory allocation
19   USE timing                        ! Timing
20
21   IMPLICIT NONE
22   PRIVATE
23
24   PUBLIC   dom_c1d                  ! Routine called in domcfg.F90
25
26   !!----------------------------------------------------------------------
27   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
28   !! $Id$
29   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
30   !!----------------------------------------------------------------------
31CONTAINS
32   
33   SUBROUTINE dom_c1d( plat, plon )
34      !!----------------------------------------------------------------------
35      !!                   ***  ROUTINE dom_c1d  ***
36      !!
37      !! ** Purpose : Recalculate jpizoom/jpjzoom indices from lat/lon point
38      !!
39      !! ** Method  : Calculate global gphit and glamt as for dom_hgr.
40      !!              After, find closest grid point to lat/lon point as for
41      !!              dom_ngb on T grid. From this infer jpizoom and jpjzoom.
42      !!
43      !! ** Action  : Recalculate jpizoom, jpjzoom (indices of C1D zoom)
44      !!----------------------------------------------------------------------
45      NAMELIST/namdom/ nn_bathy, rn_bathy , rn_e3zps_min, rn_e3zps_rat, nn_msh, rn_hmin,   &
46         &             nn_acc   , rn_atfp     , rn_rdt      , rn_rdtmin ,                  &
47         &             rn_rdtmax, rn_rdth     , nn_closea , ln_crs,    &
48         &             jphgr_msh, &
49         &             ppglam0, ppgphi0, ppe1_deg, ppe2_deg, ppe1_m, ppe2_m, &
50         &             ppsur, ppa0, ppa1, ppkth, ppacr, ppdzmin, pphmax, ldbletanh, &
51         &             ppa2, ppkth2, ppacr2
52
53      INTEGER  ::  ji, jj                          ! Dummy loop indices
54      INTEGER  ::  inum                            ! Coordinate file handle (case 0)
55      INTEGER  ::  ijeq                            ! Index of equator T point (case 4)
56      INTEGER  ::  ios                             ! Local integer output status for namelist read
57
58      INTEGER , DIMENSION(2) ::   iloc             ! Minloc returned indices
59
60      REAL(wp), INTENT(in) ::  plat                ! Column latitude
61      REAL(wp), INTENT(in) ::  plon                ! Column longitude
62
63      REAL(wp) ::  zlon                            ! Wraparound longitude
64      REAL(wp) ::  zti, ztj, zarg                  ! Local scalars
65      REAL(wp) ::  glam0, gphi0                    ! Variables corresponding to parameters ppglam0 ppgphi0 set in par_oce
66      REAL(wp) ::  zlam1, zcos_alpha, ze1, ze1deg  ! Case 5 local scalars
67      REAL(wp) ::  zphi1, zsin_alpha, zim05, zjm05 !          "
68
69      REAL(wp) , POINTER, DIMENSION(:,:) ::  gphidta, glamdta, zdist ! Global lat/lon
70      !!----------------------------------------------------------------------
71
72      IF( nn_timing == 1 )   CALL timing_start('dom_c1d')
73
74      REWIND( numnam_ref )              ! Namelist namdom in reference namelist : space & time domain (bathymetry, mesh, timestep)
75      READ  ( numnam_ref, namdom, IOSTAT = ios, ERR = 901 )
76901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdom in reference namelist', lwp )
77 
78      !
79      REWIND( numnam_cfg )              ! Namelist namdom in configuration namelist : space & time domain (bathymetry, mesh, timestep)
80      READ  ( numnam_cfg, namdom, IOSTAT = ios, ERR = 902 )
81902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdom in configuration namelist', lwp )
82
83      CALL wrk_alloc( jpidta, jpjdta, gphidta, glamdta, zdist )
84
85
86      ! ============================= !
87      !  Code from dom_hgr:           !
88      !  Calculate global horizontal  !
89      !  mesh, only glamt and gphit   !
90      ! ============================= !
91
92      SELECT CASE( jphgr_msh )   ! type of horizontal mesh
93
94      CASE ( 0 )                 !  curvilinear coordinate on the sphere read in coordinate.nc file
95
96         CALL iom_open( 'coordinates', inum )
97         CALL iom_get( inum, jpdom_unknown, 'glamt', glamdta ) ! mig, mjg undefined at this point
98         CALL iom_get( inum, jpdom_unknown, 'gphit', gphidta ) ! so use jpdom_unknown not jpdom_data
99         CALL iom_close ( inum )
100
101      CASE ( 1 )                 ! geographical mesh on the sphere with regular grid-spacing
102
103         DO jj = 1, jpjdta
104            DO ji = 1, jpidta
105               zti = FLOAT( ji - 1 + nimpp - 1 )
106               ztj = FLOAT( jj - 1 + njmpp - 1 )
107
108               glamdta(ji,jj) = ppglam0 + ppe1_deg * zti
109               gphidta(ji,jj) = ppgphi0 + ppe2_deg * ztj
110            END DO
111         END DO
112
113      CASE ( 2:3 )               ! f- or beta-plane with regular grid-spacing
114         
115         glam0 = 0.e0
116         gphi0 = - ppe2_m * 1.e-3
117
118         DO jj = 1, jpjdta
119            DO ji = 1, jpidta
120               glamdta(ji,jj) = glam0 + ppe1_m * 1.e-3 * FLOAT( ji - 1 + nimpp - 1 )
121               gphidta(ji,jj) = gphi0 + ppe2_m * 1.e-3 * FLOAT( jj - 1 + njmpp - 1 )
122            END DO
123         END DO
124
125      CASE ( 4 )                 ! geographical mesh on the sphere, isotropic MERCATOR type
126
127         IF( ppgphi0 == -90 )   CALL ctl_stop( ' Mercator grid cannot start at south pole !!!! ' )
128
129         zarg = rpi / 4. - rpi / 180. * ppgphi0 / 2.
130         ijeq = ABS( 180. / rpi * LOG( COS( zarg ) / SIN( zarg ) ) / ppe1_deg )
131         IF( ppgphi0 > 0 )   ijeq = -ijeq
132
133         DO jj = 1, jpjdta
134            DO ji = 1, jpidta
135               zti = FLOAT( ji - 1    + nimpp - 1 )
136               ztj = FLOAT( jj - ijeq + njmpp - 1 )
137
138               glamdta(ji,jj) = ppglam0 + ppe1_deg * zti
139               gphidta(ji,jj) = 1. / rad * ASIN ( TANH( ppe1_deg * rad * ztj ) )
140            END DO
141         END DO
142
143      CASE ( 5 )                 ! beta-plane with regular grid-spacing and rotated domain (GYRE configuration)
144   
145         zlam1 = -85
146         zphi1 = 29
147         ze1 = 106000. / FLOAT(jp_cfg)
148 
149         zsin_alpha = - SQRT( 2. ) / 2.
150         zcos_alpha =   SQRT( 2. ) / 2.
151         ze1deg = ze1 / (ra * rad)
152
153         glam0 = zlam1 + zcos_alpha * ze1deg * FLOAT( jpjdta-2 ) ! Force global
154         gphi0 = zphi1 + zsin_alpha * ze1deg * FLOAT( jpjdta-2 )
155
156         DO jj = 1, jpjdta
157            DO ji = 1, jpidta
158               zim05 = FLOAT( ji + nimpp - 1 ) - 1.5
159               zjm05 = FLOAT( jj + njmpp - 1 ) - 1.5
160
161               glamdta(ji,jj) = glam0 + zim05 * ze1deg * zcos_alpha + zjm05 * ze1deg * zsin_alpha
162               gphidta(ji,jj) = gphi0 - zim05 * ze1deg * zsin_alpha + zjm05 * ze1deg * zcos_alpha
163            END DO
164         END DO
165
166      CASE DEFAULT
167
168         WRITE(ctmp1,*) '          bad flag value for jphgr_msh = ', jphgr_msh
169         CALL ctl_stop( ctmp1 )
170
171      END SELECT
172
173
174      ! ============================== !
175      !  Code from dom_ngb:            !
176      !  Calculate the nearest grid    !
177      !  point to the given lat/lon &  !
178      !  update jpizoom and jpjzoom    !
179      ! ============================== !
180
181      zlon         = MOD( plon         + 720., 360. )                                      ! plon    between    0 and 360
182      glamdta(:,:) = MOD( glamdta(:,:) + 720., 360. )                                      ! glamdta between    0 and 360
183      IF( zlon > 270. )   zlon = zlon - 360.                                               ! zlon    between  -90 and 270
184      IF( zlon <  90. )   WHERE( glamdta(:,:) > 180. ) glamdta(:,:) = glamdta(:,:) - 360.  ! glamdta between -180 and 180
185
186      glamdta(:,:) = glamdta(:,:) - zlon
187      gphidta(:,:) = gphidta(:,:) - plat
188      zdist(:,:)   = glamdta(:,:) * glamdta(:,:) + gphidta(:,:) * gphidta(:,:)
189     
190      iloc(:) = MINLOC( zdist(:,:) ) ! No mask; zoom indices freely defined
191      jpizoom = iloc(1) + nimpp - 2  ! Minloc index - 1; want the bottom-left
192      jpjzoom = iloc(2) + njmpp - 2  ! corner index of the zoom domain.
193
194      CALL wrk_dealloc( jpidta, jpjdta, gphidta, glamdta, zdist )
195
196      IF (lwp) THEN
197         WRITE(numout,*)
198         WRITE(numout,*) 'dom_c1d : compute jpizoom & jpjzoom from global mesh and given coordinates'
199         WRITE(numout,*) '~~~~~~~'
200         WRITE(numout,*) '      column i zoom index             jpizoom = ', jpizoom
201         WRITE(numout,*) '      column j zoom index             jpjzoom = ', jpjzoom
202         WRITE(numout,*)
203      ENDIF
204
205      IF( nn_timing == 1 )   CALL timing_stop('dom_c1d')
206
207   END SUBROUTINE dom_c1d
208
209#else
210   !!----------------------------------------------------------------------
211   !!   Default option                                  NO 1D Configuration
212   !!----------------------------------------------------------------------
213CONTAINS 
214   SUBROUTINE dom_c1d( plat, plon )     ! Empty routine
215      REAL :: plat, plon
216      WRITE(*,*) 'dom_c1d: You should not have seen this print! error?',plat,plon
217   END SUBROUTINE dom_c1d
218#endif
219
220   !!======================================================================
221END MODULE domc1d
Note: See TracBrowser for help on using the repository browser.