New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcwave.F90 in branches/UKMO/r8727_WAVE-2_Clementi_add_coupling/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/UKMO/r8727_WAVE-2_Clementi_add_coupling/NEMOGCM/NEMO/OPA_SRC/SBC/sbcwave.F90 @ 8755

Last change on this file since 8755 was 8755, checked in by jcastill, 6 years ago

Further changes for ticket #1980
Receive the ocean wind stress components from a wave model, both in forced and coupled mode
File size: 23.4 KB
Line 
1MODULE sbcwave
2   !!======================================================================
3   !!                       ***  MODULE  sbcwave  ***
4   !! Wave module
5   !!======================================================================
6   !! History :  3.3  !  2011-09  (M. Adani)  Original code: Drag Coefficient
7   !!         :  3.4  !  2012-10  (M. Adani)  Stokes Drift
8   !!            3.6  !  2014-09  (E. Clementi,P. Oddo) New Stokes Drift Computation
9   !!             -   !  2016-12  (G. Madec, E. Clementi) update Stoke drift computation
10   !!                                                    + add sbc_wave_ini routine
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   sbc_stokes    : calculate 3D Stokes-drift velocities
15   !!   sbc_wave      : wave data from wave model in netcdf files
16   !!   sbc_wave_init : initialisation fo surface waves
17   !!----------------------------------------------------------------------
18   USE phycst         ! physical constants
19   USE oce            ! ocean variables
20   USE sbc_oce        ! Surface boundary condition: ocean fields
21   USE zdf_oce,  ONLY : ln_zdfqiao
22   USE bdy_oce        ! open boundary condition variables
23   USE domvvl         ! domain: variable volume layers
24   !
25   USE iom            ! I/O manager library
26   USE in_out_manager ! I/O manager
27   USE lib_mpp        ! distribued memory computing library
28   USE fldread        ! read input fields
29   USE wrk_nemo       !
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   sbc_stokes      ! routine called in sbccpl
35   PUBLIC   sbc_wstress     ! routine called in sbcmod
36   PUBLIC   sbc_wave        ! routine called in sbcmod
37   PUBLIC   sbc_wave_init   ! routine called in sbcmod
38   
39   ! Variables checking if the wave parameters are coupled (if not, they are read from file)
40   LOGICAL, PUBLIC ::   cpl_hsig   = .FALSE.
41   LOGICAL, PUBLIC ::   cpl_phioc  = .FALSE.
42   LOGICAL, PUBLIC ::   cpl_sdrftx = .FALSE.
43   LOGICAL, PUBLIC ::   cpl_sdrfty = .FALSE.
44   LOGICAL, PUBLIC ::   cpl_wper   = .FALSE.
45   LOGICAL, PUBLIC ::   cpl_wfreq  = .FALSE.
46   LOGICAL, PUBLIC ::   cpl_wnum   = .FALSE.
47   LOGICAL, PUBLIC ::   cpl_tauoc  = .FALSE.
48   LOGICAL, PUBLIC ::   cpl_tauw   = .FALSE.
49   LOGICAL, PUBLIC ::   cpl_wdrag  = .FALSE.
50
51   INTEGER ::   jpfld    ! number of files to read for stokes drift
52   INTEGER ::   jp_usd   ! index of stokes drift  (i-component) (m/s)    at T-point
53   INTEGER ::   jp_vsd   ! index of stokes drift  (j-component) (m/s)    at T-point
54   INTEGER ::   jp_hsw   ! index of significant wave hight      (m)      at T-point
55   INTEGER ::   jp_wmp   ! index of mean wave period            (s)      at T-point
56   INTEGER ::   jp_wfr   ! index of wave peak frequency         (1/s)    at T-point
57
58   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_cd      ! structure of input fields (file informations, fields read) Drag Coefficient
59   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_sd      ! structure of input fields (file informations, fields read) Stokes Drift
60   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_wn      ! structure of input fields (file informations, fields read) wave number for Qiao
61   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_tauoc   ! structure of input fields (file informations, fields read) normalized wave stress into the ocean
62   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_tauw    ! structure of input fields (file informations, fields read) ocean stress components from wave model
63
64   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   cdn_wave            !:
65   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   hsw, wmp, wnum      !:
66   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   wfreq               !:
67   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   tauoc_wave          !: 
68   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   tauw_x, tauw_y      !: 
69   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   tsd2d               !:
70   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   div_sd              !: barotropic stokes drift divergence
71   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   ut0sd, vt0sd        !: surface Stokes drift velocities at t-point
72   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:,:) ::   usd  , vsd  , wsd   !: Stokes drift velocities at u-, v- & w-points, resp.
73
74   !! * Substitutions
75#  include "vectopt_loop_substitute.h90"
76   !!----------------------------------------------------------------------
77   !! NEMO/OPA 3.7 , NEMO Consortium (2014)
78   !! $Id$
79   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
80   !!----------------------------------------------------------------------
81CONTAINS
82
83   SUBROUTINE sbc_stokes( )
84      !!---------------------------------------------------------------------
85      !!                     ***  ROUTINE sbc_stokes  ***
86      !!
87      !! ** Purpose :   compute the 3d Stokes Drift according to Breivik et al.,
88      !!                2014 (DOI: 10.1175/JPO-D-14-0020.1)
89      !!
90      !! ** Method  : - Calculate Stokes transport speed
91      !!              - Calculate horizontal divergence
92      !!              - Integrate the horizontal divergenze from the bottom
93      !! ** action 
94      !!---------------------------------------------------------------------
95      INTEGER  ::   jj, ji, jk   ! dummy loop argument
96      INTEGER  ::   ik           ! local integer
97      REAL(wp) ::  ztransp, zfac, ztemp, zsp0
98      REAL(wp) ::  zdep_u, zdep_v, zkh_u, zkh_v, zda_u, zda_v
99      REAL(wp), DIMENSION(:,:)  , POINTER ::   zk_t, zk_u, zk_v, zu0_sd, zv0_sd   ! 2D workspace
100      REAL(wp), DIMENSION(:,:,:), POINTER ::   ze3divh                            ! 3D workspace
101      !!---------------------------------------------------------------------
102      !
103      CALL wrk_alloc( jpi,jpj,jpk,   ze3divh )
104      CALL wrk_alloc( jpi,jpj,       zk_t, zk_u, zk_v, zu0_sd, zv0_sd )
105      !
106      ! select parameterization for the calculation of vertical Stokes drift
107      ! exp. wave number at t-point
108      IF( nn_sdrift==jp_breivik .OR. nn_sdrift==jp_phillips ) THEN   ! (Eq. (19) in Breivick et al. (2014) )
109         zfac = 2.0_wp * rpi / 16.0_wp
110         DO jj = 1, jpj
111            DO ji = 1, jpi
112               ! Stokes drift velocity estimated from Hs and Tmean
113               ztransp = zfac * hsw(ji,jj)*hsw(ji,jj) / MAX( wmp(ji,jj), 0.0000001_wp )
114               ! Stokes surface speed
115               tsd2d(ji,jj) = SQRT( ut0sd(ji,jj)*ut0sd(ji,jj) + vt0sd(ji,jj)*vt0sd(ji,jj))
116               ! Wavenumber scale
117               zk_t(ji,jj) = ABS( tsd2d(ji,jj) ) / MAX( ABS( 5.97_wp*ztransp ), 0.0000001_wp )
118            END DO
119         END DO
120         DO jj = 1, jpjm1              ! exp. wave number & Stokes drift velocity at u- & v-points
121            DO ji = 1, jpim1
122               zk_u(ji,jj) = 0.5_wp * ( zk_t(ji,jj) + zk_t(ji+1,jj) )
123               zk_v(ji,jj) = 0.5_wp * ( zk_t(ji,jj) + zk_t(ji,jj+1) )
124               !
125               zu0_sd(ji,jj) = 0.5_wp * ( ut0sd(ji,jj) + ut0sd(ji+1,jj) )
126               zv0_sd(ji,jj) = 0.5_wp * ( vt0sd(ji,jj) + vt0sd(ji,jj+1) )
127            END DO
128         END DO
129      ELSE IF( nn_sdrift==jp_peakfr ) THEN    ! peak wave number calculated from the peak frequency received by the wave model
130         DO jj = 1, jpjm1
131            DO ji = 1, jpim1
132               zk_u(ji,jj) = 0.5_wp * ( wfreq(ji,jj)*wfreq(ji,jj) + wfreq(ji+1,jj)*wfreq(ji+1,jj) ) / grav
133               zk_v(ji,jj) = 0.5_wp * ( wfreq(ji,jj)*wfreq(ji,jj) + wfreq(ji,jj+1)*wfreq(ji,jj+1) ) / grav
134               !
135               zu0_sd(ji,jj) = 0.5_wp * ( ut0sd(ji,jj) + ut0sd(ji+1,jj) )
136               zv0_sd(ji,jj) = 0.5_wp * ( vt0sd(ji,jj) + vt0sd(ji,jj+1) )
137            END DO
138         END DO
139      ENDIF
140      !
141      !                       !==  horizontal Stokes Drift 3D velocity  ==!
142      IF( nn_sdrift==jp_breivik ) THEN
143         DO jk = 1, jpkm1
144            DO jj = 2, jpjm1
145               DO ji = 2, jpim1
146                  zdep_u = 0.5_wp * ( gdept_n(ji,jj,jk) + gdept_n(ji+1,jj,jk) )
147                  zdep_v = 0.5_wp * ( gdept_n(ji,jj,jk) + gdept_n(ji,jj+1,jk) )
148                  !                         
149                  zkh_u = zk_u(ji,jj) * zdep_u     ! k * depth
150                  zkh_v = zk_v(ji,jj) * zdep_v
151                  !                                ! Depth attenuation
152                  zda_u = EXP( -2.0_wp*zkh_u ) / ( 1.0_wp + 8.0_wp*zkh_u )
153                  zda_v = EXP( -2.0_wp*zkh_v ) / ( 1.0_wp + 8.0_wp*zkh_v )
154                  !
155                  usd(ji,jj,jk) = zda_u * zu0_sd(ji,jj) * umask(ji,jj,jk)
156                  vsd(ji,jj,jk) = zda_v * zv0_sd(ji,jj) * vmask(ji,jj,jk)
157               END DO
158            END DO
159         END DO
160      ELSE IF( nn_sdrift==jp_phillips .OR. nn_sdrift==jp_peakfr ) THEN
161         DO jk = 1, jpkm1
162            DO jj = 2, jpjm1
163               DO ji = 2, jpim1
164                  zdep_u = 0.5_wp * ( gdept_n(ji,jj,jk) + gdept_n(ji+1,jj,jk) )
165                  zdep_v = 0.5_wp * ( gdept_n(ji,jj,jk) + gdept_n(ji,jj+1,jk) )
166                  !                         
167                  zkh_u = zk_u(ji,jj) * zdep_u     ! k * depth
168                  zkh_v = zk_v(ji,jj) * zdep_v
169                  !                                ! Depth attenuation
170                  zda_u = EXP( -2.0_wp*zkh_u ) - SQRT(2.0_wp*rpi*zkh_u) * ERFC(SQRT(2.0_wp*zkh_u))
171                  zda_v = EXP( -2.0_wp*zkh_v ) - SQRT(2.0_wp*rpi*zkh_v) * ERFC(SQRT(2.0_wp*zkh_v))
172                  !
173                  usd(ji,jj,jk) = zda_u * zu0_sd(ji,jj) * umask(ji,jj,jk)
174                  vsd(ji,jj,jk) = zda_v * zv0_sd(ji,jj) * vmask(ji,jj,jk)
175               END DO
176            END DO
177         END DO
178      ENDIF
179
180      CALL lbc_lnk( usd(:,:,:), 'U', vsd(:,:,:), 'V', -1. )
181      !
182      !                       !==  vertical Stokes Drift 3D velocity  ==!
183      !
184      DO jk = 1, jpkm1               ! Horizontal e3*divergence
185         DO jj = 2, jpj
186            DO ji = fs_2, jpi
187               ze3divh(ji,jj,jk) = (  e2u(ji  ,jj) * e3u_n(ji  ,jj,jk) * usd(ji  ,jj,jk)    &
188                  &                 - e2u(ji-1,jj) * e3u_n(ji-1,jj,jk) * usd(ji-1,jj,jk)    &
189                  &                 + e1v(ji,jj  ) * e3v_n(ji,jj  ,jk) * vsd(ji,jj  ,jk)    &
190                  &                 - e1v(ji,jj-1) * e3v_n(ji,jj-1,jk) * vsd(ji,jj-1,jk)  ) * r1_e1e2t(ji,jj)
191            END DO
192         END DO
193      END DO
194      !
195      IF( .NOT. AGRIF_Root() ) THEN
196         IF( nbondi ==  1 .OR. nbondi == 2 )   ze3divh(nlci-1,   :  ,:) = 0._wp      ! east
197         IF( nbondi == -1 .OR. nbondi == 2 )   ze3divh(  2   ,   :  ,:) = 0._wp      ! west
198         IF( nbondj ==  1 .OR. nbondj == 2 )   ze3divh(  :   ,nlcj-1,:) = 0._wp      ! north
199         IF( nbondj == -1 .OR. nbondj == 2 )   ze3divh(  :   ,  2   ,:) = 0._wp      ! south
200      ENDIF
201      !
202      CALL lbc_lnk( ze3divh, 'T', 1. )
203      !
204      IF( ln_linssh ) THEN   ;   ik = 1   ! none zero velocity through the sea surface
205      ELSE                   ;   ik = 2   ! w=0 at the surface (set one for all in sbc_wave_init)
206      ENDIF
207      DO jk = jpkm1, ik, -1          ! integrate from the bottom the hor. divergence (NB: at k=jpk w is always zero)
208         wsd(:,:,jk) = wsd(:,:,jk+1) - ze3divh(:,:,jk)
209      END DO
210      !
211      IF( ln_bdy ) THEN
212         DO jk = 1, jpkm1
213            wsd(:,:,jk) = wsd(:,:,jk) * bdytmask(:,:)
214         END DO
215      ENDIF
216      !                       !==  Horizontal divergence of barotropic Stokes transport  ==!
217      div_sd(:,:) = 0._wp
218      DO jk = 1, jpkm1                                 !
219        div_sd(:,:) = div_sd(:,:) + ze3divh(:,:,jk)
220      END DO
221      !
222      CALL iom_put( "ustokes",  usd  )
223      CALL iom_put( "vstokes",  vsd  )
224      CALL iom_put( "wstokes",  wsd  )
225      !
226      CALL wrk_dealloc( jpi,jpj,jpk,   ze3divh )
227      CALL wrk_dealloc( jpi,jpj,       zk_t, zk_u, zk_v, zu0_sd, zv0_sd )
228      !
229   END SUBROUTINE sbc_stokes
230
231
232   SUBROUTINE sbc_wstress( )
233      !!---------------------------------------------------------------------
234      !!                     ***  ROUTINE sbc_wstress  ***
235      !!
236      !! ** Purpose :   Updates the ocean momentum modified by waves
237      !!
238      !! ** Method  : - Calculate u,v components of stress depending on stress
239      !!                model
240      !!              - Calculate the stress module
241      !!              - The wind module is not modified by waves
242      !! ** action 
243      !!---------------------------------------------------------------------
244      INTEGER  ::   jj, ji   ! dummy loop argument
245      !
246      IF( ln_tauoc ) THEN
247         utau(:,:) = utau(:,:)*tauoc_wave(:,:)
248         vtau(:,:) = vtau(:,:)*tauoc_wave(:,:)
249         taum(:,:) = taum(:,:)*tauoc_wave(:,:)
250      ENDIF
251      !
252      IF( ln_tauw ) THEN
253         DO jj = 1, jpjm1
254            DO ji = 1, jpim1
255               ! Stress components at u- & v-points
256               utau(ji,jj) = 0.5_wp * ( tauw_x(ji,jj) + tauw_x(ji+1,jj) )
257               vtau(ji,jj) = 0.5_wp * ( tauw_y(ji,jj) + tauw_y(ji,jj+1) )
258               !
259               ! Stress module at t points
260               taum(ji,jj) = SQRT( tauw_x(ji,jj)*tauw_x(ji,jj) + tauw_y(ji,jj)*tauw_y(ji,jj) )
261            END DO
262         END DO
263
264      ENDIF
265      !
266   END SUBROUTINE sbc_wstress
267
268
269   SUBROUTINE sbc_wave( kt )
270      !!---------------------------------------------------------------------
271      !!                     ***  ROUTINE sbc_wave  ***
272      !!
273      !! ** Purpose :   read wave parameters from wave model  in netcdf files.
274      !!
275      !! ** Method  : - Read namelist namsbc_wave
276      !!              - Read Cd_n10 fields in netcdf files
277      !!              - Read stokes drift 2d in netcdf files
278      !!              - Read wave number in netcdf files
279      !!              - Compute 3d stokes drift using Breivik et al.,2014
280      !!                formulation
281      !! ** action 
282      !!---------------------------------------------------------------------
283      INTEGER, INTENT(in   ) ::   kt   ! ocean time step
284      !!---------------------------------------------------------------------
285      !
286      IF( ln_cdgw .AND. .NOT. cpl_wdrag ) THEN     !==  Neutral drag coefficient  ==!
287         CALL fld_read( kt, nn_fsbc, sf_cd )             ! read from external forcing
288         cdn_wave(:,:) = sf_cd(1)%fnow(:,:,1)
289      ENDIF
290
291      IF( ln_tauoc .AND. .NOT. cpl_tauoc ) THEN    !==  Wave induced stress  ==!
292         CALL fld_read( kt, nn_fsbc, sf_tauoc )          ! read wave norm stress from external forcing
293         tauoc_wave(:,:) = sf_tauoc(1)%fnow(:,:,1)
294      ENDIF
295
296      IF( ln_tauw .AND. .NOT. cpl_tauw ) THEN      !==  Wave induced stress  ==!
297         CALL fld_read( kt, nn_fsbc, sf_tauw )           ! read ocean stress components from external forcing (T grid)
298         tauw_x(:,:) = sf_tauw(1)%fnow(:,:,1)
299         tauw_y(:,:) = sf_tauw(2)%fnow(:,:,1)
300      ENDIF
301
302      IF( ln_sdw )  THEN                           !==  Computation of the 3d Stokes Drift  ==!
303         !
304         IF( jpfld > 0 ) THEN                            ! Read from file only if the field is not coupled
305            CALL fld_read( kt, nn_fsbc, sf_sd )          ! read wave parameters from external forcing
306            IF( jp_hsw > 0 )   hsw  (:,:) = sf_sd(jp_hsw)%fnow(:,:,1)   ! significant wave height
307            IF( jp_wmp > 0 )   wmp  (:,:) = sf_sd(jp_wmp)%fnow(:,:,1)   ! wave mean period
308            IF( jp_wfr > 0 )   wfreq(:,:) = sf_sd(jp_wfr)%fnow(:,:,1)   ! Peak wave frequency
309            IF( jp_usd > 0 )   ut0sd(:,:) = sf_sd(jp_usd)%fnow(:,:,1)   ! 2D zonal Stokes Drift at T point
310            IF( jp_vsd > 0 )   vt0sd(:,:) = sf_sd(jp_vsd)%fnow(:,:,1)   ! 2D meridional Stokes Drift at T point
311         ENDIF
312         !
313         ! Read also wave number if needed, so that it is available in coupling routines
314         IF( ln_zdfqiao .AND. .NOT.cpl_wnum ) THEN
315            CALL fld_read( kt, nn_fsbc, sf_wn )          ! read wave parameters from external forcing
316            wnum(:,:) = sf_wn(1)%fnow(:,:,1)
317         ENDIF
318           
319         !                                         !==  Computation of the 3d Stokes Drift  ==!
320         !
321         IF( ((nn_sdrift==jp_breivik .OR. nn_sdrift==jp_phillips) .AND. &
322                          jp_hsw>0 .AND. jp_wmp>0 .AND. jp_usd>0 .AND. jp_vsd>0) .OR. &
323             (nn_sdrift==jp_peakfr .AND. jp_wfr>0 .AND. jp_usd>0 .AND. jp_vsd>0) ) &
324            CALL sbc_stokes()            ! Calculate only if required fields are read
325         !                               ! In coupled wave model-NEMO case the call is done after coupling
326         !
327      ENDIF
328      !
329   END SUBROUTINE sbc_wave
330
331
332   SUBROUTINE sbc_wave_init
333      !!---------------------------------------------------------------------
334      !!                     ***  ROUTINE sbc_wave_init  ***
335      !!
336      !! ** Purpose :   read wave parameters from wave model  in netcdf files.
337      !!
338      !! ** Method  : - Read namelist namsbc_wave
339      !!              - Read Cd_n10 fields in netcdf files
340      !!              - Read stokes drift 2d in netcdf files
341      !!              - Read wave number in netcdf files
342      !!              - Compute 3d stokes drift using Breivik et al.,2014
343      !!                formulation
344      !! ** action 
345      !!---------------------------------------------------------------------
346      INTEGER ::   ierror, ios   ! local integer
347      INTEGER ::   ifpr
348      !!
349      CHARACTER(len=100)     ::  cn_dir                          ! Root directory for location of drag coefficient files
350      TYPE(FLD_N), ALLOCATABLE, DIMENSION(:) ::   slf_i, slf_j     ! array of namelist informations on the fields to read
351      TYPE(FLD_N)            ::  sn_cdg, sn_usd, sn_vsd,  &
352                             &   sn_hsw, sn_wmp, sn_wfr, sn_wnum, &
353                             &   sn_tauoc, sn_tauwx, sn_tauwy      ! informations about the fields to be read
354      !
355      NAMELIST/namsbc_wave/  sn_cdg, cn_dir, sn_usd, sn_vsd, sn_hsw, sn_wmp, sn_wfr, &
356                             sn_wnum, sn_tauoc, sn_tauwx, sn_tauwy
357      !!---------------------------------------------------------------------
358      !
359      REWIND( numnam_ref )              ! Namelist namsbc_wave in reference namelist : File for drag coeff. from wave model
360      READ  ( numnam_ref, namsbc_wave, IOSTAT = ios, ERR = 901)
361901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_wave in reference namelist', lwp )
362         
363      REWIND( numnam_cfg )              ! Namelist namsbc_wave in configuration namelist : File for drag coeff. from wave model
364      READ  ( numnam_cfg, namsbc_wave, IOSTAT = ios, ERR = 902 )
365902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_wave in configuration namelist', lwp )
366      IF(lwm) WRITE ( numond, namsbc_wave )
367      !
368      IF( ln_cdgw ) THEN
369         IF( .NOT. cpl_wdrag ) THEN
370            ALLOCATE( sf_cd(1), STAT=ierror )           !* allocate and fill sf_wave with sn_cdg
371            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable to allocate sf_wave structure' )
372            !
373                                   ALLOCATE( sf_cd(1)%fnow(jpi,jpj,1)   )
374            IF( sn_cdg%ln_tint )   ALLOCATE( sf_cd(1)%fdta(jpi,jpj,1,2) )
375            CALL fld_fill( sf_cd, (/ sn_cdg /), cn_dir, 'sbc_wave_init', 'Wave module ', 'namsbc_wave' )
376         ENDIF
377         ALLOCATE( cdn_wave(jpi,jpj) )
378      ENDIF
379
380      IF( ln_tauoc ) THEN
381         IF( .NOT. cpl_tauoc ) THEN
382            ALLOCATE( sf_tauoc(1), STAT=ierror )           !* allocate and fill sf_wave with sn_tauoc
383            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable to allocate sf_wave structure' )
384            !
385                                    ALLOCATE( sf_tauoc(1)%fnow(jpi,jpj,1)   )
386            IF( sn_tauoc%ln_tint )  ALLOCATE( sf_tauoc(1)%fdta(jpi,jpj,1,2) )
387            CALL fld_fill( sf_tauoc, (/ sn_tauoc /), cn_dir, 'sbc_wave_init', 'Wave module', 'namsbc_wave' )
388         ENDIF
389         ALLOCATE( tauoc_wave(jpi,jpj) )
390      ENDIF
391
392      IF( ln_tauw ) THEN
393         IF( .NOT. cpl_tauw ) THEN
394            ALLOCATE( sf_tauw(2), STAT=ierror )           !* allocate and fill sf_wave with sn_tauwx/y
395            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable to allocate sf_tauw structure' )
396            !
397            ALLOCATE( slf_j(2) )
398            slf_j(1) = sn_tauwx
399            slf_j(2) = sn_tauwy
400                                    ALLOCATE( sf_tauw(1)%fnow(jpi,jpj,1)   )
401                                    ALLOCATE( sf_tauw(2)%fnow(jpi,jpj,1)   )
402            IF( slf_j(1)%ln_tint )  ALLOCATE( sf_tauw(1)%fdta(jpi,jpj,1,2) )
403            IF( slf_j(2)%ln_tint )  ALLOCATE( sf_tauw(2)%fdta(jpi,jpj,1,2) )
404            CALL fld_fill( sf_tauw, (/ slf_j /), cn_dir, 'sbc_wave_init', 'read wave input', 'namsbc_wave' )
405         ENDIF
406         ALLOCATE( tauw_x(jpi,jpj) )
407         ALLOCATE( tauw_y(jpi,jpj) )
408      ENDIF
409
410      IF( ln_sdw ) THEN   ! Find out how many fields have to be read from file if not coupled
411         jpfld=0
412         jp_usd=0   ;   jp_vsd=0   ;   jp_hsw=0   ;   jp_wmp=0   ;   jp_wfr=0
413         IF( .NOT. cpl_sdrftx ) THEN
414            jpfld  = jpfld + 1
415            jp_usd = jpfld
416         ENDIF
417         IF( .NOT. cpl_sdrfty ) THEN
418            jpfld  = jpfld + 1
419            jp_vsd = jpfld
420         ENDIF
421         IF( .NOT. cpl_hsig .AND. (nn_sdrift==jp_breivik .OR. nn_sdrift==jp_phillips) ) THEN
422            jpfld  = jpfld + 1
423            jp_hsw = jpfld
424         ENDIF
425         IF( .NOT. cpl_wper .AND. (nn_sdrift==jp_breivik .OR. nn_sdrift==jp_phillips) ) THEN
426            jpfld  = jpfld + 1
427            jp_wmp = jpfld
428         ENDIF
429         IF( .NOT. cpl_wfreq .AND. nn_sdrift==jp_peakfr ) THEN
430            jpfld  = jpfld + 1
431            jp_wfr = jpfld
432         ENDIF
433
434         ! Read from file only the non-coupled fields
435         IF( jpfld > 0 ) THEN
436            ALLOCATE( slf_i(jpfld) )
437            IF( jp_usd > 0 )   slf_i(jp_usd) = sn_usd
438            IF( jp_vsd > 0 )   slf_i(jp_vsd) = sn_vsd
439            IF( jp_hsw > 0 )   slf_i(jp_hsw) = sn_hsw
440            IF( jp_wmp > 0 )   slf_i(jp_wmp) = sn_wmp
441            IF( jp_wfr > 0 )   slf_i(jp_wfr) = sn_wfr
442
443            ALLOCATE( sf_sd(jpfld), STAT=ierror )   !* allocate and fill sf_sd with stokes drift
444            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable to allocate sf_wave structure' )
445            !
446            DO ifpr= 1, jpfld
447               ALLOCATE( sf_sd(ifpr)%fnow(jpi,jpj,1) )
448               IF( slf_i(ifpr)%ln_tint )   ALLOCATE( sf_sd(ifpr)%fdta(jpi,jpj,1,2) )
449            END DO
450            !
451            CALL fld_fill( sf_sd, slf_i, cn_dir, 'sbc_wave_init', 'Wave module ', 'namsbc_wave' )
452         ENDIF
453         ALLOCATE( usd  (jpi,jpj,jpk), vsd  (jpi,jpj,jpk), wsd(jpi,jpj,jpk) )
454         ALLOCATE( hsw  (jpi,jpj)    , wmp  (jpi,jpj)     )
455         ALLOCATE( wfreq(jpi,jpj) )
456         ALLOCATE( ut0sd(jpi,jpj)    , vt0sd(jpi,jpj)     )
457         ALLOCATE( div_sd(jpi,jpj) )
458         ALLOCATE( tsd2d (jpi,jpj) )
459         usd(:,:,:) = 0._wp
460         vsd(:,:,:) = 0._wp
461         wsd(:,:,:) = 0._wp
462         ! Wave number needed only if ln_zdfqiao=T
463         IF( .NOT. cpl_wnum ) THEN
464            ALLOCATE( sf_wn(1), STAT=ierror )           !* allocate and fill sf_wave with sn_wnum
465            IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable toallocate sf_wave structure' )
466                                   ALLOCATE( sf_wn(1)%fnow(jpi,jpj,1)   )
467            IF( sn_wnum%ln_tint )  ALLOCATE( sf_wn(1)%fdta(jpi,jpj,1,2) )
468            CALL fld_fill( sf_wn, (/ sn_wnum /), cn_dir, 'sbc_wave', 'Wave module', 'namsbc_wave' )
469         ENDIF
470         ALLOCATE( wnum(jpi,jpj) )
471      ENDIF
472      !
473   END SUBROUTINE sbc_wave_init
474
475   !!======================================================================
476END MODULE sbcwave
Note: See TracBrowser for help on using the repository browser.