New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcwave.F90 in branches/UKMO/r8727_WAVE-2_Clementi_add_coupling/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/UKMO/r8727_WAVE-2_Clementi_add_coupling/NEMOGCM/NEMO/OPA_SRC/SBC/sbcwave.F90 @ 8750

Last change on this file since 8750 was 8750, checked in by jcastill, 6 years ago

First set of changes for ticket #1980
Addition of the Phillips parametrization for vertical Stokes drift

File size: 20.5 KB
Line 
1MODULE sbcwave
2   !!======================================================================
3   !!                       ***  MODULE  sbcwave  ***
4   !! Wave module
5   !!======================================================================
6   !! History :  3.3  !  2011-09  (M. Adani)  Original code: Drag Coefficient
7   !!         :  3.4  !  2012-10  (M. Adani)  Stokes Drift
8   !!            3.6  !  2014-09  (E. Clementi,P. Oddo) New Stokes Drift Computation
9   !!             -   !  2016-12  (G. Madec, E. Clementi) update Stoke drift computation
10   !!                                                    + add sbc_wave_ini routine
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   sbc_stokes    : calculate 3D Stokes-drift velocities
15   !!   sbc_wave      : wave data from wave model in netcdf files
16   !!   sbc_wave_init : initialisation fo surface waves
17   !!----------------------------------------------------------------------
18   USE phycst         ! physical constants
19   USE oce            ! ocean variables
20   USE sbc_oce        ! Surface boundary condition: ocean fields
21   USE zdf_oce,  ONLY : ln_zdfqiao
22   USE bdy_oce        ! open boundary condition variables
23   USE domvvl         ! domain: variable volume layers
24   !
25   USE iom            ! I/O manager library
26   USE in_out_manager ! I/O manager
27   USE lib_mpp        ! distribued memory computing library
28   USE fldread        ! read input fields
29   USE wrk_nemo       !
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   sbc_stokes      ! routine called in sbccpl
35   PUBLIC   sbc_wave        ! routine called in sbcmod
36   PUBLIC   sbc_wave_init   ! routine called in sbcmod
37   
38   ! Variables checking if the wave parameters are coupled (if not, they are read from file)
39   LOGICAL, PUBLIC ::   cpl_hsig   = .FALSE.
40   LOGICAL, PUBLIC ::   cpl_phioc  = .FALSE.
41   LOGICAL, PUBLIC ::   cpl_sdrftx = .FALSE.
42   LOGICAL, PUBLIC ::   cpl_sdrfty = .FALSE.
43   LOGICAL, PUBLIC ::   cpl_wper   = .FALSE.
44   LOGICAL, PUBLIC ::   cpl_wfreq  = .FALSE.
45   LOGICAL, PUBLIC ::   cpl_wnum   = .FALSE.
46   LOGICAL, PUBLIC ::   cpl_wstrf  = .FALSE.
47   LOGICAL, PUBLIC ::   cpl_wdrag  = .FALSE.
48
49   INTEGER ::   jpfld    ! number of files to read for stokes drift
50   INTEGER ::   jp_usd   ! index of stokes drift  (i-component) (m/s)    at T-point
51   INTEGER ::   jp_vsd   ! index of stokes drift  (j-component) (m/s)    at T-point
52   INTEGER ::   jp_hsw   ! index of significant wave hight      (m)      at T-point
53   INTEGER ::   jp_wmp   ! index of mean wave period            (s)      at T-point
54   INTEGER ::   jp_wfr   ! index of wave peak frequency         (1/s)    at T-point
55
56   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_cd      ! structure of input fields (file informations, fields read) Drag Coefficient
57   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_sd      ! structure of input fields (file informations, fields read) Stokes Drift
58   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_wn      ! structure of input fields (file informations, fields read) wave number for Qiao
59   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_tauoc   ! structure of input fields (file informations, fields read) normalized wave stress into the ocean
60   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   cdn_wave            !:
61   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   hsw, wmp, wnum      !:
62   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   wfreq               !:
63   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   tauoc_wave          !: 
64   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   tsd2d               !:
65   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   div_sd              !: barotropic stokes drift divergence
66   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   ut0sd, vt0sd        !: surface Stokes drift velocities at t-point
67   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:,:) ::   usd  , vsd  , wsd   !: Stokes drift velocities at u-, v- & w-points, resp.
68
69   !! * Substitutions
70#  include "vectopt_loop_substitute.h90"
71   !!----------------------------------------------------------------------
72   !! NEMO/OPA 3.7 , NEMO Consortium (2014)
73   !! $Id$
74   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
75   !!----------------------------------------------------------------------
76CONTAINS
77
78   SUBROUTINE sbc_stokes( )
79      !!---------------------------------------------------------------------
80      !!                     ***  ROUTINE sbc_stokes  ***
81      !!
82      !! ** Purpose :   compute the 3d Stokes Drift according to Breivik et al.,
83      !!                2014 (DOI: 10.1175/JPO-D-14-0020.1)
84      !!
85      !! ** Method  : - Calculate Stokes transport speed
86      !!              - Calculate horizontal divergence
87      !!              - Integrate the horizontal divergenze from the bottom
88      !! ** action 
89      !!---------------------------------------------------------------------
90      INTEGER  ::   jj, ji, jk   ! dummy loop argument
91      INTEGER  ::   ik           ! local integer
92      REAL(wp) ::  ztransp, zfac, ztemp, zsp0
93      REAL(wp) ::  zdep_u, zdep_v, zkh_u, zkh_v, zda_u, zda_v
94      REAL(wp), DIMENSION(:,:)  , POINTER ::   zk_t, zk_u, zk_v, zu0_sd, zv0_sd   ! 2D workspace
95      REAL(wp), DIMENSION(:,:,:), POINTER ::   ze3divh                            ! 3D workspace
96      !!---------------------------------------------------------------------
97      !
98      CALL wrk_alloc( jpi,jpj,jpk,   ze3divh )
99      CALL wrk_alloc( jpi,jpj,       zk_t, zk_u, zk_v, zu0_sd, zv0_sd )
100      !
101      ! select parameterization for the calculation of vertical Stokes drift
102      ! exp. wave number at t-point
103      IF( nn_sdrift==jp_breivik .OR. nn_sdrift==jp_phillips ) THEN   ! (Eq. (19) in Breivick et al. (2014) )
104         zfac = 2.0_wp * rpi / 16.0_wp
105         DO jj = 1, jpj
106            DO ji = 1, jpi
107               ! Stokes drift velocity estimated from Hs and Tmean
108               ztransp = zfac * hsw(ji,jj)*hsw(ji,jj) / MAX( wmp(ji,jj), 0.0000001_wp )
109               ! Stokes surface speed
110               tsd2d(ji,jj) = SQRT( ut0sd(ji,jj)*ut0sd(ji,jj) + vt0sd(ji,jj)*vt0sd(ji,jj))
111               ! Wavenumber scale
112               zk_t(ji,jj) = ABS( tsd2d(ji,jj) ) / MAX( ABS( 5.97_wp*ztransp ), 0.0000001_wp )
113            END DO
114         END DO
115         DO jj = 1, jpjm1              ! exp. wave number & Stokes drift velocity at u- & v-points
116            DO ji = 1, jpim1
117               zk_u(ji,jj) = 0.5_wp * ( zk_t(ji,jj) + zk_t(ji+1,jj) )
118               zk_v(ji,jj) = 0.5_wp * ( zk_t(ji,jj) + zk_t(ji,jj+1) )
119               !
120               zu0_sd(ji,jj) = 0.5_wp * ( ut0sd(ji,jj) + ut0sd(ji+1,jj) )
121               zv0_sd(ji,jj) = 0.5_wp * ( vt0sd(ji,jj) + vt0sd(ji,jj+1) )
122            END DO
123         END DO
124      ELSE IF( nn_sdrift==jp_peakfr ) THEN    ! peak wave number calculated from the peak frequency received by the wave model
125         DO jj = 1, jpjm1
126            DO ji = 1, jpim1
127               zk_u(ji,jj) = 0.5_wp * ( wfreq(ji,jj)*wfreq(ji,jj) + wfreq(ji+1,jj)*wfreq(ji+1,jj) ) / grav
128               zk_v(ji,jj) = 0.5_wp * ( wfreq(ji,jj)*wfreq(ji,jj) + wfreq(ji,jj+1)*wfreq(ji,jj+1) ) / grav
129               !
130               zu0_sd(ji,jj) = 0.5_wp * ( ut0sd(ji,jj) + ut0sd(ji+1,jj) )
131               zv0_sd(ji,jj) = 0.5_wp * ( vt0sd(ji,jj) + vt0sd(ji,jj+1) )
132            END DO
133         END DO
134      ENDIF
135      !
136      !                       !==  horizontal Stokes Drift 3D velocity  ==!
137      IF( nn_sdrift==jp_breivik ) THEN
138         DO jk = 1, jpkm1
139            DO jj = 2, jpjm1
140               DO ji = 2, jpim1
141                  zdep_u = 0.5_wp * ( gdept_n(ji,jj,jk) + gdept_n(ji+1,jj,jk) )
142                  zdep_v = 0.5_wp * ( gdept_n(ji,jj,jk) + gdept_n(ji,jj+1,jk) )
143                  !                         
144                  zkh_u = zk_u(ji,jj) * zdep_u     ! k * depth
145                  zkh_v = zk_v(ji,jj) * zdep_v
146                  !                                ! Depth attenuation
147                  zda_u = EXP( -2.0_wp*zkh_u ) / ( 1.0_wp + 8.0_wp*zkh_u )
148                  zda_v = EXP( -2.0_wp*zkh_v ) / ( 1.0_wp + 8.0_wp*zkh_v )
149                  !
150                  usd(ji,jj,jk) = zda_u * zu0_sd(ji,jj) * umask(ji,jj,jk)
151                  vsd(ji,jj,jk) = zda_v * zv0_sd(ji,jj) * vmask(ji,jj,jk)
152               END DO
153            END DO
154         END DO
155      ELSE IF( nn_sdrift==jp_phillips .OR. nn_sdrift==jp_peakfr ) THEN
156         DO jk = 1, jpkm1
157            DO jj = 2, jpjm1
158               DO ji = 2, jpim1
159                  zdep_u = 0.5_wp * ( gdept_n(ji,jj,jk) + gdept_n(ji+1,jj,jk) )
160                  zdep_v = 0.5_wp * ( gdept_n(ji,jj,jk) + gdept_n(ji,jj+1,jk) )
161                  !                         
162                  zkh_u = zk_u(ji,jj) * zdep_u     ! k * depth
163                  zkh_v = zk_v(ji,jj) * zdep_v
164                  !                                ! Depth attenuation
165                  zda_u = EXP( -2.0_wp*zkh_u ) - SQRT(2.0_wp*rpi*zkh_u) * ERFC(SQRT(2.0_wp*zkh_u))
166                  zda_v = EXP( -2.0_wp*zkh_v ) - SQRT(2.0_wp*rpi*zkh_v) * ERFC(SQRT(2.0_wp*zkh_v))
167                  !
168                  usd(ji,jj,jk) = zda_u * zu0_sd(ji,jj) * umask(ji,jj,jk)
169                  vsd(ji,jj,jk) = zda_v * zv0_sd(ji,jj) * vmask(ji,jj,jk)
170               END DO
171            END DO
172         END DO
173      ENDIF
174
175      CALL lbc_lnk( usd(:,:,:), 'U', vsd(:,:,:), 'V', -1. )
176      !
177      !                       !==  vertical Stokes Drift 3D velocity  ==!
178      !
179      DO jk = 1, jpkm1               ! Horizontal e3*divergence
180         DO jj = 2, jpj
181            DO ji = fs_2, jpi
182               ze3divh(ji,jj,jk) = (  e2u(ji  ,jj) * e3u_n(ji  ,jj,jk) * usd(ji  ,jj,jk)    &
183                  &                 - e2u(ji-1,jj) * e3u_n(ji-1,jj,jk) * usd(ji-1,jj,jk)    &
184                  &                 + e1v(ji,jj  ) * e3v_n(ji,jj  ,jk) * vsd(ji,jj  ,jk)    &
185                  &                 - e1v(ji,jj-1) * e3v_n(ji,jj-1,jk) * vsd(ji,jj-1,jk)  ) * r1_e1e2t(ji,jj)
186            END DO
187         END DO
188      END DO
189      !
190      IF( .NOT. AGRIF_Root() ) THEN
191         IF( nbondi ==  1 .OR. nbondi == 2 )   ze3divh(nlci-1,   :  ,:) = 0._wp      ! east
192         IF( nbondi == -1 .OR. nbondi == 2 )   ze3divh(  2   ,   :  ,:) = 0._wp      ! west
193         IF( nbondj ==  1 .OR. nbondj == 2 )   ze3divh(  :   ,nlcj-1,:) = 0._wp      ! north
194         IF( nbondj == -1 .OR. nbondj == 2 )   ze3divh(  :   ,  2   ,:) = 0._wp      ! south
195      ENDIF
196      !
197      CALL lbc_lnk( ze3divh, 'T', 1. )
198      !
199      IF( ln_linssh ) THEN   ;   ik = 1   ! none zero velocity through the sea surface
200      ELSE                   ;   ik = 2   ! w=0 at the surface (set one for all in sbc_wave_init)
201      ENDIF
202      DO jk = jpkm1, ik, -1          ! integrate from the bottom the hor. divergence (NB: at k=jpk w is always zero)
203         wsd(:,:,jk) = wsd(:,:,jk+1) - ze3divh(:,:,jk)
204      END DO
205      !
206      IF( ln_bdy ) THEN
207         DO jk = 1, jpkm1
208            wsd(:,:,jk) = wsd(:,:,jk) * bdytmask(:,:)
209         END DO
210      ENDIF
211      !                       !==  Horizontal divergence of barotropic Stokes transport  ==!
212      div_sd(:,:) = 0._wp
213      DO jk = 1, jpkm1                                 !
214        div_sd(:,:) = div_sd(:,:) + ze3divh(:,:,jk)
215      END DO
216      !
217      CALL iom_put( "ustokes",  usd  )
218      CALL iom_put( "vstokes",  vsd  )
219      CALL iom_put( "wstokes",  wsd  )
220      !
221      CALL wrk_dealloc( jpi,jpj,jpk,   ze3divh )
222      CALL wrk_dealloc( jpi,jpj,       zk_t, zk_u, zk_v, zu0_sd, zv0_sd )
223      !
224   END SUBROUTINE sbc_stokes
225
226
227   SUBROUTINE sbc_wave( kt )
228      !!---------------------------------------------------------------------
229      !!                     ***  ROUTINE sbc_wave  ***
230      !!
231      !! ** Purpose :   read wave parameters from wave model  in netcdf files.
232      !!
233      !! ** Method  : - Read namelist namsbc_wave
234      !!              - Read Cd_n10 fields in netcdf files
235      !!              - Read stokes drift 2d in netcdf files
236      !!              - Read wave number in netcdf files
237      !!              - Compute 3d stokes drift using Breivik et al.,2014
238      !!                formulation
239      !! ** action 
240      !!---------------------------------------------------------------------
241      INTEGER, INTENT(in   ) ::   kt   ! ocean time step
242      !!---------------------------------------------------------------------
243      !
244      IF( ln_cdgw .AND. .NOT. cpl_wdrag ) THEN     !==  Neutral drag coefficient  ==!
245         CALL fld_read( kt, nn_fsbc, sf_cd )             ! read from external forcing
246         cdn_wave(:,:) = sf_cd(1)%fnow(:,:,1)
247      ENDIF
248
249      IF( ln_tauoc .AND. .NOT. cpl_wstrf ) THEN    !==  Wave induced stress  ==!
250         CALL fld_read( kt, nn_fsbc, sf_tauoc )          ! read wave norm stress from external forcing
251         tauoc_wave(:,:) = sf_tauoc(1)%fnow(:,:,1)
252      ENDIF
253
254      IF( ln_sdw )  THEN                           !==  Computation of the 3d Stokes Drift  ==!
255         !
256         IF( jpfld > 0 ) THEN                            ! Read from file only if the field is not coupled
257            CALL fld_read( kt, nn_fsbc, sf_sd )          ! read wave parameters from external forcing
258            IF( jp_hsw > 0 )   hsw  (:,:) = sf_sd(jp_hsw)%fnow(:,:,1)   ! significant wave height
259            IF( jp_wmp > 0 )   wmp  (:,:) = sf_sd(jp_wmp)%fnow(:,:,1)   ! wave mean period
260            IF( jp_wfr > 0 )   wfreq(:,:) = sf_sd(jp_wfr)%fnow(:,:,1)   ! Peak wave frequency
261            IF( jp_usd > 0 )   ut0sd(:,:) = sf_sd(jp_usd)%fnow(:,:,1)   ! 2D zonal Stokes Drift at T point
262            IF( jp_vsd > 0 )   vt0sd(:,:) = sf_sd(jp_vsd)%fnow(:,:,1)   ! 2D meridional Stokes Drift at T point
263         ENDIF
264         !
265         ! Read also wave number if needed, so that it is available in coupling routines
266         IF( ln_zdfqiao .AND. .NOT.cpl_wnum ) THEN
267            CALL fld_read( kt, nn_fsbc, sf_wn )          ! read wave parameters from external forcing
268            wnum(:,:) = sf_wn(1)%fnow(:,:,1)
269         ENDIF
270           
271         !                                         !==  Computation of the 3d Stokes Drift  ==!
272         !
273         IF( ((nn_sdrift==jp_breivik .OR. nn_sdrift==jp_phillips) .AND. &
274                          jp_hsw>0 .AND. jp_wmp>0 .AND. jp_usd>0 .AND. jp_vsd>0) .OR. &
275             (nn_sdrift==jp_peakfr .AND. jp_wfr>0 .AND. jp_usd>0 .AND. jp_vsd>0) ) &
276            CALL sbc_stokes()            ! Calculate only if required fields are read
277         !                               ! In coupled wave model-NEMO case the call is done after coupling
278         !
279      ENDIF
280      !
281   END SUBROUTINE sbc_wave
282
283
284   SUBROUTINE sbc_wave_init
285      !!---------------------------------------------------------------------
286      !!                     ***  ROUTINE sbc_wave_init  ***
287      !!
288      !! ** Purpose :   read wave parameters from wave model  in netcdf files.
289      !!
290      !! ** Method  : - Read namelist namsbc_wave
291      !!              - Read Cd_n10 fields in netcdf files
292      !!              - Read stokes drift 2d in netcdf files
293      !!              - Read wave number in netcdf files
294      !!              - Compute 3d stokes drift using Breivik et al.,2014
295      !!                formulation
296      !! ** action 
297      !!---------------------------------------------------------------------
298      INTEGER ::   ierror, ios   ! local integer
299      INTEGER ::   ifpr
300      !!
301      CHARACTER(len=100)     ::  cn_dir                          ! Root directory for location of drag coefficient files
302      TYPE(FLD_N), ALLOCATABLE, DIMENSION(:) ::   slf_i     ! array of namelist informations on the fields to read
303      TYPE(FLD_N)            ::  sn_cdg, sn_usd, sn_vsd,  &
304                             &   sn_hsw, sn_wmp, sn_wfr, sn_wnum, sn_tauoc      ! informations about the fields to be read
305      !
306      NAMELIST/namsbc_wave/  sn_cdg, cn_dir, sn_usd, sn_vsd, sn_hsw, sn_wmp, sn_wfr, sn_wnum, sn_tauoc
307      !!---------------------------------------------------------------------
308      !
309      REWIND( numnam_ref )              ! Namelist namsbc_wave in reference namelist : File for drag coeff. from wave model
310      READ  ( numnam_ref, namsbc_wave, IOSTAT = ios, ERR = 901)
311901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_wave in reference namelist', lwp )
312         
313      REWIND( numnam_cfg )              ! Namelist namsbc_wave in configuration namelist : File for drag coeff. from wave model
314      READ  ( numnam_cfg, namsbc_wave, IOSTAT = ios, ERR = 902 )
315902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_wave in configuration namelist', lwp )
316      IF(lwm) WRITE ( numond, namsbc_wave )
317      !
318      IF( ln_cdgw ) THEN
319         IF( .NOT. cpl_wdrag ) THEN
320            ALLOCATE( sf_cd(1), STAT=ierror )           !* allocate and fill sf_wave with sn_cdg
321            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable to allocate sf_wave structure' )
322            !
323                                   ALLOCATE( sf_cd(1)%fnow(jpi,jpj,1)   )
324            IF( sn_cdg%ln_tint )   ALLOCATE( sf_cd(1)%fdta(jpi,jpj,1,2) )
325            CALL fld_fill( sf_cd, (/ sn_cdg /), cn_dir, 'sbc_wave_init', 'Wave module ', 'namsbc_wave' )
326         ENDIF
327         ALLOCATE( cdn_wave(jpi,jpj) )
328      ENDIF
329
330      IF( ln_tauoc ) THEN
331         IF( .NOT. cpl_wstrf ) THEN
332            ALLOCATE( sf_tauoc(1), STAT=ierror )           !* allocate and fill sf_wave with sn_tauoc
333            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable to allocate sf_wave structure' )
334            !
335                                    ALLOCATE( sf_tauoc(1)%fnow(jpi,jpj,1)   )
336            IF( sn_tauoc%ln_tint )  ALLOCATE( sf_tauoc(1)%fdta(jpi,jpj,1,2) )
337            CALL fld_fill( sf_tauoc, (/ sn_tauoc /), cn_dir, 'sbc_wave_init', 'Wave module', 'namsbc_wave' )
338         ENDIF
339         ALLOCATE( tauoc_wave(jpi,jpj) )
340      ENDIF
341
342      IF( ln_sdw ) THEN   ! Find out how many fields have to be read from file if not coupled
343         jpfld=0
344         jp_usd=0   ;   jp_vsd=0   ;   jp_hsw=0   ;   jp_wmp=0   ;   jp_wfr=0
345         IF( .NOT. cpl_sdrftx ) THEN
346            jpfld  = jpfld + 1
347            jp_usd = jpfld
348         ENDIF
349         IF( .NOT. cpl_sdrfty ) THEN
350            jpfld  = jpfld + 1
351            jp_vsd = jpfld
352         ENDIF
353         IF( .NOT. cpl_hsig .AND. (nn_sdrift==jp_breivik .OR. nn_sdrift==jp_phillips) ) THEN
354            jpfld  = jpfld + 1
355            jp_hsw = jpfld
356         ENDIF
357         IF( .NOT. cpl_wper .AND. (nn_sdrift==jp_breivik .OR. nn_sdrift==jp_phillips) ) THEN
358            jpfld  = jpfld + 1
359            jp_wmp = jpfld
360         ENDIF
361         IF( .NOT. cpl_wfreq .AND. nn_sdrift==jp_peakfr ) THEN
362            jpfld  = jpfld + 1
363            jp_wfr = jpfld
364         ENDIF
365
366         ! Read from file only the non-coupled fields
367         IF( jpfld > 0 ) THEN
368            ALLOCATE( slf_i(jpfld) )
369            IF( jp_usd > 0 )   slf_i(jp_usd) = sn_usd
370            IF( jp_vsd > 0 )   slf_i(jp_vsd) = sn_vsd
371            IF( jp_hsw > 0 )   slf_i(jp_hsw) = sn_hsw
372            IF( jp_wmp > 0 )   slf_i(jp_wmp) = sn_wmp
373            IF( jp_wfr > 0 )   slf_i(jp_wfr) = sn_wfr
374
375            ALLOCATE( sf_sd(jpfld), STAT=ierror )   !* allocate and fill sf_sd with stokes drift
376            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable to allocate sf_wave structure' )
377            !
378            DO ifpr= 1, jpfld
379               ALLOCATE( sf_sd(ifpr)%fnow(jpi,jpj,1) )
380               IF( slf_i(ifpr)%ln_tint )   ALLOCATE( sf_sd(ifpr)%fdta(jpi,jpj,1,2) )
381            END DO
382            !
383            CALL fld_fill( sf_sd, slf_i, cn_dir, 'sbc_wave_init', 'Wave module ', 'namsbc_wave' )
384         ENDIF
385         ALLOCATE( usd  (jpi,jpj,jpk), vsd  (jpi,jpj,jpk), wsd(jpi,jpj,jpk) )
386         ALLOCATE( hsw  (jpi,jpj)    , wmp  (jpi,jpj)     )
387         ALLOCATE( wfreq(jpi,jpj) )
388         ALLOCATE( ut0sd(jpi,jpj)    , vt0sd(jpi,jpj)     )
389         ALLOCATE( div_sd(jpi,jpj) )
390         ALLOCATE( tsd2d (jpi,jpj) )
391         usd(:,:,:) = 0._wp
392         vsd(:,:,:) = 0._wp
393         wsd(:,:,:) = 0._wp
394         ! Wave number needed only if ln_zdfqiao=T
395         IF( .NOT. cpl_wnum ) THEN
396            ALLOCATE( sf_wn(1), STAT=ierror )           !* allocate and fill sf_wave with sn_wnum
397            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable toallocate sf_wave structure' )
398                                   ALLOCATE( sf_wn(1)%fnow(jpi,jpj,1)   )
399            IF( sn_wnum%ln_tint )  ALLOCATE( sf_wn(1)%fdta(jpi,jpj,1,2) )
400            CALL fld_fill( sf_wn, (/ sn_wnum /), cn_dir, 'sbc_wave', 'Wave module', 'namsbc_wave' )
401         ENDIF
402         ALLOCATE( wnum(jpi,jpj) )
403      ENDIF
404      !
405   END SUBROUTINE sbc_wave_init
406
407   !!======================================================================
408END MODULE sbcwave
Note: See TracBrowser for help on using the repository browser.