source: branches/UKMO/test_moci_test_suite_namelist_read/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 9395

Last change on this file since 9395 was 9395, checked in by andmirek, 3 years ago

#2050 move sbc_init

File size: 40.1 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  LIM sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!            3.4  ! 2011-11  (C. Harris) decomposition changes for running with CICE
31   !!                 ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32   !!----------------------------------------------------------------------
33
34   !!----------------------------------------------------------------------
35   !!   nemo_gcm       : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
36   !!   nemo_init      : initialization of the NEMO system
37   !!   nemo_ctl       : initialisation of the contol print
38   !!   nemo_closefile : close remaining open files
39   !!   nemo_alloc     : dynamical allocation
40   !!   nemo_partition : calculate MPP domain decomposition
41   !!   factorise      : calculate the factors of the no. of MPI processes
42   !!----------------------------------------------------------------------
43   USE step_oce        ! module used in the ocean time stepping module
44   USE cla             ! cross land advection               (tra_cla routine)
45   USE domcfg          ! domain configuration               (dom_cfg routine)
46   USE mppini          ! shared/distributed memory setting (mpp_init routine)
47   USE domain          ! domain initialization             (dom_init routine)
48#if defined key_nemocice_decomp
49   USE ice_domain_size, only: nx_global, ny_global
50#endif
51   USE tideini         ! tidal components initialization   (tide_ini routine)
52   USE bdyini          ! open boundary cond. setting       (bdy_init routine)
53   USE bdydta          ! open boundary cond. setting   (bdy_dta_init routine)
54   USE bdytides        ! open boundary cond. setting   (bdytide_init routine)
55   USE istate          ! initial state setting          (istate_init routine)
56   USE ldfdyn          ! lateral viscosity setting      (ldfdyn_init routine)
57   USE ldftra          ! lateral diffusivity setting    (ldftra_init routine)
58   USE zdfini          ! vertical physics setting          (zdf_init routine)
59   USE phycst          ! physical constant                  (par_cst routine)
60   USE trdini          ! dyn/tra trends initialization     (trd_init routine)
61   USE asminc          ! assimilation increments     
62   USE asmbkg          ! writing out state trajectory
63   USE diaptr          ! poleward transports           (dia_ptr_init routine)
64   USE diadct          ! sections transports           (dia_dct_init routine)
65   USE diaobs          ! Observation diagnostics       (dia_obs_init routine)
66   USE lib_fortran     ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
67   USE step            ! NEMO time-stepping                 (stp     routine)
68   USE icbini          ! handle bergs, initialisation
69   USE icbstp          ! handle bergs, calving, themodynamics and transport
70   USE cpl_oasis3      ! OASIS3 coupling
71   USE c1d             ! 1D configuration
72   USE step_c1d        ! Time stepping loop for the 1D configuration
73   USE dyndmp          ! Momentum damping
74#if defined key_top
75   USE trcini          ! passive tracer initialisation
76#endif
77   USE lib_mpp         ! distributed memory computing
78#if defined key_iomput
79   USE xios
80#endif
81   USE sbctide, ONLY: lk_tide
82   USE crsini          ! initialise grid coarsening utility
83   USE lbcnfd, ONLY: isendto, nsndto, nfsloop, nfeloop ! Setup of north fold exchanges
84   USE sbc_oce, ONLY: lk_oasis
85   USE stopar
86   USE stopts
87
88   IMPLICIT NONE
89   PRIVATE
90
91   PUBLIC   nemo_gcm    ! called by model.F90
92   PUBLIC   nemo_init   ! needed by AGRIF
93   PUBLIC   nemo_alloc  ! needed by TAM
94
95   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
96
97   !!----------------------------------------------------------------------
98   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
99   !! $Id$
100   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
101   !!----------------------------------------------------------------------
102CONTAINS
103
104   SUBROUTINE nemo_gcm
105      !!----------------------------------------------------------------------
106      !!                     ***  ROUTINE nemo_gcm  ***
107      !!
108      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
109      !!              curvilinear mesh on the sphere.
110      !!
111      !! ** Method  : - model general initialization
112      !!              - launch the time-stepping (stp routine)
113      !!              - finalize the run by closing files and communications
114      !!
115      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
116      !!              Madec, 2008, internal report, IPSL.
117      !!----------------------------------------------------------------------
118      INTEGER ::   istp       ! time step index
119      !!----------------------------------------------------------------------
120      !
121#if defined key_agrif
122      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
123#endif
124
125      !                            !-----------------------!
126      CALL nemo_init               !==  Initialisations  ==!
127      !                            !-----------------------!
128#if defined key_agrif
129      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
130      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
131# if defined key_top
132      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
133# endif
134# if defined key_lim2
135      CALL Agrif_Declare_Var_lim2  !  "      "   "   "      "  LIM
136# endif
137#endif
138      ! check that all process are still there... If some process have an error,
139      ! they will never enter in step and other processes will wait until the end of the cpu time!
140      IF( lk_mpp )   CALL mpp_max( nstop )
141
142      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
143
144      !                            !-----------------------!
145      !                            !==   time stepping   ==!
146      !                            !-----------------------!
147      istp = nit000
148#if defined key_c1d
149         DO WHILE ( istp <= nitend .AND. nstop == 0 )
150            CALL stp_c1d( istp )
151            istp = istp + 1
152         END DO
153#else
154          IF( lk_asminc ) THEN
155             IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 )    ! Output background fields
156             IF( ln_asmdin ) THEN                        ! Direct initialization
157                IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 )    ! Tracers
158                IF( ln_dyninc ) CALL dyn_asm_inc( nit000 - 1 )    ! Dynamics
159                IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 )    ! SSH
160             ENDIF
161          ENDIF
162
163#if defined key_agrif
164          CALL Agrif_Regrid()
165#endif
166
167         DO WHILE ( istp <= nitend .AND. nstop == 0 )
168#if defined key_agrif
169            CALL stp                         ! AGRIF: time stepping
170#else
171            CALL stp( istp )                 ! standard time stepping
172#endif
173            istp = istp + 1
174            IF( lk_mpp )   CALL mpp_max( nstop )
175         END DO
176#endif
177
178      IF( lk_diaobs   )   CALL dia_obs_wri
179      !
180      IF( ln_icebergs )   CALL icb_end( nitend )
181
182      !                            !------------------------!
183      !                            !==  finalize the run  ==!
184      !                            !------------------------!
185      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
186      !
187      IF( nstop /= 0 .AND. lwp ) THEN   ! error print
188         WRITE(numout,cform_err)
189         WRITE(numout,*) nstop, ' error have been found'
190      ENDIF
191      !
192#if defined key_agrif
193      IF( .NOT. Agrif_Root() ) THEN
194         CALL Agrif_ParentGrid_To_ChildGrid()
195         IF( lk_diaobs ) CALL dia_obs_wri
196         IF( nn_timing == 1 )   CALL timing_finalize
197         CALL Agrif_ChildGrid_To_ParentGrid()
198      ENDIF
199#endif
200      IF( nn_timing == 1 )   CALL timing_finalize
201      !
202      CALL nemo_closefile
203      !
204#if defined key_iomput
205      CALL xios_finalize                ! end mpp communications with xios
206      IF( lk_oasis ) CALL cpl_finalize    ! end coupling and mpp communications with OASIS
207#else
208      IF( lk_oasis ) THEN
209         CALL cpl_finalize              ! end coupling and mpp communications with OASIS
210      ELSE
211         IF( lk_mpp )   CALL mppstop    ! end mpp communications
212      ENDIF
213#endif
214      !
215   END SUBROUTINE nemo_gcm
216
217
218   SUBROUTINE nemo_init
219      !!----------------------------------------------------------------------
220      !!                     ***  ROUTINE nemo_init  ***
221      !!
222      !! ** Purpose :   initialization of the NEMO GCM
223      !!----------------------------------------------------------------------
224      INTEGER ::   ji            ! dummy loop indices
225      INTEGER ::   ilocal_comm   ! local integer
226      INTEGER ::   ios
227      CHARACTER(len=80), DIMENSION(16) ::   cltxt
228      !
229      NAMELIST/namctl/ ln_ctl  , nn_print, nn_ictls, nn_ictle,   &
230         &             nn_isplt, nn_jsplt, nn_jctls, nn_jctle,   &
231         &             nn_bench, nn_timing
232      NAMELIST/namcfg/ cp_cfg, cp_cfz, jp_cfg, jpidta, jpjdta, jpkdta, jpiglo, jpjglo, &
233         &             jpizoom, jpjzoom, jperio, ln_use_jattr
234      !!----------------------------------------------------------------------
235      !
236      cltxt = ''
237      cxios_context = 'nemo'
238      !
239      !                             ! Open reference namelist and configuration namelist files
240      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
241      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
242      !
243      REWIND( numnam_ref )              ! Namelist namctl in reference namelist : Control prints & Benchmark
244      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
245901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
246
247      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist : Control prints & Benchmark
248      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
249902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
250
251      !
252      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist : Control prints & Benchmark
253      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
254903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
255
256      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist : Control prints & Benchmark
257      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
258904   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )   
259
260! Force values for AGRIF zoom (cf. agrif_user.F90)
261#if defined key_agrif
262   IF( .NOT. Agrif_Root() ) THEN
263      jpiglo  = nbcellsx + 2 + 2*nbghostcells
264      jpjglo  = nbcellsy + 2 + 2*nbghostcells
265      jpi     = ( jpiglo-2*jpreci + (jpni-1+0) ) / jpni + 2*jpreci
266      jpj     = ( jpjglo-2*jprecj + (jpnj-1+0) ) / jpnj + 2*jprecj
267      jpidta  = jpiglo
268      jpjdta  = jpjglo
269      jpizoom = 1
270      jpjzoom = 1
271      nperio  = 0
272      jperio  = 0
273      ln_use_jattr = .false.
274   ENDIF
275#endif
276      !
277      !                             !--------------------------------------------!
278      !                             !  set communicator & select the local node  !
279      !                             !  NB: mynode also opens output.namelist.dyn !
280      !                             !      on unit number numond on first proc   !
281      !                             !--------------------------------------------!
282#if defined key_iomput
283      IF( Agrif_Root() ) THEN
284         IF( lk_oasis ) THEN
285            CALL cpl_init( "oceanx", ilocal_comm )                     ! nemo local communicator given by oasis
286            CALL xios_initialize( "not used",local_comm=ilocal_comm )    ! send nemo communicator to xios
287         ELSE
288            CALL  xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm )    ! nemo local communicator given by xios
289         ENDIF
290      ENDIF
291      ! Nodes selection (control print return in cltxt)
292      narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
293#else
294      IF( lk_oasis ) THEN
295         IF( Agrif_Root() ) THEN
296            CALL cpl_init( "oceanx", ilocal_comm )                      ! nemo local communicator given by oasis
297         ENDIF
298         ! Nodes selection (control print return in cltxt)
299         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
300      ELSE
301         ilocal_comm = 0
302         ! Nodes selection (control print return in cltxt)
303         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )
304      ENDIF
305#endif
306
307      narea = narea + 1                                     ! mynode return the rank of proc (0 --> jpnij -1 )
308
309      lwm = (narea == 1)                                    ! control of output namelists
310      lwp = (narea == 1) .OR. ln_ctl                        ! control of all listing output print
311!close namelist on processors other then lwm
312      IF( numnam_ref      /= -1 .AND. narea /= 1 )   CLOSE( numnam_ref      )   ! oce reference namelist
313      IF( numnam_cfg      /= -1 .AND. narea /= 1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
314
315      IF(lwm) THEN
316         ! write merged namelists from earlier to output namelist now that the
317         ! file has been opened in call to mynode. nammpp has already been
318         ! written in mynode (if lk_mpp_mpi)
319         WRITE( numond, namctl )
320         WRITE( numond, namcfg )
321      ENDIF
322
323      ! If dimensions of processor grid weren't specified in the namelist file
324      ! then we calculate them here now that we have our communicator size
325      IF( (jpni < 1) .OR. (jpnj < 1) )THEN
326#if   defined key_mpp_mpi
327         IF( Agrif_Root() ) CALL nemo_partition(mppsize)
328#else
329         jpni  = 1
330         jpnj  = 1
331         jpnij = jpni*jpnj
332#endif
333      END IF
334
335      ! Calculate domain dimensions given calculated jpni and jpnj
336      ! This used to be done in par_oce.F90 when they were parameters rather
337      ! than variables
338      IF( Agrif_Root() ) THEN
339#if defined key_nemocice_decomp
340         jpi = ( nx_global+2-2*jpreci + (jpni-1) ) / jpni + 2*jpreci ! first  dim.
341         jpj = ( ny_global+2-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj ! second dim.
342#else
343         jpi = ( jpiglo-2*jpreci + (jpni-1) ) / jpni + 2*jpreci   ! first  dim.
344         jpj = ( jpjglo-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj   ! second dim.
345#endif
346      ENDIF         
347         jpk = jpkdta                                             ! third dim
348#if defined key_agrif
349         ! simple trick to use same vertical grid as parent
350         ! but different number of levels:
351         ! Save maximum number of levels in jpkdta, then define all vertical grids
352         ! with this number.
353         ! Suppress once vertical online interpolation is ok
354         IF(.NOT.Agrif_Root()) jpkdta = Agrif_Parent(jpkdta)
355#endif
356         jpim1 = jpi-1                                            ! inner domain indices
357         jpjm1 = jpj-1                                            !   "           "
358         jpkm1 = jpk-1                                            !   "           "
359         jpij  = jpi*jpj                                          !  jpi x j
360
361      IF(lwp) THEN                            ! open listing units
362         !
363         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
364         !
365         WRITE(numout,*)
366         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
367         WRITE(numout,*) '                       NEMO team'
368         WRITE(numout,*) '            Ocean General Circulation Model'
369         WRITE(numout,*) '                  version 3.6  (2015) '
370         WRITE(numout,*)
371         WRITE(numout,*)
372         DO ji = 1, SIZE(cltxt)
373            IF( TRIM(cltxt(ji)) /= '' )   WRITE(numout,*) cltxt(ji)      ! control print of mynode
374         END DO
375         WRITE(numout,cform_aaa)                                         ! Flag AAAAAAA
376         !
377      ENDIF
378
379      ! Now we know the dimensions of the grid and numout has been set we can
380      ! allocate arrays
381      CALL nemo_alloc()
382
383      !                             !-------------------------------!
384      !                             !  NEMO general initialization  !
385      !                             !-------------------------------!
386
387      CALL nemo_ctl                          ! Control prints & Benchmark
388
389      !                                      ! Domain decomposition
390      IF( jpni*jpnj == jpnij ) THEN   ;   CALL mpp_init      ! standard cutting out
391      ELSE                            ;   CALL mpp_init2     ! eliminate land processors
392      ENDIF
393      !
394      IF( nn_timing == 1 )  CALL timing_init
395      !
396      !                                      ! General initialization
397                            CALL     phy_cst    ! Physical constants
398                            CALL     eos_init   ! Equation of state
399      IF( lk_c1d        )   CALL     c1d_init   ! 1D column configuration
400                            CALL     dom_cfg    ! Domain configuration
401CALL     sbc_init   ! Forcings : surface module (restart read with XIOS)
402                            CALL     dom_init   ! Domain
403
404      IF( ln_nnogather )    CALL nemo_northcomms   ! Initialise the northfold neighbour lists (must be done after the masks are defined)
405
406      IF( ln_ctl        )   CALL prt_ctl_init   ! Print control
407
408                            CALL  istate_init   ! ocean initial state (Dynamics and tracers)
409
410      IF( lk_tide       )   CALL    tide_init( nit000 )    ! Initialisation of the tidal harmonics
411!                           CALL     sbc_init   ! Forcings : surface module (restart read with XIOS)
412      IF( lk_bdy        )   CALL     bdy_init   ! Open boundaries initialisation
413      IF( lk_bdy        )   CALL bdy_dta_init   ! Open boundaries initialisation of external data arrays
414      IF( lk_bdy .AND. lk_tide )   &
415         &                  CALL bdytide_init   ! Open boundaries initialisation of tidal harmonic forcing
416
417                            CALL dyn_nept_init  ! simplified form of Neptune effect
418      !     
419      IF( ln_crs        )   CALL     crs_init   ! Domain initialization of coarsened grid
420      !
421                                ! Ocean physics
422      !                                         ! Vertical physics
423                            CALL     zdf_init      ! namelist read
424                            CALL zdf_bfr_init      ! bottom friction
425      IF( lk_zdfric     )   CALL zdf_ric_init      ! Richardson number dependent Kz
426      IF( lk_zdftke     )   CALL zdf_tke_init      ! TKE closure scheme
427      IF( lk_zdfgls     )   CALL zdf_gls_init      ! GLS closure scheme
428      IF( lk_zdfkpp     )   CALL zdf_kpp_init      ! KPP closure scheme
429      IF( lk_zdftmx     )   CALL zdf_tmx_init      ! tidal vertical mixing
430      IF( lk_zdfddm .AND. .NOT. lk_zdfkpp )   &
431         &                  CALL zdf_ddm_init      ! double diffusive mixing
432      !                                         ! Lateral physics
433                            CALL ldf_tra_init      ! Lateral ocean tracer physics
434                            CALL ldf_dyn_init      ! Lateral ocean momentum physics
435      IF( lk_ldfslp     )   CALL ldf_slp_init      ! slope of lateral mixing
436
437      !                                     ! Active tracers
438                            CALL tra_qsr_init   ! penetrative solar radiation qsr
439                            CALL tra_bbc_init   ! bottom heat flux
440      IF( lk_trabbl     )   CALL tra_bbl_init   ! advective (and/or diffusive) bottom boundary layer scheme
441                            CALL tra_dmp_init   ! internal damping trends- tracers
442                            CALL tra_adv_init   ! horizontal & vertical advection
443                            CALL tra_ldf_init   ! lateral mixing
444                            CALL tra_zdf_init   ! vertical mixing and after tracer fields
445
446      !                                     ! Dynamics
447      IF( lk_c1d        )   CALL dyn_dmp_init   ! internal damping trends- momentum
448                            CALL dyn_adv_init   ! advection (vector or flux form)
449                            CALL dyn_vor_init   ! vorticity term including Coriolis
450                            CALL dyn_ldf_init   ! lateral mixing
451                            CALL dyn_hpg_init   ! horizontal gradient of Hydrostatic pressure
452                            CALL dyn_zdf_init   ! vertical diffusion
453                            CALL dyn_spg_init   ! surface pressure gradient
454
455      !                                     ! Misc. options
456      IF( nn_cla == 1 .AND. cp_cfg == 'orca' .AND. jp_cfg == 2 )   CALL cla_init       ! Cross Land Advection
457                            CALL icb_init( rdt, nit000)   ! initialise icebergs instance
458                            CALL sto_par_init   ! Stochastic parametrization
459      IF( ln_sto_eos     )  CALL sto_pts_init   ! RRandom T/S fluctuations
460     
461#if defined key_top
462      !                                     ! Passive tracers
463                            CALL     trc_init
464#endif
465      !                                     ! Diagnostics
466      IF( lk_floats     )   CALL     flo_init   ! drifting Floats
467                            CALL dia_ptr_init   ! Poleward TRansports initialization
468      IF( lk_diadct     )   CALL dia_dct_init   ! Sections tranports
469                            CALL dia_hsb_init   ! heat content, salt content and volume budgets
470                            CALL     trd_init   ! Mixed-layer/Vorticity/Integral constraints trends
471      IF( lk_diaobs     ) THEN                  ! Observation & model comparison
472                            CALL dia_obs_init            ! Initialize observational data
473                            CALL dia_obs( nit000 - 1 )   ! Observation operator for restart
474      ENDIF
475
476      !                                     ! Assimilation increments
477      IF( lk_asminc     )   CALL asm_inc_init   ! Initialize assimilation increments
478      IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
479      !
480   END SUBROUTINE nemo_init
481
482
483   SUBROUTINE nemo_ctl
484      !!----------------------------------------------------------------------
485      !!                     ***  ROUTINE nemo_ctl  ***
486      !!
487      !! ** Purpose :   control print setting
488      !!
489      !! ** Method  : - print namctl information and check some consistencies
490      !!----------------------------------------------------------------------
491      !
492      IF(lwp) THEN                  ! control print
493         WRITE(numout,*)
494         WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark'
495         WRITE(numout,*) '~~~~~~~ '
496         WRITE(numout,*) '   Namelist namctl'
497         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
498         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
499         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
500         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
501         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
502         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
503         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
504         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
505         WRITE(numout,*) '      benchmark parameter (0/1)       nn_bench   = ', nn_bench
506         WRITE(numout,*) '      timing activated    (0/1)       nn_timing  = ', nn_timing
507      ENDIF
508      !
509      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
510      nictls    = nn_ictls
511      nictle    = nn_ictle
512      njctls    = nn_jctls
513      njctle    = nn_jctle
514      isplt     = nn_isplt
515      jsplt     = nn_jsplt
516      nbench    = nn_bench
517
518      IF(lwp) THEN                  ! control print
519         WRITE(numout,*)
520         WRITE(numout,*) 'namcfg  : configuration initialization through namelist read'
521         WRITE(numout,*) '~~~~~~~ '
522         WRITE(numout,*) '   Namelist namcfg'
523         WRITE(numout,*) '      configuration name              cp_cfg      = ', TRIM(cp_cfg)
524         WRITE(numout,*) '      configuration zoom name         cp_cfz      = ', TRIM(cp_cfz)
525         WRITE(numout,*) '      configuration resolution        jp_cfg      = ', jp_cfg
526         WRITE(numout,*) '      1st lateral dimension ( >= jpi ) jpidta     = ', jpidta
527         WRITE(numout,*) '      2nd    "         "    ( >= jpj ) jpjdta     = ', jpjdta
528         WRITE(numout,*) '      3nd    "         "               jpkdta     = ', jpkdta
529         WRITE(numout,*) '      1st dimension of global domain in i jpiglo  = ', jpiglo
530         WRITE(numout,*) '      2nd    -                  -    in j jpjglo  = ', jpjglo
531         WRITE(numout,*) '      left bottom i index of the zoom (in data domain) jpizoom = ', jpizoom
532         WRITE(numout,*) '      left bottom j index of the zoom (in data domain) jpizoom = ', jpjzoom
533         WRITE(numout,*) '      lateral cond. type (between 0 and 6) jperio = ', jperio   
534         WRITE(numout,*) '      use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr
535      ENDIF
536      !                             ! Parameter control
537      !
538      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
539         IF( lk_mpp .AND. jpnij > 1 ) THEN
540            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
541         ELSE
542            IF( isplt == 1 .AND. jsplt == 1  ) THEN
543               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
544                  &           ' - the print control will be done over the whole domain' )
545            ENDIF
546            ijsplt = isplt * jsplt            ! total number of processors ijsplt
547         ENDIF
548         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
549         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
550         !
551         !                              ! indices used for the SUM control
552         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
553            lsp_area = .FALSE.
554         ELSE                                             ! print control done over a specific  area
555            lsp_area = .TRUE.
556            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
557               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
558               nictls = 1
559            ENDIF
560            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
561               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
562               nictle = jpiglo
563            ENDIF
564            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
565               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
566               njctls = 1
567            ENDIF
568            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
569               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
570               njctle = jpjglo
571            ENDIF
572         ENDIF
573      ENDIF
574      !
575      IF( nbench == 1 ) THEN              ! Benchmark
576         SELECT CASE ( cp_cfg )
577         CASE ( 'gyre' )   ;   CALL ctl_warn( ' The Benchmark is activated ' )
578         CASE DEFAULT      ;   CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:',   &
579            &                                 ' cp_cfg = "gyre" in namelist &namcfg or set nbench = 0' )
580         END SELECT
581      ENDIF
582      !
583      IF( 1_wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ',  &
584         &                                               'f2003 standard. '                              ,  &
585         &                                               'Compile with key_nosignedzero enabled' )
586      !
587   END SUBROUTINE nemo_ctl
588
589
590   SUBROUTINE nemo_closefile
591      !!----------------------------------------------------------------------
592      !!                     ***  ROUTINE nemo_closefile  ***
593      !!
594      !! ** Purpose :   Close the files
595      !!----------------------------------------------------------------------
596      !
597      IF( lk_mpp )   CALL mppsync
598      !
599      CALL iom_close                                 ! close all input/output files managed by iom_*
600      !
601      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
602      IF( numsol          /= -1 )   CLOSE( numsol          )   ! solver file
603      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
604      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
605      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
606      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
607      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
608      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
609      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
610      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
611      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
612      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
613      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
614
615      !
616      numout = 6                                     ! redefine numout in case it is used after this point...
617      !
618   END SUBROUTINE nemo_closefile
619
620
621   SUBROUTINE nemo_alloc
622      !!----------------------------------------------------------------------
623      !!                     ***  ROUTINE nemo_alloc  ***
624      !!
625      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
626      !!
627      !! ** Method  :
628      !!----------------------------------------------------------------------
629      USE diawri    , ONLY: dia_wri_alloc
630      USE dom_oce   , ONLY: dom_oce_alloc
631      USE ldfdyn_oce, ONLY: ldfdyn_oce_alloc
632      USE ldftra_oce, ONLY: ldftra_oce_alloc
633      USE trc_oce   , ONLY: trc_oce_alloc
634#if defined key_diadct 
635      USE diadct    , ONLY: diadct_alloc 
636#endif 
637#if defined key_bdy
638      USE bdy_oce   , ONLY: bdy_oce_alloc
639#endif
640      !
641      INTEGER :: ierr
642      !!----------------------------------------------------------------------
643      !
644      ierr =        oce_alloc       ()          ! ocean
645      ierr = ierr + dia_wri_alloc   ()
646      ierr = ierr + dom_oce_alloc   ()          ! ocean domain
647      ierr = ierr + ldfdyn_oce_alloc()          ! ocean lateral  physics : dynamics
648      ierr = ierr + ldftra_oce_alloc()          ! ocean lateral  physics : tracers
649      ierr = ierr + zdf_oce_alloc   ()          ! ocean vertical physics
650      !
651      ierr = ierr + trc_oce_alloc   ()          ! shared TRC / TRA arrays
652      !
653#if defined key_diadct 
654      ierr = ierr + diadct_alloc    ()          !
655#endif 
656#if defined key_bdy
657      ierr = ierr + bdy_oce_alloc   ()          ! bdy masks (incl. initialization)
658#endif
659      !
660      IF( lk_mpp    )   CALL mpp_sum( ierr )
661      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
662      !
663   END SUBROUTINE nemo_alloc
664
665
666   SUBROUTINE nemo_partition( num_pes )
667      !!----------------------------------------------------------------------
668      !!                 ***  ROUTINE nemo_partition  ***
669      !!
670      !! ** Purpose :
671      !!
672      !! ** Method  :
673      !!----------------------------------------------------------------------
674      INTEGER, INTENT(in) ::   num_pes   ! The number of MPI processes we have
675      !
676      INTEGER, PARAMETER :: nfactmax = 20
677      INTEGER :: nfact ! The no. of factors returned
678      INTEGER :: ierr  ! Error flag
679      INTEGER :: ji
680      INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
681      INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
682      !!----------------------------------------------------------------------
683      !
684      ierr = 0
685      !
686      CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
687      !
688      IF( nfact <= 1 ) THEN
689         WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
690         WRITE (numout, *) '       : using grid of ',num_pes,' x 1'
691         jpnj = 1
692         jpni = num_pes
693      ELSE
694         ! Search through factors for the pair that are closest in value
695         mindiff = 1000000
696         imin    = 1
697         DO ji = 1, nfact-1, 2
698            idiff = ABS( ifact(ji) - ifact(ji+1) )
699            IF( idiff < mindiff ) THEN
700               mindiff = idiff
701               imin = ji
702            ENDIF
703         END DO
704         jpnj = ifact(imin)
705         jpni = ifact(imin + 1)
706      ENDIF
707      !
708      jpnij = jpni*jpnj
709      !
710   END SUBROUTINE nemo_partition
711
712
713   SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
714      !!----------------------------------------------------------------------
715      !!                     ***  ROUTINE factorise  ***
716      !!
717      !! ** Purpose :   return the prime factors of n.
718      !!                knfax factors are returned in array kfax which is of
719      !!                maximum dimension kmaxfax.
720      !! ** Method  :
721      !!----------------------------------------------------------------------
722      INTEGER                    , INTENT(in   ) ::   kn, kmaxfax
723      INTEGER                    , INTENT(  out) ::   kerr, knfax
724      INTEGER, DIMENSION(kmaxfax), INTENT(  out) ::   kfax
725      !
726      INTEGER :: ifac, jl, inu
727      INTEGER, PARAMETER :: ntest = 14
728      INTEGER, DIMENSION(ntest) :: ilfax
729      !
730      ! ilfax contains the set of allowed factors.
731      ilfax(:) = (/(2**jl,jl=ntest,1,-1)/)
732      !!----------------------------------------------------------------------
733      ! ilfax contains the set of allowed factors.
734      ilfax(:) = (/(2**jl,jl=ntest,1,-1)/)
735
736      ! Clear the error flag and initialise output vars
737      kerr = 0
738      kfax = 1
739      knfax = 0
740
741      ! Find the factors of n.
742      IF( kn == 1 )   GOTO 20
743
744      ! nu holds the unfactorised part of the number.
745      ! knfax holds the number of factors found.
746      ! l points to the allowed factor list.
747      ! ifac holds the current factor.
748
749      inu   = kn
750      knfax = 0
751
752      DO jl = ntest, 1, -1
753         !
754         ifac = ilfax(jl)
755         IF( ifac > inu )   CYCLE
756
757         ! Test whether the factor will divide.
758
759         IF( MOD(inu,ifac) == 0 ) THEN
760            !
761            knfax = knfax + 1            ! Add the factor to the list
762            IF( knfax > kmaxfax ) THEN
763               kerr = 6
764               write (*,*) 'FACTOR: insufficient space in factor array ', knfax
765               return
766            ENDIF
767            kfax(knfax) = ifac
768            ! Store the other factor that goes with this one
769            knfax = knfax + 1
770            kfax(knfax) = inu / ifac
771            !WRITE (*,*) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
772         ENDIF
773         !
774      END DO
775
776   20 CONTINUE      ! Label 20 is the exit point from the factor search loop.
777      !
778   END SUBROUTINE factorise
779
780#if defined key_mpp_mpi
781
782   SUBROUTINE nemo_northcomms
783      !!======================================================================
784      !!                     ***  ROUTINE  nemo_northcomms  ***
785      !! nemo_northcomms    :  Setup for north fold exchanges with explicit
786      !!                       point-to-point messaging
787      !!=====================================================================
788      !!----------------------------------------------------------------------
789      !!
790      !! ** Purpose :   Initialization of the northern neighbours lists.
791      !!----------------------------------------------------------------------
792      !!    1.0  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE)
793      !!    2.0  ! 2013-06 Setup avoiding MPI communication (I. Epicoco, S. Mocavero, CMCC)
794      !!----------------------------------------------------------------------
795
796      INTEGER  ::   sxM, dxM, sxT, dxT, jn
797      INTEGER  ::   njmppmax
798
799      njmppmax = MAXVAL( njmppt )
800   
801      !initializes the north-fold communication variables
802      isendto(:) = 0
803      nsndto = 0
804
805      !if I am a process in the north
806      IF ( njmpp == njmppmax ) THEN
807          !sxM is the first point (in the global domain) needed to compute the
808          !north-fold for the current process
809          sxM = jpiglo - nimppt(narea) - nlcit(narea) + 1
810          !dxM is the last point (in the global domain) needed to compute the
811          !north-fold for the current process
812          dxM = jpiglo - nimppt(narea) + 2
813
814          !loop over the other north-fold processes to find the processes
815          !managing the points belonging to the sxT-dxT range
816 
817          DO jn = 1, jpni
818                !sxT is the first point (in the global domain) of the jn
819                !process
820                sxT = nfiimpp(jn, jpnj)
821                !dxT is the last point (in the global domain) of the jn
822                !process
823                dxT = nfiimpp(jn, jpnj) + nfilcit(jn, jpnj) - 1
824                IF ((sxM .gt. sxT) .AND. (sxM .lt. dxT)) THEN
825                   nsndto = nsndto + 1
826                     isendto(nsndto) = jn
827                ELSEIF ((sxM .le. sxT) .AND. (dxM .ge. dxT)) THEN
828                   nsndto = nsndto + 1
829                     isendto(nsndto) = jn
830                ELSEIF ((dxM .lt. dxT) .AND. (sxT .lt. dxM)) THEN
831                   nsndto = nsndto + 1
832                     isendto(nsndto) = jn
833                END IF
834          END DO
835          nfsloop = 1
836          nfeloop = nlci
837          DO jn = 2,jpni-1
838           IF(nfipproc(jn,jpnj) .eq. (narea - 1)) THEN
839              IF (nfipproc(jn - 1 ,jpnj) .eq. -1) THEN
840                 nfsloop = nldi
841              ENDIF
842              IF (nfipproc(jn + 1,jpnj) .eq. -1) THEN
843                 nfeloop = nlei
844              ENDIF
845           ENDIF
846        END DO
847
848      ENDIF
849      l_north_nogather = .TRUE.
850   END SUBROUTINE nemo_northcomms
851#else
852   SUBROUTINE nemo_northcomms      ! Dummy routine
853      WRITE(*,*) 'nemo_northcomms: You should not have seen this print! error?'
854   END SUBROUTINE nemo_northcomms
855#endif
856
857   !!======================================================================
858END MODULE nemogcm
859
860
Note: See TracBrowser for help on using the repository browser.