New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

limthd_2.F90 in branches/dev_001_SBC/NEMO/LIM_SRC – NEMO

Context Navigation

source: branches/dev_001_SBC/NEMO/LIM_SRC/limthd_2.F90 @ 882

Last change on this file since 882 was 882, checked in by ctlod, 16 years ago
dev_001_SBC: Step II: change effectively the modules names in addining _2 extension, see ticket: #110
Property svn:eol-style set to `native` Property svn:keywords set to `Id`
File size: 25.0 KB

Line
1	MODULE limthd_2
2	!!======================================================================
3	!! * MODULE limthd_2 *
4	!! LIM thermo ice model : ice thermodynamic
5	!!======================================================================
6	!! History : 1.0 ! 00-01 (LIM)
7	!! 2.0 ! 02-07 (C. Ethe, G. Madec) F90
8	!! 2.0 ! 03-08 (C. Ethe) add lim_thd_init
9	!!---------------------------------------------------------------------
10	#if defined key_lim2
11	!!----------------------------------------------------------------------
12	!! 'key_lim2' : LIM 2.0 sea-ice model
13	!!----------------------------------------------------------------------
14	!! lim_thd_2 : thermodynamic of sea ice
15	!! lim_thd_init_2 : initialisation of sea-ice thermodynamic
16	!!----------------------------------------------------------------------
17	USE phycst ! physical constants
18	USE dom_oce ! ocean space and time domain variables
19	USE lbclnk
20	USE in_out_manager ! I/O manager
21	USE ice_2 ! LIM sea-ice variables
22	USE ice_oce ! sea-ice/ocean variables
23	USE sbc_oce !
24	USE sbc_ice !
25	USE thd_ice_2 ! LIM thermodynamic sea-ice variables
26	USE dom_ice_2 ! LIM sea-ice domain
27	USE iceini_2
28	USE limthd_zdf_2
29	USE limthd_lac_2
30	USE limtab_2
31	USE prtctl ! Print control
32
33	IMPLICIT NONE
34	PRIVATE
35
36	PUBLIC lim_thd_2 ! called by lim_step
37
38	REAL(wp) :: epsi20 = 1.e-20 , & ! constant values
39	& epsi16 = 1.e-16 , &
40	& epsi04 = 1.e-04 , &
41	& zzero = 0.e0 , &
42	& zone = 1.e0
43
44	!! * Substitutions
45	# include "domzgr_substitute.h90"
46	# include "vectopt_loop_substitute.h90"
47	!!-------- -------------------------------------------------------------
48	!! LIM 2.0, UCL-LOCEAN-IPSL (2005)
49	!! $Id$
50	!! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
51	!!----------------------------------------------------------------------
52
53	CONTAINS
54
55	SUBROUTINE lim_thd_2( kt )
56	!!-------------------------------------------------------------------
57	!! * ROUTINE lim_thd_2 *
58	!!
59	!! ** Purpose : This routine manages the ice thermodynamic.
60	!!
61	!! ** Action : - Initialisation of some variables
62	!! - Some preliminary computation (oceanic heat flux
63	!! at the ice base, snow acc.,heat budget of the leads)
64	!! - selection of the icy points and put them in an array
65	!! - call lim_vert_ther for vert ice thermodynamic
66	!! - back to the geographic grid
67	!! - selection of points for lateral accretion
68	!! - call lim_lat_acc for the ice accretion
69	!! - back to the geographic grid
70	!!
71	!! References : Goosse et al. 1996, Bul. Soc. Roy. Sc. Liege, 65, 87-90
72	!!---------------------------------------------------------------------
73	INTEGER, INTENT(in) :: kt ! number of iteration
74	!!
75	INTEGER :: ji, jj, & ! dummy loop indices
76	nbpb , & ! nb of icy pts for thermo. cal.
77	nbpac ! nb of pts for lateral accretion
78	CHARACTER (len=22) :: charout
79	REAL(wp) :: &
80	zfric_umin = 5e-03 , & ! lower bound for the friction velocity
81	zfric_umax = 2e-02 ! upper bound for the friction velocity
82	REAL(wp) :: &
83	zinda , & ! switch for test. the val. of concen.
84	zindb, zindg , & ! switches for test. the val of arg
85	za , zh, zthsnice , &
86	zfric_u , & ! friction velocity
87	zfnsol , & ! total non solar heat
88	zfontn , & ! heat flux from snow thickness
89	zfntlat, zpareff ! test. the val. of lead heat budget
90	REAL(wp), DIMENSION(jpi,jpj) :: zhicifp, & ! ice thickness for outputs
91	& zqlbsbq ! link with lead energy budget qldif
92	REAL(wp), DIMENSION(jpi,jpj,jpk) :: zmsk ! working array
93	!!-------------------------------------------------------------------
94
95	IF( kt == nit000 ) CALL lim_thd_init_2 ! Initialization (first time-step only)
96
97	!-------------------------------------------!
98	! Initilization of diagnostic variables !
99	!-------------------------------------------!
100
101	!i est-ce utile? oui au moins en partie
102	rdvosif(:,:) = 0.e0 ! variation of ice volume at surface
103	rdvobif(:,:) = 0.e0 ! variation of ice volume at bottom
104	fdvolif(:,:) = 0.e0 ! total variation of ice volume
105	rdvonif(:,:) = 0.e0 ! lateral variation of ice volume
106	fstric (:,:) = 0.e0 ! part of solar radiation absorbing inside the ice
107	fscmbq (:,:) = 0.e0 ! linked with fstric
108	ffltbif(:,:) = 0.e0 ! linked with fstric
109	qfvbq (:,:) = 0.e0 ! linked with fstric
110	rdmsnif(:,:) = 0.e0 ! variation of snow mass per unit area
111	rdmicif(:,:) = 0.e0 ! variation of ice mass per unit area
112	hicifp (:,:) = 0.e0 ! daily thermodynamic ice production.
113	zmsk (:,:,:) = 0.e0
114
115	DO jj = 1, jpj
116	DO ji = 1, jpi
117	hsnif(ji,jj) = hsnif(ji,jj) * MAX( zzero, SIGN( zone , hsnif(ji,jj) - epsi04 ) )
118	END DO
119	END DO
120
121	IF(ln_ctl) CALL prt_ctl(tab2d_1=hsnif , clinfo1=' lim_thd: hsnif : ')
122
123	!-----------------------------------!
124	! Treatment of particular cases !
125	!-----------------------------------!
126
127	DO jj = 1, jpj
128	DO ji = 1, jpi
129	! snow is transformed into ice if the original ice cover disappears.
130	zindg = tms(ji,jj) * MAX( zzero , SIGN( zone , -hicif(ji,jj) ) )
131	hicif(ji,jj) = hicif(ji,jj) + zindg * rhosn * hsnif(ji,jj) / rau0
132	hsnif(ji,jj) = ( zone - zindg ) * hsnif(ji,jj) + zindg * hicif(ji,jj) * ( rau0 - rhoic ) / rhosn
133	dmgwi(ji,jj) = zindg * (1.0 - frld(ji,jj)) * rhoic * hicif(ji,jj) ! snow/ice mass
134
135	! the lead fraction, frld, must be little than or equal to amax (ice ridging).
136	zthsnice = hsnif(ji,jj) + hicif(ji,jj)
137	zindb = tms(ji,jj) * ( 1.0 - MAX( zzero , SIGN( zone , - zthsnice ) ) )
138	za = zindb * MIN( zone, ( 1.0 - frld(ji,jj) ) * uscomi )
139	hsnif (ji,jj) = hsnif(ji,jj) * za
140	hicif (ji,jj) = hicif(ji,jj) * za
141	qstoif(ji,jj) = qstoif(ji,jj) * za
142	frld (ji,jj) = 1.0 - zindb * ( 1.0 - frld(ji,jj) ) / MAX( za , epsi20 )
143
144	! the in situ ice thickness, hicif, must be equal to or greater than hiclim.
145	zh = MAX( zone , zindb * hiclim / MAX( hicif(ji,jj) , epsi20 ) )
146	hsnif (ji,jj) = hsnif(ji,jj) * zh
147	hicif (ji,jj) = hicif(ji,jj) * zh
148	qstoif(ji,jj) = qstoif(ji,jj) * zh
149	frld (ji,jj) = ( frld(ji,jj) + ( zh - 1.0 ) ) / zh
150	END DO
151	END DO
152
153	IF(ln_ctl) THEN
154	CALL prt_ctl(tab2d_1=hicif , clinfo1=' lim_thd: hicif : ')
155	CALL prt_ctl(tab2d_1=hsnif , clinfo1=' lim_thd: hsnif : ')
156	CALL prt_ctl(tab2d_1=dmgwi , clinfo1=' lim_thd: dmgwi : ')
157	CALL prt_ctl(tab2d_1=qstoif , clinfo1=' lim_thd: qstoif : ')
158	CALL prt_ctl(tab2d_1=frld , clinfo1=' lim_thd: frld : ')
159	ENDIF
160
161
162	!-------------------------------!
163	! Thermodynamics of sea ice !
164	!-------------------------------!
165
166	! Partial computation of forcing for the thermodynamic sea ice model.
167	!--------------------------------------------------------------------------
168
169	sst_m(:,:) = sst_m(:,:) + rt0
170
171	!CDIR NOVERRCHK
172	DO jj = 1, jpj
173	!CDIR NOVERRCHK
174	DO ji = 1, jpi
175	zthsnice = hsnif(ji,jj) + hicif(ji,jj)
176	zindb = tms(ji,jj) * ( 1.0 - MAX( zzero , SIGN( zone , - zthsnice ) ) )
177	pfrld(ji,jj) = frld(ji,jj)
178	zinda = 1.0 - MAX( zzero , SIGN( zone , - ( 1.0 - pfrld(ji,jj) ) ) )
179
180	! solar irradiance transmission at the mixed layer bottom and used in the lead heat budget
181	thcm(ji,jj) = 0.e0
182
183	! net downward heat flux from the ice to the ocean, expressed as a function of ocean
184	! temperature and turbulent mixing (McPhee, 1992)
185	zfric_u = MAX ( MIN( SQRT( ust2s(ji,jj) ) , zfric_umax ) , zfric_umin ) ! friction velocity
186	fdtcn(ji,jj) = zindb * rau0 * rcp * 0.006 * zfric_u * ( sst_m(ji,jj) - tfu(ji,jj) )
187	qdtcn(ji,jj) = zindb * fdtcn(ji,jj) * frld(ji,jj) * rdt_ice
188
189	! partial computation of the lead energy budget (qldif)
190	zfontn = ( sprecip(ji,jj) / rhosn ) * xlsn ! energy for melting
191	zfnsol = qns(ji,jj) ! total non solar flux over the ocean
192	qldif(ji,jj) = tms(ji,jj) * ( qsr(ji,jj) * ( 1.0 - thcm(ji,jj) ) &
193	& + zfnsol + fdtcn(ji,jj) - zfontn &
194	& + ( 1.0 - zindb ) * fsbbq(ji,jj) ) &
195	& * frld(ji,jj) * rdt_ice
196	! parlat : percentage of energy used for lateral ablation (0.0)
197	zfntlat = 1.0 - MAX( zzero , SIGN( zone , - qldif(ji,jj) ) )
198	zpareff = 1.0 + ( parlat - 1.0 ) * zinda * zfntlat
199	zqlbsbq(ji,jj) = qldif(ji,jj) * ( 1.0 - zpareff ) / MAX( (1.0 - frld(ji,jj)) * rdt_ice , epsi16 )
200	qldif (ji,jj) = zpareff * qldif(ji,jj)
201	qdtcn (ji,jj) = zpareff * qdtcn(ji,jj)
202
203	! energy needed to bring ocean surface layer until its freezing
204	qcmif (ji,jj) = rau0 * rcp * fse3t(ji,jj,1) * ( tfu(ji,jj) - sst_m(ji,jj) ) * ( 1 - zinda )
205
206	! calculate oceanic heat flux.
207	fbif (ji,jj) = zindb * ( fsbbq(ji,jj) / MAX( (1.0 - frld(ji,jj)) , epsi20 ) + fdtcn(ji,jj) )
208
209	! computation of the daily thermodynamic ice production (only needed for output)
210	zhicifp(ji,jj) = hicif(ji,jj) * ( 1.0 - frld(ji,jj) )
211	END DO
212	END DO
213
214	sst_m(:,:) = sst_m(:,:) - rt0
215
216	! Select icy points and fulfill arrays for the vectorial grid.
217	!----------------------------------------------------------------------
218	nbpb = 0
219	DO jj = 1, jpj
220	DO ji = 1, jpi
221	IF ( frld(ji,jj) < 1.0 ) THEN
222	nbpb = nbpb + 1
223	npb(nbpb) = (jj - 1) * jpi + ji
224	ENDIF
225	END DO
226	END DO
227
228	IF(ln_ctl) THEN
229	CALL prt_ctl(tab2d_1=pfrld, clinfo1=' lim_thd: pfrld : ', tab2d_2=thcm , clinfo2=' thcm : ')
230	CALL prt_ctl(tab2d_1=fdtcn, clinfo1=' lim_thd: fdtcn : ', tab2d_2=qdtcn , clinfo2=' qdtcn : ')
231	CALL prt_ctl(tab2d_1=qldif, clinfo1=' lim_thd: qldif : ', tab2d_2=zqlbsbq, clinfo2=' zqlbsbq : ')
232	CALL prt_ctl(tab2d_1=qcmif, clinfo1=' lim_thd: qcmif : ', tab2d_2=fbif , clinfo2=' fbif : ')
233	zmsk(:,:,1) = tms(:,:)
234	CALL prt_ctl(tab2d_1=qcmif , clinfo1=' lim_thd: qcmif : ', mask1=zmsk)
235	CALL prt_ctl(tab2d_1=zhicifp, clinfo1=' lim_thd: zhicifp : ')
236	WRITE(charout, FMT="('lim_thd: nbpb = ',I4)") nbpb
237	CALL prt_ctl_info(charout)
238	ENDIF
239
240
241	! If there is no ice, do nothing. Otherwise, compute Top and Bottom accretion/ablation
242	!------------------------------------------------------------------------------------
243
244	IF ( nbpb > 0) THEN
245
246	! put the variable in a 1-D array for thermodynamics process
247	CALL tab_2d_1d_2( nbpb, frld_1d (1:nbpb) , frld , jpi, jpj, npb(1:nbpb) )
248	CALL tab_2d_1d_2( nbpb, h_ice_1d (1:nbpb) , hicif , jpi, jpj, npb(1:nbpb) )
249	CALL tab_2d_1d_2( nbpb, h_snow_1d (1:nbpb) , hsnif , jpi, jpj, npb(1:nbpb) )
250	CALL tab_2d_1d_2( nbpb, sist_1d (1:nbpb) , sist , jpi, jpj, npb(1:nbpb) )
251	CALL tab_2d_1d_2( nbpb, tbif_1d (1:nbpb , 1 ), tbif(:,:,1), jpi, jpj, npb(1:nbpb) )
252	CALL tab_2d_1d_2( nbpb, tbif_1d (1:nbpb , 2 ), tbif(:,:,2), jpi, jpj, npb(1:nbpb) )
253	CALL tab_2d_1d_2( nbpb, tbif_1d (1:nbpb , 3 ), tbif(:,:,3), jpi, jpj, npb(1:nbpb) )
254	CALL tab_2d_1d_2( nbpb, qsr_ice_1d (1:nbpb) , qsr_ice , jpi, jpj, npb(1:nbpb) )
255	CALL tab_2d_1d_2( nbpb, fr1_i0_1d (1:nbpb) , fr1_i0 , jpi, jpj, npb(1:nbpb) )
256	CALL tab_2d_1d_2( nbpb, fr2_i0_1d (1:nbpb) , fr2_i0 , jpi, jpj, npb(1:nbpb) )
257	CALL tab_2d_1d_2( nbpb, qns_ice_1d (1:nbpb) , qns_ice , jpi, jpj, npb(1:nbpb) )
258	#if ! defined key_coupled
259	CALL tab_2d_1d_2( nbpb, qla_ice_1d (1:nbpb) , qla_ice , jpi, jpj, npb(1:nbpb) )
260	CALL tab_2d_1d_2( nbpb, dqla_ice_1d(1:nbpb) , dqla_ice , jpi, jpj, npb(1:nbpb) )
261	#endif
262	CALL tab_2d_1d_2( nbpb, dqns_ice_1d(1:nbpb) , dqns_ice , jpi, jpj, npb(1:nbpb) )
263	CALL tab_2d_1d_2( nbpb, tfu_1d (1:nbpb) , tfu , jpi, jpj, npb(1:nbpb) )
264	CALL tab_2d_1d_2( nbpb, sprecip_1d (1:nbpb) , sprecip , jpi, jpj, npb(1:nbpb) )
265	CALL tab_2d_1d_2( nbpb, fbif_1d (1:nbpb) , fbif , jpi, jpj, npb(1:nbpb) )
266	CALL tab_2d_1d_2( nbpb, thcm_1d (1:nbpb) , thcm , jpi, jpj, npb(1:nbpb) )
267	CALL tab_2d_1d_2( nbpb, qldif_1d (1:nbpb) , qldif , jpi, jpj, npb(1:nbpb) )
268	CALL tab_2d_1d_2( nbpb, qstbif_1d (1:nbpb) , qstoif , jpi, jpj, npb(1:nbpb) )
269	CALL tab_2d_1d_2( nbpb, rdmicif_1d (1:nbpb) , rdmicif , jpi, jpj, npb(1:nbpb) )
270	CALL tab_2d_1d_2( nbpb, dmgwi_1d (1:nbpb) , dmgwi , jpi, jpj, npb(1:nbpb) )
271	CALL tab_2d_1d_2( nbpb, qlbbq_1d (1:nbpb) , zqlbsbq , jpi, jpj, npb(1:nbpb) )
272
273	CALL lim_thd_zdf_2( 1, nbpb ) ! compute ice growth
274
275	! back to the geographic grid.
276	CALL tab_1d_2d_2( nbpb, frld , npb, frld_1d (1:nbpb) , jpi, jpj )
277	CALL tab_1d_2d_2( nbpb, hicif , npb, h_ice_1d (1:nbpb) , jpi, jpj )
278	CALL tab_1d_2d_2( nbpb, hsnif , npb, h_snow_1d (1:nbpb) , jpi, jpj )
279	CALL tab_1d_2d_2( nbpb, sist , npb, sist_1d (1:nbpb) , jpi, jpj )
280	CALL tab_1d_2d_2( nbpb, tbif(:,:,1), npb, tbif_1d (1:nbpb , 1 ), jpi, jpj )
281	CALL tab_1d_2d_2( nbpb, tbif(:,:,2), npb, tbif_1d (1:nbpb , 2 ), jpi, jpj )
282	CALL tab_1d_2d_2( nbpb, tbif(:,:,3), npb, tbif_1d (1:nbpb , 3 ), jpi, jpj )
283	CALL tab_1d_2d_2( nbpb, fscmbq , npb, fscbq_1d (1:nbpb) , jpi, jpj )
284	CALL tab_1d_2d_2( nbpb, ffltbif , npb, fltbif_1d (1:nbpb) , jpi, jpj )
285	CALL tab_1d_2d_2( nbpb, fstric , npb, fstbif_1d (1:nbpb) , jpi, jpj )
286	CALL tab_1d_2d_2( nbpb, qldif , npb, qldif_1d (1:nbpb) , jpi, jpj )
287	CALL tab_1d_2d_2( nbpb, qfvbq , npb, qfvbq_1d (1:nbpb) , jpi, jpj )
288	CALL tab_1d_2d_2( nbpb, qstoif , npb, qstbif_1d (1:nbpb) , jpi, jpj )
289	CALL tab_1d_2d_2( nbpb, rdmicif , npb, rdmicif_1d(1:nbpb) , jpi, jpj )
290	CALL tab_1d_2d_2( nbpb, dmgwi , npb, dmgwi_1d (1:nbpb) , jpi, jpj )
291	CALL tab_1d_2d_2( nbpb, rdmsnif , npb, rdmsnif_1d(1:nbpb) , jpi, jpj )
292	CALL tab_1d_2d_2( nbpb, rdvosif , npb, dvsbq_1d (1:nbpb) , jpi, jpj )
293	CALL tab_1d_2d_2( nbpb, rdvobif , npb, dvbbq_1d (1:nbpb) , jpi, jpj )
294	CALL tab_1d_2d_2( nbpb, fdvolif , npb, dvlbq_1d (1:nbpb) , jpi, jpj )
295	CALL tab_1d_2d_2( nbpb, rdvonif , npb, dvnbq_1d (1:nbpb) , jpi, jpj )
296
297
298	ENDIF
299
300
301	! Up-date sea ice thickness.
302	!---------------------------------
303	DO jj = 1, jpj
304	DO ji = 1, jpi
305	phicif(ji,jj) = hicif(ji,jj)
306	hicif(ji,jj) = hicif(ji,jj) * ( zone - MAX( zzero, SIGN( zone, - ( 1.0 - frld(ji,jj) ) ) ) )
307	END DO
308	END DO
309
310
311	! Tricky trick : add 2 to frld in the Southern Hemisphere.
312	!----------------------------------------------------------
313	IF( fcor(1,1) < 0.e0 ) THEN
314	DO jj = 1, njeqm1
315	DO ji = 1, jpi
316	frld(ji,jj) = frld(ji,jj) + 2.0
317	END DO
318	END DO
319	ENDIF
320
321
322	! Select points for lateral accretion (this occurs when heat exchange
323	! between ice and ocean is negative; ocean losing heat)
324	!-----------------------------------------------------------------
325	nbpac = 0
326	DO jj = 1, jpj
327	DO ji = 1, jpi
328	!i yes! IF ( ( qcmif(ji,jj) - qldif(ji,jj) ) > 0.e0 ) THEN
329	IF ( tms(ji,jj) * ( qcmif(ji,jj) - qldif(ji,jj) ) > 0.e0 ) THEN
330	nbpac = nbpac + 1
331	npac( nbpac ) = (jj - 1) * jpi + ji
332	ENDIF
333	END DO
334	END DO
335
336	IF(ln_ctl) THEN
337	CALL prt_ctl(tab2d_1=phicif, clinfo1=' lim_thd: phicif : ', tab2d_2=hicif, clinfo2=' hicif : ')
338	WRITE(charout, FMT="('lim_thd: nbpac = ',I4)") nbpac
339	CALL prt_ctl_info(charout)
340	ENDIF
341
342
343	!
344	! If ocean gains heat do nothing ; otherwise, one performs lateral accretion
345	!--------------------------------------------------------------------------------
346
347	IF( nbpac > 0 ) THEN
348
349	!...Put the variable in a 1-D array for lateral accretion
350	CALL tab_2d_1d_2( nbpac, frld_1d (1:nbpac) , frld , jpi, jpj, npac(1:nbpac) )
351	CALL tab_2d_1d_2( nbpac, h_snow_1d (1:nbpac) , hsnif , jpi, jpj, npac(1:nbpac) )
352	CALL tab_2d_1d_2( nbpac, h_ice_1d (1:nbpac) , hicif , jpi, jpj, npac(1:nbpac) )
353	CALL tab_2d_1d_2( nbpac, tbif_1d (1:nbpac , 1 ), tbif(:,:,1), jpi, jpj, npac(1:nbpac) )
354	CALL tab_2d_1d_2( nbpac, tbif_1d (1:nbpac , 2 ), tbif(:,:,2), jpi, jpj, npac(1:nbpac) )
355	CALL tab_2d_1d_2( nbpac, tbif_1d (1:nbpac , 3 ), tbif(:,:,3), jpi, jpj, npac(1:nbpac) )
356	CALL tab_2d_1d_2( nbpac, qldif_1d (1:nbpac) , qldif , jpi, jpj, npac(1:nbpac) )
357	CALL tab_2d_1d_2( nbpac, qcmif_1d (1:nbpac) , qcmif , jpi, jpj, npac(1:nbpac) )
358	CALL tab_2d_1d_2( nbpac, qstbif_1d (1:nbpac) , qstoif , jpi, jpj, npac(1:nbpac) )
359	CALL tab_2d_1d_2( nbpac, rdmicif_1d(1:nbpac) , rdmicif , jpi, jpj, npac(1:nbpac) )
360	CALL tab_2d_1d_2( nbpac, dvlbq_1d (1:nbpac) , fdvolif , jpi, jpj, npac(1:nbpac) )
361	CALL tab_2d_1d_2( nbpac, tfu_1d (1:nbpac) , tfu , jpi, jpj, npac(1:nbpac) )
362
363	! call lateral accretion routine.
364	CALL lim_thd_lac_2( 1 , nbpac )
365
366	! back to the geographic grid
367	CALL tab_1d_2d_2( nbpac, frld , npac(1:nbpac), frld_1d (1:nbpac) , jpi, jpj )
368	CALL tab_1d_2d_2( nbpac, hsnif , npac(1:nbpac), h_snow_1d (1:nbpac) , jpi, jpj )
369	CALL tab_1d_2d_2( nbpac, hicif , npac(1:nbpac), h_ice_1d (1:nbpac) , jpi, jpj )
370	CALL tab_1d_2d_2( nbpac, tbif(:,:,1), npac(1:nbpac), tbif_1d (1:nbpac , 1 ), jpi, jpj )
371	CALL tab_1d_2d_2( nbpac, tbif(:,:,2), npac(1:nbpac), tbif_1d (1:nbpac , 2 ), jpi, jpj )
372	CALL tab_1d_2d_2( nbpac, tbif(:,:,3), npac(1:nbpac), tbif_1d (1:nbpac , 3 ), jpi, jpj )
373	CALL tab_1d_2d_2( nbpac, qstoif , npac(1:nbpac), qstbif_1d (1:nbpac) , jpi, jpj )
374	CALL tab_1d_2d_2( nbpac, rdmicif , npac(1:nbpac), rdmicif_1d(1:nbpac) , jpi, jpj )
375	CALL tab_1d_2d_2( nbpac, fdvolif , npac(1:nbpac), dvlbq_1d (1:nbpac) , jpi, jpj )
376
377	ENDIF
378
379
380	! Recover frld values between 0 and 1 in the Southern Hemisphere (tricky trick)
381	! Update daily thermodynamic ice production.
382	!------------------------------------------------------------------------------
383
384	DO jj = 1, jpj
385	DO ji = 1, jpi
386	frld (ji,jj) = MIN( frld(ji,jj), ABS( frld(ji,jj) - 2.0 ) )
387	hicifp(ji,jj) = hicif(ji,jj) * ( 1.0 - frld(ji,jj) ) - zhicifp(ji,jj) + hicifp(ji,jj)
388	END DO
389	END DO
390
391	IF(ln_ctl) THEN
392	CALL prt_ctl_info(' lim_thd end ')
393	CALL prt_ctl(tab2d_1=hicif , clinfo1=' lim_thd: hicif : ', tab2d_2=hsnif , clinfo2=' hsnif : ')
394	CALL prt_ctl(tab2d_1=frld , clinfo1=' lim_thd: frld : ', tab2d_2=hicifp, clinfo2=' hicifp : ')
395	CALL prt_ctl(tab2d_1=phicif, clinfo1=' lim_thd: phicif : ', tab2d_2=pfrld , clinfo2=' pfrld : ')
396	CALL prt_ctl(tab2d_1=sist , clinfo1=' lim_thd: sist : ')
397	CALL prt_ctl(tab2d_1=tbif(:,:,1), clinfo1=' lim_thd: tbif 1 : ')
398	CALL prt_ctl(tab2d_1=tbif(:,:,2), clinfo1=' lim_thd: tbif 2 : ')
399	CALL prt_ctl(tab2d_1=tbif(:,:,3), clinfo1=' lim_thd: tbif 3 : ')
400	CALL prt_ctl(tab2d_1=fdtcn , clinfo1=' lim_thd: fdtcn : ', tab2d_2=qdtcn , clinfo2=' qdtcn : ')
401	CALL prt_ctl(tab2d_1=qstoif, clinfo1=' lim_thd: qstoif : ', tab2d_2=fsbbq , clinfo2=' fsbbq : ')
402	ENDIF
403	!
404	END SUBROUTINE lim_thd_2
405
406
407	SUBROUTINE lim_thd_init_2
408	!!-------------------------------------------------------------------
409	!! * ROUTINE lim_thd_init_2 *
410	!!
411	!! ** Purpose : Physical constants and parameters linked to the ice
412	!! thermodynamics
413	!!
414	!! ** Method : Read the namicethd namelist and check the ice-thermo
415	!! parameter values called at the first timestep (nit000)
416	!!
417	!! ** input : Namelist namicether
418	!!-------------------------------------------------------------------
419	NAMELIST/namicethd/ hmelt , hiccrit, hicmin, hiclim, amax , &
420	& swiqst, sbeta , parlat, hakspl, hibspl, exld, &
421	& hakdif, hnzst , thth , parsub, alphs
422	!!-------------------------------------------------------------------
423
424
425	! Define the initial parameters
426	! -------------------------
427	REWIND( numnam_ice )
428	READ ( numnam_ice , namicethd )
429	IF(lwp) THEN
430	WRITE(numout,*)
431	WRITE(numout,*)'lim_thd_init_2: ice parameters for ice thermodynamic computation '
432	WRITE(numout,*)'~~~~~~~~~~~~~~'
433	WRITE(numout,*)' maximum melting at the bottom hmelt = ', hmelt
434	WRITE(numout,*)' ice thick. for lateral accretion in NH (SH) hiccrit(1/2) = ', hiccrit
435	WRITE(numout,*)' ice thick. corr. to max. energy stored in brine pocket hicmin = ', hicmin
436	WRITE(numout,*)' minimum ice thickness hiclim = ', hiclim
437	WRITE(numout,*)' maximum lead fraction amax = ', amax
438	WRITE(numout,*)' energy stored in brine pocket (=1) or not (=0) swiqst = ', swiqst
439	WRITE(numout,*)' numerical carac. of the scheme for diffusion in ice '
440	WRITE(numout,*)' Cranck-Nicholson (=0.5), implicit (=1), explicit (=0) sbeta = ', sbeta
441	WRITE(numout,*)' percentage of energy used for lateral ablation parlat = ', parlat
442	WRITE(numout,*)' slope of distr. for Hakkinen-Mellor lateral melting hakspl = ', hakspl
443	WRITE(numout,*)' slope of distribution for Hibler lateral melting hibspl = ', hibspl
444	WRITE(numout,*)' exponent for leads-closure rate exld = ', exld
445	WRITE(numout,*)' coefficient for diffusions of ice and snow hakdif = ', hakdif
446	WRITE(numout,*)' threshold thick. for comp. of eq. thermal conductivity zhth = ', thth
447	WRITE(numout,*)' thickness of the surf. layer in temp. computation hnzst = ', hnzst
448	WRITE(numout,*)' switch for snow sublimation (=1) or not (=0) parsub = ', parsub
449	WRITE(numout,*)' coefficient for snow density when snow ice formation alphs = ', alphs
450	ENDIF
451
452	uscomi = 1.0 / ( 1.0 - amax ) ! inverse of minimum lead fraction
453	rcdsn = hakdif * rcdsn
454	rcdic = hakdif * rcdic
455
456	IF ( ( hsndif > 100.e0 ) .OR. ( hicdif > 100.e0 ) ) THEN
457	cnscg = 0.e0
458	ELSE
459	cnscg = rcpsn / rcpic ! ratio rcpsn/rcpic
460	ENDIF
461
462	END SUBROUTINE lim_thd_init_2
463
464	#else
465	!!----------------------------------------------------------------------
466	!! Default option Dummy module NO LIM 2.0 sea-ice model
467	!!----------------------------------------------------------------------
468	CONTAINS
469	SUBROUTINE lim_thd_2 ! Dummy routine
470	END SUBROUTINE lim_thd_2
471	#endif
472
473	!!======================================================================
474	END MODULE limthd_2

Note: See TracBrowser for help on using the repository browser.

Download in other formats: