New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
restart.F90 in branches/UKMO/restart_datestamp/NEMOGCM/NEMO/OPA_SRC/IOM – NEMO

source: branches/UKMO/restart_datestamp/NEMOGCM/NEMO/OPA_SRC/IOM/restart.F90 @ 5538

Last change on this file since 5538 was 5538, checked in by davestorkey, 9 years ago

This the functional change for this branch!
File size: 14.2 KB
Line 
1MODULE restart
2   !!======================================================================
3   !!                     ***  MODULE  restart  ***
4   !! Ocean restart :  write the ocean restart file
5   !!======================================================================
6   !! History :  OPA  !  1999-11  (M. Imbard)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec)  F90: Free form
8   !!            2.0  !  2006-07  (S. Masson)  use IOM for restart
9   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  modified LF-RA
10   !!            - -  !  2010-10  (C. Ethe, G. Madec) TRC-TRA merge (T-S in 4D)
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   rst_opn    : open the ocean restart file
15   !!   rst_write  : write the ocean restart file
16   !!   rst_read   : read the ocean restart file
17   !!----------------------------------------------------------------------
18   USE oce             ! ocean dynamics and tracers
19   USE dom_oce         ! ocean space and time domain
20   USE phycst          ! physical constants
21   USE in_out_manager  ! I/O manager
22   USE iom             ! I/O module
23   USE ioipsl, ONLY : ju2ymds    ! for calendar
24   USE eosbn2          ! equation of state            (eos bn2 routine)
25   USE trdmxl_oce      ! ocean active mixed layer tracers trends variables
26   USE divcur          ! hor. divergence and curl      (div & cur routines)
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   rst_opn         ! routine called by step module
32   PUBLIC   rst_write       ! routine called by step module
33   PUBLIC   rst_read        ! routine called by istate module
34   PUBLIC   rst_read_open   ! routine called in rst_read and (possibly) in dom_vvl_init
35
36   !! * Substitutions
37#  include "domzgr_substitute.h90"
38#  include "vectopt_loop_substitute.h90"
39   !!----------------------------------------------------------------------
40   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
41   !! $Id$
42   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
43   !!----------------------------------------------------------------------
44CONTAINS
45
46   SUBROUTINE rst_opn( kt )
47      !!---------------------------------------------------------------------
48      !!                   ***  ROUTINE rst_opn  ***
49      !!                     
50      !! ** Purpose : + initialization (should be read in the namelist) of nitrst
51      !!              + open the restart when we are one time step before nitrst
52      !!                   - restart header is defined when kt = nitrst-1
53      !!                   - restart data  are written when kt = nitrst
54      !!              + define lrst_oce to .TRUE. when we need to define or write the restart
55      !!----------------------------------------------------------------------
56      INTEGER, INTENT(in) ::   kt     ! ocean time-step
57      INTEGER             ::   iyear, imonth, iday
58      REAL (wp)           ::   zsec
59      !!
60      CHARACTER(LEN=20)   ::   clkt     ! ocean time-step deine as a character
61      CHARACTER(LEN=50)   ::   clname   ! ocean output restart file name
62      CHARACTER(LEN=150)  ::   clpath   ! full path to ocean output restart file
63      !!----------------------------------------------------------------------
64      !
65      IF( kt == nit000 ) THEN   ! default definitions
66         lrst_oce = .FALSE.   
67         IF( ln_rst_list ) THEN
68            nrst_lst = 1
69            nitrst = nstocklist( nrst_lst )
70         ELSE
71            nitrst = nitend
72         ENDIF
73      ENDIF
74
75      ! frequency-based restart dumping (nn_stock)
76      IF( .NOT. ln_rst_list .AND. MOD( kt - 1, nstock ) == 0 ) THEN   
77         ! we use kt - 1 and not kt - nit000 to keep the same periodicity from the beginning of the experiment
78         nitrst = kt + nstock - 1                  ! define the next value of nitrst for restart writing
79         IF( nitrst > nitend )   nitrst = nitend   ! make sure we write a restart at the end of the run
80      ENDIF
81      ! to get better performances with NetCDF format:
82      ! we open and define the ocean restart file one time step before writing the data (-> at nitrst - 1)
83      ! except if we write ocean restart files every time step or if an ocean restart file was writen at nitend - 1
84      IF( kt == nitrst - 1 .OR. nstock == 1 .OR. ( kt == nitend .AND. .NOT. lrst_oce ) ) THEN
85         IF( nitrst <= nitend .AND. nitrst > 0 ) THEN
86            IF ( ln_rstdate ) THEN
87               CALL ju2ymds( fjulday + rdttra(1) / rday, iyear, imonth, iday, zsec )           
88               WRITE(clkt, '(i4.4,2i2.2)') iyear, imonth, iday
89            ELSE
90               ! beware of the format used to write kt (default is i8.8, that should be large enough...)
91               IF( nitrst > 999999999 ) THEN   ;   WRITE(clkt, *       ) nitrst
92               ELSE                            ;   WRITE(clkt, '(i8.8)') nitrst
93               ENDIF
94            ENDIF
95            ! create the file
96            clname = TRIM(cexper)//"_"//TRIM(ADJUSTL(clkt))//"_"//TRIM(cn_ocerst_out)
97            clpath = TRIM(cn_ocerst_outdir)
98            IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
99            IF(lwp) THEN
100               WRITE(numout,*)
101               SELECT CASE ( jprstlib )
102               CASE ( jprstdimg )   ;   WRITE(numout,*)                            &
103                   '             open ocean restart binary file: ',TRIM(clpath)//clname
104               CASE DEFAULT         ;   WRITE(numout,*)                            &
105                   '             open ocean restart NetCDF file: ',TRIM(clpath)//clname
106               END SELECT
107               IF ( snc4set%luse )      WRITE(numout,*) '             opened for NetCDF4 chunking and compression'
108               IF( kt == nitrst - 1 ) THEN   ;   WRITE(numout,*) '             kt = nitrst - 1 = ', kt
109               ELSE                          ;   WRITE(numout,*) '             kt = '             , kt
110               ENDIF
111            ENDIF
112            !
113            CALL iom_open( TRIM(clpath)//TRIM(clname), numrow, ldwrt = .TRUE., kiolib = jprstlib )
114            lrst_oce = .TRUE.
115         ENDIF
116      ENDIF
117      !
118   END SUBROUTINE rst_opn
119
120
121   SUBROUTINE rst_write( kt )
122      !!---------------------------------------------------------------------
123      !!                   ***  ROUTINE rstwrite  ***
124      !!                     
125      !! ** Purpose :   Write restart fields in the format corresponding to jprstlib
126      !!
127      !! ** Method  :   Write in numrow when kt == nitrst in NetCDF
128      !!              file, save fields which are necessary for restart
129      !!----------------------------------------------------------------------
130      INTEGER, INTENT(in) ::   kt   ! ocean time-step
131      !!----------------------------------------------------------------------
132
133                     CALL iom_rstput( kt, nitrst, numrow, 'rdt'    , rdt       )   ! dynamics time step
134                     CALL iom_rstput( kt, nitrst, numrow, 'rdttra1', rdttra(1) )   ! surface tracer time step
135
136                     CALL iom_rstput( kt, nitrst, numrow, 'ub'     , ub        )     ! before fields
137                     CALL iom_rstput( kt, nitrst, numrow, 'vb'     , vb        )
138                     CALL iom_rstput( kt, nitrst, numrow, 'tb'     , tsb(:,:,:,jp_tem) )
139                     CALL iom_rstput( kt, nitrst, numrow, 'sb'     , tsb(:,:,:,jp_sal) )
140                     CALL iom_rstput( kt, nitrst, numrow, 'rotb'   , rotb      )
141                     CALL iom_rstput( kt, nitrst, numrow, 'hdivb'  , hdivb     )
142                     CALL iom_rstput( kt, nitrst, numrow, 'sshb'   , sshb      )
143                     !
144                     CALL iom_rstput( kt, nitrst, numrow, 'un'     , un        )     ! now fields
145                     CALL iom_rstput( kt, nitrst, numrow, 'vn'     , vn        )
146                     CALL iom_rstput( kt, nitrst, numrow, 'tn'     , tsn(:,:,:,jp_tem) )
147                     CALL iom_rstput( kt, nitrst, numrow, 'sn'     , tsn(:,:,:,jp_sal) )
148                     CALL iom_rstput( kt, nitrst, numrow, 'rotn'   , rotn      )
149                     CALL iom_rstput( kt, nitrst, numrow, 'hdivn'  , hdivn     )
150                     CALL iom_rstput( kt, nitrst, numrow, 'sshn'   , sshn      )
151                     CALL iom_rstput( kt, nitrst, numrow, 'rhop'   , rhop      )
152#if defined key_zdfkpp
153                     CALL iom_rstput( kt, nitrst, numrow, 'rhd'    , rhd       )
154#endif
155      IF( kt == nitrst ) THEN
156         CALL iom_close( numrow )     ! close the restart file (only at last time step)
157!!gm         IF( .NOT. lk_trdmld )   lrst_oce = .FALSE.
158!!gm  not sure what to do here   ===>>>  ask to Sebastian
159         lrst_oce = .FALSE.
160            IF( ln_rst_list ) THEN
161               nrst_lst = MIN(nrst_lst + 1, SIZE(nstocklist,1))
162               nitrst = nstocklist( nrst_lst )
163            ENDIF
164            lrst_oce = .FALSE.
165      ENDIF
166      !
167   END SUBROUTINE rst_write
168
169
170   SUBROUTINE rst_read_open
171      !!----------------------------------------------------------------------
172      !!                   ***  ROUTINE rst_read_open  ***
173      !!
174      !! ** Purpose :   Open read files for restart (format fixed by jprstlib )
175      !!
176      !! ** Method  :   Use a non-zero, positive value of numror to assess whether or not
177      !!                the file has already been opened
178      !!----------------------------------------------------------------------
179      INTEGER        ::   jlibalt = jprstlib
180      LOGICAL        ::   llok
181      CHARACTER(lc)  ::   clpath   ! full path to ocean output restart file
182      !!----------------------------------------------------------------------
183      !
184      IF( numror <= 0 ) THEN
185         IF(lwp) THEN                                             ! Contol prints
186            WRITE(numout,*)
187            SELECT CASE ( jprstlib )
188            CASE ( jpnf90    )   ;   WRITE(numout,*) 'rst_read : read oce NetCDF restart file'
189            CASE ( jprstdimg )   ;   WRITE(numout,*) 'rst_read : read oce binary restart file'
190            END SELECT
191            IF ( snc4set%luse )      WRITE(numout,*) 'rst_read : configured with NetCDF4 support'
192            WRITE(numout,*) '~~~~~~~~'
193         ENDIF
194
195         clpath = TRIM(cn_ocerst_indir)
196         IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
197         IF ( jprstlib == jprstdimg ) THEN
198           ! eventually read netcdf file (monobloc)  for restarting on different number of processors
199           ! if {cn_ocerst_in}.nc exists, then set jlibalt to jpnf90
200           INQUIRE( FILE = TRIM(cn_ocerst_indir)//'/'//TRIM(cn_ocerst_in)//'.nc', EXIST = llok )
201           IF ( llok ) THEN ; jlibalt = jpnf90  ; ELSE ; jlibalt = jprstlib ; ENDIF
202         ENDIF
203         CALL iom_open( TRIM(clpath)//cn_ocerst_in, numror, kiolib = jlibalt )
204      ENDIF
205   END SUBROUTINE rst_read_open
206
207   SUBROUTINE rst_read
208      !!----------------------------------------------------------------------
209      !!                   ***  ROUTINE rst_read  ***
210      !!
211      !! ** Purpose :   Read files for restart (format fixed by jprstlib )
212      !!
213      !! ** Method  :   Read in restart.nc file fields which are necessary for restart
214      !!----------------------------------------------------------------------
215      REAL(wp) ::   zrdt, zrdttra1
216      INTEGER  ::   jk
217      LOGICAL  ::   llok
218      !!----------------------------------------------------------------------
219
220      CALL rst_read_open           ! open restart for reading (if not already opened)
221
222      ! Check dynamics and tracer time-step consistency and force Euler restart if changed
223      IF( iom_varid( numror, 'rdt', ldstop = .FALSE. ) > 0 )   THEN
224         CALL iom_get( numror, 'rdt', zrdt )
225         IF( zrdt /= rdt )   neuler = 0
226      ENDIF
227      IF( iom_varid( numror, 'rdttra1', ldstop = .FALSE. ) > 0 )   THEN
228         CALL iom_get( numror, 'rdttra1', zrdttra1 )
229         IF( zrdttra1 /= rdttra(1) )   neuler = 0
230      ENDIF
231      !
232      IF( iom_varid( numror, 'ub', ldstop = .FALSE. ) > 0 ) THEN
233         CALL iom_get( numror, jpdom_autoglo, 'ub'     , ub      )   ! before fields
234         CALL iom_get( numror, jpdom_autoglo, 'vb'     , vb      )
235         CALL iom_get( numror, jpdom_autoglo, 'tb'     , tsb(:,:,:,jp_tem) )
236         CALL iom_get( numror, jpdom_autoglo, 'sb'     , tsb(:,:,:,jp_sal) )
237         CALL iom_get( numror, jpdom_autoglo, 'rotb'   , rotb    )
238         CALL iom_get( numror, jpdom_autoglo, 'hdivb'  , hdivb   )
239         CALL iom_get( numror, jpdom_autoglo, 'sshb'   , sshb    )
240      ELSE
241         neuler = 0
242      ENDIF
243      !
244      CALL iom_get( numror, jpdom_autoglo, 'un'     , un      )   ! now    fields
245      CALL iom_get( numror, jpdom_autoglo, 'vn'     , vn      )
246      CALL iom_get( numror, jpdom_autoglo, 'tn'     , tsn(:,:,:,jp_tem) )
247      CALL iom_get( numror, jpdom_autoglo, 'sn'     , tsn(:,:,:,jp_sal) )
248      CALL iom_get( numror, jpdom_autoglo, 'sshn'   , sshn    )
249      IF( iom_varid( numror, 'rotn', ldstop = .FALSE. ) > 0 ) THEN
250         CALL iom_get( numror, jpdom_autoglo, 'rotn'   , rotn    )
251         CALL iom_get( numror, jpdom_autoglo, 'hdivn'  , hdivn   )
252      ELSE
253         CALL div_cur( 0 )                              ! Horizontal divergence & Relative vorticity
254      ENDIF
255      IF( iom_varid( numror, 'rhop', ldstop = .FALSE. ) > 0 ) THEN
256         CALL iom_get( numror, jpdom_autoglo, 'rhop'   , rhop    )   ! now    potential density
257      ELSE
258         CALL eos    ( tsn, rhd, rhop, fsdept_n(:,:,:) )   
259      ENDIF
260#if defined key_zdfkpp
261      IF( iom_varid( numror, 'rhd', ldstop = .FALSE. ) > 0 ) THEN
262         CALL iom_get( numror, jpdom_autoglo, 'rhd'    , rhd     )   ! now    in situ density anomaly
263      ELSE
264         CALL eos( tsn, rhd, fsdept_n(:,:,:) )   ! compute rhd
265      ENDIF
266#endif
267      !
268      IF( neuler == 0 ) THEN                                  ! Euler restart (neuler=0)
269         tsb  (:,:,:,:) = tsn  (:,:,:,:)                             ! all before fields set to now values
270         ub   (:,:,:)   = un   (:,:,:)
271         vb   (:,:,:)   = vn   (:,:,:)
272         rotb (:,:,:)   = rotn (:,:,:)
273         hdivb(:,:,:)   = hdivn(:,:,:)
274         sshb (:,:)     = sshn (:,:)
275
276         IF( lk_vvl ) THEN
277            DO jk = 1, jpk
278               fse3t_b(:,:,jk) = fse3t_n(:,:,jk)
279            END DO
280         ENDIF
281
282      ENDIF
283      !
284   END SUBROUTINE rst_read
285
286   !!=====================================================================
287END MODULE restart
Note: See TracBrowser for help on using the repository browser.