source: branches/UKMO/r6232_tracer_advection/NEMOGCM/NEMO/OPA_SRC/TRA/traldf_iso_grif.F90 @ 9295

Last change on this file since 9295 was 9295, checked in by jcastill, 3 years ago

Remove svn keywords

File size: 22.9 KB
Line 
1MODULE traldf_iso_grif
2   !!======================================================================
3   !!                   ***  MODULE  traldf_iso_grif  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!======================================================================
6   !! History : 3.3  ! 2010-10  (G. Nurser, C. Harris, G. Madec)
7   !!                !          Griffies operator version adapted from traldf_iso.F90
8   !!----------------------------------------------------------------------
9#if   defined key_ldfslp   ||   defined key_esopa
10   !!----------------------------------------------------------------------
11   !!   'key_ldfslp'               slope of the lateral diffusive direction
12   !!----------------------------------------------------------------------
13   !!   tra_ldf_iso_grif  : update the tracer trend with the horizontal component
14   !!                       of the Griffies iso-neutral laplacian operator
15   !!----------------------------------------------------------------------
16   USE oce             ! ocean dynamics and active tracers
17   USE dom_oce         ! ocean space and time domain
18   USE phycst          ! physical constants
19   USE trc_oce         ! share passive tracers/Ocean variables
20   USE zdf_oce         ! ocean vertical physics
21   USE ldftra_oce      ! ocean active tracers: lateral physics
22   USE ldfslp          ! iso-neutral slopes
23   USE diaptr          ! poleward transport diagnostics
24   USE in_out_manager  ! I/O manager
25   USE iom             ! I/O library
26   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
27   USE lib_mpp         ! MPP library
28   USE wrk_nemo        ! Memory Allocation
29   USE timing          ! Timing
30
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   tra_ldf_iso_grif   ! routine called by traldf.F90
36
37   REAL(wp), PUBLIC, DIMENSION(:,:,:), ALLOCATABLE, SAVE ::   psix_eiv, psiy_eiv   !: eiv stream function (diag only)
38   REAL(wp), PUBLIC, DIMENSION(:,:,:), ALLOCATABLE, SAVE ::   ah_wslp2             !: aeiv*w-slope^2
39   REAL(wp),         DIMENSION(:,:,:), ALLOCATABLE, SAVE ::   zdkt3d               !: vertical tracer gradient at 2 levels
40
41   !! * Substitutions
42#  include "domzgr_substitute.h90"
43#  include "ldftra_substitute.h90"
44#  include "vectopt_loop_substitute.h90"
45#  include "ldfeiv_substitute.h90"
46   !!----------------------------------------------------------------------
47   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
48   !! $Id$
49   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
50   !!----------------------------------------------------------------------
51CONTAINS
52
53  SUBROUTINE tra_ldf_iso_grif( kt, kit000, cdtype, pgu, pgv,              &
54       &                                   ptb, pta, kjpt, pahtb0 )
55      !!----------------------------------------------------------------------
56      !!                  ***  ROUTINE tra_ldf_iso_grif  ***
57      !!
58      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
59      !!      trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and
60      !!      add it to the general trend of tracer equation.
61      !!
62      !! ** Method  :   The horizontal component of the lateral diffusive trends
63      !!      is provided by a 2nd order operator rotated along neural or geopo-
64      !!      tential surfaces to which an eddy induced advection can be added
65      !!      It is computed using before fields (forward in time) and isopyc-
66      !!      nal or geopotential slopes computed in routine ldfslp.
67      !!
68      !!      1st part :  masked horizontal derivative of T  ( di[ t ] )
69      !!      ========    with partial cell update if ln_zps=T.
70      !!
71      !!      2nd part :  horizontal fluxes of the lateral mixing operator
72      !!      ========
73      !!         zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ]
74      !!               - aht       e2u*uslp    dk[ mi(mk(tb)) ]
75      !!         zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ]
76      !!               - aht       e2u*vslp    dk[ mj(mk(tb)) ]
77      !!      take the horizontal divergence of the fluxes:
78      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
79      !!      Add this trend to the general trend (ta,sa):
80      !!         ta = ta + difft
81      !!
82      !!      3rd part: vertical trends of the lateral mixing operator
83      !!      ========  (excluding the vertical flux proportional to dk[t] )
84      !!      vertical fluxes associated with the rotated lateral mixing:
85      !!         zftw =-aht {  e2t*wslpi di[ mi(mk(tb)) ]
86      !!                     + e1t*wslpj dj[ mj(mk(tb)) ]  }
87      !!      take the horizontal divergence of the fluxes:
88      !!         difft = 1/(e1t*e2t*e3t) dk[ zftw ]
89      !!      Add this trend to the general trend (ta,sa):
90      !!         pta = pta + difft
91      !!
92      !! ** Action :   Update pta arrays with the before rotated diffusion
93      !!----------------------------------------------------------------------
94      USE oce     , ONLY:   zftu => ua       , zftv => va            ! (ua,va) used as 3D workspace
95      !
96      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
97      INTEGER                              , INTENT(in   ) ::   kit000     ! first time step index
98      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
99      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
100      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
101      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! before and now tracer fields
102      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
103      REAL(wp)                             , INTENT(in   ) ::   pahtb0     ! background diffusion coef
104      !
105      INTEGER  ::  ji, jj, jk,jn   ! dummy loop indices
106      INTEGER  ::  ip,jp,kp        ! dummy loop indices
107      INTEGER  ::  ierr            ! temporary integer
108      REAL(wp) ::  zmsku, zabe1, zcof1, zcoef3   ! local scalars
109      REAL(wp) ::  zmskv, zabe2, zcof2, zcoef4   !   -      -
110      REAL(wp) ::  zcoef0, zbtr                  !   -      -
111      !
112      REAL(wp) ::   zslope_skew, zslope_iso, zslope2, zbu, zbv
113      REAL(wp) ::   ze1ur, zdxt, ze2vr, ze3wr, zdyt, zdzt
114      REAL(wp) ::   zah, zah_slp, zaei_slp
115      REAL(wp), POINTER, DIMENSION(:,:  ) :: z2d
116      REAL(wp), POINTER, DIMENSION(:,:,:) :: zdit, zdjt, ztfw 
117      REAL(wp), POINTER, DIMENSION(:,:,:) :: zw3d       ! 3D workspace
118      !!----------------------------------------------------------------------
119      !
120      IF( nn_timing == 1 )  CALL timing_start('tra_ldf_iso_grif')
121      !
122      CALL wrk_alloc( jpi, jpj,      z2d ) 
123      CALL wrk_alloc( jpi, jpj, jpk, zdit, zdjt, ztfw  ) 
124      !
125
126      IF( kt == kit000 .AND. .NOT.ALLOCATED(ah_wslp2) )  THEN
127         IF(lwp) WRITE(numout,*)
128         IF(lwp) WRITE(numout,*) 'tra_ldf_iso_grif : rotated laplacian diffusion operator on ', cdtype
129         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
130         ALLOCATE( ah_wslp2(jpi,jpj,jpk) , zdkt3d(jpi,jpj,0:1), STAT=ierr )
131         IF( lk_mpp   )   CALL mpp_sum ( ierr )
132         IF( ierr > 0 )   CALL ctl_stop('STOP', 'tra_ldf_iso_grif: unable to allocate arrays')
133         IF( ln_traldf_gdia ) THEN
134            IF (.NOT. ALLOCATED(psix_eiv))THEN
135                ALLOCATE( psix_eiv(jpi,jpj,jpk) , psiy_eiv(jpi,jpj,jpk) , STAT=ierr )
136                IF( lk_mpp   )   CALL mpp_sum ( ierr )
137                IF( ierr > 0 )   CALL ctl_stop('STOP', 'tra_ldf_iso_grif: unable to allocate diagnostics')
138            ENDIF
139         ENDIF
140      ENDIF
141
142      !!----------------------------------------------------------------------
143      !!   0 - calculate  ah_wslp2, psix_eiv, psiy_eiv
144      !!----------------------------------------------------------------------
145
146      !!gm Future development: consider using Ah defined at T-points and attached to the 4 t-point triads
147
148      ah_wslp2(:,:,:) = 0._wp
149      IF( ln_traldf_gdia ) THEN
150         psix_eiv(:,:,:) = 0._wp
151         psiy_eiv(:,:,:) = 0._wp
152      ENDIF
153
154      DO ip = 0, 1
155         DO kp = 0, 1
156            DO jk = 1, jpkm1
157               DO jj = 1, jpjm1
158                  DO ji = 1, fs_jpim1
159                     ze1ur = 1._wp / e1u(ji,jj)
160                     ze3wr = 1._wp / fse3w(ji+ip,jj,jk+kp)
161                     zbu   = 0.25_wp * e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk)
162                     zah   = fsahtu(ji,jj,jk)                                  ! fsaht(ji+ip,jj,jk)
163                     zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp)
164                     ! Subtract s-coordinate slope at t-points to give slope rel to s surfaces
165                     ! (do this by *adding* gradient of depth)
166                     zslope2 = zslope_skew + ( fsdept(ji+1,jj,jk) - fsdept(ji ,jj ,jk) ) * ze1ur * umask(ji,jj,jk+kp)
167                     zslope2 = zslope2 *zslope2
168                     ah_wslp2(ji+ip,jj,jk+kp) = ah_wslp2(ji+ip,jj,jk+kp)    &
169                        &                     + zah * ( zbu * ze3wr / ( e1t(ji+ip,jj) * e2t(ji+ip,jj) ) ) * zslope2
170                     IF( ln_traldf_gdia ) THEN
171                        zaei_slp = fsaeiw(ji+ip,jj,jk) * zslope_skew           ! fsaeit(ji+ip,jj,jk)*zslope_skew
172                        psix_eiv(ji,jj,jk+kp) = psix_eiv(ji,jj,jk+kp) + 0.25_wp * zaei_slp
173                     ENDIF
174                  END DO
175               END DO
176            END DO
177         END DO
178      END DO
179      !
180      DO jp = 0, 1
181         DO kp = 0, 1
182            DO jk = 1, jpkm1
183               DO jj = 1, jpjm1
184                  DO ji=1,fs_jpim1
185                     ze2vr = 1._wp / e2v(ji,jj)
186                     ze3wr = 1.0_wp / fse3w(ji,jj+jp,jk+kp)
187                     zbv   = 0.25_wp * e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk)
188                     zah   = fsahtv(ji,jj,jk)                                  ! fsaht(ji,jj+jp,jk)
189                     zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp)
190                     ! Subtract s-coordinate slope at t-points to give slope rel to s surfaces
191                     !    (do this by *adding* gradient of depth)
192                     zslope2 = zslope_skew + ( fsdept(ji,jj+1,jk) - fsdept(ji,jj,jk) ) * ze2vr * vmask(ji,jj,jk+kp)
193                     zslope2 = zslope2 * zslope2
194                     ah_wslp2(ji,jj+jp,jk+kp) = ah_wslp2(ji,jj+jp,jk+kp)   &
195                        &                     + zah * ( zbv * ze3wr / ( e1t(ji,jj+jp) * e2t(ji,jj+jp) ) ) * zslope2
196                     IF( ln_traldf_gdia ) THEN
197                        zaei_slp = fsaeiw(ji,jj+jp,jk) * zslope_skew           ! fsaeit(ji,jj+jp,jk)*zslope_skew
198                        psiy_eiv(ji,jj,jk+kp) = psiy_eiv(ji,jj,jk+kp) + 0.25_wp * zaei_slp
199                     ENDIF
200                  END DO
201               END DO
202            END DO
203         END DO
204      END DO
205      !
206      IF( iom_use("uoce_eiv") .OR. iom_use("voce_eiv") .OR. iom_use("woce_eiv") )  THEN
207         !
208         IF( ln_traldf_gdia .AND. cdtype == 'TRA' ) THEN
209            CALL wrk_alloc( jpi , jpj , jpk  , zw3d )
210            DO jk=1,jpkm1
211               zw3d(:,:,jk) = (psix_eiv(:,:,jk+1) - psix_eiv(:,:,jk))/fse3u(:,:,jk)  ! u_eiv = -dpsix/dz
212            END DO
213            zw3d(:,:,jpk) = 0._wp
214            CALL iom_put( "uoce_eiv", zw3d )    ! i-eiv current
215
216            DO jk=1,jpk-1
217               zw3d(:,:,jk) = (psiy_eiv(:,:,jk+1) - psiy_eiv(:,:,jk))/fse3v(:,:,jk)  ! v_eiv = -dpsiy/dz
218            END DO
219            zw3d(:,:,jpk) = 0._wp
220            CALL iom_put( "voce_eiv", zw3d )    ! j-eiv current
221
222            DO jk=1,jpk-1
223               DO jj = 2, jpjm1
224                  DO ji = fs_2, fs_jpim1  ! vector opt.
225                     zw3d(ji,jj,jk) = (psiy_eiv(ji,jj,jk) - psiy_eiv(ji,jj-1,jk))/e2t(ji,jj) + &
226                          &    (psix_eiv(ji,jj,jk) - psix_eiv(ji-1,jj,jk))/e1t(ji,jj) ! w_eiv = dpsiy/dy + dpsiy/dx
227                  END DO
228               END DO
229            END DO
230            zw3d(:,:,jpk) = 0._wp
231            CALL iom_put( "woce_eiv", zw3d )    ! vert. eiv current
232            CALL wrk_dealloc( jpi , jpj , jpk  , zw3d )
233         ENDIF
234         !
235      ENDIF
236      !                                                          ! ===========
237      DO jn = 1, kjpt                                            ! tracer loop
238         !                                                       ! ===========
239         ! Zero fluxes for each tracer
240         ztfw(:,:,:) = 0._wp
241         zftu(:,:,:) = 0._wp
242         zftv(:,:,:) = 0._wp
243         !
244         DO jk = 1, jpkm1                          !==  before lateral T & S gradients at T-level jk  ==!
245            DO jj = 1, jpjm1
246               DO ji = 1, fs_jpim1   ! vector opt.
247                  zdit(ji,jj,jk) = ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) ) * umask(ji,jj,jk)
248                  zdjt(ji,jj,jk) = ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
249               END DO
250            END DO
251         END DO
252         IF( ln_zps.and.l_grad_zps ) THEN              ! partial steps: correction at the last level
253            DO jj = 1, jpjm1
254               DO ji = 1, jpim1
255                  zdit(ji,jj,mbku(ji,jj)) = pgu(ji,jj,jn)
256                  zdjt(ji,jj,mbkv(ji,jj)) = pgv(ji,jj,jn)
257               END DO
258            END DO
259         ENDIF
260
261         !!----------------------------------------------------------------------
262         !!   II - horizontal trend  (full)
263         !!----------------------------------------------------------------------
264         !
265         DO jk = 1, jpkm1
266            !
267            !                    !==  Vertical tracer gradient at level jk and jk+1
268            zdkt3d(:,:,1) = ( ptb(:,:,jk,jn) - ptb(:,:,jk+1,jn) ) * tmask(:,:,jk+1)
269            !
270            !                    ! surface boundary condition: zdkt3d(jk=0)=zdkt3d(jk=1)
271            IF( jk == 1 ) THEN   ;   zdkt3d(:,:,0) = zdkt3d(:,:,1)
272            ELSE                 ;   zdkt3d(:,:,0) = ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) ) * tmask(:,:,jk)
273            ENDIF
274
275
276            IF (ln_botmix_grif) THEN
277               DO ip = 0, 1              !==  Horizontal & vertical fluxes
278                  DO kp = 0, 1
279                     DO jj = 1, jpjm1
280                        DO ji = 1, fs_jpim1
281                           ze1ur = 1._wp / e1u(ji,jj)
282                           zdxt  = zdit(ji,jj,jk) * ze1ur
283                           ze3wr = 1._wp / fse3w(ji+ip,jj,jk+kp)
284                           zdzt  = zdkt3d(ji+ip,jj,kp) * ze3wr
285                           zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp)
286                           zslope_iso  = triadi(ji+ip,jj,jk,1-ip,kp)
287
288                           zbu = 0.25_wp * e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk)
289                           ! ln_botmix_grif is .T. don't mask zah for bottom half cells
290                           zah = fsahtu(ji,jj,jk)   !*umask(ji,jj,jk+kp)         !fsaht(ji+ip,jj,jk)           ===>>  ????
291                           zah_slp  = zah * zslope_iso
292                           zaei_slp = fsaeiw(ji+ip,jj,jk) * zslope_skew    !fsaeit(ji+ip,jj,jk)*zslope_skew
293                           zftu(ji,jj,jk) = zftu(ji,jj,jk) - ( zah * zdxt + (zah_slp - zaei_slp) * zdzt ) * zbu * ze1ur
294                           ztfw(ji+ip,jj,jk+kp) = ztfw(ji+ip,jj,jk+kp) - (zah_slp + zaei_slp) * zdxt * zbu * ze3wr
295                        END DO
296                     END DO
297                  END DO
298               END DO
299
300               DO jp = 0, 1
301                  DO kp = 0, 1
302                     DO jj = 1, jpjm1
303                        DO ji = 1, fs_jpim1
304                           ze2vr = 1._wp / e2v(ji,jj)
305                           zdyt  = zdjt(ji,jj,jk) * ze2vr
306                           ze3wr = 1._wp / fse3w(ji,jj+jp,jk+kp)
307                           zdzt  = zdkt3d(ji,jj+jp,kp) * ze3wr
308                           zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp)
309                           zslope_iso  = triadj(ji,jj+jp,jk,1-jp,kp)
310                           zbv = 0.25_wp * e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk)
311                           ! ln_botmix_grif is .T. don't mask zah for bottom half cells
312                           zah = fsahtv(ji,jj,jk)        !*vmask(ji,jj,jk+kp)  ! fsaht(ji,jj+jp,jk)
313                           zah_slp = zah * zslope_iso
314                           zaei_slp = fsaeiw(ji,jj+jp,jk) * zslope_skew        ! fsaeit(ji,jj+jp,jk)*zslope_skew
315                           zftv(ji,jj,jk) = zftv(ji,jj,jk) - ( zah * zdyt + (zah_slp - zaei_slp) * zdzt ) * zbv * ze2vr
316                           ztfw(ji,jj+jp,jk+kp) = ztfw(ji,jj+jp,jk+kp) - (zah_slp + zaei_slp) * zdyt * zbv * ze3wr
317                        END DO
318                     END DO
319                  END DO
320               END DO
321            ELSE
322               DO ip = 0, 1              !==  Horizontal & vertical fluxes
323                  DO kp = 0, 1
324                     DO jj = 1, jpjm1
325                        DO ji = 1, fs_jpim1
326                           ze1ur = 1._wp / e1u(ji,jj)
327                           zdxt  = zdit(ji,jj,jk) * ze1ur
328                           ze3wr = 1._wp / fse3w(ji+ip,jj,jk+kp)
329                           zdzt  = zdkt3d(ji+ip,jj,kp) * ze3wr
330                           zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp)
331                           zslope_iso  = triadi(ji+ip,jj,jk,1-ip,kp)
332
333                           zbu = 0.25_wp * e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk)
334                           ! ln_botmix_grif is .F. mask zah for bottom half cells
335                           zah = fsahtu(ji,jj,jk) * umask(ji,jj,jk+kp)         ! fsaht(ji+ip,jj,jk)   ===>>  ????
336                           zah_slp  = zah * zslope_iso
337                           zaei_slp = fsaeiw(ji+ip,jj,jk) * zslope_skew        ! fsaeit(ji+ip,jj,jk)*zslope_skew
338                           zftu(ji,jj,jk) = zftu(ji,jj,jk) - ( zah * zdxt + (zah_slp - zaei_slp) * zdzt ) * zbu * ze1ur
339                           ztfw(ji+ip,jj,jk+kp) = ztfw(ji+ip,jj,jk+kp) - (zah_slp + zaei_slp) * zdxt * zbu * ze3wr
340                        END DO
341                     END DO
342                  END DO
343               END DO
344
345               DO jp = 0, 1
346                  DO kp = 0, 1
347                     DO jj = 1, jpjm1
348                        DO ji = 1, fs_jpim1
349                           ze2vr = 1._wp / e2v(ji,jj)
350                           zdyt  = zdjt(ji,jj,jk) * ze2vr
351                           ze3wr = 1._wp / fse3w(ji,jj+jp,jk+kp)
352                           zdzt  = zdkt3d(ji,jj+jp,kp) * ze3wr
353                           zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp)
354                           zslope_iso  = triadj(ji,jj+jp,jk,1-jp,kp)
355                           zbv = 0.25_wp * e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk)
356                           ! ln_botmix_grif is .F. mask zah for bottom half cells
357                           zah = fsahtv(ji,jj,jk) * vmask(ji,jj,jk+kp)         ! fsaht(ji,jj+jp,jk)
358                           zah_slp = zah * zslope_iso
359                           zaei_slp = fsaeiw(ji,jj+jp,jk) * zslope_skew        ! fsaeit(ji,jj+jp,jk)*zslope_skew
360                           zftv(ji,jj,jk) = zftv(ji,jj,jk) - ( zah * zdyt + (zah_slp - zaei_slp) * zdzt ) * zbv * ze2vr
361                           ztfw(ji,jj+jp,jk+kp) = ztfw(ji,jj+jp,jk+kp) - (zah_slp + zaei_slp) * zdyt * zbv * ze3wr
362                        END DO
363                     END DO
364                  END DO
365               END DO
366            END IF
367            !                          !==  divergence and add to the general trend  ==!
368            DO jj = 2 , jpjm1
369               DO ji = fs_2, fs_jpim1  ! vector opt.
370                  zbtr = 1._wp / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
371                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + zbtr * (   zftu(ji-1,jj,jk) - zftu(ji,jj,jk)   &
372                     &                                           + zftv(ji,jj-1,jk) - zftv(ji,jj,jk)   )
373               END DO
374            END DO
375            !
376         END DO
377         !
378         DO jk = 1, jpkm1              !== Divergence of vertical fluxes added to the general tracer trend
379            DO jj = 2, jpjm1
380               DO ji = fs_2, fs_jpim1  ! vector opt.
381                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + (  ztfw(ji,jj,jk+1) - ztfw(ji,jj,jk)  )   &
382                     &                                / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
383               END DO
384            END DO
385         END DO
386         !
387         !                             ! "Poleward" diffusive heat or salt transports (T-S case only)
388         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN
389            IF( jn == jp_tem)   htr_ldf(:) = ptr_sj( zftv(:,:,:) )        ! 3.3  names
390            IF( jn == jp_sal)   str_ldf(:) = ptr_sj( zftv(:,:,:) )
391         ENDIF
392
393         IF( iom_use("udiff_heattr") .OR. iom_use("vdiff_heattr") ) THEN
394           !
395           IF( cdtype == 'TRA' .AND. jn == jp_tem  ) THEN
396               z2d(:,:) = 0._wp 
397               DO jk = 1, jpkm1
398                  DO jj = 2, jpjm1
399                     DO ji = fs_2, fs_jpim1   ! vector opt.
400                        z2d(ji,jj) = z2d(ji,jj) + zftu(ji,jj,jk) 
401                     END DO
402                  END DO
403               END DO
404               z2d(:,:) = rau0_rcp * z2d(:,:) 
405               CALL lbc_lnk( z2d, 'U', -1. )
406               CALL iom_put( "udiff_heattr", z2d )                  ! heat transport in i-direction
407               !
408               z2d(:,:) = 0._wp 
409               DO jk = 1, jpkm1
410                  DO jj = 2, jpjm1
411                     DO ji = fs_2, fs_jpim1   ! vector opt.
412                        z2d(ji,jj) = z2d(ji,jj) + zftv(ji,jj,jk) 
413                     END DO
414                  END DO
415               END DO
416               z2d(:,:) = rau0_rcp * z2d(:,:)     
417               CALL lbc_lnk( z2d, 'V', -1. )
418               CALL iom_put( "vdiff_heattr", z2d )                  !  heat transport in i-direction
419            END IF
420            !
421         ENDIF
422         !
423      END DO
424      !
425      CALL wrk_dealloc( jpi, jpj,      z2d ) 
426      CALL wrk_dealloc( jpi, jpj, jpk, zdit, zdjt, ztfw  ) 
427      !
428      IF( nn_timing == 1 )  CALL timing_stop('tra_ldf_iso_grif')
429      !
430  END SUBROUTINE tra_ldf_iso_grif
431
432#else
433   !!----------------------------------------------------------------------
434   !!   default option :   Dummy code   NO rotation of the diffusive tensor
435   !!----------------------------------------------------------------------
436   REAL, PUBLIC, DIMENSION(:,:,:), ALLOCATABLE, SAVE ::   psix_eiv, psiy_eiv   !: eiv stream function (diag only)
437CONTAINS
438   SUBROUTINE tra_ldf_iso_grif( kt, kit000, cdtype, pgu, pgv,              &
439       &                                   ptb, pta, kjpt, pahtb0 )
440      CHARACTER(len=3) ::   cdtype
441      INTEGER          ::   kit000     ! first time step index
442      REAL, DIMENSION(:,:,:) ::   pgu, pgv   ! tracer gradient at pstep levels
443      REAL, DIMENSION(:,:,:,:) ::   ptb, pta
444      WRITE(*,*) 'tra_ldf_iso_grif: You should not have seen this print! error?', kt, cdtype,    &
445         &                  pgu(1,1,1), pgv(1,1,1), ptb(1,1,1,1), pta(1,1,1,1), kjpt, pahtb0
446   END SUBROUTINE tra_ldf_iso_grif
447#endif
448
449   !!==============================================================================
450END MODULE traldf_iso_grif
Note: See TracBrowser for help on using the repository browser.