New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcice_lim.F90 in branches/dev_r4028_CNRS_LIM3_MV2014/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/dev_r4028_CNRS_LIM3_MV2014/NEMOGCM/NEMO/OPA_SRC/SBC/sbcice_lim.F90 @ 4506

Last change on this file since 4506 was 4506, checked in by vancop, 10 years ago

[Heat conservation in LIM3, part HC1 (LIM_SRC_3_HC17)]

  • Property svn:keywords set to Id
File size: 45.1 KB
Line 
1MODULE sbcice_lim
2   !!======================================================================
3   !!                       ***  MODULE  sbcice_lim  ***
4   !! Surface module :  update the ocean surface boundary condition over ice
5   !!       &           covered area using LIM sea-ice model
6   !! Sea-Ice model  :  LIM-3 Sea ice model time-stepping
7   !!=====================================================================
8   !! History :  2.0  ! 2006-12  (M. Vancoppenolle) Original code
9   !!            3.0  ! 2008-02  (C. Talandier)  Surface module from icestp.F90
10   !!             -   ! 2008-04  (G. Madec)  sltyle and lim_ctl routine
11   !!            3.3  ! 2010-11  (G. Madec) ice-ocean stress always computed at each ocean time-step
12   !!            3.4  ! 2011-01  (A Porter)  dynamical allocation
13   !!             -   ! 2012-10  (C. Rousset)  add lim_diahsb
14   !!----------------------------------------------------------------------
15#if defined key_lim3
16   !!----------------------------------------------------------------------
17   !!   'key_lim3' :                                  LIM 3.0 sea-ice model
18   !!----------------------------------------------------------------------
19   !!   sbc_ice_lim  : sea-ice model time-stepping and update ocean sbc over ice-covered area
20   !!   lim_ctl       : alerts in case of ice model crash
21   !!   lim_prt_state : ice control print at a given grid point
22   !!----------------------------------------------------------------------
23   USE oce             ! ocean dynamics and tracers
24   USE dom_oce         ! ocean space and time domain
25   USE par_ice         ! sea-ice parameters
26   USE ice             ! LIM-3: ice variables
27   USE iceini          ! LIM-3: ice initialisation
28   USE dom_ice         ! LIM-3: ice domain
29
30   USE sbc_oce         ! Surface boundary condition: ocean fields
31   USE sbc_ice         ! Surface boundary condition: ice   fields
32   USE sbcblk_core     ! Surface boundary condition: CORE bulk
33   USE sbcblk_clio     ! Surface boundary condition: CLIO bulk
34   USE sbccpl          ! Surface boundary condition: coupled interface
35   USE albedo          ! ocean & ice albedo
36
37   USE phycst          ! Define parameters for the routines
38   USE eosbn2          ! equation of state
39   USE limdyn          ! Ice dynamics
40   USE limtrp          ! Ice transport
41   USE limthd          ! Ice thermodynamics
42   USE limitd_th       ! Thermodynamics on ice thickness distribution
43   USE limitd_me       ! Mechanics on ice thickness distribution
44   USE limsbc          ! sea surface boundary condition
45   USE limdiahsb       ! Ice budget diagnostics
46   USE limwri          ! Ice outputs
47   USE limrst          ! Ice restarts
48   USE limupdate1       ! update of global variables
49   USE limupdate2       ! update of global variables
50   USE limvar          ! Ice variables switch
51
52   USE c1d             ! 1D vertical configuration
53   USE lbclnk          ! lateral boundary condition - MPP link
54   USE lib_mpp         ! MPP library
55   USE wrk_nemo        ! work arrays
56   USE timing          ! Timing
57   USE iom             ! I/O manager library
58   USE in_out_manager  ! I/O manager
59   USE prtctl          ! Print control
60   USE lib_fortran     !
61
62#if defined key_bdy 
63   USE bdyice_lim       ! unstructured open boundary data  (bdy_ice_lim routine)
64#endif
65
66   IMPLICIT NONE
67   PRIVATE
68
69   PUBLIC sbc_ice_lim  ! routine called by sbcmod.F90
70   
71   !! * Substitutions
72#  include "domzgr_substitute.h90"
73#  include "vectopt_loop_substitute.h90"
74   !!----------------------------------------------------------------------
75   !! NEMO/OPA 4.0 , UCL NEMO Consortium (2011)
76   !! $Id$
77   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
78   !!----------------------------------------------------------------------
79CONTAINS
80
81   FUNCTION fice_cell_ave ( ptab)
82      !!--------------------------------------------------------------------------
83      !! * Compute average over categories, for grid cell (ice covered and free ocean)
84      !!--------------------------------------------------------------------------
85      REAL (wp), DIMENSION (jpi,jpj) :: fice_cell_ave
86      REAL (wp), DIMENSION (jpi,jpj,jpl), INTENT (in) :: ptab
87      INTEGER :: jl ! Dummy loop index
88     
89      fice_cell_ave (:,:) = 0.0_wp
90     
91      DO jl = 1, jpl
92         fice_cell_ave (:,:) = fice_cell_ave (:,:) &
93            &                  + a_i (:,:,jl) * ptab (:,:,jl)
94      END DO
95     
96   END FUNCTION fice_cell_ave
97   
98   FUNCTION fice_ice_ave ( ptab)
99      !!--------------------------------------------------------------------------
100      !! * Compute average over categories, for ice covered part of grid cell
101      !!--------------------------------------------------------------------------
102      REAL (kind=wp), DIMENSION (jpi,jpj) :: fice_ice_ave
103      REAL (kind=wp), DIMENSION (jpi,jpj,jpl), INTENT(in) :: ptab
104
105      fice_ice_ave (:,:) = 0.0_wp
106      WHERE ( at_i (:,:) .GT. 0.0_wp ) fice_ice_ave (:,:) = fice_cell_ave ( ptab (:,:,:)) / at_i (:,:)
107
108   END FUNCTION fice_ice_ave
109
110   !!======================================================================
111
112   SUBROUTINE sbc_ice_lim( kt, kblk )
113      !!---------------------------------------------------------------------
114      !!                  ***  ROUTINE sbc_ice_lim  ***
115      !!                   
116      !! ** Purpose :   update the ocean surface boundary condition via the
117      !!                Louvain la Neuve Sea Ice Model time stepping
118      !!
119      !! ** Method  :   ice model time stepping
120      !!              - call the ice dynamics routine
121      !!              - call the ice advection/diffusion routine
122      !!              - call the ice thermodynamics routine
123      !!              - call the routine that computes mass and
124      !!                heat fluxes at the ice/ocean interface
125      !!              - save the outputs
126      !!              - save the outputs for restart when necessary
127      !!
128      !! ** Action  : - time evolution of the LIM sea-ice model
129      !!              - update all sbc variables below sea-ice:
130      !!                utau, vtau, taum, wndm, qns , qsr, emp , sfx
131      !!---------------------------------------------------------------------
132      INTEGER, INTENT(in) ::   kt      ! ocean time step
133      INTEGER, INTENT(in) ::   kblk    ! type of bulk (=3 CLIO, =4 CORE)
134      !!
135      INTEGER  ::   jl      ! dummy loop index
136      REAL(wp) ::   zcoef   ! local scalar
137      REAL(wp), POINTER, DIMENSION(:,:,:)   ::   zalb_ice_os, zalb_ice_cs  ! albedo of the ice under overcast/clear sky
138      REAL(wp), POINTER, DIMENSION(:,:,:)   ::   zalb_ice      ! mean albedo of ice
139
140      REAL(wp), POINTER, DIMENSION(:,:) :: zalb_ice_all    ! Mean albedo over all categories
141      REAL(wp), POINTER, DIMENSION(:,:) :: ztem_ice_all    ! Mean temperature over all categories
142     
143      REAL(wp), POINTER, DIMENSION(:,:) :: z_qsr_ice_all   ! Mean solar heat flux over all categories
144      REAL(wp), POINTER, DIMENSION(:,:) :: z_qns_ice_all   ! Mean non solar heat flux over all categories
145      REAL(wp), POINTER, DIMENSION(:,:) :: z_qla_ice_all   ! Mean latent heat flux over all categories
146      REAL(wp), POINTER, DIMENSION(:,:) :: z_dqns_ice_all  ! Mean d(qns)/dT over all categories
147      REAL(wp), POINTER, DIMENSION(:,:) :: z_dqla_ice_all  ! Mean d(qla)/dT over all categories
148      !!----------------------------------------------------------------------
149
150      !- O.M. : why do we allocate all these arrays even when MOD( kt-1, nn_fsbc ) /= 0 ?????
151
152      IF( nn_timing == 1 )  CALL timing_start('sbc_ice_lim')
153
154      CALL wrk_alloc( jpi,jpj,jpl, zalb_ice_os, zalb_ice_cs, zalb_ice )
155
156#if defined key_coupled
157      IF ( ln_iceflx_ave .OR. ln_iceflx_linear ) &
158         &   CALL wrk_alloc( jpi,jpj, ztem_ice_all, zalb_ice_all, z_qsr_ice_all, z_qns_ice_all, z_qla_ice_all, z_dqns_ice_all, z_dqla_ice_all)
159#endif
160
161      IF( kt == nit000 ) THEN
162         IF(lwp) WRITE(numout,*)
163         IF(lwp) WRITE(numout,*) 'sbc_ice_lim : update ocean surface boudary condition' 
164         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   via Louvain la Neuve Ice Model (LIM-3) time stepping'
165         !
166         CALL ice_init
167         !
168         IF( ln_nicep ) THEN      ! control print at a given point
169            jiindx = 14    ;   jjindx =  25
170            IF(lwp) WRITE(numout,*) ' The debugging point is : jiindx : ',jiindx, ' jjindx : ',jjindx
171         ENDIF
172      ENDIF
173
174      !                                        !----------------------!
175      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN     !  Ice time-step only  !
176         !                                     !----------------------!
177         !                                           !  Bulk Formulae !
178         !                                           !----------------!
179         !
180         u_oce(:,:) = ssu_m(:,:)                     ! mean surface ocean current at ice velocity point
181         v_oce(:,:) = ssv_m(:,:)                     ! (C-grid dynamics :  U- & V-points as the ocean)
182         !
183         t_bo(:,:) = tfreez( sss_m ) +  rt0          ! masked sea surface freezing temperature [Kelvin]
184         !                                           ! (set to rt0 over land)
185         CALL albedo_ice( t_su, ht_i, ht_s, zalb_ice_cs, zalb_ice_os )  ! ... ice albedo
186
187         DO jl = 1, jpl
188            t_su(:,:,jl) = t_su(:,:,jl) +  rt0 * ( 1. - tmask(:,:,1) )
189         END DO
190
191         IF ( ln_cpl ) zalb_ice (:,:,:) = 0.5 * ( zalb_ice_cs (:,:,:) +  zalb_ice_os (:,:,:) )
192         
193#if defined key_coupled
194         IF ( ln_iceflx_ave .OR. ln_iceflx_linear ) THEN
195            !
196            ! Compute mean albedo and temperature
197            zalb_ice_all (:,:) = fice_ice_ave ( zalb_ice (:,:,:) ) 
198            ztem_ice_all (:,:) = fice_ice_ave ( tn_ice   (:,:,:) ) 
199            !
200         ENDIF
201#endif
202                                               ! Bulk formulea - provides the following fields:
203         ! utau_ice, vtau_ice : surface ice stress                     (U- & V-points)   [N/m2]
204         ! qsr_ice , qns_ice  : solar & non solar heat flux over ice   (T-point)         [W/m2]
205         ! qla_ice            : latent heat flux over ice              (T-point)         [W/m2]
206         ! dqns_ice, dqla_ice : non solar & latent heat sensistivity   (T-point)         [W/m2]
207         ! tprecip , sprecip  : total & solid precipitation            (T-point)         [Kg/m2/s]
208         ! fr1_i0  , fr2_i0   : 1sr & 2nd fraction of qsr penetration in ice             [%]
209         !
210         SELECT CASE( kblk )
211         CASE( 3 )                                       ! CLIO bulk formulation
212            CALL blk_ice_clio( t_su , zalb_ice_cs, zalb_ice_os,                           &
213               &                      utau_ice   , vtau_ice   , qns_ice   , qsr_ice   ,   &
214               &                      qla_ice    , dqns_ice   , dqla_ice  ,               &
215               &                      tprecip    , sprecip    ,                           &
216               &                      fr1_i0     , fr2_i0     , cp_ice_msh, jpl  )
217            !         
218         CASE( 4 )                                       ! CORE bulk formulation
219            ! MV 2014
220            ! We must account for cloud fraction in the computation of the albedo
221            ! The present ref just uses the clear sky value
222            ! The overcast sky value is 0.06 higher, and polar skies are mostly overcast
223            ! CORE has no cloud fraction, hence we must prescribe it
224            ! Mean summer cloud fraction computed from CLIO = 0.81
225            zalb_ice(:,:,:) = 0.19 * zalb_ice_cs(:,:,:) + 0.81 * zalb_ice_os(:,:,:)
226            ! Following line, we replace zalb_ice_cs by simply zalb_ice
227            CALL blk_ice_core( t_su , u_ice     , v_ice     , zalb_ice   ,               &
228               &                      utau_ice  , vtau_ice  , qns_ice    , qsr_ice   ,   &
229               &                      qla_ice   , dqns_ice  , dqla_ice   ,               &
230               &                      tprecip   , sprecip   ,                            &
231               &                      fr1_i0    , fr2_i0    , cp_ice_msh, jpl  )
232            !
233         CASE ( 5 )
234            zalb_ice (:,:,:) = 0.5 * ( zalb_ice_cs (:,:,:) +  zalb_ice_os (:,:,:) )
235           
236            CALL sbc_cpl_ice_tau( utau_ice , vtau_ice )
237
238            CALL sbc_cpl_ice_flx( p_frld=ato_i, palbi=zalb_ice, psst=sst_m, pist=tn_ice    )
239
240            ! Latent heat flux is forced to 0 in coupled :
241            !  it is included in qns (non-solar heat flux)
242            qla_ice  (:,:,:) = 0.0e0_wp
243            dqla_ice (:,:,:) = 0.0e0_wp
244            !
245         END SELECT
246
247         ! Average over all categories
248#if defined key_coupled
249         IF ( ln_iceflx_ave .OR. ln_iceflx_linear ) THEN
250
251            z_qns_ice_all  (:,:) = fice_ice_ave ( qns_ice  (:,:,:) )
252            z_qsr_ice_all  (:,:) = fice_ice_ave ( qsr_ice  (:,:,:) )
253            z_dqns_ice_all (:,:) = fice_ice_ave ( dqns_ice (:,:,:) )
254            z_qla_ice_all  (:,:) = fice_ice_ave ( qla_ice  (:,:,:) )
255            z_dqla_ice_all (:,:) = fice_ice_ave ( dqla_ice (:,:,:) )
256
257            DO jl = 1, jpl
258               dqns_ice (:,:,jl) = z_dqns_ice_all (:,:)
259               dqla_ice (:,:,jl) = z_dqla_ice_all (:,:)
260            END DO
261            !
262            IF ( ln_iceflx_ave ) THEN
263               DO jl = 1, jpl
264                  qns_ice  (:,:,jl) = z_qns_ice_all  (:,:)
265                  qsr_ice  (:,:,jl) = z_qsr_ice_all  (:,:)
266                  qla_ice  (:,:,jl) = z_qla_ice_all  (:,:)
267               END DO
268            END IF
269            !
270            IF ( ln_iceflx_linear ) THEN
271               DO jl = 1, jpl
272                  qns_ice  (:,:,jl) = z_qns_ice_all(:,:) + z_dqns_ice_all(:,:) * (tn_ice(:,:,jl) - ztem_ice_all(:,:))
273                  qla_ice  (:,:,jl) = z_qla_ice_all(:,:) + z_dqla_ice_all(:,:) * (tn_ice(:,:,jl) - ztem_ice_all(:,:))
274                  qsr_ice  (:,:,jl) = (1.0e0_wp-zalb_ice(:,:,jl)) / (1.0e0_wp-zalb_ice_all(:,:)) * z_qsr_ice_all(:,:)
275               END DO
276            END IF
277         END IF
278#endif
279         !                                           !----------------------!
280         !                                           ! LIM-3  time-stepping !
281         !                                           !----------------------!
282         !
283         numit = numit + nn_fsbc                     ! Ice model time step
284         !
285         !                                           ! Store previous ice values
286!!gm : remark   old_...   should becomes ...b  as tn versus tb 
287         old_a_i  (:,:,:)   = a_i  (:,:,:)     ! ice area
288         old_e_i  (:,:,:,:) = e_i  (:,:,:,:)   ! ice thermal energy
289         old_v_i  (:,:,:)   = v_i  (:,:,:)     ! ice volume
290         old_v_s  (:,:,:)   = v_s  (:,:,:)     ! snow volume
291         old_e_s  (:,:,:,:) = e_s  (:,:,:,:)   ! snow thermal energy
292         old_smv_i(:,:,:)   = smv_i(:,:,:)     ! salt content
293         old_oa_i (:,:,:)   = oa_i (:,:,:)     ! areal age content
294         !
295         old_u_ice(:,:) = u_ice(:,:)
296         old_v_ice(:,:) = v_ice(:,:)
297         !                                           ! intialisation to zero    !!gm is it truly necessary ???
298         d_a_i_thd  (:,:,:)   = 0._wp   ;   d_a_i_trp  (:,:,:)   = 0._wp
299         d_v_i_thd  (:,:,:)   = 0._wp   ;   d_v_i_trp  (:,:,:)   = 0._wp
300         d_e_i_thd  (:,:,:,:) = 0._wp   ;   d_e_i_trp  (:,:,:,:) = 0._wp
301         d_v_s_thd  (:,:,:)   = 0._wp   ;   d_v_s_trp  (:,:,:)   = 0._wp
302         d_e_s_thd  (:,:,:,:) = 0._wp   ;   d_e_s_trp  (:,:,:,:) = 0._wp
303         d_smv_i_thd(:,:,:)   = 0._wp   ;   d_smv_i_trp(:,:,:)   = 0._wp
304         d_oa_i_thd (:,:,:)   = 0._wp   ;   d_oa_i_trp (:,:,:)   = 0._wp
305         !
306         d_u_ice_dyn(:,:) = 0._wp
307         d_v_ice_dyn(:,:) = 0._wp
308         !
309         sfx    (:,:) = 0._wp   ;   sfx_thd  (:,:) = 0._wp
310         sfx_bri(:,:) = 0._wp   ;   sfx_mec  (:,:) = 0._wp   ;   sfx_res  (:,:) = 0._wp
311         fhbri  (:,:) = 0._wp   ;   
312         fheat_res(:,:) = 0._wp 
313         fhmec  (:,:) = 0._wp   ;   
314         fmmec  (:,:) = 0._wp
315         fmmflx (:,:) = 0._wp     
316         focea2D(:,:) = 0._wp
317         fsup2D (:,:) = 0._wp
318
319         ! used in limthd.F90
320         rdvosif(:,:) = 0._wp   ! variation of ice volume at surface
321         rdvobif(:,:) = 0._wp   ! variation of ice volume at bottom
322         fdvolif(:,:) = 0._wp   ! total variation of ice volume
323         rdvonif(:,:) = 0._wp   ! lateral variation of ice volume
324         fstric (:,:) = 0._wp   ! part of solar radiation transmitted through the ice
325         ffltbif(:,:) = 0._wp   ! linked with fstric
326         qfvbq  (:,:) = 0._wp   ! linked with fstric
327         rdm_snw(:,:) = 0._wp   ! variation of snow mass per unit area
328         rdm_ice(:,:) = 0._wp   ! variation of ice mass per unit area
329         rdq_snw(:,:) = 0._wp   ! heat flux associated with mass exchange (ice contribution)
330         rdq_ice(:,:) = 0._wp   ! heat flux associated with mass exchange (snow contribution)
331         hicifp (:,:) = 0._wp   ! daily thermodynamic ice production.
332         !
333         diag_sni_gr(:,:) = 0._wp   ;   diag_lat_gr(:,:) = 0._wp
334         diag_bot_gr(:,:) = 0._wp   ;   diag_dyn_gr(:,:) = 0._wp
335         diag_bot_me(:,:) = 0._wp   ;   diag_sur_me(:,:) = 0._wp
336         diag_res_pr(:,:) = 0._wp   ;   diag_trp_vi(:,:) = 0._wp
337         ! dynamical invariants
338         delta_i(:,:) = 0._wp       ;   divu_i(:,:) = 0._wp       ;   shear_i(:,:) = 0._wp
339
340                          CALL lim_rst_opn( kt )     ! Open Ice restart file
341         !
342         IF( ln_nicep )   CALL lim_prt_state( kt, jiindx, jjindx, 1, ' - Beginning the time step - ' )   ! control print
343         ! ----------------------------------------------
344         ! ice dynamics and transport (except in 1D case)
345         ! ----------------------------------------------
346         IF( .NOT. lk_c1d ) THEN
347                          CALL lim_dyn( kt )              ! Ice dynamics    ( rheology/dynamics )
348                          CALL lim_trp( kt )              ! Ice transport   ( Advection/diffusion )
349                          CALL lim_var_glo2eqv            ! equivalent variables, requested for rafting
350         IF( ln_nicep )   CALL lim_prt_state( kt, jiindx, jjindx,-1, ' - ice dyn & trp - ' )   ! control print
351                          CALL lim_itd_me                 ! Mechanical redistribution ! (ridging/rafting)
352                          CALL lim_var_agg( 1 ) 
353#if defined key_bdy
354                          ! bdy ice thermo
355                          CALL lim_var_glo2eqv            ! equivalent variables
356                          CALL bdy_ice_lim( kt )
357                          CALL lim_itd_me_zapsmall
358                          CALL lim_var_agg(1)
359         IF( ln_nicep )   CALL lim_prt_state( kt, jiindx, jjindx, 1, ' - ice thermo bdy - ' )   ! control print
360#endif
361                          CALL lim_update1
362         ENDIF
363!                         !- Change old values for new values
364                          old_u_ice(:,:)   = u_ice (:,:)
365                          old_v_ice(:,:)   = v_ice (:,:)
366                          old_a_i(:,:,:)   = a_i (:,:,:)
367                          old_v_s(:,:,:)   = v_s (:,:,:)
368                          old_v_i(:,:,:)   = v_i (:,:,:)
369                          old_e_s(:,:,:,:) = e_s (:,:,:,:)
370                          old_e_i(:,:,:,:) = e_i (:,:,:,:)
371                          old_oa_i(:,:,:)  = oa_i(:,:,:)
372                          old_smv_i(:,:,:) = smv_i (:,:,:)
373 
374         ! ----------------------------------------------
375         ! ice thermodynamic
376         ! ----------------------------------------------
377                          CALL lim_var_glo2eqv            ! equivalent variables
378                          CALL lim_var_agg(1)             ! aggregate ice categories
379                          ! previous lead fraction and ice volume for flux calculations
380                          pfrld(:,:)   = 1._wp - at_i(:,:)
381                          phicif(:,:)  = vt_i(:,:)
382                          !
383                          CALL lim_var_bv                 ! bulk brine volume (diag)
384                          CALL lim_thd( kt )              ! Ice thermodynamics
385                          zcoef = rdt_ice /rday           !  Ice natural aging
386                          oa_i(:,:,:) = oa_i(:,:,:) + a_i(:,:,:) * zcoef
387                          CALL lim_var_glo2eqv            ! this CALL is maybe not necessary (Martin)
388         IF( ln_nicep )   CALL lim_prt_state( kt, jiindx, jjindx, 1, ' - ice thermodyn. - ' )   ! control print
389                          CALL lim_itd_th( kt )           !  Remap ice categories, lateral accretion  !
390                          CALL lim_var_agg( 1 )           ! requested by limupdate
391                          CALL lim_update2                ! Global variables update
392
393                          CALL lim_var_glo2eqv            ! equivalent variables (outputs)
394                          CALL lim_var_agg(2)             ! aggregate ice thickness categories
395         IF( ln_nicep )   CALL lim_prt_state( kt, jiindx, jjindx, 2, ' - Final state - ' )   ! control print
396         !
397                          CALL lim_sbc_flx( kt )     ! Update surface ocean mass, heat and salt fluxes
398         !
399         IF( ln_nicep )   CALL lim_prt_state( kt, jiindx, jjindx, 3, ' - Final state lim_sbc - ' )   ! control print
400         !
401         !                                           ! Diagnostics and outputs
402         IF (ln_limdiaout) CALL lim_diahsb
403!clem # if ! defined key_iomput
404                          CALL lim_wri( 1  )              ! Ice outputs
405!clem # endif
406         IF( kt == nit000 .AND. ln_rstart )   &
407            &             CALL iom_close( numrir )        ! clem: close input ice restart file
408         !
409         IF( lrst_ice )   CALL lim_rst_write( kt )        ! Ice restart file
410                          CALL lim_var_glo2eqv            ! ???
411         !
412         IF( ln_nicep )   CALL lim_ctl( kt )              ! alerts in case of model crash
413         !
414      ENDIF                                    ! End sea-ice time step only
415
416      !                                        !--------------------------!
417      !                                        !  at all ocean time step  !
418      !                                        !--------------------------!
419      !                                               
420      !                                              ! Update surface ocean stresses (only in ice-dynamic case)
421      !                                                   ! otherwise the atm.-ocean stresses are used everywhere
422      IF( ln_limdyn )     CALL lim_sbc_tau( kt, ub(:,:,1), vb(:,:,1) )  ! using before instantaneous surf. currents
423     
424!!gm   remark, the ocean-ice stress is not saved in ice diag call above .....  find a solution!!!
425      CALL wrk_dealloc( jpi,jpj,jpl, zalb_ice_os, zalb_ice_cs, zalb_ice )
426
427#if defined key_coupled
428 
429      IF ( ln_iceflx_ave .OR. ln_iceflx_linear ) &
430         &    CALL wrk_dealloc( jpi,jpj, ztem_ice_all, zalb_ice_all, z_qsr_ice_all, z_qns_ice_all, z_qla_ice_all, z_dqns_ice_all, z_dqla_ice_all)
431#endif
432      !
433      IF( nn_timing == 1 )  CALL timing_stop('sbc_ice_lim')
434      !
435   END SUBROUTINE sbc_ice_lim
436
437
438   SUBROUTINE lim_ctl( kt )
439      !!-----------------------------------------------------------------------
440      !!                   ***  ROUTINE lim_ctl ***
441      !!                 
442      !! ** Purpose :   Alerts in case of model crash
443      !!-------------------------------------------------------------------
444      INTEGER, INTENT(in) ::   kt      ! ocean time step
445      INTEGER  ::   ji, jj, jk,  jl   ! dummy loop indices
446      INTEGER  ::   inb_altests       ! number of alert tests (max 20)
447      INTEGER  ::   ialert_id         ! number of the current alert
448      REAL(wp) ::   ztmelts           ! ice layer melting point
449      CHARACTER (len=30), DIMENSION(20)      ::   cl_alname   ! name of alert
450      INTEGER           , DIMENSION(20)      ::   inb_alp     ! number of alerts positive
451      !!-------------------------------------------------------------------
452
453      inb_altests = 10
454      inb_alp(:)  =  0
455
456      ! Alert if incompatible volume and concentration
457      ialert_id = 2 ! reference number of this alert
458      cl_alname(ialert_id) = ' Incompat vol and con         '    ! name of the alert
459
460      DO jl = 1, jpl
461         DO jj = 1, jpj
462            DO ji = 1, jpi
463               IF(  v_i(ji,jj,jl) /= 0._wp   .AND.   a_i(ji,jj,jl) == 0._wp   ) THEN
464                  !WRITE(numout,*) ' ALERTE 2 :   Incompatible volume and concentration '
465                  !WRITE(numout,*) ' at_i     ', at_i(ji,jj)
466                  !WRITE(numout,*) ' Point - category', ji, jj, jl
467                  !WRITE(numout,*) ' a_i *** a_i_old ', a_i      (ji,jj,jl), old_a_i  (ji,jj,jl)
468                  !WRITE(numout,*) ' v_i *** v_i_old ', v_i      (ji,jj,jl), old_v_i  (ji,jj,jl)
469                  !WRITE(numout,*) ' d_a_i_thd/trp   ', d_a_i_thd(ji,jj,jl), d_a_i_trp(ji,jj,jl)
470                  !WRITE(numout,*) ' d_v_i_thd/trp   ', d_v_i_thd(ji,jj,jl), d_v_i_trp(ji,jj,jl)
471                  inb_alp(ialert_id) = inb_alp(ialert_id) + 1
472               ENDIF
473            END DO
474         END DO
475      END DO
476
477      ! Alerte if very thick ice
478      ialert_id = 3 ! reference number of this alert
479      cl_alname(ialert_id) = ' Very thick ice               ' ! name of the alert
480      jl = jpl 
481      DO jj = 1, jpj
482         DO ji = 1, jpi
483            IF(   ht_i(ji,jj,jl)  >  50._wp   ) THEN
484               !CALL lim_prt_state( kt, ji, jj, 2, ' ALERTE 3 :   Very thick ice ' )
485               inb_alp(ialert_id) = inb_alp(ialert_id) + 1
486            ENDIF
487         END DO
488      END DO
489
490      ! Alert if very fast ice
491      ialert_id = 4 ! reference number of this alert
492      cl_alname(ialert_id) = ' Very fast ice               ' ! name of the alert
493      DO jj = 1, jpj
494         DO ji = 1, jpi
495            IF(   MAX( ABS( u_ice(ji,jj) ), ABS( v_ice(ji,jj) ) ) > 1.5  .AND.  &
496               &  at_i(ji,jj) > 0._wp   ) THEN
497               !CALL lim_prt_state( kt, ji, jj, 1, ' ALERTE 4 :   Very fast ice ' )
498               !WRITE(numout,*) ' ice strength             : ', strength(ji,jj)
499               !WRITE(numout,*) ' oceanic stress utau      : ', utau(ji,jj)
500               !WRITE(numout,*) ' oceanic stress vtau      : ', vtau(ji,jj)
501               !WRITE(numout,*) ' sea-ice stress utau_ice  : ', utau_ice(ji,jj)
502               !WRITE(numout,*) ' sea-ice stress vtau_ice  : ', vtau_ice(ji,jj)
503               !WRITE(numout,*) ' oceanic speed u          : ', u_oce(ji,jj)
504               !WRITE(numout,*) ' oceanic speed v          : ', v_oce(ji,jj)
505               !WRITE(numout,*) ' sst                      : ', sst_m(ji,jj)
506               !WRITE(numout,*) ' sss                      : ', sss_m(ji,jj)
507               !WRITE(numout,*)
508               inb_alp(ialert_id) = inb_alp(ialert_id) + 1
509            ENDIF
510         END DO
511      END DO
512
513      ! Alert if there is ice on continents
514      ialert_id = 6 ! reference number of this alert
515      cl_alname(ialert_id) = ' Ice on continents           ' ! name of the alert
516      DO jj = 1, jpj
517         DO ji = 1, jpi
518            IF(   tms(ji,jj) <= 0._wp   .AND.   at_i(ji,jj) > 0._wp   ) THEN 
519               !CALL lim_prt_state( kt, ji, jj, 1, ' ALERTE 6 :   Ice on continents ' )
520               !WRITE(numout,*) ' masks s, u, v        : ', tms(ji,jj), tmu(ji,jj), tmv(ji,jj)
521               !WRITE(numout,*) ' sst                  : ', sst_m(ji,jj)
522               !WRITE(numout,*) ' sss                  : ', sss_m(ji,jj)
523               !WRITE(numout,*) ' at_i(ji,jj)          : ', at_i(ji,jj)
524               !WRITE(numout,*) ' v_ice(ji,jj)         : ', v_ice(ji,jj)
525               !WRITE(numout,*) ' v_ice(ji,jj-1)       : ', v_ice(ji,jj-1)
526               !WRITE(numout,*) ' u_ice(ji-1,jj)       : ', u_ice(ji-1,jj)
527               !WRITE(numout,*) ' u_ice(ji,jj)         : ', v_ice(ji,jj)
528               !
529               inb_alp(ialert_id) = inb_alp(ialert_id) + 1
530            ENDIF
531         END DO
532      END DO
533
534!
535!     ! Alert if very fresh ice
536      ialert_id = 7 ! reference number of this alert
537      cl_alname(ialert_id) = ' Very fresh ice               ' ! name of the alert
538      DO jl = 1, jpl
539         DO jj = 1, jpj
540            DO ji = 1, jpi
541               IF( sm_i(ji,jj,jl) < 0.1 .AND. a_i(ji,jj,jl) > 0._wp ) THEN
542!                 CALL lim_prt_state(kt,ji,jj,1, ' ALERTE 7 :   Very fresh ice ' )
543!                 WRITE(numout,*) ' sst                  : ', sst_m(ji,jj)
544!                 WRITE(numout,*) ' sss                  : ', sss_m(ji,jj)
545!                 WRITE(numout,*) ' s_i_newice           : ', s_i_newice(ji,jj,1:jpl)
546!                 WRITE(numout,*)
547                  inb_alp(ialert_id) = inb_alp(ialert_id) + 1
548               ENDIF
549            END DO
550         END DO
551      END DO
552!
553
554!     ! Alert if too old ice
555      ialert_id = 9 ! reference number of this alert
556      cl_alname(ialert_id) = ' Very old   ice               ' ! name of the alert
557      DO jl = 1, jpl
558         DO jj = 1, jpj
559            DO ji = 1, jpi
560               IF ( ( ( ABS( o_i(ji,jj,jl) ) > rdt_ice ) .OR. &
561                      ( ABS( o_i(ji,jj,jl) ) < 0._wp) ) .AND. &
562                             ( a_i(ji,jj,jl) > 0._wp ) ) THEN
563                  !CALL lim_prt_state( kt, ji, jj, 1, ' ALERTE 9 :   Wrong ice age ')
564                  inb_alp(ialert_id) = inb_alp(ialert_id) + 1
565               ENDIF
566            END DO
567         END DO
568      END DO
569 
570      ! Alert on salt flux
571      ialert_id = 5 ! reference number of this alert
572      cl_alname(ialert_id) = ' High salt flux               ' ! name of the alert
573      DO jj = 1, jpj
574         DO ji = 1, jpi
575            IF( ABS( sfx (ji,jj) ) .GT. 1.0e-2 ) THEN  ! = 1 psu/day for 1m ocean depth
576               !CALL lim_prt_state( kt, ji, jj, 3, ' ALERTE 5 :   High salt flux ' )
577               !DO jl = 1, jpl
578                  !WRITE(numout,*) ' Category no: ', jl
579                  !WRITE(numout,*) ' a_i        : ', a_i      (ji,jj,jl) , ' old_a_i    : ', old_a_i  (ji,jj,jl)   
580                  !WRITE(numout,*) ' d_a_i_trp  : ', d_a_i_trp(ji,jj,jl) , ' d_a_i_thd  : ', d_a_i_thd(ji,jj,jl)
581                  !WRITE(numout,*) ' v_i        : ', v_i      (ji,jj,jl) , ' old_v_i    : ', old_v_i  (ji,jj,jl)   
582                  !WRITE(numout,*) ' d_v_i_trp  : ', d_v_i_trp(ji,jj,jl) , ' d_v_i_thd  : ', d_v_i_thd(ji,jj,jl)
583                  !WRITE(numout,*) ' '
584               !END DO
585               inb_alp(ialert_id) = inb_alp(ialert_id) + 1
586            ENDIF
587         END DO
588      END DO
589
590      ! Alert if qns very big
591      ialert_id = 8 ! reference number of this alert
592      cl_alname(ialert_id) = ' fnsolar very big             ' ! name of the alert
593      DO jj = 1, jpj
594         DO ji = 1, jpi
595            IF( ABS( qns(ji,jj) ) > 1500._wp .AND. at_i(ji,jj) > 0._wp ) THEN
596               !
597               !WRITE(numout,*) ' ALERTE 8 :   Very high non-solar heat flux'
598               !WRITE(numout,*) ' ji, jj    : ', ji, jj
599               !WRITE(numout,*) ' qns       : ', qns(ji,jj)
600               !WRITE(numout,*) ' sst       : ', sst_m(ji,jj)
601               !WRITE(numout,*) ' sss       : ', sss_m(ji,jj)
602               !WRITE(numout,*) ' qcmif     : ', qcmif(ji,jj)
603               !WRITE(numout,*) ' qldif     : ', qldif(ji,jj)
604               !WRITE(numout,*) ' qcmif     : ', qcmif(ji,jj) / rdt_ice
605               !WRITE(numout,*) ' qldif     : ', qldif(ji,jj) / rdt_ice
606               !WRITE(numout,*) ' qfvbq     : ', qfvbq(ji,jj)
607               !WRITE(numout,*) ' qdtcn     : ', qdtcn(ji,jj)
608               !WRITE(numout,*) ' qfvbq / dt: ', qfvbq(ji,jj) / rdt_ice
609               !WRITE(numout,*) ' qdtcn / dt: ', qdtcn(ji,jj) / rdt_ice
610               !WRITE(numout,*) ' fdtcn     : ', fdtcn(ji,jj)
611               !WRITE(numout,*) ' fhmec     : ', fhmec(ji,jj)
612               !WRITE(numout,*) ' fheat_mec : ', fheat_mec(ji,jj)
613               !WRITE(numout,*) ' fheat_res : ', fheat_res(ji,jj)
614               !WRITE(numout,*) ' fhbri     : ', fhbri(ji,jj)
615               !
616               !CALL lim_prt_state( kt, ji, jj, 2, '   ')
617               inb_alp(ialert_id) = inb_alp(ialert_id) + 1
618               !
619            ENDIF
620         END DO
621      END DO
622      !+++++
623 
624      ! Alert if very warm ice
625      ialert_id = 10 ! reference number of this alert
626      cl_alname(ialert_id) = ' Very warm ice                ' ! name of the alert
627      inb_alp(ialert_id) = 0
628      DO jl = 1, jpl
629         DO jk = 1, nlay_i
630            DO jj = 1, jpj
631               DO ji = 1, jpi
632                  ztmelts    =  -tmut * s_i(ji,jj,jk,jl) + rtt
633                  IF( t_i(ji,jj,jk,jl) >= ztmelts  .AND.  v_i(ji,jj,jl) > 1.e-10   &
634                     &                             .AND.  a_i(ji,jj,jl) > 0._wp   ) THEN
635                     !WRITE(numout,*) ' ALERTE 10 :   Very warm ice'
636                     !WRITE(numout,*) ' ji, jj, jk, jl : ', ji, jj, jk, jl
637                     !WRITE(numout,*) ' t_i : ', t_i(ji,jj,jk,jl)
638                     !WRITE(numout,*) ' e_i : ', e_i(ji,jj,jk,jl)
639                     !WRITE(numout,*) ' s_i : ', s_i(ji,jj,jk,jl)
640                     !WRITE(numout,*) ' ztmelts : ', ztmelts
641                     inb_alp(ialert_id) = inb_alp(ialert_id) + 1
642                  ENDIF
643               END DO
644            END DO
645         END DO
646      END DO
647
648      ! sum of the alerts on all processors
649      IF( lk_mpp ) THEN
650         DO ialert_id = 1, inb_altests
651            CALL mpp_sum(inb_alp(ialert_id))
652         END DO
653      ENDIF
654
655      ! print alerts
656      IF( lwp ) THEN
657         ialert_id = 1                                 ! reference number of this alert
658         cl_alname(ialert_id) = ' NO alerte 1      '   ! name of the alert
659         WRITE(numout,*) ' time step ',kt
660         WRITE(numout,*) ' All alerts at the end of ice model '
661         DO ialert_id = 1, inb_altests
662            WRITE(numout,*) ialert_id, cl_alname(ialert_id)//' : ', inb_alp(ialert_id), ' times ! '
663         END DO
664      ENDIF
665     !
666   END SUBROUTINE lim_ctl
667 
668   
669   SUBROUTINE lim_prt_state( kt, ki, kj, kn, cd1 )
670      !!-----------------------------------------------------------------------
671      !!                   ***  ROUTINE lim_prt_state ***
672      !!                 
673      !! ** Purpose :   Writes global ice state on the (i,j) point
674      !!                in ocean.ouput
675      !!                3 possibilities exist
676      !!                n = 1/-1 -> simple ice state (plus Mechanical Check if -1)
677      !!                n = 2    -> exhaustive state
678      !!                n = 3    -> ice/ocean salt fluxes
679      !!
680      !! ** input   :   point coordinates (i,j)
681      !!                n : number of the option
682      !!-------------------------------------------------------------------
683      INTEGER         , INTENT(in) ::   kt      ! ocean time step
684      INTEGER         , INTENT(in) ::   ki, kj, kn    ! ocean gridpoint indices
685      CHARACTER(len=*), INTENT(in) ::   cd1           !
686      !!
687      INTEGER :: jl, ji, jj
688      !!-------------------------------------------------------------------
689
690      DO ji = mi0(ki), mi1(ki)
691         DO jj = mj0(kj), mj1(kj)
692
693            WRITE(numout,*) ' time step ',kt,' ',cd1             ! print title
694
695            !----------------
696            !  Simple state
697            !----------------
698           
699            IF ( kn == 1 .OR. kn == -1 ) THEN
700               WRITE(numout,*) ' lim_prt_state - Point : ',ji,jj
701               WRITE(numout,*) ' ~~~~~~~~~~~~~~ '
702               WRITE(numout,*) ' Simple state '
703               WRITE(numout,*) ' masks s,u,v   : ', tms(ji,jj), tmu(ji,jj), tmv(ji,jj)
704               WRITE(numout,*) ' lat - long    : ', gphit(ji,jj), glamt(ji,jj)
705               WRITE(numout,*) ' Time step     : ', numit
706               WRITE(numout,*) ' - Ice drift   '
707               WRITE(numout,*) '   ~~~~~~~~~~~ '
708               WRITE(numout,*) ' u_ice(i-1,j)  : ', u_ice(ji-1,jj)
709               WRITE(numout,*) ' u_ice(i  ,j)  : ', u_ice(ji,jj)
710               WRITE(numout,*) ' v_ice(i  ,j-1): ', v_ice(ji,jj-1)
711               WRITE(numout,*) ' v_ice(i  ,j)  : ', v_ice(ji,jj)
712               WRITE(numout,*) ' strength      : ', strength(ji,jj)
713               WRITE(numout,*)
714               WRITE(numout,*) ' - Cell values '
715               WRITE(numout,*) '   ~~~~~~~~~~~ '
716               WRITE(numout,*) ' cell area     : ', area(ji,jj)
717               WRITE(numout,*) ' at_i          : ', at_i(ji,jj)       
718               WRITE(numout,*) ' vt_i          : ', vt_i(ji,jj)       
719               WRITE(numout,*) ' vt_s          : ', vt_s(ji,jj)       
720               DO jl = 1, jpl
721                  WRITE(numout,*) ' - Category (', jl,')'
722                  WRITE(numout,*) ' a_i           : ', a_i(ji,jj,jl)
723                  WRITE(numout,*) ' ht_i          : ', ht_i(ji,jj,jl)
724                  WRITE(numout,*) ' ht_s          : ', ht_s(ji,jj,jl)
725                  WRITE(numout,*) ' v_i           : ', v_i(ji,jj,jl)
726                  WRITE(numout,*) ' v_s           : ', v_s(ji,jj,jl)
727                  WRITE(numout,*) ' e_s           : ', e_s(ji,jj,1,jl)/1.0e9
728                  WRITE(numout,*) ' e_i           : ', e_i(ji,jj,1:nlay_i,jl)/1.0e9
729                  WRITE(numout,*) ' t_su          : ', t_su(ji,jj,jl)
730                  WRITE(numout,*) ' t_snow        : ', t_s(ji,jj,1,jl)
731                  WRITE(numout,*) ' t_i           : ', t_i(ji,jj,1:nlay_i,jl)
732                  WRITE(numout,*) ' sm_i          : ', sm_i(ji,jj,jl)
733                  WRITE(numout,*) ' smv_i         : ', smv_i(ji,jj,jl)
734                  WRITE(numout,*)
735               END DO
736            ENDIF
737            IF( kn == -1 ) THEN
738               WRITE(numout,*) ' Mechanical Check ************** '
739               WRITE(numout,*) ' Check what means ice divergence '
740               WRITE(numout,*) ' Total ice concentration ', at_i (ji,jj)
741               WRITE(numout,*) ' Total lead fraction     ', ato_i(ji,jj)
742               WRITE(numout,*) ' Sum of both             ', ato_i(ji,jj) + at_i(ji,jj)
743               WRITE(numout,*) ' Sum of both minus 1     ', ato_i(ji,jj) + at_i(ji,jj) - 1.00
744            ENDIF
745           
746
747            !--------------------
748            !  Exhaustive state
749            !--------------------
750           
751            IF ( kn .EQ. 2 ) THEN
752               WRITE(numout,*) ' lim_prt_state - Point : ',ji,jj
753               WRITE(numout,*) ' ~~~~~~~~~~~~~~ '
754               WRITE(numout,*) ' Exhaustive state '
755               WRITE(numout,*) ' lat - long ', gphit(ji,jj), glamt(ji,jj)
756               WRITE(numout,*) ' Time step ', numit
757               WRITE(numout,*) 
758               WRITE(numout,*) ' - Cell values '
759               WRITE(numout,*) '   ~~~~~~~~~~~ '
760               WRITE(numout,*) ' cell area     : ', area(ji,jj)
761               WRITE(numout,*) ' at_i          : ', at_i(ji,jj)       
762               WRITE(numout,*) ' vt_i          : ', vt_i(ji,jj)       
763               WRITE(numout,*) ' vt_s          : ', vt_s(ji,jj)       
764               WRITE(numout,*) ' u_ice(i-1,j)  : ', u_ice(ji-1,jj)
765               WRITE(numout,*) ' u_ice(i  ,j)  : ', u_ice(ji,jj)
766               WRITE(numout,*) ' v_ice(i  ,j-1): ', v_ice(ji,jj-1)
767               WRITE(numout,*) ' v_ice(i  ,j)  : ', v_ice(ji,jj)
768               WRITE(numout,*) ' strength      : ', strength(ji,jj)
769               WRITE(numout,*) ' d_u_ice_dyn   : ', d_u_ice_dyn(ji,jj), ' d_v_ice_dyn   : ', d_v_ice_dyn(ji,jj)
770               WRITE(numout,*) ' old_u_ice     : ', old_u_ice(ji,jj)  , ' old_v_ice     : ', old_v_ice(ji,jj) 
771               WRITE(numout,*)
772               
773               DO jl = 1, jpl
774                  WRITE(numout,*) ' - Category (',jl,')'
775                  WRITE(numout,*) '   ~~~~~~~~         ' 
776                  WRITE(numout,*) ' ht_i       : ', ht_i(ji,jj,jl)             , ' ht_s       : ', ht_s(ji,jj,jl)
777                  WRITE(numout,*) ' t_i        : ', t_i(ji,jj,1:nlay_i,jl)
778                  WRITE(numout,*) ' t_su       : ', t_su(ji,jj,jl)             , ' t_s        : ', t_s(ji,jj,1,jl)
779                  WRITE(numout,*) ' sm_i       : ', sm_i(ji,jj,jl)             , ' o_i        : ', o_i(ji,jj,jl)
780                  WRITE(numout,*) ' a_i        : ', a_i(ji,jj,jl)              , ' old_a_i    : ', old_a_i(ji,jj,jl)   
781                  WRITE(numout,*) ' d_a_i_trp  : ', d_a_i_trp(ji,jj,jl)        , ' d_a_i_thd  : ', d_a_i_thd(ji,jj,jl) 
782                  WRITE(numout,*) ' v_i        : ', v_i(ji,jj,jl)              , ' old_v_i    : ', old_v_i(ji,jj,jl)   
783                  WRITE(numout,*) ' d_v_i_trp  : ', d_v_i_trp(ji,jj,jl)        , ' d_v_i_thd  : ', d_v_i_thd(ji,jj,jl) 
784                  WRITE(numout,*) ' v_s        : ', v_s(ji,jj,jl)              , ' old_v_s    : ', old_v_s(ji,jj,jl) 
785                  WRITE(numout,*) ' d_v_s_trp  : ', d_v_s_trp(ji,jj,jl)        , ' d_v_s_thd  : ', d_v_s_thd(ji,jj,jl)
786                  WRITE(numout,*) ' e_i1       : ', e_i(ji,jj,1,jl)/1.0e9      , ' old_ei1    : ', old_e_i(ji,jj,1,jl)/1.0e9 
787                  WRITE(numout,*) ' de_i1_trp  : ', d_e_i_trp(ji,jj,1,jl)/1.0e9, ' de_i1_thd  : ', d_e_i_thd(ji,jj,1,jl)/1.0e9
788                  WRITE(numout,*) ' e_i2       : ', e_i(ji,jj,2,jl)/1.0e9      , ' old_ei2    : ', old_e_i(ji,jj,2,jl)/1.0e9 
789                  WRITE(numout,*) ' de_i2_trp  : ', d_e_i_trp(ji,jj,2,jl)/1.0e9, ' de_i2_thd  : ', d_e_i_thd(ji,jj,2,jl)/1.0e9
790                  WRITE(numout,*) ' e_snow     : ', e_s(ji,jj,1,jl)            , ' old_e_snow : ', old_e_s(ji,jj,1,jl) 
791                  WRITE(numout,*) ' d_e_s_trp  : ', d_e_s_trp(ji,jj,1,jl)      , ' d_e_s_thd  : ', d_e_s_thd(ji,jj,1,jl)
792                  WRITE(numout,*) ' smv_i      : ', smv_i(ji,jj,jl)            , ' old_smv_i  : ', old_smv_i(ji,jj,jl)   
793                  WRITE(numout,*) ' d_smv_i_trp: ', d_smv_i_trp(ji,jj,jl)      , ' d_smv_i_thd: ', d_smv_i_thd(ji,jj,jl) 
794                  WRITE(numout,*) ' oa_i       : ', oa_i(ji,jj,jl)             , ' old_oa_i   : ', old_oa_i(ji,jj,jl)
795                  WRITE(numout,*) ' d_oa_i_trp : ', d_oa_i_trp(ji,jj,jl)       , ' d_oa_i_thd : ', d_oa_i_thd(ji,jj,jl)
796               END DO !jl
797               
798               WRITE(numout,*)
799               WRITE(numout,*) ' - Heat / FW fluxes '
800               WRITE(numout,*) '   ~~~~~~~~~~~~~~~~ '
801               WRITE(numout,*) ' emp        : ', emp      (ji,jj)
802               WRITE(numout,*) ' sfx        : ', sfx      (ji,jj)
803               WRITE(numout,*) ' sfx_thd    : ', sfx_thd(ji,jj)
804               WRITE(numout,*) ' sfx_bri    : ', sfx_bri  (ji,jj)
805               WRITE(numout,*) ' sfx_mec    : ', sfx_mec  (ji,jj)
806               WRITE(numout,*) ' sfx_res    : ', sfx_res(ji,jj)
807               WRITE(numout,*) ' fmmec      : ', fmmec    (ji,jj)
808               WRITE(numout,*) ' fhmec      : ', fhmec    (ji,jj)
809               WRITE(numout,*) ' fhbri      : ', fhbri    (ji,jj)
810               WRITE(numout,*) 
811               WRITE(numout,*) ' sst        : ', sst_m(ji,jj) 
812               WRITE(numout,*) ' sss        : ', sss_m(ji,jj) 
813               WRITE(numout,*) 
814               WRITE(numout,*) ' - Stresses '
815               WRITE(numout,*) '   ~~~~~~~~ '
816               WRITE(numout,*) ' utau_ice   : ', utau_ice(ji,jj) 
817               WRITE(numout,*) ' vtau_ice   : ', vtau_ice(ji,jj)
818               WRITE(numout,*) ' utau       : ', utau    (ji,jj) 
819               WRITE(numout,*) ' vtau       : ', vtau    (ji,jj)
820               WRITE(numout,*) ' oc. vel. u : ', u_oce   (ji,jj)
821               WRITE(numout,*) ' oc. vel. v : ', v_oce   (ji,jj)
822            ENDIF
823           
824            !---------------------
825            ! Salt / heat fluxes
826            !---------------------
827           
828            IF ( kn .EQ. 3 ) THEN
829               WRITE(numout,*) ' lim_prt_state - Point : ',ji,jj
830               WRITE(numout,*) ' ~~~~~~~~~~~~~~ '
831               WRITE(numout,*) ' - Salt / Heat Fluxes '
832               WRITE(numout,*) '   ~~~~~~~~~~~~~~~~ '
833               WRITE(numout,*) ' lat - long ', gphit(ji,jj), glamt(ji,jj)
834               WRITE(numout,*) ' Time step ', numit
835               WRITE(numout,*)
836               WRITE(numout,*) ' - Heat fluxes at bottom interface ***'
837               WRITE(numout,*) ' qsr       : ', qsr(ji,jj)
838               WRITE(numout,*) ' qns       : ', qns(ji,jj)
839               WRITE(numout,*) ' fdtcn     : ', fdtcn(ji,jj)
840               WRITE(numout,*) ' qcmif     : ', qcmif(ji,jj) * r1_rdtice
841               WRITE(numout,*) ' qldif     : ', qldif(ji,jj) * r1_rdtice
842               WRITE(numout,*)
843               WRITE(numout,*) ' - Salt fluxes at bottom interface ***'
844               WRITE(numout,*) ' emp       : ', emp    (ji,jj)
845               WRITE(numout,*) ' sfx_bri   : ', sfx_bri(ji,jj)
846               WRITE(numout,*) ' sfx       : ', sfx    (ji,jj)
847               WRITE(numout,*) ' sfx_res   : ', sfx_res(ji,jj)
848               WRITE(numout,*) ' sfx_mec   : ', sfx_mec(ji,jj)
849               WRITE(numout,*) ' - Heat fluxes at bottom interface ***'
850               WRITE(numout,*) ' fheat_res : ', fheat_res(ji,jj)
851               WRITE(numout,*)
852               WRITE(numout,*) ' - Momentum fluxes '
853               WRITE(numout,*) ' utau      : ', utau(ji,jj) 
854               WRITE(numout,*) ' vtau      : ', vtau(ji,jj)
855            ENDIF
856            WRITE(numout,*) ' '
857            !
858         END DO
859      END DO
860
861   END SUBROUTINE lim_prt_state
862
863#else
864   !!----------------------------------------------------------------------
865   !!   Default option           Dummy module      NO LIM 3.0 sea-ice model
866   !!----------------------------------------------------------------------
867CONTAINS
868   SUBROUTINE sbc_ice_lim ( kt, kblk )     ! Dummy routine
869      WRITE(*,*) 'sbc_ice_lim: You should not have seen this print! error?', kt, kblk
870   END SUBROUTINE sbc_ice_lim
871#endif
872
873   !!======================================================================
874END MODULE sbcice_lim
Note: See TracBrowser for help on using the repository browser.