| 1 | MODULE traqsr |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE traqsr *** |
|---|
| 4 | !! Ocean physics: solar radiation penetration in the top ocean levels |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : OPA ! 1990-10 (B. Blanke) Original code |
|---|
| 7 | !! 7.0 ! 1991-11 (G. Madec) |
|---|
| 8 | !! ! 1996-01 (G. Madec) s-coordinates |
|---|
| 9 | !! NEMO 1.0 ! 2002-06 (G. Madec) F90: Free form and module |
|---|
| 10 | !! - ! 2005-11 (G. Madec) zco, zps, sco coordinate |
|---|
| 11 | !! 3.2 ! 2009-04 (G. Madec & NEMO team) |
|---|
| 12 | !! 3.4 ! 2012-05 (C. Rousset) store attenuation coef for use in ice model |
|---|
| 13 | !! 3.6 ! 2015-12 (O. Aumont, J. Jouanno, C. Ethe) use vertical profile of chlorophyll |
|---|
| 14 | !!---------------------------------------------------------------------- |
|---|
| 15 | |
|---|
| 16 | !!---------------------------------------------------------------------- |
|---|
| 17 | !! tra_qsr : trend due to the solar radiation penetration |
|---|
| 18 | !! tra_qsr_init : solar radiation penetration initialization |
|---|
| 19 | !!---------------------------------------------------------------------- |
|---|
| 20 | USE oce ! ocean dynamics and active tracers |
|---|
| 21 | USE dom_oce ! ocean space and time domain |
|---|
| 22 | USE sbc_oce ! surface boundary condition: ocean |
|---|
| 23 | USE trc_oce ! share SMS/Ocean variables |
|---|
| 24 | USE trd_oce ! trends: ocean variables |
|---|
| 25 | USE trdtra ! trends manager: tracers |
|---|
| 26 | USE in_out_manager ! I/O manager |
|---|
| 27 | USE phycst ! physical constants |
|---|
| 28 | USE prtctl ! Print control |
|---|
| 29 | USE iom ! I/O manager |
|---|
| 30 | USE fldread ! read input fields |
|---|
| 31 | USE restart ! ocean restart |
|---|
| 32 | USE lib_mpp ! MPP library |
|---|
| 33 | USE wrk_nemo ! Memory Allocation |
|---|
| 34 | USE timing ! Timing |
|---|
| 35 | USE iom_def, ONLY : lxios_read, lwxios |
|---|
| 36 | |
|---|
| 37 | IMPLICIT NONE |
|---|
| 38 | PRIVATE |
|---|
| 39 | |
|---|
| 40 | PUBLIC tra_qsr ! routine called by step.F90 (ln_traqsr=T) |
|---|
| 41 | PUBLIC tra_qsr_init ! routine called by nemogcm.F90 |
|---|
| 42 | PRIVATE qsr_namelist |
|---|
| 43 | |
|---|
| 44 | ! !!* Namelist namtra_qsr: penetrative solar radiation |
|---|
| 45 | LOGICAL , PUBLIC :: ln_traqsr !: light absorption (qsr) flag |
|---|
| 46 | LOGICAL , PUBLIC :: ln_qsr_rgb !: Red-Green-Blue light absorption flag |
|---|
| 47 | LOGICAL , PUBLIC :: ln_qsr_2bd !: 2 band light absorption flag |
|---|
| 48 | LOGICAL , PUBLIC :: ln_qsr_bio !: bio-model light absorption flag |
|---|
| 49 | LOGICAL , PUBLIC :: ln_qsr_ice !: light penetration for ice-model LIM3 (clem) |
|---|
| 50 | INTEGER , PUBLIC :: nn_chldta !: use Chlorophyll data (=1) or not (=0) |
|---|
| 51 | REAL(wp), PUBLIC :: rn_abs !: fraction absorbed in the very near surface (RGB & 2 bands) |
|---|
| 52 | REAL(wp), PUBLIC :: rn_si0 !: very near surface depth of extinction (RGB & 2 bands) |
|---|
| 53 | REAL(wp), PUBLIC :: rn_si1 !: deepest depth of extinction (water type I) (2 bands) |
|---|
| 54 | LOGICAL :: ln_qsr_sio !: single processor read flag |
|---|
| 55 | |
|---|
| 56 | ! Module variables |
|---|
| 57 | REAL(wp) :: xsi0r !: inverse of rn_si0 |
|---|
| 58 | REAL(wp) :: xsi1r !: inverse of rn_si1 |
|---|
| 59 | TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_chl ! structure of input Chl (file informations, fields read) |
|---|
| 60 | INTEGER, PUBLIC :: nksr ! levels below which the light cannot penetrate ( depth larger than 391 m) |
|---|
| 61 | REAL(wp), DIMENSION(3,61) :: rkrgb !: tabulated attenuation coefficients for RGB absorption |
|---|
| 62 | |
|---|
| 63 | !! * Substitutions |
|---|
| 64 | # include "domzgr_substitute.h90" |
|---|
| 65 | # include "vectopt_loop_substitute.h90" |
|---|
| 66 | !!---------------------------------------------------------------------- |
|---|
| 67 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
|---|
| 68 | !! $Id$ |
|---|
| 69 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 70 | !!---------------------------------------------------------------------- |
|---|
| 71 | CONTAINS |
|---|
| 72 | |
|---|
| 73 | SUBROUTINE tra_qsr( kt ) |
|---|
| 74 | !!---------------------------------------------------------------------- |
|---|
| 75 | !! *** ROUTINE tra_qsr *** |
|---|
| 76 | !! |
|---|
| 77 | !! ** Purpose : Compute the temperature trend due to the solar radiation |
|---|
| 78 | !! penetration and add it to the general temperature trend. |
|---|
| 79 | !! |
|---|
| 80 | !! ** Method : The profile of the solar radiation within the ocean is defined |
|---|
| 81 | !! through 2 wavebands (rn_si0,rn_si1) or 3 wavebands (RGB) and a ratio rn_abs |
|---|
| 82 | !! Considering the 2 wavebands case: |
|---|
| 83 | !! I(k) = Qsr*( rn_abs*EXP(z(k)/rn_si0) + (1.-rn_abs)*EXP(z(k)/rn_si1) ) |
|---|
| 84 | !! The temperature trend associated with the solar radiation penetration |
|---|
| 85 | !! is given by : zta = 1/e3t dk[ I ] / (rau0*Cp) |
|---|
| 86 | !! At the bottom, boudary condition for the radiation is no flux : |
|---|
| 87 | !! all heat which has not been absorbed in the above levels is put |
|---|
| 88 | !! in the last ocean level. |
|---|
| 89 | !! In z-coordinate case, the computation is only done down to the |
|---|
| 90 | !! level where I(k) < 1.e-15 W/m2. In addition, the coefficients |
|---|
| 91 | !! used for the computation are calculated one for once as they |
|---|
| 92 | !! depends on k only. |
|---|
| 93 | !! |
|---|
| 94 | !! ** Action : - update ta with the penetrative solar radiation trend |
|---|
| 95 | !! - save the trend in ttrd ('key_trdtra') |
|---|
| 96 | !! |
|---|
| 97 | !! Reference : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp. |
|---|
| 98 | !! Lengaigne et al. 2007, Clim. Dyn., V28, 5, 503-516. |
|---|
| 99 | !! Morel, A. et Berthon, JF, 1989, Limnol Oceanogr 34(8), 1545-1562 |
|---|
| 100 | !!---------------------------------------------------------------------- |
|---|
| 101 | ! |
|---|
| 102 | INTEGER, INTENT(in) :: kt ! ocean time-step |
|---|
| 103 | ! |
|---|
| 104 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 105 | INTEGER :: irgb ! local integers |
|---|
| 106 | REAL(wp) :: zchl, zcoef, zfact ! local scalars |
|---|
| 107 | REAL(wp) :: zc0, zc1, zc2, zc3 ! - - |
|---|
| 108 | REAL(wp) :: zz0, zz1, z1_e3t ! - - |
|---|
| 109 | REAL(wp) :: zCb, zCmax, zze, zpsi, zpsimax, zdelpsi, zCtot, zCze |
|---|
| 110 | REAL(wp) :: zlogc, zlogc2, zlogc3 |
|---|
| 111 | REAL(wp), POINTER, DIMENSION(:,: ) :: zekb, zekg, zekr |
|---|
| 112 | REAL(wp), POINTER, DIMENSION(:,:,:) :: ze0, ze1, ze2, ze3, zea, ztrdt, zchl3d |
|---|
| 113 | !!-------------------------------------------------------------------------- |
|---|
| 114 | ! |
|---|
| 115 | IF( nn_timing == 1 ) CALL timing_start('tra_qsr') |
|---|
| 116 | ! |
|---|
| 117 | CALL wrk_alloc( jpi, jpj, zekb, zekg, zekr ) |
|---|
| 118 | CALL wrk_alloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea, zchl3d ) |
|---|
| 119 | ! |
|---|
| 120 | IF( kt == nit000 ) THEN |
|---|
| 121 | IF(lwp) WRITE(numout,*) |
|---|
| 122 | IF(lwp) WRITE(numout,*) 'tra_qsr : penetration of the surface solar radiation' |
|---|
| 123 | IF(lwp) WRITE(numout,*) '~~~~~~~' |
|---|
| 124 | IF( .NOT.ln_traqsr ) RETURN |
|---|
| 125 | ENDIF |
|---|
| 126 | |
|---|
| 127 | IF( l_trdtra ) THEN ! Save ta and sa trends |
|---|
| 128 | CALL wrk_alloc( jpi, jpj, jpk, ztrdt ) |
|---|
| 129 | ztrdt(:,:,:) = tsa(:,:,:,jp_tem) |
|---|
| 130 | ENDIF |
|---|
| 131 | |
|---|
| 132 | ! Set before qsr tracer content field |
|---|
| 133 | ! *********************************** |
|---|
| 134 | IF( kt == nit000 ) THEN ! Set the forcing field at nit000 - 1 |
|---|
| 135 | ! ! ----------------------------------- |
|---|
| 136 | qsr_hc(:,:,:) = 0.e0 |
|---|
| 137 | ! |
|---|
| 138 | IF( ln_rstart .AND. & ! Restart: read in restart file |
|---|
| 139 | & iom_varid( numror, 'qsr_hc_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 140 | IF(lwp) WRITE(numout,*) ' nit000-1 qsr tracer content forcing field red in the restart file' |
|---|
| 141 | zfact = 0.5e0 |
|---|
| 142 | CALL iom_get( numror, jpdom_autoglo, 'qsr_hc_b', qsr_hc_b, lrxios = lxios_read ) ! before heat content trend due to Qsr flux |
|---|
| 143 | ELSE ! No restart or restart not found: Euler forward time stepping |
|---|
| 144 | zfact = 1.e0 |
|---|
| 145 | qsr_hc_b(:,:,:) = 0.e0 |
|---|
| 146 | ENDIF |
|---|
| 147 | ELSE ! Swap of forcing field |
|---|
| 148 | ! ! --------------------- |
|---|
| 149 | zfact = 0.5e0 |
|---|
| 150 | qsr_hc_b(:,:,:) = qsr_hc(:,:,:) |
|---|
| 151 | ENDIF |
|---|
| 152 | ! Compute now qsr tracer content field |
|---|
| 153 | ! ************************************ |
|---|
| 154 | |
|---|
| 155 | ! ! ============================================== ! |
|---|
| 156 | IF( lk_qsr_bio .AND. ln_qsr_bio ) THEN ! bio-model fluxes : all vertical coordinates ! |
|---|
| 157 | ! ! ============================================== ! |
|---|
| 158 | DO jk = 1, jpkm1 |
|---|
| 159 | qsr_hc(:,:,jk) = r1_rau0_rcp * ( etot3(:,:,jk) - etot3(:,:,jk+1) ) |
|---|
| 160 | END DO |
|---|
| 161 | ! Add to the general trend |
|---|
| 162 | DO jk = 1, jpkm1 |
|---|
| 163 | DO jj = 2, jpjm1 |
|---|
| 164 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 165 | z1_e3t = zfact / fse3t(ji,jj,jk) |
|---|
| 166 | tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t |
|---|
| 167 | END DO |
|---|
| 168 | END DO |
|---|
| 169 | END DO |
|---|
| 170 | CALL iom_put( 'qsr3d', etot3 ) ! Shortwave Radiation 3D distribution |
|---|
| 171 | ! clem: store attenuation coefficient of the first ocean level |
|---|
| 172 | IF ( ln_qsr_ice ) THEN |
|---|
| 173 | DO jj = 1, jpj |
|---|
| 174 | DO ji = 1, jpi |
|---|
| 175 | IF ( qsr(ji,jj) /= 0._wp ) THEN |
|---|
| 176 | fraqsr_1lev(ji,jj) = ( qsr_hc(ji,jj,1) / ( r1_rau0_rcp * qsr(ji,jj) ) ) |
|---|
| 177 | ELSE |
|---|
| 178 | fraqsr_1lev(ji,jj) = 1. |
|---|
| 179 | ENDIF |
|---|
| 180 | END DO |
|---|
| 181 | END DO |
|---|
| 182 | ENDIF |
|---|
| 183 | ! ! ============================================== ! |
|---|
| 184 | ELSE ! Ocean alone : |
|---|
| 185 | ! ! ============================================== ! |
|---|
| 186 | ! |
|---|
| 187 | ! ! ------------------------- ! |
|---|
| 188 | IF( ln_qsr_rgb) THEN ! R-G-B light penetration ! |
|---|
| 189 | ! ! ------------------------- ! |
|---|
| 190 | lspr = ln_qsr_sio |
|---|
| 191 | ! Set chlorophyl concentration |
|---|
| 192 | IF( nn_chldta == 1 .OR. nn_chldta == 2 .OR. lk_vvl ) THEN !* Variable Chlorophyll or ocean volume |
|---|
| 193 | ! |
|---|
| 194 | IF( nn_chldta == 1 ) THEN !* 2D Variable Chlorophyll |
|---|
| 195 | ! |
|---|
| 196 | CALL fld_read( kt, 1, sf_chl ) ! Read Chl data and provides it at the current time step |
|---|
| 197 | DO jk = 1, nksr + 1 |
|---|
| 198 | zchl3d(:,:,jk) = sf_chl(1)%fnow(:,:,1) |
|---|
| 199 | ENDDO |
|---|
| 200 | ! |
|---|
| 201 | ELSE IF( nn_chldta == 2 ) THEN !* -3-D Variable Chlorophyll |
|---|
| 202 | ! |
|---|
| 203 | CALL fld_read( kt, 1, sf_chl ) ! Read Chl data and provides it at the current time step |
|---|
| 204 | !CDIR NOVERRCHK ! |
|---|
| 205 | DO jj = 1, jpj |
|---|
| 206 | !CDIR NOVERRCHK |
|---|
| 207 | DO ji = 1, jpi |
|---|
| 208 | zchl = sf_chl(1)%fnow(ji,jj,1) |
|---|
| 209 | zCtot = 40.6 * zchl**0.459 |
|---|
| 210 | zze = 568.2 * zCtot**(-0.746) |
|---|
| 211 | IF( zze > 102. ) zze = 200.0 * zCtot**(-0.293) |
|---|
| 212 | zlogc = LOG( zchl ) |
|---|
| 213 | zlogc2 = zlogc * zlogc |
|---|
| 214 | zlogc3 = zlogc * zlogc * zlogc |
|---|
| 215 | zCb = 0.768 + 0.087 * zlogc - 0.179 * zlogc2 - 0.025 * zlogc3 |
|---|
| 216 | zCmax = 0.299 - 0.289 * zlogc + 0.579 * zlogc2 |
|---|
| 217 | zpsimax = 0.6 - 0.640 * zlogc + 0.021 * zlogc2 + 0.115 * zlogc3 |
|---|
| 218 | zdelpsi = 0.710 + 0.159 * zlogc + 0.021 * zlogc2 |
|---|
| 219 | zCze = 1.12 * (zchl)**0.803 |
|---|
| 220 | DO jk = 1, nksr + 1 |
|---|
| 221 | zpsi = fsdept(ji,jj,jk) / zze |
|---|
| 222 | zchl3d(ji,jj,jk) = zCze * ( zCb + zCmax * EXP( -( (zpsi - zpsimax) / zdelpsi )**2 ) ) |
|---|
| 223 | END DO |
|---|
| 224 | ! |
|---|
| 225 | END DO |
|---|
| 226 | END DO |
|---|
| 227 | ! |
|---|
| 228 | ELSE !* Variable ocean volume but constant chrlorophyll |
|---|
| 229 | DO jk = 1, nksr + 1 |
|---|
| 230 | zchl3d(:,:,jk) = 0.05 |
|---|
| 231 | ENDDO |
|---|
| 232 | ENDIF |
|---|
| 233 | ! |
|---|
| 234 | zcoef = ( 1. - rn_abs ) / 3.e0 ! equi-partition in R-G-B |
|---|
| 235 | ze0(:,:,1) = rn_abs * qsr(:,:) |
|---|
| 236 | ze1(:,:,1) = zcoef * qsr(:,:) |
|---|
| 237 | ze2(:,:,1) = zcoef * qsr(:,:) |
|---|
| 238 | ze3(:,:,1) = zcoef * qsr(:,:) |
|---|
| 239 | zea(:,:,1) = qsr(:,:) |
|---|
| 240 | ! |
|---|
| 241 | DO jk = 2, nksr+1 |
|---|
| 242 | ! |
|---|
| 243 | DO jj = 1, jpj ! Separation in R-G-B depending of vertical profile of Chl |
|---|
| 244 | !CDIR NOVERRCHK |
|---|
| 245 | DO ji = 1, jpi |
|---|
| 246 | zchl = MIN( 10. , MAX( 0.03, zchl3d(ji,jj,jk) ) ) |
|---|
| 247 | irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 ) |
|---|
| 248 | zekb(ji,jj) = rkrgb(1,irgb) |
|---|
| 249 | zekg(ji,jj) = rkrgb(2,irgb) |
|---|
| 250 | zekr(ji,jj) = rkrgb(3,irgb) |
|---|
| 251 | END DO |
|---|
| 252 | END DO |
|---|
| 253 | !CDIR NOVERRCHK |
|---|
| 254 | DO jj = 1, jpj |
|---|
| 255 | !CDIR NOVERRCHK |
|---|
| 256 | DO ji = 1, jpi |
|---|
| 257 | zc0 = ze0(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * xsi0r ) |
|---|
| 258 | zc1 = ze1(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekb(ji,jj) ) |
|---|
| 259 | zc2 = ze2(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekg(ji,jj) ) |
|---|
| 260 | zc3 = ze3(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekr(ji,jj) ) |
|---|
| 261 | ze0(ji,jj,jk) = zc0 |
|---|
| 262 | ze1(ji,jj,jk) = zc1 |
|---|
| 263 | ze2(ji,jj,jk) = zc2 |
|---|
| 264 | ze3(ji,jj,jk) = zc3 |
|---|
| 265 | zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk) |
|---|
| 266 | END DO |
|---|
| 267 | END DO |
|---|
| 268 | END DO |
|---|
| 269 | ! |
|---|
| 270 | DO jk = 1, nksr ! compute and add qsr trend to ta |
|---|
| 271 | qsr_hc(:,:,jk) = r1_rau0_rcp * ( zea(:,:,jk) - zea(:,:,jk+1) ) |
|---|
| 272 | END DO |
|---|
| 273 | zea(:,:,nksr+1:jpk) = 0.e0 ! below 400m set to zero |
|---|
| 274 | CALL iom_put( 'qsr3d', zea ) ! Shortwave Radiation 3D distribution |
|---|
| 275 | ! |
|---|
| 276 | IF ( ln_qsr_ice ) THEN ! store attenuation coefficient of the first ocean level |
|---|
| 277 | !CDIR NOVERRCHK |
|---|
| 278 | DO jj = 1, jpj ! Separation in R-G-B depending of the surface Chl |
|---|
| 279 | !CDIR NOVERRCHK |
|---|
| 280 | DO ji = 1, jpi |
|---|
| 281 | zchl = MIN( 10. , MAX( 0.03, zchl3d(ji,jj,1) ) ) |
|---|
| 282 | irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 ) |
|---|
| 283 | zekb(ji,jj) = rkrgb(1,irgb) |
|---|
| 284 | zekg(ji,jj) = rkrgb(2,irgb) |
|---|
| 285 | zekr(ji,jj) = rkrgb(3,irgb) |
|---|
| 286 | END DO |
|---|
| 287 | END DO |
|---|
| 288 | ! |
|---|
| 289 | DO jj = 1, jpj |
|---|
| 290 | DO ji = 1, jpi |
|---|
| 291 | zc0 = rn_abs * EXP( - fse3t(ji,jj,1) * xsi0r ) |
|---|
| 292 | zc1 = zcoef * EXP( - fse3t(ji,jj,1) * zekb(ji,jj) ) |
|---|
| 293 | zc2 = zcoef * EXP( - fse3t(ji,jj,1) * zekg(ji,jj) ) |
|---|
| 294 | zc3 = zcoef * EXP( - fse3t(ji,jj,1) * zekr(ji,jj) ) |
|---|
| 295 | fraqsr_1lev(ji,jj) = 1.0 - ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,2) |
|---|
| 296 | END DO |
|---|
| 297 | END DO |
|---|
| 298 | ! |
|---|
| 299 | ENDIF |
|---|
| 300 | ! |
|---|
| 301 | ELSE !* Constant Chlorophyll |
|---|
| 302 | DO jk = 1, nksr |
|---|
| 303 | qsr_hc(:,:,jk) = etot3(:,:,jk) * qsr(:,:) |
|---|
| 304 | END DO |
|---|
| 305 | ! store attenuation coefficient of the first ocean level |
|---|
| 306 | IF( ln_qsr_ice ) THEN |
|---|
| 307 | fraqsr_1lev(:,:) = etot3(:,:,1) / r1_rau0_rcp |
|---|
| 308 | ENDIF |
|---|
| 309 | ENDIF |
|---|
| 310 | lspr = .false. |
|---|
| 311 | ENDIF |
|---|
| 312 | ! ! ------------------------- ! |
|---|
| 313 | IF( ln_qsr_2bd ) THEN ! 2 band light penetration ! |
|---|
| 314 | ! ! ------------------------- ! |
|---|
| 315 | ! |
|---|
| 316 | IF( lk_vvl ) THEN !* variable volume |
|---|
| 317 | zz0 = rn_abs * r1_rau0_rcp |
|---|
| 318 | zz1 = ( 1. - rn_abs ) * r1_rau0_rcp |
|---|
| 319 | DO jk = 1, nksr ! solar heat absorbed at T-point in the top 400m |
|---|
| 320 | DO jj = 1, jpj |
|---|
| 321 | DO ji = 1, jpi |
|---|
| 322 | zc0 = zz0 * EXP( -fsdepw(ji,jj,jk )*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk )*xsi1r ) |
|---|
| 323 | zc1 = zz0 * EXP( -fsdepw(ji,jj,jk+1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk+1)*xsi1r ) |
|---|
| 324 | qsr_hc(ji,jj,jk) = qsr(ji,jj) * ( zc0*tmask(ji,jj,jk) - zc1*tmask(ji,jj,jk+1) ) |
|---|
| 325 | END DO |
|---|
| 326 | END DO |
|---|
| 327 | END DO |
|---|
| 328 | ! clem: store attenuation coefficient of the first ocean level |
|---|
| 329 | IF ( ln_qsr_ice ) THEN |
|---|
| 330 | DO jj = 1, jpj |
|---|
| 331 | DO ji = 1, jpi |
|---|
| 332 | zc0 = zz0 * EXP( -fsdepw(ji,jj,1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,1)*xsi1r ) |
|---|
| 333 | zc1 = zz0 * EXP( -fsdepw(ji,jj,2)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,2)*xsi1r ) |
|---|
| 334 | fraqsr_1lev(ji,jj) = ( zc0*tmask(ji,jj,1) - zc1*tmask(ji,jj,2) ) / r1_rau0_rcp |
|---|
| 335 | END DO |
|---|
| 336 | END DO |
|---|
| 337 | ENDIF |
|---|
| 338 | ELSE !* constant volume: coef. computed one for all |
|---|
| 339 | DO jk = 1, nksr |
|---|
| 340 | DO jj = 2, jpjm1 |
|---|
| 341 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 342 | ! (ISF) no light penetration below the ice shelves |
|---|
| 343 | qsr_hc(ji,jj,jk) = etot3(ji,jj,jk) * qsr(ji,jj) * tmask(ji,jj,1) |
|---|
| 344 | END DO |
|---|
| 345 | END DO |
|---|
| 346 | END DO |
|---|
| 347 | ! clem: store attenuation coefficient of the first ocean level |
|---|
| 348 | IF ( ln_qsr_ice ) THEN |
|---|
| 349 | fraqsr_1lev(:,:) = etot3(:,:,1) / r1_rau0_rcp |
|---|
| 350 | ENDIF |
|---|
| 351 | ! |
|---|
| 352 | ENDIF |
|---|
| 353 | ! |
|---|
| 354 | ENDIF |
|---|
| 355 | ! |
|---|
| 356 | ! Add to the general trend |
|---|
| 357 | DO jk = 1, nksr |
|---|
| 358 | DO jj = 2, jpjm1 |
|---|
| 359 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 360 | z1_e3t = zfact / fse3t(ji,jj,jk) |
|---|
| 361 | tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t |
|---|
| 362 | END DO |
|---|
| 363 | END DO |
|---|
| 364 | END DO |
|---|
| 365 | ! |
|---|
| 366 | ENDIF |
|---|
| 367 | ! |
|---|
| 368 | IF( lrst_oce ) THEN ! Write in the ocean restart file |
|---|
| 369 | ! ******************************* |
|---|
| 370 | IF(lwp) WRITE(numout,*) |
|---|
| 371 | IF(lwp) WRITE(numout,*) 'qsr tracer content forcing field written in ocean restart file ', & |
|---|
| 372 | & 'at it= ', kt,' date= ', ndastp |
|---|
| 373 | IF(lwp) WRITE(numout,*) '~~~~' |
|---|
| 374 | IF( lwxios ) CALL iom_swap( wxios_context ) |
|---|
| 375 | CALL iom_rstput( kt, nitrst, numrow, 'qsr_hc_b', qsr_hc, lxios = lwxios ) |
|---|
| 376 | CALL iom_rstput( kt, nitrst, numrow, 'fraqsr_1lev', fraqsr_1lev, lxios = lwxios) ! default definition in sbcssm |
|---|
| 377 | IF( lwxios ) CALL iom_swap( cxios_context ) |
|---|
| 378 | ! |
|---|
| 379 | ENDIF |
|---|
| 380 | |
|---|
| 381 | IF( l_trdtra ) THEN ! qsr tracers trends saved for diagnostics |
|---|
| 382 | ztrdt(:,:,:) = tsa(:,:,:,jp_tem) - ztrdt(:,:,:) |
|---|
| 383 | CALL trd_tra( kt, 'TRA', jp_tem, jptra_qsr, ztrdt ) |
|---|
| 384 | CALL wrk_dealloc( jpi, jpj, jpk, ztrdt ) |
|---|
| 385 | ENDIF |
|---|
| 386 | ! ! print mean trends (used for debugging) |
|---|
| 387 | IF(ln_ctl) CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' qsr - Ta: ', mask1=tmask, clinfo3='tra-ta' ) |
|---|
| 388 | ! |
|---|
| 389 | CALL wrk_dealloc( jpi, jpj, zekb, zekg, zekr ) |
|---|
| 390 | CALL wrk_dealloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea, zchl3d ) |
|---|
| 391 | ! |
|---|
| 392 | IF( nn_timing == 1 ) CALL timing_stop('tra_qsr') |
|---|
| 393 | ! |
|---|
| 394 | END SUBROUTINE tra_qsr |
|---|
| 395 | |
|---|
| 396 | |
|---|
| 397 | SUBROUTINE tra_qsr_init |
|---|
| 398 | !!---------------------------------------------------------------------- |
|---|
| 399 | !! *** ROUTINE tra_qsr_init *** |
|---|
| 400 | !! |
|---|
| 401 | !! ** Purpose : Initialization for the penetrative solar radiation |
|---|
| 402 | !! |
|---|
| 403 | !! ** Method : The profile of solar radiation within the ocean is set |
|---|
| 404 | !! from two length scale of penetration (rn_si0,rn_si1) and a ratio |
|---|
| 405 | !! (rn_abs). These parameters are read in the namtra_qsr namelist. The |
|---|
| 406 | !! default values correspond to clear water (type I in Jerlov' |
|---|
| 407 | !! (1968) classification. |
|---|
| 408 | !! called by tra_qsr at the first timestep (nit000) |
|---|
| 409 | !! |
|---|
| 410 | !! ** Action : - initialize rn_si0, rn_si1 and rn_abs |
|---|
| 411 | !! |
|---|
| 412 | !! Reference : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp. |
|---|
| 413 | !!---------------------------------------------------------------------- |
|---|
| 414 | ! |
|---|
| 415 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 416 | INTEGER :: irgb, ierror, ioptio, nqsr ! local integer |
|---|
| 417 | INTEGER :: ios ! Local integer output status for namelist read |
|---|
| 418 | REAL(wp) :: zz0, zc0 , zc1, zcoef ! local scalars |
|---|
| 419 | REAL(wp) :: zz1, zc2 , zc3, zchl ! - - |
|---|
| 420 | REAL(wp), POINTER, DIMENSION(:,: ) :: zekb, zekg, zekr |
|---|
| 421 | REAL(wp), POINTER, DIMENSION(:,:,:) :: ze0, ze1, ze2, ze3, zea |
|---|
| 422 | ! |
|---|
| 423 | CHARACTER(len=100) :: cn_dir ! Root directory for location of ssr files |
|---|
| 424 | TYPE(FLD_N) :: sn_chl ! informations about the chlorofyl field to be read |
|---|
| 425 | !! |
|---|
| 426 | NAMELIST/namtra_qsr/ sn_chl, cn_dir, ln_traqsr, ln_qsr_rgb, ln_qsr_2bd, ln_qsr_bio, ln_qsr_ice, & |
|---|
| 427 | & nn_chldta, rn_abs, rn_si0, rn_si1, ln_qsr_sio |
|---|
| 428 | !!---------------------------------------------------------------------- |
|---|
| 429 | |
|---|
| 430 | ! |
|---|
| 431 | IF( nn_timing == 1 ) CALL timing_start('tra_qsr_init') |
|---|
| 432 | ! |
|---|
| 433 | CALL wrk_alloc( jpi, jpj, zekb, zekg, zekr ) |
|---|
| 434 | CALL wrk_alloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) |
|---|
| 435 | ! |
|---|
| 436 | ln_qsr_ice = .FALSE. |
|---|
| 437 | IF(lwm) THEN |
|---|
| 438 | REWIND( numnam_ref ) ! Namelist namtra_qsr in reference namelist : Ratio and length of penetration |
|---|
| 439 | READ ( numnam_ref, namtra_qsr, IOSTAT = ios, ERR = 901) |
|---|
| 440 | 901 CONTINUE |
|---|
| 441 | ENDIF |
|---|
| 442 | call mpp_bcast(ios) |
|---|
| 443 | IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_qsr in reference namelist', lwp ) |
|---|
| 444 | IF(lwm) THEN |
|---|
| 445 | REWIND( numnam_cfg ) ! Namelist namtra_qsr in configuration namelist : Ratio and length of penetration |
|---|
| 446 | READ ( numnam_cfg, namtra_qsr, IOSTAT = ios, ERR = 902 ) |
|---|
| 447 | 902 CONTINUE |
|---|
| 448 | ENDIF |
|---|
| 449 | call mpp_bcast(ios) |
|---|
| 450 | IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_qsr in configuration namelist', lwp ) |
|---|
| 451 | |
|---|
| 452 | IF(lwm) WRITE ( numond, namtra_qsr ) |
|---|
| 453 | ! |
|---|
| 454 | CALL qsr_namelist(sn_chl, cn_dir) |
|---|
| 455 | |
|---|
| 456 | IF(lwp) THEN ! control print |
|---|
| 457 | WRITE(numout,*) |
|---|
| 458 | WRITE(numout,*) 'tra_qsr_init : penetration of the surface solar radiation' |
|---|
| 459 | WRITE(numout,*) '~~~~~~~~~~~~' |
|---|
| 460 | WRITE(numout,*) ' Namelist namtra_qsr : set the parameter of penetration' |
|---|
| 461 | WRITE(numout,*) ' Light penetration (T) or not (F) ln_traqsr = ', ln_traqsr |
|---|
| 462 | WRITE(numout,*) ' RGB (Red-Green-Blue) light penetration ln_qsr_rgb = ', ln_qsr_rgb |
|---|
| 463 | WRITE(numout,*) ' 2 band light penetration ln_qsr_2bd = ', ln_qsr_2bd |
|---|
| 464 | WRITE(numout,*) ' bio-model light penetration ln_qsr_bio = ', ln_qsr_bio |
|---|
| 465 | WRITE(numout,*) ' light penetration for ice-model LIM3 ln_qsr_ice = ', ln_qsr_ice |
|---|
| 466 | WRITE(numout,*) ' RGB : Chl data (=1/2) or cst value (=0) nn_chldta = ', nn_chldta |
|---|
| 467 | WRITE(numout,*) ' RGB & 2 bands: fraction of light (rn_si1) rn_abs = ', rn_abs |
|---|
| 468 | WRITE(numout,*) ' RGB & 2 bands: shortess depth of extinction rn_si0 = ', rn_si0 |
|---|
| 469 | WRITE(numout,*) ' 2 bands: longest depth of extinction rn_si1 = ', rn_si1 |
|---|
| 470 | ENDIF |
|---|
| 471 | |
|---|
| 472 | IF( ln_traqsr ) THEN ! control consistency |
|---|
| 473 | ! |
|---|
| 474 | IF( .NOT.lk_qsr_bio .AND. ln_qsr_bio ) THEN |
|---|
| 475 | CALL ctl_warn( 'No bio model : force ln_qsr_bio = FALSE ' ) |
|---|
| 476 | ln_qsr_bio = .FALSE. |
|---|
| 477 | ENDIF |
|---|
| 478 | ! |
|---|
| 479 | ioptio = 0 ! Parameter control |
|---|
| 480 | IF( ln_qsr_rgb ) ioptio = ioptio + 1 |
|---|
| 481 | IF( ln_qsr_2bd ) ioptio = ioptio + 1 |
|---|
| 482 | IF( ln_qsr_bio ) ioptio = ioptio + 1 |
|---|
| 483 | ! |
|---|
| 484 | IF( ioptio /= 1 ) & |
|---|
| 485 | CALL ctl_stop( ' Choose ONE type of light penetration in namelist namtra_qsr', & |
|---|
| 486 | & ' 2 bands, 3 RGB bands or bio-model light penetration' ) |
|---|
| 487 | ! |
|---|
| 488 | IF( ln_qsr_rgb .AND. nn_chldta == 0 ) nqsr = 1 |
|---|
| 489 | IF( ln_qsr_rgb .AND. nn_chldta == 1 ) nqsr = 2 |
|---|
| 490 | IF( ln_qsr_rgb .AND. nn_chldta == 2 ) nqsr = 3 |
|---|
| 491 | IF( ln_qsr_2bd ) nqsr = 4 |
|---|
| 492 | IF( ln_qsr_bio ) nqsr = 5 |
|---|
| 493 | ! |
|---|
| 494 | IF(lwp) THEN ! Print the choice |
|---|
| 495 | WRITE(numout,*) |
|---|
| 496 | IF( nqsr == 1 ) WRITE(numout,*) ' R-G-B light penetration - Constant Chlorophyll' |
|---|
| 497 | IF( nqsr == 2 ) WRITE(numout,*) ' R-G-B light penetration - 2D Chl data ' |
|---|
| 498 | IF( nqsr == 3 ) WRITE(numout,*) ' R-G-B light penetration - 3D Chl data ' |
|---|
| 499 | IF( nqsr == 4 ) WRITE(numout,*) ' 2 bands light penetration' |
|---|
| 500 | IF( nqsr == 5 ) WRITE(numout,*) ' bio-model light penetration' |
|---|
| 501 | ENDIF |
|---|
| 502 | ! |
|---|
| 503 | ENDIF |
|---|
| 504 | ! ! ===================================== ! |
|---|
| 505 | IF( ln_traqsr ) THEN ! Initialisation of Light Penetration ! |
|---|
| 506 | ! ! ===================================== ! |
|---|
| 507 | ! |
|---|
| 508 | xsi0r = 1.e0 / rn_si0 |
|---|
| 509 | xsi1r = 1.e0 / rn_si1 |
|---|
| 510 | ! ! ---------------------------------- ! |
|---|
| 511 | IF( ln_qsr_rgb ) THEN ! Red-Green-Blue light penetration ! |
|---|
| 512 | ! ! ---------------------------------- ! |
|---|
| 513 | ! |
|---|
| 514 | CALL trc_oce_rgb( rkrgb ) !* tabulated attenuation coef. |
|---|
| 515 | ! |
|---|
| 516 | ! !* level of light extinction |
|---|
| 517 | IF( ln_sco ) THEN ; nksr = jpkm1 |
|---|
| 518 | ELSE ; nksr = trc_oce_ext_lev( r_si2, 0.33e2 ) |
|---|
| 519 | ENDIF |
|---|
| 520 | |
|---|
| 521 | IF(lwp) WRITE(numout,*) ' level of light extinction = ', nksr, ' ref depth = ', gdepw_1d(nksr+1), ' m' |
|---|
| 522 | ! |
|---|
| 523 | IF( nn_chldta == 1 .OR. nn_chldta == 2 ) THEN !* Chl data : set sf_chl structure |
|---|
| 524 | IF(lwp) WRITE(numout,*) |
|---|
| 525 | IF(lwp) WRITE(numout,*) ' Chlorophyll read in a file' |
|---|
| 526 | ALLOCATE( sf_chl(1), STAT=ierror ) |
|---|
| 527 | IF( ierror > 0 ) THEN |
|---|
| 528 | CALL ctl_stop( 'tra_qsr_init: unable to allocate sf_chl structure' ) ; RETURN |
|---|
| 529 | ENDIF |
|---|
| 530 | ALLOCATE( sf_chl(1)%fnow(jpi,jpj,1) ) |
|---|
| 531 | IF( sn_chl%ln_tint )ALLOCATE( sf_chl(1)%fdta(jpi,jpj,1,2) ) |
|---|
| 532 | ! ! fill sf_chl with sn_chl and control print |
|---|
| 533 | CALL fld_fill( sf_chl, (/ sn_chl /), cn_dir, 'tra_qsr_init', & |
|---|
| 534 | & 'Solar penetration function of read chlorophyll', 'namtra_qsr' ) |
|---|
| 535 | ! |
|---|
| 536 | ELSE !* constant Chl : compute once for all the distribution of light (etot3) |
|---|
| 537 | IF(lwp) WRITE(numout,*) |
|---|
| 538 | IF(lwp) WRITE(numout,*) ' Constant Chlorophyll concentration = 0.05' |
|---|
| 539 | IF( lk_vvl ) THEN ! variable volume |
|---|
| 540 | IF(lwp) WRITE(numout,*) ' key_vvl: light distribution will be computed at each time step' |
|---|
| 541 | ELSE ! constant volume: computes one for all |
|---|
| 542 | IF(lwp) WRITE(numout,*) ' fixed volume: light distribution computed one for all' |
|---|
| 543 | ! |
|---|
| 544 | zchl = 0.05 ! constant chlorophyll |
|---|
| 545 | irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 ) |
|---|
| 546 | zekb(:,:) = rkrgb(1,irgb) ! Separation in R-G-B depending of the chlorophyll |
|---|
| 547 | zekg(:,:) = rkrgb(2,irgb) |
|---|
| 548 | zekr(:,:) = rkrgb(3,irgb) |
|---|
| 549 | ! |
|---|
| 550 | zcoef = ( 1. - rn_abs ) / 3.e0 ! equi-partition in R-G-B |
|---|
| 551 | ze0(:,:,1) = rn_abs |
|---|
| 552 | ze1(:,:,1) = zcoef |
|---|
| 553 | ze2(:,:,1) = zcoef |
|---|
| 554 | ze3(:,:,1) = zcoef |
|---|
| 555 | zea(:,:,1) = tmask(:,:,1) ! = ( ze0+ze1+z2+ze3 ) * tmask |
|---|
| 556 | |
|---|
| 557 | DO jk = 2, nksr+1 |
|---|
| 558 | !CDIR NOVERRCHK |
|---|
| 559 | DO jj = 1, jpj |
|---|
| 560 | !CDIR NOVERRCHK |
|---|
| 561 | DO ji = 1, jpi |
|---|
| 562 | zc0 = ze0(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * xsi0r ) |
|---|
| 563 | zc1 = ze1(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * zekb(ji,jj) ) |
|---|
| 564 | zc2 = ze2(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * zekg(ji,jj) ) |
|---|
| 565 | zc3 = ze3(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * zekr(ji,jj) ) |
|---|
| 566 | ze0(ji,jj,jk) = zc0 |
|---|
| 567 | ze1(ji,jj,jk) = zc1 |
|---|
| 568 | ze2(ji,jj,jk) = zc2 |
|---|
| 569 | ze3(ji,jj,jk) = zc3 |
|---|
| 570 | zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk) |
|---|
| 571 | END DO |
|---|
| 572 | END DO |
|---|
| 573 | END DO |
|---|
| 574 | ! |
|---|
| 575 | DO jk = 1, nksr |
|---|
| 576 | ! (ISF) no light penetration below the ice shelves |
|---|
| 577 | etot3(:,:,jk) = r1_rau0_rcp * ( zea(:,:,jk) - zea(:,:,jk+1) ) * tmask(:,:,1) |
|---|
| 578 | END DO |
|---|
| 579 | etot3(:,:,nksr+1:jpk) = 0.e0 ! below 400m set to zero |
|---|
| 580 | ENDIF |
|---|
| 581 | ENDIF |
|---|
| 582 | ! |
|---|
| 583 | ENDIF |
|---|
| 584 | ! ! ---------------------------------- ! |
|---|
| 585 | IF( ln_qsr_2bd ) THEN ! 2 bands light penetration ! |
|---|
| 586 | ! ! ---------------------------------- ! |
|---|
| 587 | ! |
|---|
| 588 | ! ! level of light extinction |
|---|
| 589 | nksr = trc_oce_ext_lev( rn_si1, 1.e2 ) |
|---|
| 590 | IF(lwp) THEN |
|---|
| 591 | WRITE(numout,*) |
|---|
| 592 | IF(lwp) WRITE(numout,*) ' level of light extinction = ', nksr, ' ref depth = ', gdepw_1d(nksr+1), ' m' |
|---|
| 593 | ENDIF |
|---|
| 594 | ! |
|---|
| 595 | IF( lk_vvl ) THEN ! variable volume |
|---|
| 596 | IF(lwp) WRITE(numout,*) ' key_vvl: light distribution will be computed at each time step' |
|---|
| 597 | ELSE ! constant volume: computes one for all |
|---|
| 598 | zz0 = rn_abs * r1_rau0_rcp |
|---|
| 599 | zz1 = ( 1. - rn_abs ) * r1_rau0_rcp |
|---|
| 600 | DO jk = 1, nksr !* solar heat absorbed at T-point computed once for all |
|---|
| 601 | DO jj = 1, jpj ! top 400 meters |
|---|
| 602 | DO ji = 1, jpi |
|---|
| 603 | zc0 = zz0 * EXP( -fsdepw(ji,jj,jk )*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk )*xsi1r ) |
|---|
| 604 | zc1 = zz0 * EXP( -fsdepw(ji,jj,jk+1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk+1)*xsi1r ) |
|---|
| 605 | etot3(ji,jj,jk) = ( zc0 * tmask(ji,jj,jk) - zc1 * tmask(ji,jj,jk+1) ) * tmask(ji,jj,1) |
|---|
| 606 | END DO |
|---|
| 607 | END DO |
|---|
| 608 | END DO |
|---|
| 609 | etot3(:,:,nksr+1:jpk) = 0.e0 ! below 400m set to zero |
|---|
| 610 | ! |
|---|
| 611 | ENDIF |
|---|
| 612 | ENDIF |
|---|
| 613 | ! ! ===================================== ! |
|---|
| 614 | ELSE ! No light penetration ! |
|---|
| 615 | ! ! ===================================== ! |
|---|
| 616 | IF(lwp) THEN |
|---|
| 617 | WRITE(numout,*) |
|---|
| 618 | WRITE(numout,*) 'tra_qsr_init : NO solar flux penetration' |
|---|
| 619 | WRITE(numout,*) '~~~~~~~~~~~~' |
|---|
| 620 | ENDIF |
|---|
| 621 | ENDIF |
|---|
| 622 | ! |
|---|
| 623 | ! initialisation of fraqsr_1lev used in sbcssm |
|---|
| 624 | IF( iom_varid( numror, 'fraqsr_1lev', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 625 | CALL iom_get( numror, jpdom_autoglo, 'fraqsr_1lev' , fraqsr_1lev, lrxios = lxios_read ) |
|---|
| 626 | ELSE |
|---|
| 627 | fraqsr_1lev(:,:) = 1._wp ! default definition |
|---|
| 628 | ENDIF |
|---|
| 629 | ! |
|---|
| 630 | CALL wrk_dealloc( jpi, jpj, zekb, zekg, zekr ) |
|---|
| 631 | CALL wrk_dealloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) |
|---|
| 632 | ! |
|---|
| 633 | IF( nn_timing == 1 ) CALL timing_stop('tra_qsr_init') |
|---|
| 634 | ! |
|---|
| 635 | END SUBROUTINE tra_qsr_init |
|---|
| 636 | |
|---|
| 637 | SUBROUTINE qsr_namelist(sd_chl, cd_dir) |
|---|
| 638 | !!--------------------------------------------------------------------- |
|---|
| 639 | !! *** ROUTINE qsr_namelist *** |
|---|
| 640 | !! |
|---|
| 641 | !! ** Purpose : Broadkast namelist variables read by procesor lwm |
|---|
| 642 | !! |
|---|
| 643 | !! ** Method : use lib_mpp |
|---|
| 644 | !!---------------------------------------------------------------------- |
|---|
| 645 | CHARACTER(len=100) :: cd_dir ! Root directory for location of ssr files |
|---|
| 646 | TYPE(FLD_N) :: sd_chl ! informations about the chlorofyl field to be read |
|---|
| 647 | #if defined key_mpp_mpi |
|---|
| 648 | CALL fld_n_bcast(sd_chl) |
|---|
| 649 | CALL mpp_bcast(cd_dir, 100) |
|---|
| 650 | CALL mpp_bcast(ln_traqsr) |
|---|
| 651 | CALL mpp_bcast(ln_qsr_rgb) |
|---|
| 652 | CALL mpp_bcast(ln_qsr_2bd) |
|---|
| 653 | CALL mpp_bcast(ln_qsr_bio) |
|---|
| 654 | CALL mpp_bcast(ln_qsr_ice) |
|---|
| 655 | CALL mpp_bcast(nn_chldta) |
|---|
| 656 | CALL mpp_bcast(rn_abs) |
|---|
| 657 | CALL mpp_bcast(rn_si0) |
|---|
| 658 | CALL mpp_bcast(rn_si1) |
|---|
| 659 | CALL mpp_bcast(ln_qsr_sio) |
|---|
| 660 | #endif |
|---|
| 661 | END SUBROUTINE qsr_namelist |
|---|
| 662 | |
|---|
| 663 | !!====================================================================== |
|---|
| 664 | END MODULE traqsr |
|---|
