New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zche.F90 in branches/dev_005_AWL/NEMO/TOP_SRC/PISCES – NEMO

source: branches/dev_005_AWL/NEMO/TOP_SRC/PISCES/p4zche.F90 @ 1804

Last change on this file since 1804 was 1804, checked in by sga, 14 years ago

merge of trunk changes from r1782 to r1802 into NEMO branch dev_005_AWL

  • Property svn:executable set to *
  • Property svn:keywords set to Id
File size: 13.6 KB
Line 
1MODULE p4zche
2   !!======================================================================
3   !!                         ***  MODULE p4zche  ***
4   !! TOP :   PISCES Sea water chemistry computed following OCMIP protocol
5   !!======================================================================
6   !! History :    -   !  1988     (E. Maier-Reimer)  Original code
7   !!              -   !  1998     (O. Aumont)  addition
8   !!              -   !  1999     (C. Le Quere)  modification
9   !!             1.0  !  2004     (O. Aumont)  modification
10   !!              -   !  2006     (R. Gangsto)  modification
11   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
12   !!----------------------------------------------------------------------
13#if defined key_pisces
14   !!----------------------------------------------------------------------
15   !!   'key_pisces'                                       PISCES bio-model
16   !!----------------------------------------------------------------------
17   !!   p4z_che        :  Sea water chemistry computed following OCMIP protocol
18   !!----------------------------------------------------------------------
19   USE oce_trc         !
20   USE trc         !
21   USE sms_pisces      !
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC   p4z_che 
27
28   !! * Shared module variables
29   REAL(wp), PUBLIC, DIMENSION(jpi,jpj,jpk) ::   &   !:
30      sio3eq, fekeq           !: chemistry of Fe and Si
31
32   REAL(wp), PUBLIC, DIMENSION(jpi,jpj,2)   ::   &   !:
33      chemc                   !: Solubilities of O2 and CO2
34
35   !! * Module variables
36
37   REAL(wp) :: &
38      salchl = 1./1.80655 ! conversion factor for salinity --> chlorinity (Wooster et al. 1969)
39
40   REAL(wp) :: &            ! coeff. for apparent solubility equilibrium
41      akcc1 = -171.9065 , &    ! Millero et al. 1995 from Mucci 1983
42      akcc2 = -0.077993 , & 
43      akcc3 = 2839.319  , & 
44      akcc4 = 71.595    , & 
45      akcc5 = -0.77712  , & 
46      akcc6 = 0.0028426 , & 
47      akcc7 = 178.34    , & 
48      akcc8 = -0.07711  , & 
49      akcc9 = 0.0041249
50
51   REAL(wp) :: &             ! universal gas constants
52      rgas = 83.143, &
53      oxyco = 1./22.4144
54
55   REAL(wp) :: &             ! borat constants
56      bor1 = 0.00023, &
57      bor2 = 1./10.82
58
59   REAL(wp) :: &              !
60      ca0 = -162.8301  , &
61      ca1 = 218.2968   , &
62      ca2 = 90.9241    , &
63      ca3 = -1.47696   , &
64      ca4 = 0.025695   , &
65      ca5 = -0.025225  , &
66      ca6 = 0.0049867
67
68   REAL(wp) :: &              ! coeff. for 1. dissoc. of carbonic acid (Edmond and Gieskes, 1970)   
69      c10 = -3670.7   , &
70      c11 = 62.008    , &
71      c12 = -9.7944   , &
72      c13 = 0.0118    , &
73      c14 = -0.000116
74
75   REAL(wp) :: &              ! coeff. for 2. dissoc. of carbonic acid (Millero, 1995)   
76      c20 = -1394.7   , &
77      c21 = -4.777    , &
78      c22 = 0.0184    , &
79      c23 = -0.000118
80
81   REAL(wp) :: &             ! constants for calculate concentrations
82      st1  = 0.14     , &    ! for sulfate (Morris & Riley 1966)
83      st2  = 1./96.062, &
84      ks0  = 141.328  , &
85      ks1  = -4276.1  , &
86      ks2  = -23.093  , &
87      ks3  = -13856.  , &
88      ks4  = 324.57   , &
89      ks5  = -47.986  , &
90      ks6  = 35474.   , &
91      ks7  = -771.54  , &
92      ks8  = 114.723  , &
93      ks9  = -2698.   , &
94      ks10 = 1776.    , &
95      ks11 = 1.       , &
96      ks12 = -0.001005 
97
98   REAL(wp) :: &             ! constants for calculate concentrations
99      ft1  = 0.000067   , &  ! fluorides (Dickson & Riley 1979 )
100      ft2  = 1./18.9984 , &
101      kf0  = -12.641    , &
102      kf1  = 1590.2     , &
103      kf2  = 1.525      , &
104      kf3  = 1.0        , &
105      kf4  =-0.001005
106
107   REAL(wp) :: &              ! coeff. for 1. dissoc. of boric acid (Dickson and Goyet, 1994)
108      cb0  = -8966.90, &
109      cb1  = -2890.53, &
110      cb2  = -77.942 , &
111      cb3  = 1.728   , &
112      cb4  = -0.0996 , &
113      cb5  = 148.0248, &
114      cb6  = 137.1942, &
115      cb7  = 1.62142 , &
116      cb8  = -24.4344, &
117      cb9  = -25.085 , &
118      cb10 = -0.2474 , &
119      cb11 = 0.053105
120
121   REAL(wp) :: &             ! coeff. for dissoc. of water (Dickson and Riley, 1979 )
122      cw0 = -13847.26  , &
123      cw1 = 148.9652   , &
124      cw2 = -23.6521   , &
125      cw3 = 118.67     , &
126      cw4 = -5.977     , &
127      cw5 = 1.0495     , &
128      cw6 = -0.01615
129 
130   REAL(wp) :: &              ! volumetric solubility constants for o2 in ml/l (Weiss, 1974)
131      ox0 = -58.3877   , &
132      ox1 = 85.8079    , &
133      ox2 = 23.8439    , &
134      ox3 = -0.034892  , &
135      ox4 = 0.015568   , &
136      ox5 = -0.0019387 
137
138   REAL(wp), DIMENSION(5)  :: &  ! coeff. for seawater pressure correction
139      devk1, devk2, devk3,    &  ! (millero 95)
140      devk4, devk5
141
142   DATA devk1 / -25.5    , -15.82    , -29.48  , -25.60     , -48.76    /   
143   DATA devk2 / 0.1271   , -0.0219   , 0.1622  , 0.2324     , 0.5304    /   
144   DATA devk3 / 0.       , 0.        , 2.608E-3,  -3.6246E-3, 0.        /   
145   DATA devk4 / -3.08E-3 , 1.13E-3   , -2.84E-3, -5.13E-3   , -11.76E-3 /   
146   DATA devk5 / 0.0877E-3, -0.1475E-3,  0.     , 0.0794E-3  , 0.3692E-3 /
147
148   !!* Substitution
149#include "top_substitute.h90"
150   !!----------------------------------------------------------------------
151   !! NEMO/TOP 2.0 , LOCEAN-IPSL (2007)
152   !! $Id$
153   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
154   !!----------------------------------------------------------------------
155
156CONTAINS
157
158   SUBROUTINE p4z_che
159      !!---------------------------------------------------------------------
160      !!                     ***  ROUTINE p4z_che  ***
161      !!
162      !! ** Purpose :   Sea water chemistry computed following OCMIP protocol
163      !!
164      !! ** Method  : - ...
165      !!---------------------------------------------------------------------
166      INTEGER  ::   ji, jj, jk
167      REAL(wp) ::   ztkel, zsal , zqtt  , zbuf1 , zbuf2
168      REAL(wp) ::   zpres, ztc  , zcl   , zcpexp, zoxy  , zcpexp2
169      REAL(wp) ::   zsqrt, ztr  , zlogt , zcek1
170      REAL(wp) ::   zlqtt, zqtt2, zsal15, zis   , zis2 , zisqrt
171      REAL(wp) ::   zckb , zck1 , zck2  , zckw  , zak1 , zak2  , zakb , zaksp0, zakw
172      REAL(wp) ::   zst  , zft  , zcks  , zckf  , zaksp1
173      !!---------------------------------------------------------------------
174
175      ! CHEMICAL CONSTANTS - SURFACE LAYER
176      ! ----------------------------------
177!CDIR NOVERRCHK
178      DO jj = 1, jpj
179!CDIR NOVERRCHK
180         DO ji = 1, jpi
181
182            !                             ! SET ABSOLUTE TEMPERATURE
183            ztkel = tn(ji,jj,1) + 273.16
184            zqtt  = ztkel * 0.01
185            zqtt2 = zqtt * zqtt
186            zsal  = sn(ji,jj,1) + (1.- tmask(ji,jj,1) ) * 35.
187            zlqtt = LOG( zqtt )
188
189            !                             ! LN(K0) OF SOLUBILITY OF CO2 (EQ. 12, WEISS, 1980)
190            !                             !     AND FOR THE ATMOSPHERE FOR NON IDEAL GAS
191            zcek1 = ca0 + ca1 / zqtt + ca2 * zlqtt + ca3 * zqtt2 + zsal*( ca4 + ca5 * zqtt + ca6 * zqtt2 )
192
193            !                             ! LN(K0) OF SOLUBILITY OF O2 and N2 (EQ. 4, WEISS, 1970)
194            zoxy  = ox0 + ox1 / zqtt + ox2 * zlqtt + zsal * ( ox3 + ox4 * zqtt + ox5 * zqtt2 )
195
196            !                             ! SET SOLUBILITIES OF O2 AND CO2
197            chemc(ji,jj,1) = EXP( zcek1 ) * 1.e-6 * rhop(ji,jj,1) / 1000.
198            chemc(ji,jj,2) = EXP( zoxy  ) * oxyco
199
200         END DO
201      END DO
202
203      ! CHEMICAL CONSTANTS - DEEP OCEAN
204      ! -------------------------------
205!CDIR NOVERRCHK
206      DO jk = 1, jpk
207!CDIR NOVERRCHK
208         DO jj = 1, jpj
209!CDIR NOVERRCHK
210            DO ji = 1, jpi
211
212               ! SET PRESSION
213               zpres   = 1.025e-1 * fsdept(ji,jj,jk)
214
215               ! SET ABSOLUTE TEMPERATURE
216               ztkel   = tn(ji,jj,jk) + 273.16
217               zqtt    = ztkel * 0.01
218               zsal    = sn(ji,jj,jk) + ( 1.-tmask(ji,jj,jk) ) * 35.
219               zsqrt  = SQRT( zsal )
220               zsal15  = zsqrt * zsal
221               zlogt  = LOG( ztkel )
222               ztr    = 1. / ztkel
223               zis    = 19.924 * zsal / ( 1000.- 1.005 * zsal )
224               zis2   = zis * zis
225               zisqrt = SQRT( zis )
226               ztc     = tn(ji,jj,jk) + ( 1.- tmask(ji,jj,jk) ) * 20.
227
228               ! CHLORINITY (WOOSTER ET AL., 1969)
229               zcl     = zsal * salchl
230
231               ! TOTAL SULFATE CONCENTR. [MOLES/kg soln]
232               zst     = st1 * zcl * st2
233
234               ! TOTAL FLUORIDE CONCENTR. [MOLES/kg soln]
235               zft     = ft1 * zcl * ft2
236
237               ! DISSOCIATION CONSTANT FOR SULFATES on free H scale (Dickson 1990)
238               zcks    = EXP(  ks1 * ztr + ks0 + ks2 * zlogt                           &
239                  &                     + ( ks3 * ztr + ks4 + ks5 * zlogt ) * zisqrt   &
240                  &                     + ( ks6 * ztr + ks7 + ks8 * zlogt ) * zis      &
241                  &                     + ks9 * ztr * zis * zisqrt + ks10 * ztr *zis2 + LOG( ks11 + ks12 *zsal )  )
242
243               ! DISSOCIATION CONSTANT FOR FLUORIDES on free H scale (Dickson and Riley 79)
244               zckf    = EXP(  kf1 * ztr + kf0 + kf2 * zisqrt + LOG( kf3 + kf4 * zsal )  )
245
246               ! DISSOCIATION CONSTANT FOR CARBONATE AND BORATE
247               zckb    = ( cb0 + cb1 * zsqrt + cb2  * zsal + cb3 * zsal15 + cb4 * zsal * zsal ) * ztr   &
248                  &    + ( cb5 + cb6 * zsqrt + cb7  * zsal )                                            &
249                  &    + ( cb8 + cb9 * zsqrt + cb10 * zsal ) * zlogt + cb11 * zsqrt * ztkel             &
250                  &    + LOG(  ( 1.+ zst / zcks + zft / zckf ) / ( 1.+ zst / zcks )  )
251!!gm zsal**2 to be replaced by a *...
252               zck1    = c10 * ztr + c11 + c12 * zlogt + c13 * zsal + c14 * zsal**2
253               zck2    = c20 * ztr + c21 + c22 * zsal   + c23 * zsal**2
254
255               ! PKW (H2O) (DICKSON AND RILEY, 1979)
256               zckw    = cw0 * ztr + cw1 + cw2 * zlogt + ( cw3 * ztr + cw4 + cw5 * zlogt ) * zsqrt + cw6 * zsal
257
258
259               ! APPARENT SOLUBILITY PRODUCT K'SP OF CALCITE IN SEAWATER
260               !       (S=27-43, T=2-25 DEG C) at pres =0 (atmos. pressure) (MUCCI 1983)
261               zaksp0  = akcc1 + akcc2 * ztkel + akcc3 * ztr + akcc4 * LOG10( ztkel )   &
262                  &   + ( akcc5 + akcc6 * ztkel + akcc7 * ztr ) * zsqrt + akcc8 * zsal + akcc9 * zsal15
263
264               ! K1, K2 OF CARBONIC ACID, KB OF BORIC ACID, KW (H2O) (LIT.?)
265               zak1    = 10**(zck1)
266               zak2    = 10**(zck2)
267               zakb    = EXP( zckb  )
268               zakw    = EXP( zckw )
269               zaksp1  = 10**(zaksp0)
270
271               ! FORMULA FOR CPEXP AFTER EDMOND & GIESKES (1970)
272               !        (REFERENCE TO CULBERSON & PYTKOQICZ (1968) AS MADE
273               !        IN BROECKER ET AL. (1982) IS INCORRECT; HERE RGAS IS
274               !        TAKEN TENFOLD TO CORRECT FOR THE NOTATION OF pres  IN
275               !        DBAR INSTEAD OF BAR AND THE EXPRESSION FOR CPEXP IS
276               !        MULTIPLIED BY LN(10.) TO ALLOW USE OF EXP-FUNCTION
277               !        WITH BASIS E IN THE FORMULA FOR AKSPP (CF. EDMOND
278               !        & GIESKES (1970), P. 1285-1286 (THE SMALL
279               !        FORMULA ON P. 1286 IS RIGHT AND CONSISTENT WITH THE
280               !        SIGN IN PARTIAL MOLAR VOLUME CHANGE AS SHOWN ON P. 1285))
281               zcpexp  = zpres /(rgas*ztkel)
282               zcpexp2 = zpres * zpres/(rgas*ztkel)
283
284               ! KB OF BORIC ACID, K1,K2 OF CARBONIC ACID PRESSURE
285               !        CORRECTION AFTER CULBERSON AND PYTKOWICZ (1968)
286               !        (CF. BROECKER ET AL., 1982)
287
288               zbuf1  = -(devk1(1)+devk2(1)*ztc+devk3(1)*ztc*ztc)
289               zbuf2  = 0.5*(devk4(1)+devk5(1)*ztc)
290               ak13(ji,jj,jk) = zak1 * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 )
291
292               zbuf1  =     - ( devk1(2) + devk2(2) * ztc + devk3(2) * ztc * ztc )
293               zbuf2  = 0.5 * ( devk4(2) + devk5(2) * ztc )
294               ak23(ji,jj,jk) = zak2 * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 )
295
296               zbuf1  =     - ( devk1(3) + devk2(3) * ztc + devk3(3) * ztc * ztc )
297               zbuf2  = 0.5 * ( devk4(3) + devk5(3) * ztc )
298               akb3(ji,jj,jk) = zakb * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 )
299
300               zbuf1  =     - ( devk1(4) + devk2(4) * ztc + devk3(4) * ztc * ztc )
301               zbuf2  = 0.5 * ( devk4(4) + devk5(4) * ztc )
302               akw3(ji,jj,jk) = zakw * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 )
303
304
305               ! APPARENT SOLUBILITY PRODUCT K'SP OF CALCITE
306               !        AS FUNCTION OF PRESSURE FOLLOWING MILLERO
307               !        (P. 1285) AND BERNER (1976)
308               zbuf1  =     - ( devk1(5) + devk2(5) * ztc + devk3(5) * ztc * ztc )
309               zbuf2  = 0.5 * ( devk4(5) + devk5(5) * ztc )
310               aksp(ji,jj,jk) = zaksp1 * EXP( zbuf1 * zcpexp + zbuf2 * zcpexp2 )
311
312
313               ! TOTAL BORATE CONCENTR. [MOLES/L]
314               borat(ji,jj,jk) = bor1 * zcl * bor2
315
316               ! Iron and SIO3 saturation concentration from ...
317               sio3eq(ji,jj,jk) = EXP(  LOG( 10.) * ( 6.44 - 968. / ztkel )  ) * 1.e-6
318               fekeq (ji,jj,jk) = 10**( 17.27 - 1565.7 / ( 273.15 + ztc ) )
319
320            END DO
321         END DO
322      END DO
323      !
324   END SUBROUTINE p4z_che
325
326#else
327   !!======================================================================
328   !!  Dummy module :                                   No PISCES bio-model
329   !!======================================================================
330CONTAINS
331   SUBROUTINE p4z_che( kt )                   ! Empty routine
332      INTEGER, INTENT( in ) ::   kt
333      WRITE(*,*) 'p4z_che: You should not have seen this print! error?', kt
334   END SUBROUTINE p4z_che
335#endif 
336
337   !!======================================================================
338END MODULE  p4zche
Note: See TracBrowser for help on using the repository browser.