| 1 | MODULE daymod |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE daymod *** |
|---|
| 4 | !! Ocean : calendar |
|---|
| 5 | !!===================================================================== |
|---|
| 6 | !! History : OPA ! 1994-09 (M. Pontaud M. Imbard) Original code |
|---|
| 7 | !! ! 1997-03 (O. Marti) |
|---|
| 8 | !! ! 1997-05 (G. Madec) |
|---|
| 9 | !! ! 1997-08 (M. Imbard) |
|---|
| 10 | !! NEMO 1.0 ! 2003-09 (G. Madec) F90 + nyear, nmonth, nday |
|---|
| 11 | !! ! 2004-01 (A.M. Treguier) new calculation based on adatrj |
|---|
| 12 | !! ! 2006-08 (G. Madec) surface module major update |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | !! day : calendar |
|---|
| 17 | !! |
|---|
| 18 | !! ------------------------------- |
|---|
| 19 | !! ----------- WARNING ----------- |
|---|
| 20 | !! |
|---|
| 21 | !! we suppose that the time step is deviding the number of second of in a day |
|---|
| 22 | !! ---> MOD( rday, rdttra(1) ) == 0 |
|---|
| 23 | !! |
|---|
| 24 | !! ----------- WARNING ----------- |
|---|
| 25 | !! ------------------------------- |
|---|
| 26 | !! |
|---|
| 27 | !!---------------------------------------------------------------------- |
|---|
| 28 | USE dom_oce ! ocean space and time domain |
|---|
| 29 | USE phycst ! physical constants |
|---|
| 30 | USE in_out_manager ! I/O manager |
|---|
| 31 | USE iom ! |
|---|
| 32 | USE ioipsl, ONLY : ymds2ju ! for calendar |
|---|
| 33 | USE prtctl ! Print control |
|---|
| 34 | USE restart ! |
|---|
| 35 | |
|---|
| 36 | IMPLICIT NONE |
|---|
| 37 | PRIVATE |
|---|
| 38 | |
|---|
| 39 | PUBLIC day ! called by step.F90 |
|---|
| 40 | PUBLIC day_init ! called by istate.F90 |
|---|
| 41 | |
|---|
| 42 | INTEGER :: nsecd, nsecd05, ndt, ndt05 |
|---|
| 43 | |
|---|
| 44 | !!---------------------------------------------------------------------- |
|---|
| 45 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
|---|
| 46 | !! $Id$ |
|---|
| 47 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 48 | !!---------------------------------------------------------------------- |
|---|
| 49 | |
|---|
| 50 | CONTAINS |
|---|
| 51 | |
|---|
| 52 | SUBROUTINE day_init |
|---|
| 53 | !!---------------------------------------------------------------------- |
|---|
| 54 | !! *** ROUTINE day_init *** |
|---|
| 55 | !! |
|---|
| 56 | !! ** Purpose : Initialization of the calendar values to their values 1 time step before nit000 |
|---|
| 57 | !! because day will be called at the beginning of step |
|---|
| 58 | !! |
|---|
| 59 | !! ** Action : - nyear : current year |
|---|
| 60 | !! - nmonth : current month of the year nyear |
|---|
| 61 | !! - nday : current day of the month nmonth |
|---|
| 62 | !! - nday_year : current day of the year nyear |
|---|
| 63 | !! - nsec_year : current time step counted in second since 00h jan 1st of the current year |
|---|
| 64 | !! - nsec_month : current time step counted in second since 00h 1st day of the current month |
|---|
| 65 | !! - nsec_day : current time step counted in second since 00h of the current day |
|---|
| 66 | !! - nsec1jan000 : second since Jan. 1st 00h of nit000 year and Jan. 1st 00h of the current year |
|---|
| 67 | !! - nmonth_len, nyear_len, nmonth_half, nmonth_end through day_mth |
|---|
| 68 | !!---------------------------------------------------------------------- |
|---|
| 69 | INTEGER :: inbday, idweek |
|---|
| 70 | REAL(wp) :: zjul |
|---|
| 71 | !!---------------------------------------------------------------------- |
|---|
| 72 | |
|---|
| 73 | ! all calendar staff is based on the fact that MOD( rday, rdttra(1) ) == 0 |
|---|
| 74 | IF( MOD( rday , rdttra(1) ) /= 0. ) CALL ctl_stop( 'the time step must devide the number of second of in a day' ) |
|---|
| 75 | IF( MOD( rday , 2. ) /= 0. ) CALL ctl_stop( 'the number of second of in a day must be an even number' ) |
|---|
| 76 | IF( MOD( rdttra(1), 2. ) /= 0. ) CALL ctl_stop( 'the time step (in second) must be an even number' ) |
|---|
| 77 | nsecd = NINT(rday ) |
|---|
| 78 | nsecd05 = NINT(0.5 * rday ) |
|---|
| 79 | ndt = NINT( rdttra(1)) |
|---|
| 80 | ndt05 = NINT(0.5 * rdttra(1)) |
|---|
| 81 | |
|---|
| 82 | CALL day_rst( nit000, 'READ' ) |
|---|
| 83 | |
|---|
| 84 | ! set the calandar from ndastp (read in restart file and namelist) |
|---|
| 85 | |
|---|
| 86 | nyear = ndastp / 10000 |
|---|
| 87 | nmonth = ( ndastp - (nyear * 10000) ) / 100 |
|---|
| 88 | nday = ndastp - (nyear * 10000) - ( nmonth * 100 ) |
|---|
| 89 | |
|---|
| 90 | CALL ymds2ju( nyear, nmonth, nday, 0.0, fjulday ) ! we assume that we start run at 00:00 |
|---|
| 91 | IF( ABS(fjulday - REAL(NINT(fjulday),wp)) < 0.1 / rday ) fjulday = REAL(NINT(fjulday),wp) ! avoid truncation error |
|---|
| 92 | fjulday = fjulday + 1. ! move back to the day at nit000 (and not at nit000 - 1) |
|---|
| 93 | |
|---|
| 94 | nsec1jan000 = 0 |
|---|
| 95 | CALL day_mth |
|---|
| 96 | |
|---|
| 97 | IF ( nday == 0 ) THEN ! for ex if ndastp = ndate0 - 1 |
|---|
| 98 | nmonth = nmonth - 1 |
|---|
| 99 | nday = nmonth_len(nmonth) |
|---|
| 100 | ENDIF |
|---|
| 101 | IF ( nmonth == 0 ) THEN ! go at the end of previous year |
|---|
| 102 | nmonth = 12 |
|---|
| 103 | nyear = nyear - 1 |
|---|
| 104 | nsec1jan000 = nsec1jan000 - nsecd * nyear_len(0) |
|---|
| 105 | IF( nleapy == 1 ) CALL day_mth |
|---|
| 106 | ENDIF |
|---|
| 107 | |
|---|
| 108 | ! day since january 1st |
|---|
| 109 | nday_year = nday + SUM( nmonth_len(1:nmonth - 1) ) |
|---|
| 110 | |
|---|
| 111 | !compute number of days between last monday and today |
|---|
| 112 | CALL ymds2ju( 1900, 01, 01, 0.0, zjul ) ! compute julian day value of 01.01.1900 (our reference that was a Monday) |
|---|
| 113 | inbday = NINT(fjulday - zjul) ! compute nb day between 01.01.1900 and current day |
|---|
| 114 | idweek = MOD(inbday, 7) ! compute nb day between last monday and current day |
|---|
| 115 | |
|---|
| 116 | ! number of seconds since the beginning of current year/month/week/day at the middle of the time-step |
|---|
| 117 | nsec_year = nday_year * nsecd - ndt05 ! 1 time step before the middle of the first time step |
|---|
| 118 | nsec_month = nday * nsecd - ndt05 ! because day will be called at the beginning of step |
|---|
| 119 | nsec_week = idweek * nsecd - ndt05 |
|---|
| 120 | nsec_day = nsecd - ndt05 |
|---|
| 121 | |
|---|
| 122 | ! control print |
|---|
| 123 | IF(lwp) WRITE(numout,'(a,i6,a,i2,a,i2,a,i6)')' ==============>> 1/2 time step before the start of the run DATE Y/M/D = ', & |
|---|
| 124 | & nyear, '/', nmonth, '/', nday, ' nsec_day:', nsec_day, ' nsec_week:', nsec_week |
|---|
| 125 | |
|---|
| 126 | ! Up to now, calendar parameters are related to the end of previous run (nit000-1) |
|---|
| 127 | ! call day to set the calendar parameters at the begining of the current simulaton. needed by iom_init |
|---|
| 128 | CALL day( nit000 ) |
|---|
| 129 | |
|---|
| 130 | |
|---|
| 131 | END SUBROUTINE day_init |
|---|
| 132 | |
|---|
| 133 | |
|---|
| 134 | SUBROUTINE day_mth |
|---|
| 135 | !!---------------------------------------------------------------------- |
|---|
| 136 | !! *** ROUTINE day_init *** |
|---|
| 137 | !! |
|---|
| 138 | !! ** Purpose : calendar values related to the months |
|---|
| 139 | !! |
|---|
| 140 | !! ** Action : - nmonth_len : length in days of the months of the current year |
|---|
| 141 | !! - nyear_len : length in days of the previous/current year |
|---|
| 142 | !! - nmonth_half : second since the beginning of the year and the halft of the months |
|---|
| 143 | !! - nmonth_end : second since the beginning of the year and the end of the months |
|---|
| 144 | !!---------------------------------------------------------------------- |
|---|
| 145 | INTEGER :: jm ! dummy loop indice |
|---|
| 146 | !!---------------------------------------------------------------------- |
|---|
| 147 | |
|---|
| 148 | ! length of the month of the current year (from nleapy, read in namelist) |
|---|
| 149 | IF ( nleapy < 2 ) THEN |
|---|
| 150 | nmonth_len(:) = (/ 31, 31, 28, 31, 30, 31, 30, 31, 31, 30, 31, 30, 31, 31 /) |
|---|
| 151 | nyear_len(:) = 365 |
|---|
| 152 | IF ( nleapy == 1 ) THEN ! we are using calandar with leap years |
|---|
| 153 | IF ( MOD(nyear-1, 4) == 0 .AND. ( MOD(nyear-1, 400) == 0 .OR. MOD(nyear-1, 100) /= 0 ) ) THEN |
|---|
| 154 | nyear_len(0) = 366 |
|---|
| 155 | ENDIF |
|---|
| 156 | IF ( MOD(nyear, 4) == 0 .AND. ( MOD(nyear, 400) == 0 .OR. MOD(nyear, 100) /= 0 ) ) THEN |
|---|
| 157 | nmonth_len(2) = 29 |
|---|
| 158 | nyear_len(1) = 366 |
|---|
| 159 | ENDIF |
|---|
| 160 | ENDIF |
|---|
| 161 | ELSE |
|---|
| 162 | nmonth_len(:) = nleapy ! all months with nleapy days per year |
|---|
| 163 | nyear_len(:) = 12 * nleapy |
|---|
| 164 | ENDIF |
|---|
| 165 | |
|---|
| 166 | ! half month in second since the begining of the year: |
|---|
| 167 | ! time since Jan 1st 0 1 2 ... 11 12 13 |
|---|
| 168 | ! ---------*--|--*--|--*--| ... |--*--|--*--|--*--|-------------------------------------- |
|---|
| 169 | ! <---> <---> <---> ... <---> <---> <---> |
|---|
| 170 | ! month number 0 1 2 ... 11 12 13 |
|---|
| 171 | ! |
|---|
| 172 | ! nmonth_half(jm) = rday * REAL( 0.5 * nmonth_len(jm) + SUM(nmonth_len(1:jm-1)) ) |
|---|
| 173 | nmonth_half(0) = - nsecd05 * nmonth_len(0) |
|---|
| 174 | DO jm = 1, 13 |
|---|
| 175 | nmonth_half(jm) = nmonth_half(jm-1) + nsecd05 * ( nmonth_len(jm-1) + nmonth_len(jm) ) |
|---|
| 176 | END DO |
|---|
| 177 | |
|---|
| 178 | nmonth_end(0) = 0 |
|---|
| 179 | DO jm = 1, 13 |
|---|
| 180 | nmonth_end(jm) = nmonth_end(jm-1) + nsecd * nmonth_len(jm) |
|---|
| 181 | END DO |
|---|
| 182 | ! |
|---|
| 183 | END SUBROUTINE |
|---|
| 184 | |
|---|
| 185 | |
|---|
| 186 | SUBROUTINE day( kt ) |
|---|
| 187 | !!---------------------------------------------------------------------- |
|---|
| 188 | !! *** ROUTINE day *** |
|---|
| 189 | !! |
|---|
| 190 | !! ** Purpose : Compute the date with a day iteration IF necessary. |
|---|
| 191 | !! |
|---|
| 192 | !! ** Method : - ??? |
|---|
| 193 | !! |
|---|
| 194 | !! ** Action : - nyear : current year |
|---|
| 195 | !! - nmonth : current month of the year nyear |
|---|
| 196 | !! - nday : current day of the month nmonth |
|---|
| 197 | !! - nday_year : current day of the year nyear |
|---|
| 198 | !! - ndastp : = nyear*10000 + nmonth*100 + nday |
|---|
| 199 | !! - adatrj : date in days since the beginning of the run |
|---|
| 200 | !! - nsec_year : current time of the year (in second since 00h, jan 1st) |
|---|
| 201 | !!---------------------------------------------------------------------- |
|---|
| 202 | INTEGER, INTENT(in) :: kt ! ocean time-step indices |
|---|
| 203 | ! |
|---|
| 204 | CHARACTER (len=25) :: charout |
|---|
| 205 | REAL(wp) :: zprec ! fraction of day corresponding to 0.1 second |
|---|
| 206 | !!---------------------------------------------------------------------- |
|---|
| 207 | zprec = 0.1 / rday |
|---|
| 208 | ! ! New time-step |
|---|
| 209 | nsec_year = nsec_year + ndt |
|---|
| 210 | nsec_month = nsec_month + ndt |
|---|
| 211 | nsec_week = nsec_week + ndt |
|---|
| 212 | nsec_day = nsec_day + ndt |
|---|
| 213 | adatrj = adatrj + rdttra(1) / rday |
|---|
| 214 | fjulday = fjulday + rdttra(1) / rday |
|---|
| 215 | IF( ABS(fjulday - REAL(NINT(fjulday),wp)) < zprec ) fjulday = REAL(NINT(fjulday),wp) ! avoid truncation error |
|---|
| 216 | IF( ABS(adatrj - REAL(NINT(adatrj ),wp)) < zprec ) adatrj = REAL(NINT(adatrj ),wp) ! avoid truncation error |
|---|
| 217 | |
|---|
| 218 | IF( nsec_day > nsecd ) THEN ! New day |
|---|
| 219 | ! |
|---|
| 220 | nday = nday + 1 |
|---|
| 221 | nday_year = nday_year + 1 |
|---|
| 222 | nsec_day = ndt05 |
|---|
| 223 | ! |
|---|
| 224 | IF( nday == nmonth_len(nmonth) + 1 ) THEN ! New month |
|---|
| 225 | nday = 1 |
|---|
| 226 | nmonth = nmonth + 1 |
|---|
| 227 | nsec_month = ndt05 |
|---|
| 228 | IF( nmonth == 13 ) THEN ! New year |
|---|
| 229 | nyear = nyear + 1 |
|---|
| 230 | nmonth = 1 |
|---|
| 231 | nday_year = 1 |
|---|
| 232 | nsec_year = ndt05 |
|---|
| 233 | nsec1jan000 = nsec1jan000 + nsecd * nyear_len(1) |
|---|
| 234 | IF( nleapy == 1 ) CALL day_mth |
|---|
| 235 | ENDIF |
|---|
| 236 | ENDIF |
|---|
| 237 | ! |
|---|
| 238 | ndastp = nyear * 10000 + nmonth * 100 + nday ! New date |
|---|
| 239 | ! |
|---|
| 240 | !compute first day of the year in julian days |
|---|
| 241 | CALL ymds2ju( nyear, 01, 01, 0.0, fjulstartyear ) |
|---|
| 242 | ! |
|---|
| 243 | IF(lwp) WRITE(numout,'(a,i8,a,i4.4,a,i2.2,a,i2.2,a,i3.3)') '======>> time-step =', kt, & |
|---|
| 244 | & ' New day, DATE Y/M/D = ', nyear, '/', nmonth, '/', nday, ' nday_year = ', nday_year |
|---|
| 245 | IF(lwp) WRITE(numout,'(a,i8,a,i7,a,i5)') ' nsec_year = ', nsec_year, & |
|---|
| 246 | & ' nsec_month = ', nsec_month, ' nsec_day = ', nsec_day, ' nsec_week = ', nsec_week |
|---|
| 247 | ENDIF |
|---|
| 248 | |
|---|
| 249 | IF( nsec_week > 7*nsecd ) nsec_week = ndt05 ! New week |
|---|
| 250 | |
|---|
| 251 | IF(ln_ctl) THEN |
|---|
| 252 | WRITE(charout,FMT="('kt =', I4,' d/m/y =',I2,I2,I4)") kt, nday, nmonth, nyear |
|---|
| 253 | CALL prt_ctl_info(charout) |
|---|
| 254 | ENDIF |
|---|
| 255 | |
|---|
| 256 | #if ! defined key_offline |
|---|
| 257 | CALL rst_opn( kt ) ! Open the restart file if needed and control lrst_oce |
|---|
| 258 | #endif |
|---|
| 259 | IF( lrst_oce ) CALL day_rst( kt, 'WRITE' ) ! write day restart information |
|---|
| 260 | ! |
|---|
| 261 | END SUBROUTINE day |
|---|
| 262 | |
|---|
| 263 | |
|---|
| 264 | SUBROUTINE day_rst( kt, cdrw ) |
|---|
| 265 | !!--------------------------------------------------------------------- |
|---|
| 266 | !! *** ROUTINE ts_rst *** |
|---|
| 267 | !! |
|---|
| 268 | !! ** Purpose : Read or write calendar in restart file: |
|---|
| 269 | !! |
|---|
| 270 | !! WRITE(READ) mode: |
|---|
| 271 | !! kt : number of time step since the begining of the experiment at the |
|---|
| 272 | !! end of the current(previous) run |
|---|
| 273 | !! adatrj(0) : number of elapsed days since the begining of the experiment at the |
|---|
| 274 | !! end of the current(previous) run (REAL -> keep fractions of day) |
|---|
| 275 | !! ndastp : date at the end of the current(previous) run (coded as yyyymmdd integer) |
|---|
| 276 | !! |
|---|
| 277 | !! According to namelist parameter nrstdt, |
|---|
| 278 | !! nrstdt = 0 no control on the date (nit000 is arbitrary). |
|---|
| 279 | !! nrstdt = 1 we verify that nit000 is equal to the last |
|---|
| 280 | !! time step of previous run + 1. |
|---|
| 281 | !! In both those options, the exact duration of the experiment |
|---|
| 282 | !! since the beginning (cumulated duration of all previous restart runs) |
|---|
| 283 | !! is not stored in the restart and is assumed to be (nit000-1)*rdt. |
|---|
| 284 | !! This is valid is the time step has remained constant. |
|---|
| 285 | !! |
|---|
| 286 | !! nrstdt = 2 the duration of the experiment in days (adatrj) |
|---|
| 287 | !! has been stored in the restart file. |
|---|
| 288 | !!---------------------------------------------------------------------- |
|---|
| 289 | INTEGER , INTENT(in) :: kt ! ocean time-step |
|---|
| 290 | CHARACTER(len=*), INTENT(in) :: cdrw ! "READ"/"WRITE" flag |
|---|
| 291 | ! |
|---|
| 292 | REAL(wp) :: zkt, zndastp |
|---|
| 293 | !!---------------------------------------------------------------------- |
|---|
| 294 | |
|---|
| 295 | IF( TRIM(cdrw) == 'READ' ) THEN |
|---|
| 296 | |
|---|
| 297 | IF( iom_varid( numror, 'kt', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 298 | ! Get Calendar informations |
|---|
| 299 | CALL iom_get( numror, 'kt', zkt ) ! last time-step of previous run |
|---|
| 300 | IF(lwp) THEN |
|---|
| 301 | WRITE(numout,*) ' *** Info read in restart : ' |
|---|
| 302 | WRITE(numout,*) ' previous time-step : ', NINT( zkt ) |
|---|
| 303 | WRITE(numout,*) ' *** restart option' |
|---|
| 304 | SELECT CASE ( nrstdt ) |
|---|
| 305 | CASE ( 0 ) ; WRITE(numout,*) ' nrstdt = 0 : no control of nit000' |
|---|
| 306 | CASE ( 1 ) ; WRITE(numout,*) ' nrstdt = 1 : no control the date at nit000 (use ndate0 read in the namelist)' |
|---|
| 307 | CASE ( 2 ) ; WRITE(numout,*) ' nrstdt = 2 : calendar parameters read in restart' |
|---|
| 308 | END SELECT |
|---|
| 309 | WRITE(numout,*) |
|---|
| 310 | ENDIF |
|---|
| 311 | ! Control of date |
|---|
| 312 | IF( nit000 - NINT( zkt ) /= 1 .AND. nrstdt /= 0 ) & |
|---|
| 313 | & CALL ctl_stop( ' ===>>>> : problem with nit000 for the restart', & |
|---|
| 314 | & ' verify the restart file or rerun with nrstdt = 0 (namelist)' ) |
|---|
| 315 | ! define ndastp and adatrj |
|---|
| 316 | IF ( nrstdt == 2 ) THEN |
|---|
| 317 | ! read the parameters correspondting to nit000 - 1 (last time step of previous run) |
|---|
| 318 | CALL iom_get( numror, 'ndastp', zndastp ) |
|---|
| 319 | ndastp = NINT( zndastp ) |
|---|
| 320 | CALL iom_get( numror, 'adatrj', adatrj ) |
|---|
| 321 | ELSE |
|---|
| 322 | ! parameters correspondting to nit000 - 1 (as we start the step loop with a call to day) |
|---|
| 323 | ndastp = ndate0 - 1 ! ndate0 read in the namelist in dom_nam, we assume that we start run at 00:00 |
|---|
| 324 | adatrj = ( REAL( nit000-1, wp ) * rdttra(1) ) / rday |
|---|
| 325 | ! note this is wrong if time step has changed during run |
|---|
| 326 | ENDIF |
|---|
| 327 | ELSE |
|---|
| 328 | ! parameters correspondting to nit000 - 1 (as we start the step loop with a call to day) |
|---|
| 329 | ndastp = ndate0 - 1 ! ndate0 read in the namelist in dom_nam, we assume that we start run at 00:00 |
|---|
| 330 | adatrj = ( REAL( nit000-1, wp ) * rdttra(1) ) / rday |
|---|
| 331 | ENDIF |
|---|
| 332 | IF( ABS(adatrj - REAL(NINT(adatrj),wp)) < 0.1 / rday ) adatrj = REAL(NINT(adatrj),wp) ! avoid truncation error |
|---|
| 333 | ! |
|---|
| 334 | IF(lwp) THEN |
|---|
| 335 | WRITE(numout,*) ' *** Info used values : ' |
|---|
| 336 | WRITE(numout,*) ' date ndastp : ', ndastp |
|---|
| 337 | WRITE(numout,*) ' number of elapsed days since the begining of run : ', adatrj |
|---|
| 338 | WRITE(numout,*) |
|---|
| 339 | ENDIF |
|---|
| 340 | ! |
|---|
| 341 | ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN |
|---|
| 342 | ! |
|---|
| 343 | IF( kt == nitrst ) THEN |
|---|
| 344 | IF(lwp) WRITE(numout,*) |
|---|
| 345 | IF(lwp) WRITE(numout,*) 'rst_write : write oce restart file kt =', kt |
|---|
| 346 | IF(lwp) WRITE(numout,*) '~~~~~~~' |
|---|
| 347 | ENDIF |
|---|
| 348 | ! calendar control |
|---|
| 349 | CALL iom_rstput( kt, nitrst, numrow, 'kt' , REAL( kt , wp) ) ! time-step |
|---|
| 350 | CALL iom_rstput( kt, nitrst, numrow, 'ndastp' , REAL( ndastp, wp) ) ! date |
|---|
| 351 | CALL iom_rstput( kt, nitrst, numrow, 'adatrj' , adatrj ) ! number of elapsed days since |
|---|
| 352 | ! ! the begining of the run [s] |
|---|
| 353 | ENDIF |
|---|
| 354 | ! |
|---|
| 355 | END SUBROUTINE day_rst |
|---|
| 356 | |
|---|
| 357 | !!====================================================================== |
|---|
| 358 | END MODULE daymod |
|---|
