New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
domvvl.F90 in branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/DOM – NEMO

source: branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/DOM/domvvl.F90 @ 2690

Last change on this file since 2690 was 2690, checked in by gm, 13 years ago

dynamic mem: #785 ; homogeneization of the coding style associated with dyn allocation

  • Property svn:keywords set to Id
File size: 10.0 KB
Line 
1MODULE domvvl
2   !!======================================================================
3   !!                       ***  MODULE domvvl   ***
4   !! Ocean :
5   !!======================================================================
6   !! History :  2.0  !  2006-06  (B. Levier, L. Marie)  original code
7   !!            3.1  !  2009-02  (G. Madec, M. Leclair, R. Benshila)  pure z* coordinate
8   !!----------------------------------------------------------------------
9#if defined key_vvl
10   !!----------------------------------------------------------------------
11   !!   'key_vvl'                              variable volume
12   !!----------------------------------------------------------------------
13   !!   dom_vvl     : defined coefficients to distribute ssh on each layers
14   !!----------------------------------------------------------------------
15   USE oce             ! ocean dynamics and tracers
16   USE dom_oce         ! ocean space and time domain
17   USE sbc_oce         ! surface boundary condition: ocean
18   USE phycst          ! physical constants
19   USE in_out_manager  ! I/O manager
20   USE lib_mpp         ! distributed memory computing library
21   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC   dom_vvl       ! called by domain.F90
27   PUBLIC   dom_vvl_alloc ! called by nemogcm.F90
28
29   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   ee_t, ee_u, ee_v, ee_f   !: ???
30   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   mut , muu , muv , muf    !: ???
31
32   REAL(wp),         ALLOCATABLE, SAVE, DIMENSION(:)     ::   r2dt   ! vertical profile time-step, = 2 rdttra
33      !                                                              ! except at nit000 (=rdttra) if neuler=0
34
35   !! * Substitutions
36#  include "domzgr_substitute.h90"
37#  include "vectopt_loop_substitute.h90"
38   !!----------------------------------------------------------------------
39   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
40   !! $Id$
41   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
42   !!----------------------------------------------------------------------
43CONTAINS       
44
45   INTEGER FUNCTION dom_vvl_alloc()
46      !!----------------------------------------------------------------------
47      !!                ***  ROUTINE dom_vvl_alloc  ***
48      !!----------------------------------------------------------------------
49      !
50      ALLOCATE( mut (jpi,jpj,jpk) , muu (jpi,jpj,jpk) , muv (jpi,jpj,jpk) , muf (jpi,jpj,jpk) ,     &
51         &      ee_t(jpi,jpj)     , ee_u(jpi,jpj)     , ee_v(jpi,jpj)     , ee_f(jpi,jpj)     ,     &
52         &      r2dt        (jpk)                                                             , STAT=dom_vvl_alloc )
53         !
54      IF( lk_mpp             )   CALL mpp_sum ( dom_vvl_alloc )
55      IF( dom_vvl_alloc /= 0 )   CALL ctl_warn('dom_vvl_alloc: failed to allocate arrays')
56      !
57   END FUNCTION dom_vvl_alloc
58
59
60   SUBROUTINE dom_vvl
61      !!----------------------------------------------------------------------
62      !!                ***  ROUTINE dom_vvl  ***
63      !!                   
64      !! ** Purpose :  compute coefficients muX at T-U-V-F points to spread
65      !!               ssh over the whole water column (scale factors)
66      !!----------------------------------------------------------------------
67      USE wrk_nemo, ONLY:   wrk_in_use, wrk_not_released
68      USE wrk_nemo, ONLY:   zs_t   => wrk_2d_1 , zs_u_1 => wrk_2d_2 , zs_v_1 => wrk_2d_3     ! 2D workspace
69      !
70      INTEGER  ::   ji, jj, jk   ! dummy loop indices
71      REAL(wp) ::   zcoefu , zcoefv   , zcoeff                   ! local scalars
72      REAL(wp) ::   zv_t_ij, zv_t_ip1j, zv_t_ijp1, zv_t_ip1jp1   !   -      -
73      !!----------------------------------------------------------------------
74
75      IF( wrk_in_use(2, 1,2,3) ) THEN
76         CALL ctl_stop('dom_vvl: requested workspace arrays unavailable')   ;   RETURN
77      ENDIF
78
79      IF(lwp) THEN
80         WRITE(numout,*)
81         WRITE(numout,*) 'dom_vvl : Variable volume initialization'
82         WRITE(numout,*) '~~~~~~~~  compute coef. used to spread ssh over each layers'
83      ENDIF
84     
85      IF( dom_vvl_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'dom_vvl : unable to allocate arrays' )
86
87      fsdept(:,:,:) = gdept (:,:,:)
88      fsdepw(:,:,:) = gdepw (:,:,:)
89      fsde3w(:,:,:) = gdep3w(:,:,:)
90      fse3t (:,:,:) = e3t   (:,:,:)
91      fse3u (:,:,:) = e3u   (:,:,:)
92      fse3v (:,:,:) = e3v   (:,:,:)
93      fse3f (:,:,:) = e3f   (:,:,:)
94      fse3w (:,:,:) = e3w   (:,:,:)
95      fse3uw(:,:,:) = e3uw  (:,:,:)
96      fse3vw(:,:,:) = e3vw  (:,:,:)
97
98      !                                 !==  mu computation  ==!
99      ee_t(:,:) = fse3t_0(:,:,1)                ! Lower bound : thickness of the first model level
100      ee_u(:,:) = fse3u_0(:,:,1)
101      ee_v(:,:) = fse3v_0(:,:,1)
102      ee_f(:,:) = fse3f_0(:,:,1)
103      DO jk = 2, jpkm1                          ! Sum of the masked vertical scale factors
104         ee_t(:,:) = ee_t(:,:) + fse3t_0(:,:,jk) * tmask(:,:,jk)
105         ee_u(:,:) = ee_u(:,:) + fse3u_0(:,:,jk) * umask(:,:,jk)
106         ee_v(:,:) = ee_v(:,:) + fse3v_0(:,:,jk) * vmask(:,:,jk)
107         DO jj = 1, jpjm1                      ! f-point : fmask=shlat at coasts, use the product of umask
108            ee_f(:,jj) = ee_f(:,jj) + fse3f_0(:,jj,jk) *  umask(:,jj,jk) * umask(:,jj+1,jk)
109         END DO
110      END DO 
111      !                                         ! Compute and mask the inverse of the local depth at T, U, V and F points
112      ee_t(:,:) = 1. / ee_t(:,:) * tmask(:,:,1)
113      ee_u(:,:) = 1. / ee_u(:,:) * umask(:,:,1)
114      ee_v(:,:) = 1. / ee_v(:,:) * vmask(:,:,1)
115      DO jj = 1, jpjm1                               ! f-point case fmask cannot be used
116         ee_f(:,jj) = 1. / ee_f(:,jj) * umask(:,jj,1) * umask(:,jj+1,1)
117      END DO
118      CALL lbc_lnk( ee_f, 'F', 1. )                  ! lateral boundary condition on ee_f
119      !
120      DO jk = 1, jpk                            ! mu coefficients
121         mut(:,:,jk) = ee_t(:,:) * tmask(:,:,jk)     ! T-point at T levels
122         muu(:,:,jk) = ee_u(:,:) * umask(:,:,jk)     ! U-point at T levels
123         muv(:,:,jk) = ee_v(:,:) * vmask(:,:,jk)     ! V-point at T levels
124      END DO
125      DO jk = 1, jpk                                 ! F-point : fmask=shlat at coasts, use the product of umask
126         DO jj = 1, jpjm1
127               muf(:,jj,jk) = ee_f(:,jj) * umask(:,jj,jk) * umask(:,jj+1,jk)   ! at T levels
128         END DO
129         muf(:,jpj,jk) = 0.e0
130      END DO
131      CALL lbc_lnk( muf, 'F', 1. )                   ! lateral boundary condition
132
133
134      hu_0(:,:) = 0.e0                          ! Reference ocean depth at U- and V-points
135      hv_0(:,:) = 0.e0
136      DO jk = 1, jpk
137         hu_0(:,:) = hu_0(:,:) + fse3u_0(:,:,jk) * umask(:,:,jk)
138         hv_0(:,:) = hv_0(:,:) + fse3v_0(:,:,jk) * vmask(:,:,jk)
139      END DO
140     
141      ! surface at t-points and inverse surface at (u/v)-points used in surface averaging computations
142      ! for ssh and scale factors
143      zs_t  (:,:) =       e1t(:,:) * e2t(:,:)
144      zs_u_1(:,:) = 0.5 / e1u(:,:) * e2u(:,:)
145      zs_v_1(:,:) = 0.5 / e1v(:,:) * e2v(:,:)
146
147      DO jj = 1, jpjm1                          ! initialise before and now Sea Surface Height at u-, v-, f-points
148         DO ji = 1, jpim1   ! NO vector opt.
149            zcoefu = umask(ji,jj,1) * zs_u_1(ji,jj)
150            zcoefv = vmask(ji,jj,1) * zs_v_1(ji,jj)
151            zcoeff = 0.5 * umask(ji,jj,1) * umask(ji,jj+1,1) / ( e1f(ji,jj) * e2f(ji,jj) )
152            ! before fields
153            zv_t_ij       = zs_t(ji  ,jj  ) * sshb(ji  ,jj  )
154            zv_t_ip1j     = zs_t(ji+1,jj  ) * sshb(ji+1,jj  )
155            zv_t_ijp1     = zs_t(ji  ,jj+1) * sshb(ji  ,jj+1)
156            sshu_b(ji,jj) = zcoefu * ( zv_t_ij + zv_t_ip1j )
157            sshv_b(ji,jj) = zcoefv * ( zv_t_ij + zv_t_ijp1 )
158            ! now fields
159            zv_t_ij       = zs_t(ji  ,jj  ) * sshn(ji  ,jj  )
160            zv_t_ip1j     = zs_t(ji+1,jj  ) * sshn(ji+1,jj  )
161            zv_t_ijp1     = zs_t(ji  ,jj+1) * sshn(ji  ,jj+1)
162            zv_t_ip1jp1   = zs_t(ji  ,jj+1) * sshn(ji  ,jj+1)
163            sshu_n(ji,jj) = zcoefu * ( zv_t_ij + zv_t_ip1j )
164            sshv_n(ji,jj) = zcoefv * ( zv_t_ij + zv_t_ijp1 )
165            sshf_n(ji,jj) = zcoeff * ( zv_t_ij + zv_t_ip1j + zv_t_ijp1 + zv_t_ip1jp1 )
166         END DO
167      END DO
168      CALL lbc_lnk( sshu_n, 'U', 1. )   ;   CALL lbc_lnk( sshu_b, 'U', 1. )      ! lateral boundary conditions
169      CALL lbc_lnk( sshv_n, 'V', 1. )   ;   CALL lbc_lnk( sshv_b, 'V', 1. )
170      CALL lbc_lnk( sshf_n, 'F', 1. )
171
172                                                ! initialise before scale factors at (u/v)-points
173      ! Scale factor anomaly at (u/v)-points: surface averaging of scale factor at t-points
174      DO jk = 1, jpkm1
175         DO jj = 1, jpjm1
176            DO ji = 1, jpim1
177               zv_t_ij           = zs_t(ji  ,jj  ) * fse3t_b(ji  ,jj  ,jk)
178               zv_t_ip1j         = zs_t(ji+1,jj  ) * fse3t_b(ji+1,jj  ,jk)
179               zv_t_ijp1         = zs_t(ji  ,jj+1) * fse3t_b(ji  ,jj+1,jk)
180               fse3u_b(ji,jj,jk) = umask(ji,jj,jk) * ( zs_u_1(ji,jj) * ( zv_t_ij + zv_t_ip1j ) - fse3u_0(ji,jj,jk) )
181               fse3v_b(ji,jj,jk) = vmask(ji,jj,jk) * ( zs_v_1(ji,jj) * ( zv_t_ij + zv_t_ijp1 ) - fse3v_0(ji,jj,jk) )
182            END DO
183         END DO
184      END DO
185      CALL lbc_lnk( fse3u_b(:,:,:), 'U', 1. )               ! lateral boundary conditions
186      CALL lbc_lnk( fse3v_b(:,:,:), 'V', 1. )
187      ! Add initial scale factor to scale factor anomaly
188      fse3u_b(:,:,:) = fse3u_b(:,:,:) + fse3u_0(:,:,:)
189      fse3v_b(:,:,:) = fse3v_b(:,:,:) + fse3v_0(:,:,:)
190      !
191      IF( wrk_not_released(2, 1,2,3) )   CALL ctl_stop('dom_vvl: failed to release workspace arrays')
192      !
193   END SUBROUTINE dom_vvl
194
195#else
196   !!----------------------------------------------------------------------
197   !!   Default option :                                      Empty routine
198   !!----------------------------------------------------------------------
199CONTAINS
200   SUBROUTINE dom_vvl
201   END SUBROUTINE dom_vvl
202#endif
203
204   !!======================================================================
205END MODULE domvvl
Note: See TracBrowser for help on using the repository browser.