| 1 | MODULE iom_ioipsl |
|---|
| 2 | !!===================================================================== |
|---|
| 3 | !! *** MODULE iom_ioipsl *** |
|---|
| 4 | !! Input/Output manager : Library to read input files with IOIPSL (only fliocom module) |
|---|
| 5 | !!==================================================================== |
|---|
| 6 | !! History : 9.0 ! 05 12 (J. Belier) Original code |
|---|
| 7 | !! 9.0 ! 06 02 (S. Masson) Adaptation to NEMO |
|---|
| 8 | !! " ! 07 07 (D. Storkey) Changes to iom_ioipsl_gettime |
|---|
| 9 | !!-------------------------------------------------------------------- |
|---|
| 10 | !!gm caution add !DIR nec: improved performance to be checked as well as no result changes |
|---|
| 11 | |
|---|
| 12 | !!-------------------------------------------------------------------- |
|---|
| 13 | !! iom_open : open a file read only |
|---|
| 14 | !! iom_close : close a file or all files opened by iom |
|---|
| 15 | !! iom_get : read a field (interfaced to several routines) |
|---|
| 16 | !! iom_gettime : read the time axis kvid in the file |
|---|
| 17 | !! iom_varid : get the id of a variable in a file |
|---|
| 18 | !! iom_rstput : write a field in a restart file (interfaced to several routines) |
|---|
| 19 | !!-------------------------------------------------------------------- |
|---|
| 20 | USE in_out_manager ! I/O manager |
|---|
| 21 | USE dom_oce ! ocean space and time domain |
|---|
| 22 | USE iom_def ! iom variables definitions |
|---|
| 23 | USE ioipsl ! IOIPSL library |
|---|
| 24 | |
|---|
| 25 | IMPLICIT NONE |
|---|
| 26 | PRIVATE |
|---|
| 27 | |
|---|
| 28 | PUBLIC iom_ioipsl_open, iom_ioipsl_close, iom_ioipsl_varid, iom_ioipsl_get, iom_ioipsl_gettime, iom_ioipsl_rstput |
|---|
| 29 | |
|---|
| 30 | INTERFACE iom_ioipsl_get |
|---|
| 31 | MODULE PROCEDURE iom_ioipsl_g0d, iom_ioipsl_g123d |
|---|
| 32 | END INTERFACE |
|---|
| 33 | INTERFACE iom_ioipsl_rstput |
|---|
| 34 | MODULE PROCEDURE iom_ioipsl_rp0123d |
|---|
| 35 | END INTERFACE |
|---|
| 36 | !!---------------------------------------------------------------------- |
|---|
| 37 | !! OPA 9.0 , LOCEAN-IPSL (2006) |
|---|
| 38 | !! $Header: /home/opalod/NEMOCVSROOT/NEMO/OPA_SRC/IOM/iom_ioipsl.F90,v 1.8 2007/06/29 14:10:50 opalod Exp $ |
|---|
| 39 | !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt) |
|---|
| 40 | !!---------------------------------------------------------------------- |
|---|
| 41 | |
|---|
| 42 | CONTAINS |
|---|
| 43 | |
|---|
| 44 | SUBROUTINE iom_ioipsl_open( cdname, kiomid, ldwrt, ldok, kdompar ) |
|---|
| 45 | !!--------------------------------------------------------------------- |
|---|
| 46 | !! *** SUBROUTINE iom_open *** |
|---|
| 47 | !! |
|---|
| 48 | !! ** Purpose : open an input file with IOIPSL (only fliocom module) |
|---|
| 49 | !!--------------------------------------------------------------------- |
|---|
| 50 | CHARACTER(len=*) , INTENT(inout) :: cdname ! File name |
|---|
| 51 | INTEGER , INTENT( out) :: kiomid ! ioipsl identifier of the opened file |
|---|
| 52 | LOGICAL , INTENT(in ) :: ldwrt ! read or write the file? |
|---|
| 53 | LOGICAL , INTENT(in ) :: ldok ! check the existence |
|---|
| 54 | INTEGER, DIMENSION(2,5), INTENT(in ), OPTIONAL :: kdompar ! domain parameters: |
|---|
| 55 | |
|---|
| 56 | CHARACTER(LEN=100) :: clinfo ! info character |
|---|
| 57 | INTEGER :: iln ! lengths of character |
|---|
| 58 | INTEGER :: istop ! temporary storage of nstop |
|---|
| 59 | INTEGER :: ifliodom ! model domain identifier (see flio_dom_set) |
|---|
| 60 | INTEGER :: ioipslid ! ioipsl identifier of the opened file |
|---|
| 61 | INTEGER :: jl ! loop variable |
|---|
| 62 | !--------------------------------------------------------------------- |
|---|
| 63 | |
|---|
| 64 | clinfo = ' iom_ioipsl_open ~~~ ' |
|---|
| 65 | istop = nstop |
|---|
| 66 | ! |
|---|
| 67 | IF( ldok ) THEN ! Open existing file... |
|---|
| 68 | ! ! ============= |
|---|
| 69 | IF( ldwrt ) THEN ! ... in write mode |
|---|
| 70 | IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in WRITE mode' |
|---|
| 71 | CALL flioopfd( TRIM(cdname), ioipslid, "WRITE" ) |
|---|
| 72 | ELSE ! ... in read mode |
|---|
| 73 | IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in READ mode' |
|---|
| 74 | CALL flioopfd( TRIM(cdname), ioipslid ) |
|---|
| 75 | ENDIF |
|---|
| 76 | ELSE ! the file does not exist |
|---|
| 77 | ! ! ============= |
|---|
| 78 | iln = INDEX( cdname, '.nc' ) |
|---|
| 79 | IF( ldwrt ) THEN ! the file should be open in write mode so we create it... |
|---|
| 80 | IF( jpnij > 1 ) THEN |
|---|
| 81 | ! define the domain position regarding to the global domain (mainly useful in mpp) |
|---|
| 82 | CALL flio_dom_set( jpnij, narea-1, (/1, 2/), (/jpiglo, jpjglo/) & |
|---|
| 83 | & , kdompar(:,1), kdompar(:,2), kdompar(:,3), kdompar(:,4), kdompar(:,5) & |
|---|
| 84 | & , 'BOX', ifliodom ) |
|---|
| 85 | ! Note that fliocrfd may change the value of cdname (add the cpu number...) |
|---|
| 86 | IF(lwp) WRITE(numout,*) TRIM(clinfo)//' create new file: '//cdname(1:iln-1)//'... in WRITE mode' |
|---|
| 87 | CALL fliocrfd( cdname, (/'x' , 'y' , 'z', 't'/) & |
|---|
| 88 | & , (/kdompar(1,1), kdompar(2,1), jpk, -1 /), ioipslid, ifliodom ) |
|---|
| 89 | ELSE ! the file should be open for read mode so it must exist... |
|---|
| 90 | IF(lwp) WRITE(numout,*) TRIM(clinfo)//' create new file: '//cdname//' in WRITE mode' |
|---|
| 91 | CALL fliocrfd( cdname, (/'x' , 'y' , 'z', 't'/) & |
|---|
| 92 | & , (/kdompar(1,1), kdompar(2,1), jpk, -1 /), ioipslid ) |
|---|
| 93 | ENDIF |
|---|
| 94 | ELSE ! the file should be open for read mode so it must exist... |
|---|
| 95 | CALL ctl_stop( TRIM(clinfo), ' should be impossible case...' ) |
|---|
| 96 | ENDIF |
|---|
| 97 | ENDIF |
|---|
| 98 | ! start to fill file informations |
|---|
| 99 | ! ============= |
|---|
| 100 | IF( istop == nstop ) THEN ! no error within this routine |
|---|
| 101 | !does not work with some compilers kiomid = MINLOC(iom_file(:)%nfid, dim = 1) |
|---|
| 102 | kiomid = 0 |
|---|
| 103 | DO jl = jpmax_files, 1, -1 |
|---|
| 104 | IF( iom_file(jl)%nfid == 0 ) kiomid = jl |
|---|
| 105 | ENDDO |
|---|
| 106 | iom_file(kiomid)%name = TRIM(cdname) |
|---|
| 107 | iom_file(kiomid)%nfid = ioipslid |
|---|
| 108 | iom_file(kiomid)%iolib = jpioipsl |
|---|
| 109 | iom_file(kiomid)%nvars = 0 |
|---|
| 110 | iom_file(kiomid)%irec = -1 ! useless for NetCDF files |
|---|
| 111 | CALL flioinqf( ioipslid, id_uld = iom_file(kiomid)%iduld ) |
|---|
| 112 | IF(lwp) WRITE(numout,*) ' ---> '//TRIM(cdname)//' OK' |
|---|
| 113 | ELSE |
|---|
| 114 | kiomid = 0 ! return error flag |
|---|
| 115 | ENDIF |
|---|
| 116 | ! |
|---|
| 117 | END SUBROUTINE iom_ioipsl_open |
|---|
| 118 | |
|---|
| 119 | |
|---|
| 120 | SUBROUTINE iom_ioipsl_close( kiomid ) |
|---|
| 121 | !!-------------------------------------------------------------------- |
|---|
| 122 | !! *** SUBROUTINE iom_ioipsl_close *** |
|---|
| 123 | !! |
|---|
| 124 | !! ** Purpose : close an input file with IOIPSL (only fliocom module) |
|---|
| 125 | !!-------------------------------------------------------------------- |
|---|
| 126 | INTEGER, INTENT(in) :: kiomid ! iom identifier of the file to be closed |
|---|
| 127 | !--------------------------------------------------------------------- |
|---|
| 128 | ! |
|---|
| 129 | CALL flioclo( iom_file(kiomid)%nfid ) |
|---|
| 130 | ! |
|---|
| 131 | END SUBROUTINE iom_ioipsl_close |
|---|
| 132 | |
|---|
| 133 | |
|---|
| 134 | FUNCTION iom_ioipsl_varid ( kiomid, cdvar, kiv, kdimsz ) |
|---|
| 135 | !!----------------------------------------------------------------------- |
|---|
| 136 | !! *** FUNCTION iom_varid *** |
|---|
| 137 | !! |
|---|
| 138 | !! ** Purpose : get the id of a variable in a file with IOIPSL (only fliocom module) |
|---|
| 139 | !!----------------------------------------------------------------------- |
|---|
| 140 | INTEGER , INTENT(in ) :: kiomid ! file Identifier |
|---|
| 141 | CHARACTER(len=*) , INTENT(in ) :: cdvar ! name of the variable |
|---|
| 142 | INTEGER , INTENT(in ) :: kiv ! |
|---|
| 143 | INTEGER, DIMENSION(:), INTENT( out), OPTIONAL :: kdimsz ! size of the dimensions |
|---|
| 144 | ! |
|---|
| 145 | INTEGER :: iom_ioipsl_varid ! iom variable Id |
|---|
| 146 | INTEGER :: ioipslid ! ioipsl file identifier |
|---|
| 147 | INTEGER :: ji ! dummy loop index |
|---|
| 148 | INTEGER :: i_nvd ! number of dimension of the variable |
|---|
| 149 | INTEGER, DIMENSION(jpmax_dims) :: idimid ! dimension ids of the variable |
|---|
| 150 | LOGICAL :: ll_fnd ! found test |
|---|
| 151 | CHARACTER(LEN=100) :: clinfo ! info character |
|---|
| 152 | !!----------------------------------------------------------------------- |
|---|
| 153 | clinfo = 'iom_ioipsl_varid, file: '//trim(iom_file(kiomid)%name)//', var: '//trim(cdvar) |
|---|
| 154 | iom_ioipsl_varid = 0 ! default definition |
|---|
| 155 | IF( PRESENT(kdimsz) ) kdimsz(:) = 0 ! default definition |
|---|
| 156 | ioipslid = iom_file(kiomid)%nfid ! get back ioipsl file identifier |
|---|
| 157 | CALL flioinqv( ioipslid, cdvar, ll_fnd, nb_dims = i_nvd ) ! does the variable exist in the file |
|---|
| 158 | IF( ll_fnd ) THEN |
|---|
| 159 | IF( i_nvd <= jpmax_dims ) THEN |
|---|
| 160 | iom_ioipsl_varid = kiv |
|---|
| 161 | iom_file(kiomid)%nvars = kiv |
|---|
| 162 | iom_file(kiomid)%nvid(kiv) = -1 ! variable id is not available in ioipsl |
|---|
| 163 | iom_file(kiomid)%cn_var(kiv) = TRIM(cdvar) |
|---|
| 164 | iom_file(kiomid)%ndims(kiv) = i_nvd |
|---|
| 165 | CALL flioinqv( ioipslid, cdvar, ll_fnd, & |
|---|
| 166 | & len_dims = iom_file(kiomid)%dimsz(1:i_nvd,kiv), & ! dimensions size |
|---|
| 167 | & id_dims = idimid(1:i_nvd) ) ! dimensions ids |
|---|
| 168 | iom_file(kiomid)%luld(kiv) = .FALSE. ! default value |
|---|
| 169 | DO ji = 1, i_nvd ! find the unlimited dimension |
|---|
| 170 | IF( idimid(ji) == iom_file(kiomid)%iduld ) iom_file(kiomid)%luld(kiv) = .TRUE. |
|---|
| 171 | END DO |
|---|
| 172 | !---------- Deal with scale_factor and add_offset |
|---|
| 173 | CALL flioinqa( ioipslid, cdvar, 'scale_factor', ll_fnd ) |
|---|
| 174 | IF( ll_fnd) THEN |
|---|
| 175 | CALL fliogeta( ioipslid, cdvar, 'scale_factor', iom_file(kiomid)%scf(kiv) ) |
|---|
| 176 | ELSE |
|---|
| 177 | iom_file(kiomid)%scf(kiv) = 1. |
|---|
| 178 | END IF |
|---|
| 179 | CALL flioinqa( ioipslid, cdvar, 'add_offset', ll_fnd ) |
|---|
| 180 | IF( ll_fnd ) THEN |
|---|
| 181 | CALL fliogeta( ioipslid, cdvar, 'add_offset', iom_file(kiomid)%ofs(kiv) ) |
|---|
| 182 | ELSE |
|---|
| 183 | iom_file(kiomid)%ofs(kiv) = 0. |
|---|
| 184 | END IF |
|---|
| 185 | ! return the simension size |
|---|
| 186 | IF( PRESENT(kdimsz) ) THEN |
|---|
| 187 | IF( i_nvd == SIZE(kdimsz) ) THEN |
|---|
| 188 | kdimsz(:) = iom_file(kiomid)%dimsz(1:i_nvd,kiv) |
|---|
| 189 | ELSE |
|---|
| 190 | WRITE(ctmp1,*) i_nvd, SIZE(kdimsz) |
|---|
| 191 | CALL ctl_stop( TRIM(clinfo), 'error in kdimsz size'//TRIM(ctmp1) ) |
|---|
| 192 | ENDIF |
|---|
| 193 | ENDIF |
|---|
| 194 | ELSE |
|---|
| 195 | CALL ctl_stop( TRIM(clinfo), 'Too many dimensions in the file '//iom_file(kiomid)%name, & |
|---|
| 196 | & 'increase the parameter jpmax_vars') |
|---|
| 197 | ENDIF |
|---|
| 198 | ELSE |
|---|
| 199 | iom_ioipsl_varid = -1 ! variable not found, return error code: -1 |
|---|
| 200 | ENDIF |
|---|
| 201 | ! |
|---|
| 202 | END FUNCTION iom_ioipsl_varid |
|---|
| 203 | |
|---|
| 204 | |
|---|
| 205 | SUBROUTINE iom_ioipsl_g0d( kiomid, kvid, pvar ) |
|---|
| 206 | !!----------------------------------------------------------------------- |
|---|
| 207 | !! *** ROUTINE iom_ioipsl_g0d *** |
|---|
| 208 | !! |
|---|
| 209 | !! ** Purpose : read a scalar with IOIPSL (only fliocom module) |
|---|
| 210 | !!----------------------------------------------------------------------- |
|---|
| 211 | INTEGER , INTENT(in ) :: kiomid ! Identifier of the file |
|---|
| 212 | INTEGER , INTENT(in ) :: kvid ! variable id |
|---|
| 213 | REAL(wp), INTENT( out) :: pvar ! read field |
|---|
| 214 | ! |
|---|
| 215 | CALL fliogetv( iom_file(kiomid)%nfid, TRIM(iom_file(kiomid)%cn_var(kvid)), pvar ) |
|---|
| 216 | ! |
|---|
| 217 | END SUBROUTINE iom_ioipsl_g0d |
|---|
| 218 | |
|---|
| 219 | |
|---|
| 220 | SUBROUTINE iom_ioipsl_g123d( kiomid, kvid, knbdim, kstart, kcount, kx1, kx2, ky1, ky2, & |
|---|
| 221 | & pv_r1d, pv_r2d, pv_r3d) |
|---|
| 222 | !!----------------------------------------------------------------------- |
|---|
| 223 | !! *** ROUTINE iom_ioipsl_g123d *** |
|---|
| 224 | !! |
|---|
| 225 | !! ** Purpose : read a 1D/2D/3D variable with IOIPSL (only fliocom module) |
|---|
| 226 | !! |
|---|
| 227 | !! ** Method : read ONE record at each CALL |
|---|
| 228 | !!----------------------------------------------------------------------- |
|---|
| 229 | INTEGER , INTENT(in ) :: kiomid ! iom identifier of the file |
|---|
| 230 | INTEGER , INTENT(in ) :: kvid ! Name of the variable |
|---|
| 231 | INTEGER , INTENT(in ) :: knbdim ! number of dimensions of the variable |
|---|
| 232 | INTEGER , DIMENSION(:) , INTENT(in ) :: kstart ! start position of the reading in each axis |
|---|
| 233 | INTEGER , DIMENSION(:) , INTENT(in ) :: kcount ! number of points to be read in each axis |
|---|
| 234 | INTEGER , INTENT(in ) :: kx1, kx2, ky1, ky2 ! subdomain indexes |
|---|
| 235 | REAL(wp), DIMENSION(:) , INTENT( out), OPTIONAL :: pv_r1d ! read field (1D case) |
|---|
| 236 | REAL(wp), DIMENSION(:,:) , INTENT( out), OPTIONAL :: pv_r2d ! read field (2D case) |
|---|
| 237 | REAL(wp), DIMENSION(:,:,:) , INTENT( out), OPTIONAL :: pv_r3d ! read field (3D case) |
|---|
| 238 | ! |
|---|
| 239 | INTEGER :: ioipslid ! ioipsl file identifier |
|---|
| 240 | CHARACTER(LEN=100) :: clvn ! variable name |
|---|
| 241 | !--------------------------------------------------------------------- |
|---|
| 242 | clvn = TRIM(iom_file(kiomid)%cn_var(kvid)) ! get back variable name |
|---|
| 243 | ioipslid = iom_file(kiomid)%nfid ! get back IPIPSL file id |
|---|
| 244 | ! |
|---|
| 245 | IF( PRESENT(pv_r1d) ) THEN |
|---|
| 246 | CALL fliogetv( ioipslid, clvn, pv_r1d(: ), start = kstart(1:knbdim), count = kcount(1:knbdim) ) |
|---|
| 247 | ELSEIF( PRESENT(pv_r2d) ) THEN |
|---|
| 248 | CALL fliogetv( ioipslid, clvn, pv_r2d(kx1:kx2,ky1:ky2 ), start = kstart(1:knbdim), count = kcount(1:knbdim) ) |
|---|
| 249 | ELSEIF( PRESENT(pv_r3d) ) THEN |
|---|
| 250 | CALL fliogetv( ioipslid, clvn, pv_r3d(kx1:kx2,ky1:ky2,:), start = kstart(1:knbdim), count = kcount(1:knbdim) ) |
|---|
| 251 | ENDIF |
|---|
| 252 | ! |
|---|
| 253 | ! |
|---|
| 254 | END SUBROUTINE iom_ioipsl_g123d |
|---|
| 255 | |
|---|
| 256 | |
|---|
| 257 | SUBROUTINE iom_ioipsl_gettime( kiomid, kvid, ptime, cdunits, cdcalendar ) |
|---|
| 258 | !!-------------------------------------------------------------------- |
|---|
| 259 | !! *** SUBROUTINE iom_gettime *** |
|---|
| 260 | !! |
|---|
| 261 | !! ** Purpose : read the time axis kvid in the file with IOIPSL (only fliocom module) |
|---|
| 262 | !!-------------------------------------------------------------------- |
|---|
| 263 | INTEGER , INTENT(in ) :: kiomid ! file Identifier |
|---|
| 264 | INTEGER , INTENT(in ) :: kvid ! variable id |
|---|
| 265 | REAL(wp), DIMENSION(:) , INTENT( out) :: ptime ! the time axis |
|---|
| 266 | CHARACTER(len=*), OPTIONAL, INTENT( out) :: cdunits ! units attribute |
|---|
| 267 | CHARACTER(len=*), OPTIONAL, INTENT( out) :: cdcalendar ! calendar attribute |
|---|
| 268 | !--------------------------------------------------------------------- |
|---|
| 269 | ! |
|---|
| 270 | CALL fliogetv( iom_file(kiomid)%nfid, TRIM(iom_file(kiomid)%cn_var(kvid)), ptime(:), & |
|---|
| 271 | & start=(/ 1 /), count=(/ iom_file(kiomid)%dimsz(1, kvid) /) ) |
|---|
| 272 | IF ( PRESENT(cdunits) ) THEN |
|---|
| 273 | CALL fliogeta( iom_file(kiomid)%nfid, TRIM(iom_file(kiomid)%cn_var(kvid)), "units", cdunits ) |
|---|
| 274 | ENDIF |
|---|
| 275 | IF ( PRESENT(cdcalendar) ) THEN |
|---|
| 276 | CALL fliogeta( iom_file(kiomid)%nfid, TRIM(iom_file(kiomid)%cn_var(kvid)), "calendar", cdcalendar ) |
|---|
| 277 | ENDIF |
|---|
| 278 | ! |
|---|
| 279 | END SUBROUTINE iom_ioipsl_gettime |
|---|
| 280 | |
|---|
| 281 | |
|---|
| 282 | SUBROUTINE iom_ioipsl_rp0123d( kt, kwrite, kiomid, cdvar , kvid , ktype, & |
|---|
| 283 | & pv_r0d, pv_r1d, pv_r2d, pv_r3d ) |
|---|
| 284 | !!-------------------------------------------------------------------- |
|---|
| 285 | !! *** SUBROUTINE iom_ioipsl_rstput *** |
|---|
| 286 | !! |
|---|
| 287 | !! ** Purpose : read the time axis cdvar in the file |
|---|
| 288 | !!-------------------------------------------------------------------- |
|---|
| 289 | INTEGER , INTENT(in) :: kt ! ocean time-step |
|---|
| 290 | INTEGER , INTENT(in) :: kwrite ! writing time-step |
|---|
| 291 | INTEGER , INTENT(in) :: kiomid ! Identifier of the file |
|---|
| 292 | CHARACTER(len=*) , INTENT(in) :: cdvar ! variable name |
|---|
| 293 | INTEGER , INTENT(in) :: kvid ! variable id |
|---|
| 294 | INTEGER , INTENT(in), OPTIONAL :: ktype ! variable type (default R8) |
|---|
| 295 | REAL(wp) , INTENT(in), OPTIONAL :: pv_r0d ! written Od field |
|---|
| 296 | REAL(wp), DIMENSION( jpk), INTENT(in), OPTIONAL :: pv_r1d ! written 1d field |
|---|
| 297 | REAL(wp), DIMENSION(jpi,jpj ), INTENT(in), OPTIONAL :: pv_r2d ! written 2d field |
|---|
| 298 | REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in), OPTIONAL :: pv_r3d ! written 3d field |
|---|
| 299 | ! |
|---|
| 300 | INTEGER :: idims ! number of dimension |
|---|
| 301 | INTEGER :: idvar ! variable id |
|---|
| 302 | INTEGER :: itype ! variable type |
|---|
| 303 | INTEGER :: ix1, ix2, iy1, iy2 ! subdomain indexes |
|---|
| 304 | INTEGER, DIMENSION(4) :: idimsz ! dimensions size |
|---|
| 305 | INTEGER, DIMENSION(4) :: idimid ! dimensions id |
|---|
| 306 | CHARACTER(LEN=100) :: clinfo ! info character |
|---|
| 307 | INTEGER :: ioipslid ! ioipsl file identifier |
|---|
| 308 | !--------------------------------------------------------------------- |
|---|
| 309 | ! |
|---|
| 310 | clinfo = ' iom_ioipsl_rp0123d, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(cdvar) |
|---|
| 311 | ioipslid = iom_file(kiomid)%nfid |
|---|
| 312 | ! |
|---|
| 313 | ! define dimension variables if it is not already done |
|---|
| 314 | ! ========================== |
|---|
| 315 | IF( iom_file(kiomid)%nvars == 0 ) THEN |
|---|
| 316 | ! define the dimension variables if it is not already done |
|---|
| 317 | CALL fliodefv( ioipslid,'nav_lon', (/1,2/), v_t=flio_r4 , axis='X', & |
|---|
| 318 | & long_name="Longitude", units="degrees_east" ) |
|---|
| 319 | CALL fliodefv( ioipslid,'nav_lat', (/1,2/), v_t=flio_r4 , axis='Y', & |
|---|
| 320 | & long_name="Latitude", units="degrees_north" ) |
|---|
| 321 | CALL fliodefv( ioipslid,'nav_lev', (/3/) , v_t=flio_i4 , axis='Z', & |
|---|
| 322 | & long_name="Model levels",units="model_levels") |
|---|
| 323 | CALL fliodefv( ioipslid,'time_counter', (/4/), v_t=flio_r4, axis='T', & |
|---|
| 324 | & long_name="Time axis", units='seconds since 0001-01-01 00:00:00' ) |
|---|
| 325 | ! update informations structure related the dimension variable we just added... |
|---|
| 326 | iom_file(kiomid)%nvars = 4 |
|---|
| 327 | iom_file(kiomid)%luld(1:4) = (/ .FALSE., .FALSE., .FALSE., .TRUE. /) |
|---|
| 328 | iom_file(kiomid)%cn_var(1:3) = (/ 'nav_lon', 'nav_lat', 'nav_lev' /) |
|---|
| 329 | iom_file(kiomid)%cn_var(4) = 'time_counter' |
|---|
| 330 | iom_file(kiomid)%ndims(1:4) = (/ 2, 2, 1, 1 /) |
|---|
| 331 | ! trick: defined to 0 to say that dimension variables are defined but not yet written |
|---|
| 332 | iom_file(kiomid)%dimsz(1, 1) = 0 |
|---|
| 333 | IF(lwp) WRITE(numout,*) TRIM(clinfo)//' define dimension variables done' |
|---|
| 334 | ENDIF |
|---|
| 335 | |
|---|
| 336 | ! define the data if it is not already done |
|---|
| 337 | ! =============== |
|---|
| 338 | IF( kvid <= 0 ) THEN |
|---|
| 339 | ! variable definition |
|---|
| 340 | IF( PRESENT(pv_r0d) ) THEN ; idims = 0 |
|---|
| 341 | ELSEIF( PRESENT(pv_r1d) ) THEN ; idims = 2 ; idimid(1:idims) = (/ 3,4/) |
|---|
| 342 | ELSEIF( PRESENT(pv_r2d) ) THEN ; idims = 3 ; idimid(1:idims) = (/1,2 ,4/) |
|---|
| 343 | ELSEIF( PRESENT(pv_r3d) ) THEN ; idims = 4 ; idimid(1:idims) = (/1,2,3,4/) |
|---|
| 344 | ENDIF |
|---|
| 345 | IF( PRESENT(ktype) ) THEN ! variable external type |
|---|
| 346 | SELECT CASE (ktype) |
|---|
| 347 | CASE (jp_r8) ; itype = flio_r8 |
|---|
| 348 | CASE (jp_r4) ; itype = flio_r4 |
|---|
| 349 | CASE (jp_i4) ; itype = flio_i4 |
|---|
| 350 | CASE (jp_i2) ; itype = flio_i2 |
|---|
| 351 | CASE (jp_i1) ; itype = flio_i1 ! fliocom does not handle i1 type of variable |
|---|
| 352 | CASE DEFAULT ; CALL ctl_stop( TRIM(clinfo)//' unknown variable type' ) |
|---|
| 353 | END SELECT |
|---|
| 354 | ELSE |
|---|
| 355 | itype = flio_r8 |
|---|
| 356 | ENDIF |
|---|
| 357 | IF( PRESENT(pv_r0d) ) THEN ; CALL fliodefv (ioipslid, TRIM(cdvar) , v_t = itype) |
|---|
| 358 | ELSE ; CALL fliodefv (ioipslid, TRIM(cdvar), idimid(1:idims), v_t = itype) |
|---|
| 359 | ENDIF |
|---|
| 360 | ! update informations structure related the new variable we want to add... |
|---|
| 361 | idvar = iom_file(kiomid)%nvars + 1 |
|---|
| 362 | iom_file(kiomid)%nvars = idvar |
|---|
| 363 | iom_file(kiomid)%cn_var(idvar) = TRIM(cdvar) |
|---|
| 364 | iom_file(kiomid)%nvid(idvar) = -1 ! netcdf variable id is not available in ioipsl |
|---|
| 365 | iom_file(kiomid)%scf(idvar) = 1. |
|---|
| 366 | iom_file(kiomid)%ofs(idvar) = 0. |
|---|
| 367 | iom_file(kiomid)%ndims(idvar) = idims |
|---|
| 368 | IF( .NOT. PRESENT(pv_r0d) ) THEN |
|---|
| 369 | iom_file(kiomid)%luld(idvar) = .TRUE. |
|---|
| 370 | CALL flioinqf( ioipslid, ln_dim = idimsz ) |
|---|
| 371 | iom_file(kiomid)%dimsz(1:idims-1,idvar) = idimsz(idimid(1:idims-1)) |
|---|
| 372 | ELSE |
|---|
| 373 | iom_file(kiomid)%luld(idvar) = .FALSE. |
|---|
| 374 | ENDIF |
|---|
| 375 | IF(lwp) WRITE(numout,*) TRIM(clinfo)//' defined ok' |
|---|
| 376 | ELSE |
|---|
| 377 | idvar = kvid |
|---|
| 378 | ENDIF |
|---|
| 379 | |
|---|
| 380 | ! time step kwrite : write the variable |
|---|
| 381 | IF( kt == kwrite ) THEN |
|---|
| 382 | ! on what kind of domain must the data be written? |
|---|
| 383 | IF( PRESENT(pv_r2d) .OR. PRESENT(pv_r3d) ) THEN |
|---|
| 384 | idimsz(1:2) = iom_file(kiomid)%dimsz(1:2,idvar) |
|---|
| 385 | IF( idimsz(1) == (nlei - nldi + 1) .AND. idimsz(2) == (nlej - nldj + 1) ) THEN |
|---|
| 386 | ix1 = nldi ; ix2 = nlei ; iy1 = nldj ; iy2 = nlej |
|---|
| 387 | ELSEIF( idimsz(1) == nlci .AND. idimsz(2) == nlcj ) THEN |
|---|
| 388 | ix1 = 1 ; ix2 = nlci ; iy1 = 1 ; iy2 = nlcj |
|---|
| 389 | ELSEIF( idimsz(1) == jpi .AND. idimsz(2) == jpj ) THEN |
|---|
| 390 | ix1 = 1 ; ix2 = jpi ; iy1 = 1 ; iy2 = jpj |
|---|
| 391 | ELSE |
|---|
| 392 | CALL ctl_stop( 'iom_ioipsl_rp0123d: should have been an impossible case...' ) |
|---|
| 393 | ENDIF |
|---|
| 394 | |
|---|
| 395 | ! write dimension variables if it is not already done |
|---|
| 396 | ! ============= |
|---|
| 397 | ! trick: is defined to 0 => dimension variable are defined but not yet written |
|---|
| 398 | IF( iom_file(kiomid)%dimsz(1, 1) == 0 ) THEN |
|---|
| 399 | CALL flioputv( ioipslid, 'nav_lon' , glamt(ix1:ix2, iy1:iy2) ) |
|---|
| 400 | CALL flioputv( ioipslid, 'nav_lat' , gphit(ix1:ix2, iy1:iy2) ) |
|---|
| 401 | CALL flioputv( ioipslid, 'nav_lev' , gdept_0 ) |
|---|
| 402 | ! +++ WRONG VALUE: to be improved but not really useful... |
|---|
| 403 | CALL flioputv( ioipslid, 'time_counter', kt ) |
|---|
| 404 | ! update the values of the variables dimensions size |
|---|
| 405 | CALL flioinqf( ioipslid, ln_dim = idimsz ) |
|---|
| 406 | iom_file(kiomid)%dimsz(1:2, 1) = idimsz(1:2) |
|---|
| 407 | iom_file(kiomid)%dimsz(1:2, 2) = idimsz(1:2) |
|---|
| 408 | iom_file(kiomid)%dimsz(1, 3:4) = (/idimsz(3), 1/) |
|---|
| 409 | IF(lwp) WRITE(numout,*) TRIM(clinfo)//' write dimension variables done' |
|---|
| 410 | ENDIF |
|---|
| 411 | ENDIF |
|---|
| 412 | |
|---|
| 413 | ! write the data |
|---|
| 414 | ! ============= |
|---|
| 415 | IF( PRESENT(pv_r0d) ) THEN ; CALL flioputv( ioipslid, cdvar, pv_r0d ) |
|---|
| 416 | ELSEIF( PRESENT(pv_r1d) ) THEN ; CALL flioputv( ioipslid, cdvar, pv_r1d( :) ) |
|---|
| 417 | ELSEIF( PRESENT(pv_r2d) ) THEN ; CALL flioputv( ioipslid, cdvar, pv_r2d(ix1:ix2, iy1:iy2 ) ) |
|---|
| 418 | ELSEIF( PRESENT(pv_r3d) ) THEN ; CALL flioputv( ioipslid, cdvar, pv_r3d(ix1:ix2, iy1:iy2, :) ) |
|---|
| 419 | ENDIF |
|---|
| 420 | ! add 1 to the size of the temporal dimension (not really useful...) |
|---|
| 421 | IF( iom_file(kiomid)%luld(idvar) ) iom_file(kiomid)%dimsz(iom_file(kiomid)%ndims(idvar), idvar) & |
|---|
| 422 | & = iom_file(kiomid)%dimsz(iom_file(kiomid)%ndims(idvar), idvar) + 1 |
|---|
| 423 | IF(lwp) WRITE(numout,*) TRIM(clinfo)//' written ok' |
|---|
| 424 | ENDIF |
|---|
| 425 | ! |
|---|
| 426 | END SUBROUTINE iom_ioipsl_rp0123d |
|---|
| 427 | |
|---|
| 428 | |
|---|
| 429 | !!====================================================================== |
|---|
| 430 | END MODULE iom_ioipsl |
|---|
