New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
diaharm.F90 in branches/UKMO/test_moci_test_suite_namelist_read/NEMOGCM/NEMO/OPA_SRC/DIA – NEMO

source: branches/UKMO/test_moci_test_suite_namelist_read/NEMOGCM/NEMO/OPA_SRC/DIA/diaharm.F90 @ 9366

Last change on this file since 9366 was 9366, checked in by andmirek, 6 years ago

#2050 first version. Compiled OK in moci test suite

File size: 20.8 KB
Line 
1MODULE diaharm 
2   !!======================================================================
3   !!                       ***  MODULE  diaharm  ***
4   !! Harmonic analysis of tidal constituents
5   !!======================================================================
6   !! History :  3.1  !  2007  (O. Le Galloudec, J. Chanut)  Original code
7   !!----------------------------------------------------------------------
8#if defined key_diaharm && defined key_tide
9   !!----------------------------------------------------------------------
10   !!   'key_diaharm'
11   !!   'key_tide'
12   !!----------------------------------------------------------------------
13   USE oce             ! ocean dynamics and tracers variables
14   USE dom_oce         ! ocean space and time domain
15   USE phycst
16   USE dynspg_oce
17   USE dynspg_ts
18   USE daymod
19   USE tide_mod
20   !
21   USE in_out_manager  ! I/O units
22   USE iom             ! I/0 library
23   USE ioipsl          ! NetCDF IPSL library
24   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
25   USE diadimg         ! To write dimg
26   USE timing          ! preformance summary
27   USE wrk_nemo        ! working arrays
28
29   IMPLICIT NONE
30   PRIVATE
31   PRIVATE harm_namelist
32
33   LOGICAL, PUBLIC, PARAMETER :: lk_diaharm  = .TRUE.
34   
35   INTEGER, PARAMETER :: jpincomax    = 2.*jpmax_harmo
36   INTEGER, PARAMETER :: jpdimsparse  = jpincomax*300*24
37
38   !                         !!** namelist variables **
39   INTEGER ::   nit000_han    ! First time step used for harmonic analysis
40   INTEGER ::   nitend_han    ! Last time step used for harmonic analysis
41   INTEGER ::   nstep_han     ! Time step frequency for harmonic analysis
42   INTEGER ::   nb_ana        ! Number of harmonics to analyse
43
44   INTEGER , ALLOCATABLE, DIMENSION(:)       ::   name
45   REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:) ::   ana_temp
46   REAL(wp), ALLOCATABLE, DIMENSION(:)       ::   ana_freq, ut   , vt   , ft
47   REAL(wp), ALLOCATABLE, DIMENSION(:,:,:)   ::   out_eta , out_u, out_v
48
49   INTEGER ::   ninco, nsparse
50   INTEGER ,       DIMENSION(jpdimsparse)         ::   njsparse, nisparse
51   INTEGER , SAVE, DIMENSION(jpincomax)           ::   ipos1
52   REAL(wp),       DIMENSION(jpdimsparse)         ::   valuesparse
53   REAL(wp),       DIMENSION(jpincomax)           ::   ztmp4 , ztmp7
54   REAL(wp), SAVE, DIMENSION(jpincomax,jpincomax) ::   ztmp3 , zpilier
55   REAL(wp), SAVE, DIMENSION(jpincomax)           ::   zpivot
56
57   CHARACTER (LEN=4), DIMENSION(jpmax_harmo) ::   tname   ! Names of tidal constituents ('M2', 'K1',...)
58
59   PUBLIC   dia_harm   ! routine called by step.F90
60
61   !!----------------------------------------------------------------------
62   !! NEMO/OPA 3.5 , NEMO Consortium (2013)
63   !! $Id$
64   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
65   !!----------------------------------------------------------------------
66CONTAINS
67
68   SUBROUTINE dia_harm_init 
69      !!----------------------------------------------------------------------
70      !!                 ***  ROUTINE dia_harm_init  ***
71      !!         
72      !! ** Purpose :   Initialization of tidal harmonic analysis
73      !!
74      !! ** Method  :   Initialize frequency array and  nodal factor for nit000_han
75      !!
76      !!--------------------------------------------------------------------
77      INTEGER :: jh, nhan, jk, ji
78      INTEGER ::   ios                 ! Local integer output status for namelist read
79
80      NAMELIST/nam_diaharm/ nit000_han, nitend_han, nstep_han, tname
81      !!----------------------------------------------------------------------
82
83      IF(lwp) THEN
84         WRITE(numout,*)
85         WRITE(numout,*) 'dia_harm_init: Tidal harmonic analysis initialization'
86         WRITE(numout,*) '~~~~~~~ '
87      ENDIF
88      !
89      CALL tide_init_Wave
90      !
91      IF(lwm) THEN
92         REWIND( numnam_ref )              ! Namelist nam_diaharm in reference namelist : Tidal harmonic analysis
93         READ  ( numnam_ref, nam_diaharm, IOSTAT = ios, ERR = 901)
94901      IF( ios /= 0 ) CALL ctl_nam ( ios , 'nam_diaharm in reference namelist', lwm )
95         REWIND( numnam_cfg )              ! Namelist nam_diaharm in configuration namelist : Tidal harmonic analysis
96         READ  ( numnam_cfg, nam_diaharm, IOSTAT = ios, ERR = 902 )
97902      IF( ios /= 0 ) CALL ctl_nam ( ios , 'nam_diaharm in configuration namelist', lwm )
98      ENDIF
99
100      IF(lwm) WRITE ( numond, nam_diaharm )
101      !
102      CALL harm_namelist()
103
104      IF(lwp) THEN
105         WRITE(numout,*) 'First time step used for analysis:  nit000_han= ', nit000_han
106         WRITE(numout,*) 'Last  time step used for analysis:  nitend_han= ', nitend_han
107         WRITE(numout,*) 'Time step frequency for harmonic analysis:  nstep_han= ', nstep_han
108      ENDIF
109
110      ! Basic checks on harmonic analysis time window:
111      ! ----------------------------------------------
112      IF( nit000 > nit000_han )   CALL ctl_stop( 'dia_harm_init : nit000_han must be greater than nit000',   &
113         &                                       ' restart capability not implemented' )
114      IF( nitend < nitend_han )   CALL ctl_stop( 'dia_harm_init : nitend_han must be lower than nitend',   &
115         &                                       'restart capability not implemented' )
116
117      IF( MOD( nitend_han-nit000_han+1 , nstep_han ) /= 0 )   &
118         &                        CALL ctl_stop( 'dia_harm_init : analysis time span must be a multiple of nstep_han' )
119
120      nb_ana = 0
121      DO jk=1,jpmax_harmo
122         DO ji=1,jpmax_harmo
123            IF(TRIM(tname(jk)) == Wave(ji)%cname_tide) THEN
124               nb_ana=nb_ana+1
125            ENDIF
126         END DO
127      END DO
128      !
129      IF(lwp) THEN
130         WRITE(numout,*) '        Namelist nam_diaharm'
131         WRITE(numout,*) '        nb_ana    = ', nb_ana
132         CALL flush(numout)
133      ENDIF
134      !
135      IF (nb_ana > jpmax_harmo) THEN
136        IF(lwp) WRITE(numout,*) ' E R R O R dia_harm_init : nb_ana must be lower than jpmax_harmo, stop'
137        IF(lwp) WRITE(numout,*) ' jpmax_harmo= ', jpmax_harmo
138        nstop = nstop + 1
139      ENDIF
140
141      ALLOCATE(name    (nb_ana))
142      DO jk=1,nb_ana
143       DO ji=1,jpmax_harmo
144          IF (TRIM(tname(jk)) .eq. Wave(ji)%cname_tide) THEN
145             name(jk) = ji
146             EXIT
147          END IF
148       END DO
149      END DO
150
151      ! Initialize frequency array:
152      ! ---------------------------
153      ALLOCATE( ana_freq(nb_ana), ut(nb_ana), vt(nb_ana), ft(nb_ana) )
154
155      CALL tide_harmo( ana_freq, vt, ut, ft, name, nb_ana )
156
157      IF(lwp) WRITE(numout,*) 'Analysed frequency  : ',nb_ana ,'Frequency '
158
159      DO jh = 1, nb_ana
160        IF(lwp) WRITE(numout,*) '                    : ',tname(jh),' ',ana_freq(jh)
161      END DO
162
163      ! Initialize temporary arrays:
164      ! ----------------------------
165      ALLOCATE( ana_temp(jpi,jpj,2*nb_ana,3) )
166      ana_temp(:,:,:,:) = 0._wp
167
168   END SUBROUTINE dia_harm_init
169
170
171   SUBROUTINE dia_harm ( kt )
172      !!----------------------------------------------------------------------
173      !!                 ***  ROUTINE dia_harm  ***
174      !!         
175      !! ** Purpose :   Tidal harmonic analysis main routine
176      !!
177      !! ** Action  :   Sums ssh/u/v over time analysis [nit000_han,nitend_han]
178      !!
179      !!--------------------------------------------------------------------
180      INTEGER, INTENT( IN ) :: kt
181      !
182      INTEGER  :: ji, jj, jh, jc, nhc
183      REAL(wp) :: ztime, ztemp
184      !!--------------------------------------------------------------------
185      IF( nn_timing == 1 )   CALL timing_start('dia_harm')
186
187      IF( kt == nit000 ) CALL dia_harm_init
188
189      IF( kt >= nit000_han .AND. kt <= nitend_han .AND. MOD(kt,nstep_han) == 0 ) THEN
190
191         ztime = (kt-nit000+1) * rdt 
192       
193         nhc = 0
194         DO jh = 1, nb_ana
195            DO jc = 1, 2
196               nhc = nhc+1
197               ztemp =(     MOD(jc,2) * ft(jh) *COS(ana_freq(jh)*ztime + vt(jh) + ut(jh))  &
198                  &    +(1.-MOD(jc,2))* ft(jh) *SIN(ana_freq(jh)*ztime + vt(jh) + ut(jh)))
199
200               DO jj = 1,jpj
201                  DO ji = 1,jpi
202                     ! Elevation
203                     ana_temp(ji,jj,nhc,1) = ana_temp(ji,jj,nhc,1) + ztemp*sshn(ji,jj)*tmask_i(ji,jj)       
204                     ana_temp(ji,jj,nhc,2) = ana_temp(ji,jj,nhc,2) + ztemp*un_b(ji,jj)*umask_i(ji,jj)
205                     ana_temp(ji,jj,nhc,3) = ana_temp(ji,jj,nhc,3) + ztemp*vn_b(ji,jj)*vmask_i(ji,jj)
206                  END DO
207               END DO
208               !
209            END DO
210         END DO
211         !       
212      END IF
213
214      IF ( kt == nitend_han )   CALL dia_harm_end
215
216      IF( nn_timing == 1 )   CALL timing_stop('dia_harm')
217 
218   END SUBROUTINE dia_harm
219
220
221   SUBROUTINE dia_harm_end
222      !!----------------------------------------------------------------------
223      !!                 ***  ROUTINE diaharm_end  ***
224      !!         
225      !! ** Purpose :  Compute the Real and Imaginary part of tidal constituents
226      !!
227      !! ** Action  :  Decompose the signal on the harmonic constituents
228      !!
229      !!--------------------------------------------------------------------
230      INTEGER :: ji, jj, jh, jc, jn, nhan, jl
231      INTEGER :: ksp, kun, keq
232      REAL(wp) :: ztime, ztime_ini, ztime_end
233      REAL(wp) :: X1,X2
234      REAL(wp), POINTER, DIMENSION(:,:,:,:) :: ana_amp
235      !!--------------------------------------------------------------------
236      CALL wrk_alloc( jpi , jpj , jpmax_harmo , 2 , ana_amp )
237
238      IF(lwp) WRITE(numout,*)
239      IF(lwp) WRITE(numout,*) 'anharmo_end: kt=nitend_han: Perform harmonic analysis'
240      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~'
241
242      ztime_ini = nit000_han*rdt                 ! Initial time in seconds at the beginning of analysis
243      ztime_end = nitend_han*rdt                 ! Final time in seconds at the end of analysis
244      nhan = (nitend_han-nit000_han+1)/nstep_han ! Number of dumps used for analysis
245
246      ninco = 2*nb_ana
247
248      ksp = 0
249      keq = 0       
250      DO jn = 1, nhan
251         ztime=( (nhan-jn)*ztime_ini + (jn-1)*ztime_end )/FLOAT(nhan-1)
252         keq = keq + 1
253         kun = 0
254         DO jh = 1, nb_ana
255            DO jc = 1, 2
256               kun = kun + 1
257               ksp = ksp + 1
258               nisparse(ksp) = keq
259               njsparse(ksp) = kun
260               valuesparse(ksp) = (   MOD(jc,2) * ft(jh) * COS(ana_freq(jh)*ztime + vt(jh) + ut(jh))   &
261                  &             + (1.-MOD(jc,2))* ft(jh) * SIN(ana_freq(jh)*ztime + vt(jh) + ut(jh)) )
262            END DO
263         END DO
264      END DO
265
266      nsparse = ksp
267
268      ! Elevation:
269      DO jj = 1, jpj
270         DO ji = 1, jpi
271            ! Fill input array
272            kun = 0
273            DO jh = 1, nb_ana
274               DO jc = 1, 2
275                  kun = kun + 1
276                  ztmp4(kun)=ana_temp(ji,jj,kun,1)
277               END DO
278            END DO
279
280            CALL SUR_DETERMINE(jj)
281
282            ! Fill output array
283            DO jh = 1, nb_ana
284               ana_amp(ji,jj,jh,1)=ztmp7((jh-1)*2+1)
285               ana_amp(ji,jj,jh,2)=ztmp7((jh-1)*2+2)
286            END DO
287         END DO
288      END DO
289
290      ALLOCATE( out_eta(jpi,jpj,2*nb_ana),   & 
291         &      out_u  (jpi,jpj,2*nb_ana),   &
292         &      out_v  (jpi,jpj,2*nb_ana)  )
293
294      DO jj = 1, jpj
295         DO ji = 1, jpi
296            DO jh = 1, nb_ana 
297               X1 = ana_amp(ji,jj,jh,1)
298               X2 =-ana_amp(ji,jj,jh,2)
299               out_eta(ji,jj,jh       ) = X1 * tmask_i(ji,jj)
300               out_eta(ji,jj,jh+nb_ana) = X2 * tmask_i(ji,jj)
301            END DO
302         END DO
303      END DO
304
305      ! ubar:
306      DO jj = 1, jpj
307         DO ji = 1, jpi
308            ! Fill input array
309            kun=0
310            DO jh = 1,nb_ana
311               DO jc = 1,2
312                  kun = kun + 1
313                  ztmp4(kun)=ana_temp(ji,jj,kun,2)
314               END DO
315            END DO
316
317            CALL SUR_DETERMINE(jj+1)
318
319            ! Fill output array
320            DO jh = 1, nb_ana
321               ana_amp(ji,jj,jh,1) = ztmp7((jh-1)*2+1)
322               ana_amp(ji,jj,jh,2) = ztmp7((jh-1)*2+2)
323            END DO
324
325         END DO
326      END DO
327
328      DO jj = 1, jpj
329         DO ji = 1, jpi
330            DO jh = 1, nb_ana 
331               X1= ana_amp(ji,jj,jh,1)
332               X2=-ana_amp(ji,jj,jh,2)
333               out_u(ji,jj,       jh) = X1 * umask_i(ji,jj)
334               out_u(ji,jj,nb_ana+jh) = X2 * umask_i(ji,jj)
335            ENDDO
336         ENDDO
337      ENDDO
338
339      ! vbar:
340      DO jj = 1, jpj
341         DO ji = 1, jpi
342            ! Fill input array
343            kun=0
344            DO jh = 1,nb_ana
345               DO jc = 1,2
346                  kun = kun + 1
347                  ztmp4(kun)=ana_temp(ji,jj,kun,3)
348               END DO
349            END DO
350
351            CALL SUR_DETERMINE(jj+1)
352
353            ! Fill output array
354            DO jh = 1, nb_ana
355               ana_amp(ji,jj,jh,1)=ztmp7((jh-1)*2+1)
356               ana_amp(ji,jj,jh,2)=ztmp7((jh-1)*2+2)
357            END DO
358
359         END DO
360      END DO
361
362      DO jj = 1, jpj
363         DO ji = 1, jpi
364            DO jh = 1, nb_ana 
365               X1=ana_amp(ji,jj,jh,1)
366               X2=-ana_amp(ji,jj,jh,2)
367               out_v(ji,jj,       jh)=X1 * vmask_i(ji,jj)
368               out_v(ji,jj,nb_ana+jh)=X2 * vmask_i(ji,jj)
369            END DO
370         END DO
371      END DO
372
373      CALL dia_wri_harm ! Write results in files
374      CALL wrk_dealloc( jpi , jpj , jpmax_harmo , 2 , ana_amp )
375      !
376   END SUBROUTINE dia_harm_end
377
378
379   SUBROUTINE dia_wri_harm
380      !!--------------------------------------------------------------------
381      !!                 ***  ROUTINE dia_wri_harm  ***
382      !!         
383      !! ** Purpose : Write tidal harmonic analysis results in a netcdf file
384      !!--------------------------------------------------------------------
385      CHARACTER(LEN=lc) :: cltext
386      CHARACTER(LEN=lc) ::   &
387         cdfile_name_T   ,   & ! name of the file created (T-points)
388         cdfile_name_U   ,   & ! name of the file created (U-points)
389         cdfile_name_V         ! name of the file created (V-points)
390      INTEGER  ::   jh
391      !!----------------------------------------------------------------------
392
393#if defined key_dimgout
394      cdfile_name_T = TRIM(cexper)//'_Tidal_harmonics_gridT.dimgproc'
395      cdfile_name_U = TRIM(cexper)//'_Tidal_harmonics_gridU.dimgproc'
396      cdfile_name_V = TRIM(cexper)//'_Tidal_harmonics_gridV.dimgproc'
397#endif
398
399      IF(lwp) WRITE(numout,*) '  '
400      IF(lwp) WRITE(numout,*) 'dia_wri_harm : Write harmonic analysis results'
401#if defined key_dimgout
402      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~  Output files: ', TRIM(cdfile_name_T)
403      IF(lwp) WRITE(numout,*) '                             ', TRIM(cdfile_name_U)
404      IF(lwp) WRITE(numout,*) '                             ', TRIM(cdfile_name_V)
405#endif
406      IF(lwp) WRITE(numout,*) '  '
407
408      ! A) Elevation
409      !/////////////
410      !
411#if defined key_dimgout
412      cltext='Elevation amplitude and phase'
413      CALL dia_wri_dimg(TRIM(cdfile_name_T), TRIM(cltext), out_eta, 2*nb_ana, '2')
414#else
415      DO jh = 1, nb_ana
416      CALL iom_put( TRIM(tname(jh))//'x', out_eta(:,:,jh) )
417      CALL iom_put( TRIM(tname(jh))//'y', out_eta(:,:,nb_ana+jh) )
418      END DO
419#endif
420
421      ! B) ubar
422      !/////////
423      !
424#if defined key_dimgout
425      cltext='ubar amplitude and phase'
426      CALL dia_wri_dimg(TRIM(cdfile_name_U), TRIM(cltext), out_u, 2*nb_ana, '2')
427#else
428      DO jh = 1, nb_ana
429      CALL iom_put( TRIM(tname(jh))//'x_u', out_u(:,:,jh) )
430      CALL iom_put( TRIM(tname(jh))//'y_u', out_u(:,:,nb_ana+jh) )
431      END DO
432#endif
433
434      ! C) vbar
435      !/////////
436      !
437#if defined key_dimgout
438      cltext='vbar amplitude and phase'
439      CALL dia_wri_dimg(TRIM(cdfile_name_V), TRIM(cltext), out_v, 2*nb_ana, '2')
440#else
441      DO jh = 1, nb_ana
442         CALL iom_put( TRIM(tname(jh))//'x_v', out_v(:,:,jh       ) )
443         CALL iom_put( TRIM(tname(jh))//'y_v', out_v(:,:,jh+nb_ana) )
444      END DO
445#endif
446      !
447   END SUBROUTINE dia_wri_harm
448
449
450   SUBROUTINE SUR_DETERMINE(init)
451      !!---------------------------------------------------------------------------------
452      !!                      *** ROUTINE SUR_DETERMINE ***
453      !!   
454      !!   
455      !!       
456      !!---------------------------------------------------------------------------------
457      INTEGER, INTENT(in) ::   init 
458      !
459      INTEGER                         :: ji_sd, jj_sd, ji1_sd, ji2_sd, jk1_sd, jk2_sd
460      REAL(wp)                        :: zval1, zval2, zx1
461      REAL(wp), POINTER, DIMENSION(:) :: ztmpx, zcol1, zcol2
462      INTEGER , POINTER, DIMENSION(:) :: ipos2, ipivot
463      !---------------------------------------------------------------------------------
464      CALL wrk_alloc( jpincomax , ztmpx , zcol1 , zcol2 )
465      CALL wrk_alloc( jpincomax , ipos2 , ipivot        )
466           
467      IF( init == 1 ) THEN
468         IF( nsparse > jpdimsparse )   CALL ctl_stop( 'STOP', 'SUR_DETERMINE : nsparse .GT. jpdimsparse')
469         IF( ninco   > jpincomax   )   CALL ctl_stop( 'STOP', 'SUR_DETERMINE : ninco .GT. jpincomax')
470         !
471         ztmp3(:,:) = 0._wp
472         !
473         DO jk1_sd = 1, nsparse
474            DO jk2_sd = 1, nsparse
475               nisparse(jk2_sd) = nisparse(jk2_sd)
476               njsparse(jk2_sd) = njsparse(jk2_sd)
477               IF( nisparse(jk2_sd) == nisparse(jk1_sd) ) THEN
478                  ztmp3(njsparse(jk1_sd),njsparse(jk2_sd)) = ztmp3(njsparse(jk1_sd),njsparse(jk2_sd))  &
479                     &                                     + valuesparse(jk1_sd)*valuesparse(jk2_sd)
480               ENDIF
481            END DO
482         END DO
483         !
484         DO jj_sd = 1 ,ninco
485            ipos1(jj_sd) = jj_sd
486            ipos2(jj_sd) = jj_sd
487         END DO
488         !
489         DO ji_sd = 1 , ninco
490            !
491            !find greatest non-zero pivot:
492            zval1 = ABS(ztmp3(ji_sd,ji_sd))
493            !
494            ipivot(ji_sd) = ji_sd
495            DO jj_sd = ji_sd, ninco
496               zval2 = ABS(ztmp3(ji_sd,jj_sd))
497               IF( zval2.GE.zval1 )THEN
498                  ipivot(ji_sd) = jj_sd
499                  zval1         = zval2
500               ENDIF
501            END DO
502            !
503            DO ji1_sd = 1, ninco
504               zcol1(ji1_sd)               = ztmp3(ji1_sd,ji_sd)
505               zcol2(ji1_sd)               = ztmp3(ji1_sd,ipivot(ji_sd))
506               ztmp3(ji1_sd,ji_sd)         = zcol2(ji1_sd)
507               ztmp3(ji1_sd,ipivot(ji_sd)) = zcol1(ji1_sd)
508            END DO
509            !
510            ipos2(ji_sd)         = ipos1(ipivot(ji_sd))
511            ipos2(ipivot(ji_sd)) = ipos1(ji_sd)
512            ipos1(ji_sd)         = ipos2(ji_sd)
513            ipos1(ipivot(ji_sd)) = ipos2(ipivot(ji_sd))
514            zpivot(ji_sd)        = ztmp3(ji_sd,ji_sd)
515            DO jj_sd = 1, ninco
516               ztmp3(ji_sd,jj_sd) = ztmp3(ji_sd,jj_sd) / zpivot(ji_sd)
517            END DO
518            !
519            DO ji2_sd = ji_sd+1, ninco
520               zpilier(ji2_sd,ji_sd)=ztmp3(ji2_sd,ji_sd)
521               DO jj_sd=1,ninco
522                  ztmp3(ji2_sd,jj_sd)=  ztmp3(ji2_sd,jj_sd) - ztmp3(ji_sd,jj_sd) * zpilier(ji2_sd,ji_sd)
523               END DO
524            END DO
525            !
526         END DO
527         !
528      ENDIF ! End init==1
529
530      DO ji_sd = 1, ninco
531         ztmp4(ji_sd) = ztmp4(ji_sd) / zpivot(ji_sd)
532         DO ji2_sd = ji_sd+1, ninco
533            ztmp4(ji2_sd) = ztmp4(ji2_sd) - ztmp4(ji_sd) * zpilier(ji2_sd,ji_sd)
534         END DO
535      END DO
536
537      !system solving:
538      ztmpx(ninco) = ztmp4(ninco) / ztmp3(ninco,ninco)
539      ji_sd = ninco
540      DO ji_sd = ninco-1, 1, -1
541         zx1 = 0._wp
542         DO jj_sd = ji_sd+1, ninco
543            zx1 = zx1 + ztmpx(jj_sd) * ztmp3(ji_sd,jj_sd)
544         END DO
545         ztmpx(ji_sd) = ztmp4(ji_sd)-zx1
546      END DO
547
548      DO jj_sd =1, ninco
549         ztmp7(ipos1(jj_sd))=ztmpx(jj_sd)
550      END DO
551
552      CALL wrk_dealloc( jpincomax , ztmpx , zcol1 , zcol2 )
553      CALL wrk_dealloc( jpincomax , ipos2 , ipivot        )
554      !
555   END SUBROUTINE SUR_DETERMINE
556
557   SUBROUTINE harm_namelist()
558     !!---------------------------------------------------------------------
559     !!                   ***  ROUTINE harm_namelist  ***
560     !!                     
561     !! ** Purpose :   Broadcast namelist variables read by procesor lwm
562     !!
563     !! ** Method  :   use lib_mpp
564     !!----------------------------------------------------------------------
565     INTEGER :: il
566#if defined key_mpp_mpi
567      CALL mpp_bcast(nit000_han)
568      CALL mpp_bcast(nitend_han)
569      CALL mpp_bcast(nstep_han)
570      DO il = 1,jpmax_harmo
571         CALL mpp_bcast(tname(il), 4)
572      ENDDO
573#endif
574   END SUBROUTINE harm_namelist
575#else
576   !!----------------------------------------------------------------------
577   !!   Default case :   Empty module
578   !!----------------------------------------------------------------------
579   LOGICAL, PUBLIC, PARAMETER ::   lk_diaharm = .FALSE.
580CONTAINS
581   SUBROUTINE dia_harm ( kt )     ! Empty routine
582      INTEGER, INTENT( IN ) :: kt 
583      WRITE(*,*) 'dia_harm: you should not have seen this print'
584   END SUBROUTINE dia_harm
585#endif
586
587   !!======================================================================
588END MODULE diaharm
Note: See TracBrowser for help on using the repository browser.