New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zdfmxl.F90 in branches/UKMO/r6232_tracer_advection/NEMOGCM/NEMO/OPA_SRC/ZDF – NEMO

source: branches/UKMO/r6232_tracer_advection/NEMOGCM/NEMO/OPA_SRC/ZDF/zdfmxl.F90 @ 9295

Last change on this file since 9295 was 9295, checked in by jcastill, 6 years ago

Remove svn keywords

File size: 7.1 KB
Line 
1MODULE zdfmxl
2   !!======================================================================
3   !!                       ***  MODULE  zdfmxl  ***
4   !! Ocean physics: mixed layer depth
5   !!======================================================================
6   !! History :  1.0  ! 2003-08  (G. Madec)  original code
7   !!            3.2  ! 2009-07  (S. Masson, G. Madec)  IOM + merge of DO-loop
8   !!            3.7  ! 2012-03  (G. Madec)  make public the density criteria for trdmxl
9   !!             -   ! 2014-02  (F. Roquet)  mixed layer depth calculated using N2 instead of rhop
10   !!----------------------------------------------------------------------
11   !!   zdf_mxl      : Compute the turbocline and mixed layer depths.
12   !!----------------------------------------------------------------------
13   USE oce             ! ocean dynamics and tracers variables
14   USE dom_oce         ! ocean space and time domain variables
15   USE zdf_oce         ! ocean vertical physics
16   USE in_out_manager  ! I/O manager
17   USE prtctl          ! Print control
18   USE phycst          ! physical constants
19   USE iom             ! I/O library
20   USE lib_mpp         ! MPP library
21   USE wrk_nemo        ! work arrays
22   USE timing          ! Timing
23   USE trc_oce, ONLY : lk_offline ! offline flag
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   zdf_mxl       ! called by step.F90
29   PUBLIC   zdf_mxl_alloc ! Used in zdf_tke_init
30
31   INTEGER , PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   nmln    !: number of level in the mixed layer (used by TOP)
32   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   hmld    !: mixing layer depth (turbocline)      [m]
33   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   hmlp    !: mixed layer depth  (rho=rho0+zdcrit) [m]
34   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) ::   hmlpt   !: mixed layer depth at t-points        [m]
35
36   REAL(wp), PUBLIC ::   rho_c = 0.01_wp    !: density criterion for mixed layer depth
37   REAL(wp)         ::   avt_c = 5.e-4_wp   ! Kz criterion for the turbocline depth
38
39   !! * Substitutions
40#  include "domzgr_substitute.h90"
41   !!----------------------------------------------------------------------
42   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
43   !! $Id$
44   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48   INTEGER FUNCTION zdf_mxl_alloc()
49      !!----------------------------------------------------------------------
50      !!               ***  FUNCTION zdf_mxl_alloc  ***
51      !!----------------------------------------------------------------------
52      zdf_mxl_alloc = 0      ! set to zero if no array to be allocated
53      IF( .NOT. ALLOCATED( nmln ) ) THEN
54         ALLOCATE( nmln(jpi,jpj), hmld(jpi,jpj), hmlp(jpi,jpj), hmlpt(jpi,jpj), STAT= zdf_mxl_alloc )
55         !
56         IF( lk_mpp             )   CALL mpp_sum ( zdf_mxl_alloc )
57         IF( zdf_mxl_alloc /= 0 )   CALL ctl_warn('zdf_mxl_alloc: failed to allocate arrays.')
58         !
59      ENDIF
60   END FUNCTION zdf_mxl_alloc
61
62
63   SUBROUTINE zdf_mxl( kt )
64      !!----------------------------------------------------------------------
65      !!                  ***  ROUTINE zdfmxl  ***
66      !!                   
67      !! ** Purpose :   Compute the turbocline depth and the mixed layer depth
68      !!              with density criteria.
69      !!
70      !! ** Method  :   The mixed layer depth is the shallowest W depth with
71      !!      the density of the corresponding T point (just bellow) bellow a
72      !!      given value defined locally as rho(10m) + rho_c
73      !!               The turbocline depth is the depth at which the vertical
74      !!      eddy diffusivity coefficient (resulting from the vertical physics
75      !!      alone, not the isopycnal part, see trazdf.F) fall below a given
76      !!      value defined locally (avt_c here taken equal to 5 cm/s2 by default)
77      !!
78      !! ** Action  :   nmln, hmld, hmlp, hmlpt
79      !!----------------------------------------------------------------------
80      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
81      !
82      INTEGER  ::   ji, jj, jk   ! dummy loop indices
83      INTEGER  ::   iikn, iiki, ikt, imkt   ! local integer
84      REAL(wp) ::   zN2_c        ! local scalar
85      INTEGER, POINTER, DIMENSION(:,:) ::   imld   ! 2D workspace
86      !!----------------------------------------------------------------------
87      !
88      IF( nn_timing == 1 )  CALL timing_start('zdf_mxl')
89      !
90      CALL wrk_alloc( jpi,jpj, imld )
91
92      IF( kt == nit000 ) THEN
93         IF(lwp) WRITE(numout,*)
94         IF(lwp) WRITE(numout,*) 'zdf_mxl : mixed layer depth'
95         IF(lwp) WRITE(numout,*) '~~~~~~~ '
96         !                             ! allocate zdfmxl arrays
97         IF( zdf_mxl_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'zdf_mxl : unable to allocate arrays' )
98      ENDIF
99
100      ! w-level of the mixing and mixed layers
101      nmln(:,:)  = nlb10               ! Initialization to the number of w ocean point
102      hmlp(:,:)  = 0._wp               ! here hmlp used as a dummy variable, integrating vertically N^2
103      zN2_c = grav * rho_c * r1_rau0   ! convert density criteria into N^2 criteria
104      DO jk = nlb10, jpkm1
105         DO jj = 1, jpj                ! Mixed layer level: w-level
106            DO ji = 1, jpi
107               ikt = mbkt(ji,jj)
108               hmlp(ji,jj) = hmlp(ji,jj) + MAX( rn2b(ji,jj,jk) , 0._wp ) * fse3w(ji,jj,jk)
109               IF( hmlp(ji,jj) < zN2_c )   nmln(ji,jj) = MIN( jk , ikt ) + 1   ! Mixed layer level
110            END DO
111         END DO
112      END DO
113      !
114      ! w-level of the turbocline
115      imld(:,:) = mbkt(:,:) + 1        ! Initialization to the number of w ocean point
116      DO jk = jpkm1, nlb10, -1         ! from the bottom to nlb10
117         DO jj = 1, jpj
118            DO ji = 1, jpi
119               imkt = mikt(ji,jj)
120               IF( avt (ji,jj,jk) < avt_c )   imld(ji,jj) = MAX( imkt, jk )      ! Turbocline
121            END DO
122         END DO
123      END DO
124      ! depth of the mixing and mixed layers
125      DO jj = 1, jpj
126         DO ji = 1, jpi
127            iiki = imld(ji,jj)
128            iikn = nmln(ji,jj)
129            imkt = mikt(ji,jj)
130            hmld (ji,jj) = ( fsdepw(ji,jj,iiki  ) - fsdepw(ji,jj,imkt ) ) * ssmask(ji,jj)    ! Turbocline depth
131            hmlp (ji,jj) = ( fsdepw(ji,jj,iikn  ) - fsdepw(ji,jj,imkt ) ) * ssmask(ji,jj)    ! Mixed layer depth
132            hmlpt(ji,jj) = ( fsdept(ji,jj,iikn-1) - fsdepw(ji,jj,imkt ) ) * ssmask(ji,jj)    ! depth of the last T-point inside the mixed layer
133         END DO
134      END DO
135      IF( .NOT.lk_offline ) THEN            ! no need to output in offline mode
136         CALL iom_put( "mldr10_1", hmlp )   ! mixed layer depth
137         CALL iom_put( "mldkz5"  , hmld )   ! turbocline depth
138      ENDIF
139     
140      IF(ln_ctl)   CALL prt_ctl( tab2d_1=REAL(nmln,wp), clinfo1=' nmln : ', tab2d_2=hmlp, clinfo2=' hmlp : ', ovlap=1 )
141      !
142      CALL wrk_dealloc( jpi,jpj, imld )
143      !
144      IF( nn_timing == 1 )  CALL timing_stop('zdf_mxl')
145      !
146   END SUBROUTINE zdf_mxl
147
148   !!======================================================================
149END MODULE zdfmxl
Note: See TracBrowser for help on using the repository browser.