source: branches/UKMO/r6232_tracer_advection/NEMOGCM/NEMO/OPA_SRC/ZDF/zdfevd.F90 @ 9295

Last change on this file since 9295 was 9295, checked in by jcastill, 3 years ago

Remove svn keywords

File size: 5.9 KB
Line 
1MODULE zdfevd
2   !!======================================================================
3   !!                       ***  MODULE  zdfevd  ***
4   !! Ocean physics: parameterization of convection through an enhancement
5   !!                of vertical eddy mixing coefficient
6   !!======================================================================
7   !! History :  OPA  !  1997-06  (G. Madec, A. Lazar)  Original code
8   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
9   !!             -   !  2005-06  (C. Ethe) KPP parameterization
10   !!            3.2  !  2009-03  (M. Leclair, G. Madec, R. Benshila) test on both before & after
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   zdf_evd      : increase the momentum and tracer Kz at the location of
15   !!                  statically unstable portion of the water column (ln_zdfevd=T)
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean dynamics and tracers variables
18   USE dom_oce         ! ocean space and time domain variables
19   USE zdf_oce         ! ocean vertical physics variables
20   USE zdfkpp          ! KPP vertical mixing
21   USE in_out_manager  ! I/O manager
22   USE iom             ! for iom_put
23   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
24   USE timing          ! Timing
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   zdf_evd    ! called by step.F90
30
31   !! * Substitutions
32#  include "domzgr_substitute.h90"
33   !!----------------------------------------------------------------------
34   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
35   !! $Id$
36   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
37   !!----------------------------------------------------------------------
38CONTAINS
39
40   SUBROUTINE zdf_evd( kt )
41      !!----------------------------------------------------------------------
42      !!                  ***  ROUTINE zdf_evd  ***
43      !!                   
44      !! ** Purpose :   Local increased the vertical eddy viscosity and diffu-
45      !!      sivity coefficients when a static instability is encountered.
46      !!
47      !! ** Method  :   avt, avm, and the 4 neighbouring avmu, avmv coefficients
48      !!      are set to avevd (namelist parameter) if the water column is
49      !!      statically unstable (i.e. if rn2 < -1.e-12 )
50      !!
51      !! ** Action  :   avt, avm, avmu, avmv updted in static instability cases
52      !!
53      !! References :   Lazar, A., these de l'universite Paris VI, France, 1997
54      !!----------------------------------------------------------------------
55      USE oce,   zavt_evd => ua , zavm_evd => va  ! (ua,va) used ua workspace
56      !
57      INTEGER, INTENT( in ) ::   kt   ! ocean time-step indexocean time step
58      !
59      INTEGER ::   ji, jj, jk   ! dummy loop indices
60      !!----------------------------------------------------------------------
61      !
62      IF( nn_timing == 1 )  CALL timing_start('zdf_evd')
63      !
64      IF( kt == nit000 ) THEN
65         IF(lwp) WRITE(numout,*)
66         IF(lwp) WRITE(numout,*) 'zdf_evd : Enhanced Vertical Diffusion (evd)'
67         IF(lwp) WRITE(numout,*) '~~~~~~~ '
68         IF(lwp) WRITE(numout,*)
69      ENDIF
70
71      zavt_evd(:,:,:) = avt(:,:,:)           ! set avt prior to evd application
72
73      SELECT CASE ( nn_evdm )
74      !
75      CASE ( 1 )           ! enhance vertical eddy viscosity and diffusivity (if rn2<-1.e-12)
76         !
77         zavm_evd(:,:,:) = avm(:,:,:)           ! set avm prior to evd application
78         !
79         DO jk = 1, jpkm1 
80            DO jj = 2, jpj             ! no vector opt.
81               DO ji = 2, jpi
82#if defined key_zdfkpp
83                  ! no evd mixing in the boundary layer with KPP
84                  IF(  MIN( rn2(ji,jj,jk), rn2b(ji,jj,jk) ) <= -1.e-12  .AND.  fsdepw(ji,jj,jk) > hkpp(ji,jj)  ) THEN
85#else
86                  IF(  MIN( rn2(ji,jj,jk), rn2b(ji,jj,jk) ) <= -1.e-12 ) THEN
87#endif
88                     avt (ji  ,jj  ,jk) = rn_avevd * tmask(ji  ,jj  ,jk)
89                     avm (ji  ,jj  ,jk) = rn_avevd * tmask(ji  ,jj  ,jk)
90                     avmu(ji  ,jj  ,jk) = rn_avevd * umask(ji  ,jj  ,jk)
91                     avmu(ji-1,jj  ,jk) = rn_avevd * umask(ji-1,jj  ,jk)
92                     avmv(ji  ,jj  ,jk) = rn_avevd * vmask(ji  ,jj  ,jk)
93                     avmv(ji  ,jj-1,jk) = rn_avevd * vmask(ji  ,jj-1,jk)
94                  ENDIF
95               END DO
96            END DO
97         END DO
98         CALL lbc_lnk( avt , 'W', 1. )   ;   CALL lbc_lnk( avm , 'W', 1. )   ! Lateral boundary conditions
99         CALL lbc_lnk( avmu, 'U', 1. )   ;   CALL lbc_lnk( avmv, 'V', 1. )
100         !
101         zavm_evd(:,:,:) = avm(:,:,:) - zavm_evd(:,:,:)   ! change in avm due to evd
102         CALL iom_put( "avm_evd", zavm_evd )              ! output this change
103         !
104      CASE DEFAULT         ! enhance vertical eddy diffusivity only (if rn2<-1.e-12)
105         DO jk = 1, jpkm1
106!!!         WHERE( rn2(:,:,jk) <= -1.e-12 ) avt(:,:,jk) = tmask(:,:,jk) * avevd   ! agissant sur T SEUL!
107            DO jj = 1, jpj             ! loop over the whole domain (no lbc_lnk call)
108               DO ji = 1, jpi
109#if defined key_zdfkpp
110                  ! no evd mixing in the boundary layer with KPP
111                  IF(  MIN( rn2(ji,jj,jk), rn2b(ji,jj,jk) ) <= -1.e-12  .AND.  fsdepw(ji,jj,jk) > hkpp(ji,jj)  )   &         
112#else
113                  IF(  MIN( rn2(ji,jj,jk), rn2b(ji,jj,jk) ) <= -1.e-12 )   &
114#endif
115                     avt(ji,jj,jk) = rn_avevd * tmask(ji,jj,jk)
116               END DO
117            END DO
118         END DO
119         !
120      END SELECT
121
122      zavt_evd(:,:,:) = avt(:,:,:) - zavt_evd(:,:,:)   ! change in avt due to evd
123      CALL iom_put( "avt_evd", zavt_evd )              ! output this change
124      !
125      IF( nn_timing == 1 )  CALL timing_stop('zdf_evd')
126      !
127   END SUBROUTINE zdf_evd
128
129   !!======================================================================
130END MODULE zdfevd
Note: See TracBrowser for help on using the repository browser.