New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zpshde.F90 in branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/dev_r2586_dynamic_mem/NEMOGCM/NEMO/OPA_SRC/TRA/zpshde.F90 @ 2696

Last change on this file since 2696 was 2690, checked in by gm, 13 years ago

dynamic mem: #785 ; homogeneization of the coding style associated with dyn allocation
  • Property svn:keywords set to Id
File size: 11.1 KB
Line 
1MODULE zpshde
2   !!======================================================================
3   !!                       ***  MODULE zpshde   ***
4   !! z-coordinate + partial step : Horizontal Derivative at ocean bottom level
5   !!======================================================================
6   !! History :  OPA  !  2002-04  (A. Bozec)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec E. Durand)  Optimization and Free form
8   !!             -   !  2004-03  (C. Ethe)  adapted for passive tracers
9   !!            3.3  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA
10   !!======================================================================
11   
12   !!----------------------------------------------------------------------
13   !!   zps_hde      :  Horizontal DErivative of T, S and rd at the last
14   !!                   ocean level (Z-coord. with Partial Steps)
15   !!----------------------------------------------------------------------
16   USE oce             ! ocean: dynamics and tracers variables
17   USE dom_oce         ! domain: ocean variables
18   USE phycst          ! physical constants
19   USE eosbn2          ! ocean equation of state
20   USE in_out_manager  ! I/O manager
21   USE lbclnk          ! lateral boundary conditions (or mpp link)
22   USE lib_mpp         ! MPP library
23
24   IMPLICIT NONE
25   PRIVATE
26
27   PUBLIC   zps_hde    ! routine called by step.F90
28
29   !! * Substitutions
30#  include "domzgr_substitute.h90"
31#  include "vectopt_loop_substitute.h90"
32   !!----------------------------------------------------------------------
33   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
34   !! $Id$
35   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
36   !!----------------------------------------------------------------------
37CONTAINS
38
39   SUBROUTINE zps_hde( kt, kjpt, pta, pgtu, pgtv,   &
40                                 prd, pgru, pgrv    )
41      !!----------------------------------------------------------------------
42      !!                     ***  ROUTINE zps_hde  ***
43      !!                   
44      !! ** Purpose :   Compute the horizontal derivative of T, S and rho
45      !!      at u- and v-points with a linear interpolation for z-coordinate
46      !!      with partial steps.
47      !!
48      !! ** Method  :   In z-coord with partial steps, scale factors on last
49      !!      levels are different for each grid point, so that T, S and rd
50      !!      points are not at the same depth as in z-coord. To have horizontal
51      !!      gradients again, we interpolate T and S at the good depth :
52      !!      Linear interpolation of T, S   
53      !!         Computation of di(tb) and dj(tb) by vertical interpolation:
54      !!          di(t) = t~ - t(i,j,k) or t(i+1,j,k) - t~
55      !!          dj(t) = t~ - t(i,j,k) or t(i,j+1,k) - t~
56      !!         This formulation computes the two cases:
57      !!                 CASE 1                   CASE 2 
58      !!         k-1  ___ ___________   k-1   ___ ___________
59      !!                    Ti  T~                  T~  Ti+1
60      !!                  _____                        _____
61      !!         k        |   |Ti+1     k           Ti |   |
62      !!                  |   |____                ____|   |
63      !!              ___ |   |   |           ___  |   |   |
64      !!                 
65      !!      case 1->   e3w(i+1) >= e3w(i) ( and e3w(j+1) >= e3w(j) ) then
66      !!          t~ = t(i+1,j  ,k) + (e3w(i+1) - e3w(i)) * dk(Ti+1)/e3w(i+1)
67      !!        ( t~ = t(i  ,j+1,k) + (e3w(j+1) - e3w(j)) * dk(Tj+1)/e3w(j+1)  )
68      !!          or
69      !!      case 2->   e3w(i+1) <= e3w(i) ( and e3w(j+1) <= e3w(j) ) then
70      !!          t~ = t(i,j,k) + (e3w(i) - e3w(i+1)) * dk(Ti)/e3w(i )
71      !!        ( t~ = t(i,j,k) + (e3w(j) - e3w(j+1)) * dk(Tj)/e3w(j ) )
72      !!          Idem for di(s) and dj(s)         
73      !!
74      !!      For rho, we call eos_insitu_2d which will compute rd~(t~,s~) at
75      !!      the good depth zh from interpolated T and S for the different
76      !!      formulation of the equation of state (eos).
77      !!      Gradient formulation for rho :
78      !!          di(rho) = rd~ - rd(i,j,k) or rd(i+1,j,k) - rd~
79      !!
80      !! ** Action  : - pgtu, pgtv: horizontal gradient of tracer at u- & v-points
81      !!              - pgru, pgrv: horizontal gradient of rho (if present) at u- & v-points
82      !!----------------------------------------------------------------------
83      USE wrk_nemo, ONLY:   wrk_in_use, wrk_not_released
84      USE wrk_nemo, ONLY:   zri => wrk_2d_1 , zrj => wrk_2d_2   ! interpolated value of rd
85      USE wrk_nemo, ONLY:   zhi => wrk_2d_3 , zhj => wrk_2d_4   ! depth of interpolation for eos2d
86      !
87      INTEGER                              , INTENT(in   )           ::  kt          ! ocean time-step index
88      INTEGER                              , INTENT(in   )           ::  kjpt        ! number of tracers
89      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   )           ::  pta         ! 4D tracers fields
90      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(  out)           ::  pgtu, pgtv  ! hor. grad. of ptra at u- & v-pts
91      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ), OPTIONAL ::  prd         ! 3D density anomaly fields
92      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pgru, pgrv  ! hor. grad. of prd at u- & v-pts
93      !
94      INTEGER  ::   ji, jj, jn      ! Dummy loop indices
95      INTEGER  ::   iku, ikv, ikum1, ikvm1   ! partial step level (ocean bottom level) at u- and v-points
96      REAL(wp) ::  ze3wu, ze3wv, zmaxu, zmaxv  ! temporary scalars
97      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   zti, ztj    ! interpolated value of tracer
98      !!----------------------------------------------------------------------
99
100      IF( wrk_in_use(2, 1,2,3,4) ) THEN
101         CALL ctl_stop('zps_hde: requested workspace arrays unavailable')  ;  RETURN
102      END IF
103
104      ! Allocate workspaces whose dimension is > jpk
105      ALLOCATE( zti(jpi,jpj,kjpt) )
106      ALLOCATE( ztj(jpi,jpj,kjpt) )
107
108      DO jn = 1, kjpt      !==   Interpolation of tracers at the last ocean level   ==!
109         !
110# if defined key_vectopt_loop
111         jj = 1
112         DO ji = 1, jpij-jpi   ! vector opt. (forced unrolled)
113# else
114         DO jj = 1, jpjm1
115            DO ji = 1, jpim1
116# endif
117               iku = mbku(ji,jj)   ;   ikum1 = MAX( iku - 1 , 1 )    ! last and before last ocean level at u- & v-points
118               ikv = mbkv(ji,jj)   ;   ikvm1 = MAX( ikv - 1 , 1 )    ! if level first is a p-step, ik.m1=1
119               ze3wu = fse3w(ji+1,jj  ,iku) - fse3w(ji,jj,iku)
120               ze3wv = fse3w(ji  ,jj+1,ikv) - fse3w(ji,jj,ikv)
121               !
122               ! i- direction
123               IF( ze3wu >= 0._wp ) THEN      ! case 1
124                  zmaxu =  ze3wu / fse3w(ji+1,jj,iku)
125                  ! interpolated values of tracers
126                  zti(ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,ikum1,jn) - pta(ji+1,jj,iku,jn) )
127                  ! gradient of  tracers
128                  pgtu(ji,jj,jn) = umask(ji,jj,1) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
129               ELSE                           ! case 2
130                  zmaxu = -ze3wu / fse3w(ji,jj,iku)
131                  ! interpolated values of tracers
132                  zti(ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,ikum1,jn) - pta(ji,jj,iku,jn) )
133                  ! gradient of tracers
134                  pgtu(ji,jj,jn) = umask(ji,jj,1) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
135               ENDIF
136               !
137               ! j- direction
138               IF( ze3wv >= 0._wp ) THEN      ! case 1
139                  zmaxv =  ze3wv / fse3w(ji,jj+1,ikv)
140                  ! interpolated values of tracers
141                  ztj(ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikvm1,jn) - pta(ji,jj+1,ikv,jn) )
142                  ! gradient of tracers
143                  pgtv(ji,jj,jn) = vmask(ji,jj,1) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
144               ELSE                           ! case 2
145                  zmaxv =  -ze3wv / fse3w(ji,jj,ikv)
146                  ! interpolated values of tracers
147                  ztj(ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikvm1,jn) - pta(ji,jj,ikv,jn) )
148                  ! gradient of tracers
149                  pgtv(ji,jj,jn) = vmask(ji,jj,1) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
150               ENDIF
151# if ! defined key_vectopt_loop
152            END DO
153# endif
154         END DO
155         CALL lbc_lnk( pgtu(:,:,jn), 'U', -1. )   ;   CALL lbc_lnk( pgtv(:,:,jn), 'V', -1. )   ! Lateral boundary cond.
156         !
157      END DO
158
159      ! horizontal derivative of density anomalies (rd)
160      IF( PRESENT( prd ) ) THEN         ! depth of the partial step level
161# if defined key_vectopt_loop
162         jj = 1
163         DO ji = 1, jpij-jpi   ! vector opt. (forced unrolled)
164# else
165         DO jj = 1, jpjm1
166            DO ji = 1, jpim1
167# endif
168               iku = mbku(ji,jj)
169               ikv = mbkv(ji,jj)
170               ze3wu  = fse3w(ji+1,jj  ,iku) - fse3w(ji,jj,iku)
171               ze3wv  = fse3w(ji  ,jj+1,ikv) - fse3w(ji,jj,ikv)
172               IF( ze3wu >= 0._wp ) THEN   ;   zhi(ji,jj) = fsdept(ji  ,jj,iku)     ! i-direction: case 1
173               ELSE                        ;   zhi(ji,jj) = fsdept(ji+1,jj,iku)     ! -     -      case 2
174               ENDIF
175               IF( ze3wv >= 0._wp ) THEN   ;   zhj(ji,jj) = fsdept(ji,jj  ,ikv)     ! j-direction: case 1
176               ELSE                        ;   zhj(ji,jj) = fsdept(ji,jj+1,ikv)     ! -     -      case 2
177               ENDIF
178# if ! defined key_vectopt_loop
179            END DO
180# endif
181         END DO
182
183         ! Compute interpolated rd from zti, ztj for the 2 cases at the depth of the partial
184         ! step and store it in  zri, zrj for each  case
185         CALL eos( zti, zhi, zri )   ;   CALL eos( ztj, zhj, zrj )
186
187         ! Gradient of density at the last level
188# if defined key_vectopt_loop
189         jj = 1
190         DO ji = 1, jpij-jpi   ! vector opt. (forced unrolled)
191# else
192         DO jj = 1, jpjm1
193            DO ji = 1, jpim1
194# endif
195               iku = mbku(ji,jj)
196               ikv = mbkv(ji,jj)
197               ze3wu  = fse3w(ji+1,jj  ,iku) - fse3w(ji,jj,iku)
198               ze3wv  = fse3w(ji  ,jj+1,ikv) - fse3w(ji,jj,ikv)
199               IF( ze3wu >= 0._wp ) THEN   ;   pgru(ji,jj) = umask(ji,jj,1) * ( zri(ji  ,jj) - prd(ji,jj,iku) )   ! i: 1
200               ELSE                        ;   pgru(ji,jj) = umask(ji,jj,1) * ( prd(ji+1,jj,iku) - zri(ji,jj) )   ! i: 2
201               ENDIF
202               IF( ze3wv >= 0._wp ) THEN   ;   pgrv(ji,jj) = vmask(ji,jj,1) * ( zrj(ji,jj  ) - prd(ji,jj,ikv) )   ! j: 1
203               ELSE                        ;   pgrv(ji,jj) = vmask(ji,jj,1) * ( prd(ji,jj+1,ikv) - zrj(ji,jj) )   ! j: 2
204               ENDIF
205# if ! defined key_vectopt_loop
206            END DO
207# endif
208         END DO
209         CALL lbc_lnk( pgru , 'U', -1. )   ;   CALL lbc_lnk( pgrv , 'V', -1. )   ! Lateral boundary conditions
210         !
211      END IF
212      !
213      IF( wrk_not_released(2, 1,2,3,4) )   CALL ctl_stop('zps_hde: failed to release workspace arrays')
214      !
215      DEALLOCATE( zti )
216      DEALLOCATE( ztj )
217      !
218   END SUBROUTINE zps_hde
219
220   !!======================================================================
221END MODULE zpshde
Note: See TracBrowser for help on using the repository browser.