Context Navigation

← Previous Revision
Latest Revision
Next Revision →
Blame
Revision Log

sbcrnf.F90 @ 8243

Last change on this file since 8243 was 8243, checked in by andmirek, 7 years ago
#1914 working XIOS read, XIOS write and single processor read
File size: 29.9 KB

Line
1	MODULE sbcrnf
2	!!======================================================================
3	!! * MODULE sbcrnf *
4	!! Ocean forcing: river runoff
5	!!=====================================================================
6	!! History : OPA ! 2000-11 (R. Hordoir, E. Durand) NetCDF FORMAT
7	!! NEMO 1.0 ! 2002-09 (G. Madec) F90: Free form and module
8	!! 3.0 ! 2006-07 (G. Madec) Surface module
9	!! 3.2 ! 2009-04 (B. Lemaire) Introduce iom_put
10	!! 3.3 ! 2010-10 (R. Furner, G. Madec) runoff distributed over ocean levels
11	!!----------------------------------------------------------------------
12
13	!!----------------------------------------------------------------------
14	!! sbc_rnf : monthly runoffs read in a NetCDF file
15	!! sbc_rnf_init : runoffs initialisation
16	!! rnf_mouth : set river mouth mask
17	!!----------------------------------------------------------------------
18	USE dom_oce ! ocean space and time domain
19	USE phycst ! physical constants
20	USE sbc_oce ! surface boundary condition variables
21	USE sbcisf ! PM we could remove it I think
22	USE closea ! closed seas
23	USE fldread ! read input field at current time step
24	USE in_out_manager ! I/O manager
25	USE iom ! I/O module
26	USE lib_mpp ! MPP library
27	USE eosbn2
28	USE wrk_nemo ! Memory allocation
29	USE iom_def, ONLY : lxios_read, lwxios
30
31	IMPLICIT NONE
32	PRIVATE
33
34	PUBLIC sbc_rnf ! routine call in sbcmod module
35	PUBLIC sbc_rnf_div ! routine called in divcurl module
36	PUBLIC sbc_rnf_alloc ! routine call in sbcmod module
37	PUBLIC sbc_rnf_init ! (PUBLIC for TAM)
38	! !!* namsbc_rnf namelist *
39	CHARACTER(len=100) :: cn_dir !: Root directory for location of rnf files
40	LOGICAL :: ln_rnf_depth !: depth river runoffs attribute specified in a file
41	LOGICAL :: ln_rnf_depth_ini !: depth river runoffs computed at the initialisation
42	REAL(wp) :: rn_rnf_max !: maximum value of the runoff climatologie ( ln_rnf_depth_ini = .true )
43	REAL(wp) :: rn_dep_max !: depth over which runoffs is spread ( ln_rnf_depth_ini = .true )
44	INTEGER :: nn_rnf_depth_file !: create (=1) a runoff depth file or not (=0)
45	LOGICAL :: ln_rnf_tem !: temperature river runoffs attribute specified in a file
46	LOGICAL , PUBLIC :: ln_rnf_sal !: salinity river runoffs attribute specified in a file
47	TYPE(FLD_N) , PUBLIC :: sn_rnf !: information about the runoff file to be read
48	TYPE(FLD_N) :: sn_cnf !: information about the runoff mouth file to be read
49	TYPE(FLD_N) :: sn_s_rnf !: information about the salinities of runoff file to be read
50	TYPE(FLD_N) :: sn_t_rnf !: information about the temperatures of runoff file to be read
51	TYPE(FLD_N) :: sn_dep_rnf !: information about the depth which river inflow affects
52	LOGICAL , PUBLIC :: ln_rnf_mouth !: specific treatment in mouths vicinity
53	REAL(wp) :: rn_hrnf !: runoffs, depth over which enhanced vertical mixing is used
54	REAL(wp) , PUBLIC :: rn_avt_rnf !: runoffs, value of the additional vertical mixing coef. [m2/s]
55	REAL(wp) , PUBLIC :: rn_rfact !: multiplicative factor for runoff
56
57	LOGICAL , PUBLIC :: l_rnfcpl = .false. ! runoffs recieved from oasis
58	LOGICAL :: ln_rnf_sio !: single processor read
59
60	INTEGER , PUBLIC :: nkrnf = 0 !: nb of levels over which Kz is increased at river mouths
61	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: rnfmsk !: river mouth mask (hori.)
62	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:) :: rnfmsk_z !: river mouth mask (vert.)
63	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: h_rnf !: depth of runoff in m
64	INTEGER, PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: nk_rnf !: depth of runoff in model levels
65	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: rnf_tsc_b, rnf_tsc !: before and now T & S runoff contents [K.m/s & PSU.m/s]
66
67	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_rnf ! structure: river runoff (file information, fields read)
68	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_s_rnf ! structure: river runoff salinity (file information, fields read)
69	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_t_rnf ! structure: river runoff temperature (file information, fields read)
70
71	!! * Substitutions
72	# include "domzgr_substitute.h90"
73	!!----------------------------------------------------------------------
74	!! NEMO/OPA 3.3 , NEMO Consortium (2010)
75	!! $Id$
76	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
77	!!----------------------------------------------------------------------
78	CONTAINS
79
80	INTEGER FUNCTION sbc_rnf_alloc()
81	!!----------------------------------------------------------------------
82	!! * ROUTINE sbc_rnf_alloc *
83	!!----------------------------------------------------------------------
84	ALLOCATE( rnfmsk(jpi,jpj) , rnfmsk_z(jpk) , &
85	& h_rnf (jpi,jpj) , nk_rnf (jpi,jpj) , &
86	& rnf_tsc_b(jpi,jpj,jpts) , rnf_tsc (jpi,jpj,jpts) , STAT=sbc_rnf_alloc )
87	!
88	IF( lk_mpp ) CALL mpp_sum ( sbc_rnf_alloc )
89	IF( sbc_rnf_alloc > 0 ) CALL ctl_warn('sbc_rnf_alloc: allocation of arrays failed')
90	END FUNCTION sbc_rnf_alloc
91
92
93	SUBROUTINE sbc_rnf( kt )
94	!!----------------------------------------------------------------------
95	!! * ROUTINE sbc_rnf *
96	!!
97	!! ** Purpose : Introduce a climatological run off forcing
98	!!
99	!! ** Method : Set each river mouth with a monthly climatology
100	!! provided from different data.
101	!! CAUTION : upward water flux, runoff forced to be < 0
102	!!
103	!! ** Action : runoff updated runoff field at time-step kt
104	!!----------------------------------------------------------------------
105	INTEGER, INTENT(in) :: kt ! ocean time step
106	!
107	INTEGER :: ji, jj ! dummy loop indices
108	INTEGER :: z_err = 0 ! dummy integer for error handling
109	!!----------------------------------------------------------------------
110	REAL(wp), DIMENSION(:,:), POINTER :: ztfrz ! freezing point used for temperature correction
111	!
112	CALL wrk_alloc( jpi,jpj, ztfrz)
113
114	! ! ---------------------------------------- !
115	IF( kt /= nit000 ) THEN ! Swap of forcing fields !
116	! ! ---------------------------------------- !
117	rnf_b (:,: ) = rnf (:,: ) ! Swap the ocean forcing fields except at nit000
118	rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:) ! where before fields are set at the end of the routine
119	!
120	ENDIF
121
122	! !-------------------!
123	! ! Update runoff !
124	! !-------------------!
125	!
126	IF( .NOT. l_rnfcpl ) CALL fld_read ( kt, nn_fsbc, sf_rnf ) ! Read Runoffs data and provide it at kt
127	IF( ln_rnf_tem ) CALL fld_read ( kt, nn_fsbc, sf_t_rnf ) ! idem for runoffs temperature if required
128	IF( ln_rnf_sal ) CALL fld_read ( kt, nn_fsbc, sf_s_rnf ) ! idem for runoffs salinity if required
129	!
130	IF( MOD( kt - 1, nn_fsbc ) == 0 ) THEN
131	!
132	IF( .NOT. l_rnfcpl ) rnf(:,:) = rn_rfact * ( sf_rnf(1)%fnow(:,:,1) ) ! updated runoff value at time step kt
133	!
134	! ! set temperature & salinity content of runoffs
135	IF( ln_rnf_tem ) THEN ! use runoffs temperature data
136	rnf_tsc(:,:,jp_tem) = ( sf_t_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rau0
137	WHERE( sf_t_rnf(1)%fnow(:,:,1) == -999._wp ) ! if missing data value use SST as runoffs temperature
138	rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rau0
139	END WHERE
140	WHERE( sf_t_rnf(1)%fnow(:,:,1) == -222._wp ) ! where fwf comes from melting of ice shelves or iceberg
141	ztfrz(:,:) = -1.9 !tfreez( sss_m(:,:) ) !PM to be discuss (trouble if sensitivity study)
142	rnf_tsc(:,:,jp_tem) = ztfrz(:,:) * rnf(:,:) * r1_rau0 - rnf(:,:) * lfusisf * r1_rau0_rcp
143	END WHERE
144	ELSE ! use SST as runoffs temperature
145	rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rau0
146	ENDIF
147	! ! use runoffs salinity data
148	IF( ln_rnf_sal ) rnf_tsc(:,:,jp_sal) = ( sf_s_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rau0
149	! ! else use S=0 for runoffs (done one for all in the init)
150	CALL iom_put( "runoffs", rnf ) ! output runoffs arrays
151	ENDIF
152	!
153	! ! ---------------------------------------- !
154	IF( kt == nit000 ) THEN ! set the forcing field at nit000 - 1 !
155	! ! ---------------------------------------- !
156	IF( ln_rstart .AND. & !* Restart: read in restart file
157	& iom_varid( numror, 'rnf_b', ldstop = .FALSE. ) > 0 ) THEN
158	IF(lwp) WRITE(numout,*) ' nit000-1 runoff forcing fields red in the restart file'
159	CALL iom_get( numror, jpdom_autoglo, 'rnf_b', rnf_b, lrxios = lxios_read ) ! before runoff
160	CALL iom_get( numror, jpdom_autoglo, 'rnf_hc_b', rnf_tsc_b(:,:,jp_tem), lrxios = lxios_read ) ! before heat content of runoff
161	CALL iom_get( numror, jpdom_autoglo, 'rnf_sc_b', rnf_tsc_b(:,:,jp_sal), lrxios = lxios_read ) ! before salinity content of runoff
162	ELSE !* no restart: set from nit000 values
163	IF(lwp) WRITE(numout,*) ' nit000-1 runoff forcing fields set to nit000'
164	rnf_b (:,: ) = rnf (:,: )
165	rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)
166	ENDIF
167	ENDIF
168	! ! ---------------------------------------- !
169	IF( lrst_oce ) THEN ! Write in the ocean restart file !
170	! ! ---------------------------------------- !
171	IF(lwp) WRITE(numout,*)
172	IF(lwp) WRITE(numout,*) 'sbcrnf : runoff forcing fields written in ocean restart file ', &
173	& 'at it= ', kt,' date= ', ndastp
174	IF(lwp) WRITE(numout,*) '~~~~'
175	IF( lwxios ) CALL iom_swap( wxios_context )
176	CALL iom_rstput( kt, nitrst, numrow, 'rnf_b' , rnf, lxios = lwxios )
177	CALL iom_rstput( kt, nitrst, numrow, 'rnf_hc_b', rnf_tsc(:,:,jp_tem), lxios = lwxios )
178	CALL iom_rstput( kt, nitrst, numrow, 'rnf_sc_b', rnf_tsc(:,:,jp_sal), lxios = lwxios )
179	IF( lwxios ) CALL iom_swap( cxios_context )
180	ENDIF
181	!
182	CALL wrk_dealloc( jpi,jpj, ztfrz)
183	!
184	END SUBROUTINE sbc_rnf
185
186
187	SUBROUTINE sbc_rnf_div( phdivn )
188	!!----------------------------------------------------------------------
189	!! * ROUTINE sbc_rnf *
190	!!
191	!! ** Purpose : update the horizontal divergence with the runoff inflow
192	!!
193	!! ** Method :
194	!! CAUTION : rnf is positive (inflow) decreasing the
195	!! divergence and expressed in m/s
196	!!
197	!! ** Action : phdivn decreased by the runoff inflow
198	!!----------------------------------------------------------------------
199	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: phdivn ! horizontal divergence
200	!!
201	INTEGER :: ji, jj, jk ! dummy loop indices
202	REAL(wp) :: zfact ! local scalar
203	!!----------------------------------------------------------------------
204	!
205	zfact = 0.5_wp
206	!
207	IF( ln_rnf_depth .OR. ln_rnf_depth_ini ) THEN !== runoff distributed over several levels ==!
208	IF( lk_vvl ) THEN ! variable volume case
209	DO jj = 1, jpj ! update the depth over which runoffs are distributed
210	DO ji = 1, jpi
211	h_rnf(ji,jj) = 0._wp
212	DO jk = 1, nk_rnf(ji,jj) ! recalculates h_rnf to be the depth in metres
213	h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk) ! to the bottom of the relevant grid box
214	END DO
215	! ! apply the runoff input flow
216	DO jk = 1, nk_rnf(ji,jj)
217	phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rau0 / h_rnf(ji,jj)
218	END DO
219	END DO
220	END DO
221	ELSE ! constant volume case : just apply the runoff input flow
222	DO jj = 1, jpj
223	DO ji = 1, jpi
224	DO jk = 1, nk_rnf(ji,jj)
225	phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rau0 / h_rnf(ji,jj)
226	END DO
227	END DO
228	END DO
229	ENDIF
230	ELSE !== runoff put only at the surface ==!
231	IF( lk_vvl ) THEN ! variable volume case
232	h_rnf(:,:) = fse3t(:,:,1) ! recalculate h_rnf to be depth of top box
233	ENDIF
234	phdivn(:,:,1) = phdivn(:,:,1) - ( rnf(:,:) + rnf_b(:,:) ) * zfact * r1_rau0 / fse3t(:,:,1)
235	ENDIF
236	!
237	END SUBROUTINE sbc_rnf_div
238
239
240	SUBROUTINE sbc_rnf_init
241	!!----------------------------------------------------------------------
242	!! * ROUTINE sbc_rnf_init *
243	!!
244	!! ** Purpose : Initialisation of the runoffs if (ln_rnf=T)
245	!!
246	!! ** Method : - read the runoff namsbc_rnf namelist
247	!!
248	!! ** Action : - read parameters
249	!!----------------------------------------------------------------------
250	CHARACTER(len=32) :: rn_dep_file ! runoff file name
251	INTEGER :: ji, jj, jk, jm ! dummy loop indices
252	INTEGER :: ierror, inum ! temporary integer
253	INTEGER :: ios ! Local integer output status for namelist read
254	INTEGER :: nbrec ! temporary integer
255	REAL(wp) :: zacoef
256	REAL(wp), DIMENSION(12) :: zrec ! times records
257	REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: zrnfcl
258	REAL(wp), DIMENSION(:,: ), ALLOCATABLE :: zrnf
259	!
260	NAMELIST/namsbc_rnf/ cn_dir , ln_rnf_depth, ln_rnf_tem, ln_rnf_sal, &
261	& sn_rnf, sn_cnf , sn_s_rnf , sn_t_rnf , sn_dep_rnf, &
262	& ln_rnf_mouth , rn_hrnf , rn_avt_rnf, rn_rfact, &
263	& ln_rnf_depth_ini , rn_dep_max , rn_rnf_max, nn_rnf_depth_file, &
264	& ln_rnf_sio
265	!!----------------------------------------------------------------------
266	!
267	! !== allocate runoff arrays
268	IF( sbc_rnf_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'sbc_rnf_alloc : unable to allocate arrays' )
269	!
270	IF( .NOT. ln_rnf ) THEN ! no specific treatment in vicinity of river mouths
271	ln_rnf_mouth = .FALSE. ! default definition needed for example by sbc_ssr or by tra_adv_muscl
272	nkrnf = 0
273	rnf (:,:) = 0.0_wp
274	rnf_b (:,:) = 0.0_wp
275	rnfmsk (:,:) = 0.0_wp
276	rnfmsk_z(:) = 0.0_wp
277	RETURN
278	ENDIF
279	!
280	! ! ============
281	! ! Namelist
282	! ! ============
283	!
284	ln_rnf_sio = .FALSE.
285	REWIND( numnam_ref ) ! Namelist namsbc_rnf in reference namelist : Runoffs
286	READ ( numnam_ref, namsbc_rnf, IOSTAT = ios, ERR = 901)
287	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_rnf in reference namelist', lwp )
288
289	REWIND( numnam_cfg ) ! Namelist namsbc_rnf in configuration namelist : Runoffs
290	READ ( numnam_cfg, namsbc_rnf, IOSTAT = ios, ERR = 902 )
291	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_rnf in configuration namelist', lwp )
292	IF(lwm) WRITE ( numond, namsbc_rnf )
293	!
294	! ! Control print
295	IF(lwp) THEN
296	WRITE(numout,*)
297	WRITE(numout,*) 'sbc_rnf : runoff '
298	WRITE(numout,*) '~~~~~~~ '
299	WRITE(numout,*) ' Namelist namsbc_rnf'
300	WRITE(numout,*) ' specific river mouths treatment ln_rnf_mouth = ', ln_rnf_mouth
301	WRITE(numout,*) ' river mouth additional Kz rn_avt_rnf = ', rn_avt_rnf
302	WRITE(numout,*) ' depth of river mouth additional mixing rn_hrnf = ', rn_hrnf
303	WRITE(numout,*) ' multiplicative factor for runoff rn_rfact = ', rn_rfact
304	ENDIF
305	! ! ==================
306	! ! Type of runoff
307	! ! ==================
308	!
309	lspr = ln_rnf_sio
310	IF( .NOT. l_rnfcpl ) THEN
311	ALLOCATE( sf_rnf(1), STAT=ierror ) ! Create sf_rnf structure (runoff inflow)
312	IF(lwp) WRITE(numout,*)
313	IF(lwp) WRITE(numout,*) ' runoffs inflow read in a file'
314	IF( ierror > 0 ) THEN
315	CALL ctl_stop( 'sbc_rnf: unable to allocate sf_rnf structure' ) ; RETURN
316	ENDIF
317	ALLOCATE( sf_rnf(1)%fnow(jpi,jpj,1) )
318	IF( sn_rnf%ln_tint ) ALLOCATE( sf_rnf(1)%fdta(jpi,jpj,1,2) )
319	CALL fld_fill( sf_rnf, (/ sn_rnf /), cn_dir, 'sbc_rnf_init', 'read runoffs data', 'namsbc_rnf' )
320	ENDIF
321	!
322	IF( ln_rnf_tem ) THEN ! Create (if required) sf_t_rnf structure
323	IF(lwp) WRITE(numout,*)
324	IF(lwp) WRITE(numout,*) ' runoffs temperatures read in a file'
325	ALLOCATE( sf_t_rnf(1), STAT=ierror )
326	IF( ierror > 0 ) THEN
327	CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_t_rnf structure' ) ; RETURN
328	ENDIF
329	ALLOCATE( sf_t_rnf(1)%fnow(jpi,jpj,1) )
330	IF( sn_t_rnf%ln_tint ) ALLOCATE( sf_t_rnf(1)%fdta(jpi,jpj,1,2) )
331	CALL fld_fill (sf_t_rnf, (/ sn_t_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff temperature data', 'namsbc_rnf' )
332	ENDIF
333	!
334	IF( ln_rnf_sal ) THEN ! Create (if required) sf_s_rnf and sf_t_rnf structures
335	IF(lwp) WRITE(numout,*)
336	IF(lwp) WRITE(numout,*) ' runoffs salinities read in a file'
337	ALLOCATE( sf_s_rnf(1), STAT=ierror )
338	IF( ierror > 0 ) THEN
339	CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_s_rnf structure' ) ; RETURN
340	ENDIF
341	ALLOCATE( sf_s_rnf(1)%fnow(jpi,jpj,1) )
342	IF( sn_s_rnf%ln_tint ) ALLOCATE( sf_s_rnf(1)%fdta(jpi,jpj,1,2) )
343	CALL fld_fill (sf_s_rnf, (/ sn_s_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff salinity data', 'namsbc_rnf' )
344	ENDIF
345	!
346	IF( ln_rnf_depth ) THEN ! depth of runoffs set from a file
347	IF(lwp) WRITE(numout,*)
348	IF(lwp) WRITE(numout,*) ' runoffs depth read in a file'
349	rn_dep_file = TRIM( cn_dir )//TRIM( sn_dep_rnf%clname )
350	IF( .NOT. sn_dep_rnf%ln_clim ) THEN ; WRITE(rn_dep_file, '(a,"_y",i4)' ) TRIM( rn_dep_file ), nyear ! add year
351	IF( sn_dep_rnf%cltype == 'monthly' ) WRITE(rn_dep_file, '(a,"m",i2)' ) TRIM( rn_dep_file ), nmonth ! add month
352	ENDIF
353	CALL iom_open ( rn_dep_file, inum ) ! open file
354	CALL iom_get ( inum, jpdom_data, sn_dep_rnf%clvar, h_rnf ) ! read the river mouth array
355	CALL iom_close( inum ) ! close file
356	!
357	nk_rnf(:,:) = 0 ! set the number of level over which river runoffs are applied
358	DO jj = 1, jpj
359	DO ji = 1, jpi
360	IF( h_rnf(ji,jj) > 0._wp ) THEN
361	jk = 2
362	DO WHILE ( jk /= mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ; jk = jk + 1
363	END DO
364	nk_rnf(ji,jj) = jk
365	ELSEIF( h_rnf(ji,jj) == -1._wp ) THEN ; nk_rnf(ji,jj) = 1
366	ELSEIF( h_rnf(ji,jj) == -999._wp ) THEN ; nk_rnf(ji,jj) = mbkt(ji,jj)
367	ELSE
368	CALL ctl_stop( 'sbc_rnf_init: runoff depth not positive, and not -999 or -1, rnf value in file fort.999' )
369	WRITE(999,*) 'ji, jj, h_rnf(ji,jj) :', ji, jj, h_rnf(ji,jj)
370	ENDIF
371	END DO
372	END DO
373	DO jj = 1, jpj ! set the associated depth
374	DO ji = 1, jpi
375	h_rnf(ji,jj) = 0._wp
376	DO jk = 1, nk_rnf(ji,jj)
377	h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk)
378	END DO
379	END DO
380	END DO
381	!
382	ELSE IF( ln_rnf_depth_ini ) THEN ! runoffs applied at the surface
383	!
384	IF(lwp) WRITE(numout,*)
385	IF(lwp) WRITE(numout,*) ' depth of runoff computed once from max value of runoff'
386	IF(lwp) WRITE(numout,*) ' max value of the runoff climatologie (over global domain) rn_rnf_max = ', rn_rnf_max
387	IF(lwp) WRITE(numout,*) ' depth over which runoffs is spread rn_dep_max = ', rn_dep_max
388	IF(lwp) WRITE(numout,*) ' create (=1) a runoff depth file or not (=0) nn_rnf_depth_file = ', nn_rnf_depth_file
389
390	CALL iom_open( TRIM( sn_rnf%clname ), inum ) ! open runoff file
391	CALL iom_gettime( inum, zrec, kntime=nbrec)
392	ALLOCATE( zrnfcl(jpi,jpj,nbrec) ) ; ALLOCATE( zrnf(jpi,jpj) )
393	DO jm = 1, nbrec
394	CALL iom_get( inum, jpdom_data, TRIM( sn_rnf%clvar ), zrnfcl(:,:,jm), jm )
395	END DO
396	CALL iom_close( inum )
397	zrnf(:,:) = MAXVAL( zrnfcl(:,:,:), DIM=3 ) ! maximum value in time
398	DEALLOCATE( zrnfcl )
399	!
400	h_rnf(:,:) = 1.
401	!
402	zacoef = rn_dep_max / rn_rnf_max ! coef of linear relation between runoff and its depth (150m for max of runoff)
403	!
404	WHERE( zrnf(:,:) > 0._wp ) h_rnf(:,:) = zacoef * zrnf(:,:) ! compute depth for all runoffs
405	!
406	DO jj = 1, jpj ! take in account min depth of ocean rn_hmin
407	DO ji = 1, jpi
408	IF( zrnf(ji,jj) > 0._wp ) THEN
409	jk = mbkt(ji,jj)
410	h_rnf(ji,jj) = MIN( h_rnf(ji,jj), gdept_0(ji,jj,jk ) )
411	ENDIF
412	END DO
413	END DO
414	!
415	nk_rnf(:,:) = 0 ! number of levels on which runoffs are distributed
416	DO jj = 1, jpj
417	DO ji = 1, jpi
418	IF( zrnf(ji,jj) > 0._wp ) THEN
419	jk = 2
420	DO WHILE ( jk /= mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ; jk = jk + 1
421	END DO
422	nk_rnf(ji,jj) = jk
423	ELSE
424	nk_rnf(ji,jj) = 1
425	ENDIF
426	END DO
427	END DO
428	!
429	DEALLOCATE( zrnf )
430	!
431	DO jj = 1, jpj ! set the associated depth
432	DO ji = 1, jpi
433	h_rnf(ji,jj) = 0._wp
434	DO jk = 1, nk_rnf(ji,jj)
435	h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk)
436	END DO
437	END DO
438	END DO
439	!
440	IF( nn_rnf_depth_file == 1 ) THEN ! save output nb levels for runoff
441	IF(lwp) WRITE(numout,*) ' create runoff depht file'
442	CALL iom_open ( TRIM( sn_dep_rnf%clname ), inum, ldwrt = .TRUE., kiolib = jprstlib )
443	CALL iom_rstput( 0, 0, inum, 'rodepth', h_rnf )
444	CALL iom_close ( inum )
445	ENDIF
446	ELSE ! runoffs applied at the surface
447	nk_rnf(:,:) = 1
448	h_rnf (:,:) = fse3t(:,:,1)
449	ENDIF
450	!
451	rnf(:,:) = 0._wp ! runoff initialisation
452	rnf_tsc(:,:,:) = 0._wp ! runoffs temperature & salinty contents initilisation
453	!
454	! ! ========================
455	! ! River mouth vicinity
456	! ! ========================
457	!
458	IF( ln_rnf_mouth ) THEN ! Specific treatment in vicinity of river mouths :
459	! ! - Increase Kz in surface layers ( rn_hrnf > 0 )
460	! ! - set to zero SSS damping (ln_ssr=T)
461	! ! - mixed upstream-centered (ln_traadv_cen2=T)
462	!
463	IF ( ln_rnf_depth ) CALL ctl_warn( 'sbc_rnf_init: increased mixing turned on but effects may already', &
464	& 'be spread through depth by ln_rnf_depth' )
465	!
466	nkrnf = 0 ! Number of level over which Kz increase
467	IF( rn_hrnf > 0._wp ) THEN
468	nkrnf = 2
469	DO WHILE( nkrnf /= jpkm1 .AND. gdepw_1d(nkrnf+1) < rn_hrnf ) ; nkrnf = nkrnf + 1
470	END DO
471	IF( ln_sco ) CALL ctl_warn( 'sbc_rnf: number of levels over which Kz is increased is computed for zco...' )
472	ENDIF
473	IF(lwp) WRITE(numout,*)
474	IF(lwp) WRITE(numout,*) ' Specific treatment used in vicinity of river mouths :'
475	IF(lwp) WRITE(numout,*) ' - Increase Kz in surface layers (if rn_hrnf > 0 )'
476	IF(lwp) WRITE(numout,*) ' by ', rn_avt_rnf,' m2/s over ', nkrnf, ' w-levels'
477	IF(lwp) WRITE(numout,*) ' - set to zero SSS damping (if ln_ssr=T)'
478	IF(lwp) WRITE(numout,*) ' - mixed upstream-centered (if ln_traadv_cen2=T)'
479	!
480	CALL rnf_mouth ! set river mouth mask
481	!
482	ELSE ! No treatment at river mouths
483	IF(lwp) WRITE(numout,*)
484	IF(lwp) WRITE(numout,*) ' No specific treatment at river mouths'
485	rnfmsk (:,:) = 0._wp
486	rnfmsk_z(:) = 0._wp
487	nkrnf = 0
488	ENDIF
489	!
490	lspr = .false.
491	END SUBROUTINE sbc_rnf_init
492
493
494	SUBROUTINE rnf_mouth
495	!!----------------------------------------------------------------------
496	!! * ROUTINE rnf_mouth *
497	!!
498	!! ** Purpose : define the river mouths mask
499	!!
500	!! ** Method : read the river mouth mask (=0/1) in the river runoff
501	!! climatological file. Defined a given vertical structure.
502	!! CAUTION, the vertical structure is hard coded on the
503	!! first 5 levels.
504	!! This fields can be used to:
505	!! - set an upstream advection scheme
506	!! (ln_rnf_mouth=T and ln_traadv_cen2=T)
507	!! - increase vertical on the top nn_krnf vertical levels
508	!! at river runoff input grid point (nn_krnf>=2, see step.F90)
509	!! - set to zero SSS restoring flux at river mouth grid points
510	!!
511	!! ** Action : rnfmsk set to 1 at river runoff input, 0 elsewhere
512	!! rnfmsk_z vertical structure
513	!!----------------------------------------------------------------------
514	INTEGER :: inum ! temporary integers
515	CHARACTER(len=140) :: cl_rnfile ! runoff file name
516	!!----------------------------------------------------------------------
517	!
518	IF(lwp) WRITE(numout,*)
519	IF(lwp) WRITE(numout,*) 'rnf_mouth : river mouth mask'
520	IF(lwp) WRITE(numout,*) '~~~~~~~~~ '
521	!
522	cl_rnfile = TRIM( cn_dir )//TRIM( sn_cnf%clname )
523	IF( .NOT. sn_cnf%ln_clim ) THEN ; WRITE(cl_rnfile, '(a,"_y",i4)' ) TRIM( cl_rnfile ), nyear ! add year
524	IF( sn_cnf%cltype == 'monthly' ) WRITE(cl_rnfile, '(a,"m",i2)' ) TRIM( cl_rnfile ), nmonth ! add month
525	ENDIF
526	!
527	! horizontal mask (read in NetCDF file)
528	CALL iom_open ( cl_rnfile, inum ) ! open file
529	CALL iom_get ( inum, jpdom_data, sn_cnf%clvar, rnfmsk ) ! read the river mouth array
530	CALL iom_close( inum ) ! close file
531	!
532	IF( nn_closea == 1 ) CALL clo_rnf( rnfmsk ) ! closed sea inflow set as ruver mouth
533	!
534	rnfmsk_z(:) = 0._wp ! vertical structure
535	rnfmsk_z(1) = 1.0
536	rnfmsk_z(2) = 1.0 ! **********
537	rnfmsk_z(3) = 0.5 ! HARD CODED on the 5 first levels
538	rnfmsk_z(4) = 0.25 ! **********
539	rnfmsk_z(5) = 0.125
540	!
541	END SUBROUTINE rnf_mouth
542
543	!!======================================================================
544	END MODULE sbcrnf

Note: See TracBrowser for help on using the repository browser.

New URL for NEMO forge! http://forge.nemo-ocean.eu

Context Navigation

source: branches/UKMO/test_moci_test_suite/NEMOGCM/NEMO/OPA_SRC/SBC/sbcrnf.F90 @ 8243

Download in other formats: