New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trazdf_exp.F90 in branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/TRA/trazdf_exp.F90 @ 2696

Last change on this file since 2696 was 2696, checked in by rblod, 13 years ago

Compatibility with key_traldf_ano for dynamic memory
  • Property svn:keywords set to Id
File size: 8.5 KB
Line 
1MODULE trazdf_exp
2   !!==============================================================================
3   !!                    ***  MODULE  trazdf_exp  ***
4   !! Ocean  tracers:  vertical component of the tracer mixing trend using
5   !!                  a split-explicit time-stepping
6   !!==============================================================================
7   !! History :  OPA  !  1990-10  (B. Blanke)  Original code
8   !!            7.0  !  1991-11  (G. Madec)
9   !!                 !  1992-06  (M. Imbard)  correction on tracer trend loops
10   !!                 !  1996-01  (G. Madec)  statement function for e3
11   !!                 !  1997-05  (G. Madec)  vertical component of isopycnal
12   !!                 !  1997-07  (G. Madec)  geopotential diffusion in s-coord
13   !!                 !  2000-08  (G. Madec)  double diffusive mixing
14   !!   NEMO     1.0  !  2002-08  (G. Madec)  F90: Free form and module
15   !!             -   !  2004-08  (C. Talandier) New trends organisation
16   !!             -   !  2005-11  (G. Madec)  New organisation
17   !!            3.0  !  2008-04  (G. Madec)  leap-frog time stepping done in trazdf
18   !!            3.3  !  2010-06  (C. Ethe, G. Madec) Merge TRA-TRC
19   !!----------------------------------------------------------------------
20
21   !!----------------------------------------------------------------------
22   !!   tra_zdf_exp  : compute the tracer the vertical diffusion trend using a
23   !!                  split-explicit time stepping and provide the after tracer
24   !!----------------------------------------------------------------------
25   USE oce             ! ocean dynamics and active tracers
26   USE dom_oce         ! ocean space and time domain
27   USE domvvl          ! variable volume levels
28   USE zdf_oce         ! ocean vertical physics
29   USE zdfddm          ! ocean vertical physics: double diffusion
30   USE trc_oce         ! share passive tracers/Ocean variables
31   USE in_out_manager  ! I/O manager
32   USE lib_mpp         ! MPP library
33
34   IMPLICIT NONE
35   PRIVATE
36
37   PUBLIC   tra_zdf_exp   ! routine called by step.F90
38
39   !! * Substitutions
40#  include "domzgr_substitute.h90"
41#  include "zdfddm_substitute.h90"
42#  include "vectopt_loop_substitute.h90"
43   !!----------------------------------------------------------------------
44   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
45   !! $Id$
46   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
47   !!----------------------------------------------------------------------
48CONTAINS
49
50   SUBROUTINE tra_zdf_exp( kt, cdtype, p2dt, kn_zdfexp,   &
51      &                                ptb , pta      , kjpt )
52      !!----------------------------------------------------------------------
53      !!                  ***  ROUTINE tra_zdf_exp  ***
54      !!                   
55      !! ** Purpose :   Compute the after tracer fields due to the vertical
56      !!      tracer mixing alone, and then due to the whole tracer trend.
57      !!
58      !! ** Method  : - The after tracer fields due to the vertical diffusion
59      !!      of tracers alone is given by:
60      !!                zwx = ptb + p2dt difft
61      !!      where difft = dz( avt dz(ptb) ) = 1/e3t dk+1( avt/e3w dk(ptb) )
62      !!           (if lk_zdfddm=T use avs on salinity and passive tracers instead of avt)
63      !!      difft is evaluated with an Euler split-explit scheme using a
64      !!      no flux boundary condition at both surface and bottomi boundaries.
65      !!      (N.B. bottom condition is applied through the masked field avt).
66      !!              - the after tracer fields due to the whole trend is
67      !!      obtained in leap-frog environment by :
68      !!          pta = zwx + p2dt pta
69      !!              - in case of variable level thickness (lk_vvl=T) the
70      !!     the leap-frog is applied on thickness weighted tracer. That is:
71      !!          pta = [ ptb*e3tb + e3tn*( zwx - ptb + p2dt pta ) ] / e3tn
72      !!
73      !! ** Action : - after tracer fields pta
74      !!---------------------------------------------------------------------
75      USE wrk_nemo, ONLY:   wrk_in_use, wrk_not_released
76      USE wrk_nemo, ONLY:   zwx => wrk_3d_6, zwy => wrk_3d_7     ! 3D workspace
77      !
78      INTEGER                              , INTENT(in   ) ::   kt          ! ocean time-step index
79      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype      ! =TRA or TRC (tracer indicator)
80      INTEGER                              , INTENT(in   ) ::   kjpt        ! number of tracers
81      INTEGER                              , INTENT(in   ) ::   kn_zdfexp   ! number of sub-time step
82      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt        ! vertical profile of tracer time-step
83      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb         ! before and now tracer fields
84      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta         ! tracer trend
85      !
86      INTEGER  ::  ji, jj, jk, jn, jl        ! dummy loop indices
87      REAL(wp) ::  zlavmr, zave3r, ze3tr     ! local scalars
88      REAL(wp) ::  ztra, ze3tb               !   -      -
89      !!---------------------------------------------------------------------
90
91      IF( wrk_in_use(3, 6,7) ) THEN
92         CALL ctl_stop('tra_zdf_exp: requested workspace arrays unavailable')   ;   RETURN
93      ENDIF
94
95      IF( kt == nit000 )  THEN
96         IF(lwp) WRITE(numout,*)
97         IF(lwp) WRITE(numout,*) 'tra_zdf_exp : explicit vertical mixing on ', cdtype
98         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
99      ENDIF
100
101      ! Initializations
102      ! ---------------
103      zlavmr = 1. / float( kn_zdfexp )         ! Local constant
104      !
105      !
106      DO jn = 1, kjpt                          ! loop over tracers
107         !
108         zwy(:,:, 1 ) = 0.e0     ! surface boundary conditions: no flux
109         zwy(:,:,jpk) = 0.e0     ! bottom  boundary conditions: no flux
110         !
111         zwx(:,:,:)   = ptb(:,:,:,jn)  ! zwx array set to before tracer values
112
113         ! Split-explicit loop  (after tracer due to the vertical diffusion alone)
114         ! -------------------
115         !
116         DO jl = 1, kn_zdfexp
117            !                     ! first vertical derivative
118            DO jk = 2, jpk
119               DO jj = 2, jpjm1 
120                  DO ji = fs_2, fs_jpim1   ! vector opt.
121                     zave3r = 1.e0 / fse3w_n(ji,jj,jk) 
122                     IF( cdtype == 'TRA' .AND. jn == jp_tem ) THEN  ! temperature : use of avt
123                        zwy(ji,jj,jk) =   avt(ji,jj,jk) * ( zwx(ji,jj,jk-1) - zwx(ji,jj,jk) ) * zave3r
124                     ELSE                                           ! salinity or pass. tracer : use of avs
125                        zwy(ji,jj,jk) = fsavs(ji,jj,jk) * ( zwx(ji,jj,jk-1) - zwx(ji,jj,jk) ) * zave3r
126                     END IF
127                  END DO
128               END DO
129            END DO
130            !
131            DO jk = 1, jpkm1      ! second vertical derivative   ==> tracer at kt+l*2*rdt/nn_zdfexp
132               DO jj = 2, jpjm1 
133                  DO ji = fs_2, fs_jpim1   ! vector opt.
134                     ze3tr = zlavmr / fse3t_n(ji,jj,jk)
135                     zwx(ji,jj,jk) = zwx(ji,jj,jk) + p2dt(jk) * ( zwy(ji,jj,jk) - zwy(ji,jj,jk+1) ) * ze3tr
136                  END DO
137               END DO
138            END DO
139            !
140         END DO
141
142         ! After tracer due to all trends
143         ! ------------------------------
144         IF( lk_vvl ) THEN          ! variable level thickness : leap-frog on tracer*e3t
145            DO jk = 1, jpkm1
146               DO jj = 2, jpjm1 
147                  DO ji = fs_2, fs_jpim1   ! vector opt.
148                     ze3tb = fse3t_b(ji,jj,jk) / fse3t(ji,jj,jk)                          ! before e3t
149                     ztra  = zwx(ji,jj,jk) - ptb(ji,jj,jk,jn) + p2dt(jk) * pta(ji,jj,jk,jn)       ! total trends * 2*rdt
150                     pta(ji,jj,jk,jn) = ( ze3tb * ptb(ji,jj,jk,jn) + ztra ) * tmask(ji,jj,jk)
151                  END DO
152               END DO
153            END DO
154         ELSE                       ! fixed level thickness : leap-frog on tracers
155            DO jk = 1, jpkm1
156               DO jj = 2, jpjm1 
157                  DO ji = fs_2, fs_jpim1   ! vector opt.
158                     pta(ji,jj,jk,jn) = ( zwx(ji,jj,jk) + p2dt(jk) * pta(ji,jj,jk,jn) ) * tmask(ji,jj,jk)
159                  END DO
160               END DO
161            END DO
162         ENDIF
163         !
164      END DO
165      !
166      IF( wrk_not_released(3, 6,7) )   CALL ctl_stop('tra_zdf_exp: failed to release workspace arrays')
167      !
168   END SUBROUTINE tra_zdf_exp
169
170   !!==============================================================================
171END MODULE trazdf_exp
Note: See TracBrowser for help on using the repository browser.