New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
diaharm.F90 in branches/UKMO/r6232_tracer_advection/NEMOGCM/NEMO/OPA_SRC/DIA – NEMO

source: branches/UKMO/r6232_tracer_advection/NEMOGCM/NEMO/OPA_SRC/DIA/diaharm.F90 @ 9295

Last change on this file since 9295 was 9295, checked in by jcastill, 6 years ago

Remove svn keywords

File size: 20.0 KB
Line 
1MODULE diaharm 
2   !!======================================================================
3   !!                       ***  MODULE  diaharm  ***
4   !! Harmonic analysis of tidal constituents
5   !!======================================================================
6   !! History :  3.1  !  2007  (O. Le Galloudec, J. Chanut)  Original code
7   !!----------------------------------------------------------------------
8#if defined key_diaharm && defined key_tide
9   !!----------------------------------------------------------------------
10   !!   'key_diaharm'
11   !!   'key_tide'
12   !!----------------------------------------------------------------------
13   USE oce             ! ocean dynamics and tracers variables
14   USE dom_oce         ! ocean space and time domain
15   USE phycst
16   USE dynspg_oce
17   USE dynspg_ts
18   USE daymod
19   USE tide_mod
20   !
21   USE in_out_manager  ! I/O units
22   USE iom             ! I/0 library
23   USE ioipsl          ! NetCDF IPSL library
24   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
25   USE diadimg         ! To write dimg
26   USE timing          ! preformance summary
27   USE wrk_nemo        ! working arrays
28
29   IMPLICIT NONE
30   PRIVATE
31
32   LOGICAL, PUBLIC, PARAMETER :: lk_diaharm  = .TRUE.
33   
34   INTEGER, PARAMETER :: jpincomax    = 2.*jpmax_harmo
35   INTEGER, PARAMETER :: jpdimsparse  = jpincomax*300*24
36
37   !                         !!** namelist variables **
38   INTEGER ::   nit000_han    ! First time step used for harmonic analysis
39   INTEGER ::   nitend_han    ! Last time step used for harmonic analysis
40   INTEGER ::   nstep_han     ! Time step frequency for harmonic analysis
41   INTEGER ::   nb_ana        ! Number of harmonics to analyse
42
43   INTEGER , ALLOCATABLE, DIMENSION(:)       ::   name
44   REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:) ::   ana_temp
45   REAL(wp), ALLOCATABLE, DIMENSION(:)       ::   ana_freq, ut   , vt   , ft
46   REAL(wp), ALLOCATABLE, DIMENSION(:,:,:)   ::   out_eta , out_u, out_v
47
48   INTEGER ::   ninco, nsparse
49   INTEGER ,       DIMENSION(jpdimsparse)         ::   njsparse, nisparse
50   INTEGER , SAVE, DIMENSION(jpincomax)           ::   ipos1
51   REAL(wp),       DIMENSION(jpdimsparse)         ::   valuesparse
52   REAL(wp),       DIMENSION(jpincomax)           ::   ztmp4 , ztmp7
53   REAL(wp), SAVE, DIMENSION(jpincomax,jpincomax) ::   ztmp3 , zpilier
54   REAL(wp), SAVE, DIMENSION(jpincomax)           ::   zpivot
55
56   CHARACTER (LEN=4), DIMENSION(jpmax_harmo) ::   tname   ! Names of tidal constituents ('M2', 'K1',...)
57
58   PUBLIC   dia_harm   ! routine called by step.F90
59
60   !!----------------------------------------------------------------------
61   !! NEMO/OPA 3.5 , NEMO Consortium (2013)
62   !! $Id$
63   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
64   !!----------------------------------------------------------------------
65CONTAINS
66
67   SUBROUTINE dia_harm_init 
68      !!----------------------------------------------------------------------
69      !!                 ***  ROUTINE dia_harm_init  ***
70      !!         
71      !! ** Purpose :   Initialization of tidal harmonic analysis
72      !!
73      !! ** Method  :   Initialize frequency array and  nodal factor for nit000_han
74      !!
75      !!--------------------------------------------------------------------
76      INTEGER :: jh, nhan, jk, ji
77      INTEGER ::   ios                 ! Local integer output status for namelist read
78
79      NAMELIST/nam_diaharm/ nit000_han, nitend_han, nstep_han, tname
80      !!----------------------------------------------------------------------
81
82      IF(lwp) THEN
83         WRITE(numout,*)
84         WRITE(numout,*) 'dia_harm_init: Tidal harmonic analysis initialization'
85         WRITE(numout,*) '~~~~~~~ '
86      ENDIF
87      !
88      CALL tide_init_Wave
89      !
90      REWIND( numnam_ref )              ! Namelist nam_diaharm in reference namelist : Tidal harmonic analysis
91      READ  ( numnam_ref, nam_diaharm, IOSTAT = ios, ERR = 901)
92901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nam_diaharm in reference namelist', lwp )
93
94      REWIND( numnam_cfg )              ! Namelist nam_diaharm in configuration namelist : Tidal harmonic analysis
95      READ  ( numnam_cfg, nam_diaharm, IOSTAT = ios, ERR = 902 )
96902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nam_diaharm in configuration namelist', lwp )
97      IF(lwm) WRITE ( numond, nam_diaharm )
98      !
99      IF(lwp) THEN
100         WRITE(numout,*) 'First time step used for analysis:  nit000_han= ', nit000_han
101         WRITE(numout,*) 'Last  time step used for analysis:  nitend_han= ', nitend_han
102         WRITE(numout,*) 'Time step frequency for harmonic analysis:  nstep_han= ', nstep_han
103      ENDIF
104
105      ! Basic checks on harmonic analysis time window:
106      ! ----------------------------------------------
107      IF( nit000 > nit000_han )   CALL ctl_stop( 'dia_harm_init : nit000_han must be greater than nit000',   &
108         &                                       ' restart capability not implemented' )
109      IF( nitend < nitend_han )   CALL ctl_stop( 'dia_harm_init : nitend_han must be lower than nitend',   &
110         &                                       'restart capability not implemented' )
111
112      IF( MOD( nitend_han-nit000_han+1 , nstep_han ) /= 0 )   &
113         &                        CALL ctl_stop( 'dia_harm_init : analysis time span must be a multiple of nstep_han' )
114
115      nb_ana = 0
116      DO jk=1,jpmax_harmo
117         DO ji=1,jpmax_harmo
118            IF(TRIM(tname(jk)) == Wave(ji)%cname_tide) THEN
119               nb_ana=nb_ana+1
120            ENDIF
121         END DO
122      END DO
123      !
124      IF(lwp) THEN
125         WRITE(numout,*) '        Namelist nam_diaharm'
126         WRITE(numout,*) '        nb_ana    = ', nb_ana
127         CALL flush(numout)
128      ENDIF
129      !
130      IF (nb_ana > jpmax_harmo) THEN
131        IF(lwp) WRITE(numout,*) ' E R R O R dia_harm_init : nb_ana must be lower than jpmax_harmo, stop'
132        IF(lwp) WRITE(numout,*) ' jpmax_harmo= ', jpmax_harmo
133        nstop = nstop + 1
134      ENDIF
135
136      ALLOCATE(name    (nb_ana))
137      DO jk=1,nb_ana
138       DO ji=1,jpmax_harmo
139          IF (TRIM(tname(jk)) .eq. Wave(ji)%cname_tide) THEN
140             name(jk) = ji
141             EXIT
142          END IF
143       END DO
144      END DO
145
146      ! Initialize frequency array:
147      ! ---------------------------
148      ALLOCATE( ana_freq(nb_ana), ut(nb_ana), vt(nb_ana), ft(nb_ana) )
149
150      CALL tide_harmo( ana_freq, vt, ut, ft, name, nb_ana )
151
152      IF(lwp) WRITE(numout,*) 'Analysed frequency  : ',nb_ana ,'Frequency '
153
154      DO jh = 1, nb_ana
155        IF(lwp) WRITE(numout,*) '                    : ',tname(jh),' ',ana_freq(jh)
156      END DO
157
158      ! Initialize temporary arrays:
159      ! ----------------------------
160      ALLOCATE( ana_temp(jpi,jpj,2*nb_ana,3) )
161      ana_temp(:,:,:,:) = 0._wp
162
163   END SUBROUTINE dia_harm_init
164
165
166   SUBROUTINE dia_harm ( kt )
167      !!----------------------------------------------------------------------
168      !!                 ***  ROUTINE dia_harm  ***
169      !!         
170      !! ** Purpose :   Tidal harmonic analysis main routine
171      !!
172      !! ** Action  :   Sums ssh/u/v over time analysis [nit000_han,nitend_han]
173      !!
174      !!--------------------------------------------------------------------
175      INTEGER, INTENT( IN ) :: kt
176      !
177      INTEGER  :: ji, jj, jh, jc, nhc
178      REAL(wp) :: ztime, ztemp
179      !!--------------------------------------------------------------------
180      IF( nn_timing == 1 )   CALL timing_start('dia_harm')
181
182      IF( kt == nit000 ) CALL dia_harm_init
183
184      IF( kt >= nit000_han .AND. kt <= nitend_han .AND. MOD(kt,nstep_han) == 0 ) THEN
185
186         ztime = (kt-nit000+1) * rdt 
187       
188         nhc = 0
189         DO jh = 1, nb_ana
190            DO jc = 1, 2
191               nhc = nhc+1
192               ztemp =(     MOD(jc,2) * ft(jh) *COS(ana_freq(jh)*ztime + vt(jh) + ut(jh))  &
193                  &    +(1.-MOD(jc,2))* ft(jh) *SIN(ana_freq(jh)*ztime + vt(jh) + ut(jh)))
194
195               DO jj = 1,jpj
196                  DO ji = 1,jpi
197                     ! Elevation
198                     ana_temp(ji,jj,nhc,1) = ana_temp(ji,jj,nhc,1) + ztemp*sshn(ji,jj)*tmask_i(ji,jj)       
199                     ana_temp(ji,jj,nhc,2) = ana_temp(ji,jj,nhc,2) + ztemp*un_b(ji,jj)*umask_i(ji,jj)
200                     ana_temp(ji,jj,nhc,3) = ana_temp(ji,jj,nhc,3) + ztemp*vn_b(ji,jj)*vmask_i(ji,jj)
201                  END DO
202               END DO
203               !
204            END DO
205         END DO
206         !       
207      END IF
208
209      IF ( kt == nitend_han )   CALL dia_harm_end
210
211      IF( nn_timing == 1 )   CALL timing_stop('dia_harm')
212 
213   END SUBROUTINE dia_harm
214
215
216   SUBROUTINE dia_harm_end
217      !!----------------------------------------------------------------------
218      !!                 ***  ROUTINE diaharm_end  ***
219      !!         
220      !! ** Purpose :  Compute the Real and Imaginary part of tidal constituents
221      !!
222      !! ** Action  :  Decompose the signal on the harmonic constituents
223      !!
224      !!--------------------------------------------------------------------
225      INTEGER :: ji, jj, jh, jc, jn, nhan, jl
226      INTEGER :: ksp, kun, keq
227      REAL(wp) :: ztime, ztime_ini, ztime_end
228      REAL(wp) :: X1,X2
229      REAL(wp), POINTER, DIMENSION(:,:,:,:) :: ana_amp
230      !!--------------------------------------------------------------------
231      CALL wrk_alloc( jpi , jpj , jpmax_harmo , 2 , ana_amp )
232
233      IF(lwp) WRITE(numout,*)
234      IF(lwp) WRITE(numout,*) 'anharmo_end: kt=nitend_han: Perform harmonic analysis'
235      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~'
236
237      ztime_ini = nit000_han*rdt                 ! Initial time in seconds at the beginning of analysis
238      ztime_end = nitend_han*rdt                 ! Final time in seconds at the end of analysis
239      nhan = (nitend_han-nit000_han+1)/nstep_han ! Number of dumps used for analysis
240
241      ninco = 2*nb_ana
242
243      ksp = 0
244      keq = 0       
245      DO jn = 1, nhan
246         ztime=( (nhan-jn)*ztime_ini + (jn-1)*ztime_end )/FLOAT(nhan-1)
247         keq = keq + 1
248         kun = 0
249         DO jh = 1, nb_ana
250            DO jc = 1, 2
251               kun = kun + 1
252               ksp = ksp + 1
253               nisparse(ksp) = keq
254               njsparse(ksp) = kun
255               valuesparse(ksp) = (   MOD(jc,2) * ft(jh) * COS(ana_freq(jh)*ztime + vt(jh) + ut(jh))   &
256                  &             + (1.-MOD(jc,2))* ft(jh) * SIN(ana_freq(jh)*ztime + vt(jh) + ut(jh)) )
257            END DO
258         END DO
259      END DO
260
261      nsparse = ksp
262
263      ! Elevation:
264      DO jj = 1, jpj
265         DO ji = 1, jpi
266            ! Fill input array
267            kun = 0
268            DO jh = 1, nb_ana
269               DO jc = 1, 2
270                  kun = kun + 1
271                  ztmp4(kun)=ana_temp(ji,jj,kun,1)
272               END DO
273            END DO
274
275            CALL SUR_DETERMINE(jj)
276
277            ! Fill output array
278            DO jh = 1, nb_ana
279               ana_amp(ji,jj,jh,1)=ztmp7((jh-1)*2+1)
280               ana_amp(ji,jj,jh,2)=ztmp7((jh-1)*2+2)
281            END DO
282         END DO
283      END DO
284
285      ALLOCATE( out_eta(jpi,jpj,2*nb_ana),   & 
286         &      out_u  (jpi,jpj,2*nb_ana),   &
287         &      out_v  (jpi,jpj,2*nb_ana)  )
288
289      DO jj = 1, jpj
290         DO ji = 1, jpi
291            DO jh = 1, nb_ana 
292               X1 = ana_amp(ji,jj,jh,1)
293               X2 =-ana_amp(ji,jj,jh,2)
294               out_eta(ji,jj,jh       ) = X1 * tmask_i(ji,jj)
295               out_eta(ji,jj,jh+nb_ana) = X2 * tmask_i(ji,jj)
296            END DO
297         END DO
298      END DO
299
300      ! ubar:
301      DO jj = 1, jpj
302         DO ji = 1, jpi
303            ! Fill input array
304            kun=0
305            DO jh = 1,nb_ana
306               DO jc = 1,2
307                  kun = kun + 1
308                  ztmp4(kun)=ana_temp(ji,jj,kun,2)
309               END DO
310            END DO
311
312            CALL SUR_DETERMINE(jj+1)
313
314            ! Fill output array
315            DO jh = 1, nb_ana
316               ana_amp(ji,jj,jh,1) = ztmp7((jh-1)*2+1)
317               ana_amp(ji,jj,jh,2) = ztmp7((jh-1)*2+2)
318            END DO
319
320         END DO
321      END DO
322
323      DO jj = 1, jpj
324         DO ji = 1, jpi
325            DO jh = 1, nb_ana 
326               X1= ana_amp(ji,jj,jh,1)
327               X2=-ana_amp(ji,jj,jh,2)
328               out_u(ji,jj,       jh) = X1 * umask_i(ji,jj)
329               out_u(ji,jj,nb_ana+jh) = X2 * umask_i(ji,jj)
330            ENDDO
331         ENDDO
332      ENDDO
333
334      ! vbar:
335      DO jj = 1, jpj
336         DO ji = 1, jpi
337            ! Fill input array
338            kun=0
339            DO jh = 1,nb_ana
340               DO jc = 1,2
341                  kun = kun + 1
342                  ztmp4(kun)=ana_temp(ji,jj,kun,3)
343               END DO
344            END DO
345
346            CALL SUR_DETERMINE(jj+1)
347
348            ! Fill output array
349            DO jh = 1, nb_ana
350               ana_amp(ji,jj,jh,1)=ztmp7((jh-1)*2+1)
351               ana_amp(ji,jj,jh,2)=ztmp7((jh-1)*2+2)
352            END DO
353
354         END DO
355      END DO
356
357      DO jj = 1, jpj
358         DO ji = 1, jpi
359            DO jh = 1, nb_ana 
360               X1=ana_amp(ji,jj,jh,1)
361               X2=-ana_amp(ji,jj,jh,2)
362               out_v(ji,jj,       jh)=X1 * vmask_i(ji,jj)
363               out_v(ji,jj,nb_ana+jh)=X2 * vmask_i(ji,jj)
364            END DO
365         END DO
366      END DO
367
368      CALL dia_wri_harm ! Write results in files
369      CALL wrk_dealloc( jpi , jpj , jpmax_harmo , 2 , ana_amp )
370      !
371   END SUBROUTINE dia_harm_end
372
373
374   SUBROUTINE dia_wri_harm
375      !!--------------------------------------------------------------------
376      !!                 ***  ROUTINE dia_wri_harm  ***
377      !!         
378      !! ** Purpose : Write tidal harmonic analysis results in a netcdf file
379      !!--------------------------------------------------------------------
380      CHARACTER(LEN=lc) :: cltext
381      CHARACTER(LEN=lc) ::   &
382         cdfile_name_T   ,   & ! name of the file created (T-points)
383         cdfile_name_U   ,   & ! name of the file created (U-points)
384         cdfile_name_V         ! name of the file created (V-points)
385      INTEGER  ::   jh
386      !!----------------------------------------------------------------------
387
388#if defined key_dimgout
389      cdfile_name_T = TRIM(cexper)//'_Tidal_harmonics_gridT.dimgproc'
390      cdfile_name_U = TRIM(cexper)//'_Tidal_harmonics_gridU.dimgproc'
391      cdfile_name_V = TRIM(cexper)//'_Tidal_harmonics_gridV.dimgproc'
392#endif
393
394      IF(lwp) WRITE(numout,*) '  '
395      IF(lwp) WRITE(numout,*) 'dia_wri_harm : Write harmonic analysis results'
396#if defined key_dimgout
397      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~  Output files: ', TRIM(cdfile_name_T)
398      IF(lwp) WRITE(numout,*) '                             ', TRIM(cdfile_name_U)
399      IF(lwp) WRITE(numout,*) '                             ', TRIM(cdfile_name_V)
400#endif
401      IF(lwp) WRITE(numout,*) '  '
402
403      ! A) Elevation
404      !/////////////
405      !
406#if defined key_dimgout
407      cltext='Elevation amplitude and phase'
408      CALL dia_wri_dimg(TRIM(cdfile_name_T), TRIM(cltext), out_eta, 2*nb_ana, '2')
409#else
410      DO jh = 1, nb_ana
411      CALL iom_put( TRIM(tname(jh))//'x', out_eta(:,:,jh) )
412      CALL iom_put( TRIM(tname(jh))//'y', out_eta(:,:,nb_ana+jh) )
413      END DO
414#endif
415
416      ! B) ubar
417      !/////////
418      !
419#if defined key_dimgout
420      cltext='ubar amplitude and phase'
421      CALL dia_wri_dimg(TRIM(cdfile_name_U), TRIM(cltext), out_u, 2*nb_ana, '2')
422#else
423      DO jh = 1, nb_ana
424      CALL iom_put( TRIM(tname(jh))//'x_u', out_u(:,:,jh) )
425      CALL iom_put( TRIM(tname(jh))//'y_u', out_u(:,:,nb_ana+jh) )
426      END DO
427#endif
428
429      ! C) vbar
430      !/////////
431      !
432#if defined key_dimgout
433      cltext='vbar amplitude and phase'
434      CALL dia_wri_dimg(TRIM(cdfile_name_V), TRIM(cltext), out_v, 2*nb_ana, '2')
435#else
436      DO jh = 1, nb_ana
437         CALL iom_put( TRIM(tname(jh))//'x_v', out_v(:,:,jh       ) )
438         CALL iom_put( TRIM(tname(jh))//'y_v', out_v(:,:,jh+nb_ana) )
439      END DO
440#endif
441      !
442   END SUBROUTINE dia_wri_harm
443
444
445   SUBROUTINE SUR_DETERMINE(init)
446      !!---------------------------------------------------------------------------------
447      !!                      *** ROUTINE SUR_DETERMINE ***
448      !!   
449      !!   
450      !!       
451      !!---------------------------------------------------------------------------------
452      INTEGER, INTENT(in) ::   init 
453      !
454      INTEGER                         :: ji_sd, jj_sd, ji1_sd, ji2_sd, jk1_sd, jk2_sd
455      REAL(wp)                        :: zval1, zval2, zx1
456      REAL(wp), POINTER, DIMENSION(:) :: ztmpx, zcol1, zcol2
457      INTEGER , POINTER, DIMENSION(:) :: ipos2, ipivot
458      !---------------------------------------------------------------------------------
459      CALL wrk_alloc( jpincomax , ztmpx , zcol1 , zcol2 )
460      CALL wrk_alloc( jpincomax , ipos2 , ipivot        )
461           
462      IF( init == 1 ) THEN
463         IF( nsparse > jpdimsparse )   CALL ctl_stop( 'STOP', 'SUR_DETERMINE : nsparse .GT. jpdimsparse')
464         IF( ninco   > jpincomax   )   CALL ctl_stop( 'STOP', 'SUR_DETERMINE : ninco .GT. jpincomax')
465         !
466         ztmp3(:,:) = 0._wp
467         !
468         DO jk1_sd = 1, nsparse
469            DO jk2_sd = 1, nsparse
470               nisparse(jk2_sd) = nisparse(jk2_sd)
471               njsparse(jk2_sd) = njsparse(jk2_sd)
472               IF( nisparse(jk2_sd) == nisparse(jk1_sd) ) THEN
473                  ztmp3(njsparse(jk1_sd),njsparse(jk2_sd)) = ztmp3(njsparse(jk1_sd),njsparse(jk2_sd))  &
474                     &                                     + valuesparse(jk1_sd)*valuesparse(jk2_sd)
475               ENDIF
476            END DO
477         END DO
478         !
479         DO jj_sd = 1 ,ninco
480            ipos1(jj_sd) = jj_sd
481            ipos2(jj_sd) = jj_sd
482         END DO
483         !
484         DO ji_sd = 1 , ninco
485            !
486            !find greatest non-zero pivot:
487            zval1 = ABS(ztmp3(ji_sd,ji_sd))
488            !
489            ipivot(ji_sd) = ji_sd
490            DO jj_sd = ji_sd, ninco
491               zval2 = ABS(ztmp3(ji_sd,jj_sd))
492               IF( zval2.GE.zval1 )THEN
493                  ipivot(ji_sd) = jj_sd
494                  zval1         = zval2
495               ENDIF
496            END DO
497            !
498            DO ji1_sd = 1, ninco
499               zcol1(ji1_sd)               = ztmp3(ji1_sd,ji_sd)
500               zcol2(ji1_sd)               = ztmp3(ji1_sd,ipivot(ji_sd))
501               ztmp3(ji1_sd,ji_sd)         = zcol2(ji1_sd)
502               ztmp3(ji1_sd,ipivot(ji_sd)) = zcol1(ji1_sd)
503            END DO
504            !
505            ipos2(ji_sd)         = ipos1(ipivot(ji_sd))
506            ipos2(ipivot(ji_sd)) = ipos1(ji_sd)
507            ipos1(ji_sd)         = ipos2(ji_sd)
508            ipos1(ipivot(ji_sd)) = ipos2(ipivot(ji_sd))
509            zpivot(ji_sd)        = ztmp3(ji_sd,ji_sd)
510            DO jj_sd = 1, ninco
511               ztmp3(ji_sd,jj_sd) = ztmp3(ji_sd,jj_sd) / zpivot(ji_sd)
512            END DO
513            !
514            DO ji2_sd = ji_sd+1, ninco
515               zpilier(ji2_sd,ji_sd)=ztmp3(ji2_sd,ji_sd)
516               DO jj_sd=1,ninco
517                  ztmp3(ji2_sd,jj_sd)=  ztmp3(ji2_sd,jj_sd) - ztmp3(ji_sd,jj_sd) * zpilier(ji2_sd,ji_sd)
518               END DO
519            END DO
520            !
521         END DO
522         !
523      ENDIF ! End init==1
524
525      DO ji_sd = 1, ninco
526         ztmp4(ji_sd) = ztmp4(ji_sd) / zpivot(ji_sd)
527         DO ji2_sd = ji_sd+1, ninco
528            ztmp4(ji2_sd) = ztmp4(ji2_sd) - ztmp4(ji_sd) * zpilier(ji2_sd,ji_sd)
529         END DO
530      END DO
531
532      !system solving:
533      ztmpx(ninco) = ztmp4(ninco) / ztmp3(ninco,ninco)
534      ji_sd = ninco
535      DO ji_sd = ninco-1, 1, -1
536         zx1 = 0._wp
537         DO jj_sd = ji_sd+1, ninco
538            zx1 = zx1 + ztmpx(jj_sd) * ztmp3(ji_sd,jj_sd)
539         END DO
540         ztmpx(ji_sd) = ztmp4(ji_sd)-zx1
541      END DO
542
543      DO jj_sd =1, ninco
544         ztmp7(ipos1(jj_sd))=ztmpx(jj_sd)
545      END DO
546
547      CALL wrk_dealloc( jpincomax , ztmpx , zcol1 , zcol2 )
548      CALL wrk_dealloc( jpincomax , ipos2 , ipivot        )
549      !
550   END SUBROUTINE SUR_DETERMINE
551
552#else
553   !!----------------------------------------------------------------------
554   !!   Default case :   Empty module
555   !!----------------------------------------------------------------------
556   LOGICAL, PUBLIC, PARAMETER ::   lk_diaharm = .FALSE.
557CONTAINS
558   SUBROUTINE dia_harm ( kt )     ! Empty routine
559      INTEGER, INTENT( IN ) :: kt 
560      WRITE(*,*) 'dia_harm: you should not have seen this print'
561   END SUBROUTINE dia_harm
562#endif
563
564   !!======================================================================
565END MODULE diaharm
Note: See TracBrowser for help on using the repository browser.