New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p5zprod.F90 in branches/UKMO/r8727_WAVE-2_Clementi_add_coupling/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/UKMO/r8727_WAVE-2_Clementi_add_coupling/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p5zprod.F90 @ 8749

Last change on this file since 8749 was 8749, checked in by jcastill, 6 years ago

Remove svn keywords
  • Property svn:executable set to *
File size: 36.5 KB
Line 
1MODULE p5zprod
2   !!======================================================================
3   !!                         ***  MODULE p5zprod  ***
4   !! TOP :  Growth Rate of the two phytoplanktons groups
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-05  (O. Aumont, C. Ethe) New parameterization of light limitation
9   !!             3.6  !  2015-05  (O. Aumont) PISCES quota
10   !!----------------------------------------------------------------------
11   !!   p5z_prod       :   Compute the growth Rate of the two phytoplanktons groups
12   !!   p5z_prod_init  :   Initialization of the parameters for growth
13   !!   p5z_prod_alloc :   Allocate variables for growth
14   !!----------------------------------------------------------------------
15   USE oce_trc         !  shared variables between ocean and passive tracers
16   USE trc             !  passive tracers common variables
17   USE sms_pisces      !  PISCES Source Minus Sink variables
18   USE p5zlim          !  Co-limitations of differents nutrients
19   USE prtctl_trc      !  print control for debugging
20   USE iom             !  I/O manager
21
22   IMPLICIT NONE
23   PRIVATE
24
25   PUBLIC   p5z_prod         ! called in p5zbio.F90
26   PUBLIC   p5z_prod_init    ! called in trcsms_pisces.F90
27   PUBLIC   p5z_prod_alloc
28
29   !! * Shared module variables
30   REAL(wp), PUBLIC ::  pislopen        !:
31   REAL(wp), PUBLIC ::  pislopep        !:
32   REAL(wp), PUBLIC ::  pisloped        !:
33   REAL(wp), PUBLIC ::  xadap           !:
34   REAL(wp), PUBLIC ::  excretn         !:
35   REAL(wp), PUBLIC ::  excretp         !:
36   REAL(wp), PUBLIC ::  excretd         !:
37   REAL(wp), PUBLIC ::  bresp           !:
38   REAL(wp), PUBLIC ::  thetanpm        !:
39   REAL(wp), PUBLIC ::  thetannm        !:
40   REAL(wp), PUBLIC ::  thetandm        !:
41   REAL(wp), PUBLIC ::  chlcmin         !:
42   REAL(wp), PUBLIC ::  grosip          !:
43
44   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   prmaxn   !: optimal production = f(temperature)
45   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   prmaxp   !: optimal production = f(temperature)
46   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   prmaxd   !: optimal production = f(temperature)
47   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   zdaylen
48   
49   REAL(wp) :: r1_rday                !: 1 / rday
50   REAL(wp) :: texcretn               !: 1 - excret
51   REAL(wp) :: texcretp               !: 1 - excretp
52   REAL(wp) :: texcretd               !: 1 - excret2       
53
54   !!----------------------------------------------------------------------
55   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
56   !! $Id$
57   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
58   !!----------------------------------------------------------------------
59CONTAINS
60
61   SUBROUTINE p5z_prod( kt , knt )
62      !!---------------------------------------------------------------------
63      !!                     ***  ROUTINE p5z_prod  ***
64      !!
65      !! ** Purpose :   Compute the phytoplankton production depending on
66      !!              light, temperature and nutrient availability
67      !!
68      !! ** Method  : - ???
69      !!---------------------------------------------------------------------
70      !
71      INTEGER, INTENT(in) :: kt, knt
72      !
73      INTEGER  ::   ji, jj, jk
74      REAL(wp) ::   zsilfac, znanotot, zpicotot, zdiattot, zconctemp, zconctemp2
75      REAL(wp) ::   zration, zratiop, zratiof, zmax, zmax2, zsilim, ztn, zadap
76      REAL(wp) ::   zpronmax, zpropmax, zprofmax, zrat
77      REAL(wp) ::   zlim, zsilfac2, zsiborn, zprod, zprontot, zproptot, zprodtot
78      REAL(wp) ::   zprnutmax, zdocprod, zprochln, zprochld, zprochlp
79      REAL(wp) ::   zpislopen, zpislopep, zpisloped, thetannm_n, thetandm_n, thetanpm_n
80      REAL(wp) ::   zrum, zcodel, zargu, zval, zfeup
81      REAL(wp) ::   zfact, zrfact2
82      CHARACTER (len=25) :: charout
83      REAL(wp), POINTER, DIMENSION(:,:  ) :: zmixnano, zmixpico, zmixdiat, zstrn
84      REAL(wp), POINTER, DIMENSION(:,:,:) :: zpislopeadn, zpislopeadp, zpislopeadd
85      REAL(wp), POINTER, DIMENSION(:,:,:) :: zprbio, zprpic, zprdia, zysopt
86      REAL(wp), POINTER, DIMENSION(:,:,:) :: zprchln, zprchlp, zprchld
87      REAL(wp), POINTER, DIMENSION(:,:,:) :: zprorcan, zprorcap, zprorcad 
88      REAL(wp), POINTER, DIMENSION(:,:,:) :: zprofed, zprofep, zprofen
89      REAL(wp), POINTER, DIMENSION(:,:,:) :: zpronewn, zpronewp, zpronewd
90      REAL(wp), POINTER, DIMENSION(:,:,:) :: zproregn, zproregp, zproregd
91      REAL(wp), POINTER, DIMENSION(:,:,:) :: zpropo4n, zpropo4p, zpropo4d
92      REAL(wp), POINTER, DIMENSION(:,:,:) :: zprodopn, zprodopp, zprodopd
93      REAL(wp), POINTER, DIMENSION(:,:,:) :: zrespn, zrespp, zrespd, zprnut
94      REAL(wp), POINTER, DIMENSION(:,:,:) :: zcroissn, zcroissp, zcroissd
95      REAL(wp), POINTER, DIMENSION(:,:,:) :: zmxl_fac, zmxl_chl
96      REAL(wp), POINTER, DIMENSION(:,:,:) :: zw3d
97      REAL(wp), POINTER, DIMENSION(:,:  ) :: zw2d
98      !!---------------------------------------------------------------------
99      !
100      IF( nn_timing == 1 )  CALL timing_start('p5z_prod')
101      !
102      !  Allocate temporary workspace
103      CALL wrk_alloc( jpi, jpj,      zmixnano, zmixpico, zmixdiat, zstrn )
104      CALL wrk_alloc( jpi, jpj, jpk, zmxl_fac, zmxl_chl )
105      CALL wrk_alloc( jpi, jpj, jpk, zpislopeadn, zpislopeadp, zpislopeadd, zysopt ) 
106      CALL wrk_alloc( jpi, jpj, jpk, zprdia, zprpic, zprbio, zprorcan, zprorcap, zprorcad )
107      CALL wrk_alloc( jpi, jpj, jpk, zprofed, zprofep, zprofen )
108      CALL wrk_alloc( jpi, jpj, jpk, zpronewn, zpronewp, zpronewd, zproregn, zproregp, zproregd )
109      CALL wrk_alloc( jpi, jpj, jpk, zpropo4n, zpropo4p, zpropo4d, zrespn, zrespp, zrespd, zprnut )
110      CALL wrk_alloc( jpi, jpj, jpk, zprchln, zprchlp, zprchld, zprodopn, zprodopp, zprodopd )
111      CALL wrk_alloc( jpi, jpj, jpk, zcroissp, zcroissn, zcroissd )
112      !
113      zprorcan(:,:,:) = 0._wp ; zprorcap(:,:,:) = 0._wp ; zprorcad(:,:,:) = 0._wp
114      zprofed (:,:,:) = 0._wp ; zprofep (:,:,:) = 0._wp ; zprofen (:,:,:) = 0._wp
115      zpronewn(:,:,:) = 0._wp ; zpronewp(:,:,:) = 0._wp ; zpronewd(:,:,:) = 0._wp
116      zproregn(:,:,:) = 0._wp ; zproregp(:,:,:) = 0._wp ; zproregd(:,:,:) = 0._wp 
117      zpropo4n(:,:,:) = 0._wp ; zpropo4p(:,:,:) = 0._wp ; zpropo4d(:,:,:) = 0._wp
118      zprdia  (:,:,:) = 0._wp ; zprpic  (:,:,:) = 0._wp ; zprbio  (:,:,:) = 0._wp
119      zysopt  (:,:,:) = 0._wp
120      zrespn  (:,:,:) = 0._wp ; zrespp  (:,:,:) = 0._wp ; zrespd  (:,:,:) = 0._wp 
121
122      ! Computation of the optimal production
123      prmaxn(:,:,:) = ( 0.65_wp * (1. + zpsino3 * qnpmax ) ) * r1_rday * tgfunc(:,:,:)
124      prmaxp(:,:,:) = 0.5 / 0.65 * prmaxn(:,:,:) 
125      prmaxd(:,:,:) = prmaxn(:,:,:) 
126      zprnut(:,:,:) = 0.65_wp * r1_rday * tgfunc(:,:,:)
127
128      ! compute the day length depending on latitude and the day
129      zrum = REAL( nday_year - 80, wp ) / REAL( nyear_len(1), wp )
130      zcodel = ASIN(  SIN( zrum * rpi * 2._wp ) * SIN( rad * 23.5_wp )  )
131
132      ! day length in hours
133      zstrn(:,:) = 0.
134      DO jj = 1, jpj
135         DO ji = 1, jpi
136            zargu = TAN( zcodel ) * TAN( gphit(ji,jj) * rad )
137            zargu = MAX( -1., MIN(  1., zargu ) )
138            zstrn(ji,jj) = MAX( 0.0, 24. - 2. * ACOS( zargu ) / rad / 15. )
139         END DO
140      END DO
141
142         ! Impact of the day duration on phytoplankton growth
143      DO jk = 1, jpkm1
144         DO jj = 1 ,jpj
145            DO ji = 1, jpi
146               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
147                  zval = MAX( 1., zstrn(ji,jj) )
148                  IF( gdepw_n(ji,jj,jk+1) <= hmld(ji,jj) ) THEN
149                     zval = zval * MIN(1., heup_01(ji,jj) / ( hmld(ji,jj) + rtrn ))
150                  ENDIF
151                  zmxl_chl(ji,jj,jk) = zval / 24.
152                  zmxl_fac(ji,jj,jk) = 1.5 * zval / ( 12. + zval )
153               ENDIF
154            END DO
155         END DO
156      END DO
157
158      zprbio(:,:,:) = prmaxn(:,:,:) * zmxl_fac(:,:,:)
159      zprdia(:,:,:) = prmaxd(:,:,:) * zmxl_fac(:,:,:)
160      zprpic(:,:,:) = prmaxp(:,:,:) * zmxl_fac(:,:,:)
161
162
163      ! Maximum light intensity
164      zdaylen(:,:) = MAX(1., zstrn(:,:)) / 24.
165      WHERE( zstrn(:,:) < 1.e0 ) zstrn(:,:) = 24.
166
167      DO jk = 1, jpkm1
168         DO jj = 1, jpj
169            DO ji = 1, jpi
170               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
171                  ! Computation of the P-I slope for nanos and diatoms
172                  ztn         = MAX( 0., tsn(ji,jj,jk,jp_tem) - 15. )
173                  zadap       = xadap * ztn / ( 2.+ ztn )
174                  !
175                  zpislopeadn(ji,jj,jk) = pislopen * trb(ji,jj,jk,jpnch)    &
176                  &                       /( trb(ji,jj,jk,jpphy) * 12. + rtrn)
177                  zpislopeadp(ji,jj,jk) = pislopep * ( 1. + zadap * EXP( -0.25 * epico(ji,jj,jk) ) )   &
178                  &                       * trb(ji,jj,jk,jppch) /( trb(ji,jj,jk,jppic) * 12. + rtrn)
179                  zpislopeadd(ji,jj,jk) = pisloped * trb(ji,jj,jk,jpdch)    &
180                     &                    /( trb(ji,jj,jk,jpdia) * 12. + rtrn)
181                  !
182                  zpislopen = zpislopeadn(ji,jj,jk) / ( zprbio(ji,jj,jk) * rday * xlimphy(ji,jj,jk) + rtrn )
183                  zpislopep = zpislopeadp(ji,jj,jk) / ( zprpic(ji,jj,jk) * rday * xlimpic(ji,jj,jk) + rtrn )
184                  zpisloped = zpislopeadd(ji,jj,jk) / ( zprdia(ji,jj,jk) * rday * xlimdia(ji,jj,jk) + rtrn )
185
186                  ! Computation of production function for Carbon
187                  !  ---------------------------------------------
188                  zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1.- EXP( -zpislopen * enano(ji,jj,jk) )  )
189                  zprpic(ji,jj,jk) = zprpic(ji,jj,jk) * ( 1.- EXP( -zpislopep * epico(ji,jj,jk) )  )
190                  zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediat(ji,jj,jk) )  )
191
192                  ! Computation of production function for Chlorophyll
193                  !  -------------------------------------------------
194                  zpislopen = zpislopen * zmxl_fac(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
195                  zpisloped = zpisloped * zmxl_fac(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
196                  zpislopep = zpislopep * zmxl_fac(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
197                  zprchln(ji,jj,jk) = prmaxn(ji,jj,jk) * ( 1.- EXP( -zpislopen * enano(ji,jj,jk) )  )
198                  zprchlp(ji,jj,jk) = prmaxp(ji,jj,jk) * ( 1.- EXP( -zpislopep * epico(ji,jj,jk) )  )
199                  zprchld(ji,jj,jk) = prmaxd(ji,jj,jk) * ( 1.- EXP( -zpisloped * ediat(ji,jj,jk) )  )
200               ENDIF
201            END DO
202         END DO
203      END DO
204
205      DO jk = 1, jpkm1
206         DO jj = 1, jpj
207            DO ji = 1, jpi
208
209                IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
210                  !    Si/C of diatoms
211                  !    ------------------------
212                  !    Si/C increases with iron stress and silicate availability
213                  !    Si/C is arbitrariliy increased for very high Si concentrations
214                  !    to mimic the very high ratios observed in the Southern Ocean (silpot2)
215                  zlim  = trb(ji,jj,jk,jpsil) / ( trb(ji,jj,jk,jpsil) + xksi1 )
216                  zsilim = MIN( zprdia(ji,jj,jk) / ( prmaxd(ji,jj,jk) + rtrn ), xlimsi(ji,jj,jk) )
217                  zsilfac = 3.4 * EXP( -4.23 * zsilim ) * MAX( 0.e0, MIN( 1., 2.2 * ( zlim - 0.5 ) )  ) + 1.e0
218                  zsiborn = trb(ji,jj,jk,jpsil) * trb(ji,jj,jk,jpsil) * trb(ji,jj,jk,jpsil)
219                  IF (gphit(ji,jj) < -30 ) THEN
220                    zsilfac2 = 1. + 2. * zsiborn / ( zsiborn + xksi2**3 )
221                  ELSE
222                    zsilfac2 = 1. +      zsiborn / ( zsiborn + xksi2**3 )
223                  ENDIF
224                  zysopt(ji,jj,jk) = grosip * zlim * zsilfac * zsilfac2
225              ENDIF
226            END DO
227         END DO
228      END DO
229
230      !  Sea-ice effect on production                                                                               
231      DO jk = 1, jpkm1
232         DO jj = 1, jpj
233            DO ji = 1, jpi
234               zprbio(ji,jj,jk)  = zprbio(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
235               zprpic(ji,jj,jk)  = zprpic(ji,jj,jk) * ( 1. - fr_i(ji,jj) ) 
236               zprdia(ji,jj,jk)  = zprdia(ji,jj,jk) * ( 1. - fr_i(ji,jj) ) 
237               zprnut(ji,jj,jk)  = zprnut(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
238            END DO
239         END DO
240      END DO
241
242      ! Computation of the various production terms of nanophytoplankton
243      DO jk = 1, jpkm1
244         DO jj = 1, jpj
245            DO ji = 1, jpi
246               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
247                  !  production terms for nanophyto.
248                  zprorcan(ji,jj,jk) = zprbio(ji,jj,jk)  * xlimphy(ji,jj,jk) * trb(ji,jj,jk,jpphy) * rfact2
249                  !
250                  zration = trb(ji,jj,jk,jpnph) / ( trb(ji,jj,jk,jpphy) + rtrn )
251                  zratiop = trb(ji,jj,jk,jppph) / ( trb(ji,jj,jk,jpphy) + rtrn )
252                  zratiof = trb(ji,jj,jk,jpnfe) / ( trb(ji,jj,jk,jpphy) + rtrn )
253                  zprnutmax = zprnut(ji,jj,jk) * fvnuptk(ji,jj,jk) / rno3 * trb(ji,jj,jk,jpphy) * rfact2
254                  ! Uptake of nitrogen
255                  zrat = MIN( 1., zration / (xqnnmax(ji,jj,jk) + rtrn) ) 
256                  zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05))
257                  zpronmax = zprnutmax * zmax * MAX(0., MIN(1., ( zratiop - xqpnmin(ji,jj,jk) )   &
258                  &          / ( xqpnmax(ji,jj,jk) - xqpnmin(ji,jj,jk) + rtrn ), xlimnfe(ji,jj,jk) ) )
259                  zpronewn(ji,jj,jk) = zpronmax * zdaylen(ji,jj) * xnanono3(ji,jj,jk)
260                  zproregn(ji,jj,jk) = zpronmax * xnanonh4(ji,jj,jk)
261                  ! Uptake of phosphorus
262                  zrat = MIN( 1., zratiop / (xqpnmax(ji,jj,jk) + rtrn) )
263                  zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05))
264                  zpropmax = zprnutmax * zmax * xlimnfe(ji,jj,jk)
265                  zpropo4n(ji,jj,jk) = zpropmax * xnanopo4(ji,jj,jk)
266                  zprodopn(ji,jj,jk) = zpropmax * xnanodop(ji,jj,jk)
267                  ! Uptake of iron
268                  zrat = MIN( 1., zratiof / qfnmax )
269                  zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05))
270                  zprofmax = zprnutmax * qfnmax * zmax
271                  zprofen(ji,jj,jk) = zprofmax * xnanofer(ji,jj,jk) * ( 3. - 2.4 * xlimnfe(ji,jj,jk)    &
272                  &          / ( xlimnfe(ji,jj,jk) + 0.2 ) ) * (1. + 0.8 * xnanono3(ji,jj,jk) / ( rtrn  &
273                  &          + xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk) ) * (1. - xnanofer(ji,jj,jk) ) )
274               ENDIF
275            END DO
276         END DO
277      END DO
278
279      ! Computation of the various production terms of picophytoplankton
280      DO jk = 1, jpkm1
281         DO jj = 1, jpj
282            DO ji = 1, jpi
283               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
284                  !  production terms for picophyto.
285                  zprorcap(ji,jj,jk) = zprpic(ji,jj,jk)  * xlimpic(ji,jj,jk) * trb(ji,jj,jk,jppic) * rfact2
286                  !
287                  zration = trb(ji,jj,jk,jpnpi) / ( trb(ji,jj,jk,jppic) + rtrn )
288                  zratiop = trb(ji,jj,jk,jpppi) / ( trb(ji,jj,jk,jppic) + rtrn )
289                  zratiof = trb(ji,jj,jk,jppfe) / ( trb(ji,jj,jk,jppic) + rtrn )
290                  zprnutmax = zprnut(ji,jj,jk) * fvpuptk(ji,jj,jk) / rno3 * trb(ji,jj,jk,jppic) * rfact2
291                  ! Uptake of nitrogen
292                  zrat = MIN( 1., zration / (xqnpmax(ji,jj,jk) + rtrn) )
293                  zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05))
294                  zpronmax = zprnutmax * zmax * MAX(0., MIN(1., ( zratiop - xqppmin(ji,jj,jk) )   &
295                  &          / ( xqppmax(ji,jj,jk) - xqppmin(ji,jj,jk) + rtrn ), xlimpfe(ji,jj,jk) ) )
296                  zpronewp(ji,jj,jk) = zpronmax * zdaylen(ji,jj) * xpicono3(ji,jj,jk) 
297                  zproregp(ji,jj,jk) = zpronmax * xpiconh4(ji,jj,jk)
298                  ! Uptake of phosphorus
299                  zrat = MIN( 1., zratiop / (xqppmax(ji,jj,jk) + rtrn) )
300                  zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05))
301                  zpropmax = zprnutmax * zmax * xlimpfe(ji,jj,jk)
302                  zpropo4p(ji,jj,jk) = zpropmax * xpicopo4(ji,jj,jk)
303                  zprodopp(ji,jj,jk) = zpropmax * xpicodop(ji,jj,jk)
304                  ! Uptake of iron
305                  zrat = MIN( 1., zratiof / qfpmax )
306                  zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05))
307                  zprofmax = zprnutmax * qfpmax * zmax
308                  zprofep(ji,jj,jk) = zprofmax * xpicofer(ji,jj,jk) * ( 3. - 2.4 * xlimpfe(ji,jj,jk)   &
309                  &          / ( xlimpfe(ji,jj,jk) + 0.2 ) ) * (1. + 0.8 * xpicono3(ji,jj,jk) / ( rtrn   &
310                  &          + xpicono3(ji,jj,jk) + xpiconh4(ji,jj,jk) ) * (1. - xpicofer(ji,jj,jk) ) )
311               ENDIF
312            END DO
313         END DO
314      END DO
315
316      ! Computation of the various production terms of diatoms
317      DO jk = 1, jpkm1
318         DO jj = 1, jpj
319            DO ji = 1, jpi
320               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
321                  !  production terms for diatomees
322                  zprorcad(ji,jj,jk) = zprdia(ji,jj,jk) * xlimdia(ji,jj,jk) * trb(ji,jj,jk,jpdia) * rfact2
323                  ! Computation of the respiration term according to pahlow
324                  ! & oschlies (2013)
325                  !
326                  zration = trb(ji,jj,jk,jpndi) / ( trb(ji,jj,jk,jpdia) + rtrn )
327                  zratiop = trb(ji,jj,jk,jppdi) / ( trb(ji,jj,jk,jpdia) + rtrn )
328                  zratiof = trb(ji,jj,jk,jpdfe) / ( trb(ji,jj,jk,jpdia) + rtrn )
329                  zprnutmax = zprnut(ji,jj,jk) * fvduptk(ji,jj,jk) / rno3 * trb(ji,jj,jk,jpdia) * rfact2
330                  ! Uptake of nitrogen
331                  zrat = MIN( 1., zration / (xqndmax(ji,jj,jk) + rtrn) )
332                  zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05)) 
333                  zpronmax = zprnutmax * zmax * MAX(0., MIN(1., ( zratiop - xqpdmin(ji,jj,jk) )   &
334                  &          / ( xqpdmax(ji,jj,jk) - xqpdmin(ji,jj,jk) + rtrn ), xlimdfe(ji,jj,jk) ) )
335                  zpronewd(ji,jj,jk) = zpronmax * zdaylen(ji,jj) * xdiatno3(ji,jj,jk)
336                  zproregd(ji,jj,jk) = zpronmax * xdiatnh4(ji,jj,jk)
337                  ! Uptake of phosphorus
338                  zrat = MIN( 1., zratiop / (xqpdmax(ji,jj,jk) + rtrn) )
339                  zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05)) 
340                  zpropmax = zprnutmax * zmax * xlimdfe(ji,jj,jk)
341                  zpropo4d(ji,jj,jk) = zpropmax * xdiatpo4(ji,jj,jk)
342                  zprodopd(ji,jj,jk) = zpropmax * xdiatdop(ji,jj,jk)
343                  ! Uptake of iron
344                  zrat = MIN( 1., zratiof / qfdmax )
345                  zmax = MAX(0., MIN(1., (1. - zrat)/ (1.05 - zrat) * 1.05))
346                  zprofmax = zprnutmax * qfdmax * zmax
347                  zprofed(ji,jj,jk) = zprofmax * xdiatfer(ji,jj,jk) * ( 3. - 2.4 * xlimdfe(ji,jj,jk)     &
348                  &          / ( xlimdfe(ji,jj,jk) + 0.2 ) ) * (1. + 0.8 * xdiatno3(ji,jj,jk) / ( rtrn   &
349                  &          + xdiatno3(ji,jj,jk) + xdiatnh4(ji,jj,jk) ) * (1. - xdiatfer(ji,jj,jk) ) )
350               ENDIF
351            END DO
352         END DO
353      END DO
354
355      DO jk = 1, jpkm1
356         DO jj = 1, jpj
357            DO ji = 1, jpi
358               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
359                     !  production terms for nanophyto. ( chlorophyll )
360                  znanotot = enano(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
361                  zprod = rday * (zpronewn(ji,jj,jk) + zproregn(ji,jj,jk)) * zprchln(ji,jj,jk) * xlimphy(ji,jj,jk)
362                  thetannm_n   = MIN ( thetannm, ( thetannm / (1. - 1.14 / 43.4 *tsn(ji,jj,jk,jp_tem)))   &
363                  &               * (1. - 1.14 / 43.4 * 20.))
364                  zprochln = thetannm_n * zprod / ( zpislopeadn(ji,jj,jk) * znanotot + rtrn )
365                  zprochln = MAX(zprochln, chlcmin * 12. * zprorcan (ji,jj,jk) )
366                     !  production terms for picophyto. ( chlorophyll )
367                  zpicotot = epico(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
368                  zprod = rday * (zpronewp(ji,jj,jk) + zproregp(ji,jj,jk)) * zprchlp(ji,jj,jk) * xlimpic(ji,jj,jk)
369                  thetanpm_n   = MIN ( thetanpm, ( thetanpm / (1. - 1.14 / 43.4 *tsn(ji,jj,jk,jp_tem)))   &
370                  &               * (1. - 1.14 / 43.4 * 20.))
371                  zprochlp = thetanpm_n * zprod / ( zpislopeadp(ji,jj,jk) * zpicotot + rtrn )
372                  zprochlp = MAX(zprochlp, chlcmin * 12. * zprorcap(ji,jj,jk) )
373                  !  production terms for diatomees ( chlorophyll )
374                  zdiattot = ediat(ji,jj,jk) / ( zmxl_chl(ji,jj,jk) + rtrn )
375                  zprod = rday * (zpronewd(ji,jj,jk) + zproregd(ji,jj,jk)) * zprchld(ji,jj,jk) * xlimdia(ji,jj,jk)
376                  thetandm_n   = MIN ( thetandm, ( thetandm / (1. - 1.14 / 43.4 *tsn(ji,jj,jk,jp_tem)))   &
377                  &               * (1. - 1.14 / 43.4 * 20.))
378                  zprochld = thetandm_n * zprod / ( zpislopeadd(ji,jj,jk) * zdiattot + rtrn )
379                  zprochld = MAX(zprochld, chlcmin * 12. * zprorcad(ji,jj,jk) )
380                  !   Update the arrays TRA which contain the Chla sources and sinks
381                  tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) + zprochln * texcretn
382                  tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) + zprochld * texcretd
383                  tra(ji,jj,jk,jppch) = tra(ji,jj,jk,jppch) + zprochlp * texcretp
384               ENDIF
385            END DO
386         END DO
387      END DO
388
389      !   Update the arrays TRA which contain the biological sources and sinks
390      DO jk = 1, jpkm1
391         DO jj = 1, jpj
392           DO ji =1 ,jpi
393              zprontot = zpronewn(ji,jj,jk) + zproregn(ji,jj,jk)
394              zproptot = zpronewp(ji,jj,jk) + zproregp(ji,jj,jk)
395              zprodtot = zpronewd(ji,jj,jk) + zproregd(ji,jj,jk)
396              zdocprod = excretd * zprorcad(ji,jj,jk) + excretn * zprorcan(ji,jj,jk)  &
397              &          + excretp * zprorcap(ji,jj,jk)
398              tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) - zpropo4n(ji,jj,jk) - zpropo4d(ji,jj,jk)  &
399              &                     - zpropo4p(ji,jj,jk)
400              tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - zpronewn(ji,jj,jk) - zpronewd(ji,jj,jk)  &
401              &                     - zpronewp(ji,jj,jk)
402              tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zproregn(ji,jj,jk) - zproregd(ji,jj,jk)  &
403              &                     - zproregp(ji,jj,jk)
404              tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) + zprorcan(ji,jj,jk) * texcretn    &
405                 &                  - zpsino3 * zpronewn(ji,jj,jk) - zpsinh4 * zproregn(ji,jj,jk)   &
406                 &                  - zrespn(ji,jj,jk) 
407              zcroissn(ji,jj,jk) = tra(ji,jj,jk,jpphy) / rfact2/ (trb(ji,jj,jk,jpphy) + rtrn)
408              tra(ji,jj,jk,jpnph) = tra(ji,jj,jk,jpnph) + zprontot * texcretn
409              tra(ji,jj,jk,jppph) = tra(ji,jj,jk,jppph) + zpropo4n(ji,jj,jk) * texcretn   &
410              &                     + zprodopn(ji,jj,jk) * texcretn
411              tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) + zprofen(ji,jj,jk) * texcretn
412              tra(ji,jj,jk,jppic) = tra(ji,jj,jk,jppic) + zprorcap(ji,jj,jk) * texcretp     &
413                 &                  - zpsino3 * zpronewp(ji,jj,jk) - zpsinh4 * zproregp(ji,jj,jk)   &
414                 &                  - zrespp(ji,jj,jk) 
415              zcroissp(ji,jj,jk) = tra(ji,jj,jk,jppic) / rfact2/ (trb(ji,jj,jk,jppic) + rtrn)
416              tra(ji,jj,jk,jpnpi) = tra(ji,jj,jk,jpnpi) + zproptot * texcretp
417              tra(ji,jj,jk,jpppi) = tra(ji,jj,jk,jpppi) + zpropo4p(ji,jj,jk) * texcretp   &
418              &                     + zprodopp(ji,jj,jk) * texcretp
419              tra(ji,jj,jk,jppfe) = tra(ji,jj,jk,jppfe) + zprofep(ji,jj,jk) * texcretp
420              tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) + zprorcad(ji,jj,jk) * texcretd   &
421                 &                  - zpsino3 * zpronewd(ji,jj,jk) - zpsinh4 * zproregd(ji,jj,jk)   &
422                 &                  - zrespd(ji,jj,jk) 
423              zcroissd(ji,jj,jk) = tra(ji,jj,jk,jpdia) / rfact2 / (trb(ji,jj,jk,jpdia) + rtrn)
424              tra(ji,jj,jk,jpndi) = tra(ji,jj,jk,jpndi) + zprodtot * texcretd
425              tra(ji,jj,jk,jppdi) = tra(ji,jj,jk,jppdi) + zpropo4d(ji,jj,jk) * texcretd   &
426              &                     + zprodopd(ji,jj,jk) * texcretd
427              tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) + zprofed(ji,jj,jk) * texcretd
428              tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) + zprorcad(ji,jj,jk) * zysopt(ji,jj,jk) * texcretd
429              tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + excretd * zprorcad(ji,jj,jk) + excretn * zprorcan(ji,jj,jk)  &
430              &                     + excretp * zprorcap(ji,jj,jk)
431              tra(ji,jj,jk,jpdon) = tra(ji,jj,jk,jpdon) + excretd * zprodtot + excretn * zprontot   &
432              &                     + excretp * zproptot
433              tra(ji,jj,jk,jpdop) = tra(ji,jj,jk,jpdop) + excretd * zpropo4d(ji,jj,jk) + excretn * zpropo4n(ji,jj,jk)   &
434              &    - texcretn * zprodopn(ji,jj,jk) - texcretd * zprodopd(ji,jj,jk) + excretp * zpropo4p(ji,jj,jk)     &
435              &    - texcretp * zprodopp(ji,jj,jk)
436              tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) + o2ut * ( zproregn(ji,jj,jk) + zproregd(ji,jj,jk)   &
437                 &                + zproregp(ji,jj,jk) ) + ( o2ut + o2nit ) * ( zpronewn(ji,jj,jk)           &
438                 &                + zpronewd(ji,jj,jk) + zpronewp(ji,jj,jk) )   &
439                 &                - o2ut * ( zrespn(ji,jj,jk) + zrespp(ji,jj,jk) + zrespd(ji,jj,jk) )
440              zfeup = texcretn * zprofen(ji,jj,jk) + texcretd * zprofed(ji,jj,jk) + texcretp * zprofep(ji,jj,jk)
441              tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - zfeup
442              tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) - texcretd * zprorcad(ji,jj,jk) * zysopt(ji,jj,jk)
443              tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprorcan(ji,jj,jk) - zprorcad(ji,jj,jk) - zprorcap(ji,jj,jk)  &
444              &                     + zpsino3 * zpronewn(ji,jj,jk) + zpsinh4 * zproregn(ji,jj,jk)   &
445              &                     + zpsino3 * zpronewp(ji,jj,jk) + zpsinh4 * zproregp(ji,jj,jk)   &
446              &                     + zpsino3 * zpronewd(ji,jj,jk) + zpsinh4 * zproregd(ji,jj,jk)  &
447              &                     + zrespn(ji,jj,jk) + zrespd(ji,jj,jk) + zrespp(ji,jj,jk) 
448              tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * ( zpronewn(ji,jj,jk) + zpronewd(ji,jj,jk)  &
449              &                     + zpronewp(ji,jj,jk) ) - rno3 * ( zproregn(ji,jj,jk) + zproregd(ji,jj,jk)     &
450              &                     + zproregp(ji,jj,jk) ) 
451          END DO
452        END DO
453     END DO
454     !
455     IF( ln_ligand ) THEN
456         DO jk = 1, jpkm1
457            DO jj = 1, jpj
458              DO ji =1 ,jpi
459                 zdocprod = excretd * zprorcad(ji,jj,jk) + excretn * zprorcan(ji,jj,jk) + excretp * zprorcap(ji,jj,jk)
460                 zfeup    = texcretn * zprofen(ji,jj,jk) + texcretd * zprofed(ji,jj,jk) + texcretp * zprofep(ji,jj,jk)
461                 tra(ji,jj,jk,jplgw) = tra(ji,jj,jk,jplgw) + zdocprod * ldocp - zfeup * plig(ji,jj,jk) * lthet
462              END DO
463           END DO
464        END DO
465     ENDIF
466
467
468     ! Total primary production per year
469
470    ! Total primary production per year
471    IF( iom_use( "tintpp" ) .OR. ( ln_check_mass .AND. kt == nitend .AND. knt == nrdttrc )  )  &
472      & tpp = glob_sum( ( zprorcan(:,:,:) + zprorcad(:,:,:) + zprorcap(:,:,:) ) * cvol(:,:,:) )
473
474    IF( lk_iomput ) THEN
475       IF( knt == nrdttrc ) THEN
476          CALL wrk_alloc( jpi, jpj,      zw2d )
477          CALL wrk_alloc( jpi, jpj, jpk, zw3d )
478          zfact = 1.e+3 * rfact2r  !  conversion from mol/l/kt to  mol/m3/s
479          !
480          IF( iom_use( "PPPHYN" ) .OR. iom_use( "PPPHYD" ) .OR. iom_use( "PPPHYP" ) )  THEN
481              zw3d(:,:,:) = zprorcan(:,:,:) * zfact * tmask(:,:,:)  ! primary production by nanophyto
482              CALL iom_put( "PPPHYN"  , zw3d )
483              !
484              zw3d(:,:,:) = zprorcap(:,:,:) * zfact * tmask(:,:,:)  ! primary production by picophyto
485              CALL iom_put( "PPPHYP"  , zw3d )
486              !
487              zw3d(:,:,:) = zprorcad(:,:,:) * zfact * tmask(:,:,:)  ! primary production by diatomes
488              CALL iom_put( "PPPHYD"  , zw3d )
489          ENDIF
490          IF( iom_use( "PPNEWN" ) .OR. iom_use( "PPNEWD" ) .OR. iom_use( "PPNEWP" ) )  THEN
491              zw3d(:,:,:) = zpronewn(:,:,:) * zfact * tmask(:,:,:)  ! new primary production by nanophyto
492              CALL iom_put( "PPNEWN"  , zw3d )
493              !
494              zw3d(:,:,:) = zpronewp(:,:,:) * zfact * tmask(:,:,:)  ! new primary production by picophyto
495              CALL iom_put( "PPNEWP"  , zw3d )
496              !
497              zw3d(:,:,:) = zpronewd(:,:,:) * zfact * tmask(:,:,:)  ! new primary production by diatomes
498              CALL iom_put( "PPNEWD"  , zw3d )
499          ENDIF
500          IF( iom_use( "PBSi" ) )  THEN
501              zw3d(:,:,:) = zprorcad(:,:,:) * zfact * tmask(:,:,:) * zysopt(:,:,:) ! biogenic silica production
502              CALL iom_put( "PBSi"  , zw3d )
503          ENDIF
504          IF( iom_use( "PFeN" ) .OR. iom_use( "PFeD" ) .OR. iom_use( "PFeP" ) )  THEN
505              zw3d(:,:,:) = zprofen(:,:,:) * zfact * tmask(:,:,:)  ! biogenic iron production by nanophyto
506              CALL iom_put( "PFeN"  , zw3d )
507              !
508              zw3d(:,:,:) = zprofep(:,:,:) * zfact * tmask(:,:,:)  ! biogenic iron production by picophyto
509              CALL iom_put( "PFeP"  , zw3d )
510              !
511              zw3d(:,:,:) = zprofed(:,:,:) * zfact * tmask(:,:,:)  ! biogenic iron production by  diatomes
512              CALL iom_put( "PFeD"  , zw3d )
513          ENDIF
514          IF( iom_use( "Mumax" ) )  THEN
515              zw3d(:,:,:) = prmaxn(:,:,:) * tmask(:,:,:)   ! Maximum growth rate
516              CALL iom_put( "Mumax"  , zw3d )
517          ENDIF
518          IF( iom_use( "MuN" ) .OR. iom_use( "MuD" ) .OR. iom_use( "MuP" ) )  THEN
519              zw3d(:,:,:) = zprbio(:,:,:) * xlimphy(:,:,:) * tmask(:,:,:)  ! Realized growth rate for nanophyto
520              CALL iom_put( "MuN"  , zw3d )
521              !
522              zw3d(:,:,:) = zprpic(:,:,:) * xlimpic(:,:,:) * tmask(:,:,:)  ! Realized growth rate for picophyto
523              CALL iom_put( "MuP"  , zw3d )
524              !
525              zw3d(:,:,:) =  zprdia(:,:,:) * xlimdia(:,:,:) * tmask(:,:,:)  ! Realized growth rate for diatoms
526              CALL iom_put( "MuD"  , zw3d )
527          ENDIF
528          IF( iom_use( "LNlight" ) .OR. iom_use( "LDlight" ) .OR. iom_use( "LPlight" ) )  THEN
529              zw3d(:,:,:) = zprbio (:,:,:) / (prmaxn(:,:,:) + rtrn) * tmask(:,:,:) ! light limitation term
530              CALL iom_put( "LNlight"  , zw3d )
531              !
532              zw3d(:,:,:) = zprpic (:,:,:) / (prmaxp(:,:,:) + rtrn) * tmask(:,:,:) ! light limitation term
533              CALL iom_put( "LPlight"  , zw3d )
534              !
535              zw3d(:,:,:) =  zprdia (:,:,:) / (prmaxd(:,:,:) + rtrn) * tmask(:,:,:)  ! light limitation term
536              CALL iom_put( "LDlight"  , zw3d )
537          ENDIF
538          IF( iom_use( "MunetN" ) .OR. iom_use( "MunetD" ) .OR. iom_use( "MunetP" ) )  THEN
539              zw3d(:,:,:) = zcroissn(:,:,:) * tmask(:,:,:) ! ! Realized growth rate for nanophyto
540              CALL iom_put( "MunetN"  , zw3d )
541              !
542              zw3d(:,:,:) = zcroissp(:,:,:) * tmask(:,:,:) ! ! Realized growth rate for picophyto
543              CALL iom_put( "MunetP"  , zw3d )
544              !
545              zw3d(:,:,:) = zcroissd(:,:,:) * tmask(:,:,:) ! ! Realized growth rate for diatomes
546              CALL iom_put( "MunetD"  , zw3d )
547              !
548          ENDIF
549
550          IF( iom_use( "tintpp" ) )  CALL iom_put( "tintpp" , tpp * zfact )  !  global total integrated primary production molC/s
551          !
552          CALL wrk_dealloc( jpi, jpj,      zw2d )
553          CALL wrk_dealloc( jpi, jpj, jpk, zw3d )
554       ENDIF
555     ENDIF
556
557      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
558         WRITE(charout, FMT="('prod')")
559         CALL prt_ctl_trc_info(charout)
560         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
561      ENDIF
562      !
563      CALL wrk_dealloc( jpi, jpj,      zmixnano, zmixpico, zmixdiat, zstrn )
564      CALL wrk_dealloc( jpi, jpj, jpk, zmxl_fac, zmxl_chl )
565      CALL wrk_dealloc( jpi, jpj, jpk, zpislopeadn, zpislopeadp, zpislopeadd, zysopt )                           
566      CALL wrk_dealloc( jpi, jpj, jpk, zprdia, zprpic, zprbio, zprorcan, zprorcap, zprorcad )
567      CALL wrk_dealloc( jpi, jpj, jpk, zprofed, zprofep, zprofen ) 
568      CALL wrk_dealloc( jpi, jpj, jpk, zpronewn, zpronewp, zpronewd, zproregn, zproregp, zproregd )
569      CALL wrk_dealloc( jpi, jpj, jpk, zpropo4n, zpropo4p, zpropo4d, zrespn, zrespp, zrespd, zprnut )
570      CALL wrk_dealloc( jpi, jpj, jpk, zprchln, zprchlp, zprchld, zprodopn, zprodopp, zprodopd )
571      CALL wrk_dealloc( jpi, jpj, jpk, zcroissp, zcroissn, zcroissd )
572      !
573      IF( nn_timing == 1 )  CALL timing_stop('p5z_prod')
574      !
575   END SUBROUTINE p5z_prod
576
577
578   SUBROUTINE p5z_prod_init
579      !!----------------------------------------------------------------------
580      !!                  ***  ROUTINE p5z_prod_init  ***
581      !!
582      !! ** Purpose :   Initialization of phytoplankton production parameters
583      !!
584      !! ** Method  :   Read the nampisprod namelist and check the parameters
585      !!      called at the first timestep (nittrc000)
586      !!
587      !! ** input   :   Namelist nampisprod
588      !!----------------------------------------------------------------------
589      !
590      NAMELIST/namp5zprod/ pislopen, pislopep, pisloped, excretn, excretp, excretd,     &
591         &                 thetannm, thetanpm, thetandm, chlcmin, grosip, bresp, xadap
592
593      INTEGER :: ios                 ! Local integer output status for namelist read
594      !!----------------------------------------------------------------------
595
596      REWIND( numnatp_ref )              ! Namelist nampisprod in reference namelist : Pisces phytoplankton production
597      READ  ( numnatp_ref, namp5zprod, IOSTAT = ios, ERR = 901)
598901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namp5zprod in reference namelist', lwp )
599
600      REWIND( numnatp_cfg )              ! Namelist nampisprod in configuration namelist : Pisces phytoplankton production
601      READ  ( numnatp_cfg, namp5zprod, IOSTAT = ios, ERR = 902 )
602902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namp5zprod in configuration namelist', lwp )
603      IF(lwm) WRITE ( numonp, namp5zprod )
604
605      IF(lwp) THEN                         ! control print
606         WRITE(numout,*) ' '
607         WRITE(numout,*) ' Namelist parameters for phytoplankton growth, namp5zprod'
608         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
609         WRITE(numout,*) '    mean Si/C ratio                           grosip       =', grosip
610         WRITE(numout,*) '    P-I slope                                 pislopen     =', pislopen
611         WRITE(numout,*) '    P-I slope  for diatoms                    pisloped     =', pisloped
612         WRITE(numout,*) '    P-I slope  for picophytoplankton          pislopep     =', pislopep
613         WRITE(numout,*) '    Acclimation factor to low light           xadap        =', xadap
614         WRITE(numout,*) '    excretion ratio of nanophytoplankton      excretn      =', excretn
615         WRITE(numout,*) '    excretion ratio of picophytoplankton      excretp      =', excretp
616         WRITE(numout,*) '    excretion ratio of diatoms                excretd      =', excretd
617         WRITE(numout,*) '    basal respiration in phytoplankton        bresp        =', bresp
618         WRITE(numout,*) '    Maximum Chl/C in phytoplankton            chlcmin      =', chlcmin
619         WRITE(numout,*) '    Minimum Chl/N in nanophytoplankton        thetannm     =', thetannm
620         WRITE(numout,*) '    Minimum Chl/N in picophytoplankton        thetanpm     =', thetanpm
621         WRITE(numout,*) '    Minimum Chl/N in diatoms                  thetandm     =', thetandm
622      ENDIF
623      !
624      r1_rday   = 1._wp / rday 
625      texcretn  = 1._wp - excretn
626      texcretp  = 1._wp - excretp
627      texcretd  = 1._wp - excretd
628      tpp       = 0._wp
629      !
630   END SUBROUTINE p5z_prod_init
631
632
633   INTEGER FUNCTION p5z_prod_alloc()
634      !!----------------------------------------------------------------------
635      !!                     ***  ROUTINE p5z_prod_alloc  ***
636      !!----------------------------------------------------------------------
637      ALLOCATE( prmaxn(jpi,jpj,jpk), prmaxp(jpi,jpj,jpk), prmaxd(jpi,jpj,jpk),  &
638      &          zdaylen(jpi,jpj), STAT = p5z_prod_alloc )
639      !
640      IF( p5z_prod_alloc /= 0 ) CALL ctl_warn('p5z_prod_alloc : failed to allocate arrays.')
641      !
642   END FUNCTION p5z_prod_alloc
643   !!======================================================================
644END MODULE  p5zprod
Note: See TracBrowser for help on using the repository browser.