| 1 | MODULE traqsr |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE traqsr *** |
|---|
| 4 | !! Ocean physics: solar radiation penetration in the top ocean levels |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : OPA ! 1990-10 (B. Blanke) Original code |
|---|
| 7 | !! 7.0 ! 1991-11 (G. Madec) |
|---|
| 8 | !! ! 1996-01 (G. Madec) s-coordinates |
|---|
| 9 | !! NEMO 1.0 ! 2002-06 (G. Madec) F90: Free form and module |
|---|
| 10 | !! - ! 2005-11 (G. Madec) zco, zps, sco coordinate |
|---|
| 11 | !! 3.2 ! 2009-04 (G. Madec & NEMO team) |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | |
|---|
| 14 | !!---------------------------------------------------------------------- |
|---|
| 15 | !! tra_qsr : trend due to the solar radiation penetration |
|---|
| 16 | !! tra_qsr_init : solar radiation penetration initialization |
|---|
| 17 | !!---------------------------------------------------------------------- |
|---|
| 18 | USE oce ! ocean dynamics and active tracers |
|---|
| 19 | USE dom_oce ! ocean space and time domain |
|---|
| 20 | USE sbc_oce ! surface boundary condition: ocean |
|---|
| 21 | USE trc_oce ! share SMS/Ocean variables |
|---|
| 22 | USE trdmod_oce ! ocean variables trends |
|---|
| 23 | USE trdtra ! ocean active tracers trends |
|---|
| 24 | USE in_out_manager ! I/O manager |
|---|
| 25 | USE phycst ! physical constants |
|---|
| 26 | USE prtctl ! Print control |
|---|
| 27 | USE iom ! I/O manager |
|---|
| 28 | USE fldread ! read input fields |
|---|
| 29 | USE restart ! ocean restart |
|---|
| 30 | USE lib_mpp ! MPP library |
|---|
| 31 | |
|---|
| 32 | IMPLICIT NONE |
|---|
| 33 | PRIVATE |
|---|
| 34 | |
|---|
| 35 | PUBLIC tra_qsr ! routine called by step.F90 (ln_traqsr=T) |
|---|
| 36 | PUBLIC tra_qsr_init ! routine called by opa.F90 |
|---|
| 37 | |
|---|
| 38 | ! !!* Namelist namtra_qsr: penetrative solar radiation |
|---|
| 39 | LOGICAL , PUBLIC :: ln_traqsr = .TRUE. !: light absorption (qsr) flag |
|---|
| 40 | LOGICAL , PUBLIC :: ln_qsr_rgb = .FALSE. !: Red-Green-Blue light absorption flag |
|---|
| 41 | LOGICAL , PUBLIC :: ln_qsr_2bd = .TRUE. !: 2 band light absorption flag |
|---|
| 42 | LOGICAL , PUBLIC :: ln_qsr_bio = .FALSE. !: bio-model light absorption flag |
|---|
| 43 | INTEGER , PUBLIC :: nn_chldta = 0 !: use Chlorophyll data (=1) or not (=0) |
|---|
| 44 | REAL(wp), PUBLIC :: rn_abs = 0.58_wp !: fraction absorbed in the very near surface (RGB & 2 bands) |
|---|
| 45 | REAL(wp), PUBLIC :: rn_si0 = 0.35_wp !: very near surface depth of extinction (RGB & 2 bands) |
|---|
| 46 | REAL(wp), PUBLIC :: rn_si1 = 23.0_wp !: deepest depth of extinction (water type I) (2 bands) |
|---|
| 47 | |
|---|
| 48 | ! Module variables |
|---|
| 49 | REAL(wp) :: xsi0r !: inverse of rn_si0 |
|---|
| 50 | REAL(wp) :: xsi1r !: inverse of rn_si1 |
|---|
| 51 | TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_chl ! structure of input Chl (file informations, fields read) |
|---|
| 52 | INTEGER, PUBLIC :: nksr ! levels below which the light cannot penetrate ( depth larger than 391 m) |
|---|
| 53 | REAL(wp), DIMENSION(3,61) :: rkrgb !: tabulated attenuation coefficients for RGB absorption |
|---|
| 54 | |
|---|
| 55 | !! * Substitutions |
|---|
| 56 | # include "domzgr_substitute.h90" |
|---|
| 57 | # include "vectopt_loop_substitute.h90" |
|---|
| 58 | !!---------------------------------------------------------------------- |
|---|
| 59 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
|---|
| 60 | !! $Id$ |
|---|
| 61 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 62 | !!---------------------------------------------------------------------- |
|---|
| 63 | CONTAINS |
|---|
| 64 | |
|---|
| 65 | SUBROUTINE tra_qsr( kt ) |
|---|
| 66 | !!---------------------------------------------------------------------- |
|---|
| 67 | !! *** ROUTINE tra_qsr *** |
|---|
| 68 | !! |
|---|
| 69 | !! ** Purpose : Compute the temperature trend due to the solar radiation |
|---|
| 70 | !! penetration and add it to the general temperature trend. |
|---|
| 71 | !! |
|---|
| 72 | !! ** Method : The profile of the solar radiation within the ocean is defined |
|---|
| 73 | !! through 2 wavebands (rn_si0,rn_si1) or 3 wavebands (RGB) and a ratio rn_abs |
|---|
| 74 | !! Considering the 2 wavebands case: |
|---|
| 75 | !! I(k) = Qsr*( rn_abs*EXP(z(k)/rn_si0) + (1.-rn_abs)*EXP(z(k)/rn_si1) ) |
|---|
| 76 | !! The temperature trend associated with the solar radiation penetration |
|---|
| 77 | !! is given by : zta = 1/e3t dk[ I ] / (rau0*Cp) |
|---|
| 78 | !! At the bottom, boudary condition for the radiation is no flux : |
|---|
| 79 | !! all heat which has not been absorbed in the above levels is put |
|---|
| 80 | !! in the last ocean level. |
|---|
| 81 | !! In z-coordinate case, the computation is only done down to the |
|---|
| 82 | !! level where I(k) < 1.e-15 W/m2. In addition, the coefficients |
|---|
| 83 | !! used for the computation are calculated one for once as they |
|---|
| 84 | !! depends on k only. |
|---|
| 85 | !! |
|---|
| 86 | !! ** Action : - update ta with the penetrative solar radiation trend |
|---|
| 87 | !! - save the trend in ttrd ('key_trdtra') |
|---|
| 88 | !! |
|---|
| 89 | !! Reference : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp. |
|---|
| 90 | !! Lengaigne et al. 2007, Clim. Dyn., V28, 5, 503-516. |
|---|
| 91 | !!---------------------------------------------------------------------- |
|---|
| 92 | USE wrk_nemo, ONLY: wrk_in_use, wrk_not_released |
|---|
| 93 | USE wrk_nemo, ONLY: zekb => wrk_2d_1 , zekg => wrk_2d_2 , zekr => wrk_2d_3 |
|---|
| 94 | USE wrk_nemo, ONLY: ze0 => wrk_3d_1 , ze1 => wrk_3d_2 , ze2 => wrk_3d_3 |
|---|
| 95 | USE wrk_nemo, ONLY: ze3 => wrk_3d_4 , zea => wrk_3d_5 |
|---|
| 96 | ! |
|---|
| 97 | INTEGER, INTENT(in) :: kt ! ocean time-step |
|---|
| 98 | ! |
|---|
| 99 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 100 | INTEGER :: irgb ! local integers |
|---|
| 101 | REAL(wp) :: zchl, zcoef, zfact ! local scalars |
|---|
| 102 | REAL(wp) :: zc0, zc1, zc2, zc3 ! - - |
|---|
| 103 | REAL(wp) :: zz0, zz1, z1_e3t ! - - |
|---|
| 104 | REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: ztrdt |
|---|
| 105 | !!---------------------------------------------------------------------- |
|---|
| 106 | |
|---|
| 107 | IF( wrk_in_use(3, 1,2,3,4,5) .OR. wrk_in_use(2, 1,2,3) )THEN |
|---|
| 108 | CALL ctl_stop('tra_qsr: requested workspace arrays unavailable') ; RETURN |
|---|
| 109 | ENDIF |
|---|
| 110 | |
|---|
| 111 | IF( kt == nit000 ) THEN |
|---|
| 112 | IF(lwp) WRITE(numout,*) |
|---|
| 113 | IF(lwp) WRITE(numout,*) 'tra_qsr : penetration of the surface solar radiation' |
|---|
| 114 | IF(lwp) WRITE(numout,*) '~~~~~~~' |
|---|
| 115 | IF( .NOT.ln_traqsr ) RETURN |
|---|
| 116 | ENDIF |
|---|
| 117 | |
|---|
| 118 | IF( l_trdtra ) THEN ! Save ta and sa trends |
|---|
| 119 | ALLOCATE( ztrdt(jpi,jpj,jpk) ) ; ztrdt(:,:,:) = tsa(:,:,:,jp_tem) |
|---|
| 120 | ENDIF |
|---|
| 121 | |
|---|
| 122 | ! Set before qsr tracer content field |
|---|
| 123 | ! *********************************** |
|---|
| 124 | IF( kt == nit000 ) THEN ! Set the forcing field at nit000 - 1 |
|---|
| 125 | ! ! ----------------------------------- |
|---|
| 126 | IF( ln_rstart .AND. & ! Restart: read in restart file |
|---|
| 127 | & iom_varid( numror, 'qsr_hc_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 128 | IF(lwp) WRITE(numout,*) ' nit000-1 qsr tracer content forcing field red in the restart file' |
|---|
| 129 | zfact = 0.5e0 |
|---|
| 130 | CALL iom_get( numror, jpdom_autoglo, 'qsr_hc_b', qsr_hc_b ) ! before heat content trend due to Qsr flux |
|---|
| 131 | ELSE ! No restart or restart not found: Euler forward time stepping |
|---|
| 132 | zfact = 1.e0 |
|---|
| 133 | qsr_hc_b(:,:,:) = 0.e0 |
|---|
| 134 | ENDIF |
|---|
| 135 | ELSE ! Swap of forcing field |
|---|
| 136 | ! ! --------------------- |
|---|
| 137 | zfact = 0.5e0 |
|---|
| 138 | qsr_hc_b(:,:,:) = qsr_hc(:,:,:) |
|---|
| 139 | ENDIF |
|---|
| 140 | ! Compute now qsr tracer content field |
|---|
| 141 | ! ************************************ |
|---|
| 142 | |
|---|
| 143 | ! ! ============================================== ! |
|---|
| 144 | IF( lk_qsr_bio .AND. ln_qsr_bio ) THEN ! bio-model fluxes : all vertical coordinates ! |
|---|
| 145 | ! ! ============================================== ! |
|---|
| 146 | DO jk = 1, jpkm1 |
|---|
| 147 | qsr_hc(:,:,jk) = ro0cpr * ( etot3(:,:,jk) - etot3(:,:,jk+1) ) |
|---|
| 148 | END DO |
|---|
| 149 | ! Add to the general trend |
|---|
| 150 | DO jk = 1, jpkm1 |
|---|
| 151 | DO jj = 2, jpjm1 |
|---|
| 152 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 153 | z1_e3t = zfact / fse3t(ji,jj,jk) |
|---|
| 154 | tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t |
|---|
| 155 | END DO |
|---|
| 156 | END DO |
|---|
| 157 | END DO |
|---|
| 158 | CALL iom_put( 'qsr3d', etot3 ) ! Shortwave Radiation 3D distribution |
|---|
| 159 | ! ! ============================================== ! |
|---|
| 160 | ELSE ! Ocean alone : |
|---|
| 161 | ! ! ============================================== ! |
|---|
| 162 | ! |
|---|
| 163 | ! ! ------------------------- ! |
|---|
| 164 | IF( ln_qsr_rgb) THEN ! R-G-B light penetration ! |
|---|
| 165 | ! ! ------------------------- ! |
|---|
| 166 | ! Set chlorophyl concentration |
|---|
| 167 | IF( nn_chldta == 1 .OR. lk_vvl ) THEN !* Variable Chlorophyll or ocean volume |
|---|
| 168 | ! |
|---|
| 169 | IF( nn_chldta == 1 ) THEN !* Variable Chlorophyll |
|---|
| 170 | ! |
|---|
| 171 | CALL fld_read( kt, 1, sf_chl ) ! Read Chl data and provides it at the current time step |
|---|
| 172 | ! |
|---|
| 173 | !CDIR COLLAPSE |
|---|
| 174 | !CDIR NOVERRCHK |
|---|
| 175 | DO jj = 1, jpj ! Separation in R-G-B depending of the surface Chl |
|---|
| 176 | !CDIR NOVERRCHK |
|---|
| 177 | DO ji = 1, jpi |
|---|
| 178 | zchl = MIN( 10. , MAX( 0.03, sf_chl(1)%fnow(ji,jj,1) ) ) |
|---|
| 179 | irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 ) |
|---|
| 180 | zekb(ji,jj) = rkrgb(1,irgb) |
|---|
| 181 | zekg(ji,jj) = rkrgb(2,irgb) |
|---|
| 182 | zekr(ji,jj) = rkrgb(3,irgb) |
|---|
| 183 | END DO |
|---|
| 184 | END DO |
|---|
| 185 | ELSE ! Variable ocean volume but constant chrlorophyll |
|---|
| 186 | zchl = 0.05 ! constant chlorophyll |
|---|
| 187 | irgb = NINT( 41 + 20.*LOG10( zchl ) + 1.e-15 ) |
|---|
| 188 | zekb(:,:) = rkrgb(1,irgb) ! Separation in R-G-B depending of the chlorophyll |
|---|
| 189 | zekg(:,:) = rkrgb(2,irgb) |
|---|
| 190 | zekr(:,:) = rkrgb(3,irgb) |
|---|
| 191 | ENDIF |
|---|
| 192 | ! |
|---|
| 193 | zcoef = ( 1. - rn_abs ) / 3.e0 ! equi-partition in R-G-B |
|---|
| 194 | ze0(:,:,1) = rn_abs * qsr(:,:) |
|---|
| 195 | ze1(:,:,1) = zcoef * qsr(:,:) |
|---|
| 196 | ze2(:,:,1) = zcoef * qsr(:,:) |
|---|
| 197 | ze3(:,:,1) = zcoef * qsr(:,:) |
|---|
| 198 | zea(:,:,1) = qsr(:,:) |
|---|
| 199 | ! |
|---|
| 200 | DO jk = 2, nksr+1 |
|---|
| 201 | !CDIR NOVERRCHK |
|---|
| 202 | DO jj = 1, jpj |
|---|
| 203 | !CDIR NOVERRCHK |
|---|
| 204 | DO ji = 1, jpi |
|---|
| 205 | zc0 = ze0(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * xsi0r ) |
|---|
| 206 | zc1 = ze1(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekb(ji,jj) ) |
|---|
| 207 | zc2 = ze2(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekg(ji,jj) ) |
|---|
| 208 | zc3 = ze3(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekr(ji,jj) ) |
|---|
| 209 | ze0(ji,jj,jk) = zc0 |
|---|
| 210 | ze1(ji,jj,jk) = zc1 |
|---|
| 211 | ze2(ji,jj,jk) = zc2 |
|---|
| 212 | ze3(ji,jj,jk) = zc3 |
|---|
| 213 | zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk) |
|---|
| 214 | END DO |
|---|
| 215 | END DO |
|---|
| 216 | END DO |
|---|
| 217 | ! |
|---|
| 218 | DO jk = 1, nksr ! compute and add qsr trend to ta |
|---|
| 219 | qsr_hc(:,:,jk) = ro0cpr * ( zea(:,:,jk) - zea(:,:,jk+1) ) |
|---|
| 220 | END DO |
|---|
| 221 | zea(:,:,nksr+1:jpk) = 0.e0 ! below 400m set to zero |
|---|
| 222 | CALL iom_put( 'qsr3d', zea ) ! Shortwave Radiation 3D distribution |
|---|
| 223 | ! |
|---|
| 224 | ELSE !* Constant Chlorophyll |
|---|
| 225 | DO jk = 1, nksr |
|---|
| 226 | qsr_hc(:,:,jk) = etot3(:,:,jk) * qsr(:,:) |
|---|
| 227 | END DO |
|---|
| 228 | ENDIF |
|---|
| 229 | |
|---|
| 230 | ENDIF |
|---|
| 231 | ! ! ------------------------- ! |
|---|
| 232 | IF( ln_qsr_2bd ) THEN ! 2 band light penetration ! |
|---|
| 233 | ! ! ------------------------- ! |
|---|
| 234 | ! |
|---|
| 235 | IF( lk_vvl ) THEN !* variable volume |
|---|
| 236 | zz0 = rn_abs * ro0cpr |
|---|
| 237 | zz1 = ( 1. - rn_abs ) * ro0cpr |
|---|
| 238 | DO jk = 1, nksr ! solar heat absorbed at T-point in the top 400m |
|---|
| 239 | DO jj = 2, jpjm1 |
|---|
| 240 | DO ji = 2, jpim1 |
|---|
| 241 | zc0 = zz0 * EXP( -fsdepw(ji,jj,jk )*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk )*xsi1r ) |
|---|
| 242 | zc1 = zz0 * EXP( -fsdepw(ji,jj,jk+1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk+1)*xsi1r ) |
|---|
| 243 | qsr_hc(ji,jj,jk) = qsr(ji,jj) * ( zc0*tmask(ji,jj,jk) - zc1*tmask(ji,jj,jk+1) ) |
|---|
| 244 | END DO |
|---|
| 245 | END DO |
|---|
| 246 | END DO |
|---|
| 247 | ELSE !* constant volume: coef. computed one for all |
|---|
| 248 | DO jk = 1, nksr |
|---|
| 249 | DO jj = 2, jpjm1 |
|---|
| 250 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 251 | qsr_hc(ji,jj,jk) = etot3(ji,jj,jk) * qsr(ji,jj) |
|---|
| 252 | END DO |
|---|
| 253 | END DO |
|---|
| 254 | END DO |
|---|
| 255 | ! |
|---|
| 256 | ENDIF |
|---|
| 257 | ! |
|---|
| 258 | ENDIF |
|---|
| 259 | ! |
|---|
| 260 | ! Add to the general trend |
|---|
| 261 | DO jk = 1, nksr |
|---|
| 262 | DO jj = 2, jpjm1 |
|---|
| 263 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 264 | z1_e3t = zfact / fse3t(ji,jj,jk) |
|---|
| 265 | tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t |
|---|
| 266 | END DO |
|---|
| 267 | END DO |
|---|
| 268 | END DO |
|---|
| 269 | ! |
|---|
| 270 | ENDIF |
|---|
| 271 | ! |
|---|
| 272 | IF( lrst_oce ) THEN ! Write in the ocean restart file |
|---|
| 273 | ! ******************************* |
|---|
| 274 | IF(lwp) WRITE(numout,*) |
|---|
| 275 | IF(lwp) WRITE(numout,*) 'qsr tracer content forcing field written in ocean restart file ', & |
|---|
| 276 | & 'at it= ', kt,' date= ', ndastp |
|---|
| 277 | IF(lwp) WRITE(numout,*) '~~~~' |
|---|
| 278 | CALL iom_rstput( kt, nitrst, numrow, 'qsr_hc_b', qsr_hc ) |
|---|
| 279 | ! |
|---|
| 280 | ENDIF |
|---|
| 281 | |
|---|
| 282 | IF( l_trdtra ) THEN ! qsr tracers trends saved for diagnostics |
|---|
| 283 | ztrdt(:,:,:) = tsa(:,:,:,jp_tem) - ztrdt(:,:,:) |
|---|
| 284 | CALL trd_tra( kt, 'TRA', jp_tem, jptra_trd_qsr, ztrdt ) |
|---|
| 285 | DEALLOCATE( ztrdt ) |
|---|
| 286 | ENDIF |
|---|
| 287 | ! ! print mean trends (used for debugging) |
|---|
| 288 | IF(ln_ctl) CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' qsr - Ta: ', mask1=tmask, clinfo3='tra-ta' ) |
|---|
| 289 | ! |
|---|
| 290 | IF( wrk_not_released(3, 1,2,3,4,5) .OR. & |
|---|
| 291 | wrk_not_released(2, 1,2,3) ) CALL ctl_stop('tra_qsr: failed to release workspace arrays') |
|---|
| 292 | ! |
|---|
| 293 | END SUBROUTINE tra_qsr |
|---|
| 294 | |
|---|
| 295 | |
|---|
| 296 | SUBROUTINE tra_qsr_init |
|---|
| 297 | !!---------------------------------------------------------------------- |
|---|
| 298 | !! *** ROUTINE tra_qsr_init *** |
|---|
| 299 | !! |
|---|
| 300 | !! ** Purpose : Initialization for the penetrative solar radiation |
|---|
| 301 | !! |
|---|
| 302 | !! ** Method : The profile of solar radiation within the ocean is set |
|---|
| 303 | !! from two length scale of penetration (rn_si0,rn_si1) and a ratio |
|---|
| 304 | !! (rn_abs). These parameters are read in the namtra_qsr namelist. The |
|---|
| 305 | !! default values correspond to clear water (type I in Jerlov' |
|---|
| 306 | !! (1968) classification. |
|---|
| 307 | !! called by tra_qsr at the first timestep (nit000) |
|---|
| 308 | !! |
|---|
| 309 | !! ** Action : - initialize rn_si0, rn_si1 and rn_abs |
|---|
| 310 | !! |
|---|
| 311 | !! Reference : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp. |
|---|
| 312 | !!---------------------------------------------------------------------- |
|---|
| 313 | USE wrk_nemo, ONLY: wrk_in_use, wrk_not_released |
|---|
| 314 | USE wrk_nemo, ONLY: zekb => wrk_2d_1 , zekg => wrk_2d_2 , zekr => wrk_2d_3 |
|---|
| 315 | USE wrk_nemo, ONLY: ze0 => wrk_3d_1 , ze1 => wrk_3d_2 , ze2 => wrk_3d_3 |
|---|
| 316 | USE wrk_nemo, ONLY: ze3 => wrk_3d_4 , zea => wrk_3d_5 |
|---|
| 317 | ! |
|---|
| 318 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 319 | INTEGER :: irgb, ierror, ioptio, nqsr ! local integer |
|---|
| 320 | REAL(wp) :: zz0, zc0 , zc1, zcoef ! local scalars |
|---|
| 321 | REAL(wp) :: zz1, zc2 , zc3, zchl ! - - |
|---|
| 322 | ! |
|---|
| 323 | CHARACTER(len=100) :: cn_dir ! Root directory for location of ssr files |
|---|
| 324 | TYPE(FLD_N) :: sn_chl ! informations about the chlorofyl field to be read |
|---|
| 325 | !! |
|---|
| 326 | NAMELIST/namtra_qsr/ sn_chl, cn_dir, ln_traqsr, ln_qsr_rgb, ln_qsr_2bd, ln_qsr_bio, & |
|---|
| 327 | & nn_chldta, rn_abs, rn_si0, rn_si1 |
|---|
| 328 | !!---------------------------------------------------------------------- |
|---|
| 329 | |
|---|
| 330 | IF( wrk_in_use(2, 1,2,3) .OR. wrk_in_use(3, 1,2,3,4,5) )THEN |
|---|
| 331 | CALL ctl_stop('tra_qsr_init: requested workspace arrays unavailable') ; RETURN |
|---|
| 332 | ENDIF |
|---|
| 333 | |
|---|
| 334 | cn_dir = './' ! directory in which the model is executed |
|---|
| 335 | ! ... default values (NB: frequency positive => hours, negative => months) |
|---|
| 336 | ! ! file ! frequency ! variable ! time interp ! clim ! 'yearly' or ! weights ! rotation ! |
|---|
| 337 | ! ! name ! (hours) ! name ! (T/F) ! (T/F) ! 'monthly' ! filename ! pairs ! |
|---|
| 338 | sn_chl = FLD_N( 'chlorophyll' , -1 , 'CHLA' , .true. , .true. , 'yearly' , '' , '' ) |
|---|
| 339 | ! |
|---|
| 340 | REWIND( numnam ) ! Read Namelist namtra_qsr : ratio and length of penetration |
|---|
| 341 | READ ( numnam, namtra_qsr ) |
|---|
| 342 | ! |
|---|
| 343 | IF(lwp) THEN ! control print |
|---|
| 344 | WRITE(numout,*) |
|---|
| 345 | WRITE(numout,*) 'tra_qsr_init : penetration of the surface solar radiation' |
|---|
| 346 | WRITE(numout,*) '~~~~~~~~~~~~' |
|---|
| 347 | WRITE(numout,*) ' Namelist namtra_qsr : set the parameter of penetration' |
|---|
| 348 | WRITE(numout,*) ' Light penetration (T) or not (F) ln_traqsr = ', ln_traqsr |
|---|
| 349 | WRITE(numout,*) ' RGB (Red-Green-Blue) light penetration ln_qsr_rgb = ', ln_qsr_rgb |
|---|
| 350 | WRITE(numout,*) ' 2 band light penetration ln_qsr_2bd = ', ln_qsr_2bd |
|---|
| 351 | WRITE(numout,*) ' bio-model light penetration ln_qsr_bio = ', ln_qsr_bio |
|---|
| 352 | WRITE(numout,*) ' RGB : Chl data (=1) or cst value (=0) nn_chldta = ', nn_chldta |
|---|
| 353 | WRITE(numout,*) ' RGB & 2 bands: fraction of light (rn_si1) rn_abs = ', rn_abs |
|---|
| 354 | WRITE(numout,*) ' RGB & 2 bands: shortess depth of extinction rn_si0 = ', rn_si0 |
|---|
| 355 | WRITE(numout,*) ' 2 bands: longest depth of extinction rn_si1 = ', rn_si1 |
|---|
| 356 | ENDIF |
|---|
| 357 | |
|---|
| 358 | IF( ln_traqsr ) THEN ! control consistency |
|---|
| 359 | ! |
|---|
| 360 | IF( .NOT.lk_qsr_bio .AND. ln_qsr_bio ) THEN |
|---|
| 361 | CALL ctl_warn( 'No bio model : force ln_qsr_bio = FALSE ' ) |
|---|
| 362 | ln_qsr_bio = .FALSE. |
|---|
| 363 | ENDIF |
|---|
| 364 | ! |
|---|
| 365 | ioptio = 0 ! Parameter control |
|---|
| 366 | IF( ln_qsr_rgb ) ioptio = ioptio + 1 |
|---|
| 367 | IF( ln_qsr_2bd ) ioptio = ioptio + 1 |
|---|
| 368 | IF( ln_qsr_bio ) ioptio = ioptio + 1 |
|---|
| 369 | ! |
|---|
| 370 | IF( ioptio /= 1 ) & |
|---|
| 371 | CALL ctl_stop( ' Choose ONE type of light penetration in namelist namtra_qsr', & |
|---|
| 372 | & ' 2 bands, 3 RGB bands or bio-model light penetration' ) |
|---|
| 373 | ! |
|---|
| 374 | IF( ln_qsr_rgb .AND. nn_chldta == 0 ) nqsr = 1 |
|---|
| 375 | IF( ln_qsr_rgb .AND. nn_chldta == 1 ) nqsr = 2 |
|---|
| 376 | IF( ln_qsr_2bd ) nqsr = 3 |
|---|
| 377 | IF( ln_qsr_bio ) nqsr = 4 |
|---|
| 378 | ! |
|---|
| 379 | IF(lwp) THEN ! Print the choice |
|---|
| 380 | WRITE(numout,*) |
|---|
| 381 | IF( nqsr == 1 ) WRITE(numout,*) ' R-G-B light penetration - Constant Chlorophyll' |
|---|
| 382 | IF( nqsr == 2 ) WRITE(numout,*) ' R-G-B light penetration - Chl data ' |
|---|
| 383 | IF( nqsr == 3 ) WRITE(numout,*) ' 2 bands light penetration' |
|---|
| 384 | IF( nqsr == 4 ) WRITE(numout,*) ' bio-model light penetration' |
|---|
| 385 | ENDIF |
|---|
| 386 | ! |
|---|
| 387 | ENDIF |
|---|
| 388 | ! ! ===================================== ! |
|---|
| 389 | IF( ln_traqsr ) THEN ! Initialisation of Light Penetration ! |
|---|
| 390 | ! ! ===================================== ! |
|---|
| 391 | ! |
|---|
| 392 | xsi0r = 1.e0 / rn_si0 |
|---|
| 393 | xsi1r = 1.e0 / rn_si1 |
|---|
| 394 | ! ! ---------------------------------- ! |
|---|
| 395 | IF( ln_qsr_rgb ) THEN ! Red-Green-Blue light penetration ! |
|---|
| 396 | ! ! ---------------------------------- ! |
|---|
| 397 | ! |
|---|
| 398 | CALL trc_oce_rgb( rkrgb ) !* tabulated attenuation coef. |
|---|
| 399 | ! |
|---|
| 400 | ! !* level of light extinction |
|---|
| 401 | IF( ln_sco ) THEN ; nksr = jpkm1 |
|---|
| 402 | ELSE ; nksr = trc_oce_ext_lev( r_si2, 0.33e2 ) |
|---|
| 403 | ENDIF |
|---|
| 404 | |
|---|
| 405 | IF(lwp) WRITE(numout,*) ' level of light extinction = ', nksr, ' ref depth = ', gdepw_0(nksr+1), ' m' |
|---|
| 406 | ! |
|---|
| 407 | IF( nn_chldta == 1 ) THEN !* Chl data : set sf_chl structure |
|---|
| 408 | IF(lwp) WRITE(numout,*) |
|---|
| 409 | IF(lwp) WRITE(numout,*) ' Chlorophyll read in a file' |
|---|
| 410 | ALLOCATE( sf_chl(1), STAT=ierror ) |
|---|
| 411 | IF( ierror > 0 ) THEN |
|---|
| 412 | CALL ctl_stop( 'tra_qsr_init: unable to allocate sf_chl structure' ) ; RETURN |
|---|
| 413 | ENDIF |
|---|
| 414 | ALLOCATE( sf_chl(1)%fnow(jpi,jpj,1) ) |
|---|
| 415 | IF( sn_chl%ln_tint )ALLOCATE( sf_chl(1)%fdta(jpi,jpj,1,2) ) |
|---|
| 416 | ! ! fill sf_chl with sn_chl and control print |
|---|
| 417 | CALL fld_fill( sf_chl, (/ sn_chl /), cn_dir, 'tra_qsr_init', & |
|---|
| 418 | & 'Solar penetration function of read chlorophyll', 'namtra_qsr' ) |
|---|
| 419 | ! |
|---|
| 420 | ELSE !* constant Chl : compute once for all the distribution of light (etot3) |
|---|
| 421 | IF(lwp) WRITE(numout,*) |
|---|
| 422 | IF(lwp) WRITE(numout,*) ' Constant Chlorophyll concentration = 0.05' |
|---|
| 423 | IF( lk_vvl ) THEN ! variable volume |
|---|
| 424 | IF(lwp) WRITE(numout,*) ' key_vvl: light distribution will be computed at each time step' |
|---|
| 425 | ELSE ! constant volume: computes one for all |
|---|
| 426 | IF(lwp) WRITE(numout,*) ' fixed volume: light distribution computed one for all' |
|---|
| 427 | ! |
|---|
| 428 | zchl = 0.05 ! constant chlorophyll |
|---|
| 429 | irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 ) |
|---|
| 430 | zekb(:,:) = rkrgb(1,irgb) ! Separation in R-G-B depending of the chlorophyll |
|---|
| 431 | zekg(:,:) = rkrgb(2,irgb) |
|---|
| 432 | zekr(:,:) = rkrgb(3,irgb) |
|---|
| 433 | ! |
|---|
| 434 | zcoef = ( 1. - rn_abs ) / 3.e0 ! equi-partition in R-G-B |
|---|
| 435 | ze0(:,:,1) = rn_abs |
|---|
| 436 | ze1(:,:,1) = zcoef |
|---|
| 437 | ze2(:,:,1) = zcoef |
|---|
| 438 | ze3(:,:,1) = zcoef |
|---|
| 439 | zea(:,:,1) = tmask(:,:,1) ! = ( ze0+ze1+z2+ze3 ) * tmask |
|---|
| 440 | |
|---|
| 441 | DO jk = 2, nksr+1 |
|---|
| 442 | !CDIR NOVERRCHK |
|---|
| 443 | DO jj = 1, jpj |
|---|
| 444 | !CDIR NOVERRCHK |
|---|
| 445 | DO ji = 1, jpi |
|---|
| 446 | zc0 = ze0(ji,jj,jk-1) * EXP( - fse3t_0(ji,jj,jk-1) * xsi0r ) |
|---|
| 447 | zc1 = ze1(ji,jj,jk-1) * EXP( - fse3t_0(ji,jj,jk-1) * zekb(ji,jj) ) |
|---|
| 448 | zc2 = ze2(ji,jj,jk-1) * EXP( - fse3t_0(ji,jj,jk-1) * zekg(ji,jj) ) |
|---|
| 449 | zc3 = ze3(ji,jj,jk-1) * EXP( - fse3t_0(ji,jj,jk-1) * zekr(ji,jj) ) |
|---|
| 450 | ze0(ji,jj,jk) = zc0 |
|---|
| 451 | ze1(ji,jj,jk) = zc1 |
|---|
| 452 | ze2(ji,jj,jk) = zc2 |
|---|
| 453 | ze3(ji,jj,jk) = zc3 |
|---|
| 454 | zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk) |
|---|
| 455 | END DO |
|---|
| 456 | END DO |
|---|
| 457 | END DO |
|---|
| 458 | ! |
|---|
| 459 | DO jk = 1, nksr |
|---|
| 460 | etot3(:,:,jk) = ro0cpr * ( zea(:,:,jk) - zea(:,:,jk+1) ) |
|---|
| 461 | END DO |
|---|
| 462 | etot3(:,:,nksr+1:jpk) = 0.e0 ! below 400m set to zero |
|---|
| 463 | ENDIF |
|---|
| 464 | ENDIF |
|---|
| 465 | ! |
|---|
| 466 | ENDIF |
|---|
| 467 | ! ! ---------------------------------- ! |
|---|
| 468 | IF( ln_qsr_2bd ) THEN ! 2 bands light penetration ! |
|---|
| 469 | ! ! ---------------------------------- ! |
|---|
| 470 | ! |
|---|
| 471 | ! ! level of light extinction |
|---|
| 472 | nksr = trc_oce_ext_lev( rn_si1, 1.e2 ) |
|---|
| 473 | IF(lwp) THEN |
|---|
| 474 | WRITE(numout,*) |
|---|
| 475 | IF(lwp) WRITE(numout,*) ' level of light extinction = ', nksr, ' ref depth = ', gdepw_0(nksr+1), ' m' |
|---|
| 476 | ENDIF |
|---|
| 477 | ! |
|---|
| 478 | IF( lk_vvl ) THEN ! variable volume |
|---|
| 479 | IF(lwp) WRITE(numout,*) ' key_vvl: light distribution will be computed at each time step' |
|---|
| 480 | ELSE ! constant volume: computes one for all |
|---|
| 481 | zz0 = rn_abs * ro0cpr |
|---|
| 482 | zz1 = ( 1. - rn_abs ) * ro0cpr |
|---|
| 483 | DO jk = 1, nksr !* solar heat absorbed at T-point computed once for all |
|---|
| 484 | DO jj = 1, jpj ! top 400 meters |
|---|
| 485 | DO ji = 1, jpi |
|---|
| 486 | zc0 = zz0 * EXP( -fsdepw(ji,jj,jk )*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk )*xsi1r ) |
|---|
| 487 | zc1 = zz0 * EXP( -fsdepw(ji,jj,jk+1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk+1)*xsi1r ) |
|---|
| 488 | etot3(ji,jj,jk) = ( zc0 * tmask(ji,jj,jk) - zc1 * tmask(ji,jj,jk+1) ) |
|---|
| 489 | END DO |
|---|
| 490 | END DO |
|---|
| 491 | END DO |
|---|
| 492 | etot3(:,:,nksr+1:jpk) = 0.e0 ! below 400m set to zero |
|---|
| 493 | ! |
|---|
| 494 | ENDIF |
|---|
| 495 | ENDIF |
|---|
| 496 | ! ! ===================================== ! |
|---|
| 497 | ELSE ! No light penetration ! |
|---|
| 498 | ! ! ===================================== ! |
|---|
| 499 | IF(lwp) THEN |
|---|
| 500 | WRITE(numout,*) |
|---|
| 501 | WRITE(numout,*) 'tra_qsr_init : NO solar flux penetration' |
|---|
| 502 | WRITE(numout,*) '~~~~~~~~~~~~' |
|---|
| 503 | ENDIF |
|---|
| 504 | ENDIF |
|---|
| 505 | ! |
|---|
| 506 | IF( wrk_not_released(2, 1,2,3) .OR. & |
|---|
| 507 | wrk_not_released(3, 1,2,3,4,5) ) CALL ctl_stop('tra_qsr_init: failed to release workspace arrays') |
|---|
| 508 | ! |
|---|
| 509 | END SUBROUTINE tra_qsr_init |
|---|
| 510 | |
|---|
| 511 | !!====================================================================== |
|---|
| 512 | END MODULE traqsr |
|---|
