New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
eosbn2.F90 in branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/TRA/eosbn2.F90 @ 2690

Last change on this file since 2690 was 2690, checked in by gm, 13 years ago

dynamic mem: #785 ; homogeneization of the coding style associated with dyn allocation

  • Property svn:keywords set to Id
File size: 39.2 KB
Line 
1MODULE eosbn2
2   !!==============================================================================
3   !!                       ***  MODULE  eosbn2  ***
4   !! Ocean diagnostic variable : equation of state - in situ and potential density
5   !!                                               - Brunt-Vaisala frequency
6   !!==============================================================================
7   !! History :  OPA  ! 1989-03  (O. Marti)  Original code
8   !!            6.0  ! 1994-07  (G. Madec, M. Imbard)  add bn2
9   !!            6.0  ! 1994-08  (G. Madec)  Add Jackett & McDougall eos
10   !!            7.0  ! 1996-01  (G. Madec)  statement function for e3
11   !!            8.1  ! 1997-07  (G. Madec)  density instead of volumic mass
12   !!             -   ! 1999-02  (G. Madec, N. Grima) semi-implicit pressure gradient
13   !!            8.2  ! 2001-09  (M. Ben Jelloul)  bugfix on linear eos
14   !!   NEMO     1.0  ! 2002-10  (G. Madec)  add eos_init
15   !!             -   ! 2002-11  (G. Madec, A. Bozec)  partial step, eos_insitu_2d
16   !!             -   ! 2003-08  (G. Madec)  F90, free form
17   !!            3.0  ! 2006-08  (G. Madec)  add tfreez function
18   !!            3.3  ! 2010-05  (C. Ethe, G. Madec)  merge TRC-TRA
19   !!             -   ! 2010-10  (G. Nurser, G. Madec)  add eos_alpbet used in ldfslp
20   !!----------------------------------------------------------------------
21
22   !!----------------------------------------------------------------------
23   !!   eos            : generic interface of the equation of state
24   !!   eos_insitu     : Compute the in situ density
25   !!   eos_insitu_pot : Compute the insitu and surface referenced potential
26   !!                    volumic mass
27   !!   eos_insitu_2d  : Compute the in situ density for 2d fields
28   !!   eos_bn2        : Compute the Brunt-Vaisala frequency
29   !!   eos_alpbet     : calculates the in situ thermal and haline expansion coeff.
30   !!   tfreez         : Compute the surface freezing temperature
31   !!   eos_init       : set eos parameters (namelist)
32   !!----------------------------------------------------------------------
33   USE dom_oce         ! ocean space and time domain
34   USE phycst          ! physical constants
35   USE zdfddm          ! vertical physics: double diffusion
36   USE in_out_manager  ! I/O manager
37   USE lib_mpp         ! MPP library
38   USE prtctl          ! Print control
39
40   IMPLICIT NONE
41   PRIVATE
42
43   !                   !! * Interface
44   INTERFACE eos
45      MODULE PROCEDURE eos_insitu, eos_insitu_pot, eos_insitu_2d
46   END INTERFACE
47   INTERFACE bn2
48      MODULE PROCEDURE eos_bn2
49   END INTERFACE
50
51   PUBLIC   eos        ! called by step, istate, tranpc and zpsgrd modules
52   PUBLIC   eos_init   ! called by istate module
53   PUBLIC   bn2        ! called by step module
54   PUBLIC   eos_alpbet ! called by ldfslp module
55   PUBLIC   tfreez     ! called by sbcice_... modules
56
57   !                                          !!* Namelist (nameos) *
58   INTEGER , PUBLIC ::   nn_eos   = 0         !: = 0/1/2 type of eq. of state and Brunt-Vaisala frequ.
59   REAL(wp), PUBLIC ::   rn_alpha = 2.0e-4_wp !: thermal expension coeff. (linear equation of state)
60   REAL(wp), PUBLIC ::   rn_beta  = 7.7e-4_wp !: saline  expension coeff. (linear equation of state)
61
62   REAL(wp), PUBLIC ::   ralpbet              !: alpha / beta ratio
63   
64   !! * Substitutions
65#  include "domzgr_substitute.h90"
66#  include "vectopt_loop_substitute.h90"
67   !!----------------------------------------------------------------------
68   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
69   !! $Id$
70   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
71   !!----------------------------------------------------------------------
72CONTAINS
73
74   SUBROUTINE eos_insitu( pts, prd )
75      !!----------------------------------------------------------------------
76      !!                   ***  ROUTINE eos_insitu  ***
77      !!
78      !! ** Purpose :   Compute the in situ density (ratio rho/rau0) from
79      !!       potential temperature and salinity using an equation of state
80      !!       defined through the namelist parameter nn_eos.
81      !!
82      !! ** Method  :   3 cases:
83      !!      nn_eos = 0 : Jackett and McDougall (1994) equation of state.
84      !!         the in situ density is computed directly as a function of
85      !!         potential temperature relative to the surface (the opa t
86      !!         variable), salt and pressure (assuming no pressure variation
87      !!         along geopotential surfaces, i.e. the pressure p in decibars
88      !!         is approximated by the depth in meters.
89      !!              prd(t,s,p) = ( rho(t,s,p) - rau0 ) / rau0
90      !!         with pressure                      p        decibars
91      !!              potential temperature         t        deg celsius
92      !!              salinity                      s        psu
93      !!              reference volumic mass        rau0     kg/m**3
94      !!              in situ volumic mass          rho      kg/m**3
95      !!              in situ density anomalie      prd      no units
96      !!         Check value: rho = 1060.93298 kg/m**3 for p=10000 dbar,
97      !!          t = 40 deg celcius, s=40 psu
98      !!      nn_eos = 1 : linear equation of state function of temperature only
99      !!              prd(t) = 0.0285 - rn_alpha * t
100      !!      nn_eos = 2 : linear equation of state function of temperature and
101      !!               salinity
102      !!              prd(t,s) = rn_beta * s - rn_alpha * tn - 1.
103      !!      Note that no boundary condition problem occurs in this routine
104      !!      as pts are defined over the whole domain.
105      !!
106      !! ** Action  :   compute prd , the in situ density (no units)
107      !!
108      !! References :   Jackett and McDougall, J. Atmos. Ocean. Tech., 1994
109      !!----------------------------------------------------------------------
110      USE wrk_nemo, ONLY:   wrk_in_use, wrk_not_released
111      USE wrk_nemo, ONLY:   zws => wrk_3d_1   ! 3D workspace
112      !!
113      REAL(wp), DIMENSION(:,:,:,:), INTENT(in   ) ::   pts   ! 1 : potential temperature  [Celcius]
114      !                                                      ! 2 : salinity               [psu]
115      REAL(wp), DIMENSION(:,:,:)  , INTENT(  out) ::   prd   ! in situ density            [-]
116      !!
117      INTEGER  ::   ji, jj, jk           ! dummy loop indices
118      REAL(wp) ::   zt , zs , zh , zsr   ! local scalars
119      REAL(wp) ::   zr1, zr2, zr3, zr4   !   -      -
120      REAL(wp) ::   zrhop, ze, zbw, zb   !   -      -
121      REAL(wp) ::   zd , zc , zaw, za    !   -      -
122      REAL(wp) ::   zb1, za1, zkw, zk0   !   -      -
123      REAL(wp) ::   zrau0r               !   -      -
124      !!----------------------------------------------------------------------
125
126      IF( wrk_in_use(3, 1) ) THEN
127         CALL ctl_stop('eos_insitu: requested workspace array unavailable')   ;   RETURN
128      ENDIF
129
130      SELECT CASE( nn_eos )
131      !
132      CASE( 0 )                !==  Jackett and McDougall (1994) formulation  ==!
133         zrau0r = 1.e0 / rau0
134!CDIR NOVERRCHK
135         zws(:,:,:) = SQRT( ABS( pts(:,:,:,jp_sal) ) )
136         
137         DO jk = 1, jpkm1
138            DO jj = 1, jpj
139               DO ji = 1, jpi
140                  zt = pts   (ji,jj,jk,jp_tem)
141                  zs = pts   (ji,jj,jk,jp_sal)
142                  zh = fsdept(ji,jj,jk)        ! depth
143                  zsr= zws   (ji,jj,jk)        ! square root salinity
144                  !
145                  ! compute volumic mass pure water at atm pressure
146                  zr1= ( ( ( ( 6.536332e-9_wp  *zt - 1.120083e-6_wp )*zt + 1.001685e-4_wp )*zt   &
147                     &        -9.095290e-3_wp )*zt + 6.793952e-2_wp )*zt +  999.842594_wp
148                  ! seawater volumic mass atm pressure
149                  zr2= ( ( ( 5.3875e-9_wp*zt-8.2467e-7_wp ) *zt+7.6438e-5_wp ) *zt        &
150                     &                      -4.0899e-3_wp ) *zt+0.824493_wp
151                  zr3= ( -1.6546e-6_wp*zt+1.0227e-4_wp )    *zt-5.72466e-3_wp
152                  zr4= 4.8314e-4_wp
153                  !
154                  ! potential volumic mass (reference to the surface)
155                  zrhop= ( zr4*zs + zr3*zsr + zr2 ) *zs + zr1
156                  !
157                  ! add the compression terms
158                  ze = ( -3.508914e-8_wp*zt-1.248266e-8_wp ) *zt-2.595994e-6_wp
159                  zbw= (  1.296821e-6_wp*zt-5.782165e-9_wp ) *zt+1.045941e-4_wp
160                  zb = zbw + ze * zs
161                  !
162                  zd = -2.042967e-2_wp
163                  zc =   (-7.267926e-5_wp*zt+2.598241e-3_wp ) *zt+0.1571896_wp
164                  zaw= ( ( 5.939910e-6_wp*zt+2.512549e-3_wp ) *zt-0.1028859_wp ) *zt - 4.721788_wp
165                  za = ( zd*zsr + zc ) *zs + zaw
166                  !
167                  zb1=   (-0.1909078_wp*zt+7.390729_wp )        *zt-55.87545_wp
168                  za1= ( ( 2.326469e-3_wp*zt+1.553190_wp)       *zt-65.00517_wp ) *zt+1044.077_wp
169                  zkw= ( ( (-1.361629e-4_wp*zt-1.852732e-2_wp ) *zt-30.41638_wp ) *zt + 2098.925_wp ) *zt+190925.6_wp
170                  zk0= ( zb1*zsr + za1 )*zs + zkw
171                  !
172                  ! masked in situ density anomaly
173                  prd(ji,jj,jk) = (  zrhop / (  1.0_wp - zh / ( zk0 - zh * ( za - zh * zb ) )  )    &
174                     &             - rau0  ) * zrau0r * tmask(ji,jj,jk)
175               END DO
176            END DO
177         END DO
178         !
179      CASE( 1 )                !==  Linear formulation function of temperature only  ==!
180         DO jk = 1, jpkm1
181            prd(:,:,jk) = ( 0.0285_wp - rn_alpha * pts(:,:,jk,jp_tem) ) * tmask(:,:,jk)
182         END DO
183         !
184      CASE( 2 )                !==  Linear formulation function of temperature and salinity  ==!
185         DO jk = 1, jpkm1
186            prd(:,:,jk) = ( rn_beta  * pts(:,:,jk,jp_sal) - rn_alpha * pts(:,:,jk,jp_tem) ) * tmask(:,:,jk)
187         END DO
188         !
189      END SELECT
190      !
191      IF(ln_ctl)   CALL prt_ctl( tab3d_1=prd, clinfo1=' eos  : ', ovlap=1, kdim=jpk )
192      !
193      IF( wrk_not_released(3, 1) )   CALL ctl_stop('eos_insitu: failed to release workspace array')
194      !
195   END SUBROUTINE eos_insitu
196
197
198   SUBROUTINE eos_insitu_pot( pts, prd, prhop )
199      !!----------------------------------------------------------------------
200      !!                  ***  ROUTINE eos_insitu_pot  ***
201      !!           
202      !! ** Purpose :   Compute the in situ density (ratio rho/rau0) and the
203      !!      potential volumic mass (Kg/m3) from potential temperature and
204      !!      salinity fields using an equation of state defined through the
205      !!     namelist parameter nn_eos.
206      !!
207      !! ** Method  :
208      !!      nn_eos = 0 : Jackett and McDougall (1994) equation of state.
209      !!         the in situ density is computed directly as a function of
210      !!         potential temperature relative to the surface (the opa t
211      !!         variable), salt and pressure (assuming no pressure variation
212      !!         along geopotential surfaces, i.e. the pressure p in decibars
213      !!         is approximated by the depth in meters.
214      !!              prd(t,s,p) = ( rho(t,s,p) - rau0 ) / rau0
215      !!              rhop(t,s)  = rho(t,s,0)
216      !!         with pressure                      p        decibars
217      !!              potential temperature         t        deg celsius
218      !!              salinity                      s        psu
219      !!              reference volumic mass        rau0     kg/m**3
220      !!              in situ volumic mass          rho      kg/m**3
221      !!              in situ density anomalie      prd      no units
222      !!
223      !!         Check value: rho = 1060.93298 kg/m**3 for p=10000 dbar,
224      !!          t = 40 deg celcius, s=40 psu
225      !!
226      !!      nn_eos = 1 : linear equation of state function of temperature only
227      !!              prd(t) = ( rho(t) - rau0 ) / rau0 = 0.028 - rn_alpha * t
228      !!              rhop(t,s)  = rho(t,s)
229      !!
230      !!      nn_eos = 2 : linear equation of state function of temperature and
231      !!               salinity
232      !!              prd(t,s) = ( rho(t,s) - rau0 ) / rau0
233      !!                       = rn_beta * s - rn_alpha * tn - 1.
234      !!              rhop(t,s)  = rho(t,s)
235      !!      Note that no boundary condition problem occurs in this routine
236      !!      as (tn,sn) or (ta,sa) are defined over the whole domain.
237      !!
238      !! ** Action  : - prd  , the in situ density (no units)
239      !!              - prhop, the potential volumic mass (Kg/m3)
240      !!
241      !! References :   Jackett and McDougall, J. Atmos. Ocean. Tech., 1994
242      !!                Brown and Campana, Mon. Weather Rev., 1978
243      !!----------------------------------------------------------------------
244      USE wrk_nemo, ONLY:   wrk_in_use, wrk_not_released
245      USE wrk_nemo, ONLY:   zws => wrk_3d_1 ! 3D workspace
246      !!
247      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts), INTENT(in   ) ::   pts    ! 1 : potential temperature  [Celcius]
248      !                                                                ! 2 : salinity               [psu]
249      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(  out) ::   prd    ! in situ density            [-]
250      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(  out) ::   prhop  ! potential density (surface referenced)
251      !
252      INTEGER  ::   ji, jj, jk   ! dummy loop indices
253      REAL(wp) ::   zt, zs, zh, zsr, zr1, zr2, zr3, zr4, zrhop, ze, zbw   ! local scalars
254      REAL(wp) ::   zb, zd, zc, zaw, za, zb1, za1, zkw, zk0, zrau0r       !   -      -
255      !!----------------------------------------------------------------------
256
257      IF( wrk_in_use(3, 1) ) THEN
258         CALL ctl_stop('eos_insitu_pot: requested workspace array unavailable')   ;   RETURN
259      ENDIF
260
261      SELECT CASE ( nn_eos )
262      !
263      CASE( 0 )                !==  Jackett and McDougall (1994) formulation  ==!
264         zrau0r = 1.e0 / rau0
265!CDIR NOVERRCHK
266         zws(:,:,:) = SQRT( ABS( pts(:,:,:,jp_sal) ) )
267         
268         DO jk = 1, jpkm1
269            DO jj = 1, jpj
270               DO ji = 1, jpi
271                  zt = pts   (ji,jj,jk,jp_tem)
272                  zs = pts   (ji,jj,jk,jp_sal)
273                  zh = fsdept(ji,jj,jk)        ! depth
274                  zsr= zws   (ji,jj,jk)        ! square root salinity
275                  !
276                  ! compute volumic mass pure water at atm pressure
277                  zr1= ( ( ( ( 6.536332e-9_wp*zt-1.120083e-6_wp )*zt+1.001685e-4_wp )*zt   &
278                     &                          -9.095290e-3_wp )*zt+6.793952e-2_wp )*zt+999.842594_wp
279                  ! seawater volumic mass atm pressure
280                  zr2= ( ( ( 5.3875e-9_wp*zt-8.2467e-7_wp ) *zt+7.6438e-5_wp ) *zt   &
281                     &                                         -4.0899e-3_wp ) *zt+0.824493_wp
282                  zr3= ( -1.6546e-6_wp*zt+1.0227e-4_wp )    *zt-5.72466e-3_wp
283                  zr4= 4.8314e-4_wp
284                  !
285                  ! potential volumic mass (reference to the surface)
286                  zrhop= ( zr4*zs + zr3*zsr + zr2 ) *zs + zr1
287                  !
288                  ! save potential volumic mass
289                  prhop(ji,jj,jk) = zrhop * tmask(ji,jj,jk)
290                  !
291                  ! add the compression terms
292                  ze = ( -3.508914e-8_wp*zt-1.248266e-8_wp ) *zt-2.595994e-6_wp
293                  zbw= (  1.296821e-6_wp*zt-5.782165e-9_wp ) *zt+1.045941e-4_wp
294                  zb = zbw + ze * zs
295                  !
296                  zd = -2.042967e-2_wp
297                  zc =   (-7.267926e-5_wp*zt+2.598241e-3_wp ) *zt+0.1571896_wp
298                  zaw= ( ( 5.939910e-6_wp*zt+2.512549e-3_wp ) *zt-0.1028859_wp ) *zt - 4.721788_wp
299                  za = ( zd*zsr + zc ) *zs + zaw
300                  !
301                  zb1=   (  -0.1909078_wp  *zt+7.390729_wp    ) *zt-55.87545_wp
302                  za1= ( (   2.326469e-3_wp*zt+1.553190_wp    ) *zt-65.00517_wp ) *zt + 1044.077_wp
303                  zkw= ( ( (-1.361629e-4_wp*zt-1.852732e-2_wp ) *zt-30.41638_wp ) *zt + 2098.925_wp ) *zt+190925.6_wp
304                  zk0= ( zb1*zsr + za1 )*zs + zkw
305                  !
306                  ! masked in situ density anomaly
307                  prd(ji,jj,jk) = (  zrhop / (  1.0_wp - zh / ( zk0 - zh * ( za - zh * zb ) )  )    &
308                     &             - rau0  ) * zrau0r * tmask(ji,jj,jk)
309               END DO
310            END DO
311         END DO
312         !
313      CASE( 1 )                !==  Linear formulation = F( temperature )  ==!
314         DO jk = 1, jpkm1
315            prd  (:,:,jk) = ( 0.0285_wp - rn_alpha * pts(:,:,jk,jp_tem) )        * tmask(:,:,jk)
316            prhop(:,:,jk) = ( 1.e0_wp   +            prd (:,:,jk)       ) * rau0 * tmask(:,:,jk)
317         END DO
318         !
319      CASE( 2 )                !==  Linear formulation = F( temperature , salinity )  ==!
320         DO jk = 1, jpkm1
321            prd  (:,:,jk) = ( rn_beta  * pts(:,:,jk,jp_sal) - rn_alpha * pts(:,:,jk,jp_tem) )        * tmask(:,:,jk)
322            prhop(:,:,jk) = ( 1.e0_wp  + prd (:,:,jk) )                                       * rau0 * tmask(:,:,jk)
323         END DO
324         !
325      END SELECT
326      !
327      IF(ln_ctl)   CALL prt_ctl( tab3d_1=prd, clinfo1=' eos-p: ', tab3d_2=prhop, clinfo2=' pot : ', ovlap=1, kdim=jpk )
328      !
329      IF( wrk_not_released(3, 1) )   CALL ctl_stop('eos_insitu_pot: failed to release workspace array')
330      !
331   END SUBROUTINE eos_insitu_pot
332
333
334   SUBROUTINE eos_insitu_2d( pts, pdep, prd )
335      !!----------------------------------------------------------------------
336      !!                  ***  ROUTINE eos_insitu_2d  ***
337      !!
338      !! ** Purpose :   Compute the in situ density (ratio rho/rau0) from
339      !!      potential temperature and salinity using an equation of state
340      !!      defined through the namelist parameter nn_eos. * 2D field case
341      !!
342      !! ** Method :
343      !!      nn_eos = 0 : Jackett and McDougall (1994) equation of state.
344      !!         the in situ density is computed directly as a function of
345      !!         potential temperature relative to the surface (the opa t
346      !!         variable), salt and pressure (assuming no pressure variation
347      !!         along geopotential surfaces, i.e. the pressure p in decibars
348      !!         is approximated by the depth in meters.
349      !!              prd(t,s,p) = ( rho(t,s,p) - rau0 ) / rau0
350      !!         with pressure                      p        decibars
351      !!              potential temperature         t        deg celsius
352      !!              salinity                      s        psu
353      !!              reference volumic mass        rau0     kg/m**3
354      !!              in situ volumic mass          rho      kg/m**3
355      !!              in situ density anomalie      prd      no units
356      !!         Check value: rho = 1060.93298 kg/m**3 for p=10000 dbar,
357      !!          t = 40 deg celcius, s=40 psu
358      !!      nn_eos = 1 : linear equation of state function of temperature only
359      !!              prd(t) = 0.0285 - rn_alpha * t
360      !!      nn_eos = 2 : linear equation of state function of temperature and
361      !!               salinity
362      !!              prd(t,s) = rn_beta * s - rn_alpha * tn - 1.
363      !!      Note that no boundary condition problem occurs in this routine
364      !!      as pts are defined over the whole domain.
365      !!
366      !! ** Action  : - prd , the in situ density (no units)
367      !!
368      !! References :   Jackett and McDougall, J. Atmos. Ocean. Tech., 1994
369      !!----------------------------------------------------------------------
370      USE wrk_nemo, ONLY:   wrk_in_use, wrk_not_released
371      USE wrk_nemo, ONLY:   zws => wrk_2d_5 ! 2D workspace
372      !!
373      REAL(wp), DIMENSION(jpi,jpj,jpts), INTENT(in   ) ::   pts   ! 1 : potential temperature  [Celcius]
374      !                                                           ! 2 : salinity               [psu]
375      REAL(wp), DIMENSION(jpi,jpj)     , INTENT(in   ) ::   pdep  ! depth                  [m]
376      REAL(wp), DIMENSION(jpi,jpj)     , INTENT(  out) ::   prd   ! in situ density
377      !!
378      INTEGER  ::   ji, jj                    ! dummy loop indices
379      REAL(wp) ::   zt, zs, zh, zsr, zr1, zr2, zr3, zr4, zrhop, ze, zbw   ! temporary scalars
380      REAL(wp) ::   zb, zd, zc, zaw, za, zb1, za1, zkw, zk0, zmask        !    -         -
381      !!----------------------------------------------------------------------
382
383      IF( wrk_in_use(2, 5) ) THEN
384         CALL ctl_stop('eos_insitu_2d: requested workspace array unavailable')   ;   RETURN
385      ENDIF
386
387      prd(:,:) = 0._wp
388
389      SELECT CASE( nn_eos )
390      !
391      CASE( 0 )                !==  Jackett and McDougall (1994) formulation  ==!
392      !
393!CDIR NOVERRCHK
394         DO jj = 1, jpjm1
395!CDIR NOVERRCHK
396            DO ji = 1, fs_jpim1   ! vector opt.
397               zws(ji,jj) = SQRT( ABS( pts(ji,jj,jp_sal) ) )
398            END DO
399         END DO
400         DO jj = 1, jpjm1
401            DO ji = 1, fs_jpim1   ! vector opt.
402               zmask = tmask(ji,jj,1)          ! land/sea bottom mask = surf. mask
403               zt    = pts  (ji,jj,jp_tem)            ! interpolated T
404               zs    = pts  (ji,jj,jp_sal)            ! interpolated S
405               zsr   = zws  (ji,jj)            ! square root of interpolated S
406               zh    = pdep (ji,jj)            ! depth at the partial step level
407               !
408               ! compute volumic mass pure water at atm pressure
409               zr1 = ( ( ( ( 6.536332e-9_wp*zt-1.120083e-6_wp )*zt+1.001685e-4_wp )*zt   &
410                  &                        -9.095290e-3_wp )*zt+6.793952e-2_wp )*zt+999.842594_wp
411               ! seawater volumic mass atm pressure
412               zr2 = ( ( ( 5.3875e-9_wp*zt-8.2467e-7_wp )*zt+7.6438e-5_wp ) *zt   &
413                  &                                   -4.0899e-3_wp ) *zt+0.824493_wp
414               zr3 = ( -1.6546e-6_wp*zt+1.0227e-4_wp ) *zt-5.72466e-3_wp
415               zr4 = 4.8314e-4_wp
416               !
417               ! potential volumic mass (reference to the surface)
418               zrhop= ( zr4*zs + zr3*zsr + zr2 ) *zs + zr1
419               !
420               ! add the compression terms
421               ze = ( -3.508914e-8_wp*zt-1.248266e-8_wp ) *zt-2.595994e-6_wp
422               zbw= (  1.296821e-6_wp*zt-5.782165e-9_wp ) *zt+1.045941e-4_wp
423               zb = zbw + ze * zs
424               !
425               zd =    -2.042967e-2_wp
426               zc =   (-7.267926e-5_wp*zt+2.598241e-3_wp ) *zt+0.1571896_wp
427               zaw= ( ( 5.939910e-6_wp*zt+2.512549e-3_wp ) *zt-0.1028859_wp ) *zt -4.721788_wp
428               za = ( zd*zsr + zc ) *zs + zaw
429               !
430               zb1=     (-0.1909078_wp  *zt+7.390729_wp      ) *zt-55.87545_wp
431               za1=   ( ( 2.326469e-3_wp*zt+1.553190_wp      ) *zt-65.00517_wp ) *zt+1044.077_wp
432               zkw= ( ( (-1.361629e-4_wp*zt-1.852732e-2_wp   ) *zt-30.41638_wp ) *zt   &
433                  &                             +2098.925_wp ) *zt+190925.6_wp
434               zk0= ( zb1*zsr + za1 )*zs + zkw
435               !
436               ! masked in situ density anomaly
437               prd(ji,jj) = ( zrhop / (  1.0_wp - zh / ( zk0 - zh * ( za - zh * zb ) )  ) - rau0 ) / rau0 * zmask
438            END DO
439         END DO
440         !
441      CASE( 1 )                !==  Linear formulation = F( temperature )  ==!
442         DO jj = 1, jpjm1
443            DO ji = 1, fs_jpim1   ! vector opt.
444               prd(ji,jj) = ( 0.0285_wp - rn_alpha * pts(ji,jj,jp_tem) ) * tmask(ji,jj,1)
445            END DO
446         END DO
447         !
448      CASE( 2 )                !==  Linear formulation = F( temperature , salinity )  ==!
449         DO jj = 1, jpjm1
450            DO ji = 1, fs_jpim1   ! vector opt.
451               prd(ji,jj) = ( rn_beta * pts(ji,jj,jp_sal) - rn_alpha * pts(ji,jj,jp_tem) ) * tmask(ji,jj,1) 
452            END DO
453         END DO
454         !
455      END SELECT
456
457      IF(ln_ctl)   CALL prt_ctl( tab2d_1=prd, clinfo1=' eos2d: ' )
458      !
459      IF( wrk_not_released(3, 5) )   CALL ctl_stop('eos_insitu_2d: failed to release workspace array')
460      !
461   END SUBROUTINE eos_insitu_2d
462
463
464   SUBROUTINE eos_bn2( pts, pn2 )
465      !!----------------------------------------------------------------------
466      !!                  ***  ROUTINE eos_bn2  ***
467      !!
468      !! ** Purpose :   Compute the local Brunt-Vaisala frequency at the time-
469      !!      step of the input arguments
470      !!     
471      !! ** Method :
472      !!       * nn_eos = 0  : UNESCO sea water properties
473      !!         The brunt-vaisala frequency is computed using the polynomial
474      !!      polynomial expression of McDougall (1987):
475      !!            N^2 = grav * beta * ( alpha/beta*dk[ t ] - dk[ s ] )/e3w
476      !!      If lk_zdfddm=T, the heat/salt buoyancy flux ratio Rrau is
477      !!      computed and used in zdfddm module :
478      !!              Rrau = alpha/beta * ( dk[ t ] / dk[ s ] )
479      !!       * nn_eos = 1  : linear equation of state (temperature only)
480      !!            N^2 = grav * rn_alpha * dk[ t ]/e3w
481      !!       * nn_eos = 2  : linear equation of state (temperature & salinity)
482      !!            N^2 = grav * (rn_alpha * dk[ t ] - rn_beta * dk[ s ] ) / e3w
483      !!      The use of potential density to compute N^2 introduces e r r o r
484      !!      in the sign of N^2 at great depths. We recommand the use of
485      !!      nn_eos = 0, except for academical studies.
486      !!        Macro-tasked on horizontal slab (jk-loop)
487      !!      N.B. N^2 is set to zero at the first level (JK=1) in inidtr
488      !!      and is never used at this level.
489      !!
490      !! ** Action  : - pn2 : the brunt-vaisala frequency
491      !!
492      !! References :   McDougall, J. Phys. Oceanogr., 17, 1950-1964, 1987.
493      !!----------------------------------------------------------------------
494      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts), INTENT(in   ) ::   pts   ! 1 : potential temperature  [Celcius]
495      !                                                               ! 2 : salinity               [psu]
496      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(  out) ::   pn2   ! Brunt-Vaisala frequency    [s-1]
497      !!
498      INTEGER  ::   ji, jj, jk   ! dummy loop indices
499      REAL(wp) ::   zgde3w, zt, zs, zh, zalbet, zbeta   ! local scalars
500#if defined key_zdfddm
501      REAL(wp) ::   zds   ! local scalars
502#endif
503      !!----------------------------------------------------------------------
504
505      ! pn2 : interior points only (2=< jk =< jpkm1 )
506      ! --------------------------
507      !
508      SELECT CASE( nn_eos )
509      !
510      CASE( 0 )                !==  Jackett and McDougall (1994) formulation  ==!
511         DO jk = 2, jpkm1
512            DO jj = 1, jpj
513               DO ji = 1, jpi
514                  zgde3w = grav / fse3w(ji,jj,jk)
515                  zt = 0.5 * ( pts(ji,jj,jk,jp_tem) + pts(ji,jj,jk-1,jp_tem) )         ! potential temperature at w-pt
516                  zs = 0.5 * ( pts(ji,jj,jk,jp_sal) + pts(ji,jj,jk-1,jp_sal) ) - 35.0  ! salinity anomaly (s-35) at w-pt
517                  zh = fsdepw(ji,jj,jk)                                                ! depth in meters  at w-point
518                  !
519                  zalbet = ( ( ( - 0.255019e-07_wp * zt + 0.298357e-05_wp ) * zt   &   ! ratio alpha/beta
520                     &                                  - 0.203814e-03_wp ) * zt   &
521                     &                                  + 0.170907e-01_wp ) * zt   &
522                     &   +         0.665157e-01_wp                                 &
523                     &   +     ( - 0.678662e-05_wp * zs                            &
524                     &           - 0.846960e-04_wp * zt + 0.378110e-02_wp ) * zs   &
525                     &   +   ( ( - 0.302285e-13_wp * zh                            &
526                     &           - 0.251520e-11_wp * zs                            &
527                     &           + 0.512857e-12_wp * zt * zt              ) * zh   &
528                     &           - 0.164759e-06_wp * zs                            &
529                     &        +(   0.791325e-08_wp * zt - 0.933746e-06_wp ) * zt   &
530                     &                                  + 0.380374e-04_wp ) * zh
531                     !
532                  zbeta  = ( ( -0.415613e-09_wp * zt + 0.555579e-07_wp ) * zt      &   ! beta
533                     &                               - 0.301985e-05_wp ) * zt      &
534                     &   +       0.785567e-03_wp                                   &
535                     &   + (     0.515032e-08_wp * zs                              &
536                     &         + 0.788212e-08_wp * zt - 0.356603e-06_wp ) * zs     &
537                     &   + ( (   0.121551e-17_wp * zh                              &
538                     &         - 0.602281e-15_wp * zs                              &
539                     &         - 0.175379e-14_wp * zt + 0.176621e-12_wp ) * zh     &
540                     &                                + 0.408195e-10_wp   * zs     &
541                     &     + ( - 0.213127e-11_wp * zt + 0.192867e-09_wp ) * zt     &
542                     &                                - 0.121555e-07_wp ) * zh
543                     !
544                  pn2(ji,jj,jk) = zgde3w * zbeta * tmask(ji,jj,jk)           &   ! N^2
545                     &          * ( zalbet * ( pts(ji,jj,jk-1,jp_tem) - pts(ji,jj,jk,jp_tem) )   &
546                     &                     - ( pts(ji,jj,jk-1,jp_sal) - pts(ji,jj,jk,jp_sal) ) )
547#if defined key_zdfddm
548                  !                                                         !!bug **** caution a traiter zds=dk[S]= 0 !!!!
549                  zds = ( pts(ji,jj,jk-1,jp_sal) - pts(ji,jj,jk,jp_sal) )                    ! Rrau = (alpha / beta) (dk[t] / dk[s])
550                  IF ( ABS( zds) <= 1.e-20_wp ) zds = 1.e-20_wp
551                  rrau(ji,jj,jk) = zalbet * ( pts(ji,jj,jk-1,jp_tem) - pts(ji,jj,jk,jp_tem) ) / zds
552#endif
553               END DO
554            END DO
555         END DO
556         !
557      CASE( 1 )                !==  Linear formulation = F( temperature )  ==!
558         DO jk = 2, jpkm1
559            pn2(:,:,jk) = grav * rn_alpha * ( pts(:,:,jk-1,jp_tem) - pts(:,:,jk,jp_tem) ) / fse3w(:,:,jk) * tmask(:,:,jk)
560         END DO
561         !
562      CASE( 2 )                !==  Linear formulation = F( temperature , salinity )  ==!
563         DO jk = 2, jpkm1
564            pn2(:,:,jk) = grav * (  rn_alpha * ( pts(:,:,jk-1,jp_tem) - pts(:,:,jk,jp_tem) )      &
565               &                  - rn_beta  * ( pts(:,:,jk-1,jp_sal) - pts(:,:,jk,jp_sal) )  )   &
566               &               / fse3w(:,:,jk) * tmask(:,:,jk)
567         END DO 
568#if defined key_zdfddm
569         DO jk = 2, jpkm1                                 ! Rrau = (alpha / beta) (dk[t] / dk[s])
570            DO jj = 1, jpj
571               DO ji = 1, jpi
572                  zds = ( pts(ji,jj,jk-1,jp_sal) - pts(ji,jj,jk,jp_sal) ) 
573                  IF ( ABS( zds ) <= 1.e-20_wp ) zds = 1.e-20_wp
574                  rrau(ji,jj,jk) = ralpbet * ( pts(ji,jj,jk-1,jp_tem) - pts(ji,jj,jk,jp_tem) ) / zds
575               END DO
576            END DO
577         END DO
578#endif
579      END SELECT
580
581      IF(ln_ctl)   CALL prt_ctl( tab3d_1=pn2, clinfo1=' bn2  : ', ovlap=1, kdim=jpk )
582#if defined key_zdfddm
583      IF(ln_ctl)   CALL prt_ctl( tab3d_1=rrau, clinfo1=' rrau : ', ovlap=1, kdim=jpk )
584#endif
585      !
586   END SUBROUTINE eos_bn2
587
588
589   SUBROUTINE eos_alpbet( pts, palph, pbeta )
590      !!----------------------------------------------------------------------
591      !!                 ***  ROUTINE ldf_slp_grif  ***
592      !!
593      !! ** Purpose :   Calculates the thermal and haline expansion coefficients at T-points.
594      !!
595      !! ** Method  :   calculates alpha and beta at T-points
596      !!       * nn_eos = 0  : UNESCO sea water properties
597      !!         The brunt-vaisala frequency is computed using the polynomial
598      !!      polynomial expression of McDougall (1987):
599      !!            N^2 = grav * beta * ( alpha/beta*dk[ t ] - dk[ s ] )/e3w
600      !!      If lk_zdfddm=T, the heat/salt buoyancy flux ratio Rrau is
601      !!      computed and used in zdfddm module :
602      !!              Rrau = alpha/beta * ( dk[ t ] / dk[ s ] )
603      !!       * nn_eos = 1  : linear equation of state (temperature only)
604      !!            N^2 = grav * rn_alpha * dk[ t ]/e3w
605      !!       * nn_eos = 2  : linear equation of state (temperature & salinity)
606      !!            N^2 = grav * (rn_alpha * dk[ t ] - rn_beta * dk[ s ] ) / e3w
607      !!       * nn_eos = 3  : Jackett JAOT 2003 ???
608      !!
609      !! ** Action  : - palph, pbeta : thermal and haline expansion coeff. at T-point
610      !!----------------------------------------------------------------------
611      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts), INTENT(in   ) ::   pts            ! pot. temperature & salinity
612      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(  out) ::   palph, pbeta   ! thermal & haline expansion coeff.
613      !
614      INTEGER  ::   ji, jj, jk   ! dummy loop indices
615      REAL(wp) ::   zt, zs, zh   ! local scalars
616      !!----------------------------------------------------------------------
617      !
618      SELECT CASE ( nn_eos )
619      !
620      CASE ( 0 )               ! Jackett and McDougall (1994) formulation
621         DO jk = 1, jpk
622            DO jj = 1, jpj
623               DO ji = 1, jpi
624                  zt = pts(ji,jj,jk,jp_tem)           ! potential temperature
625                  zs = pts(ji,jj,jk,jp_sal) - 35._wp  ! salinity anomaly (s-35)
626                  zh = fsdept(ji,jj,jk)              ! depth in meters
627                  !
628                  pbeta(ji,jj,jk) = ( ( -0.415613e-09_wp * zt + 0.555579e-07_wp ) * zt   &
629                     &                                        - 0.301985e-05_wp ) * zt   &
630                     &           + 0.785567e-03_wp                                       &
631                     &           + (     0.515032e-08_wp * zs                            &
632                     &                 + 0.788212e-08_wp * zt - 0.356603e-06_wp ) * zs   &
633                     &           + ( (   0.121551e-17_wp * zh                            &
634                     &                 - 0.602281e-15_wp * zs                            &
635                     &                 - 0.175379e-14_wp * zt + 0.176621e-12_wp ) * zh   &
636                     &                                        + 0.408195e-10_wp   * zs   &
637                     &             + ( - 0.213127e-11_wp * zt + 0.192867e-09_wp ) * zt   &
638                     &                                        - 0.121555e-07_wp ) * zh
639                     !
640                  palph(ji,jj,jk) = - pbeta(ji,jj,jk) *                             &
641                      &     ((( ( - 0.255019e-07_wp * zt + 0.298357e-05_wp ) * zt   &
642                      &                                  - 0.203814e-03_wp ) * zt   &
643                      &                                  + 0.170907e-01_wp ) * zt   &
644                      &   + 0.665157e-01_wp                                         &
645                      &   +     ( - 0.678662e-05_wp * zs                            &
646                      &           - 0.846960e-04_wp * zt + 0.378110e-02_wp ) * zs   &
647                      &   +   ( ( - 0.302285e-13_wp * zh                            &
648                      &           - 0.251520e-11_wp * zs                            &
649                      &           + 0.512857e-12_wp * zt * zt              ) * zh   &
650                      &           - 0.164759e-06_wp * zs                            &
651                      &        +(   0.791325e-08_wp * zt - 0.933746e-06_wp ) * zt   &
652                      &                                  + 0.380374e-04_wp ) * zh)
653               END DO
654            END DO
655         END DO
656         !
657      CASE ( 1 )
658         palph(:,:,:) = - rn_alpha
659         pbeta(:,:,:) =   0._wp
660         !
661      CASE ( 2 )
662         palph(:,:,:) = - rn_alpha
663         pbeta(:,:,:) =   rn_beta
664         !
665      CASE DEFAULT
666         IF(lwp) WRITE(numout,cform_err)
667         IF(lwp) WRITE(numout,*) '          bad flag value for nn_eos = ', nn_eos
668         nstop = nstop + 1
669         !
670      END SELECT
671      !
672   END SUBROUTINE eos_alpbet
673
674
675   FUNCTION tfreez( psal ) RESULT( ptf )
676      !!----------------------------------------------------------------------
677      !!                 ***  ROUTINE eos_init  ***
678      !!
679      !! ** Purpose :   Compute the sea surface freezing temperature [Celcius]
680      !!
681      !! ** Method  :   UNESCO freezing point at the surface (pressure = 0???)
682      !!       freezing point [Celcius]=(-.0575+1.710523e-3*sqrt(abs(s))-2.154996e-4*s)*s-7.53e-4*p
683      !!       checkvalue: tf= -2.588567 Celsius for s=40.0psu, p=500. decibars
684      !!
685      !! Reference  :   UNESCO tech. papers in the marine science no. 28. 1978
686      !!----------------------------------------------------------------------
687      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   psal   ! salinity             [psu]
688      ! Leave result array automatic rather than making explicitly allocated
689      REAL(wp), DIMENSION(jpi,jpj)                ::   ptf    ! freezing temperature [Celcius]
690      !!----------------------------------------------------------------------
691      !
692      ptf(:,:) = ( - 0.0575_wp + 1.710523e-3_wp * SQRT( psal(:,:) )   &
693         &                     - 2.154996e-4_wp *       psal(:,:)   ) * psal(:,:)
694      !
695   END FUNCTION tfreez
696
697
698   SUBROUTINE eos_init
699      !!----------------------------------------------------------------------
700      !!                 ***  ROUTINE eos_init  ***
701      !!
702      !! ** Purpose :   initializations for the equation of state
703      !!
704      !! ** Method  :   Read the namelist nameos and control the parameters
705      !!----------------------------------------------------------------------
706      NAMELIST/nameos/ nn_eos, rn_alpha, rn_beta
707      !!----------------------------------------------------------------------
708      !
709      REWIND( numnam )            ! Read Namelist nameos : equation of state
710      READ  ( numnam, nameos )
711      !
712      IF(lwp) THEN                ! Control print
713         WRITE(numout,*)
714         WRITE(numout,*) 'eos_init : equation of state'
715         WRITE(numout,*) '~~~~~~~~'
716         WRITE(numout,*) '          Namelist nameos : set eos parameters'
717         WRITE(numout,*) '             flag for eq. of state and N^2  nn_eos   = ', nn_eos
718         WRITE(numout,*) '             thermal exp. coef. (linear)    rn_alpha = ', rn_alpha
719         WRITE(numout,*) '             saline  exp. coef. (linear)    rn_beta  = ', rn_beta
720      ENDIF
721      !
722      SELECT CASE( nn_eos )         ! check option
723      !
724      CASE( 0 )                        !==  Jackett and McDougall (1994) formulation  ==!
725         IF(lwp) WRITE(numout,*)
726         IF(lwp) WRITE(numout,*) '          use of Jackett & McDougall (1994) equation of state and'
727         IF(lwp) WRITE(numout,*) '                 McDougall (1987) Brunt-Vaisala frequency'
728         !
729      CASE( 1 )                        !==  Linear formulation = F( temperature )  ==!
730         IF(lwp) WRITE(numout,*)
731         IF(lwp) WRITE(numout,*) '          use of linear eos rho(T) = rau0 * ( 1.0285 - rn_alpha * T )'
732         IF( lk_zdfddm ) CALL ctl_stop( '          double diffusive mixing parameterization requires',   &
733              &                         ' that T and S are used as state variables' )
734         !
735      CASE( 2 )                        !==  Linear formulation = F( temperature , salinity )  ==!
736         ralpbet = rn_alpha / rn_beta
737         IF(lwp) WRITE(numout,*)
738         IF(lwp) WRITE(numout,*) '          use of linear eos rho(T,S) = rau0 * ( rn_beta * S - rn_alpha * T )'
739         !
740      CASE DEFAULT                     !==  ERROR in nn_eos  ==!
741         WRITE(ctmp1,*) '          bad flag value for nn_eos = ', nn_eos
742         CALL ctl_stop( ctmp1 )
743         !
744      END SELECT
745      !
746   END SUBROUTINE eos_init
747
748   !!======================================================================
749END MODULE eosbn2 
Note: See TracBrowser for help on using the repository browser.