New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_iso_grif.F90 in branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/TRA/traldf_iso_grif.F90 @ 2690

Last change on this file since 2690 was 2690, checked in by gm, 13 years ago

dynamic mem: #785 ; homogeneization of the coding style associated with dyn allocation
  • Property svn:keywords set to Id
File size: 18.5 KB
Line 
1MODULE traldf_iso_grif
2   !!======================================================================
3   !!                   ***  MODULE  traldf_iso_grif  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!======================================================================
6   !! History : 3.3  ! 2010-10  (G. Nurser, C. Harris, G. Madec) 
7   !!                !          Griffies operator version adapted from traldf_iso.F90
8   !!----------------------------------------------------------------------
9#if   defined key_ldfslp   ||   defined key_esopa
10   !!----------------------------------------------------------------------
11   !!   'key_ldfslp'               slope of the lateral diffusive direction
12   !!----------------------------------------------------------------------
13   !!   tra_ldf_iso_grif  : update the tracer trend with the horizontal component 
14   !!                       of the Griffies iso-neutral laplacian operator
15   !!----------------------------------------------------------------------
16   USE oce             ! ocean dynamics and active tracers
17   USE dom_oce         ! ocean space and time domain
18   USE phycst          ! physical constants
19   USE trc_oce         ! share passive tracers/Ocean variables
20   USE zdf_oce         ! ocean vertical physics
21   USE ldftra_oce      ! ocean active tracers: lateral physics
22   USE ldfslp          ! iso-neutral slopes
23   USE diaptr          ! poleward transport diagnostics
24   USE in_out_manager  ! I/O manager
25   USE iom             ! I/O library
26   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
27   USE lib_mpp         ! MPP library
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   tra_ldf_iso_grif   ! routine called by traldf.F90
33
34   REAL(wp), PUBLIC, DIMENSION(:,:,:), ALLOCATABLE, SAVE ::   psix_eiv, psiy_eiv   !: eiv stream function (diag only)
35   REAL(wp), PUBLIC, DIMENSION(:,:,:), ALLOCATABLE, SAVE ::   ah_wslp2             !: aeiv*w-slope^2
36   REAL(wp),         DIMENSION(:,:,:), ALLOCATABLE, SAVE ::   zdkt                 !  atypic workspace
37
38   !! * Substitutions
39#  include "domzgr_substitute.h90"
40#  include "ldftra_substitute.h90"
41#  include "vectopt_loop_substitute.h90"
42#  include "ldfeiv_substitute.h90"
43   !!----------------------------------------------------------------------
44   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
45   !! $Id$
46   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
47   !!----------------------------------------------------------------------
48CONTAINS
49
50  SUBROUTINE tra_ldf_iso_grif( kt, cdtype, pgu, pgv,              &
51       &                                   ptb, pta, kjpt, pahtb0 )
52      !!----------------------------------------------------------------------
53      !!                  ***  ROUTINE tra_ldf_iso_grif  ***
54      !!
55      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
56      !!      trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and
57      !!      add it to the general trend of tracer equation.
58      !!
59      !! ** Method  :   The horizontal component of the lateral diffusive trends
60      !!      is provided by a 2nd order operator rotated along neural or geopo-
61      !!      tential surfaces to which an eddy induced advection can be added
62      !!      It is computed using before fields (forward in time) and isopyc-
63      !!      nal or geopotential slopes computed in routine ldfslp.
64      !!
65      !!      1st part :  masked horizontal derivative of T  ( di[ t ] )
66      !!      ========    with partial cell update if ln_zps=T.
67      !!
68      !!      2nd part :  horizontal fluxes of the lateral mixing operator
69      !!      ========   
70      !!         zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ]
71      !!               - aht       e2u*uslp    dk[ mi(mk(tb)) ]
72      !!         zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ]
73      !!               - aht       e2u*vslp    dk[ mj(mk(tb)) ]
74      !!      take the horizontal divergence of the fluxes:
75      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
76      !!      Add this trend to the general trend (ta,sa):
77      !!         ta = ta + difft
78      !!
79      !!      3rd part: vertical trends of the lateral mixing operator
80      !!      ========  (excluding the vertical flux proportional to dk[t] )
81      !!      vertical fluxes associated with the rotated lateral mixing:
82      !!         zftw =-aht {  e2t*wslpi di[ mi(mk(tb)) ]
83      !!                     + e1t*wslpj dj[ mj(mk(tb)) ]  }
84      !!      take the horizontal divergence of the fluxes:
85      !!         difft = 1/(e1t*e2t*e3t) dk[ zftw ]
86      !!      Add this trend to the general trend (ta,sa):
87      !!         pta = pta + difft
88      !!
89      !! ** Action :   Update pta arrays with the before rotated diffusion
90      !!----------------------------------------------------------------------
91      USE wrk_nemo, ONLY:   wrk_in_use, wrk_not_released
92      USE oce     , ONLY:   zftu => ua       , zftv => va            ! (ua,va) used as 3D workspace
93      USE wrk_nemo, ONLY:   zdit => wrk_3d_1 , zdjt => wrk_3d_2 , ztfw => wrk_3d_3   ! 3D workspace
94      USE wrk_nemo, ONLY:   z2d  => wrk_2d_1                                         ! 2D workspace
95      !
96      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
97      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
98      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
99      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
100      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! before and now tracer fields
101      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
102      REAL(wp)                             , INTENT(in   ) ::   pahtb0     ! background diffusion coef
103      !
104      INTEGER  ::  ji, jj, jk,jn   ! dummy loop indices
105      INTEGER  ::  ip,jp,kp        ! dummy loop indices
106      INTEGER  ::  ierr            ! temporary integer
107      REAL(wp) ::  zmsku, zabe1, zcof1, zcoef3   ! local scalars
108      REAL(wp) ::  zmskv, zabe2, zcof2, zcoef4   !   -      -
109      REAL(wp) ::  zcoef0, zbtr                  !   -      -
110      !REAL(wp), POINTER, DIMENSION(:,:,:) ::   zdkt           ! 2D+1 workspace
111      !
112      REAL(wp) ::   zslope_skew, zslope_iso, zslope2, zbu, zbv
113      REAL(wp) ::   ze1ur, zdxt, ze2vr, ze3wr, zdyt, zdzt
114      REAL(wp) ::   zah, zah_slp, zaei_slp
115#if defined key_diaar5
116      REAL(wp) ::   zztmp              ! local scalar
117#endif
118      !!----------------------------------------------------------------------
119
120      IF( wrk_in_use(3, 1,2,3) .OR. wrk_in_use(2, 1) ) THEN
121         CALL ctl_stop('tra_ldf_iso_grif: requested workspace arrays unavailable.')   ;   RETURN
122      ENDIF
123      ! ARP - line below uses 'bounds re-mapping' which is only defined in
124      ! Fortran 2003 and up. We would be OK if code was written to use
125      ! zdkt(:,:,1:2) instead as then wouldn't need to re-map bounds.
126      ! As it is, we make zdkt a module array and allocate it in _alloc().
127      !zdkt(1:jpi,1:jpj,0:1) => wrk_3d_4(:,:,1:2)
128
129      IF( kt == nit000 )  THEN
130         IF(lwp) WRITE(numout,*)
131         IF(lwp) WRITE(numout,*) 'tra_ldf_iso_grif : rotated laplacian diffusion operator on ', cdtype
132         IF(lwp) WRITE(numout,*) '                   WARNING: STILL UNDER TEST, NOT RECOMMENDED. USE AT YOUR OWN PERIL'
133         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
134         ALLOCATE( ah_wslp2(jpi,jpj,jpk) , zdkt(jpi,jpj,0:1), STAT=ierr )
135         IF( lk_mpp   )   CALL mpp_sum ( ierr )
136         IF( ierr > 0 )   CALL ctl_stop('STOP', 'tra_ldf_iso_grif: unable to allocate arrays')
137         IF( ln_traldf_gdia ) THEN
138            ALLOCATE( psix_eiv(jpi,jpj,jpk) , psiy_eiv(jpi,jpj,jpk) , STAT=ierr )
139            IF( lk_mpp   )   CALL mpp_sum ( ierr )
140            IF( ierr > 0 )   CALL ctl_stop('STOP', 'tra_ldf_iso_grif: unable to allocate diagnostics')
141         ENDIF
142      ENDIF
143
144      !!----------------------------------------------------------------------
145      !!   0 - calculate  ah_wslp2, psix_eiv, psiy_eiv
146      !!----------------------------------------------------------------------
147
148!!gm Future development: consider using Ah defined at T-points and attached to the 4 t-point triads
149
150      ah_wslp2(:,:,:) = 0._wp
151      IF( ln_traldf_gdia ) THEN
152         psix_eiv(:,:,:) = 0._wp
153         psiy_eiv(:,:,:) = 0._wp
154      ENDIF
155
156      DO ip = 0, 1
157         DO kp = 0, 1
158            DO jk = 1, jpkm1
159               DO jj = 1, jpjm1
160                  DO ji = 1, fs_jpim1
161                     ze3wr = 1._wp / fse3w(ji+ip,jj,jk+kp)
162                     zbu   = 0.25_wp * e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk)
163                     zah   = fsahtu(ji,jj,jk)                                  !  fsaht(ji+ip,jj,jk)
164                     zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp)
165                     zslope2 = zslope_skew - ( fsdept(ji+1,jj,jk) - fsdept(ji ,jj ,jk) ) * ze1ur * umask(ji,jj,jk+kp)
166                     zslope2 = zslope2 *zslope2
167                     ah_wslp2(ji+ip,jj,jk+kp) = ah_wslp2(ji+ip,jj,jk+kp)    &
168                        &                     + zah * ( zbu * ze3wr / ( e1t(ji+ip,jj) * e2t(ji+ip,jj) ) ) * zslope2
169                     IF( ln_traldf_gdia ) THEN
170                        zaei_slp = fsaeiw(ji+ip,jj,jk) * zslope_skew        !fsaeit(ji+ip,jj,jk)*zslope_skew
171                        psix_eiv(ji,jj,jk+kp) = psix_eiv(ji,jj,jk+kp) + 0.25_wp * zaei_slp
172                     ENDIF
173                  END DO
174               END DO
175            END DO
176         END DO
177      END DO
178      !
179      DO jp = 0, 1
180         DO kp = 0, 1
181            DO jk = 1, jpkm1
182               DO jj = 1, jpjm1
183                  DO ji=1,fs_jpim1
184                     ze3wr = 1.0_wp / fse3w(ji,jj+jp,jk+kp)
185                     zbv   = 0.25_wp * e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk)
186                     zah   = fsahtu(ji,jj,jk)                                       !fsaht(ji,jj+jp,jk)
187                     zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp)
188                     zslope2 = zslope_skew - ( fsdept(ji,jj+1,jk) - fsdept(ji,jj,jk) ) * ze2vr * vmask(ji,jj,jk+kp)
189                     zslope2 = zslope2 * zslope2
190                     ah_wslp2(ji,jj+jp,jk+kp) = ah_wslp2(ji,jj+jp,jk+kp)   &
191                        &                     + zah * ( zbv * ze3wr / ( e1t(ji,jj+jp) * e2t(ji,jj+jp) ) ) * zslope2
192                     IF( ln_traldf_gdia ) THEN
193                        zaei_slp = fsaeiw(ji,jj+jp,jk) * zslope_skew     !fsaeit(ji,jj+jp,jk)*zslope_skew
194                        psiy_eiv(ji,jj,jk+kp) = psiy_eiv(ji,jj,jk+kp) + 0.25_wp * zaei_slp
195                     ENDIF
196                  END DO
197               END DO
198            END DO
199         END DO
200      END DO
201      !
202      !                                                          ! ===========
203      DO jn = 1, kjpt                                            ! tracer loop
204         !                                                       ! ===========
205         ! Zero fluxes for each tracer
206         ztfw(:,:,:) = 0._wp
207         zftu(:,:,:) = 0._wp
208         zftv(:,:,:) = 0._wp
209         !                                               
210         DO jk = 1, jpkm1                          !==  before lateral T & S gradients at T-level jk  ==!
211            DO jj = 1, jpjm1
212               DO ji = 1, fs_jpim1   ! vector opt.
213                  zdit(ji,jj,jk) = ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) ) * umask(ji,jj,jk)
214                  zdjt(ji,jj,jk) = ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
215               END DO
216            END DO
217         END DO
218         IF( ln_zps ) THEN                               ! partial steps: correction at the last level
219# if defined key_vectopt_loop
220            DO jj = 1, 1
221               DO ji = 1, jpij-jpi   ! vector opt. (forced unrolling)
222# else
223            DO jj = 1, jpjm1
224               DO ji = 1, jpim1
225# endif
226                  zdit(ji,jj,mbku(ji,jj)) = pgu(ji,jj,jn)         
227                  zdjt(ji,jj,mbkv(ji,jj)) = pgv(ji,jj,jn)     
228               END DO
229            END DO
230         ENDIF
231
232         !!----------------------------------------------------------------------
233         !!   II - horizontal trend  (full)
234         !!----------------------------------------------------------------------
235         !
236         DO jk = 1, jpkm1
237            !
238            !                    !==  Vertical tracer gradient at level jk and jk+1
239            zdkt(:,:,1) = ( ptb(:,:,jk,jn) - ptb(:,:,jk+1,jn) ) * tmask(:,:,jk+1)
240            !
241            !                          ! surface boundary condition: zdkt(jk=1)=zdkt(jk=2)
242            IF( jk == 1 ) THEN   ;   zdkt(:,:,0) = zdkt(:,:,1)
243            ELSE                 ;   zdkt(:,:,0) = ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) ) * tmask(:,:,jk)
244            ENDIF
245
246            IF( .NOT. l_triad_iso ) THEN
247               triadi = triadi_g
248               triadj = triadj_g
249            ENDIF
250
251            DO ip = 0, 1              !==  Horizontal & vertical fluxes
252               DO kp = 0, 1
253                  DO jj = 1, jpjm1
254                     DO ji = 1, fs_jpim1
255                        ze1ur = 1._wp / e1u(ji,jj)
256                        zdxt = zdit(ji,jj,jk) * ze1ur
257                        ze3wr = 1._wp / fse3w(ji+ip,jj,jk+kp)
258                        zdzt  = zdkt(ji+ip,jj,kp) * ze3wr
259                        zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp)
260                        zslope_iso  = triadi(ji+ip,jj,jk,1-ip,kp)
261
262                        zbu = 0.25_wp * e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk)
263                        zah = fsahtu(ji,jj,jk)   !*umask(ji,jj,jk+kp)         !fsaht(ji+ip,jj,jk)           ===>>  ????
264                        zah_slp  = zah * zslope_iso
265                        zaei_slp = fsaeiw(ji+ip,jj,jk) * zslope_skew    !fsaeit(ji+ip,jj,jk)*zslope_skew
266                        zftu(ji,jj,jk) = zftu(ji,jj,jk) - ( zah * zdxt + (zah_slp - zaei_slp) * zdzt ) * zbu * ze1ur
267                        ztfw(ji+ip,jj,jk+kp) = ztfw(ji+ip,jj,jk+kp) - (zah_slp + zaei_slp) * zdxt * zbu * ze3wr
268                     END DO
269                  END DO
270               END DO
271            END DO
272
273            DO jp = 0, 1
274               DO kp = 0, 1
275                  DO jj = 1, jpjm1
276                     DO ji = 1, fs_jpim1
277                        ze2vr = 1._wp / e2v(ji,jj)
278                        zdyt = zdjt(ji,jj,jk) * ze2vr
279                        ze3wr = 1._wp / fse3w(ji,jj+jp,jk+kp)
280                        zdzt = zdkt(ji,jj+jp,kp) * ze3wr
281                        zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp)
282                        zslope_iso  = triadj(ji,jj+jp,jk,1-jp,kp)
283                        zbv = 0.25_wp * e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk)
284                        zah = fsahtv(ji,jj,jk)        !*vmask(ji,jj,jk+kp)         !fsaht(ji,jj+jp,jk)
285                        zah_slp = zah * zslope_iso
286                        zaei_slp = fsaeiw(ji,jj+jp,jk) * zslope_skew    !fsaeit(ji,jj+jp,jk)*zslope_skew
287                        zftv(ji,jj,jk) = zftv(ji,jj,jk) - ( zah * zdyt + (zah_slp - zaei_slp) * zdzt ) * zbv * ze2vr
288                        ztfw(ji,jj+jp,jk+kp) = ztfw(ji,jj+jp,jk+kp) - (zah_slp + zaei_slp) * zdyt * zbv * ze3wr
289                     END DO
290                  END DO
291               END DO
292            END DO
293
294            !                        !==  divergence and add to the general trend  ==!
295            DO jj = 2 , jpjm1
296               DO ji = fs_2, fs_jpim1   ! vector opt.
297                  zbtr = 1._wp / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
298                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + zbtr * (   zftu(ji-1,jj,jk) - zftu(ji,jj,jk)   &
299                     &                                           + zftv(ji,jj-1,jk) - zftv(ji,jj,jk)   )
300               END DO
301            END DO
302            !
303         END DO
304         !
305         DO jk = 1, jpkm1            !== Divergence of vertical fluxes added to the general tracer trend
306            DO jj = 2, jpjm1
307               DO ji = fs_2, fs_jpim1   ! vector opt.
308                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + (  ztfw(ji,jj,jk+1) - ztfw(ji,jj,jk)  )   &
309                     &                                / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
310               END DO
311            END DO
312         END DO
313         !
314         !                            ! "Poleward" diffusive heat or salt transports (T-S case only)
315         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN
316            IF( jn == jp_tem)   htr_ldf(:) = ptr_vj( zftv(:,:,:) )        ! 3.3  names
317            IF( jn == jp_sal)   str_ldf(:) = ptr_vj( zftv(:,:,:) )
318         ENDIF
319
320#if defined key_diaar5
321         IF( cdtype == 'TRA' .AND. jn == jp_tem  ) THEN
322            z2d(:,:) = 0._wp 
323            zztmp = rau0 * rcp 
324            DO jk = 1, jpkm1
325               DO jj = 2, jpjm1
326                  DO ji = fs_2, fs_jpim1   ! vector opt.
327                     z2d(ji,jj) = z2d(ji,jj) + zftu(ji,jj,jk) 
328                  END DO
329               END DO
330            END DO
331            z2d(:,:) = zztmp * z2d(:,:)
332            CALL lbc_lnk( z2d, 'U', -1. )
333            CALL iom_put( "udiff_heattr", z2d )                  ! heat transport in i-direction
334            z2d(:,:) = 0._wp 
335            DO jk = 1, jpkm1
336               DO jj = 2, jpjm1
337                  DO ji = fs_2, fs_jpim1   ! vector opt.
338                     z2d(ji,jj) = z2d(ji,jj) + zftv(ji,jj,jk) 
339                  END DO
340               END DO
341            END DO
342            z2d(:,:) = zztmp * z2d(:,:)
343            CALL lbc_lnk( z2d, 'V', -1. )
344            CALL iom_put( "vdiff_heattr", z2d )                  !  heat transport in i-direction
345         END IF
346#endif
347         !
348      END DO
349      !
350      IF( wrk_not_released(3, 1,2,3,4) .OR.   &
351          wrk_not_released(2, 1)       )   CALL ctl_stop('tra_ldf_iso_grif: failed to release workspace arrays')
352      !
353  END SUBROUTINE tra_ldf_iso_grif
354
355#else
356   !!----------------------------------------------------------------------
357   !!   default option :   Dummy code   NO rotation of the diffusive tensor
358   !!----------------------------------------------------------------------
359CONTAINS
360   SUBROUTINE tra_ldf_iso_grif( kt, cdtype, pgu, pgv, ptb, pta, kjpt, pahtb0 )      ! Empty routine
361      CHARACTER(len=3) ::   cdtype
362      REAL, DIMENSION(:,:,:) ::   pgu, pgv   ! tracer gradient at pstep levels
363      REAL, DIMENSION(:,:,:,:) ::   ptb, pta
364      WRITE(*,*) 'tra_ldf_iso_grif: You should not have seen this print! error?', kt, cdtype,    &
365         &                  pgu(1,1,1), pgv(1,1,1), ptb(1,1,1,1), pta(1,1,1,1), kjpt, pahtb0
366   END SUBROUTINE tra_ldf_iso_grif
367#endif
368
369   !!==============================================================================
370END MODULE traldf_iso_grif
Note: See TracBrowser for help on using the repository browser.