source: branches/UKMO/r6232_tracer_advection/NEMOGCM/NEMO/OPA_SRC/IOM/iom_ioipsl.F90 @ 9295

Last change on this file since 9295 was 9295, checked in by jcastill, 3 years ago

Remove svn keywords

File size: 24.5 KB
Line 
1MODULE iom_ioipsl
2   !!=====================================================================
3   !!                    ***  MODULE  iom_ioipsl ***
4   !! Input/Output manager :  Library to read input files with IOIPSL (only fliocom module)
5   !!====================================================================
6   !! History :  9.0  ! 05 12  (J. Belier) Original code
7   !!            9.0  ! 06 02  (S. Masson) Adaptation to NEMO
8   !!             "   ! 07 07  (D. Storkey) Changes to iom_ioipsl_gettime
9   !!--------------------------------------------------------------------
10   !!gm  caution add !DIR nec: improved performance to be checked as well as no result changes
11
12   !!--------------------------------------------------------------------
13   !!   iom_open       : open a file read only
14   !!   iom_close      : close a file or all files opened by iom
15   !!   iom_get        : read a field (interfaced to several routines)
16   !!   iom_gettime    : read the time axis kvid in the file
17   !!   iom_varid      : get the id of a variable in a file
18   !!   iom_rstput     : write a field in a restart file (interfaced to several routines)
19   !!--------------------------------------------------------------------
20   USE dom_oce         ! ocean space and time domain
21   USE iom_def         ! iom variables definitions
22   USE ioipsl          ! IOIPSL library
23   USE in_out_manager  ! I/O manager
24   USE lib_mpp         ! MPP library
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC iom_ioipsl_open, iom_ioipsl_close, iom_ioipsl_varid, iom_ioipsl_get, iom_ioipsl_gettime, iom_ioipsl_rstput
30
31   INTERFACE iom_ioipsl_get
32      MODULE PROCEDURE iom_ioipsl_g0d, iom_ioipsl_g123d
33   END INTERFACE
34   INTERFACE iom_ioipsl_rstput
35      MODULE PROCEDURE iom_ioipsl_rp0123d
36   END INTERFACE
37   !!----------------------------------------------------------------------
38   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
39   !! $Id$
40   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
41   !!----------------------------------------------------------------------
42
43CONTAINS
44
45   SUBROUTINE iom_ioipsl_open( cdname, kiomid, ldwrt, ldok, kdompar )
46      !!---------------------------------------------------------------------
47      !!                   ***  SUBROUTINE  iom_open  ***
48      !!
49      !! ** Purpose :  open an input file with IOIPSL (only fliocom module)
50      !!---------------------------------------------------------------------
51      CHARACTER(len=*)       , INTENT(inout)           ::   cdname      ! File name
52      INTEGER                , INTENT(  out)           ::   kiomid      ! ioipsl identifier of the opened file
53      LOGICAL                , INTENT(in   )           ::   ldwrt       ! read or write the file?
54      LOGICAL                , INTENT(in   )           ::   ldok        ! check the existence
55      INTEGER, DIMENSION(2,5), INTENT(in   ), OPTIONAL ::   kdompar     ! domain parameters:
56
57      CHARACTER(LEN=100) ::   clinfo      ! info character
58      CHARACTER(LEN=10 ) ::   clstatus    ! status of opened file (REPLACE or NEW)
59      INTEGER            ::   iln         ! lengths of character
60      INTEGER            ::   istop       ! temporary storage of nstop
61      INTEGER            ::   ifliodom    ! model domain identifier (see flio_dom_set)
62      INTEGER            ::   ioipslid    ! ioipsl identifier of the opened file
63      INTEGER            ::   jl          ! loop variable
64      LOGICAL            ::   llclobber   ! local definition of ln_clobber
65      !---------------------------------------------------------------------
66
67      clinfo = '                    iom_ioipsl_open ~~~  '
68      istop = nstop
69      !
70      llclobber = ldwrt .AND. ln_clobber
71      IF( ldok .AND. .NOT. llclobber ) THEN      ! Open existing file...
72         !                 ! =============
73         IF( ldwrt ) THEN  ! ... in write mode
74            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in WRITE mode'
75            CALL flioopfd( TRIM(cdname), ioipslid, "WRITE" )
76         ELSE              ! ... in read mode
77            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in READ mode'
78            CALL flioopfd( TRIM(cdname), ioipslid )
79         ENDIF
80      ELSE                 ! the file does not exist
81         !                 ! =============
82         iln = INDEX( cdname, '.nc' )
83         IF( ldwrt ) THEN  ! the file should be open in write mode so we create it...
84            IF( llclobber ) THEN   ;   clstatus = 'REPLACE 64' 
85            ELSE                   ;   clstatus = 'NEW 64'
86            ENDIF
87            IF( jpnij > 1 ) THEN
88               ! define the domain position regarding to the global domain (mainly useful in mpp)
89               CALL flio_dom_set( jpnij, narea-1, (/1, 2/), (/jpiglo, jpjglo/)   &
90                  &             , kdompar(:,1), kdompar(:,2), kdompar(:,3), kdompar(:,4), kdompar(:,5)   &
91                  &             , 'BOX', ifliodom )       
92               ! Note that fliocrfd may change the value of cdname (add the cpu number...)
93               IF(lwp) WRITE(numout,*) TRIM(clinfo)//' create new file: '//cdname(1:iln-1)//'... in WRITE mode'
94               CALL fliocrfd( cdname, (/'x'         , 'y'         , 'z', 't'/)   &
95                  &         , (/kdompar(1,1), kdompar(2,1), jpk, -1 /), ioipslid, ifliodom, mode = clstatus )
96            ELSE              ! the file should be open for read mode so it must exist...
97               IF(lwp) WRITE(numout,*) TRIM(clinfo)//' create new file: '//cdname//' in WRITE mode'
98               CALL fliocrfd( cdname, (/'x'         , 'y'         , 'z', 't'/)   &
99                  &         , (/kdompar(1,1), kdompar(2,1), jpk, -1 /), ioipslid,           mode = clstatus )
100            ENDIF
101         ELSE              ! the file should be open for read mode so it must exist...
102            CALL ctl_stop( TRIM(clinfo), ' should be impossible case...' )
103         ENDIF
104      ENDIF
105      ! start to fill file informations
106      ! =============
107      IF( istop == nstop ) THEN   ! no error within this routine
108!does not work with some compilers         kiomid = MINLOC(iom_file(:)%nfid, dim = 1)
109         kiomid = 0
110         DO jl = jpmax_files, 1, -1
111            IF( iom_file(jl)%nfid == 0 )   kiomid = jl
112         ENDDO
113         iom_file(kiomid)%name   = TRIM(cdname)
114         iom_file(kiomid)%nfid   = ioipslid
115         iom_file(kiomid)%iolib  = jpioipsl
116         iom_file(kiomid)%nvars  = 0
117         iom_file(kiomid)%irec   = -1   ! useless for NetCDF files
118         CALL flioinqf( ioipslid, id_uld = iom_file(kiomid)%iduld )
119         IF(lwp) WRITE(numout,*) '                   ---> '//TRIM(cdname)//' OK'
120      ELSE
121         kiomid = 0               ! return error flag
122      ENDIF
123      !
124   END SUBROUTINE iom_ioipsl_open
125
126
127   SUBROUTINE iom_ioipsl_close( kiomid )
128      !!--------------------------------------------------------------------
129      !!                   ***  SUBROUTINE  iom_ioipsl_close  ***
130      !!
131      !! ** Purpose : close an input file with IOIPSL (only fliocom module)
132      !!--------------------------------------------------------------------
133      INTEGER, INTENT(in) ::   kiomid   ! iom identifier of the file to be closed
134      !---------------------------------------------------------------------
135      !
136      CALL flioclo( iom_file(kiomid)%nfid )
137      !   
138   END SUBROUTINE iom_ioipsl_close
139
140
141   FUNCTION iom_ioipsl_varid ( kiomid, cdvar, kiv, kdimsz ) 
142      !!-----------------------------------------------------------------------
143      !!                  ***  FUNCTION  iom_varid  ***
144      !!
145      !! ** Purpose : get the id of a variable in a file with IOIPSL (only fliocom module)
146      !!-----------------------------------------------------------------------
147      INTEGER              , INTENT(in   )           ::   kiomid   ! file Identifier
148      CHARACTER(len=*)     , INTENT(in   )           ::   cdvar    ! name of the variable
149      INTEGER              , INTENT(in   )           ::   kiv   !
150      INTEGER, DIMENSION(:), INTENT(  out), OPTIONAL ::   kdimsz   ! size of the dimensions
151      !
152      INTEGER                        ::   iom_ioipsl_varid  ! iom variable Id
153      INTEGER                        ::   ioipslid          ! ioipsl file identifier
154      INTEGER                        ::   ji                ! dummy loop index
155      INTEGER                        ::   i_nvd             ! number of dimension of the variable
156      INTEGER, DIMENSION(jpmax_dims) ::   idimid            ! dimension ids of the variable
157      LOGICAL                        ::   ll_fnd            ! found test
158      CHARACTER(LEN=100)             ::   clinfo            ! info character
159      !!-----------------------------------------------------------------------
160      clinfo = 'iom_ioipsl_varid, file: '//trim(iom_file(kiomid)%name)//', var: '//trim(cdvar)
161      iom_ioipsl_varid = 0                  ! default definition
162      IF( PRESENT(kdimsz) ) kdimsz(:) = 0   ! default definition
163      ioipslid = iom_file(kiomid)%nfid      ! get back ioipsl file identifier
164      CALL flioinqv( ioipslid, cdvar, ll_fnd, nb_dims = i_nvd )   ! does the variable exist in the file
165      IF( ll_fnd ) THEN
166         IF( i_nvd <= jpmax_dims ) THEN
167            iom_ioipsl_varid = kiv
168            iom_file(kiomid)%nvars       = kiv
169            iom_file(kiomid)%nvid(kiv)   = -1   ! variable id is not available in ioipsl
170            iom_file(kiomid)%cn_var(kiv) = TRIM(cdvar)
171            iom_file(kiomid)%ndims(kiv)  = i_nvd
172            iom_file(kiomid)%dimsz(:,kiv) = 0   ! reset dimsz in case previously used
173            CALL flioinqv( ioipslid, cdvar, ll_fnd,   &
174                  &           len_dims = iom_file(kiomid)%dimsz(1:i_nvd,kiv), &   ! dimensions size
175                  &           id_dims  = idimid(1:i_nvd) )                        ! dimensions ids
176            iom_file(kiomid)%luld(kiv) = .FALSE.   ! default value
177            DO ji = 1, i_nvd                       ! find the unlimited dimension
178               IF( idimid(ji) == iom_file(kiomid)%iduld ) iom_file(kiomid)%luld(kiv) = .TRUE.
179            END DO
180            !---------- Deal with scale_factor and add_offset
181            CALL flioinqa( ioipslid, cdvar, 'scale_factor', ll_fnd )
182            IF( ll_fnd) THEN
183               CALL fliogeta( ioipslid, cdvar, 'scale_factor', iom_file(kiomid)%scf(kiv) )
184            ELSE
185               iom_file(kiomid)%scf(kiv) = 1.
186            END IF
187            CALL flioinqa( ioipslid, cdvar, 'add_offset', ll_fnd )
188            IF( ll_fnd ) THEN
189               CALL fliogeta( ioipslid, cdvar, 'add_offset', iom_file(kiomid)%ofs(kiv) )
190            ELSE
191               iom_file(kiomid)%ofs(kiv) = 0.
192            END IF
193            ! return the simension size
194            IF( PRESENT(kdimsz) ) THEN
195               IF( i_nvd == SIZE(kdimsz) ) THEN
196                  kdimsz(:) = iom_file(kiomid)%dimsz(1:i_nvd,kiv)
197               ELSE
198                  WRITE(ctmp1,*) i_nvd, SIZE(kdimsz)
199                  CALL ctl_stop( TRIM(clinfo), 'error in kdimsz size'//TRIM(ctmp1) )
200               ENDIF
201            ENDIF
202         ELSE
203            CALL ctl_stop( TRIM(clinfo), 'Too many dimensions in the file '//iom_file(kiomid)%name,   &
204                  &                       'increase the parameter jpmax_vars')
205         ENDIF
206      ELSE 
207         iom_ioipsl_varid = -1   !   variable not found, return error code: -1
208      ENDIF
209      !
210   END FUNCTION iom_ioipsl_varid
211
212
213   SUBROUTINE iom_ioipsl_g0d( kiomid, kvid, pvar, kstart )
214      !!-----------------------------------------------------------------------
215      !!                  ***  ROUTINE  iom_ioipsl_g0d  ***
216      !!
217      !! ** Purpose : read a scalar with IOIPSL (only fliocom module)
218      !!-----------------------------------------------------------------------
219      INTEGER ,               INTENT(in   )            ::   kiomid    ! Identifier of the file
220      INTEGER ,               INTENT(in   )            ::   kvid      ! variable id
221      REAL(wp),               INTENT(  out)            ::   pvar      ! read field
222      INTEGER , DIMENSION(1), INTENT(in   ), OPTIONAL  ::   kstart    ! start position of the reading in each axis
223      !
224      CALL fliogetv( iom_file(kiomid)%nfid, TRIM(iom_file(kiomid)%cn_var(kvid)), pvar, kstart )
225      !
226   END SUBROUTINE iom_ioipsl_g0d
227
228
229   SUBROUTINE iom_ioipsl_g123d( kiomid, kvid, knbdim, kstart, kcount, kx1, kx2, ky1, ky2,   &
230         &                      pv_r1d, pv_r2d, pv_r3d)
231      !!-----------------------------------------------------------------------
232      !!                  ***  ROUTINE  iom_ioipsl_g123d  ***
233      !!
234      !! ** Purpose : read a 1D/2D/3D variable with IOIPSL (only fliocom module)
235      !!
236      !! ** Method : read ONE record at each CALL
237      !!-----------------------------------------------------------------------
238      INTEGER                    , INTENT(in   )           ::   kiomid     ! iom identifier of the file
239      INTEGER                    , INTENT(in   )           ::   kvid       ! Name of the variable
240      INTEGER                    , INTENT(in   )           ::   knbdim     ! number of dimensions of the variable
241      INTEGER , DIMENSION(:)     , INTENT(in   )           ::   kstart     ! start position of the reading in each axis
242      INTEGER , DIMENSION(:)     , INTENT(in   )           ::   kcount     ! number of points to be read in each axis
243      INTEGER ,                    INTENT(in   )           ::   kx1, kx2, ky1, ky2   ! subdomain indexes
244      REAL(wp), DIMENSION(:)     , INTENT(  out), OPTIONAL ::   pv_r1d     ! read field (1D case)
245      REAL(wp), DIMENSION(:,:)   , INTENT(  out), OPTIONAL ::   pv_r2d     ! read field (2D case)
246      REAL(wp), DIMENSION(:,:,:) , INTENT(  out), OPTIONAL ::   pv_r3d     ! read field (3D case)
247      !
248      INTEGER               ::   ioipslid   ! ioipsl file identifier
249      CHARACTER(LEN=100)    ::   clvn       ! variable name
250      !---------------------------------------------------------------------
251      clvn = TRIM(iom_file(kiomid)%cn_var(kvid))   ! get back variable name
252      ioipslid = iom_file(kiomid)%nfid             ! get back IPIPSL file id
253      !
254      IF( PRESENT(pv_r1d) ) THEN
255         CALL fliogetv( ioipslid, clvn, pv_r1d(:                ), start = kstart(1:knbdim), count = kcount(1:knbdim) )
256      ELSEIF( PRESENT(pv_r2d) ) THEN
257         CALL fliogetv( ioipslid, clvn, pv_r2d(kx1:kx2,ky1:ky2  ), start = kstart(1:knbdim), count = kcount(1:knbdim) )
258      ELSEIF( PRESENT(pv_r3d) ) THEN
259         CALL fliogetv( ioipslid, clvn, pv_r3d(kx1:kx2,ky1:ky2,:), start = kstart(1:knbdim), count = kcount(1:knbdim) )
260      ENDIF
261      !
262      !
263   END SUBROUTINE iom_ioipsl_g123d
264
265
266   SUBROUTINE iom_ioipsl_gettime( kiomid, kvid, ptime, cdunits, cdcalendar )
267      !!--------------------------------------------------------------------
268      !!                   ***  SUBROUTINE iom_gettime  ***
269      !!
270      !! ** Purpose : read the time axis kvid in the file with IOIPSL (only fliocom module)
271      !!--------------------------------------------------------------------
272      INTEGER                   , INTENT(in   ) ::   kiomid     ! file Identifier
273      INTEGER                   , INTENT(in   ) ::   kvid       ! variable id
274      REAL(wp), DIMENSION(:)    , INTENT(  out) ::   ptime      ! the time axis
275      CHARACTER(len=*), OPTIONAL, INTENT(  out) ::   cdunits    ! units attribute
276      CHARACTER(len=*), OPTIONAL, INTENT(  out) ::   cdcalendar ! calendar attribute
277      !---------------------------------------------------------------------
278      !
279      CALL fliogetv( iom_file(kiomid)%nfid, TRIM(iom_file(kiomid)%cn_var(kvid)), ptime(:),   &
280            &         start=(/ 1 /), count=(/ iom_file(kiomid)%dimsz(1, kvid) /) )
281      IF ( PRESENT(cdunits) ) THEN
282         CALL fliogeta( iom_file(kiomid)%nfid, TRIM(iom_file(kiomid)%cn_var(kvid)), "units", cdunits )
283      ENDIF
284      IF ( PRESENT(cdcalendar) ) THEN
285         CALL fliogeta( iom_file(kiomid)%nfid, TRIM(iom_file(kiomid)%cn_var(kvid)), "calendar", cdcalendar )
286      ENDIF
287      !
288   END SUBROUTINE iom_ioipsl_gettime
289
290
291   SUBROUTINE iom_ioipsl_rp0123d( kt, kwrite, kiomid, cdvar , kvid  , ktype,   &
292         &                                 pv_r0d, pv_r1d, pv_r2d, pv_r3d )
293      !!--------------------------------------------------------------------
294      !!                   ***  SUBROUTINE  iom_ioipsl_rstput  ***
295      !!
296      !! ** Purpose : read the time axis cdvar in the file
297      !!--------------------------------------------------------------------
298      INTEGER                     , INTENT(in)           ::   kt       ! ocean time-step
299      INTEGER                     , INTENT(in)           ::   kwrite   ! writing time-step
300      INTEGER                     , INTENT(in)           ::   kiomid   ! Identifier of the file
301      CHARACTER(len=*)            , INTENT(in)           ::   cdvar    ! variable name
302      INTEGER                     , INTENT(in)           ::   kvid     ! variable id
303      INTEGER                     , INTENT(in), OPTIONAL ::   ktype    ! variable type (default R8)
304      REAL(wp)                    , INTENT(in), OPTIONAL ::   pv_r0d   ! written Od field
305      REAL(wp), DIMENSION(      :), INTENT(in), OPTIONAL ::   pv_r1d   ! written 1d field
306      REAL(wp), DIMENSION(:, :   ), INTENT(in), OPTIONAL ::   pv_r2d   ! written 2d field
307      REAL(wp), DIMENSION(:, :, :), INTENT(in), OPTIONAL ::   pv_r3d   ! written 3d field
308      !
309      INTEGER               :: idims                ! number of dimension
310      INTEGER               :: idvar                ! variable id
311      INTEGER               :: itype                ! variable type
312      INTEGER               :: ix1, ix2, iy1, iy2   ! subdomain indexes
313      INTEGER, DIMENSION(4) :: idimsz               ! dimensions size 
314      INTEGER, DIMENSION(4) :: idimid               ! dimensions id
315      CHARACTER(LEN=100)    :: clinfo               ! info character
316      INTEGER               :: ioipslid             ! ioipsl file identifier
317      !---------------------------------------------------------------------
318      !
319      clinfo = '          iom_ioipsl_rp0123d, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(cdvar)
320      ioipslid = iom_file(kiomid)%nfid
321      !
322      ! define dimension variables if it is not already done
323      ! ==========================
324      IF( iom_file(kiomid)%nvars == 0 ) THEN
325         ! define the dimension variables if it is not already done
326         CALL fliodefv( ioipslid,'nav_lon', (/1,2/), v_t=flio_r4   , axis='X',   &
327               &                  long_name="Longitude", units="degrees_east" )
328         CALL fliodefv( ioipslid,'nav_lat', (/1,2/), v_t=flio_r4   , axis='Y',   &
329               &                  long_name="Latitude", units="degrees_north" )
330         CALL fliodefv( ioipslid,'nav_lev', (/3/)  , v_t=flio_i4   , axis='Z',   &
331               &                  long_name="Model levels",units="model_levels")
332         CALL fliodefv( ioipslid,'time_counter', (/4/), v_t=flio_r4, axis='T',   &
333               &                  long_name="Time axis", units='seconds since 0001-01-01 00:00:00' )
334         ! update informations structure related the dimension variable we just added...
335         iom_file(kiomid)%nvars       = 4
336         iom_file(kiomid)%luld(1:4)   = (/ .FALSE., .FALSE., .FALSE., .TRUE. /)
337         iom_file(kiomid)%cn_var(1:3) = (/ 'nav_lon', 'nav_lat', 'nav_lev' /)
338         iom_file(kiomid)%cn_var(4)   = 'time_counter'
339         iom_file(kiomid)%ndims(1:4)  = (/ 2, 2, 1, 1 /)
340         ! trick: defined to 0 to say that dimension variables are defined but not yet written
341         iom_file(kiomid)%dimsz(1, 1) = 0   
342         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' define dimension variables done'
343      ENDIF
344
345      ! define the data if it is not already done
346      ! ===============
347      IF( kvid <= 0 ) THEN
348         ! variable definition
349         IF(     PRESENT(pv_r0d) ) THEN   ;   idims = 0
350         ELSEIF( PRESENT(pv_r1d) ) THEN   ;   idims = 2   ;   idimid(1:idims) = (/    3,4/)
351         ELSEIF( PRESENT(pv_r2d) ) THEN   ;   idims = 3   ;   idimid(1:idims) = (/1,2  ,4/)
352         ELSEIF( PRESENT(pv_r3d) ) THEN   ;   idims = 4   ;   idimid(1:idims) = (/1,2,3,4/)
353         ENDIF
354         IF( PRESENT(ktype) ) THEN   ! variable external type
355            SELECT CASE (ktype)
356            CASE (jp_r8)  ;   itype = flio_r8
357            CASE (jp_r4)  ;   itype = flio_r4
358            CASE (jp_i4)  ;   itype = flio_i4
359            CASE (jp_i2)  ;   itype = flio_i2
360            CASE (jp_i1)  ;   itype = flio_i1   !   fliocom does not handle i1 type of variable
361            CASE DEFAULT   ;   CALL ctl_stop( TRIM(clinfo)//' unknown variable type' )
362            END SELECT
363         ELSE
364            itype = flio_r8
365         ENDIF
366         IF( PRESENT(pv_r0d) ) THEN   ;   CALL fliodefv (ioipslid, TRIM(cdvar)                 , v_t = itype)
367         ELSE                         ;   CALL fliodefv (ioipslid, TRIM(cdvar), idimid(1:idims), v_t = itype)
368         ENDIF
369         ! update informations structure related the new variable we want to add...
370         idvar                          = iom_file(kiomid)%nvars + 1
371         iom_file(kiomid)%nvars         = idvar
372         iom_file(kiomid)%cn_var(idvar) = TRIM(cdvar)
373         iom_file(kiomid)%nvid(idvar)   = -1   ! netcdf variable id is not available in ioipsl
374         iom_file(kiomid)%scf(idvar)    = 1.
375         iom_file(kiomid)%ofs(idvar)    = 0.
376         iom_file(kiomid)%ndims(idvar)  = idims
377         IF( .NOT. PRESENT(pv_r0d) ) THEN
378            iom_file(kiomid)%luld(idvar) = .TRUE.
379            CALL flioinqf( ioipslid, ln_dim = idimsz )
380            iom_file(kiomid)%dimsz(1:idims-1,idvar) = idimsz(idimid(1:idims-1))
381         ELSE                               
382            iom_file(kiomid)%luld(idvar) = .FALSE.
383         ENDIF
384         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' defined ok'
385      ELSE
386         idvar = kvid
387      ENDIF
388
389      ! time step kwrite : write the variable
390      IF( kt == kwrite ) THEN
391         ! on what kind of domain must the data be written?
392         IF( PRESENT(pv_r2d) .OR. PRESENT(pv_r3d) ) THEN
393            idimsz(1:2) = iom_file(kiomid)%dimsz(1:2,idvar)
394            IF(     idimsz(1) == (nlei - nldi + 1) .AND. idimsz(2) == (nlej - nldj + 1) ) THEN
395               ix1 = nldi   ;   ix2 = nlei   ;   iy1 = nldj   ;   iy2 = nlej
396            ELSEIF( idimsz(1) == nlci              .AND. idimsz(2) == nlcj              ) THEN
397               ix1 = 1      ;   ix2 = nlci   ;   iy1 = 1      ;   iy2 = nlcj
398            ELSEIF( idimsz(1) == jpi               .AND. idimsz(2) == jpj               ) THEN
399               ix1 = 1      ;   ix2 = jpi    ;   iy1 = 1      ;   iy2 = jpj
400            ELSE
401               CALL ctl_stop( 'iom_ioipsl_rp0123d: should have been an impossible case...' )
402            ENDIF
403
404            ! write dimension variables if it is not already done
405            ! =============
406            ! trick: is defined to 0 => dimension variable are defined but not yet written
407            IF( iom_file(kiomid)%dimsz(1, 1) == 0 ) THEN
408               CALL flioputv( ioipslid, 'nav_lon'     , glamt(ix1:ix2, iy1:iy2) )
409               CALL flioputv( ioipslid, 'nav_lat'     , gphit(ix1:ix2, iy1:iy2) )
410               CALL flioputv( ioipslid, 'nav_lev'     , gdept_1d )
411               ! +++ WRONG VALUE: to be improved but not really useful...
412               CALL flioputv( ioipslid, 'time_counter', kt )
413               ! update the values of the variables dimensions size
414               CALL flioinqf( ioipslid, ln_dim = idimsz )
415               iom_file(kiomid)%dimsz(1:2, 1) = idimsz(1:2)
416               iom_file(kiomid)%dimsz(1:2, 2) = idimsz(1:2)
417               iom_file(kiomid)%dimsz(1, 3:4) = (/idimsz(3), 1/)
418               IF(lwp) WRITE(numout,*) TRIM(clinfo)//' write dimension variables done'
419            ENDIF
420         ENDIF
421
422         ! write the data
423         ! =============
424         IF(     PRESENT(pv_r0d) ) THEN   ;   CALL flioputv( ioipslid, cdvar, pv_r0d                      )
425         ELSEIF( PRESENT(pv_r1d) ) THEN   ;   CALL flioputv( ioipslid, cdvar, pv_r1d(                  :) )
426         ELSEIF( PRESENT(pv_r2d) ) THEN   ;   CALL flioputv( ioipslid, cdvar, pv_r2d(ix1:ix2, iy1:iy2   ) )
427         ELSEIF( PRESENT(pv_r3d) ) THEN   ;   CALL flioputv( ioipslid, cdvar, pv_r3d(ix1:ix2, iy1:iy2, :) )
428         ENDIF
429         ! add 1 to the size of the temporal dimension (not really useful...)
430         IF( iom_file(kiomid)%luld(idvar) )   iom_file(kiomid)%dimsz(iom_file(kiomid)%ndims(idvar), idvar)    &
431               &                            = iom_file(kiomid)%dimsz(iom_file(kiomid)%ndims(idvar), idvar) + 1
432         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' written ok'
433      ENDIF
434      !     
435   END SUBROUTINE iom_ioipsl_rp0123d
436
437
438   !!======================================================================
439END MODULE iom_ioipsl
Note: See TracBrowser for help on using the repository browser.