New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

nemogcm.F90 in branches/UKMO/r8727_WAVE-2_Clementi_add_coupling/NEMOGCM/NEMO/OPA_SRC – NEMO

Context Navigation

source: branches/UKMO/r8727_WAVE-2_Clementi_add_coupling/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 8749

Last change on this file since 8749 was 8749, checked in by jcastill, 6 years ago
Remove svn keywords
File size: 40.8 KB

Line
1	MODULE nemogcm
2	!!======================================================================
3	!! * MODULE nemogcm *
4	!! Ocean system : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5	!!======================================================================
6	!! History : OPA ! 1990-10 (C. Levy, G. Madec) Original code
7	!! 7.0 ! 1991-11 (M. Imbard, C. Levy, G. Madec)
8	!! 7.1 ! 1993-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9	!! P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10	!! - ! 1992-06 (L.Terray) coupling implementation
11	!! - ! 1993-11 (M.A. Filiberti) IGLOO sea-ice
12	!! 8.0 ! 1996-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13	!! P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14	!! 8.1 ! 1997-06 (M. Imbard, G. Madec)
15	!! 8.2 ! 1999-11 (M. Imbard, H. Goosse) LIM sea-ice model
16	!! ! 1999-12 (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols) OPEN-MP
17	!! ! 2000-07 (J-M Molines, M. Imbard) Open Boundary Conditions (CLIPPER)
18	!! NEMO 1.0 ! 2002-08 (G. Madec) F90: Free form and modules
19	!! - ! 2004-06 (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20	!! - ! 2004-08 (C. Talandier) New trends organization
21	!! - ! 2005-06 (C. Ethe) Add the 1D configuration possibility
22	!! - ! 2005-11 (V. Garnier) Surface pressure gradient organization
23	!! - ! 2006-03 (L. Debreu, C. Mazauric) Agrif implementation
24	!! - ! 2006-04 (G. Madec, R. Benshila) Step reorganization
25	!! - ! 2007-07 (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26	!! 3.2 ! 2009-08 (S. Masson) open/write in the listing file in mpp
27	!! 3.3 ! 2010-05 (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28	!! - ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase
29	!! 3.3.1! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation
30	!! 3.4 ! 2011-10 (A. C. Coward, NOCS & J. Donners, PRACE) add nemo_northcomms
31	!! - ! 2011-11 (C. Harris) decomposition changes for running with CICE
32	!! 3.6 ! 2012-05 (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
33	!! - ! 2013-06 (I. Epicoco, S. Mocavero, CMCC) nemo_northcomms: setup avoiding MPI communication
34	!! - ! 2014-12 (G. Madec) remove KPP scheme and cross-land advection (cla)
35	!! 4.0 ! 2016-10 (G. Madec, S. Flavoni) domain configuration / user defined interface
36	!!----------------------------------------------------------------------
37
38	!!----------------------------------------------------------------------
39	!! nemo_gcm : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
40	!! nemo_init : initialization of the NEMO system
41	!! nemo_ctl : initialisation of the contol print
42	!! nemo_closefile: close remaining open files
43	!! nemo_alloc : dynamical allocation
44	!! nemo_partition: calculate MPP domain decomposition
45	!! factorise : calculate the factors of the no. of MPI processes
46	!!----------------------------------------------------------------------
47	USE step_oce ! module used in the ocean time stepping module (step.F90)
48	USE phycst ! physical constant (par_cst routine)
49	USE domain ! domain initialization (dom_init & dom_cfg routines)
50	USE usrdef_nam ! user defined configuration
51	USE tideini ! tidal components initialization (tide_ini routine)
52	USE bdy_oce, ONLY: ln_bdy
53	USE bdyini ! open boundary cond. setting (bdy_init routine)
54	USE istate ! initial state setting (istate_init routine)
55	USE ldfdyn ! lateral viscosity setting (ldfdyn_init routine)
56	USE ldftra ! lateral diffusivity setting (ldftra_init routine)
57	USE zdfini ! vertical physics setting (zdf_init routine)
58	USE trdini ! dyn/tra trends initialization (trd_init routine)
59	USE asminc ! assimilation increments
60	USE asmbkg ! writing out state trajectory
61	USE diaptr ! poleward transports (dia_ptr_init routine)
62	USE diadct ! sections transports (dia_dct_init routine)
63	USE diaobs ! Observation diagnostics (dia_obs_init routine)
64	USE diacfl ! CFL diagnostics (dia_cfl_init routine)
65	USE step ! NEMO time-stepping (stp routine)
66	USE icbini ! handle bergs, initialisation
67	USE icbstp ! handle bergs, calving, themodynamics and transport
68	USE cpl_oasis3 ! OASIS3 coupling
69	USE c1d ! 1D configuration
70	USE step_c1d ! Time stepping loop for the 1D configuration
71	USE dyndmp ! Momentum damping
72	USE stopar ! Stochastic param.: ???
73	USE stopts ! Stochastic param.: ???
74	USE diurnal_bulk ! diurnal bulk SST
75	USE step_diu ! diurnal bulk SST timestepping (called from here if run offline)
76	USE crsini ! initialise grid coarsening utility
77	USE diatmb ! Top,middle,bottom output
78	USE dia25h ! 25h mean output
79	USE sbc_oce , ONLY : lk_oasis
80	USE wet_dry ! Wetting and drying setting (wad_init routine)
81	#if defined key_top
82	USE trcini ! passive tracer initialisation
83	#endif
84	#if defined key_nemocice_decomp
85	USE ice_domain_size, only: nx_global, ny_global
86	#endif
87	!
88	USE lib_mpp ! distributed memory computing
89	USE mppini ! shared/distributed memory setting (mpp_init routine)
90	USE lbcnfd , ONLY : isendto, nsndto, nfsloop, nfeloop ! Setup of north fold exchanges
91	USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
92	#if defined key_iomput
93	USE xios ! xIOserver
94	#endif
95
96	IMPLICIT NONE
97	PRIVATE
98
99	PUBLIC nemo_gcm ! called by model.F90
100	PUBLIC nemo_init ! needed by AGRIF
101	PUBLIC nemo_alloc ! needed by TAM
102
103	CHARACTER(lc) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing
104
105	!!----------------------------------------------------------------------
106	!! NEMO/OPA 3.7 , NEMO Consortium (2016)
107	!! $Id$
108	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
109	!!----------------------------------------------------------------------
110	CONTAINS
111
112	SUBROUTINE nemo_gcm
113	!!----------------------------------------------------------------------
114	!! * ROUTINE nemo_gcm *
115	!!
116	!! ** Purpose : NEMO solves the primitive equations on an orthogonal
117	!! curvilinear mesh on the sphere.
118	!!
119	!! ** Method : - model general initialization
120	!! - launch the time-stepping (stp routine)
121	!! - finalize the run by closing files and communications
122	!!
123	!! References : Madec, Delecluse, Imbard, and Levy, 1997: internal report, IPSL.
124	!! Madec, 2008, internal report, IPSL.
125	!!----------------------------------------------------------------------
126	INTEGER :: istp ! time step index
127	!!----------------------------------------------------------------------
128	!
129	#if defined key_agrif
130	CALL Agrif_Init_Grids() ! AGRIF: set the meshes
131	#endif
132	!
133	! !-----------------------!
134	CALL nemo_init !== Initialisations ==!
135	! !-----------------------!
136	#if defined key_agrif
137	CALL Agrif_Declare_Var_dom ! AGRIF: set the meshes for DOM
138	CALL Agrif_Declare_Var ! " " " " " DYN/TRA
139	# if defined key_top
140	CALL Agrif_Declare_Var_top ! " " " " " TOP
141	# endif
142	# if defined key_lim2
143	CALL Agrif_Declare_Var_lim2 ! " " " " " LIM2
144	# endif
145	# if defined key_lim3
146	CALL Agrif_Declare_Var_lim3 ! " " " " " LIM3
147	# endif
148	#endif
149	! check that all process are still there... If some process have an error,
150	! they will never enter in step and other processes will wait until the end of the cpu time!
151	IF( lk_mpp ) CALL mpp_max( nstop )
152
153	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
154
155	! !-----------------------!
156	! !== time stepping ==!
157	! !-----------------------!
158	istp = nit000
159	#if defined key_c1d
160	DO WHILE ( istp <= nitend .AND. nstop == 0 )
161	CALL stp_c1d( istp )
162	istp = istp + 1
163	END DO
164	#else
165	IF( lk_asminc ) THEN
166	IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 ) ! Output background fields
167	IF( ln_asmdin ) THEN ! Direct initialization
168	IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 ) ! Tracers
169	IF( ln_dyninc ) CALL dyn_asm_inc( nit000 - 1 ) ! Dynamics
170	IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 ) ! SSH
171	ENDIF
172	ENDIF
173
174	#if defined key_agrif
175	CALL Agrif_Regrid()
176	#endif
177
178	DO WHILE ( istp <= nitend .AND. nstop == 0 )
179	#if defined key_agrif
180	CALL stp ! AGRIF: time stepping
181	#else
182	IF ( .NOT. ln_diurnal_only ) THEN
183	CALL stp( istp ) ! standard time stepping
184	ELSE
185	CALL stp_diurnal( istp ) ! time step only the diurnal SST
186	ENDIF
187	#endif
188	istp = istp + 1
189	IF( lk_mpp ) CALL mpp_max( nstop )
190	END DO
191	#endif
192
193	IF( ln_diaobs ) CALL dia_obs_wri
194	!
195	IF( ln_icebergs ) CALL icb_end( nitend )
196
197	! !------------------------!
198	! !== finalize the run ==!
199	! !------------------------!
200	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
201	!
202	IF( nstop /= 0 .AND. lwp ) THEN ! error print
203	WRITE(numout,cform_err)
204	WRITE(numout,*) nstop, ' error have been found'
205	ENDIF
206	!
207	#if defined key_agrif
208	CALL Agrif_ParentGrid_To_ChildGrid()
209	IF( ln_diaobs ) CALL dia_obs_wri
210	IF( nn_timing == 1 ) CALL timing_finalize
211	CALL Agrif_ChildGrid_To_ParentGrid()
212	#endif
213	IF( nn_timing == 1 ) CALL timing_finalize
214	!
215	CALL nemo_closefile
216	!
217	#if defined key_iomput
218	CALL xios_finalize ! end mpp communications with xios
219	IF( lk_oasis ) CALL cpl_finalize ! end coupling and mpp communications with OASIS
220	#else
221	IF( lk_oasis ) THEN
222	CALL cpl_finalize ! end coupling and mpp communications with OASIS
223	ELSE
224	IF( lk_mpp ) CALL mppstop ! end mpp communications
225	ENDIF
226	#endif
227	!
228	END SUBROUTINE nemo_gcm
229
230
231	SUBROUTINE nemo_init
232	!!----------------------------------------------------------------------
233	!! * ROUTINE nemo_init *
234	!!
235	!! ** Purpose : initialization of the NEMO GCM
236	!!----------------------------------------------------------------------
237	INTEGER :: ji ! dummy loop indices
238	INTEGER :: ios, ilocal_comm ! local integer
239	CHARACTER(len=120), DIMENSION(30) :: cltxt, cltxt2, clnam
240	!
241	NAMELIST/namctl/ ln_ctl , nn_print, nn_ictls, nn_ictle, &
242	& nn_isplt , nn_jsplt, nn_jctls, nn_jctle, &
243	& nn_timing, nn_diacfl
244	NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_write_cfg, cn_domcfg_out, ln_use_jattr
245	!!----------------------------------------------------------------------
246	!
247	cltxt = ''
248	cltxt2 = ''
249	clnam = ''
250	cxios_context = 'nemo'
251	!
252	! ! Open reference namelist and configuration namelist files
253	CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
254	CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
255	!
256	REWIND( numnam_ref ) ! Namelist namctl in reference namelist : Control prints
257	READ ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
258	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
259	!
260	REWIND( numnam_cfg ) ! Namelist namctl in confguration namelist
261	READ ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
262	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
263	!
264	REWIND( numnam_ref ) ! Namelist namcfg in reference namelist : Control prints
265	READ ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
266	903 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
267
268	REWIND( numnam_cfg ) ! Namelist namcfg in confguration namelist : Control prints & Benchmark
269	READ ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
270	904 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )
271
272	! !--------------------------!
273	! ! Set global domain size ! (control print return in cltxt2)
274	! !--------------------------!
275	IF( ln_read_cfg ) THEN ! Read sizes in domain configuration file
276	CALL domain_cfg ( cltxt2, cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
277	!
278	ELSE ! user-defined namelist
279	CALL usr_def_nam( cltxt2, clnam, cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
280	ENDIF
281	!
282	jpk = jpkglo
283	!
284	#if defined key_agrif
285	IF( .NOT. Agrif_Root() ) THEN ! AGRIF children: specific setting (cf. agrif_user.F90)
286	jpiglo = nbcellsx + 2 + 2*nbghostcells
287	jpjglo = nbcellsy + 2 + 2*nbghostcells
288	jpi = ( jpiglo-2jpreci + (jpni-1+0) ) / jpni + 2jpreci
289	jpj = ( jpjglo-2jprecj + (jpnj-1+0) ) / jpnj + 2jprecj
290	nperio = 0
291	jperio = 0
292	ln_use_jattr = .false.
293	ENDIF
294	#endif
295	!
296	! !--------------------------------------------!
297	! ! set communicator & select the local node !
298	! ! NB: mynode also opens output.namelist.dyn !
299	! ! on unit number numond on first proc !
300	! !--------------------------------------------!
301	#if defined key_iomput
302	IF( Agrif_Root() ) THEN
303	IF( lk_oasis ) THEN
304	CALL cpl_init( "oceanx", ilocal_comm ) ! nemo local communicator given by oasis
305	CALL xios_initialize( "not used" ,local_comm= ilocal_comm ) ! send nemo communicator to xios
306	ELSE
307	CALL xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm ) ! nemo local communicator given by xios
308	ENDIF
309	ENDIF
310	! Nodes selection (control print return in cltxt)
311	narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
312	#else
313	IF( lk_oasis ) THEN
314	IF( Agrif_Root() ) THEN
315	CALL cpl_init( "oceanx", ilocal_comm ) ! nemo local communicator given by oasis
316	ENDIF
317	! Nodes selection (control print return in cltxt)
318	narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
319	ELSE
320	ilocal_comm = 0 ! Nodes selection (control print return in cltxt)
321	narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )
322	ENDIF
323	#endif
324
325	narea = narea + 1 ! mynode return the rank of proc (0 --> jpnij -1 )
326
327	lwm = (narea == 1) ! control of output namelists
328	lwp = (narea == 1) .OR. ln_ctl ! control of all listing output print
329
330	IF(lwm) THEN ! write merged namelists from earlier to output namelist
331	! ! now that the file has been opened in call to mynode.
332	! ! NB: nammpp has already been written in mynode (if lk_mpp_mpi)
333	WRITE( numond, namctl )
334	WRITE( numond, namcfg )
335	IF( .NOT.ln_read_cfg ) THEN
336	DO ji = 1, SIZE(clnam)
337	IF( TRIM(clnam(ji)) /= '' ) WRITE(numond, * ) clnam(ji) ! namusr_def print
338	END DO
339	ENDIF
340	ENDIF
341
342	! If dimensions of processor grid weren't specified in the namelist file
343	! then we calculate them here now that we have our communicator size
344	IF( jpni < 1 .OR. jpnj < 1 ) THEN
345	#if defined key_mpp_mpi
346	IF( Agrif_Root() ) CALL nemo_partition( mppsize )
347	#else
348	jpni = 1
349	jpnj = 1
350	jpnij = jpni*jpnj
351	#endif
352	ENDIF
353
354	IF( Agrif_Root() ) THEN ! AGRIF mother: specific setting from jpni and jpnj
355	#if defined key_nemocice_decomp
356	jpi = ( nx_global+2-2jpreci + (jpni-1) ) / jpni + 2jpreci ! first dim.
357	jpj = ( ny_global+2-2jprecj + (jpnj-1) ) / jpnj + 2jprecj ! second dim.
358	#else
359	jpi = ( jpiglo -2jpreci + (jpni-1) ) / jpni + 2jpreci ! first dim.
360	jpj = ( jpjglo -2jprecj + (jpnj-1) ) / jpnj + 2jprecj ! second dim.
361	#endif
362	ENDIF
363
364	!!gm ??? why here it has already been done in line 301 !
365	jpk = jpkglo ! third dim
366	!!gm end
367
368	#if defined key_agrif
369	! simple trick to use same vertical grid as parent but different number of levels:
370	! Save maximum number of levels in jpkglo, then define all vertical grids with this number.
371	! Suppress once vertical online interpolation is ok
372	IF(.NOT.Agrif_Root()) jpkglo = Agrif_Parent( jpkglo )
373	#endif
374	jpim1 = jpi-1 ! inner domain indices
375	jpjm1 = jpj-1 ! " "
376	jpkm1 = MAX( 1, jpk-1 ) ! " "
377	jpij = jpi*jpj ! jpi x j
378
379	IF(lwp) THEN ! open listing units
380	!
381	CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
382	!
383	WRITE(numout,*)
384	WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
385	WRITE(numout,*) ' NEMO team'
386	WRITE(numout,*) ' Ocean General Circulation Model'
387	WRITE(numout,*) ' NEMO version 3.7 (2016) '
388	WRITE(numout,*)
389	WRITE(numout,*)
390	DO ji = 1, SIZE(cltxt)
391	IF( TRIM(cltxt (ji)) /= '' ) WRITE(numout,*) cltxt(ji) ! control print of mynode
392	END DO
393	WRITE(numout,*)
394	WRITE(numout,*)
395	DO ji = 1, SIZE(cltxt2)
396	IF( TRIM(cltxt2(ji)) /= '' ) WRITE(numout,*) cltxt2(ji) ! control print of domain size
397	END DO
398	!
399	WRITE(numout,cform_aaa) ! Flag AAAAAAA
400	!
401	ENDIF
402
403	! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
404	CALL nemo_alloc()
405
406	! !-------------------------------!
407	! ! NEMO general initialization !
408	! !-------------------------------!
409
410	CALL nemo_ctl ! Control prints
411
412	! ! Domain decomposition
413	IF( jpni*jpnj == jpnij ) THEN ; CALL mpp_init ! standard cutting out
414	ELSE ; CALL mpp_init2 ! eliminate land processors
415	ENDIF
416	!
417	IF( nn_timing == 1 ) CALL timing_init
418	!
419	! ! General initialization
420	CALL phy_cst ! Physical constants
421	CALL eos_init ! Equation of state
422	IF( lk_c1d ) CALL c1d_init ! 1D column configuration
423	CALL wad_init ! Wetting and drying options
424	CALL dom_init ! Domain
425	IF( ln_crs ) CALL crs_init ! coarsened grid: domain initialization
426	IF( ln_nnogather ) CALL nemo_northcomms! northfold neighbour lists (must be done after the masks are defined)
427	IF( ln_ctl ) CALL prt_ctl_init ! Print control
428
429	CALL diurnal_sst_bulk_init ! diurnal sst
430	IF ( ln_diurnal ) CALL diurnal_sst_coolskin_init ! cool skin
431
432	! IF ln_diurnal_only, then we only want a subset of the initialisation routines
433	IF ( ln_diurnal_only ) THEN
434	CALL istate_init ! ocean initial state (Dynamics and tracers)
435	CALL sbc_init ! Forcings : surface module
436	CALL tra_qsr_init ! penetrative solar radiation qsr
437	IF( ln_diaobs ) THEN ! Observation & model comparison
438	CALL dia_obs_init ! Initialize observational data
439	CALL dia_obs( nit000 - 1 ) ! Observation operator for restart
440	ENDIF
441	! ! Assimilation increments
442	IF( lk_asminc ) CALL asm_inc_init ! Initialize assimilation increments
443
444	IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
445	RETURN
446	ENDIF
447
448	CALL istate_init ! ocean initial state (Dynamics and tracers)
449
450	! ! external forcing
451	!!gm to be added : creation and call of sbc_apr_init
452	!==> cbr: sbc_apr_init in sbcmod as sbc_rnf_init
453	CALL tide_init ! tidal harmonics
454	CALL sbc_init ! surface boundary conditions (including sea-ice)
455	CALL bdy_init ! Open boundaries initialisation
456	! ! Ocean physics
457	! ! Vertical physics
458	CALL zdf_init ! namelist read
459	CALL zdf_bfr_init ! bottom friction
460	IF( lk_zdfric ) CALL zdf_ric_init ! Richardson number dependent Kz
461	IF( lk_zdftke ) CALL zdf_tke_init ! TKE closure scheme
462	IF( lk_zdfgls ) CALL zdf_gls_init ! GLS closure scheme
463	IF( lk_zdftmx ) CALL zdf_tmx_init ! tidal vertical mixing
464	IF( lk_zdfddm ) CALL zdf_ddm_init ! double diffusive mixing
465
466	! ! Lateral physics
467	CALL ldf_tra_init ! Lateral ocean tracer physics
468	CALL ldf_eiv_init ! eddy induced velocity param.
469	CALL ldf_dyn_init ! Lateral ocean momentum physics
470
471	! ! Active tracers
472	CALL tra_qsr_init ! penetrative solar radiation qsr
473	CALL tra_bbc_init ! bottom heat flux
474	IF( lk_trabbl ) CALL tra_bbl_init ! advective (and/or diffusive) bottom boundary layer scheme
475	CALL tra_dmp_init ! internal tracer damping
476	CALL tra_adv_init ! horizontal & vertical advection
477	CALL tra_ldf_init ! lateral mixing
478	CALL tra_zdf_init ! vertical mixing and after tracer fields
479
480	! ! Dynamics
481	IF( lk_c1d ) CALL dyn_dmp_init ! internal momentum damping
482	CALL dyn_adv_init ! advection (vector or flux form)
483	CALL dyn_vor_init ! vorticity term including Coriolis
484	CALL dyn_ldf_init ! lateral mixing
485	CALL dyn_hpg_init ! horizontal gradient of Hydrostatic pressure
486	CALL dyn_zdf_init ! vertical diffusion
487	CALL dyn_spg_init ! surface pressure gradient
488
489	#if defined key_top
490	! ! Passive tracers
491	CALL trc_init
492	#endif
493	IF( l_ldfslp ) CALL ldf_slp_init ! slope of lateral mixing
494
495	! ! Icebergs
496	CALL icb_init( rdt, nit000) ! initialise icebergs instance
497
498	! ! Misc. options
499	CALL sto_par_init ! Stochastic parametrization
500	IF( ln_sto_eos ) CALL sto_pts_init ! RRandom T/S fluctuations
501
502	! ! Diagnostics
503	IF( lk_floats ) CALL flo_init ! drifting Floats
504	CALL dia_cfl_init ! Initialise CFL diagnostics
505	CALL dia_ptr_init ! Poleward TRansports initialization
506	IF( lk_diadct ) CALL dia_dct_init ! Sections tranports
507	CALL dia_hsb_init ! heat content, salt content and volume budgets
508	CALL trd_init ! Mixed-layer/Vorticity/Integral constraints trends
509	CALL dia_obs_init ! Initialize observational data
510	IF( ln_diaobs ) CALL dia_obs( nit000 - 1 ) ! Observation operator for restart
511
512	! ! Assimilation increments
513	IF( lk_asminc ) CALL asm_inc_init ! Initialize assimilation increments
514	IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
515	CALL dia_tmb_init ! TMB outputs
516	CALL dia_25h_init ! 25h mean outputs
517	!
518	END SUBROUTINE nemo_init
519
520
521	SUBROUTINE nemo_ctl
522	!!----------------------------------------------------------------------
523	!! * ROUTINE nemo_ctl *
524	!!
525	!! ** Purpose : control print setting
526	!!
527	!! ** Method : - print namctl information and check some consistencies
528	!!----------------------------------------------------------------------
529	!
530	IF(lwp) THEN ! control print
531	WRITE(numout,*)
532	WRITE(numout,*) 'nemo_ctl: Control prints'
533	WRITE(numout,*) '~~~~~~~ '
534	WRITE(numout,*) ' Namelist namctl'
535	WRITE(numout,*) ' run control (for debugging) ln_ctl = ', ln_ctl
536	WRITE(numout,*) ' level of print nn_print = ', nn_print
537	WRITE(numout,*) ' Start i indice for SUM control nn_ictls = ', nn_ictls
538	WRITE(numout,*) ' End i indice for SUM control nn_ictle = ', nn_ictle
539	WRITE(numout,*) ' Start j indice for SUM control nn_jctls = ', nn_jctls
540	WRITE(numout,*) ' End j indice for SUM control nn_jctle = ', nn_jctle
541	WRITE(numout,*) ' number of proc. following i nn_isplt = ', nn_isplt
542	WRITE(numout,*) ' number of proc. following j nn_jsplt = ', nn_jsplt
543	WRITE(numout,*) ' timing activated (0/1) nn_timing = ', nn_timing
544	ENDIF
545	!
546	nprint = nn_print ! convert DOCTOR namelist names into OLD names
547	nictls = nn_ictls
548	nictle = nn_ictle
549	njctls = nn_jctls
550	njctle = nn_jctle
551	isplt = nn_isplt
552	jsplt = nn_jsplt
553
554	IF(lwp) THEN ! control print
555	WRITE(numout,*)
556	WRITE(numout,*) 'namcfg : configuration initialization through namelist read'
557	WRITE(numout,*) '~~~~~~ '
558	WRITE(numout,*) ' Namelist namcfg'
559	WRITE(numout,*) ' read domain configuration file ln_read_cfg = ', ln_read_cfg
560	WRITE(numout,*) ' filename to be read cn_domcfg = ', TRIM(cn_domcfg)
561	WRITE(numout,*) ' write configuration definition file ln_write_cfg = ', ln_write_cfg
562	WRITE(numout,*) ' filename to be written cn_domcfg_out = ', TRIM(cn_domcfg_out)
563	WRITE(numout,*) ' use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr
564	ENDIF
565	! ! Parameter control
566	!
567	IF( ln_ctl ) THEN ! sub-domain area indices for the control prints
568	IF( lk_mpp .AND. jpnij > 1 ) THEN
569	isplt = jpni ; jsplt = jpnj ; ijsplt = jpni*jpnj ! the domain is forced to the real split domain
570	ELSE
571	IF( isplt == 1 .AND. jsplt == 1 ) THEN
572	CALL ctl_warn( ' - isplt & jsplt are equal to 1', &
573	& ' - the print control will be done over the whole domain' )
574	ENDIF
575	ijsplt = isplt * jsplt ! total number of processors ijsplt
576	ENDIF
577	IF(lwp) WRITE(numout,*)' - The total number of processors over which the'
578	IF(lwp) WRITE(numout,*)' print control will be done is ijsplt : ', ijsplt
579	!
580	! ! indices used for the SUM control
581	IF( nictls+nictle+njctls+njctle == 0 ) THEN ! print control done over the default area
582	lsp_area = .FALSE.
583	ELSE ! print control done over a specific area
584	lsp_area = .TRUE.
585	IF( nictls < 1 .OR. nictls > jpiglo ) THEN
586	CALL ctl_warn( ' - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
587	nictls = 1
588	ENDIF
589	IF( nictle < 1 .OR. nictle > jpiglo ) THEN
590	CALL ctl_warn( ' - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
591	nictle = jpiglo
592	ENDIF
593	IF( njctls < 1 .OR. njctls > jpjglo ) THEN
594	CALL ctl_warn( ' - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
595	njctls = 1
596	ENDIF
597	IF( njctle < 1 .OR. njctle > jpjglo ) THEN
598	CALL ctl_warn( ' - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
599	njctle = jpjglo
600	ENDIF
601	ENDIF
602	ENDIF
603	!
604	IF( 1_wp /= SIGN(1._wp,-0._wp) ) CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ', &
605	& 'f2003 standard. ' , &
606	& 'Compile with key_nosignedzero enabled' )
607	!
608	END SUBROUTINE nemo_ctl
609
610
611	SUBROUTINE nemo_closefile
612	!!----------------------------------------------------------------------
613	!! * ROUTINE nemo_closefile *
614	!!
615	!! ** Purpose : Close the files
616	!!----------------------------------------------------------------------
617	!
618	IF( lk_mpp ) CALL mppsync
619	!
620	CALL iom_close ! close all input/output files managed by iom_*
621	!
622	IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file
623	IF( numsol /= -1 ) CLOSE( numsol ) ! solver file
624	IF( numnam_ref /= -1 ) CLOSE( numnam_ref ) ! oce reference namelist
625	IF( numnam_cfg /= -1 ) CLOSE( numnam_cfg ) ! oce configuration namelist
626	IF( lwm.AND.numond /= -1 ) CLOSE( numond ) ! oce output namelist
627	IF( numnam_ice_ref /= -1 ) CLOSE( numnam_ice_ref ) ! ice reference namelist
628	IF( numnam_ice_cfg /= -1 ) CLOSE( numnam_ice_cfg ) ! ice configuration namelist
629	IF( lwm.AND.numoni /= -1 ) CLOSE( numoni ) ! ice output namelist
630	IF( numevo_ice /= -1 ) CLOSE( numevo_ice ) ! ice variables (temp. evolution)
631	IF( numout /= 6 ) CLOSE( numout ) ! standard model output file
632	IF( numdct_vol /= -1 ) CLOSE( numdct_vol ) ! volume transports
633	IF( numdct_heat /= -1 ) CLOSE( numdct_heat ) ! heat transports
634	IF( numdct_salt /= -1 ) CLOSE( numdct_salt ) ! salt transports
635	!
636	numout = 6 ! redefine numout in case it is used after this point...
637	!
638	END SUBROUTINE nemo_closefile
639
640
641	SUBROUTINE nemo_alloc
642	!!----------------------------------------------------------------------
643	!! * ROUTINE nemo_alloc *
644	!!
645	!! ** Purpose : Allocate all the dynamic arrays of the OPA modules
646	!!
647	!! ** Method :
648	!!----------------------------------------------------------------------
649	USE diawri , ONLY: dia_wri_alloc
650	USE dom_oce , ONLY: dom_oce_alloc
651	USE trc_oce , ONLY: trc_oce_alloc
652	#if defined key_diadct
653	USE diadct , ONLY: diadct_alloc
654	#endif
655	USE bdy_oce , ONLY: bdy_oce_alloc
656	!
657	INTEGER :: ierr
658	!!----------------------------------------------------------------------
659	!
660	ierr = oce_alloc () ! ocean
661	ierr = ierr + dia_wri_alloc ()
662	ierr = ierr + dom_oce_alloc () ! ocean domain
663	ierr = ierr + zdf_oce_alloc () ! ocean vertical physics
664	!
665	ierr = ierr + trc_oce_alloc () ! shared TRC / TRA arrays
666	!
667	#if defined key_diadct
668	ierr = ierr + diadct_alloc () !
669	#endif
670	ierr = ierr + bdy_oce_alloc () ! bdy masks (incl. initialization)
671	!
672	IF( lk_mpp ) CALL mpp_sum( ierr )
673	IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
674	!
675	END SUBROUTINE nemo_alloc
676
677
678	SUBROUTINE nemo_partition( num_pes )
679	!!----------------------------------------------------------------------
680	!! * ROUTINE nemo_partition *
681	!!
682	!! ** Purpose :
683	!!
684	!! ** Method :
685	!!----------------------------------------------------------------------
686	INTEGER, INTENT(in) :: num_pes ! The number of MPI processes we have
687	!
688	INTEGER, PARAMETER :: nfactmax = 20
689	INTEGER :: nfact ! The no. of factors returned
690	INTEGER :: ierr ! Error flag
691	INTEGER :: ji
692	INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
693	INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
694	!!----------------------------------------------------------------------
695	!
696	ierr = 0
697	!
698	CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
699	!
700	IF( nfact <= 1 ) THEN
701	WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
702	WRITE (numout, *) ' : using grid of ',num_pes,' x 1'
703	jpnj = 1
704	jpni = num_pes
705	ELSE
706	! Search through factors for the pair that are closest in value
707	mindiff = 1000000
708	imin = 1
709	DO ji = 1, nfact-1, 2
710	idiff = ABS( ifact(ji) - ifact(ji+1) )
711	IF( idiff < mindiff ) THEN
712	mindiff = idiff
713	imin = ji
714	ENDIF
715	END DO
716	jpnj = ifact(imin)
717	jpni = ifact(imin + 1)
718	ENDIF
719	!
720	jpnij = jpni*jpnj
721	!
722	END SUBROUTINE nemo_partition
723
724
725	SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
726	!!----------------------------------------------------------------------
727	!! * ROUTINE factorise *
728	!!
729	!! ** Purpose : return the prime factors of n.
730	!! knfax factors are returned in array kfax which is of
731	!! maximum dimension kmaxfax.
732	!! ** Method :
733	!!----------------------------------------------------------------------
734	INTEGER , INTENT(in ) :: kn, kmaxfax
735	INTEGER , INTENT( out) :: kerr, knfax
736	INTEGER, DIMENSION(kmaxfax), INTENT( out) :: kfax
737	!
738	INTEGER :: ifac, jl, inu
739	INTEGER, PARAMETER :: ntest = 14
740	INTEGER, DIMENSION(ntest) :: ilfax
741	!!----------------------------------------------------------------------
742	!
743	! lfax contains the set of allowed factors.
744	ilfax(:) = (/(2**jl,jl=ntest,1,-1)/)
745	!
746	! Clear the error flag and initialise output vars
747	kerr = 0
748	kfax = 1
749	knfax = 0
750	!
751	! Find the factors of n.
752	IF( kn .NE. 1 ) THEN
753
754	! nu holds the unfactorised part of the number.
755	! knfax holds the number of factors found.
756	! l points to the allowed factor list.
757	! ifac holds the current factor.
758	!
759	inu = kn
760	knfax = 0
761	!
762	DO jl = ntest, 1, -1
763	!
764	ifac = ilfax(jl)
765	IF( ifac > inu ) CYCLE
766
767	! Test whether the factor will divide.
768
769	IF( MOD(inu,ifac) == 0 ) THEN
770	!
771	knfax = knfax + 1 ! Add the factor to the list
772	IF( knfax > kmaxfax ) THEN
773	kerr = 6
774	write (,) 'FACTOR: insufficient space in factor array ', knfax
775	return
776	ENDIF
777	kfax(knfax) = ifac
778	! Store the other factor that goes with this one
779	knfax = knfax + 1
780	kfax(knfax) = inu / ifac
781	!WRITE (,) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
782	ENDIF
783	!
784	END DO
785	!
786	ENDIF
787	!
788	END SUBROUTINE factorise
789
790	#if defined key_mpp_mpi
791
792	SUBROUTINE nemo_northcomms
793	!!----------------------------------------------------------------------
794	!! * ROUTINE nemo_northcomms *
795	!! ** Purpose : Setup for north fold exchanges with explicit
796	!! point-to-point messaging
797	!!
798	!! ** Method : Initialization of the northern neighbours lists.
799	!!----------------------------------------------------------------------
800	!! 1.0 ! 2011-10 (A. C. Coward, NOCS & J. Donners, PRACE)
801	!! 2.0 ! 2013-06 Setup avoiding MPI communication (I. Epicoco, S. Mocavero, CMCC)
802	!!----------------------------------------------------------------------
803	INTEGER :: sxM, dxM, sxT, dxT, jn
804	INTEGER :: njmppmax
805	!!----------------------------------------------------------------------
806	!
807	njmppmax = MAXVAL( njmppt )
808	!
809	!initializes the north-fold communication variables
810	isendto(:) = 0
811	nsndto = 0
812	!
813	!if I am a process in the north
814	IF ( njmpp == njmppmax ) THEN
815	!sxM is the first point (in the global domain) needed to compute the
816	!north-fold for the current process
817	sxM = jpiglo - nimppt(narea) - nlcit(narea) + 1
818	!dxM is the last point (in the global domain) needed to compute the
819	!north-fold for the current process
820	dxM = jpiglo - nimppt(narea) + 2
821
822	!loop over the other north-fold processes to find the processes
823	!managing the points belonging to the sxT-dxT range
824
825	DO jn = 1, jpni
826	!sxT is the first point (in the global domain) of the jn
827	!process
828	sxT = nfiimpp(jn, jpnj)
829	!dxT is the last point (in the global domain) of the jn
830	!process
831	dxT = nfiimpp(jn, jpnj) + nfilcit(jn, jpnj) - 1
832	IF ((sxM .gt. sxT) .AND. (sxM .lt. dxT)) THEN
833	nsndto = nsndto + 1
834	isendto(nsndto) = jn
835	ELSEIF ((sxM .le. sxT) .AND. (dxM .ge. dxT)) THEN
836	nsndto = nsndto + 1
837	isendto(nsndto) = jn
838	ELSEIF ((dxM .lt. dxT) .AND. (sxT .lt. dxM)) THEN
839	nsndto = nsndto + 1
840	isendto(nsndto) = jn
841	ENDIF
842	END DO
843	nfsloop = 1
844	nfeloop = nlci
845	DO jn = 2,jpni-1
846	IF(nfipproc(jn,jpnj) .eq. (narea - 1)) THEN
847	IF (nfipproc(jn - 1 ,jpnj) .eq. -1) THEN
848	nfsloop = nldi
849	ENDIF
850	IF (nfipproc(jn + 1,jpnj) .eq. -1) THEN
851	nfeloop = nlei
852	ENDIF
853	ENDIF
854	END DO
855
856	ENDIF
857	l_north_nogather = .TRUE.
858	END SUBROUTINE nemo_northcomms
859
860	#else
861	SUBROUTINE nemo_northcomms ! Dummy routine
862	WRITE(,) 'nemo_northcomms: You should not have seen this print! error?'
863	END SUBROUTINE nemo_northcomms
864	#endif
865
866	!!======================================================================
867	END MODULE nemogcm
868

Note: See TracBrowser for help on using the repository browser.

Download in other formats: