source: branches/UKMO/r6232_tracer_advection/NEMOGCM/NEMO/OPA_SRC/TRA/traadv.F90 @ 9295

Last change on this file since 9295 was 9295, checked in by jcastill, 3 years ago

Remove svn keywords

File size: 14.1 KB
Line 
1MODULE traadv
2   !!==============================================================================
3   !!                       ***  MODULE  traadv  ***
4   !! Ocean active tracers:  advection trend
5   !!==============================================================================
6   !! History :  2.0  !  2005-11  (G. Madec)  Original code
7   !!            3.3  !  2010-09  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
8   !!            4.0  !  2011-06  (G. Madec)  Addition of Mixed Layer Eddy parameterisation
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   tra_adv      : compute ocean tracer advection trend
13   !!   tra_adv_ctl  : control the different options of advection scheme
14   !!----------------------------------------------------------------------
15   USE oce             ! ocean dynamics and active tracers
16   USE dom_oce         ! ocean space and time domain
17   USE domvvl          ! variable vertical scale factors
18   USE traadv_cen2     ! 2nd order centered scheme (tra_adv_cen2   routine)
19   USE traadv_tvd      ! TVD      scheme           (tra_adv_tvd    routine)
20   USE traadv_muscl    ! MUSCL    scheme           (tra_adv_muscl  routine)
21   USE traadv_muscl2   ! MUSCL2   scheme           (tra_adv_muscl2 routine)
22   USE traadv_ubs      ! UBS      scheme           (tra_adv_ubs    routine)
23   USE traadv_qck      ! QUICKEST scheme           (tra_adv_qck    routine)
24   USE traadv_eiv      ! eddy induced velocity     (tra_adv_eiv    routine)
25   USE traadv_mle      ! ML eddy induced velocity  (tra_adv_mle    routine)
26   USE cla             ! cross land advection      (cla_traadv     routine)
27   USE ldftra_oce      ! lateral diffusion coefficient on tracers
28   !
29   USE in_out_manager  ! I/O manager
30   USE iom             ! I/O module
31   USE prtctl          ! Print control
32   USE lib_mpp         ! MPP library
33   USE wrk_nemo        ! Memory Allocation
34   USE timing          ! Timing
35   USE sbc_oce
36   USE diaptr          ! Poleward heat transport
37
38
39   IMPLICIT NONE
40   PRIVATE
41
42   PUBLIC   tra_adv        ! routine called by step module
43   PUBLIC   tra_adv_init   ! routine called by opa module
44
45   !                              !!* Namelist namtra_adv *
46   LOGICAL ::   ln_traadv_cen2     ! 2nd order centered scheme flag
47   LOGICAL ::   ln_traadv_tvd      ! TVD scheme flag
48   LOGICAL ::   ln_traadv_tvd_zts  ! TVD scheme flag with vertical sub time-stepping
49   LOGICAL ::   ln_traadv_muscl    ! MUSCL scheme flag
50   LOGICAL ::   ln_traadv_muscl2   ! MUSCL2 scheme flag
51   LOGICAL ::   ln_traadv_ubs      ! UBS scheme flag
52   LOGICAL ::   ln_traadv_qck      ! QUICKEST scheme flag
53   LOGICAL ::   ln_traadv_msc_ups  ! use upstream scheme within muscl
54
55
56   INTEGER ::   nadv   ! choice of the type of advection scheme
57
58   !! * Substitutions
59#  include "domzgr_substitute.h90"
60#  include "vectopt_loop_substitute.h90"
61   !!----------------------------------------------------------------------
62   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
63   !! $Id$
64   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
65   !!----------------------------------------------------------------------
66CONTAINS
67
68   SUBROUTINE tra_adv( kt )
69      !!----------------------------------------------------------------------
70      !!                  ***  ROUTINE tra_adv  ***
71      !!
72      !! ** Purpose :   compute the ocean tracer advection trend.
73      !!
74      !! ** Method  : - Update (ua,va) with the advection term following nadv
75      !!----------------------------------------------------------------------
76      !
77      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
78      !
79      INTEGER ::   jk   ! dummy loop index
80      REAL(wp), POINTER, DIMENSION(:,:,:) :: zun, zvn, zwn
81      !!----------------------------------------------------------------------
82      !
83      IF( nn_timing == 1 )  CALL timing_start('tra_adv')
84      !
85      CALL wrk_alloc( jpi, jpj, jpk, zun, zvn, zwn )
86      !                                          ! set time step
87      IF( neuler == 0 .AND. kt == nit000 ) THEN     ! at nit000
88         r2dtra(:) =  rdttra(:)                          ! = rdtra (restarting with Euler time stepping)
89      ELSEIF( kt <= nit000 + 1) THEN                ! at nit000 or nit000+1
90         r2dtra(:) = 2._wp * rdttra(:)                   ! = 2 rdttra (leapfrog)
91      ENDIF
92      !
93      IF( nn_cla == 1 .AND. cp_cfg == 'orca' .AND. jp_cfg == 2 )   CALL cla_traadv( kt )       !==  Cross Land Advection  ==! (hor. advection)
94      !
95      !                                               !==  effective transport  ==!
96      DO jk = 1, jpkm1
97         zun(:,:,jk) = e2u(:,:) * fse3u(:,:,jk) * un(:,:,jk)                  ! eulerian transport only
98         zvn(:,:,jk) = e1v(:,:) * fse3v(:,:,jk) * vn(:,:,jk)
99         zwn(:,:,jk) = e1t(:,:) * e2t(:,:)      * wn(:,:,jk)
100      END DO
101      !
102      IF( ln_vvl_ztilde .OR. ln_vvl_layer ) THEN
103         zun(:,:,:) = zun(:,:,:) + un_td(:,:,:)
104         zvn(:,:,:) = zvn(:,:,:) + vn_td(:,:,:)
105      ENDIF
106      !
107      zun(:,:,jpk) = 0._wp                                                     ! no transport trough the bottom
108      zvn(:,:,jpk) = 0._wp                                                     ! no transport trough the bottom
109      zwn(:,:,jpk) = 0._wp                                                     ! no transport trough the bottom
110      !
111      IF( lk_traldf_eiv .AND. .NOT. ln_traldf_grif )   &
112         &              CALL tra_adv_eiv( kt, nit000, zun, zvn, zwn, 'TRA' )    ! add the eiv transport (if necessary)
113      !
114      IF( ln_mle    )   CALL tra_adv_mle( kt, nit000, zun, zvn, zwn, 'TRA' )    ! add the mle transport (if necessary)
115      !
116      CALL iom_put( "uocetr_eff", zun )                                         ! output effective transport     
117      CALL iom_put( "vocetr_eff", zvn )
118      CALL iom_put( "wocetr_eff", zwn )
119      !
120      IF( ln_diaptr )   CALL dia_ptr( zvn )                                     ! diagnose the effective MSF
121      !
122   
123      SELECT CASE ( nadv )                            !==  compute advection trend and add it to general trend  ==!
124      CASE ( 1 )   ;    CALL tra_adv_cen2   ( kt, nit000, 'TRA',         zun, zvn, zwn, tsb, tsn, tsa, jpts )   !  2nd order centered
125      CASE ( 2 )   ;    CALL tra_adv_tvd    ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )   !  TVD
126      CASE ( 3 )   ;    CALL tra_adv_muscl  ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb,      tsa, jpts, ln_traadv_msc_ups )   !  MUSCL
127      CASE ( 4 )   ;    CALL tra_adv_muscl2 ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )   !  MUSCL2
128      CASE ( 5 )   ;    CALL tra_adv_ubs    ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )   !  UBS
129      CASE ( 6 )   ;    CALL tra_adv_qck    ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )   !  QUICKEST
130      CASE ( 7 )   ;    CALL tra_adv_tvd_zts( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )   !  TVD ZTS
131      !
132      CASE (-1 )                                      !==  esopa: test all possibility with control print  ==!
133         CALL tra_adv_cen2  ( kt, nit000, 'TRA',         zun, zvn, zwn, tsb, tsn, tsa, jpts )         
134         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv0 - Ta: ', mask1=tmask,               &
135            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
136         CALL tra_adv_tvd   ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )         
137         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv1 - Ta: ', mask1=tmask,               &
138            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
139         CALL tra_adv_muscl ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb,      tsa, jpts, ln_traadv_msc_ups )         
140         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv3 - Ta: ', mask1=tmask,               &
141            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
142         CALL tra_adv_muscl2( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )         
143         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv4 - Ta: ', mask1=tmask,               &
144            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
145         CALL tra_adv_ubs   ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )         
146         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv5 - Ta: ', mask1=tmask,               &
147            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
148         CALL tra_adv_qck   ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )         
149         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv6 - Ta: ', mask1=tmask,               &
150            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
151      END SELECT
152      !
153      !                                              ! print mean trends (used for debugging)
154      IF(ln_ctl)   CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv  - Ta: ', mask1=tmask,               &
155         &                       tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
156      !
157      IF( nn_timing == 1 )  CALL timing_stop( 'tra_adv' )
158      !
159      CALL wrk_dealloc( jpi, jpj, jpk, zun, zvn, zwn )
160      !                                         
161   END SUBROUTINE tra_adv
162
163
164   SUBROUTINE tra_adv_init
165      !!---------------------------------------------------------------------
166      !!                  ***  ROUTINE tra_adv_init  ***
167      !!               
168      !! ** Purpose :   Control the consistency between namelist options for
169      !!              tracer advection schemes and set nadv
170      !!----------------------------------------------------------------------
171      INTEGER ::   ioptio
172      INTEGER ::   ios                 ! Local integer output status for namelist read
173      !!
174      NAMELIST/namtra_adv/ ln_traadv_cen2 , ln_traadv_tvd,     &
175         &                 ln_traadv_muscl, ln_traadv_muscl2,  &
176         &                 ln_traadv_ubs  , ln_traadv_qck,     &
177         &                 ln_traadv_msc_ups, ln_traadv_tvd_zts
178      !!----------------------------------------------------------------------
179
180      REWIND( numnam_ref )              ! Namelist namtra_adv in reference namelist : Tracer advection scheme
181      READ  ( numnam_ref, namtra_adv, IOSTAT = ios, ERR = 901)
182901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_adv in reference namelist', lwp )
183
184      REWIND( numnam_cfg )              ! Namelist namtra_adv in configuration namelist : Tracer advection scheme
185      READ  ( numnam_cfg, namtra_adv, IOSTAT = ios, ERR = 902 )
186902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_adv in configuration namelist', lwp )
187      IF(lwm) WRITE ( numond, namtra_adv )
188
189      IF(lwp) THEN                    ! Namelist print
190         WRITE(numout,*)
191         WRITE(numout,*) 'tra_adv_init : choice/control of the tracer advection scheme'
192         WRITE(numout,*) '~~~~~~~~~~~'
193         WRITE(numout,*) '   Namelist namtra_adv : chose a advection scheme for tracers'
194         WRITE(numout,*) '      2nd order advection scheme     ln_traadv_cen2    = ', ln_traadv_cen2
195         WRITE(numout,*) '      TVD advection scheme           ln_traadv_tvd     = ', ln_traadv_tvd
196         WRITE(numout,*) '      MUSCL  advection scheme        ln_traadv_muscl   = ', ln_traadv_muscl
197         WRITE(numout,*) '      MUSCL2 advection scheme        ln_traadv_muscl2  = ', ln_traadv_muscl2
198         WRITE(numout,*) '      UBS    advection scheme        ln_traadv_ubs     = ', ln_traadv_ubs
199         WRITE(numout,*) '      QUICKEST advection scheme      ln_traadv_qck     = ', ln_traadv_qck
200         WRITE(numout,*) '      upstream scheme within muscl   ln_traadv_msc_ups = ', ln_traadv_msc_ups
201         WRITE(numout,*) '      TVD advection scheme with zts  ln_traadv_tvd_zts = ', ln_traadv_tvd_zts
202      ENDIF
203
204      ioptio = 0                      ! Parameter control
205      IF( ln_traadv_cen2   )   ioptio = ioptio + 1
206      IF( ln_traadv_tvd    )   ioptio = ioptio + 1
207      IF( ln_traadv_muscl  )   ioptio = ioptio + 1
208      IF( ln_traadv_muscl2 )   ioptio = ioptio + 1
209      IF( ln_traadv_ubs    )   ioptio = ioptio + 1
210      IF( ln_traadv_qck    )   ioptio = ioptio + 1
211      IF( ln_traadv_tvd_zts)   ioptio = ioptio + 1
212      IF( lk_esopa         )   ioptio =          1
213
214      IF( ( ln_traadv_muscl .OR. ln_traadv_muscl2 .OR. ln_traadv_ubs .OR. ln_traadv_qck .OR. ln_traadv_tvd_zts )   &
215         .AND. ln_isfcav )   CALL ctl_stop( 'Only traadv_cen2 and traadv_tvd is compatible with ice shelf cavity')
216
217      IF( ioptio /= 1 )   CALL ctl_stop( 'Choose ONE advection scheme in namelist namtra_adv' )
218
219      !                              ! Set nadv
220      IF( ln_traadv_cen2   )   nadv =  1
221      IF( ln_traadv_tvd    )   nadv =  2
222      IF( ln_traadv_muscl  )   nadv =  3
223      IF( ln_traadv_muscl2 )   nadv =  4
224      IF( ln_traadv_ubs    )   nadv =  5
225      IF( ln_traadv_qck    )   nadv =  6
226      IF( ln_traadv_tvd_zts)   nadv =  7
227      IF( lk_esopa         )   nadv = -1
228
229      IF(lwp) THEN                   ! Print the choice
230         WRITE(numout,*)
231         IF( nadv ==  1 )   WRITE(numout,*) '         2nd order scheme is used'
232         IF( nadv ==  2 )   WRITE(numout,*) '         TVD       scheme is used'
233         IF( nadv ==  3 )   WRITE(numout,*) '         MUSCL     scheme is used'
234         IF( nadv ==  4 )   WRITE(numout,*) '         MUSCL2    scheme is used'
235         IF( nadv ==  5 )   WRITE(numout,*) '         UBS       scheme is used'
236         IF( nadv ==  6 )   WRITE(numout,*) '         QUICKEST  scheme is used'
237         IF( nadv ==  7 )   WRITE(numout,*) '         TVD ZTS   scheme is used'
238         IF( nadv == -1 )   WRITE(numout,*) '         esopa test: use all advection scheme'
239      ENDIF
240      !
241      CALL tra_adv_mle_init          ! initialisation of the Mixed Layer Eddy parametrisation (MLE)
242      !
243   END SUBROUTINE tra_adv_init
244
245  !!======================================================================
246END MODULE traadv
Note: See TracBrowser for help on using the repository browser.