New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_mus.F90 in branches/UKMO/r8395_cpl_tauwav/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/UKMO/r8395_cpl_tauwav/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_mus.F90 @ 12286

Last change on this file since 12286 was 12286, checked in by jcastill, 4 years ago

Remove svn keywords

File size: 15.4 KB
Line 
1MODULE traadv_mus
2   !!======================================================================
3   !!                       ***  MODULE  traadv_mus  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!======================================================================
6   !! History :       !  2000-06  (A.Estublier)  for passive tracers
7   !!                 !  2001-08  (E.Durand, G.Madec)  adapted for T & S
8   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            3.2  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
10   !!            3.4  !  2012-06  (P. Oddo, M. Vichi) include the upstream where needed
11   !!            3.7  !  2015-09  (G. Madec) add the ice-shelf cavities boundary condition
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   tra_adv_mus   : update the tracer trend with the horizontal
16   !!                   and vertical advection trends using MUSCL scheme
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE trc_oce        ! share passive tracers/Ocean variables
20   USE dom_oce        ! ocean space and time domain
21   USE trd_oce        ! trends: ocean variables
22   USE trdtra         ! tracers trends manager
23   USE sbcrnf         ! river runoffs
24   USE diaptr         ! poleward transport diagnostics
25   USE diaar5         ! AR5 diagnostics
26
27   !
28   USE iom
29   USE wrk_nemo       ! Memory Allocation
30   USE timing         ! Timing
31   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
32   USE in_out_manager ! I/O manager
33   USE lib_mpp        ! distribued memory computing
34   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
35
36   IMPLICIT NONE
37   PRIVATE
38
39   PUBLIC   tra_adv_mus   ! routine called by traadv.F90
40   
41   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   upsmsk   !: mixed upstream/centered scheme near some straits
42   !                                                           !  and in closed seas (orca 2 and 1 configurations)
43   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   xind     !: mixed upstream/centered index
44   
45   LOGICAL  ::   l_trd   ! flag to compute trends
46   LOGICAL  ::   l_ptr   ! flag to compute poleward transport
47   LOGICAL  ::   l_hst   ! flag to compute heat/salt transport
48
49   !! * Substitutions
50#  include "vectopt_loop_substitute.h90"
51   !!----------------------------------------------------------------------
52   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
53   !! $Id$
54   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
55   !!----------------------------------------------------------------------
56CONTAINS
57
58   SUBROUTINE tra_adv_mus( kt, kit000, cdtype, p2dt, pun, pvn, pwn,             &
59      &                                              ptb, pta, kjpt, ld_msc_ups )
60      !!----------------------------------------------------------------------
61      !!                    ***  ROUTINE tra_adv_mus  ***
62      !!
63      !! ** Purpose :   Compute the now trend due to total advection of tracers
64      !!              using a MUSCL scheme (Monotone Upstream-centered Scheme for
65      !!              Conservation Laws) and add it to the general tracer trend.
66      !!
67      !! ** Method  : MUSCL scheme plus centered scheme at ocean boundaries
68      !!              ld_msc_ups=T :
69      !!
70      !! ** Action : - update pta  with the now advective tracer trends
71      !!             - send trends to trdtra module for further diagnostcs (l_trdtra=T)
72      !!             - htr_adv, str_adv : poleward advective heat and salt transport (ln_diaptr=T)
73      !!
74      !! References : Estubier, A., and M. Levy, Notes Techn. Pole de Modelisation
75      !!              IPSL, Sept. 2000 (http://www.lodyc.jussieu.fr/opa)
76      !!----------------------------------------------------------------------
77      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
78      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
79      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
80      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
81      LOGICAL                              , INTENT(in   ) ::   ld_msc_ups      ! use upstream scheme within muscl
82      REAL(wp)                             , INTENT(in   ) ::   p2dt            ! tracer time-step
83      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
84      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb             ! before tracer field
85      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
86      !
87      INTEGER  ::   ji, jj, jk, jn       ! dummy loop indices
88      INTEGER  ::   ierr                 ! local integer
89      REAL(wp) ::   zu, z0u, zzwx, zw    ! local scalars
90      REAL(wp) ::   zv, z0v, zzwy, z0w   !   -      -
91      REAL(wp) ::   zalpha               !   -      -
92      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zslpx, zslpy   ! 3D workspace
93      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zwx  , zwy     ! -      -
94      !!----------------------------------------------------------------------
95      !
96      IF( nn_timing == 1 )  CALL timing_start('tra_adv_mus')
97      !
98      CALL wrk_alloc( jpi,jpj,jpk,   zslpx, zslpy, zwx, zwy )
99      !
100      IF( kt == kit000 )  THEN
101         IF(lwp) WRITE(numout,*)
102         IF(lwp) WRITE(numout,*) 'tra_adv : MUSCL advection scheme on ', cdtype
103         IF(lwp) WRITE(numout,*) '        : mixed up-stream           ', ld_msc_ups
104         IF(lwp) WRITE(numout,*) '~~~~~~~'
105         IF(lwp) WRITE(numout,*)
106         !
107         ! Upstream / MUSCL scheme indicator
108         !
109         ALLOCATE( xind(jpi,jpj,jpk), STAT=ierr )
110         xind(:,:,:) = 1._wp              ! set equal to 1 where up-stream is not needed
111         !
112         IF( ld_msc_ups ) THEN            ! define the upstream indicator (if asked)
113            ALLOCATE( upsmsk(jpi,jpj), STAT=ierr )
114            upsmsk(:,:) = 0._wp                             ! not upstream by default
115            !
116            DO jk = 1, jpkm1
117               xind(:,:,jk) = 1._wp                              &                 ! =>1 where up-stream is not needed
118                  &         - MAX ( rnfmsk(:,:) * rnfmsk_z(jk),  &                 ! =>0 near runoff mouths (& closed sea outflows)
119                  &                 upsmsk(:,:)                ) * tmask(:,:,jk)   ! =>0 in some user defined area
120            END DO
121         ENDIF 
122         !
123      ENDIF 
124      !     
125      l_trd = .FALSE.
126      l_hst = .FALSE.
127      l_ptr = .FALSE.
128      IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) )      l_trd = .TRUE.
129      IF(   cdtype == 'TRA' .AND. ln_diaptr )                                               l_ptr = .TRUE. 
130      IF(   cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR. &
131         &                          iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  ) ) l_hst = .TRUE.
132      !
133      DO jn = 1, kjpt            !==  loop over the tracers  ==!
134         !
135         !                          !* Horizontal advective fluxes
136         !
137         !                                !-- first guess of the slopes
138         zwx(:,:,jpk) = 0._wp                   ! bottom values
139         zwy(:,:,jpk) = 0._wp 
140         DO jk = 1, jpkm1                       ! interior values
141            DO jj = 1, jpjm1     
142               DO ji = 1, fs_jpim1   ! vector opt.
143                  zwx(ji,jj,jk) = umask(ji,jj,jk) * ( ptb(ji+1,jj,jk,jn) - ptb(ji,jj,jk,jn) )
144                  zwy(ji,jj,jk) = vmask(ji,jj,jk) * ( ptb(ji,jj+1,jk,jn) - ptb(ji,jj,jk,jn) )
145               END DO
146           END DO
147         END DO
148         CALL lbc_lnk( zwx, 'U', -1. )          ! lateral boundary conditions   (changed sign)
149         CALL lbc_lnk( zwy, 'V', -1. )
150         !                                !-- Slopes of tracer
151         zslpx(:,:,jpk) = 0._wp                 ! bottom values
152         zslpy(:,:,jpk) = 0._wp
153         DO jk = 1, jpkm1                       ! interior values
154            DO jj = 2, jpj
155               DO ji = fs_2, jpi   ! vector opt.
156                  zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji-1,jj  ,jk) )   &
157                     &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji-1,jj  ,jk) ) )
158                  zslpy(ji,jj,jk) =                    ( zwy(ji,jj,jk) + zwy(ji  ,jj-1,jk) )   &
159                     &            * ( 0.25 + SIGN( 0.25, zwy(ji,jj,jk) * zwy(ji  ,jj-1,jk) ) )
160               END DO
161            END DO
162         END DO
163         !
164         DO jk = 1, jpkm1                 !-- Slopes limitation
165            DO jj = 2, jpj
166               DO ji = fs_2, jpi   ! vector opt.
167                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji  ,jj,jk) ),   &
168                     &                                                 2.*ABS( zwx  (ji-1,jj,jk) ),   &
169                     &                                                 2.*ABS( zwx  (ji  ,jj,jk) ) )
170                  zslpy(ji,jj,jk) = SIGN( 1., zslpy(ji,jj,jk) ) * MIN(    ABS( zslpy(ji,jj  ,jk) ),   &
171                     &                                                 2.*ABS( zwy  (ji,jj-1,jk) ),   &
172                     &                                                 2.*ABS( zwy  (ji,jj  ,jk) ) )
173               END DO
174           END DO
175         END DO
176         !
177         DO jk = 1, jpkm1                 !-- MUSCL horizontal advective fluxes
178            DO jj = 2, jpjm1
179               DO ji = fs_2, fs_jpim1   ! vector opt.
180                  ! MUSCL fluxes
181                  z0u = SIGN( 0.5, pun(ji,jj,jk) )
182                  zalpha = 0.5 - z0u
183                  zu  = z0u - 0.5 * pun(ji,jj,jk) * p2dt * r1_e1e2u(ji,jj) / e3u_n(ji,jj,jk)
184                  zzwx = ptb(ji+1,jj,jk,jn) + xind(ji,jj,jk) * zu * zslpx(ji+1,jj,jk)
185                  zzwy = ptb(ji  ,jj,jk,jn) + xind(ji,jj,jk) * zu * zslpx(ji  ,jj,jk)
186                  zwx(ji,jj,jk) = pun(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
187                  !
188                  z0v = SIGN( 0.5, pvn(ji,jj,jk) )
189                  zalpha = 0.5 - z0v
190                  zv  = z0v - 0.5 * pvn(ji,jj,jk) * p2dt * r1_e1e2v(ji,jj) / e3v_n(ji,jj,jk)
191                  zzwx = ptb(ji,jj+1,jk,jn) + xind(ji,jj,jk) * zv * zslpy(ji,jj+1,jk)
192                  zzwy = ptb(ji,jj  ,jk,jn) + xind(ji,jj,jk) * zv * zslpy(ji,jj  ,jk)
193                  zwy(ji,jj,jk) = pvn(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
194               END DO
195            END DO
196         END DO
197         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )   ! lateral boundary conditions   (changed sign)
198         !
199         DO jk = 1, jpkm1                 !-- Tracer advective trend
200            DO jj = 2, jpjm1     
201               DO ji = fs_2, fs_jpim1   ! vector opt.
202                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) - ( zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )       &
203                  &                                     + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  ) )     &
204                  &                                   * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
205               END DO
206           END DO
207         END DO       
208         !                                ! trend diagnostics
209         IF( l_trd )  THEN
210            CALL trd_tra( kt, cdtype, jn, jptra_xad, zwx, pun, ptb(:,:,:,jn) )
211            CALL trd_tra( kt, cdtype, jn, jptra_yad, zwy, pvn, ptb(:,:,:,jn) )
212         END IF
213         !                                 ! "Poleward" heat and salt transports
214         IF( l_ptr )  CALL dia_ptr_hst( jn, 'adv', zwy(:,:,:) )
215         !                                 !  heat transport
216         IF( l_hst )  CALL dia_ar5_hst( jn, 'adv', zwx(:,:,:), zwy(:,:,:) )
217         !
218         !                          !* Vertical advective fluxes
219         !
220         !                                !-- first guess of the slopes
221         zwx(:,:, 1 ) = 0._wp                   ! surface & bottom boundary conditions
222         zwx(:,:,jpk) = 0._wp
223         DO jk = 2, jpkm1                       ! interior values
224            zwx(:,:,jk) = tmask(:,:,jk) * ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) )
225         END DO
226         !                                !-- Slopes of tracer
227         zslpx(:,:,1) = 0._wp                   ! surface values
228         DO jk = 2, jpkm1                       ! interior value
229            DO jj = 1, jpj
230               DO ji = 1, jpi
231                  zslpx(ji,jj,jk) =                     ( zwx(ji,jj,jk) + zwx(ji,jj,jk+1) )  &
232                     &            * (  0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji,jj,jk+1) )  )
233               END DO
234            END DO
235         END DO
236         DO jk = 2, jpkm1                 !-- Slopes limitation
237            DO jj = 1, jpj                      ! interior values
238               DO ji = 1, jpi
239                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji,jj,jk  ) ),   &
240                     &                                                 2.*ABS( zwx  (ji,jj,jk+1) ),   &
241                     &                                                 2.*ABS( zwx  (ji,jj,jk  ) )  )
242               END DO
243            END DO
244         END DO
245         DO jk = 1, jpk-2                 !-- vertical advective flux
246            DO jj = 2, jpjm1     
247               DO ji = fs_2, fs_jpim1   ! vector opt.
248                  z0w = SIGN( 0.5, pwn(ji,jj,jk+1) )
249                  zalpha = 0.5 + z0w
250                  zw  = z0w - 0.5 * pwn(ji,jj,jk+1) * p2dt * r1_e1e2t(ji,jj) / e3w_n(ji,jj,jk+1)
251                  zzwx = ptb(ji,jj,jk+1,jn) + xind(ji,jj,jk) * zw * zslpx(ji,jj,jk+1)
252                  zzwy = ptb(ji,jj,jk  ,jn) + xind(ji,jj,jk) * zw * zslpx(ji,jj,jk  )
253                  zwx(ji,jj,jk+1) = pwn(ji,jj,jk+1) * ( zalpha * zzwx + (1.-zalpha) * zzwy ) * wmask(ji,jj,jk)
254               END DO
255            END DO
256         END DO
257         IF( ln_linssh ) THEN                   ! top values, linear free surface only
258            IF( ln_isfcav ) THEN                      ! ice-shelf cavities (top of the ocean)
259               DO jj = 1, jpj
260                  DO ji = 1, jpi
261                     zwx(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)
262                  END DO
263               END DO   
264            ELSE                                      ! no cavities: only at the ocean surface
265               zwx(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)
266            ENDIF
267         ENDIF
268         !
269         DO jk = 1, jpkm1                 !-- vertical advective trend
270            DO jj = 2, jpjm1     
271               DO ji = fs_2, fs_jpim1   ! vector opt.
272                  pta(ji,jj,jk,jn) =  pta(ji,jj,jk,jn) - ( zwx(ji,jj,jk) - zwx(ji,jj,jk+1) ) * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
273               END DO
274            END DO
275         END DO
276         !                                ! send trends for diagnostic
277         IF( l_trd )  CALL trd_tra( kt, cdtype, jn, jptra_zad, zwx, pwn, ptb(:,:,:,jn) )
278         !
279      END DO                     ! end of tracer loop
280      !
281      CALL wrk_dealloc( jpi,jpj,jpk,   zslpx, zslpy, zwx, zwy )
282      !
283      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_mus')
284      !
285   END SUBROUTINE tra_adv_mus
286
287   !!======================================================================
288END MODULE traadv_mus
Note: See TracBrowser for help on using the repository browser.