New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcblk_core.F90 in branches/dev_r2174_DCY/NEMO/OPA_SRC/SBC – NEMO

source: branches/dev_r2174_DCY/NEMO/OPA_SRC/SBC/sbcblk_core.F90 @ 2216

Last change on this file since 2216 was 2216, checked in by smasson, 14 years ago

diurnal cycle in coupled mode in dev_r2174_DCY, see ticket:730
  • Property svn:keywords set to Id
File size: 47.7 KB
Line 
1MODULE sbcblk_core
2   !!======================================================================
3   !!                       ***  MODULE  sbcblk_core  ***
4   !! Ocean forcing:  momentum, heat and freshwater flux formulation
5   !!=====================================================================
6   !! History :  1.0  !  2004-08  (U. Schweckendiek)  Original code
7   !!            2.0  !  2005-04  (L. Brodeau, A.M. Treguier) additions:
8   !!                           -  new bulk routine for efficiency
9   !!                           -  WINDS ARE NOW ASSUMED TO BE AT T POINTS in input files !!!!
10   !!                           -  file names and file characteristics in namelist
11   !!                           -  Implement reading of 6-hourly fields   
12   !!            3.0  !  2006-06  (G. Madec) sbc rewritting   
13   !!            3.2  !  2009-04  (B. Lemaire)  Introduce iom_put
14   !!            3.3  !  2010-10  (S. Masson)  add diurnal cycle
15   !!----------------------------------------------------------------------
16
17   !!----------------------------------------------------------------------
18   !!   sbc_blk_core  : bulk formulation as ocean surface boundary condition
19   !!                   (forced mode, CORE bulk formulea)
20   !!   blk_oce_core  : ocean: computes momentum, heat and freshwater fluxes
21   !!   blk_ice_core  : ice  : computes momentum, heat and freshwater fluxes
22   !!   turb_core     : computes the CORE turbulent transfer coefficients
23   !!----------------------------------------------------------------------
24   USE oce             ! ocean dynamics and tracers
25   USE dom_oce         ! ocean space and time domain
26   USE phycst          ! physical constants
27   USE fldread         ! read input fields
28   USE sbc_oce         ! Surface boundary condition: ocean fields
29   USE sbcdcy          ! surface boundary condition: diurnal cycle
30   USE iom             ! I/O manager library
31   USE in_out_manager  ! I/O manager
32   USE lib_mpp         ! distribued memory computing library
33   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
34   USE prtctl          ! Print control
35#if defined key_lim3
36   USE sbc_ice         ! Surface boundary condition: ice fields
37#endif
38
39   IMPLICIT NONE
40   PRIVATE
41
42   PUBLIC   sbc_blk_core       ! routine called in sbcmod module
43   PUBLIC   blk_ice_core       ! routine called in sbc_ice_lim module
44     
45   INTEGER , PARAMETER ::   jpfld   = 9           ! maximum number of files to read
46   INTEGER , PARAMETER ::   jp_wndi = 1           ! index of 10m wind velocity (i-component) (m/s)    at T-point
47   INTEGER , PARAMETER ::   jp_wndj = 2           ! index of 10m wind velocity (j-component) (m/s)    at T-point
48   INTEGER , PARAMETER ::   jp_humi = 3           ! index of specific humidity               ( - )
49   INTEGER , PARAMETER ::   jp_qsr  = 4           ! index of solar heat                      (W/m2)
50   INTEGER , PARAMETER ::   jp_qlw  = 5           ! index of Long wave                       (W/m2)
51   INTEGER , PARAMETER ::   jp_tair = 6           ! index of 10m air temperature             (Kelvin)
52   INTEGER , PARAMETER ::   jp_prec = 7           ! index of total precipitation (rain+snow) (Kg/m2/s)
53   INTEGER , PARAMETER ::   jp_snow = 8           ! index of snow (solid prcipitation)       (kg/m2/s)
54   INTEGER , PARAMETER ::   jp_tdif = 9           ! index of tau diff associated to HF tau   (N/m2)   at T-point
55   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf   ! structure of input fields (file informations, fields read)
56         
57   !                                             !!! CORE bulk parameters
58   REAL(wp), PARAMETER ::   rhoa =    1.22        ! air density
59   REAL(wp), PARAMETER ::   cpa  = 1000.5         ! specific heat of air
60   REAL(wp), PARAMETER ::   Lv   =    2.5e6       ! latent heat of vaporization
61   REAL(wp), PARAMETER ::   Ls   =    2.839e6     ! latent heat of sublimation
62   REAL(wp), PARAMETER ::   Stef =    5.67e-8     ! Stefan Boltzmann constant
63   REAL(wp), PARAMETER ::   Cice =    1.63e-3     ! transfer coefficient over ice
64
65   !                                  !!* Namelist namsbc_core : CORE bulk parameters
66   LOGICAL  ::   ln_2m     = .FALSE.   ! logical flag for height of air temp. and hum
67   LOGICAL  ::   ln_taudif = .FALSE.   ! logical flag to use the "mean of stress module - module of mean stress" data
68   REAL(wp) ::   rn_pfac   = 1.        ! multiplication factor for precipitation
69
70   !! * Substitutions
71#  include "domzgr_substitute.h90"
72#  include "vectopt_loop_substitute.h90"
73   !!----------------------------------------------------------------------
74   !! NEMO/OPA 3.3 , NEMO-consortium (2010)
75   !! $Id$
76   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
77   !!----------------------------------------------------------------------
78CONTAINS
79
80   SUBROUTINE sbc_blk_core( kt )
81      !!---------------------------------------------------------------------
82      !!                    ***  ROUTINE sbc_blk_core  ***
83      !!                   
84      !! ** Purpose :   provide at each time step the surface ocean fluxes
85      !!      (momentum, heat, freshwater and runoff)
86      !!
87      !! ** Method  : (1) READ each fluxes in NetCDF files:
88      !!      the 10m wind velocity (i-component) (m/s)    at T-point
89      !!      the 10m wind velocity (j-component) (m/s)    at T-point
90      !!      the specific humidity               ( - )
91      !!      the solar heat                      (W/m2)
92      !!      the Long wave                       (W/m2)
93      !!      the 10m air temperature             (Kelvin)
94      !!      the total precipitation (rain+snow) (Kg/m2/s)
95      !!      the snow (solid prcipitation)       (kg/m2/s)
96      !!   OPTIONAL parameter (see ln_taudif namelist flag):
97      !!      the tau diff associated to HF tau   (N/m2)   at T-point
98      !!              (2) CALL blk_oce_core
99      !!
100      !!      C A U T I O N : never mask the surface stress fields
101      !!                      the stress is assumed to be in the mesh referential
102      !!                      i.e. the (i,j) referential
103      !!
104      !! ** Action  :   defined at each time-step at the air-sea interface
105      !!              - utau, vtau  i- and j-component of the wind stress
106      !!              - taum        wind stress module at T-point
107      !!              - wndm        10m wind module at T-point
108      !!              - qns, qsr    non-slor and solar heat flux
109      !!              - emp, emps   evaporation minus precipitation
110      !!----------------------------------------------------------------------
111      INTEGER, INTENT( in  ) ::   kt   ! ocean time step
112      !!
113      INTEGER  ::   ierror   ! return error code
114      INTEGER  ::   ifpr     ! dummy loop indice
115      INTEGER  ::   jfld     ! dummy loop arguments
116      !!
117      CHARACTER(len=100) ::  cn_dir   !   Root directory for location of core files
118      TYPE(FLD_N), DIMENSION(jpfld) ::   slf_i     ! array of namelist informations on the fields to read
119      TYPE(FLD_N) ::   sn_wndi, sn_wndj, sn_humi, sn_qsr       ! informations about the fields to be read
120      TYPE(FLD_N) ::   sn_qlw , sn_tair, sn_prec, sn_snow      !   "                                 "
121      TYPE(FLD_N) ::   sn_tdif                                 !   "                                 "
122      NAMELIST/namsbc_core/ cn_dir , ln_2m  , ln_taudif, rn_pfac,           &
123         &                  sn_wndi, sn_wndj, sn_humi  , sn_qsr ,           &
124         &                  sn_qlw , sn_tair, sn_prec  , sn_snow, sn_tdif
125      !!---------------------------------------------------------------------
126
127      !                                         ! ====================== !
128      IF( kt == nit000 ) THEN                   !  First call kt=nit000  !
129         !                                      ! ====================== !
130         ! set file information (default values)
131         cn_dir = './'       ! directory in which the model is executed
132         !
133         ! (NB: frequency positive => hours, negative => months)
134         !            !    file     ! frequency !  variable  ! time intep !  clim   ! 'yearly' or ! weights  ! rotation   !
135         !            !    name     !  (hours)  !   name     !   (T/F)    !  (T/F)  !  'monthly'  ! filename ! pairs      !
136         sn_wndi = FLD_N( 'uwnd10m' ,    24     ,  'u_10'    ,  .false.   , .false. ,   'yearly'  , ''       , ''         )
137         sn_wndj = FLD_N( 'vwnd10m' ,    24     ,  'v_10'    ,  .false.   , .false. ,   'yearly'  , ''       , ''         )
138         sn_qsr  = FLD_N( 'qsw'     ,    24     ,  'qsw'     ,  .false.   , .false. ,   'yearly'  , ''       , ''         )
139         sn_qlw  = FLD_N( 'qlw'     ,    24     ,  'qlw'     ,  .false.   , .false. ,   'yearly'  , ''       , ''         )
140         sn_tair = FLD_N( 'tair10m' ,    24     ,  't_10'    ,  .false.   , .false. ,   'yearly'  , ''       , ''         )
141         sn_humi = FLD_N( 'humi10m' ,    24     ,  'q_10'    ,  .false.   , .false. ,   'yearly'  , ''       , ''         )
142         sn_prec = FLD_N( 'precip'  ,    -1     ,  'precip'  ,  .true.    , .false. ,   'yearly'  , ''       , ''         )
143         sn_snow = FLD_N( 'snow'    ,    -1     ,  'snow'    ,  .true.    , .false. ,   'yearly'  , ''       , ''         )
144         sn_tdif = FLD_N( 'taudif'  ,    24     ,  'taudif'  ,  .true.    , .false. ,   'yearly'  , ''       , ''         )
145         !
146         REWIND( numnam )                          ! read in namlist namsbc_core
147         READ  ( numnam, namsbc_core )
148         !                                         ! check: do we plan to use ln_dm2dc with non-daily forcing?
149         IF( ln_dm2dc .AND. sn_qsr%nfreqh /= 24 )   & 
150            &   CALL ctl_stop( 'sbc_blk_core: ln_dm2dc can be activated only with daily short-wave forcing' ) 
151         IF( ln_dm2dc .AND. sn_qsr%ln_tint ) THEN
152            CALL ctl_warn( 'sbc_blk_core: ln_dm2dc is taking care of the temporal interpolation of daily qsr',   &
153                 &         '              ==> We force time interpolation = .false. for qsr' )
154            sn_qsr%ln_tint = .false.
155         ENDIF
156         !                                         ! store namelist information in an array
157         slf_i(jp_wndi) = sn_wndi   ;   slf_i(jp_wndj) = sn_wndj
158         slf_i(jp_qsr ) = sn_qsr    ;   slf_i(jp_qlw ) = sn_qlw
159         slf_i(jp_tair) = sn_tair   ;   slf_i(jp_humi) = sn_humi
160         slf_i(jp_prec) = sn_prec   ;   slf_i(jp_snow) = sn_snow
161         slf_i(jp_tdif) = sn_tdif
162         !                 
163         lhftau = ln_taudif                        ! do we use HF tau information?
164         jfld = jpfld - COUNT( (/.NOT. lhftau/) )
165         !
166         ALLOCATE( sf(jfld), STAT=ierror )         ! set sf structure
167         IF( ierror > 0 ) THEN
168            CALL ctl_stop( 'sbc_blk_core: unable to allocate sf structure' )   ;   RETURN
169         ENDIF
170         DO ifpr= 1, jfld
171            ALLOCATE( sf(ifpr)%fnow(jpi,jpj) )
172            ALLOCATE( sf(ifpr)%fdta(jpi,jpj,2) )
173         END DO
174         !                                         ! fill sf with slf_i and control print
175         CALL fld_fill( sf, slf_i, cn_dir, 'sbc_blk_core', 'flux formulation for ocean surface boundary condition', 'namsbc_core' )
176         !
177      ENDIF
178
179      CALL fld_read( kt, nn_fsbc, sf )        ! input fields provided at the current time-step
180
181#if defined key_lim3
182      tatm_ice(:,:) = sf(jp_tair)%fnow(:,:)                    ! LIM3: make Tair available in sea-ice
183#endif
184      !                                                        ! surface ocean fluxes computed with CLIO bulk formulea
185      IF( MOD( kt - 1, nn_fsbc ) == 0 )   CALL blk_oce_core( sf, sst_m, ssu_m, ssv_m )
186      !
187   END SUBROUTINE sbc_blk_core
188   
189   
190   SUBROUTINE blk_oce_core( sf, pst, pu, pv )
191      !!---------------------------------------------------------------------
192      !!                     ***  ROUTINE blk_core  ***
193      !!
194      !! ** Purpose :   provide the momentum, heat and freshwater fluxes at
195      !!      the ocean surface at each time step
196      !!
197      !! ** Method  :   CORE bulk formulea for the ocean using atmospheric
198      !!      fields read in sbc_read
199      !!
200      !! ** Outputs : - utau    : i-component of the stress at U-point  (N/m2)
201      !!              - vtau    : j-component of the stress at V-point  (N/m2)
202      !!              - taum    : Wind stress module at T-point         (N/m2)
203      !!              - wndm    : Wind speed module at T-point          (m/s)
204      !!              - qsr     : Solar heat flux over the ocean        (W/m2)
205      !!              - qns     : Non Solar heat flux over the ocean    (W/m2)
206      !!              - evap    : Evaporation over the ocean            (kg/m2/s)
207      !!              - emp(s)  : evaporation minus precipitation       (kg/m2/s)
208      !!
209      !!  ** Nota  :   sf has to be a dummy argument for AGRIF on NEC
210      !!---------------------------------------------------------------------
211      TYPE(fld), INTENT(in), DIMENSION(:)       ::   sf    ! input data
212      REAL(wp),  INTENT(in), DIMENSION(jpi,jpj) ::   pst   ! surface temperature                      [Celcius]
213      REAL(wp),  INTENT(in), DIMENSION(jpi,jpj) ::   pu    ! surface current at U-point (i-component) [m/s]
214      REAL(wp),  INTENT(in), DIMENSION(jpi,jpj) ::   pv    ! surface current at V-point (j-component) [m/s]
215
216      INTEGER  ::   ji, jj     ! dummy loop indices
217      REAL(wp) ::   zcoef_qsatw
218      REAL(wp) ::   zztmp                                 ! temporary variable
219      REAL(wp), DIMENSION(jpi,jpj) ::   zwnd_i, zwnd_j    ! wind speed components at T-point
220      REAL(wp), DIMENSION(jpi,jpj) ::   zqsatw            ! specific humidity at pst
221      REAL(wp), DIMENSION(jpi,jpj) ::   zqlw, zqsb        ! long wave and sensible heat fluxes
222      REAL(wp), DIMENSION(jpi,jpj) ::   zqla, zevap       ! latent heat fluxes and evaporation
223      REAL(wp), DIMENSION(jpi,jpj) ::   Cd                ! transfer coefficient for momentum      (tau)
224      REAL(wp), DIMENSION(jpi,jpj) ::   Ch                ! transfer coefficient for sensible heat (Q_sens)
225      REAL(wp), DIMENSION(jpi,jpj) ::   Ce                ! tansfert coefficient for evaporation   (Q_lat)
226      REAL(wp), DIMENSION(jpi,jpj) ::   zst               ! surface temperature in Kelvin
227      REAL(wp), DIMENSION(jpi,jpj) ::   zt_zu             ! air temperature at wind speed height
228      REAL(wp), DIMENSION(jpi,jpj) ::   zq_zu             ! air spec. hum.  at wind speed height
229      !!---------------------------------------------------------------------
230
231      ! local scalars ( place there for vector optimisation purposes)
232      zcoef_qsatw = 0.98 * 640380. / rhoa
233     
234      zst(:,:) = pst(:,:) + rt0      ! converte Celcius to Kelvin (and set minimum value far above 0 K)
235
236      ! ----------------------------------------------------------------------------- !
237      !      0   Wind components and module at T-point relative to the moving ocean   !
238      ! ----------------------------------------------------------------------------- !
239
240      ! ... components ( U10m - U_oce ) at T-point (unmasked)
241      zwnd_i(:,:) = 0.e0 
242      zwnd_j(:,:) = 0.e0
243#if defined key_vectopt_loop
244!CDIR COLLAPSE
245#endif
246      DO jj = 2, jpjm1
247         DO ji = fs_2, fs_jpim1   ! vect. opt.
248            zwnd_i(ji,jj) = (  sf(jp_wndi)%fnow(ji,jj) - 0.5 * ( pu(ji-1,jj  ) + pu(ji,jj) )  )
249            zwnd_j(ji,jj) = (  sf(jp_wndj)%fnow(ji,jj) - 0.5 * ( pv(ji  ,jj-1) + pv(ji,jj) )  )
250         END DO
251      END DO
252      CALL lbc_lnk( zwnd_i(:,:) , 'T', -1. )
253      CALL lbc_lnk( zwnd_j(:,:) , 'T', -1. )
254      ! ... scalar wind ( = | U10m - U_oce | ) at T-point (masked)
255!CDIR NOVERRCHK
256!CDIR COLLAPSE
257      wndm(:,:) = SQRT(  zwnd_i(:,:) * zwnd_i(:,:)   &
258         &             + zwnd_j(:,:) * zwnd_j(:,:)  ) * tmask(:,:,1)
259
260      ! ----------------------------------------------------------------------------- !
261      !      I   Radiative FLUXES                                                     !
262      ! ----------------------------------------------------------------------------- !
263   
264      IF( ln_dm2dc ) THEN   ;   qsr(:,:) = sbc_dcy( sf(jp_qsr)%fnow )   ! modify now Qsr to include the diurnal cycle
265      ELSE                  ;   qsr(:,:) = sf(jp_qsr)%fnow(:,:)
266      ENDIF
267      ! ocean albedo assumed to be 0.066
268      qsr (:,:) = ( 1. - 0.066 ) * qsr(:,:) * tmask(:,:,1)                                                 ! Short Wave
269!CDIR COLLAPSE
270      zqlw(:,:) = (  sf(jp_qlw)%fnow(:,:) - Stef * zst(:,:)*zst(:,:)*zst(:,:)*zst(:,:)  ) * tmask(:,:,1)   ! Long  Wave
271                     
272      ! ----------------------------------------------------------------------------- !
273      !     II    Turbulent FLUXES                                                    !
274      ! ----------------------------------------------------------------------------- !
275
276      ! ... specific humidity at SST and IST
277!CDIR NOVERRCHK
278!CDIR COLLAPSE
279      zqsatw(:,:) = zcoef_qsatw * EXP( -5107.4 / zst(:,:) ) 
280
281      ! ... NCAR Bulk formulae, computation of Cd, Ch, Ce at T-point :
282      IF( ln_2m ) THEN
283         !! If air temp. and spec. hum. are given at different height (2m) than wind (10m) :
284         CALL TURB_CORE_2Z(2.,10., zst   , sf(jp_tair)%fnow,         &
285            &                      zqsatw, sf(jp_humi)%fnow, wndm,   &
286            &                      Cd    , Ch              , Ce  ,   &
287            &                      zt_zu , zq_zu                   )
288      ELSE
289         !! If air temp. and spec. hum. are given at same height than wind (10m) :
290!gm bug?  at the compiling phase, add a copy in temporary arrays...  ==> check perf
291!         CALL TURB_CORE_1Z( 10., zst   (:,:), sf(jp_tair)%fnow(:,:),              &
292!            &                    zqsatw(:,:), sf(jp_humi)%fnow(:,:), wndm(:,:),   &
293!            &                    Cd    (:,:),             Ch  (:,:), Ce  (:,:)  )
294!gm bug
295         CALL TURB_CORE_1Z( 10., zst   , sf(jp_tair)%fnow,         &
296            &                    zqsatw, sf(jp_humi)%fnow, wndm,   &
297            &                    Cd    , Ch              , Ce    )
298      ENDIF
299
300      ! ... tau module, i and j component
301      DO jj = 1, jpj
302         DO ji = 1, jpi
303            zztmp = rhoa * wndm(ji,jj) * Cd(ji,jj)
304            taum  (ji,jj) = zztmp * wndm  (ji,jj)
305            zwnd_i(ji,jj) = zztmp * zwnd_i(ji,jj)
306            zwnd_j(ji,jj) = zztmp * zwnd_j(ji,jj)
307         END DO
308      END DO
309
310      ! ... add the HF tau contribution to the wind stress module?
311      IF( lhftau ) THEN 
312!CDIR COLLAPSE
313         taum(:,:) = taum(:,:) + sf(jp_tdif)%fnow(:,:)
314      ENDIF
315      CALL iom_put( "taum_oce", taum )   ! output wind stress module
316
317      ! ... utau, vtau at U- and V_points, resp.
318      !     Note the use of 0.5*(2-umask) in order to unmask the stress along coastlines
319      DO jj = 1, jpjm1
320         DO ji = 1, fs_jpim1
321            utau(ji,jj) = 0.5 * ( 2. - umask(ji,jj,1) ) * ( zwnd_i(ji,jj) + zwnd_i(ji+1,jj  ) )
322            vtau(ji,jj) = 0.5 * ( 2. - vmask(ji,jj,1) ) * ( zwnd_j(ji,jj) + zwnd_j(ji  ,jj+1) )
323         END DO
324      END DO
325      CALL lbc_lnk( utau(:,:), 'U', -1. )
326      CALL lbc_lnk( vtau(:,:), 'V', -1. )
327
328      !  Turbulent fluxes over ocean
329      ! -----------------------------
330      IF( ln_2m ) THEN
331         ! Values of temp. and hum. adjusted to 10m must be used instead of 2m values
332         zevap(:,:) = MAX( 0.e0, rhoa    *Ce(:,:)*( zqsatw(:,:) - zq_zu(:,:) ) * wndm(:,:) )   ! Evaporation
333         zqsb (:,:) =            rhoa*cpa*Ch(:,:)*( zst   (:,:) - zt_zu(:,:) ) * wndm(:,:)     ! Sensible Heat
334      ELSE
335!CDIR COLLAPSE
336         zevap(:,:) = MAX( 0.e0, rhoa    *Ce(:,:)*( zqsatw(:,:) - sf(jp_humi)%fnow(:,:) ) * wndm(:,:) )   ! Evaporation
337!CDIR COLLAPSE
338         zqsb (:,:) =            rhoa*cpa*Ch(:,:)*( zst   (:,:) - sf(jp_tair)%fnow(:,:) ) * wndm(:,:)     ! Sensible Heat
339      ENDIF
340!CDIR COLLAPSE
341      zqla (:,:) = Lv * zevap(:,:)                                                              ! Latent Heat
342
343      IF(ln_ctl) THEN
344         CALL prt_ctl( tab2d_1=zqla  , clinfo1=' blk_oce_core: zqla   : ', tab2d_2=Ce , clinfo2=' Ce  : ' )
345         CALL prt_ctl( tab2d_1=zqsb  , clinfo1=' blk_oce_core: zqsb   : ', tab2d_2=Ch , clinfo2=' Ch  : ' )
346         CALL prt_ctl( tab2d_1=zqlw  , clinfo1=' blk_oce_core: zqlw   : ', tab2d_2=qsr, clinfo2=' qsr : ' )
347         CALL prt_ctl( tab2d_1=zqsatw, clinfo1=' blk_oce_core: zqsatw : ', tab2d_2=zst, clinfo2=' zst : ' )
348         CALL prt_ctl( tab2d_1=utau  , clinfo1=' blk_oce_core: utau   : ', mask1=umask,   &
349            &          tab2d_2=vtau  , clinfo2=              ' vtau : '  , mask2=vmask )
350         CALL prt_ctl( tab2d_1=wndm  , clinfo1=' blk_oce_core: wndm   : ')
351         CALL prt_ctl( tab2d_1=zst   , clinfo1=' blk_oce_core: zst    : ')
352      ENDIF
353       
354      ! ----------------------------------------------------------------------------- !
355      !     III    Total FLUXES                                                       !
356      ! ----------------------------------------------------------------------------- !
357     
358!CDIR COLLAPSE
359      qns(:,:) = zqlw(:,:) - zqsb(:,:) - zqla(:,:)      ! Downward Non Solar flux
360!CDIR COLLAPSE
361      emp (:,:) = zevap(:,:) - sf(jp_prec)%fnow(:,:) * rn_pfac * tmask(:,:,1)
362!CDIR COLLAPSE
363      emps(:,:) = emp(:,:)
364      !
365      CALL iom_put( "qlw_oce",   zqlw )                 ! output downward longwave heat over the ocean
366      CALL iom_put( "qsb_oce", - zqsb )                 ! output downward sensible heat over the ocean
367      CALL iom_put( "qla_oce", - zqla )                 ! output downward latent   heat over the ocean
368      CALL iom_put( "qns_oce",   qns  )                 ! output downward non solar heat over the ocean
369      !
370      IF(ln_ctl) THEN
371         CALL prt_ctl(tab2d_1=zqsb , clinfo1=' blk_oce_core: zqsb   : ', tab2d_2=zqlw , clinfo2=' zqlw  : ')
372         CALL prt_ctl(tab2d_1=zqla , clinfo1=' blk_oce_core: zqla   : ', tab2d_2=qsr  , clinfo2=' qsr   : ')
373         CALL prt_ctl(tab2d_1=pst  , clinfo1=' blk_oce_core: pst    : ', tab2d_2=emp  , clinfo2=' emp   : ')
374         CALL prt_ctl(tab2d_1=utau , clinfo1=' blk_oce_core: utau   : ', mask1=umask,   &
375            &         tab2d_2=vtau , clinfo2=              ' vtau  : ' , mask2=vmask )
376      ENDIF
377      !
378   END SUBROUTINE blk_oce_core
379   
380   
381   SUBROUTINE blk_ice_core(  pst   , pui   , pvi   , palb ,   &
382      &                      p_taui, p_tauj, p_qns , p_qsr,   &
383      &                      p_qla , p_dqns, p_dqla,          &
384      &                      p_tpr , p_spr ,                  &
385      &                      p_fr1 , p_fr2 , cd_grid, pdim  ) 
386      !!---------------------------------------------------------------------
387      !!                     ***  ROUTINE blk_ice_core  ***
388      !!
389      !! ** Purpose :   provide the surface boundary condition over sea-ice
390      !!
391      !! ** Method  :   compute momentum, heat and freshwater exchanged
392      !!                between atmosphere and sea-ice using CORE bulk
393      !!                formulea, ice variables and read atmmospheric fields.
394      !!                NB: ice drag coefficient is assumed to be a constant
395      !!
396      !! caution : the net upward water flux has with mm/day unit
397      !!---------------------------------------------------------------------
398      REAL(wp), INTENT(in   ), DIMENSION(:,:,:)      ::   pst      ! ice surface temperature (>0, =rt0 over land) [Kelvin]
399      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj)    ::   pui      ! ice surface velocity (i- and i- components      [m/s]
400      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj)    ::   pvi      !    at I-point (B-grid) or U & V-point (C-grid)
401      REAL(wp), INTENT(in   ), DIMENSION(:,:,:)      ::   palb     ! ice albedo (clear sky) (alb_ice_cs)               [%]
402      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj)    ::   p_taui   ! i- & j-components of surface ice stress        [N/m2]
403      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj)    ::   p_tauj   !   at I-point (B-grid) or U & V-point (C-grid)
404      REAL(wp), INTENT(  out), DIMENSION(:,:,:)      ::   p_qns    ! non solar heat flux over ice (T-point)         [W/m2]
405      REAL(wp), INTENT(  out), DIMENSION(:,:,:)      ::   p_qsr    !     solar heat flux over ice (T-point)         [W/m2]
406      REAL(wp), INTENT(  out), DIMENSION(:,:,:)      ::   p_qla    ! latent    heat flux over ice (T-point)         [W/m2]
407      REAL(wp), INTENT(  out), DIMENSION(:,:,:)      ::   p_dqns   ! non solar heat sensistivity  (T-point)         [W/m2]
408      REAL(wp), INTENT(  out), DIMENSION(:,:,:)      ::   p_dqla   ! latent    heat sensistivity  (T-point)         [W/m2]
409      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj)    ::   p_tpr    ! total precipitation          (T-point)      [Kg/m2/s]
410      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj)    ::   p_spr    ! solid precipitation          (T-point)      [Kg/m2/s]
411      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj)    ::   p_fr1    ! 1sr fraction of qsr penetration in ice (T-point)  [%]
412      REAL(wp), INTENT(  out), DIMENSION(jpi,jpj)    ::   p_fr2    ! 2nd fraction of qsr penetration in ice (T-point)  [%]
413      CHARACTER(len=1), INTENT(in   )                ::   cd_grid  ! ice grid ( C or B-grid)
414      INTEGER, INTENT(in   )                         ::   pdim     ! number of ice categories
415      !!
416      INTEGER  ::   ji, jj, jl    ! dummy loop indices
417      INTEGER  ::   ijpl          ! number of ice categories (size of 3rd dim of input arrays)
418      REAL(wp) ::   zst2, zst3
419      REAL(wp) ::   zcoef_wnorm, zcoef_wnorm2, zcoef_dqlw, zcoef_dqla, zcoef_dqsb
420      REAL(wp) ::   zcoef_frca                                   ! fractional cloud amount
421      REAL(wp) ::   zwnorm_f, zwndi_f , zwndj_f                  ! relative wind module and components at F-point
422      REAL(wp) ::             zwndi_t , zwndj_t                  ! relative wind components at T-point
423      REAL(wp), DIMENSION(jpi,jpj) ::   z_wnds_t                 ! wind speed ( = | U10m - U_ice | ) at T-point
424      REAL(wp), DIMENSION(jpi,jpj,pdim) ::   z_qlw               ! long wave heat flux over ice
425      REAL(wp), DIMENSION(jpi,jpj,pdim) ::   z_qsb               ! sensible  heat flux over ice
426      REAL(wp), DIMENSION(jpi,jpj,pdim) ::   z_dqlw              ! long wave heat sensitivity over ice
427      REAL(wp), DIMENSION(jpi,jpj,pdim) ::   z_dqsb              ! sensible  heat sensitivity over ice
428      !!---------------------------------------------------------------------
429
430      ijpl  = pdim                            ! number of ice categories
431
432      ! local scalars ( place there for vector optimisation purposes)
433      zcoef_wnorm = rhoa * Cice
434      zcoef_wnorm2 = rhoa * Cice * 0.5
435      zcoef_dqlw = 4.0 * 0.95 * Stef
436      zcoef_dqla = -Ls * Cice * 11637800. * (-5897.8)
437      zcoef_dqsb = rhoa * cpa * Cice
438      zcoef_frca = 1.0  - 0.3
439
440!!gm brutal....
441      z_wnds_t(:,:) = 0.e0
442      p_taui  (:,:) = 0.e0
443      p_tauj  (:,:) = 0.e0
444!!gm end
445
446      ! ----------------------------------------------------------------------------- !
447      !    Wind components and module relative to the moving ocean ( U10m - U_ice )   !
448      ! ----------------------------------------------------------------------------- !
449      SELECT CASE( cd_grid )
450      CASE( 'B' )                  ! B-grid ice dynamics :   I-point (i.e. F-point with sea-ice indexation)
451         !                           and scalar wind at T-point ( = | U10m - U_ice | ) (masked)
452#if defined key_vectopt_loop
453!CDIR COLLAPSE
454#endif
455!CDIR NOVERRCHK
456         DO jj = 2, jpjm1
457            DO ji = 2, jpim1   ! B grid : no vector opt
458               ! ... scalar wind at I-point (fld being at T-point)
459               zwndi_f = 0.25 * (  sf(jp_wndi)%fnow(ji-1,jj  ) + sf(jp_wndi)%fnow(ji  ,jj  )   &
460                  &              + sf(jp_wndi)%fnow(ji-1,jj-1) + sf(jp_wndi)%fnow(ji  ,jj-1)  ) - pui(ji,jj)
461               zwndj_f = 0.25 * (  sf(jp_wndj)%fnow(ji-1,jj  ) + sf(jp_wndj)%fnow(ji  ,jj  )   &
462                  &              + sf(jp_wndj)%fnow(ji-1,jj-1) + sf(jp_wndj)%fnow(ji  ,jj-1)  ) - pvi(ji,jj)
463               zwnorm_f = zcoef_wnorm * SQRT( zwndi_f * zwndi_f + zwndj_f * zwndj_f )
464               ! ... ice stress at I-point
465               p_taui(ji,jj) = zwnorm_f * zwndi_f
466               p_tauj(ji,jj) = zwnorm_f * zwndj_f
467               ! ... scalar wind at T-point (fld being at T-point)
468               zwndi_t = sf(jp_wndi)%fnow(ji,jj) - 0.25 * (  pui(ji,jj+1) + pui(ji+1,jj+1)   &
469                  &                                        + pui(ji,jj  ) + pui(ji+1,jj  )  )
470               zwndj_t = sf(jp_wndj)%fnow(ji,jj) - 0.25 * (  pvi(ji,jj+1) + pvi(ji+1,jj+1)   &
471                  &                                        + pvi(ji,jj  ) + pvi(ji+1,jj  )  )
472               z_wnds_t(ji,jj)  = SQRT( zwndi_t * zwndi_t + zwndj_t * zwndj_t ) * tmask(ji,jj,1)
473            END DO
474         END DO
475         CALL lbc_lnk( p_taui  , 'I', -1. )
476         CALL lbc_lnk( p_tauj  , 'I', -1. )
477         CALL lbc_lnk( z_wnds_t, 'T',  1. )
478         !
479      CASE( 'C' )                  ! C-grid ice dynamics :   U & V-points (same as ocean)
480#if defined key_vectopt_loop
481!CDIR COLLAPSE
482#endif
483         DO jj = 2, jpj
484            DO ji = fs_2, jpi   ! vect. opt.
485               zwndi_t = (  sf(jp_wndi)%fnow(ji,jj) - 0.5 * ( pui(ji-1,jj  ) + pui(ji,jj) )  )
486               zwndj_t = (  sf(jp_wndj)%fnow(ji,jj) - 0.5 * ( pvi(ji  ,jj-1) + pvi(ji,jj) )  )
487               z_wnds_t(ji,jj)  = SQRT( zwndi_t * zwndi_t + zwndj_t * zwndj_t ) * tmask(ji,jj,1)
488            END DO
489         END DO
490#if defined key_vectopt_loop
491!CDIR COLLAPSE
492#endif
493         DO jj = 2, jpjm1
494            DO ji = fs_2, fs_jpim1   ! vect. opt.
495               p_taui(ji,jj) = zcoef_wnorm2 * ( z_wnds_t(ji+1,jj) + z_wnds_t(ji,jj) )                          &
496                  &          * ( 0.5 * (sf(jp_wndi)%fnow(ji+1,jj) + sf(jp_wndi)%fnow(ji,jj) ) - pui(ji,jj) )
497               p_tauj(ji,jj) = zcoef_wnorm2 * ( z_wnds_t(ji,jj+1) + z_wnds_t(ji,jj) )                          &
498                  &          * ( 0.5 * (sf(jp_wndj)%fnow(ji,jj+1) + sf(jp_wndj)%fnow(ji,jj) ) - pvi(ji,jj) )
499            END DO
500         END DO
501         CALL lbc_lnk( p_taui  , 'U', -1. )
502         CALL lbc_lnk( p_tauj  , 'V', -1. )
503         CALL lbc_lnk( z_wnds_t, 'T',  1. )
504         !
505      END SELECT
506
507      !                                     ! ========================== !
508      DO jl = 1, ijpl                       !  Loop over ice categories  !
509         !                                  ! ========================== !
510!CDIR NOVERRCHK
511!CDIR COLLAPSE
512         DO jj = 1 , jpj
513!CDIR NOVERRCHK
514            DO ji = 1, jpi
515               ! ----------------------------!
516               !      I   Radiative FLUXES   !
517               ! ----------------------------!
518               zst2 = pst(ji,jj,jl) * pst(ji,jj,jl)
519               zst3 = pst(ji,jj,jl) * zst2
520               ! Short Wave (sw)
521               p_qsr(ji,jj,jl) = ( 1. - palb(ji,jj,jl) ) * sf(jp_qsr)%fnow(ji,jj) * tmask(ji,jj,1)
522               ! Long  Wave (lw)
523               z_qlw(ji,jj,jl) = 0.95 * (  sf(jp_qlw)%fnow(ji,jj)       &                         
524                  &                   - Stef * pst(ji,jj,jl) * zst3  ) * tmask(ji,jj,1)
525               ! lw sensitivity
526               z_dqlw(ji,jj,jl) = zcoef_dqlw * zst3                                               
527
528               ! ----------------------------!
529               !     II    Turbulent FLUXES  !
530               ! ----------------------------!
531
532               ! ... turbulent heat fluxes
533               ! Sensible Heat
534               z_qsb(ji,jj,jl) = rhoa * cpa * Cice * z_wnds_t(ji,jj) * ( pst(ji,jj,jl) - sf(jp_tair)%fnow(ji,jj) )
535               ! Latent Heat
536               p_qla(ji,jj,jl) = MAX( 0.e0, rhoa * Ls  * Cice * z_wnds_t(ji,jj)   &                           
537                  &                    * (  11637800. * EXP( -5897.8 / pst(ji,jj,jl) ) / rhoa - sf(jp_humi)%fnow(ji,jj)  ) )
538               ! Latent heat sensitivity for ice (Dqla/Dt)
539               p_dqla(ji,jj,jl) = zcoef_dqla * z_wnds_t(ji,jj) / ( zst2 ) * EXP( -5897.8 / pst(ji,jj,jl) )
540               ! Sensible heat sensitivity (Dqsb_ice/Dtn_ice)
541               z_dqsb(ji,jj,jl) = zcoef_dqsb * z_wnds_t(ji,jj)
542
543               ! ----------------------------!
544               !     III    Total FLUXES     !
545               ! ----------------------------!
546               ! Downward Non Solar flux
547               p_qns (ji,jj,jl) =     z_qlw (ji,jj,jl) - z_qsb (ji,jj,jl) - p_qla (ji,jj,jl)     
548               ! Total non solar heat flux sensitivity for ice
549               p_dqns(ji,jj,jl) = - ( z_dqlw(ji,jj,jl) + z_dqsb(ji,jj,jl) + p_dqla(ji,jj,jl) )   
550            END DO
551            !
552         END DO
553         !
554      END DO
555      !
556      !--------------------------------------------------------------------
557      ! FRACTIONs of net shortwave radiation which is not absorbed in the
558      ! thin surface layer and penetrates inside the ice cover
559      ! ( Maykut and Untersteiner, 1971 ; Ebert and Curry, 1993 )
560   
561!CDIR COLLAPSE
562      p_fr1(:,:) = ( 0.18 * ( 1.0 - zcoef_frca ) + 0.35 * zcoef_frca )
563!CDIR COLLAPSE
564      p_fr2(:,:) = ( 0.82 * ( 1.0 - zcoef_frca ) + 0.65 * zcoef_frca )
565       
566!CDIR COLLAPSE
567      p_tpr(:,:) = sf(jp_prec)%fnow(:,:) * rn_pfac      ! total precipitation [kg/m2/s]
568!CDIR COLLAPSE
569      p_spr(:,:) = sf(jp_snow)%fnow(:,:) * rn_pfac      ! solid precipitation [kg/m2/s]
570      CALL iom_put( 'snowpre', p_spr )                  ! Snow precipitation
571      !
572      IF(ln_ctl) THEN
573         CALL prt_ctl(tab3d_1=p_qla   , clinfo1=' blk_ice_core: p_qla  : ', tab3d_2=z_qsb   , clinfo2=' z_qsb  : ', kdim=ijpl)
574         CALL prt_ctl(tab3d_1=z_qlw   , clinfo1=' blk_ice_core: z_qlw  : ', tab3d_2=p_dqla  , clinfo2=' p_dqla : ', kdim=ijpl)
575         CALL prt_ctl(tab3d_1=z_dqsb  , clinfo1=' blk_ice_core: z_dqsb : ', tab3d_2=z_dqlw  , clinfo2=' z_dqlw : ', kdim=ijpl)
576         CALL prt_ctl(tab3d_1=p_dqns  , clinfo1=' blk_ice_core: p_dqns : ', tab3d_2=p_qsr   , clinfo2=' p_qsr  : ', kdim=ijpl)
577         CALL prt_ctl(tab3d_1=pst     , clinfo1=' blk_ice_core: pst    : ', tab3d_2=p_qns   , clinfo2=' p_qns  : ', kdim=ijpl)
578         CALL prt_ctl(tab2d_1=p_tpr   , clinfo1=' blk_ice_core: p_tpr  : ', tab2d_2=p_spr   , clinfo2=' p_spr  : ')
579         CALL prt_ctl(tab2d_1=p_taui  , clinfo1=' blk_ice_core: p_taui : ', tab2d_2=p_tauj  , clinfo2=' p_tauj : ')
580         CALL prt_ctl(tab2d_1=z_wnds_t, clinfo1=' blk_ice_core: z_wnds_t : ')
581      ENDIF
582
583   END SUBROUTINE blk_ice_core
584 
585
586   SUBROUTINE TURB_CORE_1Z(zu, sst, T_a, q_sat, q_a,   &
587      &                        dU, Cd, Ch, Ce   )
588      !!----------------------------------------------------------------------
589      !!                      ***  ROUTINE  turb_core  ***
590      !!
591      !! ** Purpose :   Computes turbulent transfert coefficients of surface
592      !!                fluxes according to Large & Yeager (2004)
593      !!
594      !! ** Method  :   I N E R T I A L   D I S S I P A T I O N   M E T H O D
595      !!      Momentum, Latent and sensible heat exchange coefficients
596      !!      Caution: this procedure should only be used in cases when air
597      !!      temperature (T_air), air specific humidity (q_air) and wind (dU)
598      !!      are provided at the same height 'zzu'!
599      !!
600      !! References :
601      !!      Large & Yeager, 2004 : ???
602      !! History :
603      !!        !  XX-XX  (???     )  Original code
604      !!   9.0  !  05-08  (L. Brodeau) Rewriting and optimization
605      !!----------------------------------------------------------------------
606      !! * Arguments
607
608      REAL(wp), INTENT(in) :: zu                 ! altitude of wind measurement       [m]
609      REAL(wp), INTENT(in), DIMENSION(jpi,jpj) ::  &
610         sst,       &       ! sea surface temperature         [Kelvin]
611         T_a,       &       ! potential air temperature       [Kelvin]
612         q_sat,     &       ! sea surface specific humidity   [kg/kg]
613         q_a,       &       ! specific air humidity           [kg/kg]
614         dU                 ! wind module |U(zu)-U(0)|        [m/s]
615      REAL(wp), intent(out), DIMENSION(jpi,jpj)  :: &
616         Cd,    &                ! transfert coefficient for momentum       (tau)
617         Ch,    &                ! transfert coefficient for temperature (Q_sens)
618         Ce                      ! transfert coefficient for evaporation  (Q_lat)
619
620      !! * Local declarations
621      REAL(wp), DIMENSION(jpi,jpj)  ::   &
622         dU10,        &       ! dU                                   [m/s]
623         dT,          &       ! air/sea temperature differeence      [K]
624         dq,          &       ! air/sea humidity difference          [K]
625         Cd_n10,      &       ! 10m neutral drag coefficient
626         Ce_n10,      &       ! 10m neutral latent coefficient
627         Ch_n10,      &       ! 10m neutral sensible coefficient
628         sqrt_Cd_n10, &       ! root square of Cd_n10
629         sqrt_Cd,     &       ! root square of Cd
630         T_vpot,      &       ! virtual potential temperature        [K]
631         T_star,      &       ! turbulent scale of tem. fluct.
632         q_star,      &       ! turbulent humidity of temp. fluct.
633         U_star,      &       ! turb. scale of velocity fluct.
634         L,           &       ! Monin-Obukov length                  [m]
635         zeta,        &       ! stability parameter at height zu
636         U_n10,       &       ! neutral wind velocity at 10m         [m]   
637         xlogt, xct, zpsi_h, zpsi_m
638      !!
639      INTEGER :: j_itt
640      INTEGER, PARAMETER :: nb_itt = 3
641      INTEGER, DIMENSION(jpi,jpj)  ::   &
642         stab         ! 1st guess stability test integer
643
644      REAL(wp), PARAMETER ::                        &
645         grav   = 9.8,          &  ! gravity                       
646         kappa  = 0.4              ! von Karman s constant
647
648      !! * Start
649      !! Air/sea differences
650      dU10 = max(0.5, dU)     ! we don't want to fall under 0.5 m/s
651      dT = T_a - sst          ! assuming that T_a is allready the potential temp. at zzu
652      dq = q_a - q_sat
653      !!   
654      !! Virtual potential temperature
655      T_vpot = T_a*(1. + 0.608*q_a)
656      !!
657      !! Neutral Drag Coefficient
658      stab    = 0.5 + sign(0.5,dT)    ! stable : stab = 1 ; unstable : stab = 0
659      Cd_n10  = 1E-3 * ( 2.7/dU10 + 0.142 + dU10/13.09 )    !   L & Y eq. (6a)
660      sqrt_Cd_n10 = sqrt(Cd_n10)
661      Ce_n10  = 1E-3 * ( 34.6 * sqrt_Cd_n10 )               !   L & Y eq. (6b)
662      Ch_n10  = 1E-3*sqrt_Cd_n10*(18*stab + 32.7*(1-stab)) !   L & Y eq. (6c), (6d)
663      !!
664      !! Initializing transfert coefficients with their first guess neutral equivalents :
665      Cd = Cd_n10 ;  Ce = Ce_n10 ;  Ch = Ch_n10 ;  sqrt_Cd = sqrt(Cd)
666
667      !! * Now starting iteration loop
668      DO j_itt=1, nb_itt
669         !! Turbulent scales :
670         U_star  = sqrt_Cd*dU10                !   L & Y eq. (7a)
671         T_star  = Ch/sqrt_Cd*dT               !   L & Y eq. (7b)
672         q_star  = Ce/sqrt_Cd*dq               !   L & Y eq. (7c)
673
674         !! Estimate the Monin-Obukov length :
675         L  = (U_star**2)/( kappa*grav*(T_star/T_vpot + q_star/(q_a + 1./0.608)) )
676
677         !! Stability parameters :
678         zeta = zu/L ;  zeta   = sign( min(abs(zeta),10.0), zeta )
679         zpsi_h = psi_h(zeta)
680         zpsi_m = psi_m(zeta)
681
682         !! Shifting the wind speed to 10m and neutral stability :
683         U_n10 = dU10*1./(1. + sqrt_Cd_n10/kappa*(log(zu/10.) - zpsi_m)) !  L & Y eq. (9a)
684
685         !! Updating the neutral 10m transfer coefficients :
686         Cd_n10  = 1E-3 * (2.7/U_n10 + 0.142 + U_n10/13.09)              !  L & Y eq. (6a)
687         sqrt_Cd_n10 = sqrt(Cd_n10)
688         Ce_n10  = 1E-3 * (34.6 * sqrt_Cd_n10)                           !  L & Y eq. (6b)
689         stab    = 0.5 + sign(0.5,zeta)
690         Ch_n10  = 1E-3*sqrt_Cd_n10*(18.*stab + 32.7*(1-stab))           !  L & Y eq. (6c), (6d)
691
692         !! Shifting the neutral  10m transfer coefficients to ( zu , zeta ) :
693         !!
694         xct = 1. + sqrt_Cd_n10/kappa*(log(zu/10) - zpsi_m)
695         Cd  = Cd_n10/(xct*xct) ;  sqrt_Cd = sqrt(Cd)
696         !!
697         xlogt = log(zu/10.) - zpsi_h
698         !!
699         xct = 1. + Ch_n10*xlogt/kappa/sqrt_Cd_n10
700         Ch  = Ch_n10*sqrt_Cd/sqrt_Cd_n10/xct
701         !!
702         xct = 1. + Ce_n10*xlogt/kappa/sqrt_Cd_n10
703         Ce  = Ce_n10*sqrt_Cd/sqrt_Cd_n10/xct
704         !!
705      END DO
706      !!
707    END SUBROUTINE TURB_CORE_1Z
708
709
710    SUBROUTINE TURB_CORE_2Z(zt, zu, sst, T_zt, q_sat, q_zt, dU, Cd, Ch, Ce, T_zu, q_zu)
711      !!----------------------------------------------------------------------
712      !!                      ***  ROUTINE  turb_core  ***
713      !!
714      !! ** Purpose :   Computes turbulent transfert coefficients of surface
715      !!                fluxes according to Large & Yeager (2004).
716      !!
717      !! ** Method  :   I N E R T I A L   D I S S I P A T I O N   M E T H O D
718      !!      Momentum, Latent and sensible heat exchange coefficients
719      !!      Caution: this procedure should only be used in cases when air
720      !!      temperature (T_air) and air specific humidity (q_air) are at 2m
721      !!      whereas wind (dU) is at 10m.
722      !!
723      !! References :
724      !!      Large & Yeager, 2004 : ???
725      !! History :
726      !!   9.0  !  06-12  (L. Brodeau) Original code for 2Z
727      !!----------------------------------------------------------------------
728      REAL(wp), INTENT(in)   :: &
729         zt,      &     ! height for T_zt and q_zt                   [m]
730         zu             ! height for dU                              [m]
731      REAL(wp), INTENT(in), DIMENSION(jpi,jpj) ::  &
732         sst,      &     ! sea surface temperature              [Kelvin]
733         T_zt,     &     ! potential air temperature            [Kelvin]
734         q_sat,    &     ! sea surface specific humidity         [kg/kg]
735         q_zt,     &     ! specific air humidity                 [kg/kg]
736         dU              ! relative wind module |U(zu)-U(0)|       [m/s]
737      REAL(wp), INTENT(out), DIMENSION(jpi,jpj)  ::  &
738         Cd,       &     ! transfer coefficient for momentum         (tau)
739         Ch,       &     ! transfer coefficient for sensible heat (Q_sens)
740         Ce,       &     ! transfert coefficient for evaporation   (Q_lat)
741         T_zu,     &     ! air temp. shifted at zu                     [K]
742         q_zu            ! spec. hum.  shifted at zu               [kg/kg]
743
744      !! * Local declarations
745      REAL(wp), DIMENSION(jpi,jpj) ::  &
746         dU10,        &     ! dU                                [m/s]
747         dT,          &     ! air/sea temperature differeence   [K]
748         dq,          &     ! air/sea humidity difference       [K]
749         Cd_n10,      &     ! 10m neutral drag coefficient
750         Ce_n10,      &     ! 10m neutral latent coefficient
751         Ch_n10,      &     ! 10m neutral sensible coefficient
752         sqrt_Cd_n10, &     ! root square of Cd_n10
753         sqrt_Cd,     &     ! root square of Cd
754         T_vpot_u,    &     ! virtual potential temperature        [K]
755         T_star,      &     ! turbulent scale of tem. fluct.
756         q_star,      &     ! turbulent humidity of temp. fluct.
757         U_star,      &     ! turb. scale of velocity fluct.
758         L,           &     ! Monin-Obukov length                  [m]
759         zeta_u,      &     ! stability parameter at height zu
760         zeta_t,      &     ! stability parameter at height zt
761         U_n10,       &     ! neutral wind velocity at 10m        [m]
762         xlogt, xct, zpsi_hu, zpsi_ht, zpsi_m
763
764      INTEGER :: j_itt
765      INTEGER, PARAMETER :: nb_itt = 3   ! number of itterations
766      INTEGER, DIMENSION(jpi,jpj) :: &
767           &     stab                ! 1st stability test integer
768      REAL(wp), PARAMETER ::                        &
769         grav   = 9.8,      &  ! gravity                       
770         kappa  = 0.4          ! von Karman's constant
771
772      !!  * Start
773
774      !! Initial air/sea differences
775      dU10 = max(0.5, dU)      !  we don't want to fall under 0.5 m/s
776      dT = T_zt - sst 
777      dq = q_zt - q_sat
778
779      !! Neutral Drag Coefficient :
780      stab = 0.5 + sign(0.5,dT)                 ! stab = 1  if dT > 0  -> STABLE
781      Cd_n10  = 1E-3*( 2.7/dU10 + 0.142 + dU10/13.09 ) 
782      sqrt_Cd_n10 = sqrt(Cd_n10)
783      Ce_n10  = 1E-3*( 34.6 * sqrt_Cd_n10 )
784      Ch_n10  = 1E-3*sqrt_Cd_n10*(18*stab + 32.7*(1 - stab))
785
786      !! Initializing transf. coeff. with their first guess neutral equivalents :
787      Cd = Cd_n10 ;  Ce = Ce_n10 ;  Ch = Ch_n10 ;  sqrt_Cd = sqrt(Cd)
788
789      !! Initializing z_u values with z_t values :
790      T_zu = T_zt ;  q_zu = q_zt
791
792      !!  * Now starting iteration loop
793      DO j_itt=1, nb_itt
794         dT = T_zu - sst ;  dq = q_zu - q_sat ! Updating air/sea differences
795         T_vpot_u = T_zu*(1. + 0.608*q_zu)    ! Updating virtual potential temperature at zu
796         U_star = sqrt_Cd*dU10                ! Updating turbulent scales :   (L & Y eq. (7))
797         T_star  = Ch/sqrt_Cd*dT              !
798         q_star  = Ce/sqrt_Cd*dq              !
799         !!
800         L = (U_star*U_star) &                ! Estimate the Monin-Obukov length at height zu
801              & / (kappa*grav/T_vpot_u*(T_star*(1.+0.608*q_zu) + 0.608*T_zu*q_star))
802         !! Stability parameters :
803         zeta_u  = zu/L  ;  zeta_u = sign( min(abs(zeta_u),10.0), zeta_u )
804         zeta_t  = zt/L  ;  zeta_t = sign( min(abs(zeta_t),10.0), zeta_t )
805         zpsi_hu = psi_h(zeta_u)
806         zpsi_ht = psi_h(zeta_t)
807         zpsi_m  = psi_m(zeta_u)
808         !!
809         !! Shifting the wind speed to 10m and neutral stability : (L & Y eq.(9a))
810!        U_n10 = dU10/(1. + sqrt_Cd_n10/kappa*(log(zu/10.) - psi_m(zeta_u)))
811         U_n10 = dU10/(1. + sqrt_Cd_n10/kappa*(log(zu/10.) - zpsi_m))
812         !!
813         !! Shifting temperature and humidity at zu :          (L & Y eq. (9b-9c))
814!        T_zu = T_zt - T_star/kappa*(log(zt/zu) + psi_h(zeta_u) - psi_h(zeta_t))
815         T_zu = T_zt - T_star/kappa*(log(zt/zu) + zpsi_hu - zpsi_ht)
816!        q_zu = q_zt - q_star/kappa*(log(zt/zu) + psi_h(zeta_u) - psi_h(zeta_t))
817         q_zu = q_zt - q_star/kappa*(log(zt/zu) + zpsi_hu - zpsi_ht)
818         !!
819         !! q_zu cannot have a negative value : forcing 0
820         stab = 0.5 + sign(0.5,q_zu) ;  q_zu = stab*q_zu
821         !!
822         !! Updating the neutral 10m transfer coefficients :
823         Cd_n10  = 1E-3 * (2.7/U_n10 + 0.142 + U_n10/13.09)    ! L & Y eq. (6a)
824         sqrt_Cd_n10 = sqrt(Cd_n10)
825         Ce_n10  = 1E-3 * (34.6 * sqrt_Cd_n10)                 ! L & Y eq. (6b)
826         stab    = 0.5 + sign(0.5,zeta_u)
827         Ch_n10  = 1E-3*sqrt_Cd_n10*(18.*stab + 32.7*(1-stab)) ! L & Y eq. (6c-6d)
828         !!
829         !!
830         !! Shifting the neutral 10m transfer coefficients to (zu,zeta_u) :
831!        xct = 1. + sqrt_Cd_n10/kappa*(log(zu/10.) - psi_m(zeta_u))
832         xct = 1. + sqrt_Cd_n10/kappa*(log(zu/10.) - zpsi_m)
833         Cd = Cd_n10/(xct*xct) ; sqrt_Cd = sqrt(Cd)
834         !!
835!        xlogt = log(zu/10.) - psi_h(zeta_u)
836         xlogt = log(zu/10.) - zpsi_hu
837         !!
838         xct = 1. + Ch_n10*xlogt/kappa/sqrt_Cd_n10
839         Ch  = Ch_n10*sqrt_Cd/sqrt_Cd_n10/xct
840         !!
841         xct = 1. + Ce_n10*xlogt/kappa/sqrt_Cd_n10
842         Ce  = Ce_n10*sqrt_Cd/sqrt_Cd_n10/xct
843         !!
844         !!
845      END DO
846      !!
847    END SUBROUTINE TURB_CORE_2Z
848
849
850    FUNCTION psi_m(zta)   !! Psis, L & Y eq. (8c), (8d), (8e)
851      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: zta
852
853      REAL(wp), PARAMETER :: pi = 3.141592653589793_wp
854      REAL(wp), DIMENSION(jpi,jpj)             :: psi_m
855      REAL(wp), DIMENSION(jpi,jpj)             :: X2, X, stabit
856      X2 = sqrt(abs(1. - 16.*zta))  ;  X2 = max(X2 , 1.0) ;  X  = sqrt(X2)
857      stabit    = 0.5 + sign(0.5,zta)
858      psi_m = -5.*zta*stabit  &                                                  ! Stable
859           & + (1. - stabit)*(2*log((1. + X)/2) + log((1. + X2)/2) - 2*atan(X) + pi/2)  ! Unstable
860    END FUNCTION psi_m
861
862    FUNCTION psi_h(zta)    !! Psis, L & Y eq. (8c), (8d), (8e)
863      REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: zta
864
865      REAL(wp), DIMENSION(jpi,jpj)             :: psi_h
866      REAL(wp), DIMENSION(jpi,jpj)             :: X2, X, stabit
867      X2 = sqrt(abs(1. - 16.*zta))  ;  X2 = max(X2 , 1.) ;  X  = sqrt(X2)
868      stabit    = 0.5 + sign(0.5,zta)
869      psi_h = -5.*zta*stabit  &                                       ! Stable
870           & + (1. - stabit)*(2.*log( (1. + X2)/2. ))                 ! Unstable
871    END FUNCTION psi_h
872 
873   !!======================================================================
874END MODULE sbcblk_core
Note: See TracBrowser for help on using the repository browser.