| 1 | MODULE sbcana |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE sbcana *** |
|---|
| 4 | !! Ocean forcing: analytical momentum, heat and freshwater forcings |
|---|
| 5 | !!===================================================================== |
|---|
| 6 | !! History : 3.0 ! 2006-06 (G. Madec) Original code |
|---|
| 7 | !! 3.2 ! 2009-07 (G. Madec) Style only |
|---|
| 8 | !!---------------------------------------------------------------------- |
|---|
| 9 | |
|---|
| 10 | !!---------------------------------------------------------------------- |
|---|
| 11 | !! sbc_ana : set an analytical ocean forcing |
|---|
| 12 | !! sbc_gyre : set the GYRE configuration analytical forcing |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | USE oce ! ocean dynamics and tracers |
|---|
| 15 | USE dom_oce ! ocean space and time domain |
|---|
| 16 | USE sbc_oce ! Surface boundary condition: ocean fields |
|---|
| 17 | USE phycst ! physical constants |
|---|
| 18 | USE in_out_manager ! I/O manager |
|---|
| 19 | USE lib_mpp ! distribued memory computing library |
|---|
| 20 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 21 | USE lib_fortran |
|---|
| 22 | |
|---|
| 23 | IMPLICIT NONE |
|---|
| 24 | PRIVATE |
|---|
| 25 | |
|---|
| 26 | PUBLIC sbc_ana ! routine called in sbcmod module |
|---|
| 27 | PUBLIC sbc_gyre ! routine called in sbcmod module |
|---|
| 28 | PRIVATE ana_namelist |
|---|
| 29 | |
|---|
| 30 | ! !!* Namelist namsbc_ana * |
|---|
| 31 | INTEGER :: nn_tau000 ! nb of time-step during which the surface stress |
|---|
| 32 | ! ! increase from 0 to its nominal value |
|---|
| 33 | REAL(wp) :: rn_utau0 ! constant wind stress value in i-direction |
|---|
| 34 | REAL(wp) :: rn_vtau0 ! constant wind stress value in j-direction |
|---|
| 35 | REAL(wp) :: rn_qns0 ! non solar heat flux |
|---|
| 36 | REAL(wp) :: rn_qsr0 ! solar heat flux |
|---|
| 37 | REAL(wp) :: rn_emp0 ! net freshwater flux |
|---|
| 38 | |
|---|
| 39 | !! * Substitutions |
|---|
| 40 | # include "domzgr_substitute.h90" |
|---|
| 41 | # include "vectopt_loop_substitute.h90" |
|---|
| 42 | !!---------------------------------------------------------------------- |
|---|
| 43 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
|---|
| 44 | !! $Id$ |
|---|
| 45 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 46 | !!---------------------------------------------------------------------- |
|---|
| 47 | CONTAINS |
|---|
| 48 | |
|---|
| 49 | SUBROUTINE sbc_ana( kt ) |
|---|
| 50 | !!--------------------------------------------------------------------- |
|---|
| 51 | !! *** ROUTINE sbc_ana *** |
|---|
| 52 | !! |
|---|
| 53 | !! ** Purpose : provide at each time-step the ocean surface boundary |
|---|
| 54 | !! condition, i.e. the momentum, heat and freshwater fluxes. |
|---|
| 55 | !! |
|---|
| 56 | !! ** Method : Constant and uniform surface forcing specified from |
|---|
| 57 | !! namsbc_ana namelist parameters. All the fluxes are time |
|---|
| 58 | !! independant except the stresses which increase from zero |
|---|
| 59 | !! during the first nn_tau000 time-step |
|---|
| 60 | !! |
|---|
| 61 | !! ** Action : - set the ocean surface boundary condition, i.e. |
|---|
| 62 | !! utau, vtau, taum, wndm, qns, qsr, emp, sfx |
|---|
| 63 | !!---------------------------------------------------------------------- |
|---|
| 64 | INTEGER, INTENT(in) :: kt ! ocean time step |
|---|
| 65 | ! |
|---|
| 66 | INTEGER :: ios ! local integer |
|---|
| 67 | REAL(wp) :: zrhoa = 1.22_wp ! air density kg/m3 |
|---|
| 68 | REAL(wp) :: zcdrag = 1.5e-3_wp ! drag coefficient |
|---|
| 69 | REAL(wp) :: zfact, ztx ! local scalars |
|---|
| 70 | REAL(wp) :: zcoef, zty, zmod ! - - |
|---|
| 71 | !! |
|---|
| 72 | NAMELIST/namsbc_ana/ nn_tau000, rn_utau0, rn_vtau0, rn_qns0, rn_qsr0, rn_emp0 |
|---|
| 73 | !!--------------------------------------------------------------------- |
|---|
| 74 | ! |
|---|
| 75 | IF( kt == nit000 ) THEN |
|---|
| 76 | ! |
|---|
| 77 | IF(lwm) THEN |
|---|
| 78 | REWIND( numnam_ref ) ! Namelist namsbc_ana in reference namelist : Analytical surface fluxes |
|---|
| 79 | READ ( numnam_ref, namsbc_ana, IOSTAT = ios, ERR = 901) |
|---|
| 80 | 901 CONTINUE |
|---|
| 81 | ENDIF |
|---|
| 82 | call mpp_bcast(ios) |
|---|
| 83 | IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_ana in reference namelist', lwp ) |
|---|
| 84 | IF(lwm) THEN |
|---|
| 85 | REWIND( numnam_cfg ) ! Namelist namsbc_ana in configuration namelist : Analytical surface fluxes |
|---|
| 86 | READ ( numnam_cfg, namsbc_ana, IOSTAT = ios, ERR = 902 ) |
|---|
| 87 | 902 CONTINUE |
|---|
| 88 | ENDIF |
|---|
| 89 | call mpp_bcast(ios) |
|---|
| 90 | IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_ana in configuration namelist', lwp ) |
|---|
| 91 | |
|---|
| 92 | IF(lwm) WRITE ( numond, namsbc_ana ) |
|---|
| 93 | |
|---|
| 94 | CALL ana_namelist() |
|---|
| 95 | ! |
|---|
| 96 | IF(lwp) WRITE(numout,*)' ' |
|---|
| 97 | IF(lwp) WRITE(numout,*)' sbc_ana : Constant surface fluxes read in namsbc_ana namelist' |
|---|
| 98 | IF(lwp) WRITE(numout,*)' ~~~~~~~ ' |
|---|
| 99 | IF(lwp) WRITE(numout,*)' spin up of the stress nn_tau000 = ', nn_tau000, ' time-steps' |
|---|
| 100 | IF(lwp) WRITE(numout,*)' constant i-stress rn_utau0 = ', rn_utau0 , ' N/m2' |
|---|
| 101 | IF(lwp) WRITE(numout,*)' constant j-stress rn_vtau0 = ', rn_vtau0 , ' N/m2' |
|---|
| 102 | IF(lwp) WRITE(numout,*)' non solar heat flux rn_qns0 = ', rn_qns0 , ' W/m2' |
|---|
| 103 | IF(lwp) WRITE(numout,*)' solar heat flux rn_qsr0 = ', rn_qsr0 , ' W/m2' |
|---|
| 104 | IF(lwp) WRITE(numout,*)' net heat flux rn_emp0 = ', rn_emp0 , ' Kg/m2/s' |
|---|
| 105 | ! |
|---|
| 106 | nn_tau000 = MAX( nn_tau000, 1 ) ! must be >= 1 |
|---|
| 107 | ! |
|---|
| 108 | utau(:,:) = rn_utau0 |
|---|
| 109 | vtau(:,:) = rn_vtau0 |
|---|
| 110 | taum(:,:) = SQRT ( rn_utau0 * rn_utau0 + rn_vtau0 * rn_vtau0 ) |
|---|
| 111 | wndm(:,:) = SQRT ( taum(1,1) / ( zrhoa * zcdrag ) ) |
|---|
| 112 | ! |
|---|
| 113 | emp (:,:) = rn_emp0 |
|---|
| 114 | sfx (:,:) = 0.0_wp |
|---|
| 115 | qns (:,:) = rn_qns0 - emp(:,:) * sst_m(:,:) * rcp ! including heat content associated with mass flux at SST |
|---|
| 116 | qsr (:,:) = rn_qsr0 |
|---|
| 117 | ! |
|---|
| 118 | ENDIF |
|---|
| 119 | |
|---|
| 120 | IF( MOD( kt - 1, nn_fsbc ) == 0 ) THEN |
|---|
| 121 | ! |
|---|
| 122 | IF( kt <= nn_tau000 ) THEN ! Increase the stress to its nominal value |
|---|
| 123 | ! ! during the first nn_tau000 time-steps |
|---|
| 124 | zfact = 0.5 * ( 1. - COS( rpi * REAL( kt, wp ) / REAL( nn_tau000, wp ) ) ) |
|---|
| 125 | zcoef = 1. / ( zrhoa * zcdrag ) |
|---|
| 126 | ztx = zfact * rn_utau0 |
|---|
| 127 | zty = zfact * rn_vtau0 |
|---|
| 128 | zmod = SQRT( ztx * ztx + zty * zty ) |
|---|
| 129 | utau(:,:) = ztx |
|---|
| 130 | vtau(:,:) = zty |
|---|
| 131 | taum(:,:) = zmod |
|---|
| 132 | zmod = SQRT( zmod * zcoef ) |
|---|
| 133 | wndm(:,:) = zmod |
|---|
| 134 | ENDIF |
|---|
| 135 | ! ! update heat and fresh water fluxes |
|---|
| 136 | ! ! as they may have been changed by sbcssr module |
|---|
| 137 | emp (:,:) = rn_emp0 ! NB: qns changes with SST if emp /= 0 |
|---|
| 138 | sfx (:,:) = 0._wp |
|---|
| 139 | qns (:,:) = rn_qns0 - emp(:,:) * sst_m(:,:) * rcp |
|---|
| 140 | qsr (:,:) = rn_qsr0 |
|---|
| 141 | ! |
|---|
| 142 | ENDIF |
|---|
| 143 | ! |
|---|
| 144 | END SUBROUTINE sbc_ana |
|---|
| 145 | |
|---|
| 146 | |
|---|
| 147 | SUBROUTINE sbc_gyre( kt ) |
|---|
| 148 | !!--------------------------------------------------------------------- |
|---|
| 149 | !! *** ROUTINE sbc_ana *** |
|---|
| 150 | !! |
|---|
| 151 | !! ** Purpose : provide at each time-step the GYRE surface boundary |
|---|
| 152 | !! condition, i.e. the momentum, heat and freshwater fluxes. |
|---|
| 153 | !! |
|---|
| 154 | !! ** Method : analytical seasonal cycle for GYRE configuration. |
|---|
| 155 | !! CAUTION : never mask the surface stress field ! |
|---|
| 156 | !! |
|---|
| 157 | !! ** Action : - set the ocean surface boundary condition, i.e. |
|---|
| 158 | !! utau, vtau, taum, wndm, qns, qsr, emp, sfx |
|---|
| 159 | !! |
|---|
| 160 | !! Reference : Hazeleger, W., and S. Drijfhout, JPO, 30, 677-695, 2000. |
|---|
| 161 | !!---------------------------------------------------------------------- |
|---|
| 162 | INTEGER, INTENT(in) :: kt ! ocean time step |
|---|
| 163 | !! |
|---|
| 164 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 165 | INTEGER :: zyear0 ! initial year |
|---|
| 166 | INTEGER :: zmonth0 ! initial month |
|---|
| 167 | INTEGER :: zday0 ! initial day |
|---|
| 168 | INTEGER :: zday_year0 ! initial day since january 1st |
|---|
| 169 | REAL(wp) :: ztau , ztau_sais ! wind intensity and of the seasonal cycle |
|---|
| 170 | REAL(wp) :: ztime ! time in hour |
|---|
| 171 | REAL(wp) :: ztimemax , ztimemin ! 21th June, and 21th decem. if date0 = 1st january |
|---|
| 172 | REAL(wp) :: ztimemax1, ztimemin1 ! 21th June, and 21th decem. if date0 = 1st january |
|---|
| 173 | REAL(wp) :: ztimemax2, ztimemin2 ! 21th June, and 21th decem. if date0 = 1st january |
|---|
| 174 | REAL(wp) :: ztaun ! intensity |
|---|
| 175 | REAL(wp) :: zemp_s, zemp_n, zemp_sais, ztstar |
|---|
| 176 | REAL(wp) :: zcos_sais1, zcos_sais2, ztrp, zconv, t_star |
|---|
| 177 | REAL(wp) :: zsumemp, zsurf |
|---|
| 178 | REAL(wp) :: zrhoa = 1.22 ! Air density kg/m3 |
|---|
| 179 | REAL(wp) :: zcdrag = 1.5e-3 ! drag coefficient |
|---|
| 180 | REAL(wp) :: ztx, zty, zmod, zcoef ! temporary variables |
|---|
| 181 | REAL(wp) :: zyydd ! number of days in one year |
|---|
| 182 | !!--------------------------------------------------------------------- |
|---|
| 183 | zyydd = REAL(nyear_len(1),wp) |
|---|
| 184 | |
|---|
| 185 | ! ---------------------------- ! |
|---|
| 186 | ! heat and freshwater fluxes ! |
|---|
| 187 | ! ---------------------------- ! |
|---|
| 188 | !same temperature, E-P as in HAZELEGER 2000 |
|---|
| 189 | |
|---|
| 190 | zyear0 = ndate0 / 10000 ! initial year |
|---|
| 191 | zmonth0 = ( ndate0 - zyear0 * 10000 ) / 100 ! initial month |
|---|
| 192 | zday0 = ndate0 - zyear0 * 10000 - zmonth0 * 100 ! initial day betwen 1 and 30 |
|---|
| 193 | zday_year0 = ( zmonth0 - 1 ) * 30.+zday0 ! initial day betwen 1 and 360 |
|---|
| 194 | |
|---|
| 195 | ! current day (in hours) since january the 1st of the current year |
|---|
| 196 | ztime = REAL( kt ) * rdt / (rmmss * rhhmm) & ! total incrementation (in hours) |
|---|
| 197 | & - (nyear - 1) * rjjhh * zyydd ! minus years since beginning of experiment (in hours) |
|---|
| 198 | |
|---|
| 199 | ztimemax1 = ((5.*30.)+21.)* 24. ! 21th june at 24h in hours |
|---|
| 200 | ztimemin1 = ztimemax1 + rjjhh * zyydd / 2 ! 21th december in hours |
|---|
| 201 | ztimemax2 = ((6.*30.)+21.)* 24. ! 21th july at 24h in hours |
|---|
| 202 | ztimemin2 = ztimemax2 - rjjhh * zyydd / 2 ! 21th january in hours |
|---|
| 203 | ! ! NB: rjjhh * zyydd / 4 = one seasonal cycle in hours |
|---|
| 204 | |
|---|
| 205 | ! amplitudes |
|---|
| 206 | zemp_S = 0.7 ! intensity of COS in the South |
|---|
| 207 | zemp_N = 0.8 ! intensity of COS in the North |
|---|
| 208 | zemp_sais = 0.1 |
|---|
| 209 | zTstar = 28.3 ! intemsity from 28.3 a -5 deg |
|---|
| 210 | |
|---|
| 211 | ! 1/2 period between 21th June and 21th December and between 21th July and 21th January |
|---|
| 212 | zcos_sais1 = COS( (ztime - ztimemax1) / (ztimemin1 - ztimemax1) * rpi ) |
|---|
| 213 | zcos_sais2 = COS( (ztime - ztimemax2) / (ztimemax2 - ztimemin2) * rpi ) |
|---|
| 214 | |
|---|
| 215 | ztrp= - 40.e0 ! retroaction term on heat fluxes (W/m2/K) |
|---|
| 216 | zconv = 3.16e-5 ! convertion factor: 1 m/yr => 3.16e-5 mm/s |
|---|
| 217 | DO jj = 1, jpj |
|---|
| 218 | DO ji = 1, jpi |
|---|
| 219 | ! domain from 15 deg to 50 deg between 27 and 28 degC at 15N, -3 |
|---|
| 220 | ! and 13 degC at 50N 53.5 + or - 11 = 1/4 period : |
|---|
| 221 | ! 64.5 in summer, 42.5 in winter |
|---|
| 222 | t_star = zTstar * ( 1 + 1. / 50. * zcos_sais2 ) & |
|---|
| 223 | & * COS( rpi * (gphit(ji,jj) - 5.) & |
|---|
| 224 | & / ( 53.5 * ( 1 + 11 / 53.5 * zcos_sais2 ) * 2.) ) |
|---|
| 225 | ! 23.5 deg : tropics |
|---|
| 226 | qsr (ji,jj) = 230 * COS( 3.1415 * ( gphit(ji,jj) - 23.5 * zcos_sais1 ) / ( 0.9 * 180 ) ) |
|---|
| 227 | qns (ji,jj) = ztrp * ( tsb(ji,jj,1,jp_tem) - t_star ) - qsr(ji,jj) |
|---|
| 228 | IF( gphit(ji,jj) >= 14.845 .AND. 37.2 >= gphit(ji,jj) ) THEN ! zero at 37.8 deg, max at 24.6 deg |
|---|
| 229 | emp (ji,jj) = zemp_S * zconv & |
|---|
| 230 | & * SIN( rpi / 2 * (gphit(ji,jj) - 37.2) / (24.6 - 37.2) ) & |
|---|
| 231 | & * ( 1 - zemp_sais / zemp_S * zcos_sais1) |
|---|
| 232 | ELSE |
|---|
| 233 | emp (ji,jj) = - zemp_N * zconv & |
|---|
| 234 | & * SIN( rpi / 2 * (gphit(ji,jj) - 37.2) / (46.8 - 37.2) ) & |
|---|
| 235 | & * ( 1 - zemp_sais / zemp_N * zcos_sais1 ) |
|---|
| 236 | ENDIF |
|---|
| 237 | END DO |
|---|
| 238 | END DO |
|---|
| 239 | |
|---|
| 240 | ! Compute the emp flux such as its integration on the whole domain at each time is zero |
|---|
| 241 | IF( nbench /= 1 ) THEN |
|---|
| 242 | zsumemp = GLOB_SUM( emp(:,:) ) |
|---|
| 243 | zsurf = GLOB_SUM( tmask(:,:,1) ) |
|---|
| 244 | ! Default GYRE configuration |
|---|
| 245 | zsumemp = zsumemp / zsurf |
|---|
| 246 | ELSE |
|---|
| 247 | ! Benchmark GYRE configuration (to allow the bit to bit comparison between Mpp/Mono case) |
|---|
| 248 | zsumemp = 0.e0 ; zsurf = 0.e0 |
|---|
| 249 | ENDIF |
|---|
| 250 | |
|---|
| 251 | ! freshwater (mass flux) and update of qns with heat content of emp |
|---|
| 252 | emp (:,:) = emp(:,:) - zsumemp * tmask(:,:,1) ! freshwater flux (=0 in domain average) |
|---|
| 253 | sfx (:,:) = 0.0_wp ! no salt flux |
|---|
| 254 | qns (:,:) = qns(:,:) - emp(:,:) * sst_m(:,:) * rcp ! evap and precip are at SST |
|---|
| 255 | |
|---|
| 256 | |
|---|
| 257 | ! ---------------------------- ! |
|---|
| 258 | ! momentum fluxes ! |
|---|
| 259 | ! ---------------------------- ! |
|---|
| 260 | ! same wind as in Wico |
|---|
| 261 | !test date0 : ndate0 = 010203 |
|---|
| 262 | zyear0 = ndate0 / 10000 |
|---|
| 263 | zmonth0 = ( ndate0 - zyear0 * 10000 ) / 100 |
|---|
| 264 | zday0 = ndate0 - zyear0 * 10000 - zmonth0 * 100 |
|---|
| 265 | !Calculates nday_year, day since january 1st |
|---|
| 266 | zday_year0 = (zmonth0-1)*30.+zday0 |
|---|
| 267 | |
|---|
| 268 | !accumulates days of previous months of this year |
|---|
| 269 | ! day (in hours) since january the 1st |
|---|
| 270 | ztime = FLOAT( kt ) * rdt / (rmmss * rhhmm) & ! incrementation in hour |
|---|
| 271 | & - (nyear - 1) * rjjhh * zyydd ! - nber of hours the precedent years |
|---|
| 272 | ztimemax = ((5.*30.)+21.)* 24. ! 21th june in hours |
|---|
| 273 | ztimemin = ztimemax + rjjhh * zyydd / 2 ! 21th december in hours |
|---|
| 274 | ! ! NB: rjjhh * zyydd / 4 = 1 seasonal cycle in hours |
|---|
| 275 | |
|---|
| 276 | ! mean intensity at 0.105 ; srqt(2) because projected with 45deg angle |
|---|
| 277 | ztau = 0.105 / SQRT( 2. ) |
|---|
| 278 | ! seasonal oscillation intensity |
|---|
| 279 | ztau_sais = 0.015 |
|---|
| 280 | ztaun = ztau - ztau_sais * COS( (ztime - ztimemax) / (ztimemin - ztimemax) * rpi ) |
|---|
| 281 | DO jj = 1, jpj |
|---|
| 282 | DO ji = 1, jpi |
|---|
| 283 | ! domain from 15deg to 50deg and 1/2 period along 14deg |
|---|
| 284 | ! so 5/4 of half period with seasonal cycle |
|---|
| 285 | utau(ji,jj) = - ztaun * SIN( rpi * (gphiu(ji,jj) - 15.) / (29.-15.) ) |
|---|
| 286 | vtau(ji,jj) = ztaun * SIN( rpi * (gphiv(ji,jj) - 15.) / (29.-15.) ) |
|---|
| 287 | END DO |
|---|
| 288 | END DO |
|---|
| 289 | |
|---|
| 290 | ! module of wind stress and wind speed at T-point |
|---|
| 291 | zcoef = 1. / ( zrhoa * zcdrag ) |
|---|
| 292 | !CDIR NOVERRCHK |
|---|
| 293 | DO jj = 2, jpjm1 |
|---|
| 294 | !CDIR NOVERRCHK |
|---|
| 295 | DO ji = fs_2, fs_jpim1 ! vect. opt. |
|---|
| 296 | ztx = utau(ji-1,jj ) + utau(ji,jj) |
|---|
| 297 | zty = vtau(ji ,jj-1) + vtau(ji,jj) |
|---|
| 298 | zmod = 0.5 * SQRT( ztx * ztx + zty * zty ) |
|---|
| 299 | taum(ji,jj) = zmod |
|---|
| 300 | wndm(ji,jj) = SQRT( zmod * zcoef ) |
|---|
| 301 | END DO |
|---|
| 302 | END DO |
|---|
| 303 | CALL lbc_lnk( taum(:,:), 'T', 1. ) ; CALL lbc_lnk( wndm(:,:), 'T', 1. ) |
|---|
| 304 | |
|---|
| 305 | ! ---------------------------------- ! |
|---|
| 306 | ! control print at first time-step ! |
|---|
| 307 | ! ---------------------------------- ! |
|---|
| 308 | IF( kt == nit000 .AND. lwp ) THEN |
|---|
| 309 | WRITE(numout,*) |
|---|
| 310 | WRITE(numout,*)'sbc_gyre : analytical surface fluxes for GYRE configuration' |
|---|
| 311 | WRITE(numout,*)'~~~~~~~~ ' |
|---|
| 312 | WRITE(numout,*)' nyear = ', nyear |
|---|
| 313 | WRITE(numout,*)' nmonth = ', nmonth |
|---|
| 314 | WRITE(numout,*)' nday = ', nday |
|---|
| 315 | WRITE(numout,*)' nday_year = ', nday_year |
|---|
| 316 | WRITE(numout,*)' ztime = ', ztime |
|---|
| 317 | WRITE(numout,*)' ztimemax = ', ztimemax |
|---|
| 318 | WRITE(numout,*)' ztimemin = ', ztimemin |
|---|
| 319 | WRITE(numout,*)' ztimemax1 = ', ztimemax1 |
|---|
| 320 | WRITE(numout,*)' ztimemin1 = ', ztimemin1 |
|---|
| 321 | WRITE(numout,*)' ztimemax2 = ', ztimemax2 |
|---|
| 322 | WRITE(numout,*)' ztimemin2 = ', ztimemin2 |
|---|
| 323 | WRITE(numout,*)' zyear0 = ', zyear0 |
|---|
| 324 | WRITE(numout,*)' zmonth0 = ', zmonth0 |
|---|
| 325 | WRITE(numout,*)' zday0 = ', zday0 |
|---|
| 326 | WRITE(numout,*)' zday_year0 = ', zday_year0 |
|---|
| 327 | WRITE(numout,*)' zyydd = ', zyydd |
|---|
| 328 | WRITE(numout,*)' zemp_S = ', zemp_S |
|---|
| 329 | WRITE(numout,*)' zemp_N = ', zemp_N |
|---|
| 330 | WRITE(numout,*)' zemp_sais = ', zemp_sais |
|---|
| 331 | WRITE(numout,*)' zTstar = ', zTstar |
|---|
| 332 | WRITE(numout,*)' zsumemp = ', zsumemp |
|---|
| 333 | WRITE(numout,*)' zsurf = ', zsurf |
|---|
| 334 | WRITE(numout,*)' ztrp = ', ztrp |
|---|
| 335 | WRITE(numout,*)' zconv = ', zconv |
|---|
| 336 | WRITE(numout,*)' ndastp = ', ndastp |
|---|
| 337 | WRITE(numout,*)' adatrj = ', adatrj |
|---|
| 338 | ENDIF |
|---|
| 339 | ! |
|---|
| 340 | END SUBROUTINE sbc_gyre |
|---|
| 341 | |
|---|
| 342 | SUBROUTINE ana_namelist() |
|---|
| 343 | !!--------------------------------------------------------------------- |
|---|
| 344 | !! *** ROUTINE ana_namelist *** |
|---|
| 345 | !! |
|---|
| 346 | !! ** Purpose : Broadcast namelist variables read by procesor lwm |
|---|
| 347 | !! |
|---|
| 348 | !! ** Method : use lib_mpp |
|---|
| 349 | !!---------------------------------------------------------------------- |
|---|
| 350 | #if defined key_mpp_mpi |
|---|
| 351 | CALL mpp_bcast(nn_tau000) |
|---|
| 352 | CALL mpp_bcast(rn_utau0) |
|---|
| 353 | CALL mpp_bcast(rn_vtau0) |
|---|
| 354 | CALL mpp_bcast(rn_qns0) |
|---|
| 355 | CALL mpp_bcast(rn_qsr0) |
|---|
| 356 | CALL mpp_bcast(rn_emp0) |
|---|
| 357 | #endif |
|---|
| 358 | END SUBROUTINE ana_namelist |
|---|
| 359 | |
|---|
| 360 | !!====================================================================== |
|---|
| 361 | END MODULE sbcana |
|---|
