New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_tvd.F90 in branches/UKMO/v3_6_extra_CMIP6_diagnostics/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/UKMO/v3_6_extra_CMIP6_diagnostics/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_tvd.F90 @ 6535

Last change on this file since 6535 was 6535, checked in by timgraham, 8 years ago

1) Added vertical integral of zonal mass transport to diawri (for use in calculating barotropic streamfunction)
2) Modified iom.F90 to automatically choose an ocean point for 1_point XIOS output scalars
3) Added heat flux from runoff to sbccpl and masked some fields where needed
4) Some modifications in field_def.xml
File size: 33.1 KB
Line 
1MODULE traadv_tvd
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_tvd  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!==============================================================================
6   !! History :  OPA  !  1995-12  (L. Mortier)  Original code
7   !!                 !  2000-01  (H. Loukos)  adapted to ORCA
8   !!                 !  2000-10  (MA Foujols E.Kestenare)  include file not routine
9   !!                 !  2000-12  (E. Kestenare M. Levy)  fix bug in trtrd indexes
10   !!                 !  2001-07  (E. Durand G. Madec)  adaptation to ORCA config
11   !!            8.5  !  2002-06  (G. Madec)  F90: Free form and module
12   !!    NEMO    1.0  !  2004-01  (A. de Miranda, G. Madec, J.M. Molines ): advective bbl
13   !!            2.0  !  2008-04  (S. Cravatte) add the i-, j- & k- trends computation
14   !!             -   !  2009-11  (V. Garnier) Surface pressure gradient organization
15   !!            3.3  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
16   !!----------------------------------------------------------------------
17
18   !!----------------------------------------------------------------------
19   !!   tra_adv_tvd   : update the tracer trend with the 3D advection trends using a TVD scheme
20   !!   nonosc        : compute monotonic tracer fluxes by a non-oscillatory algorithm
21   !!----------------------------------------------------------------------
22   USE oce            ! ocean dynamics and active tracers
23   USE dom_oce        ! ocean space and time domain
24   USE trc_oce        ! share passive tracers/Ocean variables
25   USE trd_oce        ! trends: ocean variables
26   USE trdtra         ! tracers trends
27   USE dynspg_oce     ! choice/control of key cpp for surface pressure gradient
28   USE diaptr         ! poleward transport diagnostics
29   !
30   USE lib_mpp        ! MPP library
31   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
32   USE in_out_manager ! I/O manager
33   USE wrk_nemo       ! Memory Allocation
34   USE timing         ! Timing
35   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
36
37   IMPLICIT NONE
38   PRIVATE
39
40   PUBLIC   tra_adv_tvd        ! routine called by traadv.F90
41   PUBLIC   tra_adv_tvd_zts    ! routine called by traadv.F90
42
43   LOGICAL ::   l_trd   ! flag to compute trends
44
45   !! * Substitutions
46#  include "domzgr_substitute.h90"
47#  include "vectopt_loop_substitute.h90"
48   !!----------------------------------------------------------------------
49   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
50   !! $Id$
51   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
52   !!----------------------------------------------------------------------
53CONTAINS
54
55   SUBROUTINE tra_adv_tvd ( kt, kit000, cdtype, p2dt, pun, pvn, pwn,      &
56      &                                       ptb, ptn, pta, kjpt )
57      !!----------------------------------------------------------------------
58      !!                  ***  ROUTINE tra_adv_tvd  ***
59      !!
60      !! **  Purpose :   Compute the now trend due to total advection of
61      !!       tracers and add it to the general trend of tracer equations
62      !!
63      !! **  Method  :   TVD scheme, i.e. 2nd order centered scheme with
64      !!       corrected flux (monotonic correction)
65      !!       note: - this advection scheme needs a leap-frog time scheme
66      !!
67      !! ** Action : - update (pta) with the now advective tracer trends
68      !!             - save the trends
69      !!----------------------------------------------------------------------
70      USE oce     , ONLY:   zwx => ua        , zwy => va          ! (ua,va) used as workspace
71      !
72      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
73      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
74      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
75      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
76      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
77      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
78      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
79      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
80      !
81      INTEGER  ::   ji, jj, jk, jn           ! dummy loop indices
82      INTEGER  ::   ik 
83      REAL(wp) ::   z2dtt, zbtr, ztra        ! local scalar
84      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk   !   -      -
85      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk   !   -      -
86      REAL(wp), POINTER, DIMENSION(:,:,:) :: zwi, zwz
87      REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrdx, ztrdy, ztrdz
88      REAL(wp), POINTER, DIMENSION(:,:,:) :: zptry
89      !!----------------------------------------------------------------------
90      !
91      IF( nn_timing == 1 )  CALL timing_start('tra_adv_tvd')
92      !
93      CALL wrk_alloc( jpi, jpj, jpk, zwi, zwz )
94      !
95      IF( kt == kit000 )  THEN
96         IF(lwp) WRITE(numout,*)
97         IF(lwp) WRITE(numout,*) 'tra_adv_tvd : TVD advection scheme on ', cdtype
98         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
99         !
100         l_trd = .FALSE.
101         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
102      ENDIF
103      !
104      IF( l_trd )  THEN
105         CALL wrk_alloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
106         ztrdx(:,:,:) = 0.e0   ;    ztrdy(:,:,:) = 0.e0   ;   ztrdz(:,:,:) = 0.e0
107      ENDIF
108      !
109      IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
110         CALL wrk_alloc( jpi, jpj, jpk, zptry )
111         zptry(:,:,:) = 0._wp
112      ENDIF
113      !
114      zwi(:,:,:) = 0.e0 ; 
115      !
116      !                                                          ! ===========
117      DO jn = 1, kjpt                                            ! tracer loop
118         !                                                       ! ===========
119         ! 1. Bottom and k=1 value : flux set to zero
120         ! ----------------------------------
121         zwx(:,:,jpk) = 0.e0    ;    zwz(:,:,jpk) = 0.e0
122         zwy(:,:,jpk) = 0.e0    ;    zwi(:,:,jpk) = 0.e0
123         
124         zwz(:,:,1  ) = 0._wp
125         ! 2. upstream advection with initial mass fluxes & intermediate update
126         ! --------------------------------------------------------------------
127         ! upstream tracer flux in the i and j direction
128         DO jk = 1, jpkm1
129            DO jj = 1, jpjm1
130               DO ji = 1, fs_jpim1   ! vector opt.
131                  ! upstream scheme
132                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
133                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
134                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
135                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
136                  zwx(ji,jj,jk) = 0.5 * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
137                  zwy(ji,jj,jk) = 0.5 * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
138               END DO
139            END DO
140         END DO
141
142         ! upstream tracer flux in the k direction
143         ! Interior value
144         DO jk = 2, jpkm1
145            DO jj = 1, jpj
146               DO ji = 1, jpi
147                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
148                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
149                  zwz(ji,jj,jk) = 0.5 * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) ) * wmask(ji,jj,jk)
150               END DO
151            END DO
152         END DO
153         ! Surface value
154         IF( lk_vvl ) THEN   
155            IF ( ln_isfcav ) THEN
156               DO jj = 1, jpj
157                  DO ji = 1, jpi
158                     zwz(ji,jj, mikt(ji,jj) ) = 0.e0          ! volume variable
159                  END DO
160               END DO
161            ELSE
162               zwz(:,:,1) = 0.e0          ! volume variable
163            END IF
164         ELSE               
165            IF ( ln_isfcav ) THEN
166               DO jj = 1, jpj
167                  DO ji = 1, jpi
168                     zwz(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)   ! linear free surface
169                  END DO
170               END DO   
171            ELSE
172               zwz(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)   ! linear free surface
173            END IF
174         ENDIF
175
176         ! total advective trend
177         DO jk = 1, jpkm1
178            z2dtt = p2dt(jk)
179            DO jj = 2, jpjm1
180               DO ji = fs_2, fs_jpim1   ! vector opt.
181                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
182                  ! total intermediate advective trends
183                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
184                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
185                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
186                  ! update and guess with monotonic sheme
187                  pta(ji,jj,jk,jn) =   pta(ji,jj,jk,jn)         + ztra   * tmask(ji,jj,jk)
188                  zwi(ji,jj,jk)    = ( ptb(ji,jj,jk,jn) + z2dtt * ztra ) * tmask(ji,jj,jk)
189               END DO
190            END DO
191         END DO
192         !                             ! Lateral boundary conditions on zwi  (unchanged sign)
193         CALL lbc_lnk( zwi, 'T', 1. ) 
194
195         !                                 ! trend diagnostics (contribution of upstream fluxes)
196         IF( l_trd )  THEN 
197            ! store intermediate advective trends
198            ztrdx(:,:,:) = zwx(:,:,:)   ;    ztrdy(:,:,:) = zwy(:,:,:)  ;   ztrdz(:,:,:) = zwz(:,:,:)
199         END IF
200         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
201         IF( cdtype == 'TRA' .AND. ln_diaptr )    zptry(:,:,:) = zwy(:,:,:) 
202
203         ! 3. antidiffusive flux : high order minus low order
204         ! --------------------------------------------------
205         ! antidiffusive flux on i and j
206         DO jk = 1, jpkm1
207            DO jj = 1, jpjm1
208               DO ji = 1, fs_jpim1   ! vector opt.
209                  zwx(ji,jj,jk) = 0.5 * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) ) - zwx(ji,jj,jk)
210                  zwy(ji,jj,jk) = 0.5 * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) ) - zwy(ji,jj,jk)
211               END DO
212            END DO
213         END DO
214     
215         ! antidiffusive flux on k
216         ! Interior value
217         DO jk = 2, jpkm1                   
218            DO jj = 1, jpj
219               DO ji = 1, jpi
220                  zwz(ji,jj,jk) = 0.5 * pwn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj,jk-1,jn) ) - zwz(ji,jj,jk)
221               END DO
222            END DO
223         END DO
224         ! surface value
225         IF ( ln_isfcav ) THEN
226            DO jj = 1, jpj
227               DO ji = 1, jpi
228                  zwz(ji,jj,mikt(ji,jj)) = 0.e0
229               END DO
230            END DO
231         ELSE
232            zwz(:,:,1) = 0.e0
233         END IF
234         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
235         CALL lbc_lnk( zwz, 'W',  1. )
236
237         ! 4. monotonicity algorithm
238         ! -------------------------
239         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
240
241
242         ! 5. final trend with corrected fluxes
243         ! ------------------------------------
244         DO jk = 1, jpkm1
245            DO jj = 2, jpjm1
246               DO ji = fs_2, fs_jpim1   ! vector opt. 
247                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
248                  ! total advective trends
249                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
250                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
251                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
252                  ! add them to the general tracer trends
253                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra * tmask(ji,jj,jk)
254               END DO
255            END DO
256         END DO
257
258         !                                 ! trend diagnostics (contribution of upstream fluxes)
259         IF( l_trd )  THEN
260            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
261            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
262            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
263           
264            CALL trd_tra( kt, cdtype, jn, jptra_xad, ztrdx, pun, ptn(:,:,:,jn) )
265            CALL trd_tra( kt, cdtype, jn, jptra_yad, ztrdy, pvn, ptn(:,:,:,jn) )
266            CALL trd_tra( kt, cdtype, jn, jptra_zad, ztrdz, pwn, ptn(:,:,:,jn) )
267         END IF
268         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
269         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
270            zptry(:,:,:) = zptry(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
271            CALL dia_ptr_ohst_components( jn, 'adv', zptry(:,:,:) )
272         ENDIF
273         !
274      END DO
275      !
276                   CALL wrk_dealloc( jpi, jpj, jpk, zwi, zwz )
277      IF( l_trd )  CALL wrk_dealloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
278      IF( cdtype == 'TRA' .AND. ln_diaptr ) CALL wrk_dealloc( jpi, jpj, jpk, zptry )
279      !
280      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_tvd')
281      !
282   END SUBROUTINE tra_adv_tvd
283
284   SUBROUTINE tra_adv_tvd_zts ( kt, kit000, cdtype, p2dt, pun, pvn, pwn,      &
285      &                                       ptb, ptn, pta, kjpt )
286      !!----------------------------------------------------------------------
287      !!                  ***  ROUTINE tra_adv_tvd_zts  ***
288      !!
289      !! **  Purpose :   Compute the now trend due to total advection of
290      !!       tracers and add it to the general trend of tracer equations
291      !!
292      !! **  Method  :   TVD ZTS scheme, i.e. 2nd order centered scheme with
293      !!       corrected flux (monotonic correction). This version use sub-
294      !!       timestepping for the vertical advection which increases stability
295      !!       when vertical metrics are small.
296      !!       note: - this advection scheme needs a leap-frog time scheme
297      !!
298      !! ** Action : - update (pta) with the now advective tracer trends
299      !!             - save the trends
300      !!----------------------------------------------------------------------
301      USE oce     , ONLY:   zwx => ua        , zwy => va          ! (ua,va) used as workspace
302      !
303      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
304      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
305      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
306      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
307      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
308      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
309      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
310      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
311      !
312      REAL(wp), DIMENSION( jpk )                           ::   zts             ! length of sub-timestep for vertical advection
313      REAL(wp), DIMENSION( jpk )                           ::   zr_p2dt         ! reciprocal of tracer timestep
314      INTEGER  ::   ji, jj, jk, jl, jn       ! dummy loop indices 
315      INTEGER  ::   jnzts = 5       ! number of sub-timesteps for vertical advection
316      INTEGER  ::   jtb, jtn, jta   ! sub timestep pointers for leap-frog/euler forward steps
317      INTEGER  ::   jtaken          ! toggle for collecting appropriate fluxes from sub timesteps
318      REAL(wp) ::   z_rzts          ! Fractional length of Euler forward sub-timestep for vertical advection
319      REAL(wp) ::   z2dtt, zbtr, ztra        ! local scalar
320      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk   !   -      -
321      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk   !   -      -
322      REAL(wp), POINTER, DIMENSION(:,:  ) :: zwx_sav , zwy_sav
323      REAL(wp), POINTER, DIMENSION(:,:,:) :: zwi, zwz, zhdiv, zwz_sav, zwzts
324      REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrdx, ztrdy, ztrdz
325      REAL(wp), POINTER, DIMENSION(:,:,:) :: zptry
326      REAL(wp), POINTER, DIMENSION(:,:,:,:) :: ztrs
327      !!----------------------------------------------------------------------
328      !
329      IF( nn_timing == 1 )  CALL timing_start('tra_adv_tvd_zts')
330      !
331      CALL wrk_alloc( jpi, jpj, zwx_sav, zwy_sav )
332      CALL wrk_alloc( jpi, jpj, jpk, zwi, zwz , zhdiv, zwz_sav, zwzts )
333      CALL wrk_alloc( jpi, jpj, jpk, kjpt+1, ztrs )
334      !
335      IF( kt == kit000 )  THEN
336         IF(lwp) WRITE(numout,*)
337         IF(lwp) WRITE(numout,*) 'tra_adv_tvd_zts : TVD ZTS advection scheme on ', cdtype
338         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
339      ENDIF
340      !
341      l_trd = .FALSE.
342      IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
343      !
344      IF( l_trd )  THEN
345         CALL wrk_alloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
346         ztrdx(:,:,:) = 0._wp  ;    ztrdy(:,:,:) = 0._wp  ;   ztrdz(:,:,:) = 0._wp
347      ENDIF
348      !
349      IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
350         CALL wrk_alloc( jpi, jpj,jpk, zptry )
351         zptry(:,:,:) = 0._wp
352      ENDIF
353      !
354      zwi(:,:,:) = 0._wp
355      z_rzts = 1._wp / REAL( jnzts, wp )
356      zr_p2dt(:) = 1._wp / p2dt(:)
357      !
358      !                                                          ! ===========
359      DO jn = 1, kjpt                                            ! tracer loop
360         !                                                       ! ===========
361         ! 1. Bottom value : flux set to zero
362         ! ----------------------------------
363         zwx(:,:,jpk) = 0._wp   ;    zwz(:,:,jpk) = 0._wp
364         zwy(:,:,jpk) = 0._wp   ;    zwi(:,:,jpk) = 0._wp
365
366         ! 2. upstream advection with initial mass fluxes & intermediate update
367         ! --------------------------------------------------------------------
368         ! upstream tracer flux in the i and j direction
369         DO jk = 1, jpkm1
370            DO jj = 1, jpjm1
371               DO ji = 1, fs_jpim1   ! vector opt.
372                  ! upstream scheme
373                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
374                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
375                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
376                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
377                  zwx(ji,jj,jk) = 0.5_wp * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
378                  zwy(ji,jj,jk) = 0.5_wp * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
379               END DO
380            END DO
381         END DO
382
383         ! upstream tracer flux in the k direction
384         ! Interior value
385         DO jk = 2, jpkm1
386            DO jj = 1, jpj
387               DO ji = 1, jpi
388                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
389                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
390                  zwz(ji,jj,jk) = 0.5_wp * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) )
391               END DO
392            END DO
393         END DO
394         ! Surface value
395         IF( lk_vvl ) THEN
396            IF ( ln_isfcav ) THEN
397               DO jj = 1, jpj
398                  DO ji = 1, jpi
399                     zwz(ji,jj, mikt(ji,jj) ) = 0.e0          ! volume variable +    isf
400                  END DO
401               END DO
402            ELSE
403               zwz(:,:,1) = 0.e0                              ! volume variable + no isf
404            END IF
405         ELSE
406            IF ( ln_isfcav ) THEN
407               DO jj = 1, jpj
408                  DO ji = 1, jpi
409                     zwz(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)   ! linear free surface +    isf
410                  END DO
411               END DO
412            ELSE
413               zwz(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)                                               ! linear free surface + no isf
414            END IF
415         ENDIF
416
417         ! total advective trend
418         DO jk = 1, jpkm1
419            z2dtt = p2dt(jk)
420            DO jj = 2, jpjm1
421               DO ji = fs_2, fs_jpim1   ! vector opt.
422                  zbtr = 1._wp / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
423                  ! total intermediate advective trends
424                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
425                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
426                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
427                  ! update and guess with monotonic sheme
428                  pta(ji,jj,jk,jn) =   pta(ji,jj,jk,jn)         + ztra
429                  zwi(ji,jj,jk)    = ( ptb(ji,jj,jk,jn) + z2dtt * ztra ) * tmask(ji,jj,jk)
430               END DO
431            END DO
432         END DO
433         !                             ! Lateral boundary conditions on zwi  (unchanged sign)
434         CALL lbc_lnk( zwi, 'T', 1. ) 
435
436         !                                 ! trend diagnostics (contribution of upstream fluxes)
437         IF( l_trd )  THEN 
438            ! store intermediate advective trends
439            ztrdx(:,:,:) = zwx(:,:,:)   ;    ztrdy(:,:,:) = zwy(:,:,:)  ;   ztrdz(:,:,:) = zwz(:,:,:)
440         END IF
441         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
442         IF( cdtype == 'TRA' .AND. ln_diaptr )  zptry(:,:,:) = zwy(:,:,:)
443
444         ! 3. antidiffusive flux : high order minus low order
445         ! --------------------------------------------------
446         ! antidiffusive flux on i and j
447
448
449         DO jk = 1, jpkm1
450
451            DO jj = 1, jpjm1
452               DO ji = 1, fs_jpim1   ! vector opt.
453                  zwx_sav(ji,jj) = zwx(ji,jj,jk)
454                  zwy_sav(ji,jj) = zwy(ji,jj,jk)
455
456                  zwx(ji,jj,jk) = 0.5_wp * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) )
457                  zwy(ji,jj,jk) = 0.5_wp * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) )
458               END DO
459            END DO
460
461            DO jj = 2, jpjm1         ! partial horizontal divergence
462               DO ji = fs_2, fs_jpim1
463                  zhdiv(ji,jj,jk) = (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk)   &
464                     &               + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk)  )
465               END DO
466            END DO
467
468            DO jj = 1, jpjm1
469               DO ji = 1, fs_jpim1   ! vector opt.
470                  zwx(ji,jj,jk) = zwx(ji,jj,jk)  - zwx_sav(ji,jj)
471                  zwy(ji,jj,jk) = zwy(ji,jj,jk)  - zwy_sav(ji,jj)
472               END DO
473            END DO
474         END DO
475     
476         ! antidiffusive flux on k
477         zwz(:,:,1) = 0._wp        ! Surface value
478         zwz_sav(:,:,:) = zwz(:,:,:)
479         !
480         ztrs(:,:,:,1) = ptb(:,:,:,jn)
481         zwzts(:,:,:) = 0._wp
482
483         DO jl = 1, jnzts                   ! Start of sub timestepping loop
484
485            IF( jl == 1 ) THEN              ! Euler forward to kick things off
486              jtb = 1   ;   jtn = 1   ;   jta = 2
487              zts(:) = p2dt(:) * z_rzts
488              jtaken = MOD( jnzts + 1 , 2)  ! Toggle to collect every second flux
489                                            ! starting at jl =1 if jnzts is odd;
490                                            ! starting at jl =2 otherwise
491            ELSEIF( jl == 2 ) THEN          ! First leapfrog step
492              jtb = 1   ;   jtn = 2   ;   jta = 3
493              zts(:) = 2._wp * p2dt(:) * z_rzts
494            ELSE                            ! Shuffle pointers for subsequent leapfrog steps
495              jtb = MOD(jtb,3) + 1
496              jtn = MOD(jtn,3) + 1
497              jta = MOD(jta,3) + 1
498            ENDIF
499            DO jk = 2, jpkm1          ! Interior value
500               DO jj = 2, jpjm1
501                  DO ji = fs_2, fs_jpim1
502                     zwz(ji,jj,jk) = 0.5_wp * pwn(ji,jj,jk) * ( ztrs(ji,jj,jk,jtn) + ztrs(ji,jj,jk-1,jtn) )
503                     IF( jtaken == 0 ) zwzts(ji,jj,jk) = zwzts(ji,jj,jk) + zwz(ji,jj,jk)*zts(jk)           ! Accumulate time-weighted vertcal flux
504                  END DO
505               END DO
506            END DO
507
508            jtaken = MOD( jtaken + 1 , 2 )
509
510            DO jk = 2, jpkm1          ! Interior value
511               DO jj = 2, jpjm1
512                  DO ji = fs_2, fs_jpim1
513                     zbtr = 1._wp / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
514                     ! total advective trends
515                     ztra = - zbtr * (  zhdiv(ji,jj,jk) + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
516                     ztrs(ji,jj,jk,jta) = ztrs(ji,jj,jk,jtb) + zts(jk) * ztra
517                  END DO
518               END DO
519            END DO
520
521         END DO
522
523         DO jk = 2, jpkm1          ! Anti-diffusive vertical flux using average flux from the sub-timestepping
524            DO jj = 2, jpjm1
525               DO ji = fs_2, fs_jpim1
526                  zwz(ji,jj,jk) = zwzts(ji,jj,jk) * zr_p2dt(jk) - zwz_sav(ji,jj,jk)
527               END DO
528            END DO
529         END DO
530         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
531         CALL lbc_lnk( zwz, 'W',  1. )
532
533         ! 4. monotonicity algorithm
534         ! -------------------------
535         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
536
537
538         ! 5. final trend with corrected fluxes
539         ! ------------------------------------
540         DO jk = 1, jpkm1
541            DO jj = 2, jpjm1
542               DO ji = fs_2, fs_jpim1   ! vector opt. 
543                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
544                  ! total advective trends
545                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
546                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
547                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
548                  ! add them to the general tracer trends
549                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
550               END DO
551            END DO
552         END DO
553
554         !                                 ! trend diagnostics (contribution of upstream fluxes)
555         IF( l_trd )  THEN
556            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
557            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
558            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
559           
560            CALL trd_tra( kt, cdtype, jn, jptra_xad, ztrdx, pun, ptn(:,:,:,jn) )   
561            CALL trd_tra( kt, cdtype, jn, jptra_yad, ztrdy, pvn, ptn(:,:,:,jn) ) 
562            CALL trd_tra( kt, cdtype, jn, jptra_zad, ztrdz, pwn, ptn(:,:,:,jn) ) 
563         END IF
564         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
565         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
566            zptry(:,:,:) = zptry(:,:,:) + zwy(:,:,:) 
567            CALL dia_ptr_ohst_components( jn, 'adv', zptry(:,:,:) )
568         ENDIF
569         !
570      END DO
571      !
572                   CALL wrk_dealloc( jpi, jpj, jpk, zwi, zwz, zhdiv, zwz_sav, zwzts )
573                   CALL wrk_dealloc( jpi, jpj, jpk, kjpt+1, ztrs )
574                   CALL wrk_dealloc( jpi, jpj, zwx_sav, zwy_sav )
575      IF( l_trd )  CALL wrk_dealloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
576      IF( cdtype == 'TRA' .AND. ln_diaptr ) CALL wrk_dealloc( jpi, jpj, jpk, zptry )
577      !
578      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_tvd_zts')
579      !
580   END SUBROUTINE tra_adv_tvd_zts
581
582   SUBROUTINE nonosc( pbef, paa, pbb, pcc, paft, p2dt )
583      !!---------------------------------------------------------------------
584      !!                    ***  ROUTINE nonosc  ***
585      !!     
586      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
587      !!       scheme and the before field by a nonoscillatory algorithm
588      !!
589      !! **  Method  :   ... ???
590      !!       warning : pbef and paft must be masked, but the boundaries
591      !!       conditions on the fluxes are not necessary zalezak (1979)
592      !!       drange (1995) multi-dimensional forward-in-time and upstream-
593      !!       in-space based differencing for fluid
594      !!----------------------------------------------------------------------
595      REAL(wp), DIMENSION(jpk)         , INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
596      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(in   ) ::   pbef, paft      ! before & after field
597      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(inout) ::   paa, pbb, pcc   ! monotonic fluxes in the 3 directions
598      !
599      INTEGER  ::   ji, jj, jk   ! dummy loop indices
600      INTEGER  ::   ikm1         ! local integer
601      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn, z2dtt   ! local scalars
602      REAL(wp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
603      REAL(wp), POINTER, DIMENSION(:,:,:) :: zbetup, zbetdo, zbup, zbdo
604      !!----------------------------------------------------------------------
605      !
606      IF( nn_timing == 1 )  CALL timing_start('nonosc')
607      !
608      CALL wrk_alloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo )
609      !
610      zbig  = 1.e+40_wp
611      zrtrn = 1.e-15_wp
612      zbetup(:,:,:) = 0._wp   ;   zbetdo(:,:,:) = 0._wp
613
614      ! Search local extrema
615      ! --------------------
616      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
617      zbup = MAX( pbef * tmask - zbig * ( 1._wp - tmask ),   &
618         &        paft * tmask - zbig * ( 1._wp - tmask )  )
619      zbdo = MIN( pbef * tmask + zbig * ( 1._wp - tmask ),   &
620         &        paft * tmask + zbig * ( 1._wp - tmask )  )
621
622      DO jk = 1, jpkm1
623         ikm1 = MAX(jk-1,1)
624         z2dtt = p2dt(jk)
625         DO jj = 2, jpjm1
626            DO ji = fs_2, fs_jpim1   ! vector opt.
627
628               ! search maximum in neighbourhood
629               zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
630                  &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
631                  &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
632                  &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
633
634               ! search minimum in neighbourhood
635               zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
636                  &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
637                  &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
638                  &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
639
640               ! positive part of the flux
641               zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
642                  & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
643                  & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
644
645               ! negative part of the flux
646               zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
647                  & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
648                  & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
649
650               ! up & down beta terms
651               zbt = e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) / z2dtt
652               zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
653               zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
654            END DO
655         END DO
656      END DO
657      CALL lbc_lnk( zbetup, 'T', 1. )   ;   CALL lbc_lnk( zbetdo, 'T', 1. )   ! lateral boundary cond. (unchanged sign)
658
659      ! 3. monotonic flux in the i & j direction (paa & pbb)
660      ! ----------------------------------------
661      DO jk = 1, jpkm1
662         DO jj = 2, jpjm1
663            DO ji = fs_2, fs_jpim1   ! vector opt.
664               zau = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
665               zbu = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
666               zcu =       ( 0.5  + SIGN( 0.5 , paa(ji,jj,jk) ) )
667               paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1._wp - zcu) * zbu )
668
669               zav = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
670               zbv = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
671               zcv =       ( 0.5  + SIGN( 0.5 , pbb(ji,jj,jk) ) )
672               pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1._wp - zcv) * zbv )
673
674      ! monotonic flux in the k direction, i.e. pcc
675      ! -------------------------------------------
676               za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
677               zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
678               zc =       ( 0.5  + SIGN( 0.5 , pcc(ji,jj,jk+1) ) )
679               pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1._wp - zc) * zb )
680            END DO
681         END DO
682      END DO
683      CALL lbc_lnk( paa, 'U', -1. )   ;   CALL lbc_lnk( pbb, 'V', -1. )   ! lateral boundary condition (changed sign)
684      !
685      CALL wrk_dealloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo )
686      !
687      IF( nn_timing == 1 )  CALL timing_stop('nonosc')
688      !
689   END SUBROUTINE nonosc
690
691   !!======================================================================
692END MODULE traadv_tvd
Note: See TracBrowser for help on using the repository browser.