| 1 | MODULE zdftmx |
|---|
| 2 | !!======================================================================== |
|---|
| 3 | !! *** MODULE zdftmx *** |
|---|
| 4 | !! Ocean physics: vertical tidal mixing coefficient |
|---|
| 5 | !!======================================================================== |
|---|
| 6 | !! History : 1.0 ! 2004-04 (L. Bessieres, G. Madec) Original code |
|---|
| 7 | !! - ! 2006-08 (A. Koch-Larrouy) Indonesian strait |
|---|
| 8 | !! 3.3 ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase |
|---|
| 9 | !!---------------------------------------------------------------------- |
|---|
| 10 | #if defined key_zdftmx || defined key_esopa |
|---|
| 11 | !!---------------------------------------------------------------------- |
|---|
| 12 | !! 'key_zdftmx' Tidal vertical mixing |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | !! zdf_tmx : global momentum & tracer Kz with tidal induced Kz |
|---|
| 15 | !! tmx_itf : Indonesian momentum & tracer Kz with tidal induced Kz |
|---|
| 16 | !!---------------------------------------------------------------------- |
|---|
| 17 | USE oce ! ocean dynamics and tracers variables |
|---|
| 18 | USE dom_oce ! ocean space and time domain variables |
|---|
| 19 | USE zdf_oce ! ocean vertical physics variables |
|---|
| 20 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 21 | USE eosbn2 ! ocean equation of state |
|---|
| 22 | USE phycst ! physical constants |
|---|
| 23 | USE prtctl ! Print control |
|---|
| 24 | USE in_out_manager ! I/O manager |
|---|
| 25 | USE iom ! I/O Manager |
|---|
| 26 | USE lib_mpp ! MPP library |
|---|
| 27 | USE wrk_nemo ! work arrays |
|---|
| 28 | USE timing ! Timing |
|---|
| 29 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
|---|
| 30 | |
|---|
| 31 | IMPLICIT NONE |
|---|
| 32 | PRIVATE |
|---|
| 33 | |
|---|
| 34 | PUBLIC zdf_tmx ! called in step module |
|---|
| 35 | PUBLIC zdf_tmx_init ! called in opa module |
|---|
| 36 | PUBLIC zdf_tmx_alloc ! called in nemogcm module |
|---|
| 37 | PRIVATE tmx_namelist |
|---|
| 38 | |
|---|
| 39 | LOGICAL, PUBLIC, PARAMETER :: lk_zdftmx = .TRUE. !: tidal mixing flag |
|---|
| 40 | |
|---|
| 41 | ! !!* Namelist namzdf_tmx : tidal mixing * |
|---|
| 42 | REAL(wp) :: rn_htmx ! vertical decay scale for turbulence (meters) |
|---|
| 43 | REAL(wp) :: rn_n2min ! threshold of the Brunt-Vaisala frequency (s-1) |
|---|
| 44 | REAL(wp) :: rn_tfe ! tidal dissipation efficiency (St Laurent et al. 2002) |
|---|
| 45 | REAL(wp) :: rn_me ! mixing efficiency (Osborn 1980) |
|---|
| 46 | LOGICAL :: ln_tmx_itf ! Indonesian Through Flow (ITF): Koch-Larrouy et al. (2007) parameterization |
|---|
| 47 | REAL(wp) :: rn_tfe_itf ! ITF tidal dissipation efficiency (St Laurent et al. 2002) |
|---|
| 48 | |
|---|
| 49 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: en_tmx ! energy available for tidal mixing (W/m2) |
|---|
| 50 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: mask_itf ! mask to use over Indonesian area |
|---|
| 51 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: az_tmx ! coefficient used to evaluate the tidal induced Kz |
|---|
| 52 | |
|---|
| 53 | !! * Substitutions |
|---|
| 54 | # include "domzgr_substitute.h90" |
|---|
| 55 | # include "vectopt_loop_substitute.h90" |
|---|
| 56 | !!---------------------------------------------------------------------- |
|---|
| 57 | !! NEMO/OPA 4.0 , NEMO Consortium (2011) |
|---|
| 58 | !! $Id$ |
|---|
| 59 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 60 | !!---------------------------------------------------------------------- |
|---|
| 61 | CONTAINS |
|---|
| 62 | |
|---|
| 63 | INTEGER FUNCTION zdf_tmx_alloc() |
|---|
| 64 | !!---------------------------------------------------------------------- |
|---|
| 65 | !! *** FUNCTION zdf_tmx_alloc *** |
|---|
| 66 | !!---------------------------------------------------------------------- |
|---|
| 67 | ALLOCATE(en_tmx(jpi,jpj), mask_itf(jpi,jpj), az_tmx(jpi,jpj,jpk), STAT=zdf_tmx_alloc ) |
|---|
| 68 | ! |
|---|
| 69 | IF( lk_mpp ) CALL mpp_sum ( zdf_tmx_alloc ) |
|---|
| 70 | IF( zdf_tmx_alloc /= 0 ) CALL ctl_warn('zdf_tmx_alloc: failed to allocate arrays') |
|---|
| 71 | END FUNCTION zdf_tmx_alloc |
|---|
| 72 | |
|---|
| 73 | |
|---|
| 74 | SUBROUTINE zdf_tmx( kt ) |
|---|
| 75 | !!---------------------------------------------------------------------- |
|---|
| 76 | !! *** ROUTINE zdf_tmx *** |
|---|
| 77 | !! |
|---|
| 78 | !! ** Purpose : add to the vertical mixing coefficients the effect of |
|---|
| 79 | !! tidal mixing (Simmons et al 2004). |
|---|
| 80 | !! |
|---|
| 81 | !! ** Method : - tidal-induced vertical mixing is given by: |
|---|
| 82 | !! Kz_tides = az_tmx / max( rn_n2min, N^2 ) |
|---|
| 83 | !! where az_tmx is a coefficient that specified the 3D space |
|---|
| 84 | !! distribution of the faction of tidal energy taht is used |
|---|
| 85 | !! for mixing. Its expression is set in zdf_tmx_init routine, |
|---|
| 86 | !! following Simmons et al. 2004. |
|---|
| 87 | !! NB: a specific bounding procedure is performed on av_tide |
|---|
| 88 | !! so that the input tidal energy is actually almost used. The |
|---|
| 89 | !! basic maximum value is 60 cm2/s, but values of 300 cm2/s |
|---|
| 90 | !! can be reached in area where bottom stratification is too |
|---|
| 91 | !! weak. |
|---|
| 92 | !! |
|---|
| 93 | !! - update av_tide in the Indonesian Through Flow area |
|---|
| 94 | !! following Koch-Larrouy et al. (2007) parameterisation |
|---|
| 95 | !! (see tmx_itf routine). |
|---|
| 96 | !! |
|---|
| 97 | !! - update the model vertical eddy viscosity and diffusivity: |
|---|
| 98 | !! avt = avt + av_tides |
|---|
| 99 | !! avm = avm + av_tides |
|---|
| 100 | !! avmu = avmu + mi(av_tides) |
|---|
| 101 | !! avmv = avmv + mj(av_tides) |
|---|
| 102 | !! |
|---|
| 103 | !! ** Action : avt, avm, avmu, avmv increased by tidal mixing |
|---|
| 104 | !! |
|---|
| 105 | !! References : Simmons et al. 2004, Ocean Modelling, 6, 3-4, 245-263. |
|---|
| 106 | !! Koch-Larrouy et al. 2007, GRL. |
|---|
| 107 | !!---------------------------------------------------------------------- |
|---|
| 108 | USE oce, zav_tide => ua ! use ua as workspace |
|---|
| 109 | !! |
|---|
| 110 | INTEGER, INTENT(in) :: kt ! ocean time-step |
|---|
| 111 | !! |
|---|
| 112 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 113 | REAL(wp) :: ztpc ! scalar workspace |
|---|
| 114 | REAL(wp), POINTER, DIMENSION(:,:) :: zkz |
|---|
| 115 | !!---------------------------------------------------------------------- |
|---|
| 116 | ! |
|---|
| 117 | IF( nn_timing == 1 ) CALL timing_start('zdf_tmx') |
|---|
| 118 | ! |
|---|
| 119 | CALL wrk_alloc( jpi,jpj, zkz ) |
|---|
| 120 | |
|---|
| 121 | ! ! ----------------------- ! |
|---|
| 122 | ! ! Standard tidal mixing ! (compute zav_tide) |
|---|
| 123 | ! ! ----------------------- ! |
|---|
| 124 | ! !* First estimation (with n2 bound by rn_n2min) bounded by 60 cm2/s |
|---|
| 125 | zav_tide(:,:,:) = MIN( 60.e-4, az_tmx(:,:,:) / MAX( rn_n2min, rn2(:,:,:) ) ) |
|---|
| 126 | |
|---|
| 127 | zkz(:,:) = 0.e0 !* Associated potential energy consummed over the whole water column |
|---|
| 128 | DO jk = 2, jpkm1 |
|---|
| 129 | zkz(:,:) = zkz(:,:) + fse3w(:,:,jk) * MAX( 0.e0, rn2(:,:,jk) ) * rau0 * zav_tide(:,:,jk) * wmask(:,:,jk) |
|---|
| 130 | END DO |
|---|
| 131 | |
|---|
| 132 | DO jj = 1, jpj !* Here zkz should be equal to en_tmx ==> multiply by en_tmx/zkz to recover en_tmx |
|---|
| 133 | DO ji = 1, jpi |
|---|
| 134 | IF( zkz(ji,jj) /= 0.e0 ) zkz(ji,jj) = en_tmx(ji,jj) / zkz(ji,jj) |
|---|
| 135 | END DO |
|---|
| 136 | END DO |
|---|
| 137 | |
|---|
| 138 | DO jk = 2, jpkm1 !* Mutiply by zkz to recover en_tmx, BUT bound by 30/6 ==> zav_tide bound by 300 cm2/s |
|---|
| 139 | DO jj = 1, jpj !* Here zkz should be equal to en_tmx ==> multiply by en_tmx/zkz to recover en_tmx |
|---|
| 140 | DO ji = 1, jpi |
|---|
| 141 | zav_tide(ji,jj,jk) = zav_tide(ji,jj,jk) * MIN( zkz(ji,jj), 30./6. ) * wmask(ji,jj,jk) !kz max = 300 cm2/s |
|---|
| 142 | END DO |
|---|
| 143 | END DO |
|---|
| 144 | END DO |
|---|
| 145 | |
|---|
| 146 | IF( kt == nit000 ) THEN !* check at first time-step: diagnose the energy consumed by zav_tide |
|---|
| 147 | ztpc = 0.e0 |
|---|
| 148 | DO jk= 1, jpk |
|---|
| 149 | DO jj= 1, jpj |
|---|
| 150 | DO ji= 1, jpi |
|---|
| 151 | ztpc = ztpc + fse3w(ji,jj,jk) * e1t(ji,jj) * e2t(ji,jj) & |
|---|
| 152 | & * MAX( 0.e0, rn2(ji,jj,jk) ) * zav_tide(ji,jj,jk) * tmask(ji,jj,jk) * tmask_i(ji,jj) |
|---|
| 153 | END DO |
|---|
| 154 | END DO |
|---|
| 155 | END DO |
|---|
| 156 | ztpc= rau0 / ( rn_tfe * rn_me ) * ztpc |
|---|
| 157 | IF(lwp) WRITE(numout,*) |
|---|
| 158 | IF(lwp) WRITE(numout,*) ' N Total power consumption by av_tide : ztpc = ', ztpc * 1.e-12 ,'TW' |
|---|
| 159 | ENDIF |
|---|
| 160 | |
|---|
| 161 | ! ! ----------------------- ! |
|---|
| 162 | ! ! ITF tidal mixing ! (update zav_tide) |
|---|
| 163 | ! ! ----------------------- ! |
|---|
| 164 | IF( ln_tmx_itf ) CALL tmx_itf( kt, zav_tide ) |
|---|
| 165 | |
|---|
| 166 | ! ! ----------------------- ! |
|---|
| 167 | ! ! Update mixing coefs ! |
|---|
| 168 | ! ! ----------------------- ! |
|---|
| 169 | DO jk = 2, jpkm1 !* update momentum & tracer diffusivity with tidal mixing |
|---|
| 170 | DO jj = 1, jpj !* Here zkz should be equal to en_tmx ==> multiply by en_tmx/zkz to recover en_tmx |
|---|
| 171 | DO ji = 1, jpi |
|---|
| 172 | avt(ji,jj,jk) = avt(ji,jj,jk) + zav_tide(ji,jj,jk) * wmask(ji,jj,jk) |
|---|
| 173 | avm(ji,jj,jk) = avm(ji,jj,jk) + zav_tide(ji,jj,jk) * wmask(ji,jj,jk) |
|---|
| 174 | END DO |
|---|
| 175 | END DO |
|---|
| 176 | END DO |
|---|
| 177 | |
|---|
| 178 | DO jk = 2, jpkm1 !* update momentum & tracer diffusivity with tidal mixing |
|---|
| 179 | DO jj = 2, jpjm1 |
|---|
| 180 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 181 | avmu(ji,jj,jk) = avmu(ji,jj,jk) + 0.5 * ( zav_tide(ji,jj,jk) + zav_tide(ji+1,jj ,jk) ) * wumask(ji,jj,jk) |
|---|
| 182 | avmv(ji,jj,jk) = avmv(ji,jj,jk) + 0.5 * ( zav_tide(ji,jj,jk) + zav_tide(ji ,jj+1,jk) ) * wvmask(ji,jj,jk) |
|---|
| 183 | END DO |
|---|
| 184 | END DO |
|---|
| 185 | END DO |
|---|
| 186 | CALL lbc_lnk( avmu, 'U', 1. ) ; CALL lbc_lnk( avmv, 'V', 1. ) ! lateral boundary condition |
|---|
| 187 | |
|---|
| 188 | ! !* output tidal mixing coefficient |
|---|
| 189 | CALL iom_put( "av_tide", zav_tide ) |
|---|
| 190 | |
|---|
| 191 | IF(ln_ctl) CALL prt_ctl(tab3d_1=zav_tide , clinfo1=' tmx - av_tide: ', tab3d_2=avt, clinfo2=' avt: ', ovlap=1, kdim=jpk) |
|---|
| 192 | ! |
|---|
| 193 | CALL wrk_dealloc( jpi,jpj, zkz ) |
|---|
| 194 | ! |
|---|
| 195 | IF( nn_timing == 1 ) CALL timing_stop('zdf_tmx') |
|---|
| 196 | ! |
|---|
| 197 | END SUBROUTINE zdf_tmx |
|---|
| 198 | |
|---|
| 199 | |
|---|
| 200 | SUBROUTINE tmx_itf( kt, pav ) |
|---|
| 201 | !!---------------------------------------------------------------------- |
|---|
| 202 | !! *** ROUTINE tmx_itf *** |
|---|
| 203 | !! |
|---|
| 204 | !! ** Purpose : modify the vertical eddy diffusivity coefficients |
|---|
| 205 | !! (pav) in the Indonesian Through Flow area (ITF). |
|---|
| 206 | !! |
|---|
| 207 | !! ** Method : - Following Koch-Larrouy et al. (2007), in the ITF defined |
|---|
| 208 | !! by msk_itf (read in a file, see tmx_init), the tidal |
|---|
| 209 | !! mixing coefficient is computed with : |
|---|
| 210 | !! * q=1 (i.e. all the tidal energy remains trapped in |
|---|
| 211 | !! the area and thus is used for mixing) |
|---|
| 212 | !! * the vertical distribution of the tifal energy is a |
|---|
| 213 | !! proportional to N above the thermocline (d(N^2)/dz > 0) |
|---|
| 214 | !! and to N^2 below the thermocline (d(N^2)/dz < 0) |
|---|
| 215 | !! |
|---|
| 216 | !! ** Action : av_tide updated in the ITF area (msk_itf) |
|---|
| 217 | !! |
|---|
| 218 | !! References : Koch-Larrouy et al. 2007, GRL |
|---|
| 219 | !!---------------------------------------------------------------------- |
|---|
| 220 | INTEGER , INTENT(in ) :: kt ! ocean time-step |
|---|
| 221 | REAL(wp), INTENT(inout), DIMENSION(jpi,jpj,jpk) :: pav ! Tidal mixing coef. |
|---|
| 222 | !! |
|---|
| 223 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 224 | REAL(wp) :: zcoef, ztpc ! temporary scalar |
|---|
| 225 | REAL(wp), DIMENSION(:,:) , POINTER :: zkz ! 2D workspace |
|---|
| 226 | REAL(wp), DIMENSION(:,:) , POINTER :: zsum1 , zsum2 , zsum ! - - |
|---|
| 227 | REAL(wp), DIMENSION(:,:,:), POINTER :: zempba_3d_1, zempba_3d_2 ! 3D workspace |
|---|
| 228 | REAL(wp), DIMENSION(:,:,:), POINTER :: zempba_3d , zdn2dz ! - - |
|---|
| 229 | REAL(wp), DIMENSION(:,:,:), POINTER :: zavt_itf ! - - |
|---|
| 230 | !!---------------------------------------------------------------------- |
|---|
| 231 | ! |
|---|
| 232 | IF( nn_timing == 1 ) CALL timing_start('tmx_itf') |
|---|
| 233 | ! |
|---|
| 234 | CALL wrk_alloc( jpi,jpj, zkz, zsum1 , zsum2 , zsum ) |
|---|
| 235 | CALL wrk_alloc( jpi,jpj,jpk, zempba_3d_1, zempba_3d_2, zempba_3d, zdn2dz, zavt_itf ) |
|---|
| 236 | |
|---|
| 237 | ! ! compute the form function using N2 at each time step |
|---|
| 238 | zempba_3d_1(:,:,jpk) = 0.e0 |
|---|
| 239 | zempba_3d_2(:,:,jpk) = 0.e0 |
|---|
| 240 | DO jk = 1, jpkm1 |
|---|
| 241 | zdn2dz (:,:,jk) = rn2(:,:,jk) - rn2(:,:,jk+1) ! Vertical profile of dN2/dz |
|---|
| 242 | !CDIR NOVERRCHK |
|---|
| 243 | zempba_3d_1(:,:,jk) = SQRT( MAX( 0.e0, rn2(:,:,jk) ) ) ! - - of N |
|---|
| 244 | zempba_3d_2(:,:,jk) = MAX( 0.e0, rn2(:,:,jk) ) ! - - of N^2 |
|---|
| 245 | END DO |
|---|
| 246 | ! |
|---|
| 247 | zsum (:,:) = 0.e0 |
|---|
| 248 | zsum1(:,:) = 0.e0 |
|---|
| 249 | zsum2(:,:) = 0.e0 |
|---|
| 250 | DO jk= 2, jpk |
|---|
| 251 | zsum1(:,:) = zsum1(:,:) + zempba_3d_1(:,:,jk) * fse3w(:,:,jk) * tmask(:,:,jk) * tmask(:,:,jk-1) |
|---|
| 252 | zsum2(:,:) = zsum2(:,:) + zempba_3d_2(:,:,jk) * fse3w(:,:,jk) * tmask(:,:,jk) * tmask(:,:,jk-1) |
|---|
| 253 | END DO |
|---|
| 254 | DO jj = 1, jpj |
|---|
| 255 | DO ji = 1, jpi |
|---|
| 256 | IF( zsum1(ji,jj) /= 0.e0 ) zsum1(ji,jj) = 1.e0 / zsum1(ji,jj) |
|---|
| 257 | IF( zsum2(ji,jj) /= 0.e0 ) zsum2(ji,jj) = 1.e0 / zsum2(ji,jj) |
|---|
| 258 | END DO |
|---|
| 259 | END DO |
|---|
| 260 | |
|---|
| 261 | DO jk= 1, jpk |
|---|
| 262 | DO jj = 1, jpj |
|---|
| 263 | DO ji = 1, jpi |
|---|
| 264 | zcoef = 0.5 - SIGN( 0.5, zdn2dz(ji,jj,jk) ) ! =0 if dN2/dz > 0, =1 otherwise |
|---|
| 265 | ztpc = zempba_3d_1(ji,jj,jk) * zsum1(ji,jj) * zcoef & |
|---|
| 266 | & + zempba_3d_2(ji,jj,jk) * zsum2(ji,jj) * ( 1. - zcoef ) |
|---|
| 267 | ! |
|---|
| 268 | zempba_3d(ji,jj,jk) = ztpc |
|---|
| 269 | zsum (ji,jj) = zsum(ji,jj) + ztpc * fse3w(ji,jj,jk) |
|---|
| 270 | END DO |
|---|
| 271 | END DO |
|---|
| 272 | END DO |
|---|
| 273 | DO jj = 1, jpj |
|---|
| 274 | DO ji = 1, jpi |
|---|
| 275 | IF( zsum(ji,jj) > 0.e0 ) zsum(ji,jj) = 1.e0 / zsum(ji,jj) |
|---|
| 276 | END DO |
|---|
| 277 | END DO |
|---|
| 278 | |
|---|
| 279 | ! ! first estimation bounded by 10 cm2/s (with n2 bounded by rn_n2min) |
|---|
| 280 | zcoef = rn_tfe_itf / ( rn_tfe * rau0 ) |
|---|
| 281 | DO jk = 1, jpk |
|---|
| 282 | zavt_itf(:,:,jk) = MIN( 10.e-4, zcoef * en_tmx(:,:) * zsum(:,:) * zempba_3d(:,:,jk) & |
|---|
| 283 | & / MAX( rn_n2min, rn2(:,:,jk) ) * tmask(:,:,jk) ) |
|---|
| 284 | END DO |
|---|
| 285 | |
|---|
| 286 | zkz(:,:) = 0.e0 ! Associated potential energy consummed over the whole water column |
|---|
| 287 | DO jk = 2, jpkm1 |
|---|
| 288 | zkz(:,:) = zkz(:,:) + fse3w(:,:,jk) * MAX( 0.e0, rn2(:,:,jk) ) * rau0 * zavt_itf(:,:,jk) * tmask(:,:,jk) * tmask(:,:,jk-1) |
|---|
| 289 | END DO |
|---|
| 290 | |
|---|
| 291 | DO jj = 1, jpj ! Here zkz should be equal to en_tmx ==> multiply by en_tmx/zkz to recover en_tmx |
|---|
| 292 | DO ji = 1, jpi |
|---|
| 293 | IF( zkz(ji,jj) /= 0.e0 ) zkz(ji,jj) = en_tmx(ji,jj) * rn_tfe_itf / rn_tfe / zkz(ji,jj) |
|---|
| 294 | END DO |
|---|
| 295 | END DO |
|---|
| 296 | |
|---|
| 297 | DO jk = 2, jpkm1 ! Mutiply by zkz to recover en_tmx, BUT bound by 30/6 ==> zavt_itf bound by 300 cm2/s |
|---|
| 298 | zavt_itf(:,:,jk) = zavt_itf(:,:,jk) * MIN( zkz(:,:), 120./10. ) * tmask(:,:,jk) * tmask(:,:,jk-1) ! kz max = 120 cm2/s |
|---|
| 299 | END DO |
|---|
| 300 | |
|---|
| 301 | IF( kt == nit000 ) THEN ! diagnose the nergy consumed by zavt_itf |
|---|
| 302 | ztpc = 0.e0 |
|---|
| 303 | DO jk= 1, jpk |
|---|
| 304 | DO jj= 1, jpj |
|---|
| 305 | DO ji= 1, jpi |
|---|
| 306 | ztpc = ztpc + e1t(ji,jj) * e2t(ji,jj) * fse3w(ji,jj,jk) * MAX( 0.e0, rn2(ji,jj,jk) ) & |
|---|
| 307 | & * zavt_itf(ji,jj,jk) * tmask(ji,jj,jk) * tmask_i(ji,jj) |
|---|
| 308 | END DO |
|---|
| 309 | END DO |
|---|
| 310 | END DO |
|---|
| 311 | ztpc= rau0 * ztpc / ( rn_me * rn_tfe_itf ) |
|---|
| 312 | IF(lwp) WRITE(numout,*) ' N Total power consumption by zavt_itf: ztpc = ', ztpc * 1.e-12 ,'TW' |
|---|
| 313 | ENDIF |
|---|
| 314 | |
|---|
| 315 | ! ! Update pav with the ITF mixing coefficient |
|---|
| 316 | DO jk = 2, jpkm1 |
|---|
| 317 | pav(:,:,jk) = pav (:,:,jk) * ( 1.e0 - mask_itf(:,:) ) & |
|---|
| 318 | & + zavt_itf(:,:,jk) * mask_itf(:,:) |
|---|
| 319 | END DO |
|---|
| 320 | ! |
|---|
| 321 | CALL wrk_dealloc( jpi,jpj, zkz, zsum1 , zsum2 , zsum ) |
|---|
| 322 | CALL wrk_dealloc( jpi,jpj,jpk, zempba_3d_1, zempba_3d_2, zempba_3d, zdn2dz, zavt_itf ) |
|---|
| 323 | ! |
|---|
| 324 | IF( nn_timing == 1 ) CALL timing_stop('tmx_itf') |
|---|
| 325 | ! |
|---|
| 326 | END SUBROUTINE tmx_itf |
|---|
| 327 | |
|---|
| 328 | |
|---|
| 329 | SUBROUTINE zdf_tmx_init |
|---|
| 330 | !!---------------------------------------------------------------------- |
|---|
| 331 | !! *** ROUTINE zdf_tmx_init *** |
|---|
| 332 | !! |
|---|
| 333 | !! ** Purpose : Initialization of the vertical tidal mixing, Reading |
|---|
| 334 | !! of M2 and K1 tidal energy in nc files |
|---|
| 335 | !! |
|---|
| 336 | !! ** Method : - Read the namtmx namelist and check the parameters |
|---|
| 337 | !! |
|---|
| 338 | !! - Read the input data in NetCDF files : |
|---|
| 339 | !! M2 and K1 tidal energy. The total tidal energy, en_tmx, |
|---|
| 340 | !! is the sum of M2, K1 and S2 energy where S2 is assumed |
|---|
| 341 | !! to be: S2=(1/2)^2 * M2 |
|---|
| 342 | !! mask_itf, a mask array that determine where substituing |
|---|
| 343 | !! the standard Simmons et al. (2005) formulation with the |
|---|
| 344 | !! one of Koch_Larrouy et al. (2007). |
|---|
| 345 | !! |
|---|
| 346 | !! - Compute az_tmx, a 3D coefficient that allows to compute |
|---|
| 347 | !! the standard tidal-induced vertical mixing as follows: |
|---|
| 348 | !! Kz_tides = az_tmx / max( rn_n2min, N^2 ) |
|---|
| 349 | !! with az_tmx a bottom intensified coefficient is given by: |
|---|
| 350 | !! az_tmx(z) = en_tmx / ( rau0 * rn_htmx ) * EXP( -(H-z)/rn_htmx ) |
|---|
| 351 | !! / ( 1. - EXP( - H /rn_htmx ) ) |
|---|
| 352 | !! where rn_htmx the characteristic length scale of the bottom |
|---|
| 353 | !! intensification, en_tmx the tidal energy, and H the ocean depth |
|---|
| 354 | !! |
|---|
| 355 | !! ** input : - Namlist namtmx |
|---|
| 356 | !! - NetCDF file : M2_ORCA2.nc, K1_ORCA2.nc, and mask_itf.nc |
|---|
| 357 | !! |
|---|
| 358 | !! ** Action : - Increase by 1 the nstop flag is setting problem encounter |
|---|
| 359 | !! - defined az_tmx used to compute tidal-induced mixing |
|---|
| 360 | !! |
|---|
| 361 | !! References : Simmons et al. 2004, Ocean Modelling, 6, 3-4, 245-263. |
|---|
| 362 | !! Koch-Larrouy et al. 2007, GRL. |
|---|
| 363 | !!---------------------------------------------------------------------- |
|---|
| 364 | USE oce , zav_tide => ua ! ua used as workspace |
|---|
| 365 | !! |
|---|
| 366 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 367 | INTEGER :: inum ! local integer |
|---|
| 368 | INTEGER :: ios |
|---|
| 369 | REAL(wp) :: ztpc, ze_z ! local scalars |
|---|
| 370 | REAL(wp), DIMENSION(:,:) , POINTER :: zem2, zek1 ! read M2 and K1 tidal energy |
|---|
| 371 | REAL(wp), DIMENSION(:,:) , POINTER :: zkz ! total M2, K1 and S2 tidal energy |
|---|
| 372 | REAL(wp), DIMENSION(:,:) , POINTER :: zfact ! used for vertical structure function |
|---|
| 373 | REAL(wp), DIMENSION(:,:) , POINTER :: zhdep ! Ocean depth |
|---|
| 374 | REAL(wp), DIMENSION(:,:,:), POINTER :: zpc ! power consumption |
|---|
| 375 | !! |
|---|
| 376 | NAMELIST/namzdf_tmx/ rn_htmx, rn_n2min, rn_tfe, rn_me, ln_tmx_itf, rn_tfe_itf |
|---|
| 377 | !!---------------------------------------------------------------------- |
|---|
| 378 | ! |
|---|
| 379 | IF( nn_timing == 1 ) CALL timing_start('zdf_tmx_init') |
|---|
| 380 | ! |
|---|
| 381 | CALL wrk_alloc( jpi,jpj, zem2, zek1, zkz, zfact, zhdep ) |
|---|
| 382 | CALL wrk_alloc( jpi,jpj,jpk, zpc ) |
|---|
| 383 | IF(lwm) THEN |
|---|
| 384 | REWIND( numnam_ref ) ! Namelist namzdf_tmx in reference namelist : Tidal Mixing |
|---|
| 385 | READ ( numnam_ref, namzdf_tmx, IOSTAT = ios, ERR = 901) |
|---|
| 386 | 901 CONTINUE |
|---|
| 387 | ENDIF |
|---|
| 388 | call mpp_bcast(ios) |
|---|
| 389 | IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_tmx in reference namelist', lwp ) |
|---|
| 390 | IF(lwm) THEN |
|---|
| 391 | REWIND( numnam_cfg ) ! Namelist namzdf_tmx in configuration namelist : Tidal Mixing |
|---|
| 392 | READ ( numnam_cfg, namzdf_tmx, IOSTAT = ios, ERR = 902 ) |
|---|
| 393 | 902 CONTINUE |
|---|
| 394 | ENDIF |
|---|
| 395 | call mpp_bcast(ios) |
|---|
| 396 | IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_tmx in configuration namelist', lwp ) |
|---|
| 397 | |
|---|
| 398 | IF(lwm) WRITE ( numond, namzdf_tmx ) |
|---|
| 399 | |
|---|
| 400 | call tmx_namelist() |
|---|
| 401 | |
|---|
| 402 | IF(lwp) THEN ! Control print |
|---|
| 403 | WRITE(numout,*) |
|---|
| 404 | WRITE(numout,*) 'zdf_tmx_init : tidal mixing' |
|---|
| 405 | WRITE(numout,*) '~~~~~~~~~~~~' |
|---|
| 406 | WRITE(numout,*) ' Namelist namzdf_tmx : set tidal mixing parameters' |
|---|
| 407 | WRITE(numout,*) ' Vertical decay scale for turbulence = ', rn_htmx |
|---|
| 408 | WRITE(numout,*) ' Brunt-Vaisala frequency threshold = ', rn_n2min |
|---|
| 409 | WRITE(numout,*) ' Tidal dissipation efficiency = ', rn_tfe |
|---|
| 410 | WRITE(numout,*) ' Mixing efficiency = ', rn_me |
|---|
| 411 | WRITE(numout,*) ' ITF specific parameterisation = ', ln_tmx_itf |
|---|
| 412 | WRITE(numout,*) ' ITF tidal dissipation efficiency = ', rn_tfe_itf |
|---|
| 413 | ENDIF |
|---|
| 414 | |
|---|
| 415 | ! ! allocate tmx arrays |
|---|
| 416 | IF( zdf_tmx_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'zdf_tmx_init : unable to allocate tmx arrays' ) |
|---|
| 417 | |
|---|
| 418 | IF( ln_tmx_itf ) THEN ! read the Indonesian Through Flow mask |
|---|
| 419 | CALL iom_open('mask_itf',inum) |
|---|
| 420 | CALL iom_get (inum, jpdom_data, 'tmaskitf',mask_itf,1) ! |
|---|
| 421 | CALL iom_close(inum) |
|---|
| 422 | ENDIF |
|---|
| 423 | |
|---|
| 424 | ! read M2 tidal energy flux : W/m2 ( zem2 < 0 ) |
|---|
| 425 | CALL iom_open('M2rowdrg',inum) |
|---|
| 426 | CALL iom_get (inum, jpdom_data, 'field',zem2,1) ! |
|---|
| 427 | CALL iom_close(inum) |
|---|
| 428 | |
|---|
| 429 | ! read K1 tidal energy flux : W/m2 ( zek1 < 0 ) |
|---|
| 430 | CALL iom_open('K1rowdrg',inum) |
|---|
| 431 | CALL iom_get (inum, jpdom_data, 'field',zek1,1) ! |
|---|
| 432 | CALL iom_close(inum) |
|---|
| 433 | |
|---|
| 434 | ! Total tidal energy ( M2, S2 and K1 with S2=(1/2)^2 * M2 ) |
|---|
| 435 | ! only the energy available for mixing is taken into account, |
|---|
| 436 | ! (mixing efficiency tidal dissipation efficiency) |
|---|
| 437 | en_tmx(:,:) = - rn_tfe * rn_me * ( zem2(:,:) * 1.25 + zek1(:,:) ) * ssmask(:,:) |
|---|
| 438 | |
|---|
| 439 | !============ |
|---|
| 440 | !TG: Bug for VVL? Should this section be moved out of _init and be updated at every timestep? |
|---|
| 441 | ! Vertical structure (az_tmx) |
|---|
| 442 | DO jj = 1, jpj ! part independent of the level |
|---|
| 443 | DO ji = 1, jpi |
|---|
| 444 | zhdep(ji,jj) = gdepw_0(ji,jj,mbkt(ji,jj)+1) ! depth of the ocean |
|---|
| 445 | zfact(ji,jj) = rau0 * rn_htmx * ( 1. - EXP( -zhdep(ji,jj) / rn_htmx ) ) |
|---|
| 446 | IF( zfact(ji,jj) /= 0 ) zfact(ji,jj) = en_tmx(ji,jj) / zfact(ji,jj) |
|---|
| 447 | END DO |
|---|
| 448 | END DO |
|---|
| 449 | DO jk= 1, jpk ! complete with the level-dependent part |
|---|
| 450 | DO jj = 1, jpj |
|---|
| 451 | DO ji = 1, jpi |
|---|
| 452 | az_tmx(ji,jj,jk) = zfact(ji,jj) * EXP( -( zhdep(ji,jj)-gdepw_0(ji,jj,jk) ) / rn_htmx ) * tmask(ji,jj,jk) |
|---|
| 453 | END DO |
|---|
| 454 | END DO |
|---|
| 455 | END DO |
|---|
| 456 | !=========== |
|---|
| 457 | |
|---|
| 458 | IF( nprint == 1 .AND. lwp ) THEN |
|---|
| 459 | ! Control print |
|---|
| 460 | ! Total power consumption due to vertical mixing |
|---|
| 461 | ! zpc = rau0 * 1/rn_me * rn2 * zav_tide |
|---|
| 462 | zav_tide(:,:,:) = 0.e0 |
|---|
| 463 | DO jk = 2, jpkm1 |
|---|
| 464 | zav_tide(:,:,jk) = az_tmx(:,:,jk) / MAX( rn_n2min, rn2(:,:,jk) ) |
|---|
| 465 | END DO |
|---|
| 466 | |
|---|
| 467 | ztpc = 0.e0 |
|---|
| 468 | zpc(:,:,:) = MAX(rn_n2min,rn2(:,:,:)) * zav_tide(:,:,:) |
|---|
| 469 | DO jk= 2, jpkm1 |
|---|
| 470 | DO jj = 1, jpj |
|---|
| 471 | DO ji = 1, jpi |
|---|
| 472 | ztpc = ztpc + fse3w(ji,jj,jk) * e1t(ji,jj) * e2t(ji,jj) * zpc(ji,jj,jk) * wmask(ji,jj,jk) * tmask_i(ji,jj) |
|---|
| 473 | END DO |
|---|
| 474 | END DO |
|---|
| 475 | END DO |
|---|
| 476 | ztpc= rau0 * 1/(rn_tfe * rn_me) * ztpc |
|---|
| 477 | |
|---|
| 478 | WRITE(numout,*) |
|---|
| 479 | WRITE(numout,*) ' Total power consumption of the tidally driven part of Kz : ztpc = ', ztpc * 1.e-12 ,'TW' |
|---|
| 480 | |
|---|
| 481 | |
|---|
| 482 | ! control print 2 |
|---|
| 483 | zav_tide(:,:,:) = MIN( zav_tide(:,:,:), 60.e-4 ) |
|---|
| 484 | zkz(:,:) = 0.e0 |
|---|
| 485 | DO jk = 2, jpkm1 |
|---|
| 486 | DO jj = 1, jpj |
|---|
| 487 | DO ji = 1, jpi |
|---|
| 488 | zkz(ji,jj) = zkz(ji,jj) + fse3w(ji,jj,jk) * MAX(0.e0, rn2(ji,jj,jk)) * rau0 * zav_tide(ji,jj,jk) * wmask(ji,jj,jk) |
|---|
| 489 | END DO |
|---|
| 490 | END DO |
|---|
| 491 | END DO |
|---|
| 492 | ! Here zkz should be equal to en_tmx ==> multiply by en_tmx/zkz |
|---|
| 493 | DO jj = 1, jpj |
|---|
| 494 | DO ji = 1, jpi |
|---|
| 495 | IF( zkz(ji,jj) /= 0.e0 ) THEN |
|---|
| 496 | zkz(ji,jj) = en_tmx(ji,jj) / zkz(ji,jj) |
|---|
| 497 | ENDIF |
|---|
| 498 | END DO |
|---|
| 499 | END DO |
|---|
| 500 | ztpc = 1.e50 |
|---|
| 501 | DO jj = 1, jpj |
|---|
| 502 | DO ji = 1, jpi |
|---|
| 503 | IF( zkz(ji,jj) /= 0.e0 ) THEN |
|---|
| 504 | ztpc = Min( zkz(ji,jj), ztpc) |
|---|
| 505 | ENDIF |
|---|
| 506 | END DO |
|---|
| 507 | END DO |
|---|
| 508 | WRITE(numout,*) ' Min de zkz ', ztpc, ' Max = ', maxval(zkz(:,:) ) |
|---|
| 509 | |
|---|
| 510 | DO jk = 2, jpkm1 |
|---|
| 511 | DO jj = 1, jpj |
|---|
| 512 | DO ji = 1, jpi |
|---|
| 513 | zav_tide(ji,jj,jk) = zav_tide(ji,jj,jk) * MIN( zkz(ji,jj), 30./6. ) * wmask(ji,jj,jk) !kz max = 300 cm2/s |
|---|
| 514 | END DO |
|---|
| 515 | END DO |
|---|
| 516 | END DO |
|---|
| 517 | ztpc = 0.e0 |
|---|
| 518 | zpc(:,:,:) = Max(0.e0,rn2(:,:,:)) * zav_tide(:,:,:) |
|---|
| 519 | DO jk= 1, jpk |
|---|
| 520 | DO jj = 1, jpj |
|---|
| 521 | DO ji = 1, jpi |
|---|
| 522 | ztpc = ztpc + fse3w(ji,jj,jk) * e1t(ji,jj) * e2t(ji,jj) * zpc(ji,jj,jk) * wmask(ji,jj,jk) * tmask_i(ji,jj) |
|---|
| 523 | END DO |
|---|
| 524 | END DO |
|---|
| 525 | END DO |
|---|
| 526 | ztpc= rau0 * 1/(rn_tfe * rn_me) * ztpc |
|---|
| 527 | WRITE(numout,*) ' 2 Total power consumption of the tidally driven part of Kz : ztpc = ', ztpc * 1.e-12 ,'TW' |
|---|
| 528 | |
|---|
| 529 | DO jk = 1, jpk |
|---|
| 530 | ze_z = SUM( e1t(:,:) * e2t(:,:) * zav_tide(:,:,jk) * tmask_i(:,:) ) & |
|---|
| 531 | & / MAX( 1.e-20, SUM( e1t(:,:) * e2t(:,:) * wmask (:,:,jk) * tmask_i(:,:) ) ) |
|---|
| 532 | ztpc = 1.E50 |
|---|
| 533 | DO jj = 1, jpj |
|---|
| 534 | DO ji = 1, jpi |
|---|
| 535 | IF( zav_tide(ji,jj,jk) /= 0.e0 ) ztpc =Min( ztpc, zav_tide(ji,jj,jk) ) |
|---|
| 536 | END DO |
|---|
| 537 | END DO |
|---|
| 538 | WRITE(numout,*) ' N2 min - jk= ', jk,' ', ze_z * 1.e4,' cm2/s min= ',ztpc*1.e4, & |
|---|
| 539 | & 'max= ', MAXVAL(zav_tide(:,:,jk) )*1.e4, ' cm2/s' |
|---|
| 540 | END DO |
|---|
| 541 | |
|---|
| 542 | WRITE(numout,*) ' e_tide : ', SUM( e1t*e2t*en_tmx ) / ( rn_tfe * rn_me ) * 1.e-12, 'TW' |
|---|
| 543 | WRITE(numout,*) |
|---|
| 544 | WRITE(numout,*) ' Initial profile of tidal vertical mixing' |
|---|
| 545 | DO jk = 1, jpk |
|---|
| 546 | DO jj = 1,jpj |
|---|
| 547 | DO ji = 1,jpi |
|---|
| 548 | zkz(ji,jj) = az_tmx(ji,jj,jk) /MAX( rn_n2min, rn2(ji,jj,jk) ) |
|---|
| 549 | END DO |
|---|
| 550 | END DO |
|---|
| 551 | ze_z = SUM( e1t(:,:) * e2t(:,:) * zkz(:,:) * tmask_i(:,:) ) & |
|---|
| 552 | & / MAX( 1.e-20, SUM( e1t(:,:) * e2t(:,:) * wmask (:,:,jk) * tmask_i(:,:) ) ) |
|---|
| 553 | WRITE(numout,*) ' jk= ', jk,' ', ze_z * 1.e4,' cm2/s' |
|---|
| 554 | END DO |
|---|
| 555 | DO jk = 1, jpk |
|---|
| 556 | zkz(:,:) = az_tmx(:,:,jk) /rn_n2min |
|---|
| 557 | ze_z = SUM( e1t(:,:) * e2t(:,:) * zkz(:,:) * tmask_i(:,:) ) & |
|---|
| 558 | & / MAX( 1.e-20, SUM( e1t(:,:) * e2t(:,:) * wmask (:,:,jk) * tmask_i(:,:) ) ) |
|---|
| 559 | WRITE(numout,*) |
|---|
| 560 | WRITE(numout,*) ' N2 min - jk= ', jk,' ', ze_z * 1.e4,' cm2/s min= ',MINVAL(zkz)*1.e4, & |
|---|
| 561 | & 'max= ', MAXVAL(zkz)*1.e4, ' cm2/s' |
|---|
| 562 | END DO |
|---|
| 563 | ! |
|---|
| 564 | ENDIF |
|---|
| 565 | ! |
|---|
| 566 | CALL wrk_dealloc( jpi,jpj, zem2, zek1, zkz, zfact, zhdep ) |
|---|
| 567 | CALL wrk_dealloc( jpi,jpj,jpk, zpc ) |
|---|
| 568 | ! |
|---|
| 569 | IF( nn_timing == 1 ) CALL timing_stop('zdf_tmx_init') |
|---|
| 570 | ! |
|---|
| 571 | END SUBROUTINE zdf_tmx_init |
|---|
| 572 | |
|---|
| 573 | SUBROUTINE tmx_namelist() |
|---|
| 574 | !!--------------------------------------------------------------------- |
|---|
| 575 | !! *** ROUTINE tmx_namelist *** |
|---|
| 576 | !! |
|---|
| 577 | !! ** Purpose : Broadcast namelist variables read by procesor lwm |
|---|
| 578 | !! |
|---|
| 579 | !! ** Method : use lib_mpp |
|---|
| 580 | !!---------------------------------------------------------------------- |
|---|
| 581 | #if defined key_mpp_mpi |
|---|
| 582 | CALL mpp_bcast(rn_htmx) |
|---|
| 583 | CALL mpp_bcast(rn_n2min) |
|---|
| 584 | CALL mpp_bcast(rn_tfe) |
|---|
| 585 | CALL mpp_bcast(rn_me) |
|---|
| 586 | CALL mpp_bcast(ln_tmx_itf) |
|---|
| 587 | CALL mpp_bcast(rn_tfe_itf) |
|---|
| 588 | #endif |
|---|
| 589 | |
|---|
| 590 | END SUBROUTINE tmx_namelist |
|---|
| 591 | |
|---|
| 592 | #elif defined key_zdftmx_new |
|---|
| 593 | !!---------------------------------------------------------------------- |
|---|
| 594 | !! 'key_zdftmx_new' Internal wave-driven vertical mixing |
|---|
| 595 | !!---------------------------------------------------------------------- |
|---|
| 596 | !! zdf_tmx : global momentum & tracer Kz with wave induced Kz |
|---|
| 597 | !! zdf_tmx_init : global momentum & tracer Kz with wave induced Kz |
|---|
| 598 | !!---------------------------------------------------------------------- |
|---|
| 599 | USE oce ! ocean dynamics and tracers variables |
|---|
| 600 | USE dom_oce ! ocean space and time domain variables |
|---|
| 601 | USE zdf_oce ! ocean vertical physics variables |
|---|
| 602 | USE zdfddm ! ocean vertical physics: double diffusive mixing |
|---|
| 603 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 604 | USE eosbn2 ! ocean equation of state |
|---|
| 605 | USE phycst ! physical constants |
|---|
| 606 | USE prtctl ! Print control |
|---|
| 607 | USE in_out_manager ! I/O manager |
|---|
| 608 | USE iom ! I/O Manager |
|---|
| 609 | USE lib_mpp ! MPP library |
|---|
| 610 | USE wrk_nemo ! work arrays |
|---|
| 611 | USE timing ! Timing |
|---|
| 612 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
|---|
| 613 | |
|---|
| 614 | IMPLICIT NONE |
|---|
| 615 | PRIVATE |
|---|
| 616 | |
|---|
| 617 | PUBLIC zdf_tmx ! called in step module |
|---|
| 618 | PUBLIC zdf_tmx_init ! called in nemogcm module |
|---|
| 619 | PUBLIC zdf_tmx_alloc ! called in nemogcm module |
|---|
| 620 | |
|---|
| 621 | LOGICAL, PUBLIC, PARAMETER :: lk_zdftmx = .TRUE. !: wave-driven mixing flag |
|---|
| 622 | |
|---|
| 623 | ! !!* Namelist namzdf_tmx : internal wave-driven mixing * |
|---|
| 624 | INTEGER :: nn_zpyc ! pycnocline-intensified mixing energy proportional to N (=1) or N^2 (=2) |
|---|
| 625 | LOGICAL :: ln_mevar ! variable (=T) or constant (=F) mixing efficiency |
|---|
| 626 | LOGICAL :: ln_tsdiff ! account for differential T/S wave-driven mixing (=T) or not (=F) |
|---|
| 627 | |
|---|
| 628 | REAL(wp) :: r1_6 = 1._wp / 6._wp |
|---|
| 629 | |
|---|
| 630 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: ebot_tmx ! power available from high-mode wave breaking (W/m2) |
|---|
| 631 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: epyc_tmx ! power available from low-mode, pycnocline-intensified wave breaking (W/m2) |
|---|
| 632 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: ecri_tmx ! power available from low-mode, critical slope wave breaking (W/m2) |
|---|
| 633 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: hbot_tmx ! WKB decay scale for high-mode energy dissipation (m) |
|---|
| 634 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: hcri_tmx ! decay scale for low-mode critical slope dissipation (m) |
|---|
| 635 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: emix_tmx ! local energy density available for mixing (W/kg) |
|---|
| 636 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: bflx_tmx ! buoyancy flux Kz * N^2 (W/kg) |
|---|
| 637 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: pcmap_tmx ! vertically integrated buoyancy flux (W/m2) |
|---|
| 638 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: zav_ratio ! S/T diffusivity ratio (only for ln_tsdiff=T) |
|---|
| 639 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: zav_wave ! Internal wave-induced diffusivity |
|---|
| 640 | |
|---|
| 641 | !! * Substitutions |
|---|
| 642 | # include "zdfddm_substitute.h90" |
|---|
| 643 | # include "domzgr_substitute.h90" |
|---|
| 644 | # include "vectopt_loop_substitute.h90" |
|---|
| 645 | !!---------------------------------------------------------------------- |
|---|
| 646 | !! NEMO/OPA 4.0 , NEMO Consortium (2016) |
|---|
| 647 | !! $Id$ |
|---|
| 648 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 649 | !!---------------------------------------------------------------------- |
|---|
| 650 | CONTAINS |
|---|
| 651 | |
|---|
| 652 | INTEGER FUNCTION zdf_tmx_alloc() |
|---|
| 653 | !!---------------------------------------------------------------------- |
|---|
| 654 | !! *** FUNCTION zdf_tmx_alloc *** |
|---|
| 655 | !!---------------------------------------------------------------------- |
|---|
| 656 | ALLOCATE( ebot_tmx(jpi,jpj), epyc_tmx(jpi,jpj), ecri_tmx(jpi,jpj) , & |
|---|
| 657 | & hbot_tmx(jpi,jpj), hcri_tmx(jpi,jpj), emix_tmx(jpi,jpj,jpk), & |
|---|
| 658 | & bflx_tmx(jpi,jpj,jpk), pcmap_tmx(jpi,jpj), zav_ratio(jpi,jpj,jpk), & |
|---|
| 659 | & zav_wave(jpi,jpj,jpk), STAT=zdf_tmx_alloc ) |
|---|
| 660 | ! |
|---|
| 661 | IF( lk_mpp ) CALL mpp_sum ( zdf_tmx_alloc ) |
|---|
| 662 | IF( zdf_tmx_alloc /= 0 ) CALL ctl_warn('zdf_tmx_alloc: failed to allocate arrays') |
|---|
| 663 | END FUNCTION zdf_tmx_alloc |
|---|
| 664 | |
|---|
| 665 | |
|---|
| 666 | SUBROUTINE zdf_tmx( kt ) |
|---|
| 667 | !!---------------------------------------------------------------------- |
|---|
| 668 | !! *** ROUTINE zdf_tmx *** |
|---|
| 669 | !! |
|---|
| 670 | !! ** Purpose : add to the vertical mixing coefficients the effect of |
|---|
| 671 | !! breaking internal waves. |
|---|
| 672 | !! |
|---|
| 673 | !! ** Method : - internal wave-driven vertical mixing is given by: |
|---|
| 674 | !! Kz_wave = min( 100 cm2/s, f( Reb = emix_tmx /( Nu * N^2 ) ) |
|---|
| 675 | !! where emix_tmx is the 3D space distribution of the wave-breaking |
|---|
| 676 | !! energy and Nu the molecular kinematic viscosity. |
|---|
| 677 | !! The function f(Reb) is linear (constant mixing efficiency) |
|---|
| 678 | !! if the namelist parameter ln_mevar = F and nonlinear if ln_mevar = T. |
|---|
| 679 | !! |
|---|
| 680 | !! - Compute emix_tmx, the 3D power density that allows to compute |
|---|
| 681 | !! Reb and therefrom the wave-induced vertical diffusivity. |
|---|
| 682 | !! This is divided into three components: |
|---|
| 683 | !! 1. Bottom-intensified low-mode dissipation at critical slopes |
|---|
| 684 | !! emix_tmx(z) = ( ecri_tmx / rau0 ) * EXP( -(H-z)/hcri_tmx ) |
|---|
| 685 | !! / ( 1. - EXP( - H/hcri_tmx ) ) * hcri_tmx |
|---|
| 686 | !! where hcri_tmx is the characteristic length scale of the bottom |
|---|
| 687 | !! intensification, ecri_tmx a map of available power, and H the ocean depth. |
|---|
| 688 | !! 2. Pycnocline-intensified low-mode dissipation |
|---|
| 689 | !! emix_tmx(z) = ( epyc_tmx / rau0 ) * ( sqrt(rn2(z))^nn_zpyc ) |
|---|
| 690 | !! / SUM( sqrt(rn2(z))^nn_zpyc * e3w(z) ) |
|---|
| 691 | !! where epyc_tmx is a map of available power, and nn_zpyc |
|---|
| 692 | !! is the chosen stratification-dependence of the internal wave |
|---|
| 693 | !! energy dissipation. |
|---|
| 694 | !! 3. WKB-height dependent high mode dissipation |
|---|
| 695 | !! emix_tmx(z) = ( ebot_tmx / rau0 ) * rn2(z) * EXP(-z_wkb(z)/hbot_tmx) |
|---|
| 696 | !! / SUM( rn2(z) * EXP(-z_wkb(z)/hbot_tmx) * e3w(z) ) |
|---|
| 697 | !! where hbot_tmx is the characteristic length scale of the WKB bottom |
|---|
| 698 | !! intensification, ebot_tmx is a map of available power, and z_wkb is the |
|---|
| 699 | !! WKB-stretched height above bottom defined as |
|---|
| 700 | !! z_wkb(z) = H * SUM( sqrt(rn2(z'>=z)) * e3w(z'>=z) ) |
|---|
| 701 | !! / SUM( sqrt(rn2(z')) * e3w(z') ) |
|---|
| 702 | !! |
|---|
| 703 | !! - update the model vertical eddy viscosity and diffusivity: |
|---|
| 704 | !! avt = avt + av_wave |
|---|
| 705 | !! avm = avm + av_wave |
|---|
| 706 | !! avmu = avmu + mi(av_wave) |
|---|
| 707 | !! avmv = avmv + mj(av_wave) |
|---|
| 708 | !! |
|---|
| 709 | !! - if namelist parameter ln_tsdiff = T, account for differential mixing: |
|---|
| 710 | !! avs = avt + av_wave * diffusivity_ratio(Reb) |
|---|
| 711 | !! |
|---|
| 712 | !! ** Action : - Define emix_tmx used to compute internal wave-induced mixing |
|---|
| 713 | !! - avt, avs, avm, avmu, avmv increased by internal wave-driven mixing |
|---|
| 714 | !! |
|---|
| 715 | !! References : de Lavergne et al. 2015, JPO; 2016, in prep. |
|---|
| 716 | !!---------------------------------------------------------------------- |
|---|
| 717 | INTEGER, INTENT(in) :: kt ! ocean time-step |
|---|
| 718 | ! |
|---|
| 719 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 720 | REAL(wp) :: ztpc ! scalar workspace |
|---|
| 721 | REAL(wp), DIMENSION(:,:) , POINTER :: zfact ! Used for vertical structure |
|---|
| 722 | REAL(wp), DIMENSION(:,:) , POINTER :: zhdep ! Ocean depth |
|---|
| 723 | REAL(wp), DIMENSION(:,:,:), POINTER :: zwkb ! WKB-stretched height above bottom |
|---|
| 724 | REAL(wp), DIMENSION(:,:,:), POINTER :: zweight ! Weight for high mode vertical distribution |
|---|
| 725 | REAL(wp), DIMENSION(:,:,:), POINTER :: znu_t ! Molecular kinematic viscosity (T grid) |
|---|
| 726 | REAL(wp), DIMENSION(:,:,:), POINTER :: znu_w ! Molecular kinematic viscosity (W grid) |
|---|
| 727 | REAL(wp), DIMENSION(:,:,:), POINTER :: zReb ! Turbulence intensity parameter |
|---|
| 728 | !!---------------------------------------------------------------------- |
|---|
| 729 | ! |
|---|
| 730 | IF( nn_timing == 1 ) CALL timing_start('zdf_tmx') |
|---|
| 731 | ! |
|---|
| 732 | CALL wrk_alloc( jpi,jpj, zfact, zhdep ) |
|---|
| 733 | CALL wrk_alloc( jpi,jpj,jpk, zwkb, zweight, znu_t, znu_w, zReb ) |
|---|
| 734 | |
|---|
| 735 | ! ! ----------------------------- ! |
|---|
| 736 | ! ! Internal wave-driven mixing ! (compute zav_wave) |
|---|
| 737 | ! ! ----------------------------- ! |
|---|
| 738 | ! |
|---|
| 739 | ! !* Critical slope mixing: distribute energy over the time-varying ocean depth, |
|---|
| 740 | ! using an exponential decay from the seafloor. |
|---|
| 741 | DO jj = 1, jpj ! part independent of the level |
|---|
| 742 | DO ji = 1, jpi |
|---|
| 743 | zhdep(ji,jj) = fsdepw(ji,jj,mbkt(ji,jj)+1) ! depth of the ocean |
|---|
| 744 | zfact(ji,jj) = rau0 * ( 1._wp - EXP( -zhdep(ji,jj) / hcri_tmx(ji,jj) ) ) |
|---|
| 745 | IF( zfact(ji,jj) /= 0 ) zfact(ji,jj) = ecri_tmx(ji,jj) / zfact(ji,jj) |
|---|
| 746 | END DO |
|---|
| 747 | END DO |
|---|
| 748 | |
|---|
| 749 | DO jk = 2, jpkm1 ! complete with the level-dependent part |
|---|
| 750 | emix_tmx(:,:,jk) = zfact(:,:) * ( EXP( ( fsde3w(:,:,jk ) - zhdep(:,:) ) / hcri_tmx(:,:) ) & |
|---|
| 751 | & - EXP( ( fsde3w(:,:,jk-1) - zhdep(:,:) ) / hcri_tmx(:,:) ) ) * wmask(:,:,jk) & |
|---|
| 752 | & / ( fsde3w(:,:,jk) - fsde3w(:,:,jk-1) ) |
|---|
| 753 | END DO |
|---|
| 754 | |
|---|
| 755 | ! !* Pycnocline-intensified mixing: distribute energy over the time-varying |
|---|
| 756 | ! !* ocean depth as proportional to sqrt(rn2)^nn_zpyc |
|---|
| 757 | |
|---|
| 758 | SELECT CASE ( nn_zpyc ) |
|---|
| 759 | |
|---|
| 760 | CASE ( 1 ) ! Dissipation scales as N (recommended) |
|---|
| 761 | |
|---|
| 762 | zfact(:,:) = 0._wp |
|---|
| 763 | DO jk = 2, jpkm1 ! part independent of the level |
|---|
| 764 | zfact(:,:) = zfact(:,:) + fse3w(:,:,jk) * SQRT( MAX( 0._wp, rn2(:,:,jk) ) ) * wmask(:,:,jk) |
|---|
| 765 | END DO |
|---|
| 766 | |
|---|
| 767 | DO jj = 1, jpj |
|---|
| 768 | DO ji = 1, jpi |
|---|
| 769 | IF( zfact(ji,jj) /= 0 ) zfact(ji,jj) = epyc_tmx(ji,jj) / ( rau0 * zfact(ji,jj) ) |
|---|
| 770 | END DO |
|---|
| 771 | END DO |
|---|
| 772 | |
|---|
| 773 | DO jk = 2, jpkm1 ! complete with the level-dependent part |
|---|
| 774 | emix_tmx(:,:,jk) = emix_tmx(:,:,jk) + zfact(:,:) * SQRT( MAX( 0._wp, rn2(:,:,jk) ) ) * wmask(:,:,jk) |
|---|
| 775 | END DO |
|---|
| 776 | |
|---|
| 777 | CASE ( 2 ) ! Dissipation scales as N^2 |
|---|
| 778 | |
|---|
| 779 | zfact(:,:) = 0._wp |
|---|
| 780 | DO jk = 2, jpkm1 ! part independent of the level |
|---|
| 781 | zfact(:,:) = zfact(:,:) + fse3w(:,:,jk) * MAX( 0._wp, rn2(:,:,jk) ) * wmask(:,:,jk) |
|---|
| 782 | END DO |
|---|
| 783 | |
|---|
| 784 | DO jj= 1, jpj |
|---|
| 785 | DO ji = 1, jpi |
|---|
| 786 | IF( zfact(ji,jj) /= 0 ) zfact(ji,jj) = epyc_tmx(ji,jj) / ( rau0 * zfact(ji,jj) ) |
|---|
| 787 | END DO |
|---|
| 788 | END DO |
|---|
| 789 | |
|---|
| 790 | DO jk = 2, jpkm1 ! complete with the level-dependent part |
|---|
| 791 | emix_tmx(:,:,jk) = emix_tmx(:,:,jk) + zfact(:,:) * MAX( 0._wp, rn2(:,:,jk) ) * wmask(:,:,jk) |
|---|
| 792 | END DO |
|---|
| 793 | |
|---|
| 794 | END SELECT |
|---|
| 795 | |
|---|
| 796 | ! !* WKB-height dependent mixing: distribute energy over the time-varying |
|---|
| 797 | ! !* ocean depth as proportional to rn2 * exp(-z_wkb/rn_hbot) |
|---|
| 798 | |
|---|
| 799 | zwkb(:,:,:) = 0._wp |
|---|
| 800 | zfact(:,:) = 0._wp |
|---|
| 801 | DO jk = 2, jpkm1 |
|---|
| 802 | zfact(:,:) = zfact(:,:) + fse3w(:,:,jk) * SQRT( MAX( 0._wp, rn2(:,:,jk) ) ) * wmask(:,:,jk) |
|---|
| 803 | zwkb(:,:,jk) = zfact(:,:) |
|---|
| 804 | END DO |
|---|
| 805 | |
|---|
| 806 | DO jk = 2, jpkm1 |
|---|
| 807 | DO jj = 1, jpj |
|---|
| 808 | DO ji = 1, jpi |
|---|
| 809 | IF( zfact(ji,jj) /= 0 ) zwkb(ji,jj,jk) = zhdep(ji,jj) * ( zfact(ji,jj) - zwkb(ji,jj,jk) ) & |
|---|
| 810 | & * tmask(ji,jj,jk) / zfact(ji,jj) |
|---|
| 811 | END DO |
|---|
| 812 | END DO |
|---|
| 813 | END DO |
|---|
| 814 | zwkb(:,:,1) = zhdep(:,:) * tmask(:,:,1) |
|---|
| 815 | |
|---|
| 816 | zweight(:,:,:) = 0._wp |
|---|
| 817 | DO jk = 2, jpkm1 |
|---|
| 818 | zweight(:,:,jk) = MAX( 0._wp, rn2(:,:,jk) ) * hbot_tmx(:,:) * wmask(:,:,jk) & |
|---|
| 819 | & * ( EXP( -zwkb(:,:,jk) / hbot_tmx(:,:) ) - EXP( -zwkb(:,:,jk-1) / hbot_tmx(:,:) ) ) |
|---|
| 820 | END DO |
|---|
| 821 | |
|---|
| 822 | zfact(:,:) = 0._wp |
|---|
| 823 | DO jk = 2, jpkm1 ! part independent of the level |
|---|
| 824 | zfact(:,:) = zfact(:,:) + zweight(:,:,jk) |
|---|
| 825 | END DO |
|---|
| 826 | |
|---|
| 827 | DO jj = 1, jpj |
|---|
| 828 | DO ji = 1, jpi |
|---|
| 829 | IF( zfact(ji,jj) /= 0 ) zfact(ji,jj) = ebot_tmx(ji,jj) / ( rau0 * zfact(ji,jj) ) |
|---|
| 830 | END DO |
|---|
| 831 | END DO |
|---|
| 832 | |
|---|
| 833 | DO jk = 2, jpkm1 ! complete with the level-dependent part |
|---|
| 834 | emix_tmx(:,:,jk) = emix_tmx(:,:,jk) + zweight(:,:,jk) * zfact(:,:) * wmask(:,:,jk) & |
|---|
| 835 | & / ( fsde3w(:,:,jk) - fsde3w(:,:,jk-1) ) |
|---|
| 836 | END DO |
|---|
| 837 | |
|---|
| 838 | |
|---|
| 839 | ! Calculate molecular kinematic viscosity |
|---|
| 840 | znu_t(:,:,:) = 1.e-4_wp * ( 17.91_wp - 0.53810_wp * tsn(:,:,:,jp_tem) + 0.00694_wp * tsn(:,:,:,jp_tem) * tsn(:,:,:,jp_tem) & |
|---|
| 841 | & + 0.02305_wp * tsn(:,:,:,jp_sal) ) * tmask(:,:,:) * r1_rau0 |
|---|
| 842 | DO jk = 2, jpkm1 |
|---|
| 843 | znu_w(:,:,jk) = 0.5_wp * ( znu_t(:,:,jk-1) + znu_t(:,:,jk) ) * wmask(:,:,jk) |
|---|
| 844 | END DO |
|---|
| 845 | |
|---|
| 846 | ! Calculate turbulence intensity parameter Reb |
|---|
| 847 | DO jk = 2, jpkm1 |
|---|
| 848 | zReb(:,:,jk) = emix_tmx(:,:,jk) / MAX( 1.e-20_wp, znu_w(:,:,jk) * rn2(:,:,jk) ) |
|---|
| 849 | END DO |
|---|
| 850 | |
|---|
| 851 | ! Define internal wave-induced diffusivity |
|---|
| 852 | DO jk = 2, jpkm1 |
|---|
| 853 | zav_wave(:,:,jk) = znu_w(:,:,jk) * zReb(:,:,jk) * r1_6 ! This corresponds to a constant mixing efficiency of 1/6 |
|---|
| 854 | END DO |
|---|
| 855 | |
|---|
| 856 | IF( ln_mevar ) THEN ! Variable mixing efficiency case : modify zav_wave in the |
|---|
| 857 | DO jk = 2, jpkm1 ! energetic (Reb > 480) and buoyancy-controlled (Reb <10.224 ) regimes |
|---|
| 858 | DO jj = 1, jpj |
|---|
| 859 | DO ji = 1, jpi |
|---|
| 860 | IF( zReb(ji,jj,jk) > 480.00_wp ) THEN |
|---|
| 861 | zav_wave(ji,jj,jk) = 3.6515_wp * znu_w(ji,jj,jk) * SQRT( zReb(ji,jj,jk) ) |
|---|
| 862 | ELSEIF( zReb(ji,jj,jk) < 10.224_wp ) THEN |
|---|
| 863 | zav_wave(ji,jj,jk) = 0.052125_wp * znu_w(ji,jj,jk) * zReb(ji,jj,jk) * SQRT( zReb(ji,jj,jk) ) |
|---|
| 864 | ENDIF |
|---|
| 865 | END DO |
|---|
| 866 | END DO |
|---|
| 867 | END DO |
|---|
| 868 | ENDIF |
|---|
| 869 | |
|---|
| 870 | DO jk = 2, jpkm1 ! Bound diffusivity by molecular value and 100 cm2/s |
|---|
| 871 | zav_wave(:,:,jk) = MIN( MAX( 1.4e-7_wp, zav_wave(:,:,jk) ), 1.e-2_wp ) * wmask(:,:,jk) |
|---|
| 872 | END DO |
|---|
| 873 | |
|---|
| 874 | IF( kt == nit000 ) THEN !* Control print at first time-step: diagnose the energy consumed by zav_wave |
|---|
| 875 | ztpc = 0._wp |
|---|
| 876 | DO jk = 2, jpkm1 |
|---|
| 877 | DO jj = 1, jpj |
|---|
| 878 | DO ji = 1, jpi |
|---|
| 879 | ztpc = ztpc + fse3w(ji,jj,jk) * e1e2t(ji,jj) & |
|---|
| 880 | & * MAX( 0._wp, rn2(ji,jj,jk) ) * zav_wave(ji,jj,jk) * wmask(ji,jj,jk) * tmask_i(ji,jj) |
|---|
| 881 | END DO |
|---|
| 882 | END DO |
|---|
| 883 | END DO |
|---|
| 884 | IF( lk_mpp ) CALL mpp_sum( ztpc ) |
|---|
| 885 | ztpc = rau0 * ztpc ! Global integral of rauo * Kz * N^2 = power contributing to mixing |
|---|
| 886 | |
|---|
| 887 | IF(lwp) THEN |
|---|
| 888 | WRITE(numout,*) |
|---|
| 889 | WRITE(numout,*) 'zdf_tmx : Internal wave-driven mixing (tmx)' |
|---|
| 890 | WRITE(numout,*) '~~~~~~~ ' |
|---|
| 891 | WRITE(numout,*) |
|---|
| 892 | WRITE(numout,*) ' Total power consumption by av_wave: ztpc = ', ztpc * 1.e-12_wp, 'TW' |
|---|
| 893 | ENDIF |
|---|
| 894 | ENDIF |
|---|
| 895 | |
|---|
| 896 | ! ! ----------------------- ! |
|---|
| 897 | ! ! Update mixing coefs ! |
|---|
| 898 | ! ! ----------------------- ! |
|---|
| 899 | ! |
|---|
| 900 | IF( ln_tsdiff ) THEN !* Option for differential mixing of salinity and temperature |
|---|
| 901 | DO jk = 2, jpkm1 ! Calculate S/T diffusivity ratio as a function of Reb |
|---|
| 902 | DO jj = 1, jpj |
|---|
| 903 | DO ji = 1, jpi |
|---|
| 904 | zav_ratio(ji,jj,jk) = ( 0.505_wp + 0.495_wp * & |
|---|
| 905 | & TANH( 0.92_wp * ( LOG10( MAX( 1.e-20_wp, zReb(ji,jj,jk) * 5._wp * r1_6 ) ) - 0.60_wp ) ) & |
|---|
| 906 | & ) * wmask(ji,jj,jk) |
|---|
| 907 | END DO |
|---|
| 908 | END DO |
|---|
| 909 | END DO |
|---|
| 910 | CALL iom_put( "av_ratio", zav_ratio ) |
|---|
| 911 | DO jk = 2, jpkm1 !* update momentum & tracer diffusivity with wave-driven mixing |
|---|
| 912 | fsavs(:,:,jk) = avt(:,:,jk) + zav_wave(:,:,jk) * zav_ratio(:,:,jk) |
|---|
| 913 | avt (:,:,jk) = avt(:,:,jk) + zav_wave(:,:,jk) |
|---|
| 914 | avm (:,:,jk) = avm(:,:,jk) + zav_wave(:,:,jk) |
|---|
| 915 | END DO |
|---|
| 916 | ! |
|---|
| 917 | ELSE !* update momentum & tracer diffusivity with wave-driven mixing |
|---|
| 918 | DO jk = 2, jpkm1 |
|---|
| 919 | fsavs(:,:,jk) = avt(:,:,jk) + zav_wave(:,:,jk) |
|---|
| 920 | avt (:,:,jk) = avt(:,:,jk) + zav_wave(:,:,jk) |
|---|
| 921 | avm (:,:,jk) = avm(:,:,jk) + zav_wave(:,:,jk) |
|---|
| 922 | END DO |
|---|
| 923 | ENDIF |
|---|
| 924 | |
|---|
| 925 | DO jk = 2, jpkm1 !* update momentum diffusivity at wu and wv points |
|---|
| 926 | DO jj = 2, jpjm1 |
|---|
| 927 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 928 | avmu(ji,jj,jk) = avmu(ji,jj,jk) + 0.5_wp * ( zav_wave(ji,jj,jk) + zav_wave(ji+1,jj ,jk) ) * wumask(ji,jj,jk) |
|---|
| 929 | avmv(ji,jj,jk) = avmv(ji,jj,jk) + 0.5_wp * ( zav_wave(ji,jj,jk) + zav_wave(ji ,jj+1,jk) ) * wvmask(ji,jj,jk) |
|---|
| 930 | END DO |
|---|
| 931 | END DO |
|---|
| 932 | END DO |
|---|
| 933 | CALL lbc_lnk( avmu, 'U', 1. ) ; CALL lbc_lnk( avmv, 'V', 1. ) ! lateral boundary condition |
|---|
| 934 | |
|---|
| 935 | ! !* output internal wave-driven mixing coefficient |
|---|
| 936 | CALL iom_put( "av_wave", zav_wave ) |
|---|
| 937 | !* output useful diagnostics: N^2, Kz * N^2 (bflx_tmx), |
|---|
| 938 | ! vertical integral of rau0 * Kz * N^2 (pcmap_tmx), energy density (emix_tmx) |
|---|
| 939 | IF( iom_use("bflx_tmx") .OR. iom_use("pcmap_tmx") ) THEN |
|---|
| 940 | bflx_tmx(:,:,:) = MAX( 0._wp, rn2(:,:,:) ) * zav_wave(:,:,:) |
|---|
| 941 | pcmap_tmx(:,:) = 0._wp |
|---|
| 942 | DO jk = 2, jpkm1 |
|---|
| 943 | pcmap_tmx(:,:) = pcmap_tmx(:,:) + fse3w(:,:,jk) * bflx_tmx(:,:,jk) * wmask(:,:,jk) |
|---|
| 944 | END DO |
|---|
| 945 | pcmap_tmx(:,:) = rau0 * pcmap_tmx(:,:) |
|---|
| 946 | CALL iom_put( "bflx_tmx", bflx_tmx ) |
|---|
| 947 | CALL iom_put( "pcmap_tmx", pcmap_tmx ) |
|---|
| 948 | ENDIF |
|---|
| 949 | CALL iom_put( "emix_tmx", emix_tmx ) |
|---|
| 950 | |
|---|
| 951 | CALL wrk_dealloc( jpi,jpj, zfact, zhdep ) |
|---|
| 952 | CALL wrk_dealloc( jpi,jpj,jpk, zwkb, zweight, znu_t, znu_w, zReb ) |
|---|
| 953 | |
|---|
| 954 | IF(ln_ctl) CALL prt_ctl(tab3d_1=zav_wave , clinfo1=' tmx - av_wave: ', tab3d_2=avt, clinfo2=' avt: ', ovlap=1, kdim=jpk) |
|---|
| 955 | ! |
|---|
| 956 | IF( nn_timing == 1 ) CALL timing_stop('zdf_tmx') |
|---|
| 957 | ! |
|---|
| 958 | END SUBROUTINE zdf_tmx |
|---|
| 959 | |
|---|
| 960 | |
|---|
| 961 | SUBROUTINE zdf_tmx_init |
|---|
| 962 | !!---------------------------------------------------------------------- |
|---|
| 963 | !! *** ROUTINE zdf_tmx_init *** |
|---|
| 964 | !! |
|---|
| 965 | !! ** Purpose : Initialization of the wave-driven vertical mixing, reading |
|---|
| 966 | !! of input power maps and decay length scales in netcdf files. |
|---|
| 967 | !! |
|---|
| 968 | !! ** Method : - Read the namzdf_tmx namelist and check the parameters |
|---|
| 969 | !! |
|---|
| 970 | !! - Read the input data in NetCDF files : |
|---|
| 971 | !! power available from high-mode wave breaking (mixing_power_bot.nc) |
|---|
| 972 | !! power available from pycnocline-intensified wave-breaking (mixing_power_pyc.nc) |
|---|
| 973 | !! power available from critical slope wave-breaking (mixing_power_cri.nc) |
|---|
| 974 | !! WKB decay scale for high-mode wave-breaking (decay_scale_bot.nc) |
|---|
| 975 | !! decay scale for critical slope wave-breaking (decay_scale_cri.nc) |
|---|
| 976 | !! |
|---|
| 977 | !! ** input : - Namlist namzdf_tmx |
|---|
| 978 | !! - NetCDF files : mixing_power_bot.nc, mixing_power_pyc.nc, mixing_power_cri.nc, |
|---|
| 979 | !! decay_scale_bot.nc decay_scale_cri.nc |
|---|
| 980 | !! |
|---|
| 981 | !! ** Action : - Increase by 1 the nstop flag is setting problem encounter |
|---|
| 982 | !! - Define ebot_tmx, epyc_tmx, ecri_tmx, hbot_tmx, hcri_tmx |
|---|
| 983 | !! |
|---|
| 984 | !! References : de Lavergne et al. 2015, JPO; 2016, in prep. |
|---|
| 985 | !! |
|---|
| 986 | !!---------------------------------------------------------------------- |
|---|
| 987 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 988 | INTEGER :: inum ! local integer |
|---|
| 989 | INTEGER :: ios |
|---|
| 990 | REAL(wp) :: zbot, zpyc, zcri ! local scalars |
|---|
| 991 | !! |
|---|
| 992 | NAMELIST/namzdf_tmx_new/ nn_zpyc, ln_mevar, ln_tsdiff |
|---|
| 993 | !!---------------------------------------------------------------------- |
|---|
| 994 | ! |
|---|
| 995 | IF( nn_timing == 1 ) CALL timing_start('zdf_tmx_init') |
|---|
| 996 | ! |
|---|
| 997 | IF(lwm) THEN |
|---|
| 998 | REWIND( numnam_ref ) ! Namelist namzdf_tmx in reference namelist : Wave-driven mixing |
|---|
| 999 | READ ( numnam_ref, namzdf_tmx_new, IOSTAT = ios, ERR = 901) |
|---|
| 1000 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_tmx in reference namelist', lwp ) |
|---|
| 1001 | ! |
|---|
| 1002 | REWIND( numnam_cfg ) ! Namelist namzdf_tmx in configuration namelist : Wave-driven mixing |
|---|
| 1003 | READ ( numnam_cfg, namzdf_tmx_new, IOSTAT = ios, ERR = 902 ) |
|---|
| 1004 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_tmx in configuration namelist', lwp ) |
|---|
| 1005 | ENDIF |
|---|
| 1006 | IF(lwm) WRITE ( numond, namzdf_tmx_new ) |
|---|
| 1007 | |
|---|
| 1008 | CALL tmx_namelist() |
|---|
| 1009 | ! |
|---|
| 1010 | IF(lwp) THEN ! Control print |
|---|
| 1011 | WRITE(numout,*) |
|---|
| 1012 | WRITE(numout,*) 'zdf_tmx_init : internal wave-driven mixing' |
|---|
| 1013 | WRITE(numout,*) '~~~~~~~~~~~~' |
|---|
| 1014 | WRITE(numout,*) ' Namelist namzdf_tmx_new : set wave-driven mixing parameters' |
|---|
| 1015 | WRITE(numout,*) ' Pycnocline-intensified diss. scales as N (=1) or N^2 (=2) = ', nn_zpyc |
|---|
| 1016 | WRITE(numout,*) ' Variable (T) or constant (F) mixing efficiency = ', ln_mevar |
|---|
| 1017 | WRITE(numout,*) ' Differential internal wave-driven mixing (T) or not (F) = ', ln_tsdiff |
|---|
| 1018 | ENDIF |
|---|
| 1019 | |
|---|
| 1020 | ! The new wave-driven mixing parameterization elevates avt and avm in the interior, and |
|---|
| 1021 | ! ensures that avt remains larger than its molecular value (=1.4e-7). Therefore, avtb should |
|---|
| 1022 | ! be set here to a very small value, and avmb to its (uniform) molecular value (=1.4e-6). |
|---|
| 1023 | avmb(:) = 1.4e-6_wp ! viscous molecular value |
|---|
| 1024 | avtb(:) = 1.e-10_wp ! very small diffusive minimum (background avt is specified in zdf_tmx) |
|---|
| 1025 | avtb_2d(:,:) = 1.e0_wp ! uniform |
|---|
| 1026 | IF(lwp) THEN ! Control print |
|---|
| 1027 | WRITE(numout,*) |
|---|
| 1028 | WRITE(numout,*) ' Force the background value applied to avm & avt in TKE to be everywhere ', & |
|---|
| 1029 | & 'the viscous molecular value & a very small diffusive value, resp.' |
|---|
| 1030 | ENDIF |
|---|
| 1031 | |
|---|
| 1032 | IF( .NOT.lk_zdfddm ) CALL ctl_stop( 'STOP', 'zdf_tmx_init_new : key_zdftmx_new requires key_zdfddm' ) |
|---|
| 1033 | |
|---|
| 1034 | ! ! allocate tmx arrays |
|---|
| 1035 | IF( zdf_tmx_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'zdf_tmx_init : unable to allocate tmx arrays' ) |
|---|
| 1036 | ! |
|---|
| 1037 | ! ! read necessary fields |
|---|
| 1038 | CALL iom_open('mixing_power_bot',inum) ! energy flux for high-mode wave breaking [W/m2] |
|---|
| 1039 | CALL iom_get (inum, jpdom_data, 'field', ebot_tmx, 1 ) |
|---|
| 1040 | CALL iom_close(inum) |
|---|
| 1041 | ! |
|---|
| 1042 | CALL iom_open('mixing_power_pyc',inum) ! energy flux for pynocline-intensified wave breaking [W/m2] |
|---|
| 1043 | CALL iom_get (inum, jpdom_data, 'field', epyc_tmx, 1 ) |
|---|
| 1044 | CALL iom_close(inum) |
|---|
| 1045 | ! |
|---|
| 1046 | CALL iom_open('mixing_power_cri',inum) ! energy flux for critical slope wave breaking [W/m2] |
|---|
| 1047 | CALL iom_get (inum, jpdom_data, 'field', ecri_tmx, 1 ) |
|---|
| 1048 | CALL iom_close(inum) |
|---|
| 1049 | ! |
|---|
| 1050 | CALL iom_open('decay_scale_bot',inum) ! spatially variable decay scale for high-mode wave breaking [m] |
|---|
| 1051 | CALL iom_get (inum, jpdom_data, 'field', hbot_tmx, 1 ) |
|---|
| 1052 | CALL iom_close(inum) |
|---|
| 1053 | ! |
|---|
| 1054 | CALL iom_open('decay_scale_cri',inum) ! spatially variable decay scale for critical slope wave breaking [m] |
|---|
| 1055 | CALL iom_get (inum, jpdom_data, 'field', hcri_tmx, 1 ) |
|---|
| 1056 | CALL iom_close(inum) |
|---|
| 1057 | |
|---|
| 1058 | ebot_tmx(:,:) = ebot_tmx(:,:) * ssmask(:,:) |
|---|
| 1059 | epyc_tmx(:,:) = epyc_tmx(:,:) * ssmask(:,:) |
|---|
| 1060 | ecri_tmx(:,:) = ecri_tmx(:,:) * ssmask(:,:) |
|---|
| 1061 | |
|---|
| 1062 | ! Set once for all to zero the first and last vertical levels of appropriate variables |
|---|
| 1063 | emix_tmx (:,:, 1 ) = 0._wp |
|---|
| 1064 | emix_tmx (:,:,jpk) = 0._wp |
|---|
| 1065 | zav_ratio(:,:, 1 ) = 0._wp |
|---|
| 1066 | zav_ratio(:,:,jpk) = 0._wp |
|---|
| 1067 | zav_wave (:,:, 1 ) = 0._wp |
|---|
| 1068 | zav_wave (:,:,jpk) = 0._wp |
|---|
| 1069 | |
|---|
| 1070 | zbot = glob_sum( e1e2t(:,:) * ebot_tmx(:,:) ) |
|---|
| 1071 | zpyc = glob_sum( e1e2t(:,:) * epyc_tmx(:,:) ) |
|---|
| 1072 | zcri = glob_sum( e1e2t(:,:) * ecri_tmx(:,:) ) |
|---|
| 1073 | IF(lwp) THEN |
|---|
| 1074 | WRITE(numout,*) ' High-mode wave-breaking energy: ', zbot * 1.e-12_wp, 'TW' |
|---|
| 1075 | WRITE(numout,*) ' Pycnocline-intensifed wave-breaking energy: ', zpyc * 1.e-12_wp, 'TW' |
|---|
| 1076 | WRITE(numout,*) ' Critical slope wave-breaking energy: ', zcri * 1.e-12_wp, 'TW' |
|---|
| 1077 | ENDIF |
|---|
| 1078 | ! |
|---|
| 1079 | IF( nn_timing == 1 ) CALL timing_stop('zdf_tmx_init') |
|---|
| 1080 | ! |
|---|
| 1081 | END SUBROUTINE zdf_tmx_init |
|---|
| 1082 | |
|---|
| 1083 | SUBROUTINE tmx_namelist() |
|---|
| 1084 | !!--------------------------------------------------------------------- |
|---|
| 1085 | !! *** ROUTINE tmx_namelist *** |
|---|
| 1086 | !! |
|---|
| 1087 | !! ** Purpose : Broadcast namelist variables read by procesor lwm |
|---|
| 1088 | !! |
|---|
| 1089 | !! ** Method : use lib_mpp |
|---|
| 1090 | !!---------------------------------------------------------------------- |
|---|
| 1091 | #if defined key_mpp_mpi |
|---|
| 1092 | CALL mpp_bcast(nn_zpyc) |
|---|
| 1093 | CALL mpp_bcast(ln_mevar) |
|---|
| 1094 | CALL mpp_bcast(ln_tsdiff) |
|---|
| 1095 | #endif |
|---|
| 1096 | END SUBROUTINE tmx_namelist |
|---|
| 1097 | |
|---|
| 1098 | #else |
|---|
| 1099 | !!---------------------------------------------------------------------- |
|---|
| 1100 | !! Default option Dummy module NO Tidal MiXing |
|---|
| 1101 | !!---------------------------------------------------------------------- |
|---|
| 1102 | LOGICAL, PUBLIC, PARAMETER :: lk_zdftmx = .FALSE. !: tidal mixing flag |
|---|
| 1103 | CONTAINS |
|---|
| 1104 | SUBROUTINE zdf_tmx_init ! Dummy routine |
|---|
| 1105 | WRITE(*,*) 'zdf_tmx: You should not have seen this print! error?' |
|---|
| 1106 | END SUBROUTINE zdf_tmx_init |
|---|
| 1107 | SUBROUTINE zdf_tmx( kt ) ! Dummy routine |
|---|
| 1108 | WRITE(*,*) 'zdf_tmx: You should not have seen this print! error?', kt |
|---|
| 1109 | END SUBROUTINE zdf_tmx |
|---|
| 1110 | #endif |
|---|
| 1111 | |
|---|
| 1112 | !!====================================================================== |
|---|
| 1113 | END MODULE zdftmx |
|---|
