New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limtrp_2.F90 in branches/nemo_v3_3_beta/NEMOGCM/NEMO/LIM_SRC_2 – NEMO

source: branches/nemo_v3_3_beta/NEMOGCM/NEMO/LIM_SRC_2/limtrp_2.F90 @ 2370

Last change on this file since 2370 was 2370, checked in by gm, 13 years ago

v3.3beta: ice-ocean stress at kt with VP & EVP (LIM-2 and -3)

  • Property svn:keywords set to Id
File size: 16.5 KB
Line 
1MODULE limtrp_2
2   !!======================================================================
3   !!                       ***  MODULE limtrp_2   ***
4   !! LIM 2.0 transport ice model : sea-ice advection/diffusion
5   !!======================================================================
6   !! History :  LIM  !  2000-01 (UCL)  Original code
7   !!            2.0  !  2001-05 (G. Madec, R. Hordoir) opa norm
8   !!             -   !  2004-01 (G. Madec, C. Ethe)  F90, mpp
9   !!            3.3  !  2009-05  (G. Garric, C. Bricaud) addition of the lim2_evp case
10   !!----------------------------------------------------------------------
11#if defined key_lim2
12   !!----------------------------------------------------------------------
13   !!   'key_lim2' :                                  LIM 2.0 sea-ice model
14   !!----------------------------------------------------------------------
15   !!   lim_trp_2      : advection/diffusion process of sea ice
16   !!   lim_trp_init_2 : initialization and namelist read
17   !!----------------------------------------------------------------------
18   USE phycst          ! physical constant
19   USE sbc_oce         ! ocean surface boundary condition
20   USE dom_oce         ! ocean domain
21   USE in_out_manager  ! I/O manager
22   USE dom_ice_2       ! LIM-2 domain
23   USE ice_2           ! LIM-2 variables
24   USE limistate_2     ! LIM-2 initial state
25   USE limadv_2        ! LIM-2 advection
26   USE limhdf_2        ! LIM-2 horizontal diffusion
27   USE lbclnk          ! lateral boundary conditions -- MPP exchanges
28   USE lib_mpp         ! MPP library
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   lim_trp_2   ! called by sbc_ice_lim_2
34
35   REAL(wp), PUBLIC ::   bound  = 0.e0          !: boundary condit. (0.0 no-slip, 1.0 free-slip)
36
37   REAL(wp)  ::   epsi06 = 1.e-06   ! constant values
38   REAL(wp)  ::   epsi03 = 1.e-03 
39   REAL(wp)  ::   epsi16 = 1.e-16 
40   REAL(wp)  ::   rzero  = 0.e0   
41   REAL(wp)  ::   rone   = 1.e0
42
43   !! * Substitution
44#  include "vectopt_loop_substitute.h90"
45   !!----------------------------------------------------------------------
46   !! NEMO/LIM2 3.3 , UCL - NEMO Consortium (2010)
47   !! $Id$
48   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
49   !!----------------------------------------------------------------------
50
51CONTAINS
52
53   SUBROUTINE lim_trp_2( kt )
54      !!-------------------------------------------------------------------
55      !!                   ***  ROUTINE lim_trp_2 ***
56      !!                   
57      !! ** purpose : advection/diffusion process of sea ice
58      !!
59      !! ** method  : variables included in the process are scalar,   
60      !!     other values are considered as second order.
61      !!     For advection, a second order Prather scheme is used. 
62      !!
63      !! ** action :
64      !!---------------------------------------------------------------------
65      INTEGER, INTENT(in) ::   kt     ! number of iteration
66      !!
67      INTEGER  ::   ji, jj, jk   ! dummy loop indices
68      INTEGER  ::   initad       ! number of sub-timestep for the advection
69      REAL(wp) ::   zindb  , zindsn , zindic, zacrith   ! local scalars
70      REAL(wp) ::   zusvosn, zusvoic, zignm , zindhe    !   -      -
71      REAL(wp) ::   zvbord , zcfl   , zusnit            !   -      -
72      REAL(wp) ::   zrtt   , ztsn   , ztic1 , ztic2     !   -      -
73      REAL(wp), DIMENSION(jpi,jpj)  ::   zui_u , zvi_v , zsm             ! 2D workspace
74      REAL(wp), DIMENSION(jpi,jpj)  ::   zs0ice, zs0sn , zs0a            !  -      -
75      REAL(wp), DIMENSION(jpi,jpj)  ::   zs0c0 , zs0c1 , zs0c2 , zs0st   !  -      -
76      !---------------------------------------------------------------------
77
78      IF( kt == nit000  )   CALL lim_trp_init_2      ! Initialization (first time-step only)
79
80      zsm(:,:) = area(:,:)
81     
82      IF( ln_limdyn ) THEN
83         !-------------------------------------!
84         !   Advection of sea ice properties   !
85         !-------------------------------------!
86
87         ! ice velocities at ocean U- and V-points (zui_u,zvi_v)
88         ! ---------------------------------------
89         IF( lk_lim2_vp ) THEN      ! VP rheology : B-grid sea-ice dynamics (I-point ice velocity)
90            zvbord = 1._wp + ( 1._wp - bound )      ! zvbord=2 no-slip, =0 free slip boundary conditions       
91            DO jj = 1, jpjm1
92               DO ji = 1, jpim1   ! NO vector opt.
93                  zui_u(ji,jj) = ( u_ice(ji+1,jj) + u_ice(ji+1,jj+1) ) / ( MAX( tmu(ji+1,jj)+tmu(ji+1,jj+1), zvbord ) )
94                  zvi_v(ji,jj) = ( v_ice(ji,jj+1) + v_ice(ji+1,jj+1) ) / ( MAX( tmu(ji,jj+1)+tmu(ji+1,jj+1), zvbord ) )
95               END DO
96            END DO
97            CALL lbc_lnk( zui_u, 'U', -1. )   ;   CALL lbc_lnk( zvi_v, 'V', -1. )      ! Lateral boundary conditions
98            !
99         ELSE                       ! EVP rheology : C-grid sea-ice dynamics (u- & v-points ice velocity)
100            zui_u(:,:) = u_ice(:,:)      ! EVP rheology: ice (u,v) at u- and v-points
101            zvi_v(:,:) = v_ice(:,:)
102         ENDIF
103
104         ! CFL test for stability
105         ! ----------------------
106         zcfl  = 0._wp
107         zcfl  = MAX( zcfl, MAXVAL( ABS( zui_u(1:jpim1, :     ) ) * rdt_ice / e1u(1:jpim1, :     ) ) )
108         zcfl  = MAX( zcfl, MAXVAL( ABS( zvi_v( :     ,1:jpjm1) ) * rdt_ice / e2v( :     ,1:jpjm1) ) )
109         !
110         IF(lk_mpp)   CALL mpp_max( zcfl )
111         !
112         IF( zcfl > 0.5 .AND. lwp )   WRITE(numout,*) 'lim_trp_2 : violation of cfl criterion the ',nday,'th day, cfl = ', zcfl
113
114         ! content of properties
115         ! ---------------------
116         zs0sn (:,:) =  hsnm(:,:)              * area  (:,:)  ! Snow volume.
117         zs0ice(:,:) =  hicm(:,:)              * area  (:,:)  ! Ice volume.
118         zs0a  (:,:) =  ( 1.0 - frld(:,:) )    * area  (:,:)  ! Surface covered by ice.
119         zs0c0 (:,:) =  tbif(:,:,1) / rt0_snow * zs0sn (:,:)  ! Heat content of the snow layer.
120         zs0c1 (:,:) =  tbif(:,:,2) / rt0_ice  * zs0ice(:,:)  ! Heat content of the first ice layer.
121         zs0c2 (:,:) =  tbif(:,:,3) / rt0_ice  * zs0ice(:,:)  ! Heat content of the second ice layer.
122         zs0st (:,:) =  qstoif(:,:) / xlic     * zs0a  (:,:)  ! Heat reservoir for brine pockets.
123         
124 
125         ! Advection (Prather scheme)
126         ! ---------
127         initad = 1 + INT( MAX( rzero, SIGN( rone, zcfl-0.5 ) ) )   ! If ice drift field is too fast,         
128         zusnit = 1.0 / REAL( initad )                              ! split the ice time step in two
129         !
130         IF( MOD( ( kt - 1) / nn_fsbc , 2 ) == 0) THEN        !==  odd ice time step:  adv_x then adv_y  ==!
131            DO jk = 1, initad
132               CALL lim_adv_x_2( zusnit, zui_u, rone , zsm, zs0ice, sxice, sxxice, syice, syyice, sxyice )
133               CALL lim_adv_y_2( zusnit, zvi_v, rzero, zsm, zs0ice, sxice, sxxice, syice, syyice, sxyice )
134               CALL lim_adv_x_2( zusnit, zui_u, rone , zsm, zs0sn , sxsn , sxxsn , sysn , syysn , sxysn  )
135               CALL lim_adv_y_2( zusnit, zvi_v, rzero, zsm, zs0sn , sxsn , sxxsn , sysn , syysn , sxysn  )
136               CALL lim_adv_x_2( zusnit, zui_u, rone , zsm, zs0a  , sxa  , sxxa  , sya  , syya  , sxya   )
137               CALL lim_adv_y_2( zusnit, zvi_v, rzero, zsm, zs0a  , sxa  , sxxa  , sya  , syya  , sxya   )
138               CALL lim_adv_x_2( zusnit, zui_u, rone , zsm, zs0c0 , sxc0 , sxxc0 , syc0 , syyc0 , sxyc0  )
139               CALL lim_adv_y_2( zusnit, zvi_v, rzero, zsm, zs0c0 , sxc0 , sxxc0 , syc0 , syyc0 , sxyc0  )
140               CALL lim_adv_x_2( zusnit, zui_u, rone , zsm, zs0c1 , sxc1 , sxxc1 , syc1 , syyc1 , sxyc1  )
141               CALL lim_adv_y_2( zusnit, zvi_v, rzero, zsm, zs0c1 , sxc1 , sxxc1 , syc1 , syyc1 , sxyc1  )
142               CALL lim_adv_x_2( zusnit, zui_u, rone , zsm, zs0c2 , sxc2 , sxxc2 , syc2 , syyc2 , sxyc2  )
143               CALL lim_adv_y_2( zusnit, zvi_v, rzero, zsm, zs0c2 , sxc2 , sxxc2 , syc2 , syyc2 , sxyc2  )
144               CALL lim_adv_x_2( zusnit, zui_u, rone , zsm, zs0st , sxst , sxxst , syst , syyst , sxyst  )
145               CALL lim_adv_y_2( zusnit, zvi_v, rzero, zsm, zs0st , sxst , sxxst , syst , syyst , sxyst  )
146            END DO
147         ELSE                                                 !==  even ice time step:  adv_x then adv_y  ==!
148            DO jk = 1, initad
149               CALL lim_adv_y_2( zusnit, zvi_v, rone , zsm, zs0ice, sxice, sxxice, syice, syyice, sxyice )
150               CALL lim_adv_x_2( zusnit, zui_u, rzero, zsm, zs0ice, sxice, sxxice, syice, syyice, sxyice )
151               CALL lim_adv_y_2( zusnit, zvi_v, rone , zsm, zs0sn , sxsn , sxxsn , sysn , syysn , sxysn  )
152               CALL lim_adv_x_2( zusnit, zui_u, rzero, zsm, zs0sn , sxsn , sxxsn , sysn , syysn , sxysn  )
153               CALL lim_adv_y_2( zusnit, zvi_v, rone , zsm, zs0a  , sxa  , sxxa  , sya  , syya  , sxya   )
154               CALL lim_adv_x_2( zusnit, zui_u, rzero, zsm, zs0a  , sxa  , sxxa  , sya  , syya  , sxya   )
155               CALL lim_adv_y_2( zusnit, zvi_v, rone , zsm, zs0c0 , sxc0 , sxxc0 , syc0 , syyc0 , sxyc0  )
156               CALL lim_adv_x_2( zusnit, zui_u, rzero, zsm, zs0c0 , sxc0 , sxxc0 , syc0 , syyc0 , sxyc0  )
157               CALL lim_adv_y_2( zusnit, zvi_v, rone , zsm, zs0c1 , sxc1 , sxxc1 , syc1 , syyc1 , sxyc1  )
158               CALL lim_adv_x_2( zusnit, zui_u, rzero, zsm, zs0c1 , sxc1 , sxxc1 , syc1 , syyc1 , sxyc1  )
159               CALL lim_adv_y_2( zusnit, zvi_v, rone , zsm, zs0c2 , sxc2 , sxxc2 , syc2 , syyc2 , sxyc2  )
160               CALL lim_adv_x_2( zusnit, zui_u, rzero, zsm, zs0c2 , sxc2 , sxxc2 , syc2 , syyc2 , sxyc2  )
161               CALL lim_adv_y_2( zusnit, zvi_v, rone , zsm, zs0st , sxst , sxxst , syst , syyst , sxyst  )
162               CALL lim_adv_x_2( zusnit, zui_u, rzero, zsm, zs0st , sxst , sxxst , syst , syyst , sxyst  )
163            END DO
164         ENDIF
165                       
166         ! recover the properties from their contents
167         ! ------------------------------------------
168!!gm Define in limmsh one for all area = 1 /area  (CPU time saved !)
169         zs0ice(:,:) = zs0ice(:,:) / area(:,:)
170         zs0sn (:,:) = zs0sn (:,:) / area(:,:)
171         zs0a  (:,:) = zs0a  (:,:) / area(:,:)
172         zs0c0 (:,:) = zs0c0 (:,:) / area(:,:)
173         zs0c1 (:,:) = zs0c1 (:,:) / area(:,:)
174         zs0c2 (:,:) = zs0c2 (:,:) / area(:,:)
175         zs0st (:,:) = zs0st (:,:) / area(:,:)
176
177
178         !-------------------------------------!
179         !   Diffusion of sea ice properties   !
180         !-------------------------------------!
181
182         ! Masked eddy diffusivity coefficient at ocean U- and V-points
183         ! ------------------------------------------------------------
184         DO jj = 1, jpjm1          ! NB: has not to be defined on jpj line and jpi row
185            DO ji = 1 , fs_jpim1   ! vector opt.
186               pahu(ji,jj) = ( 1.0 - MAX( rzero, SIGN( rone, -zs0a(ji  ,jj) ) ) )   &
187                  &        * ( 1.0 - MAX( rzero, SIGN( rone, -zs0a(ji+1,jj) ) ) ) * ahiu(ji,jj)
188               pahv(ji,jj) = ( 1.0 - MAX( rzero, SIGN( rone, -zs0a(ji,jj  ) ) ) )   &
189                  &        * ( 1.0 - MAX( rzero, SIGN( rone,- zs0a(ji,jj+1) ) ) ) * ahiv(ji,jj)
190            END DO
191         END DO
192!!gm more readable coding: (and avoid an error in F90 with sign of zero)
193!        DO jj = 1, jpjm1          ! NB: has not to be defined on jpj line and jpi row
194!           DO ji = 1 , fs_jpim1   ! vector opt.
195!              IF( MIN( zs0a(ji,jj) , zs0a(ji+1,jj) ) == 0.e0 )   pahu(ji,jj) = 0._wp
196!              IF( MIN( zs0a(ji,jj) , zs0a(ji,jj+1) ) == 0.e0 )   pahv(ji,jj) = 0._wp
197!           END DO
198!        END DO
199!!gm end
200
201         ! diffusion
202         ! ---------
203         CALL lim_hdf_2( zs0ice )
204         CALL lim_hdf_2( zs0sn  )
205         CALL lim_hdf_2( zs0a   )
206         CALL lim_hdf_2( zs0c0  )
207         CALL lim_hdf_2( zs0c1  )
208         CALL lim_hdf_2( zs0c2  )
209         CALL lim_hdf_2( zs0st  )
210
211!!gm see comment this can be skipped
212         zs0ice(:,:) = MAX( rzero, zs0ice(:,:) * area(:,:) )    !!bug:  useless
213         zs0sn (:,:) = MAX( rzero, zs0sn (:,:) * area(:,:) )    !!bug:  cf /area  just below
214         zs0a  (:,:) = MAX( rzero, zs0a  (:,:) * area(:,:) )    !! caution: the suppression of the 2 changes
215         zs0c0 (:,:) = MAX( rzero, zs0c0 (:,:) * area(:,:) )    !! the last digit of the results
216         zs0c1 (:,:) = MAX( rzero, zs0c1 (:,:) * area(:,:) )
217         zs0c2 (:,:) = MAX( rzero, zs0c2 (:,:) * area(:,:) )
218         zs0st (:,:) = MAX( rzero, zs0st (:,:) * area(:,:) )
219
220
221         !-------------------------------------------------------------------!
222         !   Updating and limitation of sea ice properties after transport   !
223         !-------------------------------------------------------------------!
224         DO jj = 1, jpj
225            zindhe = MAX( 0.e0, SIGN( 1.e0, fcor(1,jj) ) )              ! = 0 for SH, =1 for NH
226            DO ji = 1, jpi
227               !
228               ! Recover mean values over the grid squares.
229               zs0sn (ji,jj) = MAX( rzero, zs0sn (ji,jj)/area(ji,jj) )
230               zs0ice(ji,jj) = MAX( rzero, zs0ice(ji,jj)/area(ji,jj) )
231               zs0a  (ji,jj) = MAX( rzero, zs0a  (ji,jj)/area(ji,jj) )
232               zs0c0 (ji,jj) = MAX( rzero, zs0c0 (ji,jj)/area(ji,jj) )
233               zs0c1 (ji,jj) = MAX( rzero, zs0c1 (ji,jj)/area(ji,jj) )
234               zs0c2 (ji,jj) = MAX( rzero, zs0c2 (ji,jj)/area(ji,jj) )
235               zs0st (ji,jj) = MAX( rzero, zs0st (ji,jj)/area(ji,jj) )
236
237               ! Recover in situ values.
238               zindb         = MAX( rzero, SIGN( rone, zs0a(ji,jj) - epsi06 ) )
239               zacrith       = 1.0 - ( zindhe * acrit(1) + ( 1.0 - zindhe ) * acrit(2) )
240               zs0a (ji,jj)  = zindb * MIN( zs0a(ji,jj), zacrith )
241               hsnif(ji,jj)  = zindb * ( zs0sn(ji,jj) /MAX( zs0a(ji,jj), epsi16 ) )
242               hicif(ji,jj)  = zindb * ( zs0ice(ji,jj)/MAX( zs0a(ji,jj), epsi16 ) )
243               zindsn        = MAX( rzero, SIGN( rone, hsnif(ji,jj) - epsi06 ) )
244               zindic        = MAX( rzero, SIGN( rone, hicif(ji,jj) - epsi03 ) )
245               zindb         = MAX( zindsn, zindic )
246               zs0a (ji,jj)  = zindb * zs0a(ji,jj)
247               frld (ji,jj)  = 1.0 - zs0a(ji,jj)
248               hsnif(ji,jj)  = zindsn * hsnif(ji,jj)
249               hicif(ji,jj)  = zindic * hicif(ji,jj)
250               zusvosn       = 1.0/MAX( hsnif(ji,jj) * zs0a(ji,jj), epsi16 )
251               zusvoic       = 1.0/MAX( hicif(ji,jj) * zs0a(ji,jj), epsi16 )
252               zignm         = MAX( rzero,  SIGN( rone, hsndif - hsnif(ji,jj) ) )
253               zrtt          = 173.15 * rone 
254               ztsn          =          zignm   * tbif(ji,jj,1)  &
255                              + ( 1.0 - zignm ) * MIN( MAX( zrtt, rt0_snow * zusvosn * zs0c0(ji,jj)) , tfu(ji,jj) ) 
256               ztic1          = MIN( MAX( zrtt, rt0_ice * zusvoic * zs0c1(ji,jj) ) , tfu(ji,jj) )
257               ztic2          = MIN( MAX( zrtt, rt0_ice * zusvoic * zs0c2(ji,jj) ) , tfu(ji,jj) )
258 
259               tbif(ji,jj,1) = zindsn * ztsn  + ( 1.0 - zindsn ) * tfu(ji,jj)               
260               tbif(ji,jj,2) = zindic * ztic1 + ( 1.0 - zindic ) * tfu(ji,jj)
261               tbif(ji,jj,3) = zindic * ztic2 + ( 1.0 - zindic ) * tfu(ji,jj)
262               qstoif(ji,jj) = zindb  * xlic * zs0st(ji,jj) /  MAX( zs0a(ji,jj), epsi16 )
263            END DO
264         END DO
265         !
266      ENDIF
267      !
268   END SUBROUTINE lim_trp_2
269
270
271   SUBROUTINE lim_trp_init_2
272      !!-------------------------------------------------------------------
273      !!                  ***  ROUTINE lim_trp_init_2  ***
274      !!
275      !! ** Purpose :   initialization of ice advection parameters
276      !!
277      !! ** Method  :   Read the namicetrp namelist and check the parameter
278      !!              values called at the first timestep (nit000)
279      !!
280      !! ** input   :   Namelist namicetrp
281      !!-------------------------------------------------------------------
282      NAMELIST/namicetrp/ bound
283      !!-------------------------------------------------------------------
284      !
285      REWIND ( numnam_ice )      ! Read Namelist namicetrp
286      READ   ( numnam_ice  , namicetrp )
287      IF(lwp) THEN
288         WRITE(numout,*)
289         WRITE(numout,*) 'lim_trp_init_2 : Ice parameters for advection '
290         WRITE(numout,*) '~~~~~~~~~~~~~~'
291         WRITE(numout,*) '   boundary conditions (0. no-slip, 1. free-slip) bound  = ', bound
292      ENDIF
293      !
294   END SUBROUTINE lim_trp_init_2
295
296#else
297   !!----------------------------------------------------------------------
298   !!   Default option         Empty Module                No sea-ice model
299   !!----------------------------------------------------------------------
300CONTAINS
301   SUBROUTINE lim_trp_2        ! Empty routine
302   END SUBROUTINE lim_trp_2
303#endif
304
305   !!======================================================================
306END MODULE limtrp_2
Note: See TracBrowser for help on using the repository browser.