| 1 | MODULE dtatsd |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE dtatsd *** |
|---|
| 4 | !! Ocean data : read ocean Temperature & Salinity Data from gridded data |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : OPA ! 1991-03 () Original code |
|---|
| 7 | !! - ! 1992-07 (M. Imbard) |
|---|
| 8 | !! 8.0 ! 1999-10 (M.A. Foujols, M. Imbard) NetCDF FORMAT |
|---|
| 9 | !! NEMO 1.0 ! 2002-06 (G. Madec) F90: Free form and module |
|---|
| 10 | !! 3.3 ! 2010-10 (C. Bricaud, S. Masson) use of fldread |
|---|
| 11 | !! 3.4 ! 2010-11 (G. Madec, C. Ethe) Merge of dtatem and dtasal + suppression of CPP keys |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | |
|---|
| 14 | !!---------------------------------------------------------------------- |
|---|
| 15 | !! dta_tsd : read and time interpolated ocean Temperature & Salinity Data |
|---|
| 16 | !!---------------------------------------------------------------------- |
|---|
| 17 | USE oce ! ocean dynamics and tracers |
|---|
| 18 | USE dom_oce ! ocean space and time domain |
|---|
| 19 | USE fldread ! read input fields |
|---|
| 20 | USE in_out_manager ! I/O manager |
|---|
| 21 | USE phycst ! physical constants |
|---|
| 22 | USE lib_mpp ! MPP library |
|---|
| 23 | USE wrk_nemo ! Memory allocation |
|---|
| 24 | USE timing ! Timing |
|---|
| 25 | USE iom_def, ONLY:lspr |
|---|
| 26 | |
|---|
| 27 | IMPLICIT NONE |
|---|
| 28 | PRIVATE |
|---|
| 29 | |
|---|
| 30 | PUBLIC dta_tsd_init ! called by opa.F90 |
|---|
| 31 | PUBLIC dta_tsd ! called by istate.F90 and tradmp.90 |
|---|
| 32 | |
|---|
| 33 | LOGICAL , PUBLIC :: ln_tsd_init !: T & S data flag |
|---|
| 34 | LOGICAL , PUBLIC :: ln_tsd_tradmp !: internal damping toward input data flag |
|---|
| 35 | LOGICAL , PUBLIC :: ln_tsd_sio !: read file using 1 processor |
|---|
| 36 | |
|---|
| 37 | TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_tsd ! structure of input SST (file informations, fields read) |
|---|
| 38 | |
|---|
| 39 | !! * Substitutions |
|---|
| 40 | # include "domzgr_substitute.h90" |
|---|
| 41 | !!---------------------------------------------------------------------- |
|---|
| 42 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
|---|
| 43 | !! $Id$ |
|---|
| 44 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 45 | !!---------------------------------------------------------------------- |
|---|
| 46 | CONTAINS |
|---|
| 47 | |
|---|
| 48 | SUBROUTINE dta_tsd_init( ld_tradmp ) |
|---|
| 49 | !!---------------------------------------------------------------------- |
|---|
| 50 | !! *** ROUTINE dta_tsd_init *** |
|---|
| 51 | !! |
|---|
| 52 | !! ** Purpose : initialisation of T & S input data |
|---|
| 53 | !! |
|---|
| 54 | !! ** Method : - Read namtsd namelist |
|---|
| 55 | !! - allocates T & S data structure |
|---|
| 56 | !!---------------------------------------------------------------------- |
|---|
| 57 | LOGICAL, INTENT(in), OPTIONAL :: ld_tradmp ! force the initialization when tradp is used |
|---|
| 58 | ! |
|---|
| 59 | INTEGER :: ierr0, ierr1, ierr2, ierr3 ! temporary integers |
|---|
| 60 | ! |
|---|
| 61 | CHARACTER(len=100) :: cn_dir ! Root directory for location of ssr files |
|---|
| 62 | TYPE(FLD_N), DIMENSION( jpts) :: slf_i ! array of namelist informations on the fields to read |
|---|
| 63 | TYPE(FLD_N) :: sn_tem, sn_sal |
|---|
| 64 | !! |
|---|
| 65 | NAMELIST/namtsd/ ln_tsd_init, ln_tsd_tradmp, cn_dir, sn_tem, sn_sal, ln_tsd_sio |
|---|
| 66 | INTEGER :: ios |
|---|
| 67 | !!---------------------------------------------------------------------- |
|---|
| 68 | ! |
|---|
| 69 | IF( nn_timing == 1 ) CALL timing_start('dta_tsd_init') |
|---|
| 70 | ! |
|---|
| 71 | ! Initialisation |
|---|
| 72 | ierr0 = 0 ; ierr1 = 0 ; ierr2 = 0 ; ierr3 = 0 |
|---|
| 73 | ! |
|---|
| 74 | ln_tsd_sio = .FALSE. |
|---|
| 75 | REWIND( numnam_ref ) ! Namelist namtsd in reference namelist : |
|---|
| 76 | READ ( numnam_ref, namtsd, IOSTAT = ios, ERR = 901) |
|---|
| 77 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtsd in reference namelist', lwp ) |
|---|
| 78 | |
|---|
| 79 | REWIND( numnam_cfg ) ! Namelist namtsd in configuration namelist : Parameters of the run |
|---|
| 80 | READ ( numnam_cfg, namtsd, IOSTAT = ios, ERR = 902 ) |
|---|
| 81 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtsd in configuration namelist', lwp ) |
|---|
| 82 | IF(lwm) WRITE ( numond, namtsd ) |
|---|
| 83 | |
|---|
| 84 | IF( PRESENT( ld_tradmp ) ) ln_tsd_tradmp = .TRUE. ! forces the initialization when tradmp is used |
|---|
| 85 | |
|---|
| 86 | IF(lwp) THEN ! control print |
|---|
| 87 | WRITE(numout,*) |
|---|
| 88 | WRITE(numout,*) 'dta_tsd_init : Temperature & Salinity data ' |
|---|
| 89 | WRITE(numout,*) '~~~~~~~~~~~~ ' |
|---|
| 90 | WRITE(numout,*) ' Namelist namtsd' |
|---|
| 91 | WRITE(numout,*) ' Initialisation of ocean T & S with T &S input data ln_tsd_init = ', ln_tsd_init |
|---|
| 92 | WRITE(numout,*) ' damping of ocean T & S toward T &S input data ln_tsd_tradmp = ', ln_tsd_tradmp |
|---|
| 93 | WRITE(numout,*) |
|---|
| 94 | IF( .NOT.ln_tsd_init .AND. .NOT.ln_tsd_tradmp ) THEN |
|---|
| 95 | WRITE(numout,*) |
|---|
| 96 | WRITE(numout,*) ' T & S data not used' |
|---|
| 97 | ENDIF |
|---|
| 98 | ENDIF |
|---|
| 99 | ! |
|---|
| 100 | IF( ln_rstart .AND. ln_tsd_init ) THEN |
|---|
| 101 | CALL ctl_warn( 'dta_tsd_init: ocean restart and T & S data intialisation, ', & |
|---|
| 102 | & 'we keep the restart T & S values and set ln_tsd_init to FALSE' ) |
|---|
| 103 | ln_tsd_init = .FALSE. |
|---|
| 104 | ENDIF |
|---|
| 105 | ! |
|---|
| 106 | ! ! allocate the arrays (if necessary) |
|---|
| 107 | IF( ln_tsd_init .OR. ln_tsd_tradmp ) THEN |
|---|
| 108 | ! |
|---|
| 109 | ALLOCATE( sf_tsd(jpts), STAT=ierr0 ) |
|---|
| 110 | IF( ierr0 > 0 ) THEN |
|---|
| 111 | CALL ctl_stop( 'dta_tsd_init: unable to allocate sf_tsd structure' ) ; RETURN |
|---|
| 112 | ENDIF |
|---|
| 113 | ! |
|---|
| 114 | ALLOCATE( sf_tsd(jp_tem)%fnow(jpi,jpj,jpk) , STAT=ierr0 ) |
|---|
| 115 | IF( sn_tem%ln_tint ) ALLOCATE( sf_tsd(jp_tem)%fdta(jpi,jpj,jpk,2) , STAT=ierr1 ) |
|---|
| 116 | ALLOCATE( sf_tsd(jp_sal)%fnow(jpi,jpj,jpk) , STAT=ierr2 ) |
|---|
| 117 | IF( sn_sal%ln_tint ) ALLOCATE( sf_tsd(jp_sal)%fdta(jpi,jpj,jpk,2) , STAT=ierr3 ) |
|---|
| 118 | ! |
|---|
| 119 | IF( ierr0 + ierr1 + ierr2 + ierr3 > 0 ) THEN |
|---|
| 120 | CALL ctl_stop( 'dta_tsd : unable to allocate T & S data arrays' ) ; RETURN |
|---|
| 121 | ENDIF |
|---|
| 122 | ! ! fill sf_tsd with sn_tem & sn_sal and control print |
|---|
| 123 | slf_i(jp_tem) = sn_tem ; slf_i(jp_sal) = sn_sal |
|---|
| 124 | CALL fld_fill( sf_tsd, slf_i, cn_dir, 'dta_tsd', 'Temperature & Salinity data', 'namtsd' ) |
|---|
| 125 | ! |
|---|
| 126 | ENDIF |
|---|
| 127 | ! |
|---|
| 128 | IF( nn_timing == 1 ) CALL timing_stop('dta_tsd_init') |
|---|
| 129 | ! |
|---|
| 130 | END SUBROUTINE dta_tsd_init |
|---|
| 131 | |
|---|
| 132 | |
|---|
| 133 | SUBROUTINE dta_tsd( kt, ptsd ) |
|---|
| 134 | !!---------------------------------------------------------------------- |
|---|
| 135 | !! *** ROUTINE dta_tsd *** |
|---|
| 136 | !! |
|---|
| 137 | !! ** Purpose : provides T and S data at kt |
|---|
| 138 | !! |
|---|
| 139 | !! ** Method : - call fldread routine |
|---|
| 140 | !! - ORCA_R2: add some hand made alteration to read data |
|---|
| 141 | !! - 'key_orca_lev10' interpolates on 10 times more levels |
|---|
| 142 | !! - s- or mixed z-s coordinate: vertical interpolation on model mesh |
|---|
| 143 | !! - ln_tsd_tradmp=F: deallocates the T-S data structure |
|---|
| 144 | !! as T-S data are no are used |
|---|
| 145 | !! |
|---|
| 146 | !! ** Action : ptsd T-S data on medl mesh and interpolated at time-step kt |
|---|
| 147 | !!---------------------------------------------------------------------- |
|---|
| 148 | INTEGER , INTENT(in ) :: kt ! ocean time-step |
|---|
| 149 | REAL(wp), DIMENSION(jpi,jpj,jpk,jpts), INTENT( out) :: ptsd ! T & S data |
|---|
| 150 | ! |
|---|
| 151 | INTEGER :: ji, jj, jk, jl, jkk ! dummy loop indicies |
|---|
| 152 | INTEGER :: ik, il0, il1, ii0, ii1, ij0, ij1 ! local integers |
|---|
| 153 | REAL(wp):: zl, zi |
|---|
| 154 | REAL(wp), POINTER, DIMENSION(:) :: ztp, zsp ! 1D workspace |
|---|
| 155 | !!---------------------------------------------------------------------- |
|---|
| 156 | ! |
|---|
| 157 | IF( nn_timing == 1 ) CALL timing_start('dta_tsd') |
|---|
| 158 | ! |
|---|
| 159 | lspr = ln_tsd_sio |
|---|
| 160 | CALL fld_read( kt, 1, sf_tsd ) !== read T & S data at kt time step ==! |
|---|
| 161 | lspr = .false. |
|---|
| 162 | ! |
|---|
| 163 | ! |
|---|
| 164 | ! !== ORCA_R2 configuration and T & S damping ==! |
|---|
| 165 | IF( cp_cfg == "orca" .AND. jp_cfg == 2 .AND. ln_tsd_tradmp ) THEN ! some hand made alterations |
|---|
| 166 | ! |
|---|
| 167 | ij0 = 101 ; ij1 = 109 ! Reduced T & S in the Alboran Sea |
|---|
| 168 | ii0 = 141 ; ii1 = 155 |
|---|
| 169 | DO jj = mj0(ij0), mj1(ij1) |
|---|
| 170 | DO ji = mi0(ii0), mi1(ii1) |
|---|
| 171 | sf_tsd(jp_tem)%fnow(ji,jj,13:13) = sf_tsd(jp_tem)%fnow(ji,jj,13:13) - 0.20_wp |
|---|
| 172 | sf_tsd(jp_tem)%fnow(ji,jj,14:15) = sf_tsd(jp_tem)%fnow(ji,jj,14:15) - 0.35_wp |
|---|
| 173 | sf_tsd(jp_tem)%fnow(ji,jj,16:25) = sf_tsd(jp_tem)%fnow(ji,jj,16:25) - 0.40_wp |
|---|
| 174 | ! |
|---|
| 175 | sf_tsd(jp_sal)%fnow(ji,jj,13:13) = sf_tsd(jp_sal)%fnow(ji,jj,13:13) - 0.15_wp |
|---|
| 176 | sf_tsd(jp_sal)%fnow(ji,jj,14:15) = sf_tsd(jp_sal)%fnow(ji,jj,14:15) - 0.25_wp |
|---|
| 177 | sf_tsd(jp_sal)%fnow(ji,jj,16:17) = sf_tsd(jp_sal)%fnow(ji,jj,16:17) - 0.30_wp |
|---|
| 178 | sf_tsd(jp_sal)%fnow(ji,jj,18:25) = sf_tsd(jp_sal)%fnow(ji,jj,18:25) - 0.35_wp |
|---|
| 179 | END DO |
|---|
| 180 | END DO |
|---|
| 181 | IF( nn_cla == 1 ) THEN ! Cross Land advection |
|---|
| 182 | il0 = 138 ; il1 = 138 ! set T & S profile at Gibraltar Strait |
|---|
| 183 | ij0 = 101 ; ij1 = 102 |
|---|
| 184 | ii0 = 139 ; ii1 = 139 |
|---|
| 185 | DO jl = mi0(il0), mi1(il1) |
|---|
| 186 | DO jj = mj0(ij0), mj1(ij1) |
|---|
| 187 | DO ji = mi0(ii0), mi1(ii1) |
|---|
| 188 | sf_tsd(jp_tem)%fnow(ji,jj,:) = sf_tsd(jp_tem)%fnow(jl,jj,:) |
|---|
| 189 | sf_tsd(jp_sal)%fnow(ji,jj,:) = sf_tsd(jp_sal)%fnow(jl,jj,:) |
|---|
| 190 | END DO |
|---|
| 191 | END DO |
|---|
| 192 | END DO |
|---|
| 193 | il0 = 164 ; il1 = 164 ! set T & S profile at Bab el Mandeb Strait |
|---|
| 194 | ij0 = 87 ; ij1 = 88 |
|---|
| 195 | ii0 = 161 ; ii1 = 163 |
|---|
| 196 | DO jl = mi0(il0), mi1(il1) |
|---|
| 197 | DO jj = mj0(ij0), mj1(ij1) |
|---|
| 198 | DO ji = mi0(ii0), mi1(ii1) |
|---|
| 199 | sf_tsd(jp_tem)%fnow(ji,jj,:) = sf_tsd(jp_tem)%fnow(jl,jj,:) |
|---|
| 200 | sf_tsd(jp_sal)%fnow(ji,jj,:) = sf_tsd(jp_sal)%fnow(jl,jj,:) |
|---|
| 201 | END DO |
|---|
| 202 | END DO |
|---|
| 203 | END DO |
|---|
| 204 | ELSE ! No Cross Land advection |
|---|
| 205 | ij0 = 87 ; ij1 = 96 ! Reduced temperature in Red Sea |
|---|
| 206 | ii0 = 148 ; ii1 = 160 |
|---|
| 207 | sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) , 4:10 ) = 7.0_wp |
|---|
| 208 | sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) , 11:13 ) = 6.5_wp |
|---|
| 209 | sf_tsd(jp_tem)%fnow( mi0(ii0):mi1(ii1) , mj0(ij0):mj1(ij1) , 14:20 ) = 6.0_wp |
|---|
| 210 | ENDIF |
|---|
| 211 | ENDIF |
|---|
| 212 | ! |
|---|
| 213 | ptsd(:,:,:,jp_tem) = sf_tsd(jp_tem)%fnow(:,:,:) ! NO mask |
|---|
| 214 | ptsd(:,:,:,jp_sal) = sf_tsd(jp_sal)%fnow(:,:,:) |
|---|
| 215 | ! |
|---|
| 216 | IF( ln_sco ) THEN !== s- or mixed s-zps-coordinate ==! |
|---|
| 217 | ! |
|---|
| 218 | CALL wrk_alloc( jpk, ztp, zsp ) |
|---|
| 219 | ! |
|---|
| 220 | IF( kt == nit000 .AND. lwp )THEN |
|---|
| 221 | WRITE(numout,*) |
|---|
| 222 | WRITE(numout,*) 'dta_tsd: interpolates T & S data onto the s- or mixed s-z-coordinate mesh' |
|---|
| 223 | ENDIF |
|---|
| 224 | ! |
|---|
| 225 | DO jj = 1, jpj ! vertical interpolation of T & S |
|---|
| 226 | DO ji = 1, jpi |
|---|
| 227 | DO jk = 1, jpk ! determines the intepolated T-S profiles at each (i,j) points |
|---|
| 228 | zl = gdept_0(ji,jj,jk) |
|---|
| 229 | IF( zl < gdept_1d(1 ) ) THEN ! above the first level of data |
|---|
| 230 | ztp(jk) = ptsd(ji,jj,1 ,jp_tem) |
|---|
| 231 | zsp(jk) = ptsd(ji,jj,1 ,jp_sal) |
|---|
| 232 | ELSEIF( zl > gdept_1d(jpk) ) THEN ! below the last level of data |
|---|
| 233 | ztp(jk) = ptsd(ji,jj,jpkm1,jp_tem) |
|---|
| 234 | zsp(jk) = ptsd(ji,jj,jpkm1,jp_sal) |
|---|
| 235 | ELSE ! inbetween : vertical interpolation between jkk & jkk+1 |
|---|
| 236 | DO jkk = 1, jpkm1 ! when gdept(jkk) < zl < gdept(jkk+1) |
|---|
| 237 | IF( (zl-gdept_1d(jkk)) * (zl-gdept_1d(jkk+1)) <= 0._wp ) THEN |
|---|
| 238 | zi = ( zl - gdept_1d(jkk) ) / (gdept_1d(jkk+1)-gdept_1d(jkk)) |
|---|
| 239 | ztp(jk) = ptsd(ji,jj,jkk,jp_tem) + ( ptsd(ji,jj,jkk+1,jp_tem) - ptsd(ji,jj,jkk,jp_tem) ) * zi |
|---|
| 240 | zsp(jk) = ptsd(ji,jj,jkk,jp_sal) + ( ptsd(ji,jj,jkk+1,jp_sal) - ptsd(ji,jj,jkk,jp_sal) ) * zi |
|---|
| 241 | ENDIF |
|---|
| 242 | END DO |
|---|
| 243 | ENDIF |
|---|
| 244 | END DO |
|---|
| 245 | DO jk = 1, jpkm1 |
|---|
| 246 | ptsd(ji,jj,jk,jp_tem) = ztp(jk) * tmask(ji,jj,jk) ! mask required for mixed zps-s-coord |
|---|
| 247 | ptsd(ji,jj,jk,jp_sal) = zsp(jk) * tmask(ji,jj,jk) |
|---|
| 248 | END DO |
|---|
| 249 | ptsd(ji,jj,jpk,jp_tem) = 0._wp |
|---|
| 250 | ptsd(ji,jj,jpk,jp_sal) = 0._wp |
|---|
| 251 | END DO |
|---|
| 252 | END DO |
|---|
| 253 | ! |
|---|
| 254 | CALL wrk_dealloc( jpk, ztp, zsp ) |
|---|
| 255 | ! |
|---|
| 256 | ELSE !== z- or zps- coordinate ==! |
|---|
| 257 | ! |
|---|
| 258 | ptsd(:,:,:,jp_tem) = ptsd(:,:,:,jp_tem) * tmask(:,:,:) ! Mask |
|---|
| 259 | ptsd(:,:,:,jp_sal) = ptsd(:,:,:,jp_sal) * tmask(:,:,:) |
|---|
| 260 | ! |
|---|
| 261 | IF( ln_zps ) THEN ! zps-coordinate (partial steps) interpolation at the last ocean level |
|---|
| 262 | DO jj = 1, jpj |
|---|
| 263 | DO ji = 1, jpi |
|---|
| 264 | ik = mbkt(ji,jj) |
|---|
| 265 | IF( ik > 1 ) THEN |
|---|
| 266 | zl = ( gdept_1d(ik) - gdept_0(ji,jj,ik) ) / ( gdept_1d(ik) - gdept_1d(ik-1) ) |
|---|
| 267 | ptsd(ji,jj,ik,jp_tem) = (1.-zl) * ptsd(ji,jj,ik,jp_tem) + zl * ptsd(ji,jj,ik-1,jp_tem) |
|---|
| 268 | ptsd(ji,jj,ik,jp_sal) = (1.-zl) * ptsd(ji,jj,ik,jp_sal) + zl * ptsd(ji,jj,ik-1,jp_sal) |
|---|
| 269 | ENDIF |
|---|
| 270 | ik = mikt(ji,jj) |
|---|
| 271 | IF( ik > 1 ) THEN |
|---|
| 272 | zl = ( gdept_0(ji,jj,ik) - gdept_1d(ik) ) / ( gdept_1d(ik+1) - gdept_1d(ik) ) |
|---|
| 273 | ptsd(ji,jj,ik,jp_tem) = (1.-zl) * ptsd(ji,jj,ik,jp_tem) + zl * ptsd(ji,jj,ik+1,jp_tem) |
|---|
| 274 | ptsd(ji,jj,ik,jp_sal) = (1.-zl) * ptsd(ji,jj,ik,jp_sal) + zl * ptsd(ji,jj,ik+1,jp_sal) |
|---|
| 275 | END IF |
|---|
| 276 | END DO |
|---|
| 277 | END DO |
|---|
| 278 | ENDIF |
|---|
| 279 | ! |
|---|
| 280 | ENDIF |
|---|
| 281 | ! |
|---|
| 282 | IF( lwp .AND. kt == nit000 ) THEN |
|---|
| 283 | WRITE(numout,*) ' temperature Levitus ' |
|---|
| 284 | WRITE(numout,*) |
|---|
| 285 | WRITE(numout,*)' level = 1' |
|---|
| 286 | CALL prihre( ptsd(:,:,1 ,jp_tem), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout ) |
|---|
| 287 | WRITE(numout,*)' level = ', jpk/2 |
|---|
| 288 | CALL prihre( ptsd(:,:,jpk/2,jp_tem), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout ) |
|---|
| 289 | WRITE(numout,*)' level = ', jpkm1 |
|---|
| 290 | CALL prihre( ptsd(:,:,jpkm1,jp_tem), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout ) |
|---|
| 291 | WRITE(numout,*) |
|---|
| 292 | WRITE(numout,*) ' salinity Levitus ' |
|---|
| 293 | WRITE(numout,*) |
|---|
| 294 | WRITE(numout,*)' level = 1' |
|---|
| 295 | CALL prihre( ptsd(:,:,1 ,jp_sal), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout ) |
|---|
| 296 | WRITE(numout,*)' level = ', jpk/2 |
|---|
| 297 | CALL prihre( ptsd(:,:,jpk/2,jp_sal), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout ) |
|---|
| 298 | WRITE(numout,*)' level = ', jpkm1 |
|---|
| 299 | CALL prihre( ptsd(:,:,jpkm1,jp_sal), jpi, jpj, 1, jpi, 20, 1, jpj, 20, 1., numout ) |
|---|
| 300 | WRITE(numout,*) |
|---|
| 301 | ENDIF |
|---|
| 302 | ! |
|---|
| 303 | IF( .NOT.ln_tsd_tradmp ) THEN !== deallocate T & S structure ==! |
|---|
| 304 | ! (data used only for initialisation) |
|---|
| 305 | IF(lwp) WRITE(numout,*) 'dta_tsd: deallocte T & S arrays as they are only use to initialize the run' |
|---|
| 306 | DEALLOCATE( sf_tsd(jp_tem)%fnow ) ! T arrays in the structure |
|---|
| 307 | IF( sf_tsd(jp_tem)%ln_tint ) DEALLOCATE( sf_tsd(jp_tem)%fdta ) |
|---|
| 308 | DEALLOCATE( sf_tsd(jp_sal)%fnow ) ! S arrays in the structure |
|---|
| 309 | IF( sf_tsd(jp_sal)%ln_tint ) DEALLOCATE( sf_tsd(jp_sal)%fdta ) |
|---|
| 310 | DEALLOCATE( sf_tsd ) ! the structure itself |
|---|
| 311 | ENDIF |
|---|
| 312 | ! |
|---|
| 313 | IF( nn_timing == 1 ) CALL timing_stop('dta_tsd') |
|---|
| 314 | ! |
|---|
| 315 | END SUBROUTINE dta_tsd |
|---|
| 316 | |
|---|
| 317 | !!====================================================================== |
|---|
| 318 | END MODULE dtatsd |
|---|
