New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_iso.F90 in branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/TRA/traldf_iso.F90 @ 2690

Last change on this file since 2690 was 2690, checked in by gm, 13 years ago

dynamic mem: #785 ; homogeneization of the coding style associated with dyn allocation

  • Property svn:keywords set to Id
File size: 15.8 KB
RevLine 
[3]1MODULE traldf_iso
[503]2   !!======================================================================
[457]3   !!                   ***  MODULE  traldf_iso  ***
[2528]4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
[503]5   !!======================================================================
[2528]6   !! History :  OPA  !  1994-08  (G. Madec, M. Imbard)
7   !!            8.0  !  1997-05  (G. Madec)  split into traldf and trazdf
8   !!            NEMO !  2002-08  (G. Madec)  Free form, F90
9   !!            1.0  !  2005-11  (G. Madec)  merge traldf and trazdf :-)
10   !!            3.3  !  2010-09  (C. Ethe, G. Madec) Merge TRA-TRC
[503]11   !!----------------------------------------------------------------------
[457]12#if   defined key_ldfslp   ||   defined key_esopa
[3]13   !!----------------------------------------------------------------------
[457]14   !!   'key_ldfslp'               slope of the lateral diffusive direction
[3]15   !!----------------------------------------------------------------------
[457]16   !!   tra_ldf_iso  : update the tracer trend with the horizontal
17   !!                  component of a iso-neutral laplacian operator
18   !!                  and with the vertical part of
19   !!                  the isopycnal or geopotential s-coord. operator
[3]20   !!----------------------------------------------------------------------
[457]21   USE oce             ! ocean dynamics and active tracers
22   USE dom_oce         ! ocean space and time domain
[2528]23   USE trc_oce         ! share passive tracers/Ocean variables
24   USE zdf_oce         ! ocean vertical physics
[74]25   USE ldftra_oce      ! ocean active tracers: lateral physics
[3]26   USE ldfslp          ! iso-neutral slopes
[132]27   USE diaptr          ! poleward transport diagnostics
[2528]28   USE in_out_manager  ! I/O manager
29   USE iom             ! I/O library
[1756]30#if defined key_diaar5
31   USE phycst          ! physical constants
32   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
33#endif
[3]34
35   IMPLICIT NONE
36   PRIVATE
37
[503]38   PUBLIC   tra_ldf_iso   ! routine called by step.F90
[3]39
40   !! * Substitutions
41#  include "domzgr_substitute.h90"
42#  include "ldftra_substitute.h90"
43#  include "vectopt_loop_substitute.h90"
44   !!----------------------------------------------------------------------
[2528]45   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
46   !! $Id$
47   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
[247]48   !!----------------------------------------------------------------------
[3]49CONTAINS
50
[2528]51   SUBROUTINE tra_ldf_iso( kt, cdtype, pgu, pgv,              &
52      &                                ptb, pta, kjpt, pahtb0 )
[3]53      !!----------------------------------------------------------------------
54      !!                  ***  ROUTINE tra_ldf_iso  ***
[457]55      !!
[3]56      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
[457]57      !!      trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and
58      !!      add it to the general trend of tracer equation.
[3]59      !!
60      !! ** Method  :   The horizontal component of the lateral diffusive trends
61      !!      is provided by a 2nd order operator rotated along neural or geopo-
62      !!      tential surfaces to which an eddy induced advection can be added
63      !!      It is computed using before fields (forward in time) and isopyc-
64      !!      nal or geopotential slopes computed in routine ldfslp.
65      !!
[2528]66      !!      1st part :  masked horizontal derivative of T  ( di[ t ] )
[457]67      !!      ========    with partial cell update if ln_zps=T.
68      !!
69      !!      2nd part :  horizontal fluxes of the lateral mixing operator
70      !!      ========   
[3]71      !!         zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ]
72      !!               - aht       e2u*uslp    dk[ mi(mk(tb)) ]
73      !!         zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ]
74      !!               - aht       e2u*vslp    dk[ mj(mk(tb)) ]
75      !!      take the horizontal divergence of the fluxes:
76      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
77      !!      Add this trend to the general trend (ta,sa):
78      !!         ta = ta + difft
79      !!
[457]80      !!      3rd part: vertical trends of the lateral mixing operator
81      !!      ========  (excluding the vertical flux proportional to dk[t] )
82      !!      vertical fluxes associated with the rotated lateral mixing:
83      !!         zftw =-aht {  e2t*wslpi di[ mi(mk(tb)) ]
84      !!                     + e1t*wslpj dj[ mj(mk(tb)) ]  }
85      !!      take the horizontal divergence of the fluxes:
86      !!         difft = 1/(e1t*e2t*e3t) dk[ zftw ]
87      !!      Add this trend to the general trend (ta,sa):
[2528]88      !!         pta = pta + difft
[3]89      !!
[2528]90      !! ** Action :   Update pta arrays with the before rotated diffusion
[503]91      !!----------------------------------------------------------------------
[2690]92      USE wrk_nemo, ONLY:   wrk_in_use, wrk_not_released
93      USE oce     , ONLY:   zftu => ua       , zftv  => va         ! (ua,va) used as workspace
94      USE wrk_nemo, ONLY:   zdkt => wrk_2d_1 , zdk1t => wrk_2d_2 , z2d  => wrk_2d_3   ! 2D workspace
95      USE wrk_nemo, ONLY:   zdit => wrk_3d_1 , zdjt  => wrk_3d_2 , ztfw => wrk_3d_3   ! 3D workspace
96      !
[2528]97      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
98      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
99      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
100      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
101      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! before and now tracer fields
102      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
103      REAL(wp)                             , INTENT(in   ) ::   pahtb0     ! background diffusion coef
[2690]104      !
[2528]105      INTEGER  ::  ji, jj, jk, jn   ! dummy loop indices
106      REAL(wp) ::  zmsku, zabe1, zcof1, zcoef3   ! local scalars
107      REAL(wp) ::  zmskv, zabe2, zcof2, zcoef4   !   -      -
108      REAL(wp) ::  zcoef0, zbtr, ztra            !   -      -
[1756]109#if defined key_diaar5
[2528]110      REAL(wp)                         ::   zztmp               ! local scalar
[1756]111#endif
[3]112      !!----------------------------------------------------------------------
113
[2690]114      IF( wrk_in_use(3, 1,2,3) .OR. wrk_in_use(2, 1,2,3) ) THEN
115          CALL ctl_stop('tra_ldf_iso : requested workspace array unavailable')   ;   RETURN
116      ENDIF
[2590]117
[2528]118      IF( kt == nit000 )  THEN
[3]119         IF(lwp) WRITE(numout,*)
[2528]120         IF(lwp) WRITE(numout,*) 'tra_ldf_iso : rotated laplacian diffusion operator on ', cdtype
[457]121         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
[3]122      ENDIF
[2528]123      !
124      !                                                          ! ===========
125      DO jn = 1, kjpt                                            ! tracer loop
126         !                                                       ! ===========
127         !                                               
128         !!----------------------------------------------------------------------
129         !!   I - masked horizontal derivative
130         !!----------------------------------------------------------------------
131         !!bug ajout.... why?   ( 1,jpj,:) and (jpi,1,:) should be sufficient....
132         zdit (1,:,:) = 0.e0     ;     zdit (jpi,:,:) = 0.e0
133         zdjt (1,:,:) = 0.e0     ;     zdjt (jpi,:,:) = 0.e0
134         !!end
[3]135
[2528]136         ! Horizontal tracer gradient
137         DO jk = 1, jpkm1
138            DO jj = 1, jpjm1
139               DO ji = 1, fs_jpim1   ! vector opt.
140                  zdit(ji,jj,jk) = ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) ) * umask(ji,jj,jk)
141                  zdjt(ji,jj,jk) = ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
142               END DO
[457]143            END DO
144         END DO
[2528]145         IF( ln_zps ) THEN      ! partial steps correction at the last ocean level
146            DO jj = 1, jpjm1
147               DO ji = 1, fs_jpim1   ! vector opt.
148                  zdit(ji,jj,mbku(ji,jj)) = pgu(ji,jj,jn)         
149                  zdjt(ji,jj,mbkv(ji,jj)) = pgv(ji,jj,jn)     
150               END DO
[457]151            END DO
[3]152         ENDIF
153
[2528]154         !!----------------------------------------------------------------------
155         !!   II - horizontal trend  (full)
156         !!----------------------------------------------------------------------
157!CDIR PARALLEL DO PRIVATE( zdk1t )
158         !                                                ! ===============
159         DO jk = 1, jpkm1                                 ! Horizontal slab
160            !                                             ! ===============
161            ! 1. Vertical tracer gradient at level jk and jk+1
162            ! ------------------------------------------------
163            ! surface boundary condition: zdkt(jk=1)=zdkt(jk=2)
164            zdk1t(:,:) = ( ptb(:,:,jk,jn) - ptb(:,:,jk+1,jn) ) * tmask(:,:,jk+1)
165            !
166            IF( jk == 1 ) THEN   ;   zdkt(:,:) = zdk1t(:,:)
167            ELSE                 ;   zdkt(:,:) = ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) ) * tmask(:,:,jk)
168            ENDIF
[3]169
[2528]170            ! 2. Horizontal fluxes
171            ! --------------------   
172            DO jj = 1 , jpjm1
173               DO ji = 1, fs_jpim1   ! vector opt.
174                  zabe1 = ( fsahtu(ji,jj,jk) + pahtb0 ) * e2u(ji,jj) * fse3u(ji,jj,jk) / e1u(ji,jj)
175                  zabe2 = ( fsahtv(ji,jj,jk) + pahtb0 ) * e1v(ji,jj) * fse3v(ji,jj,jk) / e2v(ji,jj)
176                  !
177                  zmsku = 1. / MAX(  tmask(ji+1,jj,jk  ) + tmask(ji,jj,jk+1)   &
178                     &             + tmask(ji+1,jj,jk+1) + tmask(ji,jj,jk  ), 1. )
179                  !
180                  zmskv = 1. / MAX(  tmask(ji,jj+1,jk  ) + tmask(ji,jj,jk+1)   &
181                     &             + tmask(ji,jj+1,jk+1) + tmask(ji,jj,jk  ), 1. )
182                  !
183                  zcof1 = - fsahtu(ji,jj,jk) * e2u(ji,jj) * uslp(ji,jj,jk) * zmsku
184                  zcof2 = - fsahtv(ji,jj,jk) * e1v(ji,jj) * vslp(ji,jj,jk) * zmskv
185                  !
186                  zftu(ji,jj,jk ) = (  zabe1 * zdit(ji,jj,jk)   &
187                     &              + zcof1 * (  zdkt (ji+1,jj) + zdk1t(ji,jj)      &
188                     &                         + zdk1t(ji+1,jj) + zdkt (ji,jj)  )  ) * umask(ji,jj,jk)
189                  zftv(ji,jj,jk) = (  zabe2 * zdjt(ji,jj,jk)   &
190                     &              + zcof2 * (  zdkt (ji,jj+1) + zdk1t(ji,jj)      &
191                     &                         + zdk1t(ji,jj+1) + zdkt (ji,jj)  )  ) * vmask(ji,jj,jk)                 
192               END DO
[3]193            END DO
194
[2528]195            ! II.4 Second derivative (divergence) and add to the general trend
196            ! ----------------------------------------------------------------
197            DO jj = 2 , jpjm1
198               DO ji = fs_2, fs_jpim1   ! vector opt.
199                  zbtr = 1.0 / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
200                  ztra = zbtr * ( zftu(ji,jj,jk) - zftu(ji-1,jj,jk) + zftv(ji,jj,jk) - zftv(ji,jj-1,jk)  )
201                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
202               END DO
[3]203            END DO
[2528]204            !                                          ! ===============
205         END DO                                        !   End of slab 
206         !                                             ! ===============
207         !
208         ! "Poleward" diffusive heat or salt transports (T-S case only)
209         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN
210            IF( jn == jp_tem)   htr_ldf(:) = ptr_vj( zftv(:,:,:) )
211            IF( jn == jp_sal)   str_ldf(:) = ptr_vj( zftv(:,:,:) )
212         ENDIF
213 
[1756]214#if defined key_diaar5
[2528]215         IF( cdtype == 'TRA' .AND. jn == jp_tem  ) THEN
216            z2d(:,:) = 0._wp 
217            zztmp = rau0 * rcp 
218            DO jk = 1, jpkm1
219               DO jj = 2, jpjm1
220                  DO ji = fs_2, fs_jpim1   ! vector opt.
221                     z2d(ji,jj) = z2d(ji,jj) + zftu(ji,jj,jk) 
222                  END DO
223               END DO
[1756]224            END DO
[2528]225            z2d(:,:) = zztmp * z2d(:,:)
226            CALL lbc_lnk( z2d, 'U', -1. )
227            CALL iom_put( "udiff_heattr", z2d )                  ! heat transport in i-direction
228            z2d(:,:) = 0._wp 
229            DO jk = 1, jpkm1
230               DO jj = 2, jpjm1
231                  DO ji = fs_2, fs_jpim1   ! vector opt.
232                     z2d(ji,jj) = z2d(ji,jj) + zftv(ji,jj,jk) 
233                  END DO
234               END DO
[1756]235            END DO
[2528]236            z2d(:,:) = zztmp * z2d(:,:)
237            CALL lbc_lnk( z2d, 'V', -1. )
238            CALL iom_put( "vdiff_heattr", z2d )                  !  heat transport in i-direction
239         END IF
[1756]240#endif
[3]241
[2528]242         !!----------------------------------------------------------------------
243         !!   III - vertical trend of T & S (extra diagonal terms only)
244         !!----------------------------------------------------------------------
245         
246         ! Local constant initialization
247         ! -----------------------------
248         ztfw(1,:,:) = 0.e0     ;     ztfw(jpi,:,:) = 0.e0
249         
250         ! Vertical fluxes
251         ! ---------------
252         
253         ! Surface and bottom vertical fluxes set to zero
254         ztfw(:,:, 1 ) = 0.e0      ;      ztfw(:,:,jpk) = 0.e0
255         
256         ! interior (2=<jk=<jpk-1)
257         DO jk = 2, jpkm1
258            DO jj = 2, jpjm1
259               DO ji = fs_2, fs_jpim1   ! vector opt.
260                  zcoef0 = - fsahtw(ji,jj,jk) * tmask(ji,jj,jk)
261                  !
262                  zmsku = 1./MAX(   umask(ji  ,jj,jk-1) + umask(ji-1,jj,jk)      &
263                     &            + umask(ji-1,jj,jk-1) + umask(ji  ,jj,jk), 1.  )
264                  zmskv = 1./MAX(   vmask(ji,jj  ,jk-1) + vmask(ji,jj-1,jk)      &
265                     &            + vmask(ji,jj-1,jk-1) + vmask(ji,jj  ,jk), 1.  )
266                  !
267                  zcoef3 = zcoef0 * e2t(ji,jj) * zmsku * wslpi (ji,jj,jk)
268                  zcoef4 = zcoef0 * e1t(ji,jj) * zmskv * wslpj (ji,jj,jk)
269                  !
270                  ztfw(ji,jj,jk) = zcoef3 * (   zdit(ji  ,jj  ,jk-1) + zdit(ji-1,jj  ,jk)      &
271                     &                        + zdit(ji-1,jj  ,jk-1) + zdit(ji  ,jj  ,jk)  )   &
272                     &           + zcoef4 * (   zdjt(ji  ,jj  ,jk-1) + zdjt(ji  ,jj-1,jk)      &
273                     &                        + zdjt(ji  ,jj-1,jk-1) + zdjt(ji  ,jj  ,jk)  )
274               END DO
[457]275            END DO
276         END DO
[2528]277         
278         
279         ! I.5 Divergence of vertical fluxes added to the general tracer trend
280         ! -------------------------------------------------------------------
281         DO jk = 1, jpkm1
282            DO jj = 2, jpjm1
283               DO ji = fs_2, fs_jpim1   ! vector opt.
284                  zbtr = 1.0 / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
285                  ztra = (  ztfw(ji,jj,jk) - ztfw(ji,jj,jk+1)  ) * zbtr
286                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
287               END DO
[457]288            END DO
289         END DO
[2528]290         !
[457]291      END DO
[503]292      !
[2690]293      IF( wrk_not_released(3, 1,2,3) .OR.   &
294          wrk_not_released(2, 1,2,3) )   CALL ctl_stop('tra_ldf_iso: failed to release workspace arrays')
[2590]295      !
[3]296   END SUBROUTINE tra_ldf_iso
297
298#else
299   !!----------------------------------------------------------------------
[457]300   !!   default option :   Dummy code   NO rotation of the diffusive tensor
[3]301   !!----------------------------------------------------------------------
302CONTAINS
[2528]303   SUBROUTINE tra_ldf_iso( kt, cdtype, pgu, pgv, ptb, pta, kjpt, pahtb0 )      ! Empty routine
304      CHARACTER(len=3) ::   cdtype
305      REAL, DIMENSION(:,:,:) ::   pgu, pgv   ! tracer gradient at pstep levels
306      REAL, DIMENSION(:,:,:,:) ::   ptb, pta
307      WRITE(*,*) 'tra_ldf_iso: You should not have seen this print! error?', kt, cdtype, pgu(1,1,1), pgv(1,1,1),   &
308         &                                                             ptb(1,1,1,1), pta(1,1,1,1), kjpt, pahtb0
[3]309   END SUBROUTINE tra_ldf_iso
310#endif
311
312   !!==============================================================================
313END MODULE traldf_iso
Note: See TracBrowser for help on using the repository browser.