New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynadv_cen2.F90 in branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/DYN/dynadv_cen2.F90 @ 2690

Last change on this file since 2690 was 2690, checked in by gm, 13 years ago

dynamic mem: #785 ; homogeneization of the coding style associated with dyn allocation

  • Property svn:keywords set to Id
File size: 8.5 KB
Line 
1MODULE dynadv_cen2
2   !!======================================================================
3   !!                       ***  MODULE  dynadv  ***
4   !! Ocean dynamics: Update the momentum trend with the flux form advection
5   !!                 using a 2nd order centred scheme
6   !!======================================================================
7   !! History :  2.0  ! 2006-08  (G. Madec, S. Theetten)  Original code
8   !!            3.2  ! 2009-07  (R. Benshila)  Suppression of rigid-lid option
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   dyn_adv_cen2       : flux form momentum advection (ln_dynadv_cen2=T)
13   !!                        trends using a 2nd order centred scheme 
14   !!----------------------------------------------------------------------
15   USE oce            ! ocean dynamics and tracers
16   USE dom_oce        ! ocean space and time domain
17   USE trdmod_oce     ! ocean variables trends
18   USE trdmod         ! ocean dynamics trends
19   USE in_out_manager ! I/O manager
20   USE lib_mpp        ! MPP library
21   USE prtctl         ! Print control
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC   dyn_adv_cen2   ! routine called by step.F90
27
28   !! * Substitutions
29#  include "domzgr_substitute.h90"
30#  include "vectopt_loop_substitute.h90"
31   !!----------------------------------------------------------------------
32   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
33   !! $Id$
34   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
35   !!----------------------------------------------------------------------
36CONTAINS
37
38   SUBROUTINE dyn_adv_cen2( kt )
39      !!----------------------------------------------------------------------
40      !!                  ***  ROUTINE dyn_adv_cen2  ***
41      !!
42      !! ** Purpose :   Compute the now momentum advection trend in flux form
43      !!              and the general trend of the momentum equation.
44      !!
45      !! ** Method  :   Trend evaluated using now fields (centered in time)
46      !!
47      !! ** Action  :   (ua,va) updated with the now vorticity term trend
48      !!----------------------------------------------------------------------
49      USE wrk_nemo, ONLY:   wrk_in_use, wrk_not_released
50      USE oce     , ONLY:   zfu   => ta       , zfv   => sa       ! (ta,sa) used as 3D workspace
51      USE wrk_nemo, ONLY:   zfu_t => wrk_3d_1 , zfv_t => wrk_3d_4 , zfu_uw =>wrk_3d_6   ! 3D workspaces
52      USE wrk_nemo, ONLY:   zfu_f => wrk_3d_2 , zfv_f => wrk_3d_5 , zfv_vw =>wrk_3d_7
53      USE wrk_nemo, ONLY:   zfw   => wrk_3d_3 
54      !
55      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
56      !
57      INTEGER  ::   ji, jj, jk   ! dummy loop indices
58      REAL(wp) ::   zbu, zbv     ! local scalars
59      !!----------------------------------------------------------------------
60
61      IF( kt == nit000 .AND. lwp ) THEN
62         WRITE(numout,*)
63         WRITE(numout,*) 'dyn_adv_cen2 : 2nd order flux form momentum advection'
64         WRITE(numout,*) '~~~~~~~~~~~~'
65      ENDIF
66
67      ! Check that global workspace arrays aren't already in use
68      IF( wrk_in_use(3, 1,2,3,4,5,6,7) ) THEN
69         CALL ctl_stop('dyn_adv_cen2 : requested workspace array unavailable')   ;   RETURN
70      ENDIF
71
72      IF( l_trddyn ) THEN           ! Save ua and va trends
73         zfu_uw(:,:,:) = ua(:,:,:)
74         zfv_vw(:,:,:) = va(:,:,:)
75      ENDIF
76
77      !                                      ! ====================== !
78      !                                      !  Horizontal advection  !
79      DO jk = 1, jpkm1                       ! ====================== !
80         !                                         ! horizontal volume fluxes
81         zfu(:,:,jk) = 0.25 * e2u(:,:) * fse3u(:,:,jk) * un(:,:,jk)
82         zfv(:,:,jk) = 0.25 * e1v(:,:) * fse3v(:,:,jk) * vn(:,:,jk)
83         !
84         DO jj = 1, jpjm1                          ! horizontal momentum fluxes at T- and F-point
85            DO ji = 1, fs_jpim1   ! vector opt.
86               zfu_t(ji+1,jj  ,jk) = ( zfu(ji,jj,jk) + zfu(ji+1,jj  ,jk) ) * ( un(ji,jj,jk) + un(ji+1,jj  ,jk) )
87               zfv_f(ji  ,jj  ,jk) = ( zfv(ji,jj,jk) + zfv(ji+1,jj  ,jk) ) * ( un(ji,jj,jk) + un(ji  ,jj+1,jk) )
88               zfu_f(ji  ,jj  ,jk) = ( zfu(ji,jj,jk) + zfu(ji  ,jj+1,jk) ) * ( vn(ji,jj,jk) + vn(ji+1,jj  ,jk) )
89               zfv_t(ji  ,jj+1,jk) = ( zfv(ji,jj,jk) + zfv(ji  ,jj+1,jk) ) * ( vn(ji,jj,jk) + vn(ji  ,jj+1,jk) )
90            END DO
91         END DO
92         DO jj = 2, jpjm1                          ! divergence of horizontal momentum fluxes
93            DO ji = fs_2, fs_jpim1   ! vector opt.
94               zbu = e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk)
95               zbv = e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk)
96               !
97               ua(ji,jj,jk) = ua(ji,jj,jk) - (  zfu_t(ji+1,jj  ,jk) - zfu_t(ji  ,jj  ,jk)    &
98                  &                           + zfv_f(ji  ,jj  ,jk) - zfv_f(ji  ,jj-1,jk)  ) / zbu
99               va(ji,jj,jk) = va(ji,jj,jk) - (  zfu_f(ji  ,jj  ,jk) - zfu_f(ji-1,jj  ,jk)    &
100                  &                           + zfv_t(ji  ,jj+1,jk) - zfv_t(ji  ,jj  ,jk)  ) / zbv
101            END DO
102         END DO
103      END DO
104      !
105      IF( l_trddyn ) THEN                          ! save the horizontal advection trend for diagnostic
106         zfu_uw(:,:,:) = ua(:,:,:) - zfu_uw(:,:,:)
107         zfv_vw(:,:,:) = va(:,:,:) - zfv_vw(:,:,:)
108         CALL trd_mod( zfu_uw, zfv_vw, jpdyn_trd_had, 'DYN', kt )
109         zfu_t(:,:,:) = ua(:,:,:)
110         zfv_t(:,:,:) = va(:,:,:)
111      ENDIF
112      !
113
114      !                                      ! ==================== !
115      !                                      !  Vertical advection  !
116      DO jk = 1, jpkm1                       ! ==================== !
117         !                                         ! Vertical volume fluxesÊ
118         zfw(:,:,jk) = 0.25 * e1t(:,:) * e2t(:,:) * wn(:,:,jk)
119         !
120         IF( jk == 1 ) THEN                        ! surface/bottom advective fluxes                   
121            zfu_uw(:,:,jpk) = 0.e0                      ! Bottom  value : flux set to zero
122            zfv_vw(:,:,jpk) = 0.e0
123            !                                           ! Surface value :
124            IF( lk_vvl ) THEN                                ! variable volume : flux set to zero
125               zfu_uw(:,:, 1 ) = 0.e0   
126               zfv_vw(:,:, 1 ) = 0.e0
127            ELSE                                             ! constant volume : advection through the surface
128               DO jj = 2, jpjm1
129                  DO ji = fs_2, fs_jpim1
130                     zfu_uw(ji,jj, 1 ) = 2.e0 * ( zfw(ji,jj,1) + zfw(ji+1,jj  ,1) ) * un(ji,jj,1)
131                     zfv_vw(ji,jj, 1 ) = 2.e0 * ( zfw(ji,jj,1) + zfw(ji  ,jj+1,1) ) * vn(ji,jj,1)
132                  END DO
133               END DO
134            ENDIF
135         ELSE                                      ! interior fluxes
136            DO jj = 2, jpjm1
137               DO ji = fs_2, fs_jpim1   ! vector opt.
138                  zfu_uw(ji,jj,jk) = ( zfw(ji,jj,jk)+ zfw(ji+1,jj  ,jk) ) * ( un(ji,jj,jk) + un(ji,jj,jk-1) )
139                  zfv_vw(ji,jj,jk) = ( zfw(ji,jj,jk)+ zfw(ji  ,jj+1,jk) ) * ( vn(ji,jj,jk) + vn(ji,jj,jk-1) )
140               END DO
141            END DO
142         ENDIF
143      END DO
144      DO jk = 1, jpkm1                             ! divergence of vertical momentum flux divergence
145         DO jj = 2, jpjm1 
146            DO ji = fs_2, fs_jpim1   ! vector opt.
147               ua(ji,jj,jk) =  ua(ji,jj,jk) - ( zfu_uw(ji,jj,jk) - zfu_uw(ji,jj,jk+1) )    &
148                  &  / ( e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk) )
149               va(ji,jj,jk) =  va(ji,jj,jk) - ( zfv_vw(ji,jj,jk) - zfv_vw(ji,jj,jk+1) )    &
150                  &  / ( e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk) )
151            END DO
152         END DO
153      END DO
154      !
155      IF( l_trddyn ) THEN                          ! save the vertical advection trend for diagnostic
156         zfu_t(:,:,:) = ua(:,:,:) - zfu_t(:,:,:)
157         zfv_t(:,:,:) = va(:,:,:) - zfv_t(:,:,:)
158         CALL trd_mod( zfu_t, zfv_t, jpdyn_trd_zad, 'DYN', kt )
159      ENDIF
160      !                                            ! Control print
161      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' cen2 adv - Ua: ', mask1=umask,   &
162         &                       tab3d_2=va, clinfo2=           ' Va: ', mask2=vmask, clinfo3='dyn' )
163      !
164      IF( wrk_not_released(3, 1,2,3,4,5,6,7) )   CALL ctl_stop('dyn_adv_cen2: failed to release workspace array')
165      !
166   END SUBROUTINE dyn_adv_cen2
167
168   !!==============================================================================
169END MODULE dynadv_cen2
Note: See TracBrowser for help on using the repository browser.